comобъект%через » Поиск

Результаты по ключевому слову: comобъект%через

Отправка почты через Mail.ru с использованием технологии шифрования SSL

Часто клиенты просят сделать автоматическую отправку счетов или отчетов на электронную почту, ниже приведены примеры кода для разных версий 1С:

Код 1C v 8.3

 

//Код для обычного приложения, для управляемого приложения отправка почты так же, только с файлами и предупреждение нужно изменить код

Функция ПолучитьПрофильПочты()

	//Создаем профиль либо считываем из справочника 

	Профиль = Новый ИнтернетПочтовыйПрофиль; 

	Профиль.АдресСервераSMTP = "smtp.mail.ru";//Отправитель.АдресСервераSMTP; //"smtp.mail.ru"; 

	Профиль.АдресСервераPOP3 = "pop.mail.ru"; //Отправитель.АдресСервераPOP3; //"pop.mail.ru"; 

	Профиль.ПортPOP3 = 995;//Отправитель.ПортPOP3; //110;

	Профиль.ПортSMTP = 465;//Отправитель.ПортSMTP; //587; 

	Профиль.Пользователь = "s_v@inbox.ru";// Отправитель.Email; //"test@mail.ru"; 

	Профиль.Пароль = "8mFTnDjC4KftTzh"; //Отправитель.Пароль; //"123456789"; 

	Профиль.ПользовательSMTP =  "s_v@inbox.ru";//Отправитель.Email; //"test@mail.ru"; 

	Профиль.ПарольSMTP = "8mFTnDjC4KftTzh";//Отправитель.Пароль; //"123456789"; 

	Профиль.АутентификацияSMTP = СпособSMTPАутентификации.Login;

	Профиль.ИспользоватьSSLPOP3 = Истина;

	Профиль.ИспользоватьSSLSMTP = Истина;  

	//Создаем письмо 

Возврат Профиль;

КонецФункции 





Процедура ОсновныеДействияФормыСчетОтправитьНаПочту(Кнопка)

	Если ЗначениеЗаполнено(Ответственный.ПочтаДляОтправкиСчета) Тогда

		Почта = Новый ИнтернетПочта; 

		Письмо = Новый ИнтернетПочтовоеСообщение; 

		Текст = Письмо.Тексты.Добавить("В приложении счет"); 

		Текст.ТипТекста = ТипТекстаПочтовогоСообщения.ПростойТекст;

		Письмо.Тема = Строка(Ссылка); 

		Письмо.Отправитель = "s_vmeste@inbox.ru"; 

		Письмо.ИмяОтправителя = "1С";

		Письмо.Получатели.Добавить(Ответственный.ПочтаДляОтправкиСчета);



		врфайл=ПолучитьИмяВременногоФайла("pdf");

		текТабдок=СчетФаксимилеТовары(); //Функция возвращает табличный документ печать счета

		текТабдок.Записать(врфайл,ТипФайлаТабличногоДокумента.PDF);



		Письмо.Вложения.Добавить(врфайл);

		//добавляем вложение если нужно, например "C:\Приложение.doc" 

		//Вложений можно добавлять сколько требуется. 

		//Отправляем письмо

		Попытка 

			Почта.Подключиться(ПолучитьПрофильПочты()); Почта.Послать(Письмо); Предупреждение("Письмо отправлено",3);

		Исключение 

			Сообщить(ОписаниеОшибки());

		КонецПопытки;

		//Закрываем письмо

		Почта.Отключиться(); 

		//Закрываем файл вложения

		Письмо.Вложения.Очистить();

	Иначе

		Предупреждение("В настройках ответственного не указана почта для отправки счета");

	КонецЕсли;

КонецПроцедуры

С версиями 8.2 сложнее, так как все почтовые сервисы перешли на SSL, а медоты:

Код 1C v 8.3

 Профиль.ИспользоватьSSLPOP3 = Истина;

	Профиль.ИспользоватьSSLSMTP = Истина;

появились только в 8.3.1 , остается использовать stunnel или CDO:

Код 1C v 8.2 УП

 //Отправка через CDO, Адрессаты через ";"

Функция ПослатьПоПочте(Знач Адрессаты, ТемаСообщения = "",ТекстСообщения = "" ,СписокВложений = "")Экспорт



    Оправитель         = "s_v@inbox.ru";

    Пароль             = "8mFTnDjC4KftTzh";



    loConfig         = Новый COMОбъект("CDO.Configuration");

    loCdoMessage     = Новый COMОбъект("CDO.Message");

    loCdoMessage.Configuration = loConfig;

    loCdoMessage.From    = Строка("1С <"+Оправитель+">");  //loCdoMessage.From    = "Тест 1C"""" <xxxxxxx@yandex.ru>";

    loCdoMessage.To      = Адрессаты; //loCdoMessage.To      = "xxxxxxx@gmail.ru>";

    loCdoMessage.Subject = ?(ТемаСообщения="","1С",ТемаСообщения);

    loCdoMessage.TextBody = "1C";

     HTMLBody = "<html>

    |<head>

    |<meta content=""text/html; charset=Windows-1251"" http-equiv=""content-type"">

    |<title> Тестовое сообщение </title>

    |</head>

    |<body>

    |<h4>" + ТекстСообщения + "</h4>

    |<p></p>

    |</body>

    |</html>";

    //loCdoMessage.BodyPart.Charset = "windows-1251"; 

    loCdoMessage.HTMLBody = HTMLBody;



    Если ТипЗнч(СписокВложений) = Тип("Строка") И Не СписокВложений = "" Тогда

        Попытка

            loCdoMessage.AddAttachment(СписокВложений);

        Исключение

        КонецПопытки;

    ИначеЕсли ТипЗнч(СписокВложений) = Тип("СписокЗначений") Тогда

        Для каждого ПутьКВложению Из СписокВложений Цикл

            Попытка

                loCdoMessage.AddAttachment(ПутьКВложению.Значение);

            Исключение

            КонецПопытки;

        КонецЦикла;

    КонецЕсли;

   loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing").            Value = 2;

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver").           Value = "smtp.mail.ru";

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport").       Value = "465";

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate").     Value = 1;

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername").         Value = Оправитель;

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword").         Value = Пароль;

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl").           Value = 1;

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout").Value = 60;



    loConfig.Fields.Update();   

    Попытка

        loCdoMessage.Send();

    Исключение

        Сообщить(ОписаниеОшибки());

        Возврат Ложь;

    КонецПопытки;



КонецФункции



Процедура ОсновныеДействияФормыСчетТовары(Кнопка)

	Если ЗначениеЗаполнено(Менеджер.ПочтаДляОтправкиСчета) Тогда

		

		врфайл=ПолучитьИмяВременногоФайла("xls");

		текТабдок=СчетФаксимилеТовары();

		текТабдок.Записать(врфайл,ТипФайлаТабличногоДокумента.XLS);

		ПослатьПоПочте(Менеджер.ПочтаДляОтправкиСчета,Строка(Ссылка),"Счет в приложении",врфайл);

		

		Предупреждение("Письмо отправлено",3);		

	Иначе

		Предупреждение("В настройках ответственного не указана почта для отправки счета");

	КонецЕсли;

КонецПроцедуры

Через stunnel в 1С код, менять не нужно, только установить программу и изменить настройки подключения к почтовому ящику

Скачиваем stunnel c официального сайта (stunnel.org) и запускаем инсталятор, жмем yes при установке спросит страну и ваши данные, это нужно для создания сертификата на вашем компьютере.

После запуска в трее появится его иконка, правой клавишей и редактировать edit configuration

В блокноте откроется файл настроек, там будет пример для gmail дополняем или заменяем его следующим:

Код Batch File (DOS, CMD, BAT)

 [gmail-pop3]

client = yes

accept = 127.0.0.1:10110

connect = pop.gmail.com:995

[gmail-imap]

client = yes

accept = 127.0.0.1:10143

connect = imap.gmail.com:993

[gmail-smtp]

client = yes

accept = 127.0.0.1:10025

connect = smtp.gmail.com:465

[yandex-pop3]

client = yes

accept = 127.0.0.1:20110

connect = pop.yandex.ru:995

[yandex-imap]

client = yes

accept = 127.0.0.1:20143

connect = imap.yandex.ru:993

[yandex-smtp]

client = yes

accept = 127.0.0.1:20025

connect = smtp.yandex.ru:465

[mail-pop3]

client = yes

accept = 127.0.0.1:30110

connect = pop.mail.ru:995

[mail-imap]

client = yes

accept = 127.0.0.1:30143

connect = imap.mail.ru:993

[mail-smtp]

client = yes

accept = 127.0.0.1:30025

connect = smtp.mail.ru:465

Сохраняем файл и делаем Reload configuration

В настройка 1С меняем порты для работы

gmail

pop3 10110

imap 10143

smtp 10025

yandex

pop3 20110

imap 20143

smtp 20025

mail

pop3 30110

imap 30143

smtp 30025

Если в коде прописано, то:

Код 1C v 8.х

 Функция ПолучитьПрофильПочты()

	//Создаем профиль либо считываем из справочника 

	Профиль = Новый ИнтернетПочтовыйПрофиль; 

	Профиль.АдресСервераSMTP = "localhost";//"smtp.mail.ru";//Отправитель.АдресСервераSMTP; //"smtp.mail.ru"; 

	Профиль.АдресСервераPOP3 = "localhost";//"pop.mail.ru"; //Отправитель.АдресСервераPOP3; //"pop.mail.ru"; 

	Профиль.ПортPOP3 = 30110;//Отправитель.ПортPOP3; //110;  995

	Профиль.ПортSMTP = 30025;//Отправитель.ПортSMTP; //587; 465

	Профиль.Пользователь = "s_v@inbox.ru";// Отправитель.Email; //"test@mail.ru"; 

	Профиль.Пароль = "8mFTnDjC4KftTzh"; //Отправитель.Пароль; //"123456789"; 

	Профиль.ПользовательSMTP =  "s_v@inbox.ru";//Отправитель.Email; //"test@mail.ru"; 

	Профиль.ПарольSMTP = "8mFTnDjC4KftTzh";//Отправитель.Пароль; //"123456789"; 

	Профиль.АутентификацияSMTP = СпособSMTPАутентификации.Login;

	//Профиль.ИспользоватьSSLPOP3 = Истина;

	//Профиль.ИспользоватьSSLSMTP = Истина;  

	//Создаем письмо 

Возврат Профиль;

КонецФункции

Все, можно отправлять и проверять работу через консоль Show log window в меню

P.S. Почтовый ящик в примерах не рабочий, как пример

Категория: Работа с Интернет, Почтой (Mail), FTP

Скрипт автообновления типовых конфигураций

Батник на "языке 1С" для клиент серверных баз, скачивает с сайта ИТС нужное обновление, бекапит базу и обновляет. Подойдет как рабочая заготовка для собственных "обновляторов". В текущем виде все работает. Надо только занести свои переменные.

Код 1C v 8.3

 //     Путь к обновлениям

Перем мРасположениеОбновлений;





//Параметры для подключения к серверу обновления 1С

Перем мИтсЛогин;

Перем мИтсПароль;





//****

Перем home;

Перем DumpIB;





Перем ФайлСписокОбновленийZIP;

Перем ФайлСписокОбновленийXML;





Перем КодВозврата;





// Проверка существования файла или каталога.

//

// Параметр:

//  ПутьКФайлу   - Строка - путь к файлу или каталогу, существование которого

//                 нужно проверить.

//

// Возвращаемое значение:

//  Булево - признак существования файла или каталога.

//

Функция ФайлСуществует(Знач ПутьКФайлу) Экспорт

    

    Файл = Новый Файл(ПутьКФайлу);

    Возврат Файл.Существует();

    

КонецФункции 





Процедура УстановитьКонстанты()

    каталог_tmplts = "D:\tmplts";

     мИтсЛогин = "---";

    мИтсПароль = "---";

    

    //**Ниже можно не менять.

    мРасположениеОбновлений = каталог_tmplts + "\1c";

    home = каталог_tmplts + "\1Cupdate";

    DumpIB = home + "\DumpIB\";

    ФайлСписокОбновленийXML = home + "\v8cscdsc.xml";

    ФайлСписокОбновленийZIP = home + "\v8upd11.zip";

    

    Если НЕ ФайлСуществует(home) Тогда

        СоздатьКаталог(home); 

    КонецЕсли;

    

    Если НЕ ФайлСуществует(DumpIB) Тогда

        СоздатьКаталог(DumpIB); 

    КонецЕсли;

    

    Если НЕ ФайлСуществует(мРасположениеОбновлений) Тогда

        СоздатьКаталог(мРасположениеОбновлений); 

    КонецЕсли;





КонецПроцедуры





Функция ВернутьРелизИПлатформу(мИмяСервера,мИмяБазы,мВерсияПлатформы,мБазаЛогин,мБазаПароль)





   ПараметрыБазы = Неопределено;

 

   Попытка

        //Создаем COM-объект с идентификатором V82.COMConnector

        COMОбъект = Новый COMОбъект("V"+мВерсияПлатформы+".COMConnector");   //выйдет V82.COMConnector

   Исключение

        Сообщить("Не удалось создать COM-объект!");    

        Возврат ПараметрыБазы;

   КонецПопытки; 





    ПутьКБазе = "srvr="""+ СокрЛП(мИмяСервера) +""";" + "ref=""" + СокрЛП(мИмяБазы)  +""";";    





    СтрокаСоединения = ПутьКБазе + "Usr="""+ СокрЛП(мБазаЛогин) +""";" + "Pwd="""+ СокрЛП(мБазаПароль) + """;";    

 

     Попытка

        //Устанавливаем внешнее соединение с информационной базой через COM-соединение

        V82 = COMОбъект.Connect(СтрокаСоединения);

    Исключение

        Сообщить(СтрокаСоединения);

        Сообщить("Внешнее соединение не установлено!");    

        Возврат ПараметрыБазы;

    КонецПопытки;





     ПараметрыБазы = Новый Структура;

     ПараметрыБазы.Вставить("ТекущаяВерсия", v82.Метаданные.Версия);

     ПараметрыБазы.Вставить("ПутьКПлатформе",v82.КаталогПрограммы() + "1cv8.exe");





     Возврат ПараметрыБазы;

КонецФункции





Процедура УстановитьCOMСоединение(мИмяСервера,мИмяБазы,мВерсияПлатформы,мБазаЛогин,мБазаПароль) 

   Попытка

        //Создаем COM-объект с идентификатором V82.COMConnector

        COMОбъект = Новый COMОбъект("V"+мВерсияПлатформы+".COMConnector");   //выйдет V82.COMConnector

   Исключение

        Сообщить("Не удалось создать COM-объект!");    

        Возврат;

   КонецПопытки; 





    //Инициализируем строку подключения к информационной базе:    

 //   Если ФайловаяИБ Тогда

        //Файловый вариант 

   //     ПутьКБазе = "File="""+ СокрЛП(КаталогИБ) +""";";

//    Иначе

        //Серверных вариант    

        ПутьКБазе = "srvr="""+ СокрЛП(мИмяСервера) +""";"+

               "ref=""" + СокрЛП(мИмяБазы)  +""";";    

//    КонецЕсли;

                

    СтрокаСоединения = ПутьКБазе +

            "Usr="""+ СокрЛП(мБазаЛогин) +""";"+

            "Pwd="""+ СокрЛП(мБазаПароль) +""";";    

        Сообщить(СтрокаСоединения);         

    Попытка

        //Устанавливаем внешнее соединение с информационной базой через COM-соединение

        V82 = COMОбъект.Connect(СтрокаСоединения);

    Исключение

        Сообщить(СтрокаСоединения);

        Сообщить("Внешнее соединение не установлено!");    

        Возврат;

    КонецПопытки;

             

КонецПроцедуры





        

        

        

// Загрузка списка обновлений из файла XML

// Достаем из XML файла, наибольший номер возможного обновления

Функция ВыполнитьЗагрузкуСпискаОбновлений(ИмяФайлаЗагрузки,ТекущаяВерсияКонфигурации)

    

    СообщениеОбОшибке = "Ошибка при чтении файла списка обновлений.";

    

    Если НЕ ФайлСуществует(ИмяФайлаЗагрузки) Тогда

        Сообщить("Нету XML файла (списка обновлений)");

        Возврат Неопределено;

    КонецЕсли;

    

    ВерсияДляОбновления = Неопределено;

    Попытка

//        ТаблицаЗначений = Новый ТаблицаЗначений;        

//        ТаблицаЗначений.Колонки.Добавить("Конфигурация",          Тип("Строка"));

//        ТаблицаЗначений.Колонки.Добавить("Поставщик",             Тип("Строка"));

//        ТаблицаЗначений.Колонки.Добавить("Версия",                Тип("Строка"));

//        ТаблицаЗначений.Колонки.Добавить("ВерсияДляОбновления",   Тип("Строка"));

//        ТаблицаЗначений.Колонки.Добавить("ПутьКФайлуОбновления",  Тип("Строка"));

//        ТаблицаЗначений.Колонки.Добавить("РазмерФайлаОбновления", Тип("Число"));

        

        ЧтениеXML = Новый ЧтениеXML;

        ЧтениеXML.ОткрытьФайл(ИмяФайлаЗагрузки);

        ЧтениеXML.Прочитать(); // <?xml version="1.0" encoding="UTF-8" ?> 

        

        // Дата формирования файла.

        ЧтениеXML.Прочитать();

        ЧтениеXML.Прочитать();

        ДатаФормирования = ЧтениеXML.Значение;

        ЧтениеXML.Прочитать();

        // Читаем начало элемента Update или конец элемента UpdateList.

        Пока ЧтениеXML.Прочитать() Цикл

            

            Если ЧтениеXML.Имя = "v8u:updateList" Тогда

                Прервать;                    

            Иначе        

                

                Конфигурация = ЧтениеXML.ПолучитьАтрибут("configuration");

                

                Пока ЧтениеXML.Прочитать() Цикл

                    

                    Если ЧтениеXML.Имя = "v8u:update" Тогда

                        Прервать;                    

                    Иначе        

                        

                        Если ЧтениеXML.Имя = "v8u:vendor" Тогда

                            ЧтениеXML.Прочитать();

                            Поставщик = ЧтениеXML.Значение;                            

                        ИначеЕсли ЧтениеXML.Имя = "v8u:version" Тогда

                            ЧтениеXML.Прочитать();

                            Версия = ЧтениеXML.Значение;

                        ИначеЕсли ЧтениеXML.Имя = "v8u:file" Тогда

                            ЧтениеXML.Прочитать();

                            ПутьКФайлуОбновления = ЧтениеXML.Значение;

                        ИначеЕсли ЧтениеXML.Имя = "v8u:size" Тогда

                            ЧтениеXML.Прочитать();

                            РазмерФайлаОбновления = ЧтениеXML.Значение;

                        ИначеЕсли ЧтениеXML.Имя = "v8u:target" Тогда

                            ЧтениеXML.Прочитать();

                        //    НоваяСтрока = ТаблицаЗначений.Добавить();

                        //    НоваяСтрока.Конфигурация          = Конфигурация;

                        //    НоваяСтрока.Поставщик             = Поставщик;

                        //    НоваяСтрока.Версия                = Версия;

                        //    НоваяСтрока.ВерсияДляОбновления      = ЧтениеXML.Значение;

                        //    НоваяСтрока.ПутьКФайлуОбновления  = ПутьКФайлуОбновления;

                        //    НоваяСтрока.РазмерФайлаОбновления = РазмерФайлаОбновления;

                            Если ЧтениеXML.Значение = ТекущаяВерсияКонфигурации Тогда   //279 Новые в конце. на последнюю полученную и будем обновяться

                                ВерсияДляОбновления = Версия;

                            КонецЕсли;

                        КонецЕсли;

                        

                        ЧтениеXML.Прочитать();

                        

                    КонецЕсли;

                    

                КонецЦикла;

                

            КонецЕсли;

            

        КонецЦикла;

        

    Исключение

        Сообщить(СообщениеОбОшибке);

        ЧтениеXML.Закрыть();

        Возврат Неопределено;

        

    КонецПопытки;

    //Возврат ТаблицаЗначений;    

    ЧтениеXML.Закрыть();

    Возврат ВерсияДляОбновления;

    

КонецФункции // ВыполнитьЗагрузкуСпискаОбновлений()









//Входящие Сервер - База - ТипКонфигурации - ВерсияРелиза - ВерсияПлатформы-ИТС логин и пароль необязательно

Процедура ПроверитьОбновлениеКонфигурации(мИмяСервера,мИмяБазы,мТипКонфигурации,мВерсияРелиза,мВерсияПлатформы,мБазаЛогин,мБазаПароль)    

    Сообщить("----------------------------------------------------------------------");

    //удалить старые файлы

    УдалитьФайлы(ФайлСписокОбновленийXML);

    УдалитьФайлы(ФайлСписокОбновленийZIP);    





    // Качаем v8cscdsc.xml в виде v8upd11.zip    

    // Создание HTTP-соединения с сервером обновлений

    СерверОбновлений = Новый HTTPСоединение("downloads.1c.ru",,мИтсЛогин,мИтсПароль,);

    ЗапросКСерверуОбновлений = Новый HTTPЗапрос("/ipp/ITSREPV/V8Update/Configs/"+мТипКонфигурации+"/"+мВерсияРелиза+"/"+мВерсияПлатформы+"/v8upd11.zip");

    СерверОбновлений.Получить(ЗапросКСерверуОбновлений,ФайлСписокОбновленийZIP);





    // Распаковываем v8cscdsc.xml

    ФайлZip = Новый ЧтениеZipФайла(ФайлСписокОбновленийZIP); 

    ФайлZip.ИзвлечьВсе(home);

    ФайлZip.Закрыть();

    УдалитьФайлы(ФайлСписокОбновленийZIP);

    

    //+++++ Запрос версии конфигурации базы...

        ПараметрыComБазы = ВернутьРелизИПлатформу(мИмяСервера,мИмяБазы,мВерсияПлатформы,мБазаЛогин,мБазаПароль);

        

        Если ПараметрыComБазы = Неопределено Тогда 

            Возврат; 

        КонецЕсли;

        ВерсияДляОбновления = ВыполнитьЗагрузкуСпискаОбновлений(ФайлСписокОбновленийXML,ПараметрыComБазы.ТекущаяВерсия);

        ТребуетсяОбновление = Ложь;

        Если ВерсияДляОбновления = Неопределено Тогда 

            Сообщить(мИмяБазы + " ver: " +ПараметрыComБазы.ТекущаяВерсия+ " ОБНОВЛЕНИЕ НЕ ТРЕБУЕТСЯ");

            Возврат;

        КонецЕсли;

        Сообщить(мИмяБазы + " ver: " +ПараметрыComБазы.ТекущаяВерсия+ " update: " + ВерсияДляОбновления);

    //----- Запрос версии конфигурации базы...

    

    КомандаПакетногоАрхивирования = """" + ПараметрыComБазы.ПутьКПлатформе +""""+" CONFIG /S"+мИмяСервера+"\"+мИмяБазы+" /N"""+мБазаЛогин+""" /P"""+мБазаПароль+""" /DumpIB "+DumpIB + мИмяБазы + ".dt /OUT """+home+"\"+мИмяБазы+".log"" -NoTruncate";

    //NoTruncate - не очищать логи 

    //Сообщить(КомандаПакетногоАрхивирования);

    ЗапуститьПриложение(КомандаПакетногоАрхивирования,,Истина,КодВозврата);

    Если КодВозврата = 0  Тогда

        Сообщить("Резервная копия успешно создана.");

    Иначе

        Сообщить("Ошибка при создании резервной копии");

        Возврат;

    КонецЕсли;

    

    Версия_Для_Обновления = СтрЗаменить(ВерсияДляОбновления, ".", "_"); //в каталоге шаблонов через подчеркивание храняться





    //качаем новую версию, если уже не скачено

    Если НЕ ФайлСуществует(мРасположениеОбновлений +"\"+мТипКонфигурации+"\"+Версия_Для_Обновления+"\") Тогда

        //качаем новую

        // Создание HTTP-соединения с сервером обновлений

        Заголовки = Новый Соответствие();

        Заголовки.Вставить("User-Agent", "1C+Enterprise/8.2");     //без заголовка сайт не даст скачать.

        СерверОбновлений = Новый HTTPСоединение("downloads.v8.1c.ru",,мИтсЛогин,мИтсПароль,);

        СтрокаЗапросHTTP = "/tmplts/1c/"+мТипКонфигурации+"/"+ Версия_Для_Обновления +"/1cv8.zip";

        Сообщить(СтрокаЗапросHTTP);

        ЗапросКСерверуОбновлений = Новый HTTPЗапрос(СтрокаЗапросHTTP,Заголовки);

        СерверОбновлений.Получить(ЗапросКСерверуОбновлений, мРасположениеОбновлений+"\1cv8.zip");

        

        ФайлZip = Новый ЧтениеZipФайла(мРасположениеОбновлений+"\1cv8.zip"); 

        ФайлZip.ИзвлечьВсе(мРасположениеОбновлений+"\"+мТипКонфигурации+"\"+Версия_Для_Обновления);

        ФайлZip.Закрыть();

        

        УдалитьФайлы(мРасположениеОбновлений+"\1cv8.zip");

    КонецЕсли;

    //запускаем обновление                                                                                                                                                              

    КомандаПакетногоОбновления = """" + ПараметрыComБазы.ПутьКПлатформе +""""+" CONFIG /S"+мИмяСервера+"\"+мИмяБазы+" /N"""+мБазаЛогин+""" /P"""+мБазаПароль+""" /UpdateCfg "+мРасположениеОбновлений+"\"+мТипКонфигурации+"\"+Версия_Для_Обновления + "\1cv8.cfu /UpdateDBCfg /OUT """+home+"\"+мИмяБазы+".log"" -NoTruncate";

    //Сообщить(КомандаПакетногоОбновления);

    ЗапуститьПриложение(КомандаПакетногоОбновления,,Истина,КодВозврата);

    Если КодВозврата = 0 Тогда

        Сообщить("База Успешно обновлена");

    Иначе

        Сообщить("ОШИБКА ПРИ ОБНОВЛЕНИИ");

        Возврат;

    КонецЕсли;

    

    //Еще разок запрос версии

    //+++++ Запрос версии конфигурации базы...

        ПараметрыComБазы = ВернутьРелизИПлатформу(мИмяСервера,мИмяБазы,мВерсияПлатформы,мБазаЛогин,мБазаПароль);

        

        Если ПараметрыComБазы = Неопределено Тогда 

            Возврат; 

        КонецЕсли;

        ВерсияДляОбновления = ВыполнитьЗагрузкуСпискаОбновлений(ФайлСписокОбновленийXML,ПараметрыComБазы.ТекущаяВерсия);

        ТребуетсяОбновление = Ложь;

        Если ВерсияДляОбновления = Неопределено Тогда 

            Сообщить(мИмяБазы + " ver: " +ПараметрыComБазы.ТекущаяВерсия+ " ОБНОВЛЕНИЕ НЕ ТРЕБУЕТСЯ");

            Возврат;

        КонецЕсли;

        Сообщить(мИмяБазы + " ver: " +ПараметрыComБазы.ТекущаяВерсия+ " update: " + ВерсияДляОбновления);

    //----- Запрос версии конфигурации базы...





КонецПроцедуры

        

УстановитьКонстанты();

//ОСНОВНЫЕ





//ЗУП 2.5

ПроверитьОбновлениеКонфигурации("ka1sql1:1641","up_el","HRM","25","82","Администратор","Администратор");

ПроверитьОбновлениеКонфигурации("ka1sql1:1641","up_spb","HRM","25","82","Администратор","Администратор");



//БП 3.0

ПроверитьОбновлениеКонфигурации("ka1sql1:1741","bp_domx","Accounting","30","83","Администратор","Администратор");

ПроверитьОбновлениеКонфигурации("ka1sql1:1741","bp_el","Accounting","30","83","Администратор","Администратор");





//СВЕТЛАНЫ

//БП 3.0

ПроверитьОбновлениеКонфигурации("ka1sql1:1741","bp_ip","Accounting","30","83","Администратор","Администратор");

ПроверитьОбновлениеКонфигурации("ka1sql1:1741","bp_guild","Accounting","30","83","Администратор","Администратор");

ПроверитьОбновлениеКонфигурации("ka1sql1:1741","bp_lebedeva","Accounting","30","83","Администратор","Администратор");

//ПроверитьОбновлениеКонфигурации("ka1sql1:1741","bp_service","AccountingBase","30","83","Администратор","Администратор");

ПроверитьОбновлениеКонфигурации("ka1sql1:1741","bp_porsche","Accounting","30","83","Администратор","Администратор");





//ЗУП 2.5

ПроверитьОбновлениеКонфигурации("ka1sql1:1641","up_service","HRM","25","82","Администратор","Администратор");

Источник

Категория: Администрирование

Универсальный парсер RSS для 1С

На одном проекте - клиент попросил отображать в программе данные, которые выдаю специализированные сайта в формате RSS - Что делать !?

Писать парсер rss для 1С

Первым делом, взглянув на ссылки, подумал что - обычный XML, сейчас его разложу и быстренько загружу в базу, но:

Выяснилось что сайты имеют разные форматы ввода RSS и главное они не валидные(

таким образом, написав небольшой код, который получает ссылку, далее XMLФайл.Прочитать() на одном сайте проходил на ура (этот пример я описывал в статье: Чтение данных с сайта в формате XML и загрузка в 1С), а вот второй сайт, и третий тоже, при попытке прочитать() выдавали:

{ОбщийМодуль.РегЗадания.Модуль(79)}: Ошибка при вызове метода контекста (Прочитать)

Пока XMLФайл.Прочитать() Цикл

по причине:

Ошибка разбора XML: - [1,1]

Фатальная ошибка:

Extra content at the end of the document

SystemId url rss

решил попробовать на rss других известных сайтов - 80% из проверяемых выдавали ошибку

Пришлось написать прямой построчный парсер RSS:

Структура конфигурации

ИсточникиRSS - URL на RSS, ДанныеRSS - сюда записываются загруженные данные новостей

Код получился таким(в принципе код универсальный, но возможно что-то придется подпилить):

Код 1C v 8.3

 

// RSS

Процедура ПрочитатьRSS(ИсточникRSS)

	url = ИсточникRSS.UrlRSS;

	

	// Получим Сервер

	Если Найти(url,".ru")>0 Тогда urlСервер = Лев(url,Найти(url,".ru")+2);	

	ИначеЕсли Найти(url,".com")>0 Тогда urlСервер = Лев(url,Найти(url,".com")+3);

	ИначеЕсли Найти(url,".org")>0 Тогда urlСервер = Лев(url,Найти(url,".org")+3);

	ИначеЕсли Найти(url,".info")>0 Тогда urlСервер = Лев(url,Найти(url,".info")+4);

	ИначеЕсли Найти(url,".pro")>0 Тогда urlСервер = Лев(url,Найти(url,".pro")+3);

	КонецЕсли;	 		

		

	//Определим тип соединения

	Если Лев(url,5)="https" Тогда

		//ssl = Новый ЗащищенноеСоединениеOpenSSL(Новый СертификатКлиентаWindows(), Новый СертификатыУдостоверяющихЦентровWindows());   

		ssl = Новый ЗащищенноеСоединениеOpenSSL( неопределено, неопределено );

		ТекАдрес = СтрЗаменить(url,urlСервер,""); Сервер = СтрЗаменить(urlСервер,"https://",""); 

		Соединение = Новый HTTPСоединение(Сервер,,,,,

		5, // таймаут в секундах

		ssl // защищенное HTTPS соединение

		);

	Иначе //Обычный HTTP 		

		ТекАдрес = СтрЗаменить(url,urlСервер,""); Сервер = СтрЗаменить(urlСервер,"http://","");

		Соединение = Новый HTTPСоединение(Сервер);

	КонецЕсли;





	Заголовки = Новый Соответствие;

	Заголовки.Вставить("host", Сервер);  

	Запрос = Новый HTTPЗапрос(ТекАдрес, Заголовки);

	Ответ =Соединение.Получить(Запрос);

	Если Ответ.КодСостояния = 200 Тогда // Данные получены, обрабатываем их

		Содержимое= Ответ.ПолучитьТелоКакСтроку();

		//Преобразуем содержимое

		Содержимое = СтрЗаменить(Содержимое,"<br/>","|"); 

		Содержимое = СтрЗаменить(Содержимое,"<![CDATA[",""); Содержимое = СтрЗаменить(Содержимое,"]]>","");  

		Содержимое = СтрЗаменить(Содержимое,Символы.ПС,""); Содержимое = СтрЗаменить(Содержимое,Символы.ВК,""); 

		Содержимое = СтрЗаменить(Содержимое,Символы.ВТаб,""); Содержимое = СтрЗаменить(Содержимое,Символы.Таб,""); 

		Содержимое = СтрЗаменить(Содержимое,"><",">"+Символы.ПС+"<"); 

		

		RegExp = Новый COMОбъект("VBScript.RegExp"); //Регулярка

		RegExp.IgnoreCase = Ложь; 

		RegExp.Global = Истина;    

		RegExp.MultiLine = Истина;   		

		RegExp.Pattern = "<[^>]*>"; //Ищем теги HTML   

		

		//Разберем полученный текст в таблицу

		ЭтоЗапись=Ложь;

		Для н=1 По СтрЧислоСтрок(Содержимое)Цикл

			обрТекст=СтрПолучитьСтроку(Содержимое,н);

			

			Если обрТекст = "<item>" Тогда //Началась запись 

				ЗаписьСтр = Новый Структура(); ЭтоЗапись=Истина; Продолжить;  

			ИначеЕсли обрТекст = "</item>" Тогда //Закончилась запись 

				

				/////////////// ЗАПИСЬ Закончилась //////////////

				/// теперь запишем ее в базу - Справочник ДанныеRSS

				// сначала ПОИСК ДУБЛЕЙ - вдруг уже загружен 				

				Запрос = Новый Запрос;

				Запрос.Текст = 

				"ВЫБРАТЬ

				|	ДанныеRSS.Ссылка

				|ИЗ

				|	Справочник.ДанныеRSS КАК ДанныеRSS

				|ГДЕ

				|	ДанныеRSS.ИсточникRSS =ИсточникRSS

				|	И ДанныеRSS.link ПОДОБНОlink";

				

				Запрос.УстановитьПараметр("link", "%"+ЗаписьСтр.link+"%");

				Запрос.УстановитьПараметр("ИсточникRSS", ИсточникRSS);				

				РезультатЗапроса = Запрос.Выполнить().Выбрать();

				Если РезультатЗапроса.Следующий() Тогда

					// Такая запись уже есть, пока ничего не делаем

				Иначе

					//СОЗДАЕМ Новый

					НовЭлем  = Справочники.ДанныеRSS.СоздатьЭлемент();

					ЗаполнитьЗначенияСвойств(НовЭлем,ЗаписьСтр);

					НовЭлем.ИсточникRSS = ИсточникRSS;

					НовЭлем.Записать(); 					

				КонецЕсли; 				

				/////////////////////// *** /////////////////////

				

				ЭтоЗапись=Ложь; Продолжить; 

			КонецЕсли; //Данные записи

			

			Если ЭтоЗапись Тогда	

				Если Найти(обрТекст,"title>")>0 и Найти(обрТекст,"/title>")>0 Тогда				

					обрТекст = СтрЗаменить(обрТекст,"title",""); обрТекст = СтрЗаменить(обрТекст,"<>",""); обрТекст = СтрЗаменить(обрТекст,"</>","");

					ЗаписьСтр.Вставить("Наименование",СокрЛП(обрТекст));

				КонецЕсли;

				

				Если Найти(обрТекст,"link>")>0 и Найти(обрТекст,"/link>")>0 Тогда				

					обрТекст = СтрЗаменить(обрТекст,"link",""); обрТекст = СтрЗаменить(обрТекст,"<>",""); обрТекст = СтрЗаменить(обрТекст,"</>","");

					ЗаписьСтр.Вставить("link",СокрЛП(обрТекст));

				КонецЕсли;

				

				Если Найти(обрТекст,"description>")>0 и Найти(обрТекст,"/description>")>0 Тогда			

					обрТекст = СтрЗаменить(обрТекст,"description",""); обрТекст = СтрЗаменить(обрТекст,"<>",""); обрТекст = СтрЗаменить(обрТекст,"</>","");

					обрТекст=RegExp.Replace(обрТекст, ""); //Удалим все теги

					ЗаписьСтр.Вставить("desc",СокрЛП(обрТекст));

				КонецЕсли;

				

				Если Найти(обрТекст,"pubDate>")>0 и Найти(обрТекст,"/pubDate>")>0 Тогда			

					обрТекст = СтрЗаменить(обрТекст,"pubDate",""); обрТекст = СтрЗаменить(обрТекст,"<>",""); обрТекст = СтрЗаменить(обрТекст,"</>","");

					ЗаписьСтр.Вставить("pubDate",ПреобразоватьRFC822КДате0(СокрЛП(обрТекст)));

				КонецЕсли;

				

				Если Найти(обрТекст,"enclosure")>0 Тогда					 

					обрТекст = СтрЗаменить(обрТекст,"""",""); обрТекст = СтрЗаменить(обрТекст,"<enclosure url=","");

					обрТекст = СтрЗаменить(обрТекст,"<enclosure url=",""); обрТекст = СтрЗаменить(обрТекст,"type=image/png length=/>","");

					ЗаписьСтр.Вставить("img",СокрЛП(обрТекст));

				КонецЕсли;

			КонецЕсли;	

							

		КонецЦикла;

		

	КонецЕсли;

	

КонецПроцедуры	









Процедура ПроверкаRSS() Экспорт

	Запрос = Новый Запрос;

	Запрос.Текст = 

	"ВЫБРАТЬ

	|	ИсточникиRSS.Ссылка КАК Ссылка

	|ИЗ

	|	Справочник.ИсточникиRSS КАК ИсточникиRSS

	|ГДЕ

	|	ИсточникиRSS.Использовать

	|	И ДОБАВИТЬКДАТЕ(ИсточникиRSS.ДатаПоследнегоОбновления, СЕКУНДА, ИсточникиRSS.ПериодОбновленияВСекундах) <ТекДата"; 	

	Запрос.УстановитьПараметр("ТекДата", ТекущаяДата());

	РезультатЗапроса = Запрос.Выполнить();

	ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

	Пока ВыборкаДетальныеЗаписи.Следующий() Цикл

		ПрочитатьRSS(ВыборкаДетальныеЗаписи.Ссылка);

		// Запишем дату последнего обновления

		ТекОб = ВыборкаДетальныеЗаписи.Ссылка.ПолучитьОбъект();

		ТекОб.ДатаПоследнегоОбновления = ТекущаяДата();

		ТекОб.Записать();

	КонецЦикла;

КонецПроцедуры



Функция ПреобразоватьRFC822КДате0(ДатаВФорматеRFC822) Экспорт

    КопияСтроки = ДатаВФорматеRFC822;

    СтруктураДаты = Новый Структура("Год,Месяц,День,Час,Минута,Секунда",  "","","","","","");

    Месяцы = Новый Структура("Jan,Feb,Mar,Apr,May,Jun,Jul,Aug,Sep,Oct,Nov,Dec",  "01","02","03","04","05","06","07","08","09","10","11","12");

    Для каждого КлючИЗначение Из Месяцы Цикл

        Позиция = Найти(КопияСтроки,КлючИЗначение.Ключ);

        Если Позиция > 0  Тогда

             СтруктураДаты.Месяц = КлючИЗначение.Значение;

            Прервать;

        КонецЕсли;

    КонецЦикла; 

	Состояние = 0;

	КопияСтроки = СтрЗаменить(КопияСтроки,", 1 ",", 01 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 2 ",", 02 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 3 ",", 03 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 4 ",", 04 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 5 ",", 05 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 6 ",", 06 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 7 ",", 07 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 8 ",", 08 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 9 ",", 09 ");

	Для ш=0 По СтрДлина(КопияСтроки) Цикл

        ТекущийСимвол = Сред(КопияСтроки,ш,1); //ПолучитьСимвол(КопияСтроки, ш);

        ТекСимволЦифра= ЭтоЦифра(ТекущийСимвол);

        Если ТекСимволЦифра И Состояние = 0  Тогда

            СтруктураДаты.День = СтруктураДаты.День + ТекущийСимвол;

            Состояние = 1; //начало день

        ИначеЕсли ТекСимволЦифра И Состояние = 1  Тогда

            СтруктураДаты.День = СтруктураДаты.День + ТекущийСимвол;

            Состояние = 2; //ждем год

        ИначеЕсли ТекСимволЦифра И Состояние = 2  Тогда

            СтруктураДаты.Год = СтруктураДаты.Год + ТекущийСимвол;

            Состояние = 3; //продолжаем год

        ИначеЕсли ТекСимволЦифра И Состояние = 3  Тогда

            СтруктураДаты.Год = СтруктураДаты.Год + ТекущийСимвол;

        ИначеЕсли ТекущийСимвол = " " И Состояние = 3 Тогда

               Состояние = 4; //дальше час    

        ИначеЕсли ТекСимволЦифра И Состояние = 4  Тогда

            СтруктураДаты.Час = СтруктураДаты.Час + ТекущийСимвол;

        ИначеЕсли ТекущийСимвол = ":" И Состояние = 4  Тогда

            Состояние = 5; //дальше минута

        ИначеЕсли ТекСимволЦифра И Состояние = 5  Тогда

            СтруктураДаты.Минута = СтруктураДаты.Минута +  ТекущийСимвол;

        ИначеЕсли ТекущийСимвол = ":" И Состояние = 5  Тогда

            Состояние = 6; //дальше секунда

        ИначеЕсли ТекСимволЦифра И Состояние = 6  Тогда

            СтруктураДаты.Секунда = СтруктураДаты.Секунда +  ТекущийСимвол;

        ИначеЕсли ТекущийСимвол = " " И Состояние = 6 Тогда

            Прервать;

        КонецЕсли;

    КонецЦикла;

    Попытка

        Результат = Дата(СтруктураДаты.Год+СтруктураДаты.Месяц+СтруктураДаты.День

                        +СтруктураДаты.Час+СтруктураДаты.Минута+СтруктураДаты.Секунда);

    Исключение

        Результат = Неопределено;    

    КонецПопытки;

    Возврат Результат;

КонецФункции



Функция ЭтоЦифра(Символ) Экспорт

     Если (КодСимвола(Символ)>=48) И (КодСимвола(Символ)<=57) Тогда Возврат Истина; Иначе Возврат ложь; КонецЕсли;

КонецФункции



Функция ПолучитьСимвол(КопияСтроки, ш)

	Возврат Сред(КопияСтроки,ш,1);

КонецФункции

Результат загрузки новостей RSS HelpF.pro

Кстати, как позже выяснилось, здесь уже есть статья с примером через IE и DOM: Получения новостей с RSS-канала сайта buh.ru

Категория: Работа с Интернет, Почтой (Mail), FTP

Как загрузить данные из Access в 1С ?

Загружаем данные из Access в 1С

Код 1C v 8.х

 Файл = "C:\files\demo.mdb" ;

   //СтрокаПодключения = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" + Файл + "; Extended Properties=""Excel 8.0;HDR=NO;""";

    СтрокаПодключения  =   "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" + Файл + ";""";

    Connection = Новый COMОбъект("ADODB.Connection");

    Попытка

        Connection.Open(СтрокаПодключения);

    Исключение

        Сообщить(ОписаниеОшибки());

        Возврат;

    КонецПопытки;

        Command = Новый COMОбъект("ADODB.Command");



    Command.ActiveConnection = Connection;

    Command.CommandText = "S_elect * FROM Table1";

    Command.CommandType = 1;

    RecordSet = Новый COMОбъект("ADODB.RecordSet");

    RecordSet = Command.Execute();

    стр ="";

      Пока RecordSet.EOF() = 0 Цикл

            для н=0 по  Recordset.Fields.Count -1 цикл

            стр = стр + " " + Recordset.Fields(н).Value;

         КонецЦикла;

      Сообщить(стр);

             стр ="";

        RecordSet.MoveNext(); 

      КонецЦикла;

   RecordSet.Close();

    Connection.Close();

Код 1C v 7.x

 Акцесс = СоздатьОбъект("ADODB.CONNECTION");

Попытка

     СтрокаПодключения="Driver={Microsoft Access Driver (*.mdb)};Dbq=C:\mybase.mdb;Uid=Admin;Pwd=";

     Акцесс.Open(СтрокаПодключения);

Исключение

     Сообщить("Все плохо:"+ОписаниеОшибки());

     Возврат;

КонецПопытки;

Команда = СоздатьОбъект("ADODB.Command");

Команда.ActiveConnection=Акцесс;

ТекстСелект = "S_elect * FROM tblCustoms";

НаборЗаписей = СоздатьОбъект("ADODB.RecordSet");

Команда.CommandText=ТекстСелект;

Попытка

     НаборЗаписей=Команда.Execute;

Исключение

     Сообщить("Обломись:"+ОписаниеОшибки());

КонецПопытки;

Попытка

     НаборЗаписей.MoveFirst();

Исключение //нет записей в рекордсете

     НаборЗаписей.Close();

     Возврат;

КонецПопытки;

Пока НаборЗаписей.EOF()=0 Цикл

     ИНН = НаборЗаписей.Fields("INN").Value;

     //ну и т.д.

     НаборЗаписей.MoveNext();

КонецЦикла;

НаборЗаписей.Close();



// Для тех, у кого в базе Акцесс создана рабочая группа (есть файлик mdw), строка подключения будет такая: 

СтрокаПодключения="Driver= Microsoft Access Driver (*.mdb)};systemDB=C:\wg.mdw;Dbq=C:\mybase.mdb;Uid=Admin;Pwd=";

Работа с ACCESS из 1С через DAO

Код 1C v 7.x

 Процедура Выполнить() 

//фасВладелец = СтрЗаменить(фасВладелец," ","_"); 

   Спр = СоздатьОбъект("Справочник.ТоварыВПрайсе"); 

   Спр.ИспользоватьВладельца(ФасВладелец); 

   dbe = СоздатьОбъект("dao.DBEngine.36"); 

   wksp = dbe.Workspaces(0); 

   db = 0; 

   Если ФС.СуществуетФайл(КаталогИБ()+"Pric_list.mdb")=0 Тогда               // 

       db = wksp.CreateDataBase(КаталогИБ()+"Pric_list.mdb",";LANGID=0x0419;Cp=1251;Country=0");             //   

       db.Execute("Create table [" + Строка(фасВладелец) + "]                                                                                             

       |(Rec_ind integer, 

       |Код text,                                                                                                           

       |Артикул text, 

       |Цена integer, 

       |Товар text, 

       |Единица text, 

       |Val text);" 

       ); 

       db.Execute("Create index Rec_ind on ["+Строка(фасВладелец)+"] (Rec_ind);"); 

   Иначе 

       db= wksp.OpenDataBase(КаталогИБ()+"Pric_list.mdb"); 

       Попытка 

           rs = db.OpenRecordset(Строка(фасВладелец)); 

       Исключение 

           Сообщить("Создается новая таблица"); 

       КонецПопытки; 

       Если ПустоеЗначение(rs)= 1 Тогда 

           db.Execute("Create table [" + Строка(фасВладелец) + "]                                                                                             

           |(Rec_ind integer, 

           |Код text, 

           |Артикул text, 

           |Цена integer, 

           |Товар text, 

           |Единица text, 

           |Val text);" 

           ); 

           db.Execute("Create index Rec_ind on ["+Строка(фасВладелец)+"] (Rec_ind);"); 

       КонецЕсли;     

       db.Execute("Delete * From ["+Строка(фасВладелец)+"];");                                                         

   КонецЕсли;   

   rs = db.OpenRecordset(Строка(фасВладелец)); 

   Y = 1; 

   Спр.ВыбратьЭлементы(); 

   Пока Спр.ПолучитьЭлемент() = 1 Цикл 

       лсЕдиницы = ""; 

       Если Спр.асТовар.апТип=Перечисление.ТипТовара.Услуга Тогда 

           лсЕдиницы = ""; 

       ИначеЕсли Спр.асТовар.апТип=Перечисление.ТипТовара.Весовой Тогда 

           лсЕдиницы = "г"; 

       ИначеЕсли Спр.асТовар.апТип=Перечисление.ТипТовара.Штучный Тогда 

           лсЕдиницы = "шт."; 

       КонецЕсли; 

       Если Спр.ЭтоГруппа() = 0 Тогда 

           rs.AddNew(); 

           rs.Rec_ind = Y; 

           rs.Код= Спр.асТовар.ПолныйКод(); 

           rs.Артикул =  Спр.асТовар.сАртикул; 

           rs.Цена = Спр.чЦена; 

           rs.Товар=Спр.асТовар.сПолнНаименование; 

           rs.Единица =  лсЕдиницы; 

           rs.Val = Спр.асВалюта.Код; 

           rs.Update(); 

           Y=Y+1; 

       КонецЕсли; 

   КонецЦикла; 

   db.Close();   

   Сообщить("Выгрузка завершена"); 

КонецПроцедуры

Код 1C v 7.x

 

Процедура ACCESS()

     dbe=CreateObject("DAO.DBEngine.36");

     wksp=dbe.Workspaces(0);

     db=0;

     // в ковычках имя фаила с расширением MDB

     Если ФС.СуществуетФайл(КаталогПользователя()+"sr.mdb")=0 Тогда

          // создание файла базы данных с русским порядком сортировки

          db=wksp.CreateDataBase(КаталогПользователя()+"mars_sr.mdb",";LANGID=0x0419;CP=1251;COUNTRY=0");

          // DDL - запрос на создание таблицы

          // описание языка DDL (подмножество SQL) смотрите в хелпе по MS Access

          // не пытайтесь делать это с другими форматами - DDL через DAO поддерживается только для MDB

          //Создадим еще таблицу

          db.Execute("CREATE TABLE   BANKS

          |(REC_IND INTEGER,

          |BANKCODE INTEGER,

          |BANKNAME  TEXT  ,

          |ModifiedFlg BIT,

          |ChangeSeqFlg BIT);"

          );

          // индекс на нужные поля

          db.Execute("CREATE INDEX REC_IND ON BANKS (REC_IND);");

     Иначе

          // просто открываем базу данных в разделенном режиме

          db=wksp.OpenDataBase(КаталогПользователя()+"sr.mdb");

          // и очищаем имеющиеся данные

          db.Execute("DELETE * FROM BANKS;");

    КонецЕсли;

    // rs-это как раз сама таблица, куда мы будем добавлять записи

    rs=db.OpenRecordset("BANKS");

    // добавление записи

    rs.AddNew();

    // присвоение значений полям

    rs.REC_IND            =     "1";

    rs.BANKCODE       =     "34";

    rs.BANKNAME       =    "Инвест";

    rs.ModifiedFlg        =     "1";

    // запомним запись

    rs.Update();

    // и так далее ...

    db.Close();  // закрытие базы данных

КонецПроцедуры

Категория: Работа с Microsoft Office и OpenOffice

Прямое подключение к сторонним Базам Данных

Иногда необходимо подключиться к другим (не 1С-ным) БД на том же SQL.
Вот примерный код такого подключения:

Код 1C v 8.х

 Connection = Новый COMОбъект("ADODB.Connection");

СтрокаПодключения = "Provider=SQLOLEDB.1;Password=" + Здесь пароль доступа + ";Persist Security Info=True;User ID=" + Здесь имя пользователя + ";Initial Catalog=" + Здесь имя БД + "; Data Source=" + Здесь имя сервера + ";";



//Ну и выполним какой-нибудь запрос с обходом:

Результат = Новый COMОбъект("ADODB.Command");

Результат.ActiveConnection = Connection; // работаем через это соединение

Результат.CommandTimeOut = Connection.CommandTimeOut; // таков тайм-аут

Результат.CommandType = "adCmdText"; // исполняем в точности процедуру

Результат.CommandText =    " S_elect name as Наименование

| FROM

|    dbo.sysobjects'";



Выборка = Результат.Execute(); // выполняем процедуру

Пока Выборка.Eof() = 0 Цикл

    Сообщить(Выборка.Fields("Наименование").Value);

   Выборка.MoveNext();

КонецЦикла;

Категория: COM-объекты, WMI, WSH

Создание и работа с БД MySQL из 1С

Появилась необходимость выложить часть данных из 1С в открытый доступ большому числу пользователей.
Что бы не нарушать условий лицензирования и обеспечить безопасность данных, было принято решение развернуть новую базу на MySQL. Так как особо модерировать ее никто не хочет, пришлось сделать управление MySQL-ной БД из 1С, и начал с создания структуры БД. Итак:
Создаем 2 справочника неирархических, один подчинен другому.
а. Таблицы
б. Колонки

Таблицы - реквизиты:
Автокод - Булево (Определяет необходимость нумеровать запись уникальным кодом, или отдать нумерование на откуп MySQL)
Таблицы - колонки:
ТипДанных - Число (в коде определим тип хранящихся данных по числу)
Длина - Число (длина хранящихся данных)
МожетБытьНоль - булево (может ли хранится пустое значение)
Связь - СсылкаНа таблицу (С которой есть связь все к одному)

Заполняем значениями справочники...

Теперь подключаемся:

Код 1C v 8.х

 Connection = Новый COMОбъект("ADODB.Connection");

СтрокаПодключения =   "DRIVER={MySQL ODBC 5.1 Driver};OPTION=3;DATABASE=" + константы.lk_БД.Получить() + ";PWD=" + константы.lk_Пароль.Получить() + ";PORT=3306;SERVER=" + константы.lk_Сервер.Получить() + ";UID=" + константы.lk_Пользователь.Получить() + ";";

Connection.Open(СокрЛП(СтрокаПодключения));

Сначала удалим таблицы если они есть:

Код 1C v 8.х

     Результат = Новый COMОбъект("ADODB.Command");

    Результат.ActiveConnection = Connection; // работаем через это соединение

    Результат.CommandTimeOut = Connection.CommandTimeOut; // таков тайм-аут

    Результат.CommandType = "adCmdText";

   

    Запрос = Новый Запрос;

    Запрос.Текст = "ВЫБРАТЬ

    |   Таблицы.Наименование КАК Таблица

    |   ИЗ

    |    Справочник.Таблицы КАК Таблицы";

    ВыборкаТаблиц = Запрос.Выполнить().Выбрать();

    Пока ВыборкаТаблиц.Следующий() Цикл

        Результат.CommandText =        " D_rop TABLE IF EXISTS " + ВыборкаТаблиц.Таблица + " ;";

        Результат.Execute();

    КонецЦикла;

Теперь приступим к созданию таблиц БД:

Код 1C v 8.х

  Запрос = Новый Запрос;

    Запрос.Текст = "ВЫБРАТЬ

    |    Таблицы.Наименование КАК Таблица,

    |    Колонки.Наименование КАК Колонка,

    |    Колонки.ТипДанных,

    |    Колонки.Длина,

    |    Колонки.МожетБытьНоль,

    |    Колонки.Связь.Наименование КАК Связь

    |ИЗ

    |    Справочник.Колонки КАК Колонки

    |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.Таблицы КАК Таблицы

    |        ПО Колонки.Владелец = Таблицы.Ссылка

    |

    |ИТОГИ ПО

    |    Таблица";

   

    ВыборкаТаблиц = Запрос.Выполнить().Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);

    Пока ВыборкаТаблиц.Следующий() Цикл

 

        Скрипт =         " CREATE TABLE " + ВыборкаТаблиц.Таблица + " ( " + символ(13) +

        " " + ПолучитьКолонкуID(ВыборкаТаблиц.Таблица) + " int(11) NOT NULL " + ?(Справочники.Lk_Таблицы.НайтиПоНаименованию(ВыборкаТаблиц.Таблица).АвтоКод,"auto_increment","") + "," + символ(13);

       

        Выборка = ВыборкаТаблиц.Выбрать();

        Строчека = "" ;

        Ключики = "";

       

        Пока Выборка.Следующий() цикл

         Строчека = Строчека + "`" + Выборка.Колонка + "` " + ПолучитьПродолжениеСкрипта(Выборка.ТипДанных,Выборка.длина,Выборка.МожетБытьНоль) + "," + символ(13);

           

            ЕСли ЗначениеЗаполнено(Выборка.Связь) Тогда

                Ключики = Ключики + ", KEY `FK_" + ВыборкаТаблиц.Таблица + "-" + Выборка.Колонка + "` (`" + Выборка.Колонка + "`),

                | CONSTRAINT `FK_" + ВыборкаТаблиц.Таблица + "-" + Выборка.Колонка + "` FOREIGN KEY (`" + Выборка.Колонка + "`) REFERENCES `" + Выборка.Связь + "` (`" + ПолучитьКолонкуID(Выборка.Связь) + "`)" + Символ(13)    ;   

            КонецЕсли;               

        КонецЦикла;

       

        Скрипт = Скрипт + Строчека;

        Скрипт = Скрипт + "  PRIMARY KEY  (" + ПолучитьКолонкуID(ВыборкаТаблиц.Таблица) + ") " + символ(13) +  Ключики +

        " ) ENGINE=InnoDB DEFAULT CHARSET=utf8;";

        Сообщить("Таблица создана: " + ВыборкаТаблиц.Таблица);

        Результат.CommandText =        скрипт;

        Результат.Execute();

     КонецЦикла;

    Connection.Close();

И под закуску недостающие функции, использованные в основном тексте:

Код 1C v 8.х

 Функция ПолучитьКолонкуID(зн) экспорт

    ПрефиксКончился = Ложь;

    Колонка = "";

    Для сч = 1 по СтрДлина(зн) Цикл

              Символик = Mid(зн,Сч, 1);

             

          Если ПрефиксКончился Тогда

        Колонка = Колонка + Символик;     

          КонецЕсли;

 

             

              Если Символик = "_" Тогда

                  ПрефиксКончился = Истина;

              КонецЕсли;

             

          КонецЦикла;

          Если Колонка = "" Тогда

              Колонка = зн;

          КонецЕсли;

          Колонка = Колонка + "ID";

          Возврат Колонка;

КонецФункции

Предполагается что название таблиц идут с префиксом например: prefix_NameTable

Код 1C v 8.х

 Функция ПолучитьПродолжениеСкрипта(ТипД,ДлинаД,Ноль) экспорт

   

    Если ТипД = 1 тогда  //строка

     Зн = " varchar(" + Строка(ДлинаД) + ") " + ?(Ноль, "null","NOT NULL");

    ИначеЕсли ТипД = 2 Тогда     //число

     Зн = " int(11) " + ?(Ноль, "null","NOT NULL");

    ИначеЕсли ТипД = 3 Тогда          //смаллчисло

     Зн = " smallint(6) " + ?(Ноль, "null","NOT NULL");

    ИначеЕсли типД = 4 тогда    //текст

     Зн = " text";

    ИначеЕсли ТипД = 5 тогда // дата

     Зн = " date " + ?(Ноль, "null","NOT NULL");

    ИначеЕсли ТипД = 6 Тогда          //смаллчисло

     Зн = " bit(1) " + ?(Ноль, "null","NOT NULL");

 ИначеЕсли ТипД = 7 Тогда // Дата и время

          Зн = " dateTime " + ?(Ноль, "null","NOT NULL");

 КонецЕсли;   

         

    Возврат Зн;

КонецФункции

Источник

Категория: COM-объекты, WMI, WSH

Чтение и Вывод данных в Excel

Замечание: В Excel разделителем дробной части считается символ ",". Поэтому перед сохранением таблицы 1С в формате Excel замените в ней другой разделитель (например ".") на ",". Иначе в Excel с этими числами не удастся произвести вычисления, или они вообще не будут отображаться как числа. Например, в таблице 1С "15.2" отобразится в Excel как "15.фев".

Для 8.х заменить СоздатьОбъект( на Новый COMОбъект(

Чтение (Получение) данных из Excel
Доступ из 1С к Excel производится посредством OLE. Например, код

Код 1C v 7.x

 Попытка

 Эксель = СоздатьОбъект("Excel.Application");

Исключение

 Сообщить(ОписаниеОшибки() + " Программа Exсel не установлена на данном компьютере!");

 Возврат;

КонецПопытки;

позволит получить доступ через переменную "Эксель" к запущенному приложению Excel. А далее уже можно получить доступ к книге (файлу), листу и ячейке с данными.Чтобы открыть книгу (файл)

Код 1C v 7.x

 Книга = Эксель.WorkBooks.Open(ПутьКФайлу);

//ПутьКФайлу - полный путь к файлу книги Excel.



//Выбор листа книги для работы с ним:

Лист = Книга.WorkSheets(НомерЛиста);

//или

Лист = Книга.WorkSheets(ИмяЛиста);

// где НомерЛиста - номер листа в книге, ИмяЛиста - имя листа в книге.



// Получение значения ячейки листа:

Значение = Лист.Cells(НомерСтроки, НомерКолонки).Value;

// где НомерСтроки, НомерКолонки - номер строки и номер колонки, на пересечении которых находится ячейка.

Важно: не забывайте поле выполнения нужных действий добавлять код

Код 1C v 7.x

 Эксель.Quit();

, иначе запущенный процесс останется незавершенным и будет занимать память и процессор компьютера.

Вывод данных в Excel
Для вывода (выгрузки) данных в Excel необходимо либо открыть существующую книгу, либо создать новую, и выбрать рабочий лист для вывода данных. Открытие существующей книги описано выше, а для создания новой книги нужно использовать следующий код:

Код 1C v 7.x

 Попытка

 Эксель = СоздатьОбъект("Excel.Application");

Исключение

 Сообщить(ОписаниеОшибки() + " Программа Exсel не установлена на данном компьютере!");

 Возврат;

КонецПопытки;



Книга = Эксель.WorkBooks.Add();

Так как при создании книги в Excel автоматически создаются листы (Сервис->Параметры->Общие->Листов в новой книге), то нужно лишь произвести выбор листа, с которым будет вестись работа:

Код 1C v 7.x

 Лист = Книга.WorkSheets(НомерЛиста);



// либо добавить в книгу новый лист, если необходимо:

Лист = Книга.Sheets.Add();

Следующим шагом будет установка значения ячейки:

Код 1C v 7.x

 Лист.Cells(НомерСтроки, НомерКолонки).Value = Значение;

// где НомерСтроки, НомерКолонки - номер строки и номер колонки, на пересечении которых находится ячейка.

И в конце нужно произвести запись созданной книги:

Код 1C v 7.x

 Попытка

 Книга.SaveAs(ПутьКФайлу);

Исключение

 Сообщить(ОписаниеОшибки()+" Файл не сохранен!");

 Возврат;

КонецПопытки;

// где ПутьКФайлу - полный путь к файлу книги Excel (включая имя).

Важно: не забывайте, что в имени файлов не должно содержаться символов \ / : * ? " > <

Категория: Работа с Microsoft Office и OpenOffice

Работа с буфером обмена средствами 1С

Копировать из 1С в буфер обмена( без ВК):

Код 1C v 8.х

 ЭлементыФормы.Добавить(Тип("ПолеHTMLДокумента"), "Поле_HTML_Документа_acb123", Ложь);

Окно = ЭлементыФормы.Поле_HTML_Документа_acb123.Документ.ParentWindow;

Окно.ClipboardData.SetData("Text", ТекстПисьма);

ЭлементыФормы.Удалить(ЭлементыФормы.Индекс(ЭлементыФормы.Найти("Поле_HTML_Документа_acb123")));

Вставить в 1С из буфера обмена:

Код 1C v 8.х

 ЭлементыФормы.Добавить(Тип("ПолеHTMLДокумента"), "Поле_HTML_Документа_acb123", Ложь);

Окно = ЭлементыФормы.Поле_HTML_Документа_acb123.Документ.ParentWindow;

СодержимоеБуфера = Окно.ClipboardData.GetData("Text");

ЭлементыФормы.Удалить(ЭлементыФормы.Индекс(ЭлементыФормы.Найти("Поле_HTML_Документа_acb123")));

ТекстПисьма = ТекстПисьма + СодержимоеБуфера;

При определенных настройках политики безопасности, способ с ПолеHTMLДокумента НЕ работает, используйте:

Код 1C v 8.х

 

Функция ПолучитьТекстБуфераОбмена() Экспорт

#Если Клиент Тогда

    Объект = Новый COMОбъект("htmlfile");

    Возврат Объект.ParentWindow.ClipboardData.Getdata("Text");

#КонецЕсли

КонецФункции

 

Функция УстановитьТекстВБуферОбмена(Текст) Экспорт

#Если Клиент Тогда 

    Объект = Новый COMОбъект("htmlfile");

    Объект.ParentWindow.ClipboardData.Setdata("Text", Текст);

    Возврат Текст;

#КонецЕсли 

КонецФункции

Для 7.7:

Код 1C v 7.x

 Set objHTM = CreateObject("htmlfile");

Текст = "Помощь в 1С";

objHTM.ParentWindow.ClipboardData.Setdata("Text", Текст);

Текст = objHTM.ParentWindow.ClipboardData.GetData("text");

Используя WSH:

Код 1C v 8.х

  // через SendKeys передаем Ctrl-C и Ctrl-V    

wsh=Новый COMОбъект("WScript.Shell");    

// Скопировать текст     

wsh.SendKeys("^c");      

// Вставить текст  

wsh.SendKeys("^v");

Код 1C v 7.x

  // через SendKeys передаем Ctrl-C и Ctrl-V    

wsh=СоздатьОбъект("WScript.Shell"); 

// Скопировать текст     

wsh.SendKeys("^c");  // или так:  wsh.SendKeys("^(C)");          

// Вставить текст  

wsh.SendKeys("^v");  // или так:  wsh.SendKeys("^(V)");  



//Объект Clipboard

WshExtra = СоздатьОбъект("WshExtra.Clipboard");  

// Скопировать текст   

WshExtra.Copy("Запись в буфер обмена")

// Вставить текст 

Текст = WshExtra.Paste();

Категория: Полезные, Универсальные Функции

Как выгрузиться в EXCEL со сводными таблицами

Пошаговый рабочий алгоритм выгрузки в EXCEL на примере выгрузки отчетов производства за смену(Автор статьи: Funny):

(1) Нарисовать форму обработки и к кнопке запуска прицепить процедуру:

Код 1C v 8.х

 Процедура КнопкаВыполнитьНажатие(Кнопка)

    

    Если ПроверкаДат() Тогда 

         Состояние("Запущена выгрузка данных");

         ПолучитьДанныеВТаблице();

         Если чОтчетов<>0 Тогда

                СортироватьТаблицу();

              ВыгрузитьТаблицуВФайл();

              ЗакрытьСистему();

              Состояние("Выгрузка завершена");

         Иначе

              //ЗакрытьСистемуАварийно();

 

         КонецЕсли;

    КонецЕсли;    

КонецПроцедуры

(2) Создадим функцию ПроверкаДат() корректного указания дат обработки
(3) Создадим процедуру ПолучитьДанныеВТаблице() выборки требуемых данных из документов в таблицу значений
(4) Создадим процедуру СортироватьТаблицу() для сортировки таблицы значений как нам нужно
(5) Создадим процедуру ВыгрузитьТаблицуВФайл() выгрузки ТЗ в Excel-файл:

Код 1C v 8.х

 Процедура ВыгрузитьТаблицуВФайл()

    

        //1. Open Excel-file 

 

               Если FileOfReports = Неопределено Тогда

            Попытка

                FileOfReports = Новый COMОбъект("Excel.Application");

                MyBook=FileOfReports.WorkBooks.Add(истина); //вместо истина можно вставить имя шаблона

 

                

                FirstSheet=MyBook.Worksheets(1);

                FirstSheet.Name = ОпределитьДату(НачПериода)+"-"+ОпределитьДату(КонПериода);

                FirstSheet.Activate();



                MyBook.SaveAs(КаталогDBF+"ОтчетыПроизводства.xls");

                

            Исключение

                Сообщить("ОШИБКА ЗАПИСИ В EXCEL-ФАЙЛ:"+ОписаниеОшибки());

                Сообщить("Совет: Возможно файл, в который должна быть произведена запись, Вами открыт для просмотра");

                Сообщить("Если это так, то закройте файл и запустите данную обработку повторно!");

            КонецПопытки;

            

            FileOfReports.Visible = 0;

        Иначе

            FileOfReports.Visible = 0;

            //FileOfReports.Visible = 1;

 

        КонецЕсли;

    

        //2.=========================================================================

        //Состояние("Анализ структуры файла...");

         

        чОтчетов = ТаблицаОтчетов.Количество();

        

        ЭлементыФормы.ИндикаторЗагрузки.МинимальноеЗначение = 0;

        ЭлементыФормы.ИндикаторЗагрузки.МаксимальноеЗначение = чОтчетов;

            

        ЭлементыФормы.Logo.Заголовок = "Выгружаю документы";

        лСчетчикИндикатора = 0;

        

        ВыгрузитьЗаголовокТаблицы(26);

        

        //ВЫГРУЖАЮ ТАБЛИЦУ В ФАЙЛ ПО СТРОКАМ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

 

        фСтарт=истина; //флаг первого прохода

 

        чОт=2;         //номер первой строки с данными

         

        Пока чОтчетов >= 1 Цикл //Цикл по строкам Таблицы отчетов

 

              чОтчетов = чОтчетов -1;

              СтрокаОтчетов = ТаблицаОтчетов.Получить(чОтчетов);

             Если (СтрокаОтчетов.ДатаВыпуска=ДатаВыпускаПред) 

                И (СтрокаОтчетов.Принадлежность=ПринадлежностьПред)

                И (СтрокаОтчетов.Типоразмер=ТипоразмерПред)

                И (СтрокаОтчетов.ТипОсновы=ТипОсновыПред)

             Тогда

             Иначе

                ДатаВыпускаПред=СтрокаОтчетов.ДатаВыпуска; 

                ПринадлежностьПред=СтрокаОтчетов.Принадлежность;

                ТипоразмерПред=СтрокаОтчетов.Типоразмер;

                ТипОсновыПред=СтрокаОтчетов.ТипОсновы;

                Если фСтарт Тогда

                     фСтарт = ложь; //Уже не первый проход

 

                Иначе     

                     чДо=глСчетчикСтрок;

                     ВыгрузитьСтрокуИтог(чОт,чДо,26);

                КонецЕсли;

                чОт=глСчетчикСтрок;

             КонецЕсли;

             

             ВыгрузитьСтрокуОтчетовВФайл(СтрокаОтчетов,26);

             

             лСчетчикИндикатора = лСчетчикИндикатора + 1;

             ЭлементыФормы.ИндикаторЗагрузки.Значение = лСчетчикИндикатора;

             

             ОбработкаПрерыванияПользователя();

        

        КонецЦикла;

        чДо=глСчетчикСтрок;

        ВыгрузитьСтрокуИтог(чОт,чДо,26);

 

        //КОНЕЦ ВЫГРУЗКИ СТРОК В ФАЙЛ 

 

        Состояние("Данные файла выгружены");               

        //~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

 

        libСообщитьНК1("ИНФО: ШАГ 1 ВЫПОЛНЕН. Данные файла Отчеты.DBF успешно считаны",1);    

        

        //Состояние("Создание сводных таблиц");

 

        ЭлементыФормы.Logo.Заголовок = "Создание сводных таблиц";

        

        //РазделитьОбласти();

 

            //Range("A2").S_elect

 

            //ActiveWindow.FreezePanes = True

 

        СоздатьТаблицуЛист(MyBook.Worksheets(1).Name,"наим","Дата","Наим","","К");

        СоздатьТаблицуЛист(MyBook.Worksheets(1).Name,"ЮВ","Дата","Наим,Каркас,Вид","","К");

        СоздатьТаблицуЛист(MyBook.Worksheets(1).Name,"В пр(2)","Дата","Наим,Каркас,Основа","","К");

        СоздатьТаблицуЛист(MyBook.Worksheets(1).Name,"В пр","Дата","Каркас,Основа","","К");

        СоздатьТаблицуЛист(MyBook.Worksheets(1).Name,"Основа","Дата","Основа","","кг основы");

        СоздатьТаблицуЛист(MyBook.Worksheets(1).Name,"Напыление","","Напылен","","кг напылен");

        СоздатьТаблицуЛист(MyBook.Worksheets(1).Name,"Клей","","Дата","","кг клея");

            

КонецПроцедуры



Процедура СоздатьТаблицуЛист(стрДанные,стрСводнаяТаблица,стрПоле1,стрПоле2,стрПоле3,стрПоле4);

    

    //Создает сводную таблицу стрСводнаяТаблица с полями (стрПоле4 - поле реквизита) 

     //и размещает ее на одноименном листе

     //Заполняет сводную таблицу данными, взятыми с листа стрДанные

     

    //Поле стрПоле2 может быть полем списка через запятую

   

    //0. Вспомогательный разбор списка значений в стрПоле2 и определение числа значений

 

         лПоля.Очистить(); //сбросим все значения, если таковые весели в памяти

 

         стрПоля=стрПоле2;

         i=1;//число значений в списке

 

         Пока Найти(стрПоля,",")<>0 Цикл

             

              n=Найти(стрПоля,",");

              лПоля.Добавить(Сред(стрПоля,1,n-1));

              стрПоля=Сред(стрПоля,n+1);

              i=i+1;

              

         КонецЦикла;      

         лПоля.Добавить(стрПоля);

         

    //1. Установить диапазон выборки данных

     FirstSheet.Activate();

    дДиапазонДанных=FirstSheet.UsedRange.Address;

    ДиапазонДанных=FirstSheet.Name+"!"+Строка(дДиапазонДанных);    

    

    //2. Создать кэш под сводную таблицу

    //   аргументы не переменные, а текст с именем переменных (crazy)

     

         SourceType = xlDatabase;

         SourceData = ДиапазонДанных;

    

         Cache = MyBook.PivotCaches().Add(SourceType, SourceData);

 

    //для отладки: FileOfReports.Visible = 1;   

           

    //3. Породить из кэша сводную таблицу с именем стрСводнаяТаблица

         TableDestination="";

         TableName=стрСводнаяТаблица;

    

         Cache.CreatePivotTable(TableDestination,TableName);

    

    //4. Определить представление данных в сводной таблице

     //стрПоле1

 

    Если СокрЛП(стрПоле1)<>"" Тогда

         MyBook.ActiveSheet.PivotTables(TableName).PivotFields(стрПоле1).Orientation = 3; //xlRowField=1 то, что указывается справа у таблицы

 

    КонецЕсли;

    

    //стрПоле2

 

    чНомер=0;

    Пока чНомер<i Цикл 

         Если СокрЛП(лПоля[чНомер].Значение)<>"" Тогда

               MyBook.ActiveSheet.PivotTables(TableName).PivotFields(лПоля[чНомер].Значение).Orientation = 1; 

         КонецЕсли;



         чНомер = чНомер + 1;  

    КонецЦикла;      



    //стрПоле3

 

    Если СокрЛП(стрПоле3)<>"" Тогда

         MyBook.ActiveSheet.PivotTables(TableName).PivotFields(стрПоле3).Orientation = 2; //xlColumnField=2 то, что указывается в вепрхней части таблицы

 

    КонецЕсли;

    

    //стрПоле4

 

    Если СокрЛП(стрПоле4)<>"" Тогда

         MyBook.ActiveSheet.PivotTables(TableName).PivotFields(стрПоле4).Orientation = 4; //xlCount=4 data

 

    КонецЕсли;

    

    //5. Скрыть пустые строки в стрПоле2, предварительно проверив, что таковые СУЩЕСТВУЮТ!!!!

    //стрПоле2

 

    чНомер=0;

    Пока чНомер<i Цикл 

         Если СокрЛП(лПоля[чНомер].Значение)<>"" Тогда

              Если IfPivotItemExists(TableName,лПоля[чНомер].Значение,"(пусто)")Тогда

                    MyBook.ActiveSheet.PivotTables(TableName).PivotFields(лПоля[чНомер].Значение).PivotItems("(пусто)").Visible = False;

              КонецЕсли;

         КонецЕсли;

         чНомер = чНомер + 1;  

    КонецЦикла;      

             

    //6. Закрыть вспомогательные панели                                                  

 

        MyBook.ShowPivotTableFieldList = False;

        FileOfReports.CommandBars("PivotTable").Visible = False;

    

    //7. Присвоить активному листу имя, заданное в параметрах процедуры

 

        MyBook.ActiveSheet.Name = стрСводнаяТаблица;

    

    //8. Сохранить файл

 

        MyBook.Save();

    

КонецПроцедуры



Функция IfPivotItemExists(strTableName,strFieldName,strItemName)

//Проверяет существование позиции поля сводной таблицы со значением strItemName    

 

        nItems = MyBook.ActiveSheet.PivotTables(strTableName).PivotFields(strFieldName).PivotItems().Count;

        i = 1;

        Пока i <= nItems Цикл

            Если strItemName=MyBook.ActiveSheet.PivotTables(strTableName).PivotFields(strFieldName).PivotItems(i).Name Тогда

                 //Искомая позиция strItemName существует:

 

                 //Сообщить("Позиция "+strItemName+" найдена");

 

                 Возврат True;

            КонецЕсли;

            i=i+1; 

        КонецЦикла;

        

        //Сообщить("Позиция "+strItemName+" не найдена");

 

        Возврат False;

        

КонецФункции

Код 1C v 7.x

  РабочаяКнига = СоздатьОбъект("Excel.Application");

РабочаяКнига.SheetsInNewWorkbook = 1;

РабочаяКнига.Caption = "Отчет по договорам отгрузки";

NewBook = РабочаяКнига.Workbooks;

List = NewBook.Add;



СписокСтолбцов = СоздатьОбъект("СписокЗначений");

СписокСтолбцов.ДобавитьЗначение("Модель");

СписокСтолбцов.ДобавитьЗначение("Разнорядка");

СписокСтолбцов.ДобавитьЗначение("По договору");

СписокСтолбцов.ДобавитьЗначение("Отгрузили");

СписокСтолбцов.ДобавитьЗначение("Осталось");



//Заполним наименование столбцов: Модель, Разнорядка, Количество

Для Столбец = 1 По СписокСтолбцов.РазмерСписка() Цикл

	Ячейка = РабочаяКнига.Cells(1,Столбец);

	Ячейка.Value = СписокСтолбцов.ПолучитьЗначение(Столбец);

КонецЦикла; 



//Формируем запрос по регистру

//	//Создание объекта типа Запрос

Запрос = СоздатьОбъект("Запрос");

ТекстЗапроса =

"//{{ЗАПРОС(Сформировать)

|Период с ДатаНач по ДатаКон;

|Разнорядка = Регистр.УчетДоговоров.Разнорядка;

|Модель = Регистр.УчетДоговоров.Модель.Группа;

|Колво = Регистр.УчетДоговоров.Количество;

|Функция КолвоПриход = Приход(Колво);

|Функция КолвоРасход = Расход(Колво);

|Функция КолвоОст = КонОст(Колво);

|Группировка Разнорядка;

|Группировка Модель;

|"//}}ЗАПРОС

;



// Если ошибка в запросе, то выход из процедуры

Если Запрос.Выполнить(ТекстЗапроса) = 0 Тогда

	Возврат;

КонецЕсли;



НомерСтроки = 1;

Пока Запрос.Группировка("Разнорядка") = 1 Цикл

	Пока Запрос.Группировка("Модель") = 1 Цикл 

		Модель = Запрос.Модель;

		Разнорядка = Запрос.Разнорядка;

		КолПоДоговору = Запрос.КолвоПриход;

		КолОтгрузили = Запрос.КолвоРасход;

		КолОсталось = Запрос.КолвоОст;

		НомерСтроки = НомерСтроки + 1;

		//Организум заполнение ячеек Excel

		Для Ст = 1 По СписокСтолбцов.РазмерСписка() Цикл

			Ячейка = РабочаяКнига.Cells(НомерСтроки,Ст);

			Если Ст = 1 Тогда

				Ячейка.Value = Модель;

			ИначеЕсли Ст = 2 Тогда

				Ячейка.Value = Строка(Разнорядка);

			ИначеЕсли Ст = 3 Тогда

				Ячейка.Value = КолПоДоговору;

			ИначеЕсли Ст = 4 Тогда

				Ячейка.Value = КолОтгрузили;

			ИначеЕсли Ст = 5 Тогда

				Ячейка.Value = КолОсталось;

			КонецЕсли;

		КонецЦикла;	

	КонецЦикла;

КонецЦикла; 

СводнаяТаблица = РабочаяКнига.ActiveSheet.PivotTableWizard;

//Метод СводнаяТаблица.Name возвращает имя сводной таблицы

//Можно задать имя таблицы СводнаяТаблица.Name = "МояТаблица"

СводнаяТаблица.SmallGrid = 0;

//Разворачивает макет сводной таблицы 



//Обращение к ячейкам сводной таблицы возможно по номеру

//Например, СводнаяТаблица.PivotFields(1).Value 

//возвращает значение "Модель"



//Попробуем с другого конца

//1 - Row

//2 - Column

//3 - Page

//4 - Data

СводнаяТаблица.PivotFields(1).Orientation = 1;    //Модель 

СводнаяТаблица.PivotFields(2).Orientation = 3;    //Разнорядка

СводнаяТаблица.PivotFields(3).Orientation = 4;    //По договору

СводнаяТаблица.PivotFields(4).Orientation = 4;    //Отгрузили

СводнаяТаблица.PivotFields(5).Orientation = 4;    //Осталось



//Пройдемся по форме отчета

СводнаяТаблица.Format(1);



//Попробуем закрыть панель инструментов сводной таблицы

РабочаяКнига.CommandBars("PivotTable").Visible = 0;

РабочаяКнига.Visible = 1;

Категория: Работа с Microsoft Office и OpenOffice

Получения курса валют из Интернет

Код 1C v 8.х

 Соединение = Новый HTTPСоединение("export.rbc.ru"); //готовим соединение

ИмяФайла = ПолучитьИмяВременногоФайла(".txt");

//строка-образец

//http://export.rbc.ru/free/cb.0/free.fcgi?period=DAILY&tickers=USD&d1=18&m1=01&y1=2009&d2=17&m2=02&y2=2009&lastdays=30&separator=TAB&data_format=BROWSER&header=1

//http://export.rbc.ru/free/cb.5/free.fcgi?period=DAILY&tickers=USDEUR_BASKET&d1=08&m1=07&y1=2009&d2=22&m2=07&y2=2009&lastdays=14&separator=TAB&data_format=BROWSER&header=1

СтрокаСоединения="/free/"+Источник+"/free.fcgi?period=DAILY&tickers="+Валюта1+"&d1="+День1+"&m1="+Месяц1+"&y1="+Год1+"&d2="+День2+"&m2="+Месяц2+"&y2="+Год2+"&separator=%7C&data_format=BROWSER";

СтрокаСоединения=СтрЗаменить(СтрокаСоединения," ","");



Попытка //соединяемся

Соединение.Получить(СтрокаСоединения,ИмяФайла);

Исключение

Сообщить("Невозможно получить курс по адресу http://export.rbc.ru"+СтрокаСоединения);

КонецПопытки;



КурсыТекст=Новый ТекстовыйДокумент; //читаем результат запроса

КурсыТекст.Прочитать(ИмяФайла);

Код 1C v 8.х

  // еще пример

 Функция ПолучитьКакСтроку(Адресс) 

	соминет = Новый COMОбъект("MSXML2.XMLHTTP");

	соминет.open ("GET", Адресс, Ложь);

	соминет.send();

	Возврат соминет.responseText;

КонецФункции	



Функция ПреобразоватьДату(дат)

	// Медот преобразования даты времен 1Сv7

	//Т=Строка(Дат);

	//Возврат Сред(Т,7,4)+"/"+Сред(Т,4,2)+"/"+Лев(Т,2);

	Возврат Формат(Дат,"ДФ=""гггг/ММ/дд""");

КонецФункции



Процедура КнопкаЗагрузитьКурсы(Элемент)

	//Список - список валют	

	Для А = 1 по Список.Количество() цикл

		Если Список[а-1].Пометка тогда

			Сообщить("Загружаем курсы для "+Строка(Список[а-1].Значение));

			Код = Строка(Список[а-1].Значение.Код);

			Дат = ПериодС;

			Пока Дат <= ПериодПо цикл

				Стр = ПолучитьКакСтроку("http://cbrates.rbc.ru/tsv/"+Код+"/"+ПреобразоватьДату(Дат)+".tsv");

				Поз = Найти(Стр,Символы.Таб);

				Если Поз = 0 Тогда

					Дат = Дат + 86400;

					Продолжить;

				КонецЕсли;					

				Кратность = Число(СокрЛП(Лев(стр,Поз-1)));

				курс = Число(СокрЛП(Сред(Стр,Поз+1,СтрДлина(Стр)-Поз)));

				Сообщить("Дата="+Строка(Дат)+" Курс="+Строка(курс)+" Кратность="+Строка(Кратность));

				Запись = РегистрыСведений.КурсыВалют.СоздатьМенеджерЗаписи();

				Запись.Период = Дат;

				Запись.Валюта = Список[а-1].Значение.Ссылка;

				Запись.Курс = Курс;

				Запись.Кратность = Кратность;

				Запись.Записать(Истина);

				Дат = Дат + 86400;                   

			КонецЦикла;				

		КонецЕсли;			

	КонецЦикла;		

КонецПроцедуры

Код 1C v 7.x

 // Взято с http://www.1c-club.kz     IUnknown

//Небольшая обработка для получения курса валют размещенной на странице Национального Банка РК.

//Внимание: работоспособность данной обработки может быть нарушена, если дизайнеры сайта НБ РК изменят формат страницы с //официальным курсом валюта. Но не большой анализ нового формата и работоспособность обработки будет восстановлена.

// шаблон для отображаемой на форме таблице значения

перем тзПустышка;



//*******************************************

// ПриНачалеВыбораЗначения(стрНазвание, чисФлаг)

//

// Параметры:

//  стрНазвание - Строка. Наименование реквизита формы инициюрующей

//                вызов процедуры.

//  чисФлаг     - Число. Флаг станадартной обработки иницации нажатия

//                кнопки выбора значения.

//

// Возвращаемое значение:

//  Нет.

//

// Описание:

//  Переопределенная процедура инициирующая при нажатии кнопки

//  выбора значения реквизита формы.

//

процедура ПриНачалеВыбораЗначения(стрНазвание, чисФлаг)

    // Если инициировали из реквизита "стрУРЛа"

    если стрНазвание = "стрУРЛа" тогда

        // откроем страницу с введенным URL

        запуститьприложение(стрУРЛа);

    конецесли;

конецпроцедуры



//*******************************************

// кнПолучить()

//

// Параметры:

//  Нет

//

// Возвращаемое значение:

//  Нет.

//

// Описание:

//  Процедура получающая курсы валют с URL находящегося в

//  строковом реквизите формы "стрУРЛа". Пытается по указаноому URL

//  получить страницу и распарсить ее.

//

//  ПРЕДУПРЕЖДЕНИЕ:

//  В случае измения формата данных представленных на странице, возможно

//  будет работать не правильно.

//

процедура кнПолучить()

    // сгенирим имя файла для временного хранения содержимого

    // страницы курса валют Национального банка

    стрИмяФайла = каталогпользователя() + "$$$$.###";

    // создадим объект XMLHttpRequest

    олеХМЛ = создатьобъект("Microsoft.XMLHTTP");

    // иницируем его типом запроса и нужным нам URL

    олеХМЛ.Open("GET", стрУРЛа, 0);

    // отправим запрос для обработки серверу

    олеХМЛ.Send();

    // создадим "поток" через ADODDB для работы с данными

    олеАДО = создатьобъект("ADODB.Stream");

    // зададим тип и режим потока

    олеАДО.Mode = 3;

    олеАДО.Type = 1;

    // откроем его

    олеАДО.Open();

    // создадим объект для управления скриптами

    олеШелл = создатьобъект("MSScriptControl.ScriptControl");

    // установим язык сценариев

    олеШелл.Language = "vbscript";

    // добавим созданные объекты

    олеШелл.AddObject("oleADO", олеАДО);

    олеШелл.AddObject("oleXML", олеХМЛ);

    // с помощью скрипта запишем в поток ADO данные из

    // объекта XMLHttpRequest

    // то есть содержимое страницы

    олеШелл.Eval("oleADO.Write(oleXML.ResponseBody)");

    // запишем данные во временный файл

    олеАДО.SaveToFile(стрИмяФайла, 2);

    // закроем данный поток

    олеАДО.Close();

    // для ускорения парсера занесем весь файл в строковую

    // переменую с разделителем строк

    // для этого инициализуруем поток установкой

    // соотвествующим режимом и типом

    олеАДО.Mode= 3;

    олеАДО.Type = 2;

    // так как страница курса валют НБК имеет формат

    // символов UTF-8, то установим соотвествующий набор

    олеАДО.CharSet="UTF-8";

    // откроем поток

    олеАДО.Open();

    // загрузим содержимое нашего файла в поток

    олеАДО.LoadFromFile(стрИмяФайла);

    // обнулим временную строковую переменную

    стрТемп = "";

    // в цикле получим из потока все строки

    пока олеАДО.EOS() = 0 цикл

        // и запишем их во временную переменую, добавив разделитель строк

        стрТемп = стрТемп + олеАДО.ReadText(-2) + разделительстрок;

    конеццикла;

    // закроем поток

    олеАДО.Close();

    // удалим временный файл

    фс.УдалитьФайл(стрИмяФайла);

    // найдем в строке позицию начала блока с данными о курсе

    чисПозиция = найти(стрТемп, "Официальные курсы валют на");

    если чисПозиция = 0 тогда

        // если позиции нет ... то мы имем другую страницу

        // или другой формат страницы...

        предупреждение("Не получилось получить курсы валют");

    иначе

        // создаим временную таблицу значений

        // для более шустрого заполения из-за отстуствия вызова

        // функции перерисовки таблицы при изменении данных

        тзТемп = создатьобъект("ТаблицаЗначений");

        // установим для нее нужный формат

        тзПустышка.Выгрузить(тзТемп);

        // отрежем все лишнее

        стрТемп = сред(стрТемп, чисПозиция);

        // получим дату курса

        дтКурса = дата(стрзаменить(стрполучитьстроку(стрТемп, 2), "/", "."));

        // первая строка с курсом валюты находится на 18 строке от начала

        // после удаления мусора

        чисПозиция = 18;

        // узнаем сколько всего строк в многострочке

        чисКоличествоСтрок = стрколичествострок(стрТемп);

        // получим строку

        стрТекущая = стрполучитьстроку(стрТемп, чисПозиция);

        // если в строке есть подстрока ... то значит это наверное очередная валюта

        пока найти(стрТекущая, "input type=""checkbox"" name=""idval""") > 0 цикл

            // добавляем новую строку

            тзТемп.НоваяСтрока();

            // получаем строку со смещением 1 от позиции

            стрТекущая = стрполучитьстроку(стрТемп, чисПозиция + 1);

            // используя фичу 1С по преобразованию, получим число

            // за сколько единиц валюты имеем курс в тенге

            тзТемп.Количество = число(стрТекущая);

            // путем убирания "мусора" получаем наименование валюты

            тзТемп.Наименование = сокрлп(стрзаменить(стрзаменить(стрТекущая, тзТемп.Количество, ""), "</td>", ""));

            // получаем строку со смещением 2 от позиции

            стрТекущая = стрполучитьстроку(стрТемп, чисПозиция + 2);

            // убираем html мусор

            стрТекущая = сокрлп(стрзаменить(стрзаменить(стрТекущая, "<td class=""gen7"" align=""center"">", ""), "</td>", ""));

            // получаем код валюты

            тзТемп.Код1 = лев(стрТекущая, 3);

            // получаем код валюты "Тенге"

            тзТемп.Код2 = прав(стрТекущая, 3);

            // получаем строку со смещением 5 от позиции

            стрТекущая = стрполучитьстроку(стрТемп, чисПозиция + 5);

            // очищаем от мусора и преобразуем в число... получаем курс

            тзТемп.Курс = число(стрзаменить(стрзаменить(стрТекущая, "<td class=""gen7"" align=""center"">", ""), "</td>", ""));

            // увеличиваем позицию на 17 ...

            чисПозиция = чисПозиция + 17;

            если чисПозиция > чисКоличествоСтрок тогда

                // если позици дальше имеющихся строк

                // то все курсов больше нет

                стрТекущая = "";

            иначе

                // получаем очередную строку для разбора

                стрТекущая = стрполучитьстроку(стрТемп, чисПозиция);

            конецесли;

        конеццикла;

        // сформированую таблицу копируем в таблицу на форме

        тзТемп.Выгрузить(тзКурсов);

    конецесли;

конецпроцедуры



//*******************************************

// установим значение реквизита текущим URL по которому можно получить курс валют

стрУРЛа = "http://www.nationalbank.kz/?docid=460&uid=DD54B73C-802C-E8F0-E27EDF82ECF77C1D";

// формируем формат таблицы

тзПустышка = создатьобъект("ТаблицаЗначений");

тзПустышка.НоваяКолонка("Количество", "число", 3, 0, "", 5);

тзПустышка.НоваяКолонка("Наименование", "строка", , , "Наименование", 70);

тзПустышка.НоваяКолонка("Код1", "строка", 3, , "код", 10);

тзПустышка.НоваяКолонка("Код2", "строка", 3, , "код", 10);

тзПустышка.НоваяКолонка("Курс", "число", 7, 2, "Курс", 10);

// копируем получившийся формат в таблицу на форме

тзПустышка.Выгрузить(тзКурсов);

Категория: COM-объекты, WMI, WSH