почты%ssl » Поиск

Результаты по ключевому слову: почты%ssl

Отправка почты через Mail.ru с использованием технологии шифрования SSL

Часто клиенты просят сделать автоматическую отправку счетов или отчетов на электронную почту, ниже приведены примеры кода для разных версий 1С:

Код 1C v 8.3

 

//Код для обычного приложения, для управляемого приложения отправка почты так же, только с файлами и предупреждение нужно изменить код

Функция ПолучитьПрофильПочты()

	//Создаем профиль либо считываем из справочника 

	Профиль = Новый ИнтернетПочтовыйПрофиль; 

	Профиль.АдресСервераSMTP = "smtp.mail.ru";//Отправитель.АдресСервераSMTP; //"smtp.mail.ru"; 

	Профиль.АдресСервераPOP3 = "pop.mail.ru"; //Отправитель.АдресСервераPOP3; //"pop.mail.ru"; 

	Профиль.ПортPOP3 = 995;//Отправитель.ПортPOP3; //110;

	Профиль.ПортSMTP = 465;//Отправитель.ПортSMTP; //587; 

	Профиль.Пользователь = "s_v@inbox.ru";// Отправитель.Email; //"test@mail.ru"; 

	Профиль.Пароль = "8mFTnDjC4KftTzh"; //Отправитель.Пароль; //"123456789"; 

	Профиль.ПользовательSMTP =  "s_v@inbox.ru";//Отправитель.Email; //"test@mail.ru"; 

	Профиль.ПарольSMTP = "8mFTnDjC4KftTzh";//Отправитель.Пароль; //"123456789"; 

	Профиль.АутентификацияSMTP = СпособSMTPАутентификации.Login;

	Профиль.ИспользоватьSSLPOP3 = Истина;

	Профиль.ИспользоватьSSLSMTP = Истина;  

	//Создаем письмо 

Возврат Профиль;

КонецФункции 





Процедура ОсновныеДействияФормыСчетОтправитьНаПочту(Кнопка)

	Если ЗначениеЗаполнено(Ответственный.ПочтаДляОтправкиСчета) Тогда

		Почта = Новый ИнтернетПочта; 

		Письмо = Новый ИнтернетПочтовоеСообщение; 

		Текст = Письмо.Тексты.Добавить("В приложении счет"); 

		Текст.ТипТекста = ТипТекстаПочтовогоСообщения.ПростойТекст;

		Письмо.Тема = Строка(Ссылка); 

		Письмо.Отправитель = "s_vmeste@inbox.ru"; 

		Письмо.ИмяОтправителя = "1С";

		Письмо.Получатели.Добавить(Ответственный.ПочтаДляОтправкиСчета);



		врфайл=ПолучитьИмяВременногоФайла("pdf");

		текТабдок=СчетФаксимилеТовары(); //Функция возвращает табличный документ печать счета

		текТабдок.Записать(врфайл,ТипФайлаТабличногоДокумента.PDF);



		Письмо.Вложения.Добавить(врфайл);

		//добавляем вложение если нужно, например "C:\Приложение.doc" 

		//Вложений можно добавлять сколько требуется. 

		//Отправляем письмо

		Попытка 

			Почта.Подключиться(ПолучитьПрофильПочты()); Почта.Послать(Письмо); Предупреждение("Письмо отправлено",3);

		Исключение 

			Сообщить(ОписаниеОшибки());

		КонецПопытки;

		//Закрываем письмо

		Почта.Отключиться(); 

		//Закрываем файл вложения

		Письмо.Вложения.Очистить();

	Иначе

		Предупреждение("В настройках ответственного не указана почта для отправки счета");

	КонецЕсли;

КонецПроцедуры

С версиями 8.2 сложнее, так как все почтовые сервисы перешли на SSL, а медоты:

Код 1C v 8.3

 Профиль.ИспользоватьSSLPOP3 = Истина;

	Профиль.ИспользоватьSSLSMTP = Истина;

появились только в 8.3.1 , остается использовать stunnel или CDO:

Код 1C v 8.2 УП

 //Отправка через CDO, Адрессаты через ";"

Функция ПослатьПоПочте(Знач Адрессаты, ТемаСообщения = "",ТекстСообщения = "" ,СписокВложений = "")Экспорт



    Оправитель         = "s_v@inbox.ru";

    Пароль             = "8mFTnDjC4KftTzh";



    loConfig         = Новый COMОбъект("CDO.Configuration");

    loCdoMessage     = Новый COMОбъект("CDO.Message");

    loCdoMessage.Configuration = loConfig;

    loCdoMessage.From    = Строка("1С <"+Оправитель+">");  //loCdoMessage.From    = "Тест 1C"""" <xxxxxxx@yandex.ru>";

    loCdoMessage.To      = Адрессаты; //loCdoMessage.To      = "xxxxxxx@gmail.ru>";

    loCdoMessage.Subject = ?(ТемаСообщения="","1С",ТемаСообщения);

    loCdoMessage.TextBody = "1C";

     HTMLBody = "<html>

    |<head>

    |<meta content=""text/html; charset=Windows-1251"" http-equiv=""content-type"">

    |<title> Тестовое сообщение </title>

    |</head>

    |<body>

    |<h4>" + ТекстСообщения + "</h4>

    |<p></p>

    |</body>

    |</html>";

    //loCdoMessage.BodyPart.Charset = "windows-1251"; 

    loCdoMessage.HTMLBody = HTMLBody;



    Если ТипЗнч(СписокВложений) = Тип("Строка") И Не СписокВложений = "" Тогда

        Попытка

            loCdoMessage.AddAttachment(СписокВложений);

        Исключение

        КонецПопытки;

    ИначеЕсли ТипЗнч(СписокВложений) = Тип("СписокЗначений") Тогда

        Для каждого ПутьКВложению Из СписокВложений Цикл

            Попытка

                loCdoMessage.AddAttachment(ПутьКВложению.Значение);

            Исключение

            КонецПопытки;

        КонецЦикла;

    КонецЕсли;

   loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing").            Value = 2;

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver").           Value = "smtp.mail.ru";

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport").       Value = "465";

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate").     Value = 1;

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername").         Value = Оправитель;

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword").         Value = Пароль;

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl").           Value = 1;

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout").Value = 60;



    loConfig.Fields.Update();   

    Попытка

        loCdoMessage.Send();

    Исключение

        Сообщить(ОписаниеОшибки());

        Возврат Ложь;

    КонецПопытки;



КонецФункции



Процедура ОсновныеДействияФормыСчетТовары(Кнопка)

	Если ЗначениеЗаполнено(Менеджер.ПочтаДляОтправкиСчета) Тогда

		

		врфайл=ПолучитьИмяВременногоФайла("xls");

		текТабдок=СчетФаксимилеТовары();

		текТабдок.Записать(врфайл,ТипФайлаТабличногоДокумента.XLS);

		ПослатьПоПочте(Менеджер.ПочтаДляОтправкиСчета,Строка(Ссылка),"Счет в приложении",врфайл);

		

		Предупреждение("Письмо отправлено",3);		

	Иначе

		Предупреждение("В настройках ответственного не указана почта для отправки счета");

	КонецЕсли;

КонецПроцедуры

Через stunnel в 1С код, менять не нужно, только установить программу и изменить настройки подключения к почтовому ящику

Скачиваем stunnel c официального сайта (stunnel.org) и запускаем инсталятор, жмем yes при установке спросит страну и ваши данные, это нужно для создания сертификата на вашем компьютере.

После запуска в трее появится его иконка, правой клавишей и редактировать edit configuration

В блокноте откроется файл настроек, там будет пример для gmail дополняем или заменяем его следующим:

Код Batch File (DOS, CMD, BAT)

 [gmail-pop3]

client = yes

accept = 127.0.0.1:10110

connect = pop.gmail.com:995

[gmail-imap]

client = yes

accept = 127.0.0.1:10143

connect = imap.gmail.com:993

[gmail-smtp]

client = yes

accept = 127.0.0.1:10025

connect = smtp.gmail.com:465

[yandex-pop3]

client = yes

accept = 127.0.0.1:20110

connect = pop.yandex.ru:995

[yandex-imap]

client = yes

accept = 127.0.0.1:20143

connect = imap.yandex.ru:993

[yandex-smtp]

client = yes

accept = 127.0.0.1:20025

connect = smtp.yandex.ru:465

[mail-pop3]

client = yes

accept = 127.0.0.1:30110

connect = pop.mail.ru:995

[mail-imap]

client = yes

accept = 127.0.0.1:30143

connect = imap.mail.ru:993

[mail-smtp]

client = yes

accept = 127.0.0.1:30025

connect = smtp.mail.ru:465

Сохраняем файл и делаем Reload configuration

В настройка 1С меняем порты для работы

gmail

pop3 10110

imap 10143

smtp 10025

yandex

pop3 20110

imap 20143

smtp 20025

mail

pop3 30110

imap 30143

smtp 30025

Если в коде прописано, то:

Код 1C v 8.х

 Функция ПолучитьПрофильПочты()

	//Создаем профиль либо считываем из справочника 

	Профиль = Новый ИнтернетПочтовыйПрофиль; 

	Профиль.АдресСервераSMTP = "localhost";//"smtp.mail.ru";//Отправитель.АдресСервераSMTP; //"smtp.mail.ru"; 

	Профиль.АдресСервераPOP3 = "localhost";//"pop.mail.ru"; //Отправитель.АдресСервераPOP3; //"pop.mail.ru"; 

	Профиль.ПортPOP3 = 30110;//Отправитель.ПортPOP3; //110;  995

	Профиль.ПортSMTP = 30025;//Отправитель.ПортSMTP; //587; 465

	Профиль.Пользователь = "s_v@inbox.ru";// Отправитель.Email; //"test@mail.ru"; 

	Профиль.Пароль = "8mFTnDjC4KftTzh"; //Отправитель.Пароль; //"123456789"; 

	Профиль.ПользовательSMTP =  "s_v@inbox.ru";//Отправитель.Email; //"test@mail.ru"; 

	Профиль.ПарольSMTP = "8mFTnDjC4KftTzh";//Отправитель.Пароль; //"123456789"; 

	Профиль.АутентификацияSMTP = СпособSMTPАутентификации.Login;

	//Профиль.ИспользоватьSSLPOP3 = Истина;

	//Профиль.ИспользоватьSSLSMTP = Истина;  

	//Создаем письмо 

Возврат Профиль;

КонецФункции

Все, можно отправлять и проверять работу через консоль Show log window в меню

P.S. Почтовый ящик в примерах не рабочий, как пример

Категория: Работа с Интернет, Почтой (Mail), FTP

Отправка и получение почты с использованием технологии шифрования SSL

Почти все почтовые сервисы перешли на использование SSL и для получения почты нужно использовать IMAP, можно конечно и POP, но это уже прошлый век )

Пример получения почты с mail.ru по IMAP используя SSL:

Код 1C v 8.3

 Функция ПолучитьНовыеПисьма() Экспорт

	Почта = Новый ИнтернетПочта;

	ИспользоватьIMAP=Истина; ПочтовыйЯщик = "";

	Профиль = ПолучитьПрофиль();

	Попытка

		Если ИспользоватьIMAP Тогда

			Почта.Подключиться(Профиль, ПротоколИнтернетПочты.IMAP);

			Если ПочтовыйЯщик = "" Тогда

				ПочтовыйЯщик = "INBOX";

			КонецЕсли;

			Почта.ТекущийПочтовыйЯщик = ПочтовыйЯщик;

		Иначе;

			Почта.Подключиться(Профиль, ПротоколИнтернетПочты.POP3);

		КонецЕсли;

	Исключение

		Сообщить(НСтр("ru = 'Ошибка при подключении к почтовому серверу. Проверьте настройки.'"));

		Сообщить(ОписаниеОшибки());

		Возврат 0;

	КонецПопытки;

	

	ЗагруженныеПисьма = ПолучитьИдентификаторыЗагруженныхПисем();

	ИдентификаторыНовыхПисем = Почта.ПолучитьИдентификаторы(ЗагруженныеПисьма);

	Если ИдентификаторыНовыхПисем.Количество() = 0 Тогда

		//Новых нет 

	Иначе

		//Получаем новые письма	

		Письма = Почта.Выбрать(Ложь, ИдентификаторыНовыхПисем,Истина);

		Для каждого Письмо Из Письма Цикл 

			Если Найти(Письмо.Тема,"siteabc.ru")>0 Тогда //Если это наше письмо то грузим его

				ПисьмоОбъект = Справочники.ВходящиеПисьма.СоздатьЭлемент();

				ПисьмоОбъект.Идентификатор = Письмо.Идентификатор[0];

				ПисьмоОбъект.Наименование = Письмо.Тема;

				ПисьмоОбъект.Дата = Письмо.ДатаОтправления;

				ПисьмоОбъект.Отправитель = Письмо.Отправитель;		

				Если ИспользоватьIMAP Тогда

					ПисьмоОбъект.ПочтовыйЯщик = "IMAP/" + ПочтовыйЯщик;

				Иначе

					ПисьмоОбъект.ПочтовыйЯщик = "POP3";

				КонецЕсли;

				Для каждого Элемент Из Письмо.Тексты Цикл

					Если Элемент.ТипТекста = ТипТекстаПочтовогоСообщения.HTML Тогда

						ПисьмоОбъект.ВидСодержимого = "HTML";

						Текст = Элемент.Текст;

						Если Найти(Текст, "<HTML>") = 0 Тогда

							Текст = "<HTML><BODY>" + Текст + "</BODY></HTML>";

						КонецЕсли;

						//Вложения = Новый Массив;

						//// обрабатываем вложения, что бы правильно сформировать HTML

						//Для каждого Вложение Из Письмо.Вложения Цикл

						//	Ид = "cid:" + Вложение.Идентификатор;

						//	Если Найти(Текст, Ид) <> 0 Тогда

						//		Вложения.Добавить(Вложение);

						//	КонецЕсли;

						//КонецЦикла;

						Прервать;

					ИначеЕсли Элемент.ТипТекста = ТипТекстаПочтовогоСообщения.ПростойТекст Тогда

						ПисьмоОбъект.ВидСодержимого ="Текст";

						Текст = Элемент.Текст;

					КонецЕсли;

				КонецЦикла;				

				

				ПисьмоОбъект.Текст = Текст;

				ПисьмоОбъект.Записать();

			КонецЕсли;

		КонецЦикла;

	КонецЕсли;

	Почта.Отключиться();



Функция ПолучитьПрофиль(ИмяОтправителя = "", ИспользоватьIMAP = Ложь) Экспорт

	Профиль = Новый ИнтернетПочтовыйПрофиль;

	Профиль.АутентификацияPOP3 = СпособPOP3Аутентификации.Обычная;

	Профиль.POP3ПередSMTP=Ложь;

	Профиль.АдресСервераIMAP = "imap.mail.ru";

	Профиль.ПортIMAP = 993;

	Профиль.ИспользоватьSSLIMAP = Истина;

	Профиль.ПользовательIMAP ="siteabcz@mail.ru";

	Профиль.ПарольIMAP = "9Ljkuf";

	Профиль.ТолькоЗащищеннаяАутентификацияIMAP = Ложь;

	Возврат Профиль;

КонецФункции





Функция ПолучитьИдентификаторыЗагруженныхПисем() Экспорт

	Идентификаторы = Новый Массив();

	Запрос = Новый Запрос;

	Запрос.Текст = "ВЫБРАТЬ Идентификатор ИЗ Справочник.ВходящиеПисьма";

	Выборка = Запрос.Выполнить().Выбрать();

	Пока Выборка.Следующий() Цикл

		Идентификаторы.Добавить(Выборка.Идентификатор);

	КонецЦикла;

	Возврат Идентификаторы;

КонецФункции



/// ЕЩЕ примеры настройки профиля

Функция ПолучитьПрофиль(ИмяОтправителя = "", ИспользоватьIMAP = Ложь) Экспорт

	//Профиль = Новый ИнтернетПочтовыйПрофиль; 	

	//Профиль.АдресСервераSMTP = Выборка.АдресSMTPСервера;

	//Профиль.ПортSMTP = Выборка.ПортSMTP;

	//Профиль.ИспользоватьSSLSMTP = Выборка.SSLSMTP;

	//Профиль.ПарольSMTP = Выборка.ПарольSMTP;

	//Профиль.ПользовательSMTP = Выборка.ПользовательSMTP;

	//Профиль.ТолькоЗащищеннаяАутентификацияSMTP  = Ложь;    

	//

	//Профиль.АдресСервераIMAP = Выборка.АдресIMAPСервера;

	//Профиль.ПортIMAP = Выборка.ПортIMAP;

	//Профиль.ИспользоватьSSLIMAP = Выборка.SSLIMAP;

	//Профиль.ПользовательIMAP = Выборка.ПользовательIMAP;

	//Профиль.ПарольIMAP = Выборка.ПарольIMAP;

	//Профиль.ТолькоЗащищеннаяАутентификацияIMAP  = Ложь;	

	//

	//Профиль.АдресСервераPOP3 = Выборка.АдресPOP3Сервера;

	//Профиль.ПортPOP3 = Выборка.ПортPOP3;

	//Профиль.ИспользоватьSSLPOP3 = Выборка.SSLPOP3;

	//Профиль.Пароль = Выборка.ПарольPOP3;

	//Профиль.Пользователь = Выборка.ПользовательPOP3;

	//Профиль.ТолькоЗащищеннаяАутентификацияPOP3  = Ложь;

	//

	//Профиль.ВремяОжидания = Выборка.ТаймаутИнтернетПочты;

	//

	//ИмяОтправителя = Выборка.ИмяОтправителяПочтовогоСообщения;

	//ИспользоватьIMAP = Выборка.ИспользоватьIMAP;

	//

	Профиль = Новый ИнтернетПочтовыйПрофиль;

	//Профиль.АдресСервераSMTP = "smtp.mail.ru";

	//Профиль.ПортSMTP = 465;

	//Профиль.ИспользоватьSSLSMTP = Истина;

	//Профиль.ПарольSMTP ="9LEY";

	//Профиль.ПользовательSMTP = "siteabcz@mail.ru";

	//Профиль.ТолькоЗащищеннаяАутентификацияSMTP = Истина; 

	//Профиль.Пользователь = "siteabcz@mail.ru";

	//Профиль.Пароль = "siteabcz";

	//Профиль.АдресСервераPOP3 = "pop.mail.ru";

	//Профиль.ПортPOP3 = 995;

	//Профиль.ИспользоватьSSLPOP3 = Истина;

	Профиль.АутентификацияPOP3 = СпособPOP3Аутентификации.Обычная;

	Профиль.POP3ПередSMTP=Ложь;

	Профиль.АдресСервераIMAP = "imap.mail.ru";

	Профиль.ПортIMAP = 993;

	Профиль.ИспользоватьSSLIMAP = Истина;

	Профиль.ПользовательIMAP ="siteabcz@mail.ru";

	Профиль.ПарольIMAP = "siteabcz";

	Профиль.ТолькоЗащищеннаяАутентификацияIMAP = Ложь;

	Возврат Профиль;

КонецФункции







//ОБЩИЙ ПРИМЕР ОТПРАВКИ и ПОЛУЧЕНИЯ

Функция ОтправитьПисьмо(EmailОтправителя, ПарольОтправителя, 

						Порт, АдресСервера, EmailПолучателя, 

						ИмяПолучателя, ТекстСообщения, 

						ЗаголовокСообщения, МассивФайловыхПутей)

						

	//ПОЧТОВЫЙ ПРОФИЛЬ

	

	Профиль = Новый ИнтернетПочтовыйПрофиль;

	Профиль.ИспользоватьSSLSMTP = Истина;

	Профиль.АдресСервераSMTP = АдресСервера; 

	Профиль.ПортSMTP = Порт;

	Профиль.Пользователь = EmailОтправителя;

	Профиль.Пароль = ПарольОтправителя;

	Профиль.АутентификацияSMTP = СпособSMTPАутентификации.ПоУмолчанию;

	Профиль.ПарольSMTP = ПарольОтправителя;

	Профиль.ПользовательSMTP = EmailОтправителя; 

   

	//ПОЧТОВОЕ СООБЩЕНИЕ

	

	Сообщение = Новый ИнтернетПочтовоеСообщение;

	Сообщение.Отправитель = EmailОтправителя;

	Сообщение.Тема = ЗаголовокСообщения;

	Сообщение.Тексты.Добавить(ТекстСообщения, ТипТекстаПочтовогоСообщения.HTML);

	Сообщение.Организация = "The company";		

	Адрес = Сообщение.Получатели.Добавить(EmailПолучателя);

	Адрес.ОтображаемоеИмя = ИмяПолучателя;

	

	Для каждого ПутьКФайлу Из МассивФайловыхПутей Цикл

		Сообщение.Вложения.Добавить(ПутьКФайлу);

	КонецЦикла; 

	

	// ПОЧТОВЫЙ СЕРВЕР

	

	Почта = Новый ИнтернетПочта();

	

	//Подключение к серверу

	Попытка

		Почта.Подключиться(Профиль);

	Исключение

		Сообщить("Ошибка при подключении к серверу: " + ОписаниеОшибки());

		Возврат Ложь;

	КонецПопытки;

	

	//Отправка письма

	Попытка

		Почта.Послать(Сообщение);

	Исключение

		Почта.Отключиться();

		Сообщить("Ошибка при отправке письма: " + ОписаниеОшибки());

		Возврат Ложь;

	КонецПопытки;

	

	Почта.Отключиться();

	Возврат Истина;

	

КонецФункции 



Функция ПолучитьПисьма()



	//ПОЧТОВЫЙ ПРОФИЛЬ	

	Профиль = Новый ИнтернетПочтовыйПрофиль;

	Профиль.Пользователь = "xxx@xxxx.xx";

	Профиль.Пароль = "xxxxxx";

	Профиль.АдресСервераPOP3 = "pop3.mail.ru";

	ПРофиль.АутентификацияPOP3 = СпособPOP3Аутентификации.Обычная;

	МассивПисем = Новый массив();

	

	//ПОЛУЧЕНИЕ ПИСЕМ	

	Попытка

		Почта = Новый ИнтернетПочта;

		Почта.Подключиться(Профиль);

		МассивПисем = Почта.Выбрать(Ложь);

	Исключение

		Сообщить("Ошибка получения почты " + ОписаниеОшибки());

	КонецПопытки;

	

	Возврат МассивПисем;

КонецФункции

Категория: Работа с Интернет, Почтой (Mail), FTP

SMTP greeting failure: 421 SMTP connection broken (reply)

Описание ошибки:С сентября 2014 Яндекс.Почта, Mail.ru перешли на протокол SSL, что сделало их ещё более безопасными. Чтобы и дальше работать с письмами через 1С, Вам нужно изменить их настройки и внести доработки в код конфигураций.

Найденные решения:

Ошибка наблюдается, в частности, в случае, когда меняются настройки почты. Например мне довелось столкнуться в случае, когда ввели для почты SSL-шифрование. Если это Ваш случай, то из быстрых и простых остается только обновление до версии платформы 8.3, где поддержка этого шифрования для "ИнтернетПочтовыйПрофиль" реализована. И доработка кода типовых конфигураций для учета настроек SSL-шифрования и включения у почтового профиля.

Код 1C v 8.х

 ИнтернетПочтовыйПрофиль.ИспользоватьSSLPOP3 = Истина;ИнтернетПочтовыйПрофиль.ИспользоватьSSLSMTP = Истина;

Сопровождающие проблему ошибки:

Яндекс.Почта

адрес_почты@yandex.ru. {ОбщийМодуль.УправлениеЭлектроннойПочтой.Модуль(1065)}: Ошибка при вызове метода контекста (Подключиться): Почтовый ящик пользователя "адрес_почты@yandex.ru" на сервере "pop.yandex.ru" не найден. Ответ сервера: "[AUTH] Working without SSL/TLS encryption is not allowed. Please visit https://help.yandex.ru/mail/mail-clients/ssl.xml. sc=NXhLmqHbM4YK"

Если установлены не правильные порты, то получим ошибку:Ошибка при вызове метода контекста (Подключиться): TLS/SSL failure for smtp.mail.ru: Invalid token, probably not an SSL serverУстановите порты 465 для smtp, 995 для pop3.

При соединении с Яндексом: в логинах оставить только содержимое логина до @yandex.ru, т.е. из примера "адрес_почты" (без кавычек). Устанавливаем для pop3 и smtp SSL-шифрование. Если почта корпоративная на Яндексе, и в наименовании не используется @yandex.ru, то оставляем логин, равный наименованию почты, как есть.

Mail.ru

Не включено SSL-шифрование для учетной записи электронной почты. Ошибка при вызове метода контекста (Подключиться): Can not authenticate to POP3 server: POP3 is available only with SSL or TLS connection enabled

Если установлены не правильные порты, то получим ошибку:Ошибка при вызове метода контекста (Подключиться): TLS/SSL failure for smtp.mail.ru: Invalid token, probably not an SSL serverУстанавливаем порты 465 для smtp, 995 для pop3.

Если возникает ошибка:Ошибка при вызове метода контекста (Подключиться): Can't connect to smtp.mail.ru,495: Timed out - значит неправильно указан порт.

Если возникает ошибка:Ошибка при вызове метода контекста (Подключиться): SMTP greeting failure: 421 SMTP connection broken (reply)Порты настроены правильно, не установлено SSL-шифрование для smtp.

В паролях для почты не использовать спецсимволы, пример из опыта: в пароле к почте был символ "+", пока из пароля не убрали, соединение не происходило! Система выдавала ошибку: Ошибка при вызове метода контекста (Подключиться): Can not authenticate to SMTP server: 535 5.7.8 Error: authentication failed: Invalid user or password!

Разработчики 1С вносят фунционал в рабочие конфигурации, например: УТ 10.3.30.1 от 26.09.2014, описание обновления: В справочник "Учетные записи электронной почты" добавлены реквизиты "Использовать защищенную версию протокола SMTP" и "Использовать защищенную версию протокола POP3". При установке этих реквизитов предоставляется возможность подключаться к почтовым серверам через безопасное соединение (SSL). Реквизиты доступны при использовании версии платформы не ниже 8.3.1.

P.S.: Возможно еще использование дополнительной программы stunnel. Но мне этот вариант меньше понравился. Т.к. клиенту не хотелось зависеть от программиста каждый раз, когда появляется новая почта или рабочее место, а чтобы сразу можно было из 1С настроить, как и раньше.

Журавлев А.С. (Сайт www.azhur-c.ru)

Категория: Системные Ошибки

Отправка почты через CDO (работает c SSL) Категория: Работа с Интернет, Почтой (Mail), FTP

Отправка отчетов из 1С по электронной почте (E-Mail) Категория: Работа с Интернет, Почтой (Mail), FTP

Ян­декс.Почта

Mail.ru

Яндекс.Почта