субконто%получить » Поиск

Результаты по ключевому слову: субконто%получить

Обход метаданных (полезные функции)

При написании небольших автоматизированных тестов часто надо обойти всю конфигурацию и проверить, например, для всех форм какое-нибудь свойство. Это всё легко делается через свойство глобального контекста "Метаданные", но чтоб дорбаться до обхода реквизитов надо написать кучу вложенных циклов. При этом код становится слабочитаемым и слабомодифицируемым.

Ниже приведен небольшой модуль, который решает задачу легко и удобно. Создана специальная функция РазвернутьСтрокуОбходаМетаданных, которая может по строке типа "Метаданные.Справочники.*.Реквизиты.*" построить массив строк с перечислением всех реквизитов всех справочников. При помощи этой и нескольких других функций в экспортных функциях модуля реализованы вполне прикладные задачи - получение всех реквизитов, всех макетов, всех форм конфигурации и построение таблицы всех составных типов.

Код 1C v 8.х

  // Автор: Alexander Speshilov

// Рекрсивная функция, которая разворачивает строку вида "Метаданные.Справочники.*[Имя].Реквизиты.*.Тип" 

// в массив строк, заменяя "*" или другой символ, задаваемый параметрами обходом всех элементов 

// коллекции. Допускает выполнение функций встроенного языка (не стоит отдавать ввод параметров 

// пользователям). При этом выражение, используемое для получения по умолчанию может быть задано в 

// квадратных скобках или параметром функции.

//

// Параметры

//  СтрокаОбхода  - Строка - Разворачиваемая строка

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Массив строк

//

Функция РазвернутьСтрокуОбходаМетаданных(СтрокаОбхода, ЗаменяемоеЗначение = "*", ПредставлениеПоУмолчанию = "")

    

    Рез = Новый Массив;

    

    ЧастиСтрокиОбхода = РазобратьСтрокуОбхода(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

    Если ЧастиСтрокиОбхода = Неопределено тогда 

        Рез.Добавить(СтрокаОбхода); //фактически это ограничение рекурсии.

    Иначе

        ОбъектКоллекции = Вычислить(ЧастиСтрокиОбхода.СтрокаКоллекции);

        РазвернутаяКоллекция = РазвернутьКоллекциюВПредставления(ОбъектКоллекции, ЧастиСтрокиОбхода.СтрокаПредставление);

        Для каждого ЭлементРазвернутойКоллекции Из РазвернутаяКоллекция Цикл

            

            // рекурсивный вызов

            ТекущаяСтрокаОбхода = ЧастиСтрокиОбхода.СтрокаНачало + ЭлементРазвернутойКоллекции + ЧастиСтрокиОбхода.СтрокаКонец;

            МассивЭлемента = РазвернутьСтрокуОбходаМетаданных(ТекущаяСтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

            

            Для каждого ПримитивныйЭлементОбхода Из МассивЭлемента Цикл

                Рез.Добавить(ПримитивныйЭлементОбхода);

            КонецЦикла;

            

        КонецЦикла;

    КонецЕсли;

    

    Возврат Рез;

    

КонецФункции // РазвернутьСтрокуОбходаМетаданных()



// Разбирает строку обхода на удобные для работы поля

//

// Параметры

//  СтрокаОбхода  - Строка - Разворачиваемая строка

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Структура с полями ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец

// или Неопределено (если строка не содержит ЗаменяемоеЗначение)

//

Функция РазобратьСтрокуОбхода(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию)

    

    Если ПустаяСтрока(ЗаменяемоеЗначение) Тогда 

        ВызватьИсключение "Некорректное выражение заменяемого значения";

    КонецЕсли;

    

    ПозицияЗамены = Найти(СтрокаОбхода, ЗаменяемоеЗначение);

    

    // Если не найдена строка - возвращаем неопределено, как индикатор

    Если ПозицияЗамены = 0 Тогда 

        Возврат Неопределено; 

    КонецЕсли;

    

    СтрокаНачало = Лев(СтрокаОбхода,ПозицияЗамены - 1);

    

    //Получение строки для выражения-коллекции

    СтрокаКоллекции = СтрокаНачало;

    Если Прав(СтрокаКоллекции, 1) = "." Тогда 

        СтрокаКоллекции = Лев(СтрокаКоллекции,СтрДлина(СтрокаКоллекции) - 1);

    КонецЕсли;

    

    ПозицияОкончанияЗамены = ПозицияЗамены + СтрДлина(ЗаменяемоеЗначение);

    

    ОстатокВыражения = Сред(СтрокаОбхода, ПозицияОкончанияЗамены);

    

    //Обработка явного задания представления

    ОткрывающаяСкобка = "[";

    ЗакрывающаяСкобка = "]";

    Если Найти(ОстатокВыражения, ОткрывающаяСкобка) = 1 Тогда

        ОстатокВыражения = Сред(ОстатокВыражения, СтрДлина(ОткрывающаяСкобка) + 1);

        ПозицияЗакрывающейСкобки = Найти(ОстатокВыражения, ЗакрывающаяСкобка);

        Если ПозицияЗакрывающейСкобки = 0 Тогда 

            ВызватьИсключение "Синтаксическая ошибка разбора выражения";

        КонецЕсли;

        СтрокаПредставление = Лев(ОстатокВыражения, ПозицияЗакрывающейСкобки - 1);

        ОстатокВыражения = Сред(ОстатокВыражения, ПозицияЗакрывающейСкобки + СтрДлина(ЗакрывающаяСкобка));

    Иначе

        СтрокаПредставление = ПредставлениеПоУмолчанию;

    КонецЕсли;

    СтрокаКонец = ОстатокВыражения;

    

    Рез = Новый Структура("ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец",

    ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец);

    

    Возврат Рез;

    

КонецФункции // РазобратьСтрокуОбхода()



// Разворачивает объект коллекции в массив представления элементов

//

// Параметры

//  Коллекция  - Произвольный - Коллекция, которую можно обойти через "Для каждого"

//  ПредставлениеЭлемента  - Строка - необяз., свойство элементов коллекции, которое 

//               используется для получения представления.

//

// Возвращаемое значение:

//   Массив   - Массив представлений коллекции

//

Функция РазвернутьКоллекциюВПредставления(Коллекция, Знач ПредставлениеЭлемента = "")

    

    //Проверка и подгонка параметров

    Если не ПустаяСтрока(ПредставлениеЭлемента) Тогда 

        Если Найти(ПредставлениеЭлемента, ";")>0 Тогда 

            ВызватьИсключение "Некорректное выражение представления";

        КонецЕсли;

        ПредставлениеЭлемента = "." + ПредставлениеЭлемента;

    КонецЕсли;

    

    Рез = Новый Массив;

    Для каждого ЭлементКоллекции Из Коллекция Цикл

        ТекПредставление = Строка(Вычислить("ЭлементКоллекции" + ПредставлениеЭлемента));

        Рез.Добавить(ТекПредставление);

    КонецЦикла; 

    Возврат Рез;

    

КонецФункции // РазвернутьКоллекцию()



// Разворачивает массив строк через РазвернутьСтрокуОбходаМетаданных

//

// Параметры

//  МассивСтрокОбхода  - Массив - Массив разворачиваемых строк

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Массив строк

//

Функция РазвернутьМассивСтрокОбходаМетаданных(МассивСтрокОбхода, ЗаменяемоеЗначение = "*", ПредставлениеПоУмолчанию = "Имя")

    

    Рез = Новый Массив;

    

    Для каждого СтрокаОбхода Из МассивСтрокОбхода Цикл

        

        ДополнениеРезультата = РазвернутьСтрокуОбходаМетаданных(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

        Для каждого ТекСтрока Из ДополнениеРезультата Цикл

            Рез.Добавить(ТекСтрока);

        КонецЦикла; 

        

    КонецЦикла; 

    

    Возврат Рез;

    

КонецФункции // РазвернутьМассивСтрокОбходаМетаданных()



// Преобразует строку в массив одиночных строк по разделителю Символы.ПС

//

// Параметры

//  ПреобразуемаяСтрока - строка для преобразования

//    ИгнорироватьПустые - Булево - Пропускать пустые строки

//  СокращатьПробелы - Использовать СокрЛП

//

// Возвращаемое значение:

//   Массив строк

//

Функция ПолучитьМассивСтрокМногострочнойСтроки(ПреобразуемаяСтрока, ИгнорироватьПустые = Истина, СокращатьПробелы = Истина)

    

    Рез = Новый Массив;

    ЧислоСтрок = СтрЧислоСтрок(ПреобразуемаяСтрока);

    

    Для Сч = 1 По ЧислоСтрок Цикл

        

        ТекСтрока = СтрПолучитьСтроку(ПреобразуемаяСтрока, Сч);

        Если ИгнорироватьПустые и ПустаяСтрока(ТекСтрока) Тогда

            Продолжить;

        КонецЕсли; 

        Если СокращатьПробелы Тогда

            ТекСтрока = СокрЛП(ТекСтрока);

        КонецЕсли; 

        Рез.Добавить(ТекСтрока);

        

    КонецЦикла;

    

    Возврат Рез;

    

КонецФункции // ПолучитьМассивСтрокМногострочнойСтроки()



// Возвращает все реквизиты конфигурации, которые сохраняются в ИБ

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеХранимыеРеквизитыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.Константы.*

    |Метаданные.ПланыОбмена.*.Реквизиты.*

    |Метаданные.ПланыОбмена.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Справочники.*.Реквизиты.*

    |Метаданные.Справочники.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Документы.*.Реквизиты.*

    |Метаданные.Документы.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Последовательности.*.Измерения.*

    |Метаданные.ПланыВидовХарактеристик.*.Реквизиты.*

    |Метаданные.ПланыВидовХарактеристик.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.ПланыСчетов.*.Реквизиты.*

    |Метаданные.ПланыСчетов.*.ПризнакиУчета.*

    |Метаданные.ПланыСчетов.*.ПризнакиУчетаСубконто.*

    |Метаданные.ПланыСчетов.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.ПланыВидовРасчета.*.Реквизиты.*

    |Метаданные.ПланыВидовРасчета.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.РегистрыСведений.*.Измерения.*

    |Метаданные.РегистрыСведений.*.Ресурсы.*

    |Метаданные.РегистрыСведений.*.Реквизиты.*

    |Метаданные.РегистрыНакопления.*.Измерения.*

    |Метаданные.РегистрыНакопления.*.Ресурсы.*

    |Метаданные.РегистрыНакопления.*.Реквизиты.*

    |Метаданные.РегистрыБухгалтерии.*.Измерения.*

    |Метаданные.РегистрыБухгалтерии.*.Ресурсы.*

    |Метаданные.РегистрыБухгалтерии.*.Реквизиты.*

    |Метаданные.РегистрыРасчета.*.Измерения.*

    |Метаданные.РегистрыРасчета.*.Ресурсы.*

    |Метаданные.РегистрыРасчета.*.Реквизиты.*

    |Метаданные.БизнесПроцессы.*.Реквизиты.*

    |Метаданные.БизнесПроцессы.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Задачи.*.Реквизиты.*

    |Метаданные.Задачи.*.РеквизитыАдресации.*

    |Метаданные.Задачи.*.ТабличныеЧасти.*.Реквизиты.*

    |";

    ВсеХранимыеРеквизитыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеХранимыеРеквизитыКонфигурации;

    

КонецФункции // ПолучитьВсеХранимыеРеквизитыКонфигурации()



// Возвращает все реквизиты конфигурации составного типа, которые сохраняются в ИБ

//

// Параметры - Нет

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция ПолучитьВсеХранимыеРеквизитыКонфигурацииСоставногоТипа() Экспорт

    

    ВсеХранимыеРеквизитыКонфигурации = ПолучитьВсеХранимыеРеквизитыКонфигурации();

    Рез = Новый ТаблицаЗначений;

    Рез.Колонки.Добавить("Имя", Новый ОписаниеТипов("Строка"));

    Рез.Колонки.Добавить("Тип", Новый ОписаниеТипов("ОписаниеТипов"));

    Рез.Колонки.Добавить("КоличествоПростыхТипов", Новый ОписаниеТипов("Число"));

    

    Для каждого ТекРеквизит Из ВсеХранимыеРеквизитыКонфигурации Цикл

        

        Реквизит = Вычислить(ТекРеквизит);

        Тип = Реквизит.Тип;

        КоличествоПростыхТипов = Тип.Типы().Количество();

        Если КоличествоПростыхТипов<>1 Тогда 

    	    ТекСтрока = Рез.Добавить();

            ТекСтрока.Имя = ТекРеквизит;

            ТекСтрока.Тип = Тип;

            ТекСтрока.КоличествоПростыхТипов = КоличествоПростыхТипов;

        КонецЕсли;

    

    КонецЦикла; 

    

    Возврат Рез;

    

КонецФункции // ПолучитьВсеХранимыеРеквизитыКонфигурации()



// Возвращает все формы конфигурации

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеФормыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.ПланыОбмена.*.Формы.*

    |Метаданные.КритерииОтбора.*.Формы.*

    |Метаданные.ОбщиеФормы.*

    |Метаданные.Справочники.*.Формы.*

    |Метаданные.Документы.*.Формы.*

    |Метаданные.ЖурналыДокументов.*.Формы.*

    |Метаданные.Перечисления.*.Формы.*

    |Метаданные.Отчеты.*.Формы.*

    |Метаданные.Обработки.*.Формы.*

    |Метаданные.ПланыВидовХарактеристик.*.Формы.*

    |Метаданные.ПланыСчетов.*.Формы.*

    |Метаданные.ПланыВидовРасчета.*.Формы.*

    |Метаданные.РегистрыСведений.*.Формы.*

    |Метаданные.РегистрыНакопления.*.Формы.*

    |Метаданные.РегистрыБухгалтерии.*.Формы.*

    |Метаданные.РегистрыРасчета.*.Формы.*

    |Метаданные.БизнесПроцессы.*.Формы.*

    |Метаданные.Задачи.*.Формы.*

    |";

    ВсеФормыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеФормыКонфигурации;

    

КонецФункции // ПолучитьВсеФормыКонфигурации()



// Возвращает все макеты конфигурации

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеМакетыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.ПланыОбмена.*.Макеты.*

    |Метаданные.ОбщиеМакеты.*

    |Метаданные.Справочники.*.Макеты.*

    |Метаданные.Документы.*.Макеты.*

    |Метаданные.ЖурналыДокументов.*.Макеты.*

    |Метаданные.Перечисления.*.Макеты.*

    |Метаданные.Отчеты.*.Макеты.*

    |Метаданные.Обработки.*.Макеты.*

    |Метаданные.ПланыВидовХарактеристик.*.Макеты.*

    |Метаданные.ПланыСчетов.*.Макеты.*

    |Метаданные.ПланыВидовРасчета.*.Макеты.*

    |Метаданные.РегистрыСведений.*.Макеты.*

    |Метаданные.РегистрыНакопления.*.Макеты.*

    |Метаданные.РегистрыБухгалтерии.*.Макеты.*

    |Метаданные.РегистрыРасчета.*.Макеты.*

    |Метаданные.БизнесПроцессы.*.Макеты.*

    |Метаданные.Задачи.*.Макеты.*

    |";

    ВсеМакетыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеМакетыКонфигурации;

    

КонецФункции // ПолучитьВсеМакетыКонфигурации()

Категория: Метаданные

Поиск в базе битых ссылок - "объект не найден"

В статье Битая ссылка, <Объект не найден>, Уникальный Идентификатор, GUID мы обсуждали как востановить битые ссылки!
А вот как найти в базе все битые ссылки, которые имеют вид типа "<Объект не найден> (137:8b270030482898d011daad3cc45fc830)"?

Для поиска этого была написана данная обработка: Скачивать файлы может только зарегистрированный пользователь!

Для поиска: Выбираем объекты метаданных , которые хотим проверить, жмем кнопочку "Выполнить" и наблюдаем в таблице выходные данные. Откуда можем попасть в объекты-источники.

Для программиста:

Код 1C v 8.х

 Процедура КнопкаВыполнитьНажатие(Кнопка)

	

	ИспользоватьОграничение = ЗначениеЗаполнено(ОграничениеТипов);

	РезультатПоиска.Очистить();

	Для Каждого ОбъектыМетаданных Из КоллекцияОбъектов Цикл

		Для Каждого ОбъектМетаданных Из ОбъектыМетаданных Цикл

			Состояние(ОбъектМетаданных.ПолноеИмя());

			ПроверитьОбъектНаБитыеСсылки(ОбъектМетаданных);

		КонецЦикла;

	КонецЦикла;

	Для Каждого ОбъектыМетаданных Из КоллекцияРегистров Цикл

		Для Каждого ОбъектМетаданных Из ОбъектыМетаданных Цикл

			Состояние(ОбъектМетаданных.ПолноеИмя());

			ПроверитьРегистрНаБитыеСсылки(ОбъектМетаданных);

		КонецЦикла;

	КонецЦикла;

	//Анализ последовательностей

	

	//ПроверитьОбъектНаБитыеСсылки(Метаданные.Справочники.СотрудникиОрганизаций);

	

КонецПроцедуры



Процедура ВывестиДанные(ТекстЗапроса)

	

	Запрос = Новый Запрос(ТекстЗапроса);

	Попытка 

		РезультатЗапроса = Запрос.Выполнить();

		Если Не РезультатЗапроса.Пустой() Тогда

			ТЗ = РезультатЗапроса.Выгрузить();

			Для Каждого Стр Из ТЗ Цикл

				ОбработкаПрерыванияПользователя();

				Строка = РезультатПоиска.Добавить();

				ЗаполнитьЗначенияСвойств(Строка, Стр);

			КонецЦикла;

		КонецЕсли;

	Исключение

		Сообщить(ИнформацияОбОшибке().Описание + " " + ИнформацияОбОшибке().Причина);

	КонецПопытки;

	

КонецПроцедуры



Процедура ПроверитьРегистрНаБитыеСсылки(ОбъектМетаданных)

	

	ИмяТаблицы = ОбъектМетаданных.ПолноеИмя();

	Если Метаданные.РегистрыСведений.Содержит(ОбъектМетаданных) Тогда

		Если ОбъектМетаданных.РежимЗаписи = НезависимыйРежимЗаписи Тогда

			//АнализСвойствРегистраСведений(ОбъектМетаданных, ОбъектМетаданных.Измерения, ИмяТаблицы);

			//АнализСвойствРегистраСведений(ОбъектМетаданных, ОбъектМетаданных.Ресурсы, ИмяТаблицы);

			//АнализСвойствРегистраСведений(ОбъектМетаданных, ОбъектМетаданных.Реквизиты, ИмяТаблицы);

			Возврат;

		КонецЕсли;

		АнализСвойствРегистра(ОбъектМетаданных, ОбъектМетаданных.Реквизиты, ИмяТаблицы);

	КонецЕсли;

	АнализСвойствРегистра(ОбъектМетаданных, ОбъектМетаданных.Измерения, ИмяТаблицы);

	АнализСвойствРегистра(ОбъектМетаданных, ОбъектМетаданных.Реквизиты, ИмяТаблицы);

	

	АнализРегистратораРегистра(ОбъектМетаданных, ИмяТаблицы);

	

	Если Метаданные.РегистрыБухгалтерии.Содержит(ОбъектМетаданных) Тогда

		//Для рег. бухгалтерии анализ субконто

		

	КонецЕсли;

	Если Метаданные.РегистрыРасчета.Содержит(ОбъектМетаданных) Тогда

		//Для регистров расчета доп. анализ

	КонецЕсли;



КонецПроцедуры



Процедура ПроверитьОбъектНаБитыеСсылки(ОбъектМетаданных)

	

	ИмяТаблицы = ОбъектМетаданных.ПолноеИмя();

	АнализСвойствОбъекта(ОбъектМетаданных, ОбъектМетаданных.Реквизиты, ИмяТаблицы);

	Для Каждого ТабЧасть Из ОбъектМетаданных.ТабличныеЧасти Цикл

		Если ТабличныеЧастиИсключения.Найти(ТабЧасть.Имя) <> Неопределено Тогда

			Продолжить;

		КонецЕсли;

		АнализСвойствОбъекта(ОбъектМетаданных, ТабЧасть.Реквизиты, ИмяТаблицы + "." + ТабЧасть.Имя)

	КонецЦикла;

	//проверка владельца у справочников

	Если Метаданные.Справочники.Содержит(ОбъектМетаданных) И ОбъектМетаданных.Владельцы.Количество() > 0 Тогда

		МассивВладельцев = Новый Массив;

		Для Каждого Элемент Из ОбъектМетаданных.Владельцы Цикл

			МассивВладельцев.Добавить(Элемент);

		КонецЦикла;

		//АнализСвойствВладельцаОбъекта(ОбъектМетаданных, МассивВладельцев, ИмяТаблицы);

	КонецЕсли;

	

	//Для задач поле исполнитель

	//проверки в журналах

	

	ОбработкаПрерыванияПользователя();

	

КонецПроцедуры



Процедура АнализСвойствОбъекта(ОбъектМетаданных, Свойства, ИмяТаблицы)

	

	Для Каждого Реквизит Из Свойства Цикл

		Если РеквизитыИсключения.Найти(Реквизит.Имя) <> Неопределено Тогда

			Продолжить;

		КонецЕсли;

		Для Каждого моТип Из Реквизит.Тип.Типы() Цикл

			ТекстЗапроса = "";

			МетаданныеТипа = Метаданные.НайтиПоТипу(моТип);

			Если МетаданныеТипа <> Неопределено

				 И Не Метаданные.Перечисления.Содержит(МетаданныеТипа) Тогда

				Если ИспользоватьОграничение Тогда

					Если Не ПоискПоТипу(МетаданныеТипа.ПолноеИмя()) Тогда

						Продолжить;

					КонецЕсли;

				КонецЕсли;

				ДобавитьВЗапросОбъект(ТекстЗапроса, ОбъектМетаданных, ИмяТаблицы, Реквизит.Имя, моТип);

			КонецЕсли;

			Если Не ПустаяСтрока(ТекстЗапроса) Тогда

				ВывестиДанные(ТекстЗапроса);

			КонецЕсли;

		КонецЦикла;

	КонецЦикла;

	

КонецПроцедуры



Процедура АнализСвойствРегистра(ОбъектМетаданных, Свойства, ИмяТаблицы)

	

	Для Каждого Реквизит Из Свойства Цикл

		Если РеквизитыИсключения.Найти(Реквизит.Имя) <> Неопределено Тогда

			Продолжить;

		КонецЕсли;

		Для Каждого моТип Из Реквизит.Тип.Типы() Цикл

			ТекстЗапроса = "";

			МетаданныеТипа = Метаданные.НайтиПоТипу(моТип);

			Если МетаданныеТипа <> Неопределено

				 И Не Метаданные.Перечисления.Содержит(МетаданныеТипа) Тогда

				Если ИспользоватьОграничение Тогда

					Если Не ПоискПоТипу(МетаданныеТипа.ПолноеИмя()) Тогда

						Продолжить;

					КонецЕсли;

				КонецЕсли;

				ДобавитьВЗапросРегистр(ТекстЗапроса, ОбъектМетаданных, ИмяТаблицы, Реквизит.Имя, моТип);

			КонецЕсли;

			Если Не ПустаяСтрока(ТекстЗапроса) Тогда

				ВывестиДанные(ТекстЗапроса);

			КонецЕсли;

		КонецЦикла;

	КонецЦикла;

	

КонецПроцедуры



Процедура АнализРегистратораРегистра(ОбъектМетаданных, ИмяТаблицы)

	

	МассивРегистраторов = ПолучитьСписокРегистраторов(ОбъектМетаданных);

	Для Каждого Регистратор Из МассивРегистраторов Цикл

		Если РеквизитыИсключения.Найти("Регистратор") <> Неопределено Тогда

			Продолжить;

		КонецЕсли;

		моТип = Регистратор;

		ТекстЗапроса = "";

		МетаданныеТипа = Метаданные.НайтиПоТипу(моТип);

		Если МетаданныеТипа <> Неопределено

			 И Не Метаданные.Перечисления.Содержит(МетаданныеТипа) Тогда

			Если ИспользоватьОграничение Тогда

				Если Не ПоискПоТипу(МетаданныеТипа.ПолноеИмя()) Тогда

					Продолжить;

				КонецЕсли;

			КонецЕсли;

			ДобавитьВЗапросРегистр(ТекстЗапроса, ОбъектМетаданных, ИмяТаблицы, "Регистратор", моТип);

		КонецЕсли;

		Если Не ПустаяСтрока(ТекстЗапроса) Тогда

			ВывестиДанные(ТекстЗапроса);

		КонецЕсли;

	КонецЦикла;

	

КонецПроцедуры



Функция ПолучитьСписокРегистраторов(ОбъектМетаданных)

	

	МассивРегистраторов = Новый Массив;

	МенеджерОбъект = ПолучитьМенеджерОбъекта(ОбъектМетаданных);

	Если МенеджерОбъект <> Неопределено Тогда

		НаборЗаписей = МенеджерОбъект.СоздатьНаборЗаписей();

		ЭлементОтбора = НаборЗаписей.Отбор.Регистратор;

		МассивРегистраторов = ЭлементОтбора.ТипЗначения.Типы();

	КонецЕсли;

	Возврат МассивРегистраторов;

	

КонецФункции



Функция ПолучитьМенеджерОбъекта(ОбъектМетаданных)

	

	Перем МенеджерОбъекта;

	Если Метаданные.РегистрыБухгалтерии.Содержит(ОбъектМетаданных) Тогда

		МенеджерОбъекта = РегистрыБухгалтерии[ОбъектМетаданных.Имя];

	ИначеЕсли Метаданные.РегистрыНакопления.Содержит(ОбъектМетаданных) Тогда

		МенеджерОбъекта = РегистрыНакопления[ОбъектМетаданных.Имя];

	ИначеЕсли Метаданные.РегистрыСведений.Содержит(ОбъектМетаданных) Тогда

		МенеджерОбъекта = РегистрыСведений[ОбъектМетаданных.Имя];

	ИначеЕсли Метаданные.РегистрыРасчета.Содержит(ОбъектМетаданных) Тогда

		МенеджерОбъекта = РегистрыРасчета[ОбъектМетаданных.Имя];

	КонецЕсли;

	Возврат МенеджерОбъекта;

	

КонецФункции



Функция ПоискПоТипу(ИмяТипа)

	

	Результат = Ложь;

	Если ИспользоватьОграничение Тогда

		МассивСтрок = ОграничениеТипов.НайтиСтроки(Новый Структура("ТипДанных", ИмяТипа));

		Если ЗначениеЗаполнено(МассивСтрок) Тогда

			Результат = Истина;

		КонецЕсли;

	КонецЕсли;

	Возврат Результат;

	

КонецФункции



Процедура ДобавитьВЗапросРегистр(ТекстЗапроса, ОбъектМетаданных, ИмяТаблицы, ИмяРеквизита, ТипРеквизита)

	

	Текст = "ВЫБРАТЬ Об." + ИмяРеквизита + " КАК Объект, 

			|	""" + ИмяТаблицы + "." + ИмяРеквизита + """ КАК ТаблицаИсточник, 

			|	Об.Регистратор КАК ОбъектИсточник,

			| 	" + ДобавитьОписаниеТипа(ИмяРеквизита, ТипРеквизита) + " 

			|ИЗ 

			|	" + ИмяТаблицы + " КАК Об

			|ГДЕ " + ДобавитьУсловия(ИмяРеквизита, ТипРеквизита);

	ТекстЗапроса = ТекстЗапроса + ?(ПустаяСтрока(ТекстЗапроса), "", Символы.ПС + "ОБЪЕДИНИТЬ ВСЕ" + Символы.ПС) + Текст;	

	

КонецПроцедуры



Процедура ДобавитьВЗапросОбъект(ТекстЗапроса, ОбъектМетаданных, ИмяТаблицы, ИмяРеквизита, ТипРеквизита)

	

	Текст = "ВЫБРАТЬ Об." + ИмяРеквизита + " КАК Объект, 

			|	""" + ИмяТаблицы + "." + ИмяРеквизита + """ КАК ТаблицаИсточник, 

			|	Об.Ссылка КАК ОбъектИсточник,

			| 	" + ДобавитьОписаниеТипа(ИмяРеквизита, ТипРеквизита) + " 

			|ИЗ 

			|	" + ИмяТаблицы + " КАК Об

			|ГДЕ " + ДобавитьУсловия(ИмяРеквизита, ТипРеквизита);

	ТекстЗапроса = ТекстЗапроса + ?(ПустаяСтрока(ТекстЗапроса), "", Символы.ПС + "ОБЪЕДИНИТЬ ВСЕ" + Символы.ПС) + Текст;

	

КонецПроцедуры



Функция ДобавитьУсловия(ИмяРеквизита, ТипРеквизита)

	

	мдОбъекта = Метаданные.НайтиПоТипу(ТипРеквизита);

	ИмяТаблицы = мдОбъекта.ПолноеИмя();

	ПроверкаНаПустыеЗначения = " Об." + ИмяРеквизита + " ССЫЛКА " + ИмяТаблицы;

	ПроверкаНаПустыеЗначения = ПроверкаНаПустыеЗначения + " И ВЫРАЗИТЬ(Об." + ИмяРеквизита + " КАК " + ИмяТаблицы + ").Ссылка есть null";

	Если Не Метаданные.Перечисления.Содержит(мдОбъекта) Тогда

		ПроверкаНаПустыеЗначения = ПроверкаНаПустыеЗначения + " И Об." + ИмяРеквизита + " <> Значение(" + ИмяТаблицы + ".ПустаяСсылка)";

	КонецЕсли;

	Возврат ПроверкаНаПустыеЗначения;

	

КонецФункции



Функция ДобавитьОписаниеТипа(ИмяРеквизита, ТипРеквизита)

	

	ОбъектТипа = Метаданные.НайтиПоТипу(ТипРеквизита);

	ИмяТаблицы = ОбъектТипа.ПолноеИмя();

	ОписаниеТипа = """" + ИмяТаблицы + """ КАК ТипДанных";	

	Возврат ОписаниеТипа;

	

КонецФункции



Процедура ОграничениеТиповТипДанныхНачалоВыбора(Элемент, СтандартнаяОбработка)

	

	Перем ЭлементСписка;

	СтандартнаяОбработка = Ложь;

	Строка = ЭлементыФормы.ОграничениеТипов.ТекущиеДанные;

	Если Не ПустаяСтрока(Строка.ТипДанных) Тогда

		ЭлементСписка = СписокТипов.НайтиПоЗначению(Строка.ТипДанных);

	КонецЕсли;

	ВыбранныйЭлемент = СписокТипов.ВыбратьЭлемент( , ЭлементСписка);

	Если ВыбранныйЭлемент <> Неопределено Тогда

		Строка.ТипДанных = ВыбранныйЭлемент.Значение;

	КонецЕсли;

	

КонецПроцедуры



РеквизитыИсключения = Новый Массив;



ТабличныеЧастиИсключения = Новый Массив;



СписокТипов = Новый СписокЗначений;

Для Каждого ОбъектМетаданных Из Метаданные.Справочники Цикл

	СписокТипов.Добавить(ОбъектМетаданных.ПолноеИмя(), ОбъектМетаданных.Имя, , БиблиотекаКартинок.СправочникОбъект);

КонецЦикла;



Для Каждого ОбъектМетаданных Из Метаданные.Документы Цикл

	СписокТипов.Добавить(ОбъектМетаданных.ПолноеИмя(), ОбъектМетаданных.Имя, , БиблиотекаКартинок.ДокументОбъект);

КонецЦикла;



КоллекцияОбъектов = Новый Массив;

КоллекцияОбъектов.Добавить(Метаданные.ПланыОбмена);

КоллекцияОбъектов.Добавить(Метаданные.Справочники);

КоллекцияОбъектов.Добавить(Метаданные.Документы);

КоллекцияОбъектов.Добавить(Метаданные.ПланыВидовХарактеристик);

КоллекцияОбъектов.Добавить(Метаданные.ПланыСчетов);

КоллекцияОбъектов.Добавить(Метаданные.ПланыВидовРасчета);

КоллекцияОбъектов.Добавить(Метаданные.БизнесПроцессы);

КоллекцияОбъектов.Добавить(Метаданные.Задачи);



КоллекцияРегистров = Новый Массив;

КоллекцияРегистров.Добавить(Метаданные.РегистрыСведений);

КоллекцияРегистров.Добавить(Метаданные.РегистрыНакопления);

КоллекцияРегистров.Добавить(Метаданные.РегистрыБухгалтерии);

КоллекцияРегистров.Добавить(Метаданные.РегистрыРасчета);

Категория: 1С Общие вопросы - Обычные формы

Получение ссылки на значение перечисления по имени перечисления и по имени его значения Категория: Перечисления

Как добавить новый вид субконто к счету? Категория: Регистры бухгалтерии

Как перенести остаток со счета на счет?

Код 1C v 8.х

 Запрос = Новый Запрос; 

Запрос.Текст = "ВЫБРАТЬ 

|	ХозрасчетныйОстатки.СуммаОстатокДт 

|ИЗ 

|	РегистрБухгалтерии.Хозрасчетный.Остатки(&Период, Счет = &Счет, , 

|	Субконто1 = &Контрагент И Организация = &Организация И Субконто2 = &Договор) КАК ХозрасчетныйОстатки"; 



// Считаем что на счете ведется аналитика только в разрезе контрагентов 

// и договоров. 

Запрос.УстановитьПараметр("Период", Период1); 

Запрос.УстановитьПараметр("Контрагент", Контрагент); 

Запрос.УстановитьПараметр("Договор", Договор); 

Запрос.УстановитьПараметр("Организация", Организация); 

Запрос.УстановитьПараметр("Счет", ПланыСчетов.Хозрасчетный.РасчетыСПокупателями); 



Выборка = Запрос.Выполнить().Выбрать(); 



Если Выборка.Следующий() Тогда 

    Документ = Документы.ОперацияБух.СоздатьДокумент(); 



    Документ.Дата = РабочаяДата; 

    Документ.Организация = Организация; 

    Документ.Содержание = "Погашение дебиторской задолженности"; 



    Проводка = Документ.Движения.Хозрасчетный.Добавить(); 

    Проводка.СчетДт = ПланыСчетов.Хозрасчетный.РасчетыСПокупателями; 

    Проводка.СчетКт = ПланыСчетов.Хозрасчетный.ПрочиеРасходы; 

    Проводка.СубконтоДт.Контрагенты = Контрагент; 

    Проводка.СубконтоДт.Договоры = Договор; 

    Проводка.Сумма = Выборка.СуммаОстатокДт; 



    Документ.СуммаОперации = Выборка.СуммаОстатокДт; 



    Форма = Документ.ПолучитьФорму(); 

    Форма.Открыть(); 

КонецЕсли;

Категория: Регистры бухгалтерии

Работа с журналом расчетов в 1С7.7 из 1С 8.1 через Com соединение

Недавно делал перенос справочников и документов из 1С 7.7 "Зарплата и кадры" в 1С 8.1 "Управление торговым предприятием" через Com соединение. Во время переноса столкнулся с некоторыми проблемами. Одна из них - это при выполнении запроса очень важно правильно указать синтаксис передаваемых значений, особенно даты, иначе запрос не будет выполняться. Как правильно написать запрос? Смотрим:

Код 1C v 8.х

 //Создадим Com объект для подключения к 1С 77

  База77  = Новый COMObject("V77.Application");

  

  //Устанавливаем соединение  

  Открыта = База77.Initialize(База77.RMTrade,"/d" + ПутьКБазе77,"NO_SPLASH_SHOW");

 

  Если Открыта Тогда

    Предупреждение("Ошибка открытия информационной базы!");

  Иначе

    Сообщить("БАЗА ОТКРЫТА УСПЕШНО!");

  Конецесли;

 

  //Определим дату из периода за который 

  //необходимо выбрать данные

  ДатаПериода = ТекущаяДата();

  

  //Подключимся к журналу расчетов

  Зрп = База77.CreateObject("ЖурналРасчетов.Зарплата");

  

  //Получим период журнала расчета по нашей дате

  //переведем в формат без времени

  НТП = Формат(Зрп.НачалоПериодаПоДате(ДатаПериода),"ДЛФ=Д");

  КТП = Формат(Зрп.КонецПериодаПоДате(ДатаПериода),"ДЛФ=Д");

  

  //Напишем текст запроса

  //обратите внимание на установку периода в запросе

  //Если неправильно написать, будет вылазить ошибка

  ТекстЗапр =  "//{{ЗАПРОС(ВидыРасч)

  |Период с '" + НТП + "' по '" + КТП + "';

  |Вир = ЖурналРасчетов.Зарплата.ВидРасч;

  |Рез = ЖурналРасчетов.Зарплата.Результат;

  |Дни = ЖурналРасчетов.Зарплата.Дни;   

  |ДатаНачала   = ЖурналРасчетов.Зарплата.ДатаНачала;

  |ДатаОкончания   = ЖурналРасчетов.Зарплата.ДатаОкончания;  

  |Часы = ЖурналРасчетов.Зарплата.Часы;   

  |Субконто = ЖурналРасчетов.Зарплата.Субконто;  

  |Сот = ЖурналРасчетов.Зарплата.Объект;

  |КодОбъекта = ЖурналРасчетов.Зарплата.Объект.Код;

  |Функция РезСумма = Сумма(Рез);

  |Группировка Сот;

  |Группировка Вир;

  |"//}}ЗАПРОС

  ;

  

  //Создаем объект типа запрос

  Запр = База77.CreateObject("Запрос");

  

  //Выполним запрос, если успешно делаем выборку

  Если Запр.Выполнить(ТекстЗапр) <> 0 Тогда

    Пока Запр.Группировка("Сот") = 1 Цикл

      Пока Запр.Группировка("Вир") = 1 Цикл                

        //...................

        //Здесь пишем код выборки и обработки полученных данных

      Конеццикла;  

    Конеццикла;  

  Конецесли;

Если нам необходимо установить отбор в журнале, например по сотруднику, то сделать это можно следующим образом:

Код 1C v 8.х

  //в перечне полей добавляем поле код объекта (можно наименование)

"|КодОбъекта = ЖурналРасчетов.Зарплата.Объект.Код;"

//строка условия будет следующей

"|Условие(КодОбъекта = " + Сотр.код + ");"

Из журнала расчетов можно выбрать записи без запроса, методом прямой выборки. В некоторых ситуациях этот способ может быть даже удобней чем через запрос. В данном случае синтаксис будет довольно простым:

Код 1C v 7.x

  Запр = База77.CreateObject("ЖурналРасчетов.Зарплата");

Запр.ВыбратьЗаписиПоОбъекту(Сотр,НТП,КТП);

Пока Запр.ПолучитьЗапись() = 1 Цикл

//Делаем обработку выборки

Конеццикла;

Написал Валецкий Станислав

Категория: Журналы расчетов

Удаление строк из табличной части документа, все или по условию.

Удалить все строки табличного поля документа.

Код 1C v 8.х

  ОтражениеВУчете.Очистить(); // ОтражениеВУчете - название табличного поля

Как в табличной части документа удалить строки только с нулевым значением реквизита "Количество"?

Код 1C v 8.х

  //Получим документ и укажем параметры поиска

ОбъектДок = СсылкаДок.ПолучитьОбъект(); 

СтруктураДляПоиска = Новый Структура("Количество", 0); 

ТабличнаяЧастьДок = ОбъектДок.Товары; 

//Получаем список строк соответсвтвующих отбору, и перебором удаляем.

МассивПустыхСтрок = ТабличнаяЧастьДок.НайтиСтроки(СтруктураДляПоиска); 

Для каждого Строка Из МассивПустыхСтрок Цикл 

	ТабличнаяЧастьДок.Удалить(Строка); 

КонецЦикла; 

ОбъектДок.Записать(); // Записываем изменения в документе

Как удалить все строки, кроме тех которые соответсвуют заданному отбору?

Код 1C v 8.х

  // Укажем условия отбора: Нужно оставить только строки где СубконтоКт1 = РБПНаПФР	

ПараметрыОтбора = Новый Структура("СубконтоКт1", Справочники.РасходыБудущихПериодов.РБПНаПФР);	

//Теперь выгружаем табличную часть в таблицу значений

ТЗисходн=ОтражениеВУчете.Выгрузить();

//Скопируем ТЗ с заданным отбором в новую ТЗ

ТЗнов = ТЗисходн.Скопировать(ПараметрыОтбора);

//Очистим табличную часть

ОтражениеВУчете.Очистить();

//Загружем в табличную часть новую таблицу значений

ОтражениеВУчете.Загрузить(ТЗнов);

В режиме управляемого приложения конструкция:

Код 1C v 8.2 УП

 Для каждого Запись из ТабличнойЧасти Цикл

Если Запись.НадоУдалить Тогда

 ТабличнойЧасти.Удалить(Запись);

КонецЕсли;

КонецЦикла;

Работает некорректно, так как переписывает табличную часть и меняет индексы, сразу после удаления и Цикл полностью не обходит.
Решение пришло такое:

Код 1C v 8.2 УП

    КолВо = Объект.ТабличнойЧасти.Количество()-1;

    ИндексСтроки = КолВо;

    Для счетчик = 0 по КолВо Цикл

        Запись = Объект.ТабличнойЧасти.Получить(ИндексСтроки);

        если Запись.НадоУдалить тогда

                Объект.ТабличнойЧасти.Удалить(Запись);

            КонецЕсли;

        ИндексСтроки = ИндексСтроки - 1;

    КонецЦикла;

Категория: Документы

Реализация алгоритмов «FIFO» и «LIFO»

Для реализации алгоритмов «FIFO» и «LIFO» (FIFO (первый пришел – первый ушел), LIFO (последний пришел – первый ушел)) необходимо добавить на счет учета ТМЦ субконто «Партии». Тогда определяется текущая стоимость товара и текущий остаток первой (последней) партии товара. Их отношение дает нам цену партии товара. Если остаток по партии товара меньше, чем реализуется, тогда выбираем следующую партию товаров и так далее.

Код 1C v 7.x

 	БИ=СоздатьОбъект("БухгалтерскиеИтоги");

БИ.ИспользоватьСубконто("ЦенныеБумаги",ЦБ,2);

БИ.ИспользоватьСубконто("ПартииЦБ");

БИ.ВыполнитьЗапрос(,ТекущийДокумент(),"58.6"); 



Если Константа.МетодОпределенияСебестоимости =   Перечисление.МетодыОпределенияСебестоимости.ФИФО Тогда

	БИ.ВыбратьСубконто(2,,,,,,0);

Иначе

	БИ.ВыбратьСубконто(2,,,,,,1);

КонецЕсли; 



Кол=Количество; 

Пока БИ.ПолучитьСубконто(2)=1 Цикл

	Сум=БИ.СКД(1);

	Ост=БИ.СКД(3);

	Если Ост<=Кол Тогда

		// списываем весь остаток по партии

		СумСпис=Сум;

		КолСпис=Ост; 

	ИначеЕсли Ост>Кол Тогда 

		// списываем требуемое количество 

		ЦенаСпис=Сум/Ост;

		КолСпис=Кол;

		СумСпис=Окр(КолСпис*ЦенаСпис,2); 

	Иначе     

		Продолжить;

	КонецЕсли;  



	Операция.НоваяПроводка();

	Операция.Дебет.Счет=Сч91_2;

	Операция.Кредит.Счет=Сч58_6;

	Операция.Кредит.ЦенныеБумаги=ЦБ;

	Операция.Кредит.ПартииЦБ=БИ.Субконто(2);  

	Операция.Сумма=СумСпис;

	Операция.Количество=КолСпис; 

	Кол=Кол-КолСпис; 

	Если Кол=0 Тогда

		Прервать;

	КонецЕсли;

КонецЦикла;



Если Кол>0 Тогда

	Сообщить("Остаток меньше нуля");

	НеПроводитьДокумент();

КонецЕсли;

Категория: Полезные, Универсальные Функции