возвращает%индекс » Поиск

Результаты по ключевому слову: возвращает%индекс

Функции сохранения таблицы значений в файл и чтения из файла

В данном примере хочу привести несколько универсальных функций по выгрузке таблицы значений в файл и дальнейшего чтения из файла:

Порядок программных действий при выгрузке в файл выглядит так:

Подготавливаем таблицу значений (выгружаем из табличной части, выбираем колонки);
Конвертируем таблицу значений в табличный документ;
Сохраняем табличный документ в MXL.

При загрузке таблицы порядок действий такой:

Читаем из файла табличный документ;
Конвертируем табличный документ в таблицу значений;
Используем эту таблицу значений в своих целях (загружаем в табличную часть).

Соответственно файл для хранения данных таблицы имеет расширение *.mxl.

Основные функции для реализации поставленной задачи следующие:

ПреобразоватьТДвТЗ – Функция преобразования табличного документа в таблицу значений.

ПреобразоватьТЗвТД – Функция обратного преобразования таблицы значений в табличный документ.

ПрочитатьТЗИзMXL – Читает из файла данные, определяет колонки таблицы и преобразует эти данные в таблицу значений.

ЗаписатьТЗВMXL – Преобразует таблицу значений в табличный документ и записывает его в файл.

Код 1C v 8.3

 // Преобразовать табличный документ в таблицу значений.

//

// Параметры:

//	ТабДок - <ТабличныйДокумент> - Исходный табличный документ;

//	СтруктураКолонок - <Структура>, <ТаблицаЗначений> - Структура колонок;

//	НачалоСтрока - <Число> - Строка начала области;

//	НачалоСтолбец - <Число> - Столбец начала области;

//	КонецСтрока - <Число> - Строка конца области;

//	КонецСтолбец - <Число> - Столбец конца области.

//	

// Возвращаемое значение:

//	<ТаблицаЗначений> - Полученная таблица значений.

//

Функция ПреобразоватьТДвТЗ(ТабДок, СтруктураКолонок, Знач НачалоСтрока = Неопределено, Знач НачалоСтолбец = Неопределено, Знач КонецСтрока = Неопределено, Знач КонецСтолбец = Неопределено) Экспорт

 

	// Определение габаритов таблицы

	Если НачалоСтрока = Неопределено И НачалоСтолбец = Неопределено Тогда

		НачалоСтрока = 1;

		НачалоСтолбец = 1;

	КонецЕсли;

 

	Если НачалоСтрока = Неопределено Тогда

		НачалоСтрока = 1;

		Пока НЕ ТабДок.Область(НачалоСтрока, НачалоСтолбец).СодержитЗначение 

		 И НачалоСтрока < ТабДок.ВысотаТаблицы 

		Цикл

			НачалоСтрока = НачалоСтрока + 1;

		КонецЦикла;

	ИначеЕсли НачалоСтолбец = Неопределено Тогда

		НачалоСтолбец = 1;

		Пока НЕ ТабДок.Область(НачалоСтрока, НачалоСтолбец).СодержитЗначение 

		 И НачалоСтолбец < ТабДок.ШиринаТаблицы

		Цикл

			НачалоСтолбец = НачалоСтолбец + 1;

		КонецЦикла;

	КонецЕсли;

 

	КонецСтрока = ?(КонецСтрока = Неопределено, ТабДок.ВысотаТаблицы, КонецСтрока);

	КонецСтолбец = ?(КонецСтолбец = Неопределено, ТабДок.ШиринаТаблицы, КонецСтолбец);

 

	// Преобразование

	ЭтоТаблица = (ТипЗнч(СтруктураКолонок) = Тип("ТаблицаЗначений"));

	ТабЗначений = ПолучитьТаблицуВывода(СтруктураКолонок);

 

	Для ИндексСтроки = НачалоСтрока По КонецСтрока Цикл

		СтрокаТЗ = ТабЗначений.Добавить();

 

		ИндексКолонки = НачалоСтолбец;

		Для Каждого Колонка Из СтруктураКолонок Цикл

			НаименованиеКолонки = ?(ЭтоТаблица, Колонка.Наименование, Колонка.Ключ);

			пИндексКолонки = ?(ЭтоТаблица, Колонка.СтолбецОтчёт, ИндексКолонки);

 

			Если ТабДок.Область(ИндексСтроки, пИндексКолонки).СодержитЗначение Тогда

				СтрокаТЗ[НаименованиеКолонки] = ТабДок.Область(ИндексСтроки, пИндексКолонки).Значение;

			Иначе

				СтрокаТЗ[НаименованиеКолонки] = ТабДок.Область(ИндексСтроки, пИндексКолонки).Текст;

			КонецЕсли;

 

			ИндексКолонки = ИндексКолонки + 1;

		КонецЦикла;

	КонецЦикла;

 

	Возврат ТабЗначений;

КонецФункции;



// Преобразовать таблицу значений в табличный документ.

//

// Параметры:

//	ТабЗначений - <ТаблицаЗначений> - Исходная таблица значений;

//	ТабДок - <ТабличныйДокумент> - Полученный табличный документ. Если параметр не задан, 

//	 то документ создаётся заново и возвращается функцией;

//	НачалоСтрока - <Число> - Строка начала области;

//	НачалоСтолбец - <Число> - Столбец начала области;

//	ВыводитьЗаголовки - <Булево> - Определяет выводить ли имена колонок или нет.

//	

// Возвращаемое значение:

//	<ТабличныйДокумент> - Полученный табличный документ (возвращает параметр "ТабДок").

//

Функция ПреобразоватьТЗвТД(ТабЗначений, ТабДок = Неопределено, Знач НачалоСтрока = Неопределено, Знач НачалоСтолбец = Неопределено, ВыводитьЗаголовки = Ложь) Экспорт

 

	Если ТабДок = Неопределено Тогда

		ТабДок = Новый ТабличныйДокумент;

	КонецЕсли;

 

	// Определение габаритов таблицы

	НачалоСтрока = ?(НачалоСтрока = Неопределено, 1, НачалоСтрока);

	НачалоСтолбец = ?(НачалоСтолбец = Неопределено, 1, НачалоСтолбец);

 

	// Преобразование

	ИндексСтроки = НачалоСтрока;

	Если ВыводитьЗаголовки Тогда

		ИндексКолонки = НачалоСтолбец;

		Для Каждого Колонка Из ТабЗначений.Колонки Цикл

			ТабДок.Область(ИндексСтроки, ИндексКолонки).Текст = ?(ПустаяСтрока(Колонка.Заголовок), Колонка.Имя, Колонка.Заголовок);

			ИндексКолонки = ИндексКолонки + 1;

		КонецЦикла;

		ИндексСтроки = ИндексСтроки + 1;

	КонецЕсли;

 

	Для Каждого Элемент Из ТабЗначений Цикл

		ИндексКолонки = НачалоСтолбец;

		Для Каждого Колонка Из ТабЗначений.Колонки Цикл

			ТабДок.Область(ИндексСтроки, ИндексКолонки).СодержитЗначение = Истина;

			ТабДок.Область(ИндексСтроки, ИндексКолонки).ТипЗначения = Новый ОписаниеТипов(Колонка.ТипЗначения);

			ТабДок.Область(ИндексСтроки, ИндексКолонки).Значение = Элемент[Колонка.Имя];

			ИндексКолонки = ИндексКолонки + 1;

		КонецЦикла;

		ИндексСтроки = ИндексСтроки + 1;

	КонецЦикла;

 

	Возврат ТабДок;

КонецФункции;



// Читает табличный документ из файла MXL и преобразует его в таблицу значений.

//

// Параметры:

//	ИмяФайла - <Строка> - Путь к файлу MXL;

//	СтруктураКолонок - <Структура>, <ТаблицаЗначений> - Структура колонок. Если этот параметр

//		не задан, то структура колонок формируется из самого табличного документа;

//	ЕстьЗаголовок - <Булево> - Есть ли первая строка с заголовками или нет.

//	

// Возвращаемое значение:

//	<ТаблицаЗначений> - Полученная таблица значений.

//

Функция ПрочитатьТЗИзMXL(ИмяФайла, СтруктураКолонок = Неопределено, ЕстьЗаголовок = Истина) Экспорт

 

	ТабДок = Новый ТабличныйДокумент;

	ТабДок.Прочитать(ИмяФайла);

 

	Если СтруктураКолонок = Неопределено И ЕстьЗаголовок Тогда

		СтруктураКолонок = Новый Структура;

		Для ИндексКолонки = 1 По ТабДок.ШиринаТаблицы Цикл

			Обл1 = ТабДок.Область(1, ИндексКолонки);

			Обл2 = ТабДок.Область(2, ИндексКолонки);

			ИмяКолонки = СокрЛП(Обл1.Текст);

			ИмяКолонки = ?(Найти(ИмяКолонки, " ") > 0, СтрЗаменить(ТРег(ИмяКолонки), " ", ""), ИмяКолонки);

			СтруктураКолонок.Вставить(ИмяКолонки, ?(Обл2.СодержитЗначение, Обл2.ТипЗначения, Новый ОписаниеТипов));

		КонецЦикла;

	ИначеЕсли СтруктураКолонок = Неопределено И НЕ ЕстьЗаголовок Тогда

		СтруктураКолонок = Новый Структура;

		Для ИндексКолонки = 1 По ТабДок.ШиринаТаблицы Цикл

			Обл2 = ТабДок.Область(1, ИндексКолонки);

			ИмяКолонки = "К" + Формат(ИндексКолонки, "ЧДЦ=0; ЧН=0; ЧГ=0");

			СтруктураКолонок.Вставить(ИмяКолонки, ?(Обл2.СодержитЗначение, Обл2.ТипЗначения, Новый ОписаниеТипов));

		КонецЦикла;

	КонецЕсли;

 

    Таблица = ПреобразоватьТДвТЗ(ТабДок, СтруктураКолонок, ?(ЕстьЗаголовок, 2, 1), 1);

 

	Возврат Таблица;

КонецФункции;



// Сохраняет таблицу значений в файле в виде табличного документа.

//

// Параметры:

//	ИмяФайла - <Строка> - Путь к файлу MXL;

//	ТабЗначений - <ТаблицаЗначений> - Сохраняемая таблица значений;

//	ЕстьЗаголовок - <Булево> - Есть ли первая строка с заголовками или нет.

//

Процедура ЗаписатьТЗВMXL(ИмяФайла, ТабЗначений, ЕстьЗаголовок = Истина) Экспорт

 

	ТабДок = ПреобразоватьТЗвТД(ТабЗначений, Неопределено, 1, 1, ЕстьЗаголовок);

	ТабДок.Записать(ИмяФайла, ТипФайлаТабличногоДокумента.MXL);

 

КонецПроцедуры;

Еще небольшой набор функций для вывода таблицы значений в табличный документ. После формирования табличного документа, - сохраняем его в файл mxl.

Табличный документ можно сохранить a файлы следующих типов:

ANSITXT - Текстовый документ
DOCX - документ MS Word
HTML
HTML3
HTML4
HTML5
MXL
MXL7
ODS - Файл Open Office
PDF - файл Acrobat Readr
TXT - Текстовый документ
XLS - файл Excel
XLS95 - файл Excel95
XLS97 - файл Excel97
XLSX - файл Excel2010

Код 1C v 8.3

 // Получаем таблицу значения из файла. 

Функция ЗагрузитьТЗизФайла(ИмяФайла)    

    Путь = КаталогВременныхФайлов() + ИмяФайла; 

    Текст = Новый ЧтениеТекста(Путь, КодировкаТекста.UTF8); 

    стрТЗ = Текст.Прочитать(); 

    Текст.Закрыть(); 

    // получим таблицу значений из строки

    ТЗ = ЗначениеИзСтрокиВнутр(стрТЗ);    

    Возврат ТЗ;    

КонецФункции    



// Заполнить ячейки в строке  значениями 

//

Функция ЗаписьТЗ2ТабДок(записьТЗ,НомерСтроки,ТабличныйДокумент)

    НомерКолонки = 1;

    Символ160 = Символ(160);    

    // цикл по колонкам таблицы

    // РезультатЗапроса.Колонки.Количество()    // - количество колонок

    Для каждого полеТЗ из ЗаписьТЗ цикл 

        // значения ячейки в Excel

        типПоляТЗ = ТипЗнч(полеТЗ);

        если типПоляТЗ = Тип("Число") тогда             

            полеТЗ=Строка(полеТЗ); 

            полеТЗ=СтрЗаменить(полеТЗ,Символ160,"");

            полеТЗ=СтрЗаменить(полеТЗ,",",".");

        иначеесли типПоляТЗ = Тип("Строка") тогда      

        иначе        

            полеТЗ = строка(полеТЗ);

        КонецЕсли;    

        имяОбласти = "R" + номерСтроки + "C" + НомерКолонки;

        имяОбласти = СтрЗаменить(имяОбласти,Символ(160),"");         

        Ячейка = ТабличныйДокумент.Область(имяОбласти);

        Ячейка.Текст = полеТЗ;

        НомерКолонки = НомерКолонки + 1;

    КонецЦикла;            

КонецФункции



// Заполнить наименованиями колонок таблицу

Функция НаимКолонок2Mxl(ТаблицаЗначений,ТабличныйДокумент)

    // массКолонки = новый массив();

    номерСтроки=1;

    номКолонки=1; 

    ТабличныйДокумент = новый ТабличныйДокумент;

    // цикл по коллекции колонок

    Для НомКол=0 по ТаблицаЗначений.Колонки.Количество() - 1 Цикл

        //Сообщить(Колонка.Имя + "(" + Колонка.ТипЗначения + ")" );            

        имяКолонки=ТаблицаЗначений.Колонки[НомКол].Имя;

        //ТабличныйДокумент.Область(

        имяОбласти = "R" + номерСтроки + "C" + номКолонки;

        имяОбласти = СтрЗаменить(имяОбласти,Символ(160),"");         

        Ячейка = ТабличныйДокумент.Область(имяОбласти);

        //значениеЯчейки = СтрЗаменить(имяОбласти,Символ(160),"");         

        Ячейка.Текст = имяКолонки;

        // на основе текущего шрифта сделаем Жирный

        ЖирныйШрифт = ?(ЖирныйШрифт = Неопределено,Новый Шрифт(Ячейка.Шрифт,,,Истина),ЖирныйШрифт);         

        Ячейка.Шрифт = ЖирныйШрифт;

        номКолонки = номКолонки + 1;        

    КонецЦикла;

КонецФункции





// Заполнить построчно табличный документ

Функция Таблица2Mxl(ТаблицаЗначений,ТабличныйДокумент)

    //Выборка = РезультатЗапроса.Выбрать();

    НомСтр=1; // заполняем данными начиная со 2-й строки    

    // цикл по строкам таблицы

    Для каждого записьТЗ из ТаблицаЗначений Цикл

        НомСтр = НомСтр + 1;

        // цикл по колонкам таблицы        

        ЗаписьТЗ2ТабДок(записьТЗ,НомСтр,ТабличныйДокумент);         

    КонецЦикла;    

КонецФункции



// Таблица значений в табличный документ

Функция ТаблицаЗначений2Mxl(ТаблицаЗначений,ФайлMxl)

    ТабличныйДокумент = новый ТабличныйДокумент;

    // вывести колонки

    НаимКолонок2Mxl(ТаблицаЗначений,ТабличныйДокумент);

    // вывести содержимое таблицы    

    Таблица2Mxl(ТаблицаЗначений,ТабличныйДокумент);

    ТабличныйДокумент.Записать(ФайлMxl,ТипФайлаТабличногоДокумента.MXL);

    ТабличныйДокумент.Показать(ФайлMxl,ФайлMxl);

    Возврат 0;

КонецФункции





Функция    Тест_ВыгрузитьТЗвMxl();

    файл_мТЗИсходныеДанные = "мТЗИсходныеДанные.dat";        

    ТЗ = ЗагрузитьТЗизФайла(файл_мТЗИсходныеДанные);    

    ФайлMxl = КаталогВременныхФайлов() + СтрЗаменить(файл_мТЗИсходныеДанные,".dat",".mxl");  

    ТаблицаЗначений2Mxl(ТЗ,ФайлMxl);

КонецФункции



Тест_ВыгрузитьТЗвMxl();

Пример выгруженной таблицы значений в файл:

Категория: Работа с Таблицей Значений

Печать штрихкода в управляемом приложении

Программируя под 8.2, работающем в режиме управляемого приложения, я столкнулся с проблемой печати штрихкода. Для платформы 8.1 и платформы 8.2 в режиме обычного приложения такой проблемы не было: устанавливаем элемент «1С:Печать штрихкодов» в макет и наслаждаемся вертикальными черточками. В режиме управляемого приложения вываливается ошибка:

Код 1C v 8.2 УП

 ОбластьВывода.Рисунки.ШтрихКод.Объект – неопределено

Что же случилось?
Дело в том, что для управляемого приложения внешние компоненты разрабатываются по другой технологии. Пример внешней компоненты для печати штрих-кода в 8.2 есть в демонстрационной конфигурации "Управляемое приложение" в макетах справочника Товары либо в конфигурации «1С:Управление торговлей» версии 11, макеты обработки «Печать этикеток и ценников».
Данная компонента, получив в качестве параметра строку штрихкода, возвращает картинку – штрихкод, которую программисту предлагается поместить в любое удобное место печатной формы.

Теперь как это сделать.
Всего обработок аж четыре штуки:
КомпонентаПечатиШтрихкодовWindows32
КомпонентаПечатиШтрихкодовWindows64
КомпонентаПечатиШтрихкодовLinux32
КомпонентаПечатиШтрихкодовLinux64

Все они загружены в одноименные макеты. Функция, подключающая внешнюю компоненту в зависимости от платформы может выглядеть так:

Код 1C v 8.х

 Функция ПодключитьВнешнююКомпонентуПечатиШтрихкода() Экспорт

	

	// В зависимости от типа платформы подключим соответствующую внешнюю компоненту

	СистемнаяИнформация = Новый СистемнаяИнформация;



	Если СистемнаяИнформация.ТипПлатформы = ТипПлатформы.Windows_x86 Тогда

		ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("Обработка.ПечатьЭтикетокИЦенников.Макет.КомпонентаПечатиШтрихкодовWindows32", "КартинкаШтрихкода", ТипВнешнейКомпоненты.Native);

	

	ИначеЕсли СистемнаяИнформация.ТипПлатформы = ТипПлатформы.Windows_x86_64 Тогда

		ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("Обработка.ПечатьЭтикетокИЦенников.Макет.КомпонентаПечатиШтрихкодовWindows64", "КартинкаШтрихкода", ТипВнешнейКомпоненты.Native);

	

	ИначеЕсли СистемнаяИнформация.ТипПлатформы = ТипПлатформы.Linux_x86 Тогда

		ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("Обработка.ПечатьЭтикетокИЦенников.Макет.КомпонентаПечатиШтрихкодовLinux32", "КартинкаШтрихкода", ТипВнешнейКомпоненты.Native);

	

	Иначе

		ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("Обработка.ПечатьЭтикетокИЦенников.Макет.КомпонентаПечатиШтрихкодовLinux64", "КартинкаШтрихкода", ТипВнешнейКомпоненты.Native);

	

	КонецЕсли;



	// Создадим объект внешней компоненты

	Если ПодключениеВыполнено Тогда

		ВнешняяКомпонента = Новый("AddIn.КартинкаШтрихкода.Barcode");

	Иначе

		Возврат Неопределено;

	КонецЕсли;

	

	// Если нет возможности рисовать

	Если НЕ ВнешняяКомпонента.ГрафикаУстановлена Тогда

		// То картинку сформировать не сможем

		Возврат Неопределено;

	Иначе

		

		// Установим основные параметры компоненты

		

		// Если в системе установлен шрифт Tahoma

		Если ВнешняяКомпонента.НайтиШрифт("Tahoma") = Истина Тогда

			// Выбираем его как шрифт для формирования картинки

			ВнешняяКомпонента.Шрифт = "Tahoma";

		Иначе

			

			// Шрифт Tahoma в системе отсутствует

			// Обойдем все доступные компоненте шрифты

			Для Сч = 0 По ВнешняяКомпонента.КоличествоШрифтов -1 Цикл

				// Получим очередной шрифт, доступный компоненте

				ТекущийШрифт = ВнешняяКомпонента.ШрифтПоИндексу(Сч);

				// Если шрифт доступен

				Если ТекущийШрифт <> Неопределено Тогда

					// Они и будет шрифтом для формирования штри-кода

					ВнешняяКомпонента.Шрифт = ТекущийШрифт;

					Прервать;

				КонецЕсли;

			КонецЦикла;

		КонецЕсли;

		

		// Утановим размер шрифта

		ВнешняяКомпонента.РазмерШрифта = 10;

		

		Возврат ВнешняяКомпонента;

		

	КонецЕсли;

	

КонецФункции

В коде выше все компоненты загружены в макеты обработки «ПечатьЭтикетокИЦенников». В принципе ничто не мешает поместить их в любое иное место. Вызов функции осуществляется командой:

Код 1C v 8.х

 ВнешняяКомпонента = ПодключитьВнешнююКомпонентуПечатиШтрихкода();

Если что-то не получилось – возвращает НЕОПРЕДЕЛЕНО.

Далее опишем функцию, которая, получив данные, сформирует нужную нам картинку с штрихкодом:

Код 1C v 8.х

 Функция ПолучитьКартинкуШтрихкода(ВнешняяКомпонента, Штрихкод, Ширина, Высота) Экспорт

	

	// Зададим размер картинки

	ВнешняяКомпонента.Ширина =Ширина;

	ВнешняяКомпонента.Высота =Высота;

	

	// Разрешим компоненте самой определять тип кода

	ВнешняяКомпонента.АвтоТип = истина;

	

	// Если код содержит контрольный символ, обязательно указываем

	ВнешняяКомпонента.СодержитКС = СтрДлина(Штрихкод) = 13;

	

	// Если отображать контрольный символ не нужно

	// ВнешняяКомпонента.ВидимостьКС = Ложь;

	

	// Формируем картинку штрихкода

	ВнешняяКомпонента.ЗначениеКода = Штрихкод;

	

	// Если установленная нами ширина меньше минимально допустимой для этого штрихкода

	Если ВнешняяКомпонента.Ширина < ВнешняяКомпонента.МинимальнаяШиринаКода Тогда

		// Скорректируем ширину

		ВнешняяКомпонента.Ширина = ВнешняяКомпонента.МинимальнаяШиринаКода + 10;

	КонецЕсли;

	

	// Сформируем картинку

	ДвоичныеДанныеКартинки = ВнешняяКомпонента.ПолучитьШтрихкод();

	

	// Если картинка сформировалась

	Если ДвоичныеДанныеКартинки <> Неопределено Тогда

		// Формируем из двоичных данных

		Возврат Новый Картинка(ДвоичныеДанныеКартинки);

	КонецЕсли;

	

	Возврат Неопределено;

	

КонецФункции

В данной функции используется автоопределение типа штрихкода командой

Код 1C v 8.х

 ВнешняяКомпонента.АвтоТип = истина;

Можно тип штрихкода указать вручную:

Код 1C v 8.х

 ВнешняяКомпонента.АвтоТип = Ложь;

ВнешняяКомпонента.ТипКода = 1; // указан тип EAN13

ТипКода - число от 0 до 15: 0 - EAN8, 1 - EAN13, 2 - EAN128. Вот полный список типов по порядку:
EAN8, EAN13, EAN128, Code39, Code128, Code16k, PDF417, Standart (Industrial) 2 of 5, Interleaved 2 of 5, Расширение Code39, Code93, ITF14, RSS14, CodaBar, EAN13 AddOn 2, EAN13 AddOn 5.

Кроме типа штрихкода, компонента имеет ряд других свойств, например ВнешняяКомпонента.ОтображатьТекст, ВнешняяКомпонента.РазмерШрифта и прочие, можно посмотреть в свойствах.

Наконец последнее - вывод штрихкода. Для этого в макет поместим картинку с именем «Штрихкод». Получаем и выводим штрихкод в область командой:

Код 1C v 8.х

 ОбластьЗначение.Рисунки.Штрихкод.Картинка = ПолучитьКартинкуШтрихкода(ВнешняяКомпонента, Штрихкод, 50, 30);

Где Штрихкод – переменная, содержащая строку штрихкода номенклатуры, 50 – требуемая ширина, 30 – высота картинки. В макете размер картинки лучше всего поставить «Реальный размер».

Замечание. Сразу бросается в глаза то, что я вручную указываю размер требуемой картинки – 50 на 30. Возникает вопрос, а нельзя ли размеры требуемой картинки получить из картинки на макете? Конечно можно:

Код 1C v 8.х

 ОбластьЗначение.Рисунки.Штрихкод.Ширина

ОбластьЗначение.Рисунки.Штрихкод.Высота

К сожалению, цифры получаемые этими командами почему-то слишком малы. Как получить реальный видимый размер картинки я пока не знаю, может кто подскажет?
Источник

Категория: Штрих-код (barcode)

Переворот или ТРАНСПОНИРОВАНИЕ Таблицы Значений

Задача такова что необходимо поменять местами Колонки со Строками. Условие Первая колонка значений это название колонок будущей таблицы значений.
Исходная таблица:
Индекс Колонка1 Колонка2 Колонка3 Колонка4
0 "Тип11" "Тип21" "Тип31" "Тип41"
1 "Тип12" "Тип22" "Тип32" "Тип42"
2 "Тип13" "Тип23" "Тип33" "Тип43"
3 "Тип14" "Тип24" "Тип34" "Тип44"
4 "Тип15" "Тип25" "Тип35" "Тип45"

Полученная таблица:
Индекс Тип11 Тип12 Тип13 Тип14 Тип15
0 "Тип11" "Тип12" "Тип13" "Тип14" "Тип15"
1 "Тип21" "Тип22" "Тип23" "Тип24" "Тип25"
2 "Тип31" "Тип32" "Тип33" "Тип34" "Тип35"
3 "Тип41" "Тип42" "Тип43" "Тип44" "Тип45"
Минусы :
1.того что имя колонок первоначальных не видно.
2. Значение исходной таблицы первой колонки должны быть типизированны для название колонок.

Код 1C v 8.х

 // OldthiefXXX

// Функция возвращает перевернутую ТЗ

// Кидаем ТЗ

Функция ПеревернутьТЗ(ТЗ)

	ТЗ2 = Новый ТаблицаЗначений;

	Массив=Тз.ВыгрузитьКолонку(Тз.Колонки[0]);

	Для Каждого Значения  ИЗ  Массив ЦИКЛ

		ЗН=ВРег(СокрЛП(Значения));

		ТЗ2.Колонки.Добавить(Значения);

	Конеццикла;

	Для каждого стр из Тз.Колонки Цикл

		ТЗ2.Добавить();

	КонецЦикла;

	СчетчикСтрок=-1;

	Для каждого стр из Тз Цикл

		СчетчикСтрок=СчетчикСтрок+1;

		Мас= Новый Массив;

		счетчик=-1;

		Для каждого КН из Тз.Колонки Цикл

			счетчик=счетчик+1;

			ЗначениеИндекса=стр[КН.Имя];

			Мас.Вставить(счетчик,ЗначениеИндекса);

		КонецЦикла;

		ТЗ2.ЗагрузитьКолонку(Мас,ТЗ2.колонки[СчетчикСтрок]);

	КонецЦикла;

	Возврат ТЗ2;	

КонецФункции

Категория: Работа с Таблицей Значений

Как в 1C загрузить из Word текст?

Как в 1C из Microsoft Office Word 2007 внести текст?

Код получения текста из файла word:

Код 1C v 8.х

 Wk = Новый COMОбъект("Word.Application"); 

//Покажем открываемый документ

Wk.Visible = Истина; Wk.Documents.Open("D:\file.doc"); 

Документ = Wk.ActiveDocument();

// перебирая строки выводим текст 

Для н = 1 по Документ.Sentences.Count Цикл

	Текст=Документ.Sentences(н).Text;

	Сообщить(Текст);  	

КонецЦикла;	

Документ.Close(); 

Wk.Quit();

Рассмотрим приёмы получения статистической информации о документе, его составе и т.д.:
'получить общее количество символов в активном документе
' (буквы, цифры, пробелы, переход на новую строку и т.д)
WordApp.ActiveDocument.Characters.Count

'получить символ по его индексу
WordApp.ActiveDocument.Characters(14).Text
'изменить символ по его индексу
WordApp.ActiveDocument.Characters(14).Text="е" 'можно несколько "еёе"

Только не забывайте, что заменив один символ несколькими, вы измените общее количество символов в документе. Поэтому осторожнее при применении циклов. Это также касается и следующего кода.

'получаем количество слов в документе
'(переход на новую строку считается словом)
DocWord.Words.Count

'получить слово по его индексу
DocWord.Words(2).Text
'изменить слово по его индексу
DocWord.Words(2).Text="текст" 'можно несколько слов "Новый текст"

'получить количество параграфов (абзацев) в документе
WordApp.ActiveDocument.Paragraphs.Count

'получить текст параграфа по его индексу
WordApp.ActiveDocument.Paragraphs(2).Range.Text
'изменить текст параграфа по его индексу
WordApp.ActiveDocument.Paragraphs(2).Range.Text="Много текста. Много " & _
" предложений. И так далее!"

'получить количество предложений в документе
WordApp.ActiveDocument.Sentences.Count

'получить текст предложения по его индексу
WordApp.ActiveDocument.Sentences(1).Text

'получить количество предложений во втором параграфе
WordApp.ActiveDocument.Paragraphs(2).Range.Sentences.Count

'получить текст предложения 1 в параграфе 2
WordApp.ActiveDocument.Paragraphs(2).Range.Sentences(1).Text

'получить текст слова 2, в предложении 1,в параграфе 2
WordApp.ActiveDocument.Paragraphs(2).Range.Sentences(1).Words(2).Text

'добавить новую секцию (раздел)
'создаёт новый раздел на новом листе
DocWord.Sections.Add
'создаёт новый раздел на текущем листе
DocWord.Application.S_election.I_nsertBreak (wdSectionBreakContinuous) '(3)

'получить количество секций в документе
DocWord.Sections.Count

'получить текст слова 2, в предложении 1,в параграфе 2, в секции 1.
DocWord.Sections(1).Range.Paragraphs(1).Range.Sentences(1).Words(2).Text

Используя Встроенные_Свойства_Документа получаем его статистические данные.

'получаем количество страниц (листов) в документе
WordApp.ActiveDocument.BuiltInDocumentProperties(wdPropertyPages) '(14)

'получаем количество строк в документе
WordApp.ActiveDocument.BuiltInDocumentProperties(wdPropertyLines) '(23)

'получаем количество слов в документе
WordApp.ActiveDocument.BuiltInDocumentProperties(wdPropertyWords) '(15)

'получаем количество параграфов (абзацев) в документе
WordApp.ActiveDocument.BuiltInDocumentProperties(wdPropertyParas) '(24)
'и т.д.

Рассмотрим примеры кода для передвижения по документу, а также поиска и замены текста.
Метод .GoTo (перейти к) позволяет вам переместиться на нужную позицию в документе. Он при прямом вызове возвращает новую позицию курсора.

'переход на лист с именем "1"
'если не указать в конце .S_elect, то код просто выдаст положение курсора
DocWord.Application.S_election.GoTo(wdGoToPage, , , "1").S_elect

wdGoToSection (0) - перейти к секции ; wdGoToPage (1) - перейти к листу ;
wdGoToTable (2) - перейти к таблице ; wdGoToLine (3) - перейти к строке ;
wdGoToFootnote (4) - перейти к сноске ; wdGoToEndnote (5) - к примечанию ;
wdGoToComment (6) - к комментарию ; wdGoToField (7) - к полю ;
wdGoToHeading (11) - к заголовку ;
wdGoToSpellingError (13) - к орфографической ошибке ;
wdGoToGrammaticalError (14) - к грамматической ошибке.

'переход на лист с индексом 1
DocWord.Application.S_election.GoTo(3, , 1, "").S_elect

'переход в начало строки с индексом 1
DocWord.Application.S_election.GoTo(3, , 1, "").S_elect

'переход в начало следующей строки (аналогично текущий_индекс+1)
DocWord.Application.S_election.GoTo(3, wdGoToNext, 1, "").S_elect

wdGoToNext (2) - на следующий ; wdGoToPrevious (3) - на предыдущий.

Поиск и замена:
'находим первое вхождение текста и выделяем его
WordApp.Application.S_election.Find.Text = "строка"
WordApp.Application.S_election.Find.Execute

'находим первое вхождение текста
WordApp.Application.S_election.Find.Text = "строка"
' и заменяем только его
WordApp.Application.S_election.Find.Replacement.Text = "1 строчка"
WordApp.Application.S_election.Find.Wrap = wdFindContinue
WordApp.Application.S_election.Find.Execute Replace:= wdReplaceOne '(1)

'или тоже самое, но другим способом (при повторном выполнении кода, заменится следующее слово)
WordApp.ActiveDocument.Content.Find.Execute _
FindText:="текста", ReplaceWith:="hello", Replace:= wdReplaceOne '(1)

Для замены всех вхождений текста применяйте wdReplaceAll (2).

Категория: Работа с Microsoft Office и OpenOffice

Прямые запросы к SQL серверу.

Как то возникла ситуация, когда в справочник, с включенной проверкой на уникальность кода, из вне приходят элементы с такими же кодами. Отключать проверку нельзя. Пришлось делать затычку.

Подключение к SQL в общем то широко описано:

Код 1C v 8.х

 	Функция Подключение(Сервер,БД)

		cnn = Новый COMОбъект("ADODB.Connection");

		cnn.ConnectionTimeOut	= 0;

		cnn.CommandTimeOut	= 0; 

		cnn.connectionString    = "SERVER="+Сервер+"; Database="+БД+"; DRIVER=SQL Server; UID=sa; PWD=*****;";  

		cnn.Open();   

		if cnn.State()=0 then

			Сообщить("Не удалось соединиться с сервером");

			cnn = 0;

			Возврат Ложь;

		endif;	

		cnn.Execute("SET NOCOUNT ON");

		Возврат cnn;

	КонецФункции

Сервер и БД можно получить и программно, но муторно. Эти данные можно взять из свойств БД на сервере 1С.

Название таблицы и полей в SQL можно получить с помощью команды 1С:

Цитата

Глобальный контекст
ПолучитьСтруктуруХраненияБазыДанных (GetDBStorageStructureInfo)
Синтаксис:
ПолучитьСтруктуруХраненияБазыДанных(<Объекты метаданных>, <Имена базы данных>)
Параметры:
<Объекты метаданных> (необязательный)
Тип: Массив. Массив имен объектов метаданных или массив объектов метаданных, для которых требуется получить структуру таблиц базы данных.
<Имена базы данных> (необязательный)
Тип: Булево. Определяет, в каких терминах выдается информация о структуре хранения.
Истина - в терминах СУБД
Ложь - в терминах SDBL.
Значение по умолчанию: Ложь
Возвращаемое значение:
Тип: ТаблицаЗначений. Возвращает таблицу значений с описаниями структуры таблиц, индексов и полей базы данных в терминах SDBL или используемой СУБД, в зависимости от значения параметра "Имена базы данных".
Если параметр не используется, то возвращаемая таблица значений содержит информацию о структуре таблиц базы данных всех объектов метаданных.
Таблица значений включает следующие колонки:
ИмяТаблицыХранения(StorageTableName) – имя таблицы SDBL или базы данных;
ИмяТаблицы(TableName) – имя таблицы в терминах языка запросов (для тех у кого оно есть);
Метаданные(Metadata) – полное имя объекта метаданных;
...

Дальше нам нужно новый элемент справочника все ж таки записать, ну например :

Код 1C v 8.х

 

Попытка

	спр.Записать();

Исключение

	Сообщить("Не уникальный код "+стр.Код+" у элемента "+стр.Наименование);

	Спр.УстановитьНовыйКод();

	Спр.Записать();

КонецПопытки;

Все, делаем подмену.

Код 1C v 8.х

 	подключение=Подключение(Сервер,База);

	ТекстЗапроса="UPDATE Номенклатура

	|SET Номенклатура._Code="+Формат(КодНужный,"ЧГ=0")+"

	|FROM _Reference57 AS Номенклатура 

	|WHERE	(CAST(Номенклатура._Folder AS int)=1)

	|AND (Номенклатура._Code="+Формат(Спр.Код,"ЧГ=0")+")

	|"; 

	подключение.Execute(ТекстЗапроса);

	Сообщить("Код "+КодБыл+" подменен на "+КодНужный);

Категория: Запросы

Как просмотреть структуру таблиц информационной базы?

В данном примере получается структура таблиц справочника Номенклатура (в общем случае с этим объектом может быть связано несколько таблиц):

Код 1C v 8.х

 МассивИменМетаданных = Новый Массив();

МассивИменМетаданных.Добавить("Справочник.Номенклатура");

	

// Таблица значений, содержащая таблицы указанного объекта.

Таблицы = ПолучитьСтруктуруХраненияБазыДанных(МассивИменМетаданных);



Для Каждого Таблица Из Таблицы Цикл



	ПоляТаблицы = Таблица.Поля;



	Для Каждого Поле Из ПоляТаблицы Цикл



		// Просмотр свойств поля.



	КонецЦикла;	

		

	ИндексыТаблицы = Таблица.Индексы;



	Для Каждого Индекс Из ИндексыТаблицы Цикл



		// Просмотр свойств индекса.



	КонецЦикла;			

КонецЦикла;

ПолучитьСтруктуруХраненияБазыДанных - возвращает таблицу значений с описаниями структуры таблиц, индексов и полей базы данных в терминах SDBL или используемой СУБД (MS SQL, PostgreSQL, IBM DB2)
Возможность получения структуры хранения базы данных может использоваться для выполнения административных действий. Информация о структуре хранения базы данных не должна применяться для реализации какой-либо части прикладной функциональности, а только для административных задач обслуживания базы данных и анализа записей технологического журнала.

Структура и название таблиц использыемых для хранения данных в БД 1С 8.х
Соответствие объектов 1С 8.х объектам в MS SQL

Категория: Администрирование

Функция загружает весь табличный документ в таблицу значений

Код 1C v 8.х

  // Вариант 1

// По переданному табличному документу возвращает таблицу значений, 

// при условии что в первой строке таблицы - идентификаторы колонок 

// Автор : dimoff

Функция ПолучитьТЗИзМакета(ТабДок, КолонкаИндекса = 1) Экспорт

    

    ТаблицаДанных = Новый ТаблицаЗначений;

    НомерКолонки = 0;

    Пока Истина Цикл

        НомерКолонки = НомерКолонки + 1;

        ИмяКолонки = ТабДок.Область(1, НомерКолонки).Текст;

        Если ПустаяСтрока(ИмяКолонки) Тогда

            Прервать;

        КонецЕсли;        

        ТаблицаДанных.Колонки.Добавить(ИмяКолонки);

    КонецЦикла;

    

    СчетчикКолонок = НомерКолонки - 1;

    

    НомерСтроки = 1; ФлагПрерывания = Ложь;

    Пока Истина Цикл

        НомерСтроки = НомерСтроки + 1;

        Стр = ТаблицаДанных.Добавить();

        

        Для А = 1 ПО СчетчикКолонок Цикл

            ТекстКолонки = ТабДок.Область(НомерСтроки, А).Текст;

            Если ПустаяСтрока(ТекстКолонки) Тогда

                Если А = КолонкаИндекса Тогда

                    Флагпрерывания = Истина;

                    ТаблицаДанных.Удалить(Стр);

                КонецЕсли;

            Иначе

                Стр[А - 1] = ТекстКолонки

            КонецЕсли;

            

            Если Флагпрерывания Тогда

                Прервать

            КонецЕсли;

        КонецЦикла;

        

        Если Флагпрерывания Тогда

            Прервать

        КонецЕсли;

    КонецЦикла;

    

    Возврат ТаблицаДанных

КонецФункции



// Варинат 2

//Функция загружает весь макет, табличный документ в таблицу значений

//Первая строка содержит подписи колонок (должны быть правильные идентификаторы)

//Пустые строки (состоящией из пробелов, переводов строки и т.п.) заменяет на Неопределено

//Если в ячейке есть значение, в ячейку таблицы значений попадает именно это значение

//Автор : Гений1С

Функция обМакетВТаблицуЗначений(Макет) Экспорт

    Перем ТЗ;

ТЗ=Новый ТаблицаЗначений();

#Если Клиент Тогда

    //Считываем колонки

	Для Стр=1 По Макет.ВысотаТаблицы Цикл

		Если Стр>1 Тогда

        	ТекСтр=ТЗ.Добавить();

		КонецЕсли;

		ПустаяСтрока=истина;

		Для Кол=1 По Макет.ШиринаТаблицы Цикл

			Яч=Макет.Область(Стр, Кол);

			Если Яч.СодержитЗначение Тогда

				Зн=Яч.Значение;

			Иначе

				Зн=Яч.Текст;

			КонецЕсли;

			Если ТипЗнч(Зн)=Тип("Строка") И ПустаяСтрока(Зн) Тогда

				Зн=Неопределено;

			КонецЕсли;

			

			//Добавляем колонку

			Если Стр=1 Тогда

		        ТЗ.Колонки.Добавить(Зн);

			Иначе

				ТекСтр[Кол-1]=Зн;

			КонецЕсли;

		КонецЦикла;

	КонецЦикла;

#КонецЕсли

   Возврат ТЗ;

КонецФункции

Категория: Табличный документ

Массив ~ Функция ищет элемент в массиве. Если находит - возвращает его индекс, иначе -1

Код 1C v 8.х

 Функция ВернутьИндексВМассиве(МассивДанные, Элемент) Экспорт 

	

	Если МассивДанные = Неопределено Тогда

		Возврат -1;

	КонецЕсли;

	

	Для ИндексЭлемента = 0 По МассивДанные.ВГраница() Цикл

		

		Если  (МассивДанные[ИндексЭлемента] = Элемент) Тогда

			Возврат ИндексЭлемента;

		КонецЕсли;	

		

	КонецЦикла;

	

	// не нашли элемент

	Возврат -1;

	

КонецФункции

Категория: Работа с Массивом, Структурой, Соответств�…

Функция выполняет пропорциональное распределение суммы в соответствии с заданными коэффициентами

Код 1C v 8.х

 

// Функция выполняет пропорциональное распределение суммы в соответствии с заданными коэффициентами распределения

//

// Параметры:

//		ИсхСумма - распределяемая сумма

//		МассивКоэф - массив коэффициентов распределения

//		Точность - точность округления при распределении. Необязателен.

//

//	Возврат:

//		МассивСумм - массив размерностью равный массиву коэффициентов, содержит

//			суммы в соответствии с весом коэффициента (из массива коэффициентов)

//          В случае если распределить не удалось (сумма = 0, кол-во коэф. = 0,

//          или суммарный вес коэф. = 0), тогда возвращается значение Неопределено

//

Функция РаспределитьПропорционально(Знач ИсхСумма, МассивКоэф, Знач Точность = 2) Экспорт

	

	Если МассивКоэф.Количество() = 0 Или ИсхСумма = 0 Или ИсхСумма = Null Тогда

		Возврат Неопределено;

	КонецЕсли;

	

	ИндексМакс = 0;

	МаксЗнач   = 0;

	РаспрСумма = 0;

	СуммаКоэф  = 0;

	

	Для К = 0 По МассивКоэф.Количество() - 1 Цикл

		

		МодульЧисла = ?(МассивКоэф[К] > 0, МассивКоэф[К], - МассивКоэф[К]);

		

		Если МаксЗнач < МодульЧисла Тогда

			МаксЗнач = МодульЧисла;

			ИндексМакс = К;

		КонецЕсли;

		

		СуммаКоэф = СуммаКоэф + МассивКоэф[К];

		

	КонецЦикла;

	

	Если СуммаКоэф = 0 Тогда

		Возврат Неопределено;

	КонецЕсли;

	

	МассивСумм = Новый Массив(МассивКоэф.Количество());

	

	Для К = 0 По МассивКоэф.Количество() - 1 Цикл

		МассивСумм[К] = Окр(ИсхСумма * МассивКоэф[К] / СуммаКоэф, Точность, 1);

		РаспрСумма = РаспрСумма + МассивСумм[К];

	КонецЦикла;

	

	// Погрешности округления отнесем на коэффиецент с максимальным весом

	Если Не РаспрСумма = ИсхСумма Тогда

		МассивСумм[ИндексМакс] = МассивСумм[ИндексМакс] + ИсхСумма - РаспрСумма;

	КонецЕсли;

	

	Возврат МассивСумм;

	

КонецФункции

Категория: Работа с Числами

Получить количество строк в многострочной строке

Код 1C v 7.x

 

//СтрКоличествоСтрок(Текст) - Возвращает число строк в многострочном тексте

Для Индекс=1 по СтрКоличествоСтрок(Текст) Цикл

	// СтрПолучитьСтроку(Текст,Индекс) - Возвращает строку из многострочного текста по заданному номеру.

	СтрТекста=СтрПолучитьСтроку(Текст,Индекс);             

КонецЦикла;

Код 1C v 8.х

 

//СтрЧислоСтрок(Текст) - Позволяет посчитать число строк в многострочной строке. Строки в многострочной строке разделены символами перевода строк (Символы.ПС). 

Для Индекс=1 по СтрЧислоСтрок(Текст) Цикл

	// СтрПолучитьСтроку(Текст,Индекс) - Получает строку многострочной строки по номеру.

	СтрТекста=СтрПолучитьСтроку(Текст,Индекс);

КонецЦикла;

Категория: Работа с Текстом (Строкой)