body » Поиск » HelpF.pro

Результаты по ключевому слову: body

Как мы писали парсер сайта с ценами для 1С

Недавно, мой постоянный клиент решил проводить маркетинговые исследования по изменению цен на товары у конкурентов... и эти данные захотел использовать в 1С в связке с его прайс-листом + куча отчетов с графиками и процентным отклонением от цен основного конкурента

В результате этого, была написана обработка собирающая данные со страниц разных сайтов. Из целей конфиденциальности - сайты раскрывать не буду...

Вид обработки загрузки данных с сайта в 1С

Ниже код загрузки данных со страницы сайта, смысл такой :

в функция передается адрес страницы сайта
полученный текст страницы обрабатывается, удаляются теги
из полученного текста формируется ТЗ с данными
По названию ищется поставщик из вспомогательного справочника Справочники.Pr_Поставщики.НайтиПоНаименованию(, если нет - создается
на выходе ТЗ с данными

Код 1C v 8.х

 Функция ПолучитьТаблицуДанных(Строка)

	

	тзДанных = Новый ТаблицаЗначений;

	Сервер = "site.ru";

	

	Соединение = Новый HTTPСоединение(Сервер);			

	Заголовки = Новый Соответствие;

	Заголовки.Вставить("host", Сервер);

	ТекАдрес = СтрЗаменить(Строка.Наименование.УРЛСтраницы,"http://","");

	ТекАдрес = СтрЗаменить(ТекАдрес,Сервер,"");

	Запрос = Новый HTTPЗапрос(ТекАдрес, Заголовки);

	Ответ =Соединение.Получить(Запрос);

	Если Ответ.КодСостояния = 200 Тогда // Данные получены, обрабатываем их

		Содержимое= Ответ.ПолучитьТелоКакСтроку();

		//Выведем тест полученной страницы

		НачалоБлока = "<table id=" + """" + "table-price" + """" + " cellspacing=" + """" + "0" + """" + " border=" + """" + "1" + """" + " bordercolor=" + """" + "#dedede" + """" + " class=" + """" + "tablesorter" + """" + " >";

		//НачалоБлока = "<div class=" + """" + "w100fl" + """" + " id=" + """" + "kurs" + """" + ">";

		КонецБлока = "</table>";

		ТекстБлока = Сред(Содержимое, Найти(Содержимое, НачалоБлока) + СтрДлина(НачалоБлока), Найти(Содержимое, КонецБлока) - Найти(Содержимое, НачалоБлока) - СтрДлина(НачалоБлока));

		    				

		//Обработаем тест  				

		обрТекст = СтрЗаменить(ТекстБлока,"<tr>","");

		обрТекст = СтрЗаменить(обрТекст,"</tr>",Символы.ПС);

		обрТекст = СтрЗаменить(обрТекст," >", ">");

		обрТекст = СтрЗаменить(обрТекст,"</th> <th>", " | ");

		обрТекст = СтрЗаменить(обрТекст,"</td> <td>", " | ");

	   	обрТекст = СтрЗаменить(обрТекст,"</th> <th class=" + """" + "sortable_header" + """" + ">", " | ");

		обрТекст = СтрЗаменить(обрТекст,"</th> <th >", " | ");

		обрТекст = СтрЗаменить(обрТекст,"</th><th>", " | ");

		обрТекст = СтрЗаменить(обрТекст,"</td><td>", " | ");

		обрТекст = СтрЗаменить(обрТекст," >", ">");

		RegExp = Новый COMОбъект("VBScript.RegExp");

		RegExp.IgnoreCase = Ложь; 

		RegExp.Global = Истина;    

		RegExp.MultiLine = Истина;    

		

		RegExp.Pattern = "<[^>]*>"; //Ищем теги HTML   

		обрТекст=RegExp.Replace(обрТекст, "");

		//Сообщить(обрТекст);

		

		Если СокрЛП(обрТекст) = "Ни одной позиции не найдено." Тогда

			Сообщить(Строка(Строка.Наименование)+ " = Ни одной позиции не найдено! Строка " + Строка.Наименование);

			Возврат тзДанных;

		КонецЕсли;





		Если Найти(обрТекст, "Страница не найдена") > 0 Тогда

			Сообщить(Строка(ТекАдрес)+" = Страница не найдена, строка " + Строка.Наименование);

			Возврат тзДанных;  

		КонецЕсли;

		

		//Преобразуем полученный текст в таблицу

		Для н=1 По СтрЧислоСтрок(обрТекст)Цикл

			СтрТекста=СтрПолучитьСтроку(обрТекст,н);

			Если Найти(СтрТекста, "Длина Цена") > 0 Тогда

				СтрТекста = СтрЗаменить(СтрТекста, "Длина Цена", "Длина | Цена");

			КонецЕсли;

			Если Найти(СтрТекста, "Марка стали Цена") > 0 Тогда

				СтрТекста = СтрЗаменить(СтрТекста, "Марка стали Цена", "Марка стали | Цена");

			КонецЕсли;

			Если Найти(СтрТекста, ",  Поставщик") > 0 Тогда

				СтрТекста = СтрЗаменить(СтрТекста, ",  Поставщик", " | Поставщик");

			КонецЕсли;

			//Выводим текст страницы построчно

			мсДанных = ПолучитьМассивИзСтрокиСРазделителем(СтрТекста, "|", Истина);

			Если н=1 Тогда

				Для Каждого ткЗнач из мсДанных Цикл

					СтрЗапрещСимволов = " .,<>""\/-";

					ИмяКолонки = ткЗнач;

					Для сч33 = 1 по СтрДлина(СтрЗапрещСимволов) Цикл

						ЗапрещСимв = Сред(СтрЗапрещСимволов, сч33, 1);

						ИмяКолонки = СтрЗаменить(ИмяКолонки, ЗапрещСимв, "_");

					КонецЦикла;

					

					// добавим нужное количество колонок- если перед колонкой Поставщик не хватает

					// бывает, что в шапке определяется меньше колонок, чем реально в таблице

					Если НРег(ИмяКолонки) = "поставщик" Тогда

						Для Сч_дк = (Строка.Наименование.Родитель.Поставшик - 2) по тзДанных.Колонки.Количество() Цикл

							тзДанных.Колонки.Добавить("Колонка_" + (тзДанных.Колонки.Количество() + 1));

						КонецЦикла;

					КонецЕсли;

					

					тзДанных.Колонки.Добавить(ИмяКолонки);

				КонецЦикла;

				тзДанных.Колонки.Добавить("ном", , , 7);

			Иначе 

				НовСтр = тзДанных.Добавить(); нмас=0;

				Для Каждого ткЗнач из мсДанных Цикл

					НовСтр[нмас] = ткЗнач;

					нмас=нмас+1;

				КонецЦикла;

				НовСтр.ном = н;

			КонецЕсли;

			//Сообщить(стр);

		КонецЦикла;

		тзДанных.Колонки.Добавить("ЕстьСоответствие", Новый ОписаниеТипов("Булево"));

		тзДанных.Колонки.Добавить("СпрPr_Поставщики", Новый ОписаниеТипов("СправочникСсылка.Pr_Поставщики"));

		

		Для каждого стр из тзДанных Цикл

			текПоставщик = Справочники.Pr_Поставщики.НайтиПоНаименованию(стр[Строка.Наименование.родитель.Поставшик-1]);

			Если текПоставщик = Справочники.Pr_Поставщики.ПустаяСсылка() Тогда

				НовЭлем = Справочники.Pr_Поставщики.СоздатьЭлемент();

				НовЭлем.Наименование = СокрЛП(стр[Строка.Наименование.родитель.Поставшик-1]);

				НовЭлем.Записать();

				текПоставщик = НовЭлем.Ссылка;

			КонецЕсли;

			стр.СпрPr_Поставщики = текПоставщик;

		КонецЦикла;

	Иначе

		тзДанных.Колонки.Добавить("ЕстьСоответствие", Новый ОписаниеТипов("Булево"));

		тзДанных.Колонки.Добавить("СпрPr_Поставщики", Новый ОписаниеТипов("СправочникСсылка.Pr_Поставщики"));

		

		Сообщить("Ошибка получения данных для строки " + Строка.Наименование);

	КонецЕсли;

	

	Возврат тзДанных;

	

КонецФункции

В коде используется вспомогательная функция ПолучитьМассивИзСтрокиСРазделителем

Код 1C v 8.2 УП

 // Функция разбивает строку разделителем.

// 

// Параметры:

//  пСтрока      - Строка - которую разбиваем;

//  *пРазделитель - Строка, "." - символ-разделитель;

//  *ОбрезатьНепечатныеСимволы - Булево, *Ложь.

//

// Возвращаемое значение:

//  Массив - фрагментов.

//

Функция ПолучитьМассивИзСтрокиСРазделителем(Знач Стр, Разделитель = ".", ОбрезатьНепечатныеСимволы = Ложь) Экспорт

	

	МассивСтрок = Новый Массив;

	

	Если Разделитель = " " Тогда

		Стр = СокрЛП(Стр);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = СокрЛ(Сред(Стр,Поз));

		КонецЦикла;

	Иначе

		ДлинаРазделителя = СтрДлина(Разделитель);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				Фрагмент = Стр;

				Если ОбрезатьНепечатныеСимволы Тогда

					Фрагмент = СокрЛП(Фрагмент);

				КонецЕсли;

				МассивСтрок.Добавить(Фрагмент);

				Возврат МассивСтрок;

			КонецЕсли;

			Фрагмент = Лев(Стр,Поз-1);

			Если ОбрезатьНепечатныеСимволы Тогда

				Фрагмент = СокрЛП(Фрагмент);

			КонецЕсли;

			МассивСтрок.Добавить(Фрагмент);

			Стр = Сред(Стр,Поз+ДлинаРазделителя);

		КонецЦикла;

	КонецЕсли;





	Возврат МассивСтрок;

		

КонецФункции // ПолучитьМассивИзСтрокиСРазделителем()

Конечно, перед тем как мы начали это делать - прошерстили интернет и нашли несколько решений , вот они:

Код 1C v 8.х

 Соединение = ПолучитьCOMОбъект("","Microsoft.XMLHTTP");

ИмяВременногоФайла=ПолучитьИмяВременногоФайла("htm");



Соединение.open("GET", "http://mamba.ru/my", 0);

Соединение.send();



//status: //404 - Not Found //200 - Ok

ТаймАут = 200;

Начало=ТекущаяДата();

Пока Соединение.readyState <> 4 И (ТаймАут=0 ИЛИ ТекущаяДата()-Начало<ТаймАут) Цикл

бфДиалоги.ксОбработкаПрерыванияПользователя();

КонецЦикла;



//Сохраняем во временный файл

обСохранитьДвоичныйБуферВФайл(Соединение.responseBody, ИмяВременногоФайла);



Соединение.open("POST", "http://mamba.ru/my");

Соединение.send("login=xxx&password=&&&");





Функция обСохранитьДвоичныйБуферВФайл(Буфер, ИмяФайла) Экспорт

    Поток = Новый COMОбъект("ADODB.Stream");

    Поток.Type = 1;  //Бинарный

       Поток.Mode = 3; 

    Поток.Open();

    Поток.Write(Буфер);

    Поток.SaveToFile(ИмяФайла);

    Поток.Close();

КонецФункции

Код 1C v 8.х

     НТТР = ПолучитьCOMОбъект("","Microsoft.XMLHTTP");

    ИмяФайлаОтвета = КаталогВременныхФайлов() + "filename.tmp";           

    НТТР.open("GET", "www.google.com",0,,); 

    НТТР.send();

    StreamTypeEnum = Новый Структура("adTypeBinary, adTypeText", 1, 2);

    ConnectModeEnum = Новый Структура(

            "adModeRead, adModeReadWrite, adModeRecursive, adModeShareDenyNone,

            |adModeShareDenyRead, adModeShareDenyWrite, adModeShareExclusive, 

            |adModeUnknown, adModeWrite", 1, 3, 4194304, 16, 4, 8, 12, 0, 2);

    SaveOptionsEnum = Новый Структура("adSaveCreateNotExist, adSaveCreateOverWrite", 1, 2);

    StreamOut = Новый COMОбъект("ADODB.Stream");

    StreamOut.Type = StreamTypeEnum.adTypeBinary;

    StreamOut.Mode = ConnectModeEnum.adModeReadWrite; //Нужны и чтение и запись   

    StreamOut.Open(); //Открыли на чтение и запись

    StreamOut.Write(НТТР.responseBody); 

    StreamOut.SaveToFile(ИмяФайлаОтвета, SaveOptionsEnum.adSaveCreateOverWrite); //"2" - перезапись файла

    StreamOut.Close();

И даже не этом сайте есть статья : Парсер сайта связного на 1С

Нужен парсер сайта в 1С!? - Обращайтесь, контакты в профиле

Категория: Работа с Интернет, Почтой (Mail), FTP

Отправка почты через CDO (работает c SSL)

&НаСервереБезКонтекста
Функция ПолучитьДанныеЯщикаСистемнойЗаписи()

СистемнаяУчетнаяЗаписьЭлектроннойПочты = Справочники.УчетныеЗаписиЭлектроннойПочты.СистемнаяУчетнаяЗаписьЭлектроннойПочты;

СтруктураНастроек = Новый Структура;
СтруктураНастроек.Вставить("СерверSMTP", СокрЛП(СистемнаяУчетнаяЗаписьЭлектроннойПочты.СерверИсходящейПочтыSMTP));
СтруктураНастроек.Вставить("ПользовательSMTP",СокрЛП(СистемнаяУчетнаяЗаписьЭлектроннойПочты.ПользовательSMTP));
СтруктураНастроек.Вставить("ПарольSMTP", СокрЛП(СистемнаяУчетнаяЗаписьЭлектроннойПочты.ПарольSMTP));
СтруктураНастроек.Вставить("ПортSMTP", СистемнаяУчетнаяЗаписьЭлектроннойПочты.ПортSMTP);
СтруктураНастроек.Вставить("Отправитель", СокрЛП(СистемнаяУчетнаяЗаписьЭлектроннойПочты.АдресЭлектроннойПочты));
СтруктураНастроек.Вставить("ИспользоватьSSL", СистемнаяУчетнаяЗаписьЭлектроннойПочты.ИспользоватьSSL);

Возврат СтруктураНастроек;

КонецФункции

//обработка, пример который приведен содержит ТЧ "НаОтправку" с реквизитами "Контрагент" - ссылка на справочник и "Файл" - строка, путь к файлу
//ПолучитьМассивКлиентов() - функция возвращает перечень всех клиентов из данной ТЧ
//
//АдресПолучателя(ЭлементМассива) - функция возвращает e-mail клиента
&НаКлиенте
Процедура ОтправкаПисем()

//тут был прочий код, не относящийся к отправке, он удален

МассивКлиенты = ПолучитьМассивКлиентов();
Для Каждого ЭлементМассива Из МассивКлиенты Цикл

//***************************************
Если АдресПолучателя(ЭлементМассива) = "" Тогда
Сообщить("У контрагента "+ЭлементМассива+" не указан email, письмо отправлено не будет!");
Продолжить;
КонецЕсли;

Кому = АдресПолучателя(ЭлементМассива);

Тема = "Документы";
Текст = "Документы";

СтруктураНастроек = ПолучитьДанныеЯщикаСистемнойЗаписи();

CDO_СерверSMTP = СтруктураНастроек.СерверSMTP;
CDO_ПользовательSMTP = СтруктураНастроек.ПользовательSMTP;
CDO_ПарольSMTP = СтруктураНастроек.ПарольSMTP;
CDO_ПортSMTP = СтруктураНастроек.ПортSMTP;
Отправитель = СтруктураНастроек.Отправитель;
ИспользоватьSSL = СтруктураНастроек.ИспользоватьSSL;

Письмо = Новый COMОбъект("CDO.Message");
Письмо.to = Кому;
Письмо.from = Отправитель;
Письмо.Sender = Отправитель;

//Письмо.cc=Копия;
//Письмо.bcc=СкрКопия;

Отбор = Новый Структура();
Отбор.Вставить("Контрагент",ЭлементМассива);
НайденныеСтроки = Объект.НаОтправку.НайтиСтроки(Отбор);
Для КАЖДОГО СтрДокументы ИЗ НайденныеСтроки ЦИКЛ
Письмо.AddAttachment(СокрЛП(СтрДокументы.Файл));
КонецЦикла;

Письмо.Subject = Тема;
Письмо.TextBody = Текст;
Письмо.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing").Value = 2;
Письмо.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver").Value = CDO_СерверSMTP;
Письмо.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate").Value = 1;// 0 - Do not authenticate; 1 - basic (clear-text) authentication; 2 - NTLM
Письмо.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername").Value = CDO_ПользовательSMTP;
Письмо.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword").Value = CDO_ПарольSMTP;
Письмо.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport").Value = CDO_ПортSMTP;

Если ИспользоватьSSL Тогда
Письмо.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl").Value = True;
КонецЕсли;
//Письмо.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl").Value = ИспользоватьSSL;
Письмо.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout").Value = 60;

Попытка
Письмо.Configuration.Fields.Update();
Исключение
Сообщить(ОписаниеОшибки());
Возврат;
КонецПопытки;

Попытка
Письмо.Send();
Исключение
Сообщить(ОписаниеОшибки());
КонецПопытки;
КонецЦикла;

Сообщить("Все...");
КонецПроцедуры

Категория: Работа с Интернет, Почтой (Mail), FTP

Как в 1С проложить маршрут используя GoogleMaps API V3

Клиенты частенько просят настроить отображение маршрутов перемещения по разным адресам в 1С, например для курьеров и т.д.

В примере описан способ отражения карт GoogleMaps в 1С:

Код 1C v 8.2 УП

 Для Каждого Стр Из НаВходе Цикл

		нСтр = ПроверкаСовпадений.Добавить();

		нСтр.Адрес = Стр.Адрес;

		нСтр.Контрагент = Стр.Контрагент;

		//Если адрес начальный или конечный - пропускаем

		Если Стр.НомерСтроки = 1 или Стр.НомерСтроки = НаВходе.Количество() Тогда

			Продолжить;

		КонецЕсли;

		опАдреса = опАдреса + "

		|waypts.push({location:'" + нСтр.Адрес + "',stopover:true});";

	КонецЦикла;

	//Подставляем параметры в макет "Карта"

	опМаршрут = ПолучитьМакет("Карта").ПолучитьТекст();

	опМаршрут = СтрЗаменить(опМаршрут,"[=-опАдреса-=]",опАдреса);

	опМаршрут = СтрЗаменить(опМаршрут,"[=-опНач-=]",опНач);

	опМаршрут = СтрЗаменить(опМаршрут,"[=-опКон-=]",опКон);

	ЭлементыФормы.Карта.УстановитьТекст(опМаршрут);

Скрипт отображения из макета Карта (выделила как VBS, но по факту это HTML):

Код VBS

 <HTML><HEAD>

<META content="text/html; charset=utf-8" http-equiv=Content-Type></META>

<META name=viewport content="initial-scale=1.0, user-scalable=no"></META>

<STYLE type=text/css>HTML {

	HEIGHT: 100%

}

BODY {

	HEIGHT: 100%; PADDING-BOTTOM: 0px; PADDING-TOP: 0px; PADDING-LEFT: 0px; MARGIN: 0px; PADDING-RIGHT: 0px

}

#map_canvas {

	HEIGHT: 100%

}

</STYLE>





<SCRIPT type=text/javascript src="http://maps.google.com/maps/api/js?sensor=false">

</SCRIPT>





<SCRIPT type=text/javascript>

var directionDisplay;

var directionsService = new google.maps.DirectionsService();

var map;





function initialize() {

 

  directionsDisplay = new google.maps.DirectionsRenderer();

  var chicago = new google.maps.LatLng(55.81234, 37.664425);

  var myOptions = {

    zoom: 6,

    mapTypeId: google.maps.MapTypeId.ROADMAP,

    center: chicago

  }

  map = new google.maps.Map(document.getElementById("map_canvas"), myOptions);

 

 

   directionsDisplay.setMap(map);

   calcRoute();

  	var trafficLayer = new google.maps.TrafficLayer();

trafficLayer.setMap(map);

}

  

function calcRoute() {

  var start = "[=-опНач-=]";

  var end = "[=-опКон-=]";

  var waypts = [];

  var checkboxArray = document.getElementById("waypoints");

  [=-опАдреса-=]

  var request = {

      origin: start, 

      destination: end,

      waypoints: waypts,

      optimizeWaypoints: true,

      travelMode: google.maps.DirectionsTravelMode.DRIVING

  };

  directionsService.route(request, function(response, status) {

    if (status == google.maps.DirectionsStatus.OK) {

      directionsDisplay.setDirections(response);

      var route = response.routes[0];

      var summaryPanel = document.getElementById("directions_panel");

      summaryPanel.innerHTML = "";

      // For each route, display summary information.

      

      for (var i = 0; i < route.legs.length; i++) {

        var routeSegment = i+1;

        summaryPanel.innerHTML += 'опЗаполнитьМаршрут("' + String.fromCharCode(routeSegment+65) + '","' + String.fromCharCode(route.legs.length+65) + '","' + route.legs[i].start_address + '","' + route.legs[i].end_address + '","' + route.legs[i].distance.text + '");';

      }

      

    }

  });

}



</SCRIPT>



<META name=GENERATOR content="MSHTML 11.00.9600.17239"></META><BASE href="v8config://c924c032-2565-45e2-b49f-9a30494bc69f/mdobject/ida329e781-b8d1-431e-9e2f-8321c1a691fc/8eb4fad1-1fa6-403e-970f-2c12dbb43e23"></BASE></HEAD>

<BODY onload=initialize()>

<DIV id=map_canvas style="HEIGHT: 100%; WIDTH: 100%"></DIV>

<DIV id=directions_panel style="MARGIN: 20px; DISPLAY: none; BACKGROUND-COLOR: #ffee77"></DIV></BODY></HTML>

Файл отображающий пример работы GoogleMaps API V3 - Прокладываем маршрут в 1С

Скрин это обработки

Категория: HTML, JS, VML

Управляем 1С со стороны используя web-сервис

Передача команд 1С на выполнение через ссылки в письме.
web-сервисы помогают интегрировать 1С с различными программами, делая её более гибкой. Статей в интеренете достаточно можно, но в основном там описывается выгрузка из 1С, обмен между двумя 1С или 1С и каким-то мощным программным продуктом написанным на C или других языках.
Для меня же была поставлена задача возможности управление 1С через браузер. Как пример: обрабатывать завершение задачи БП в 1С по ссылке в письме (примерно такого типа http://site.ru/?user=000000001&bp=000000555, т.е. отсюда видно, что пользователь 000000001 хочет закрыть задачу 000000555), т.е. пользователь со своего смартфона не имеющего доступа к 1С как таковому, должен получить возможность управлять ею извне. Собственно, более сложной задачей можно поставить написание собственных web-форм, более легких и компактных, с произвольным дизайном для управления 1С.
Задача с точки зрения написания кода 1С очень легкая. Основная сложность заключалась в освоении HTML и JavaScript для управления извне. Начальные знаний по этому вопросу я подчерпнул из статьи Примеры пользования web сервисов 1С из браузера.

Настройка 1С
Для возможности использовать 1С в вебе необходимо:
1. Установить модуль расширения веб-сервера;
title

2. Настроить Windows: доустановить компоненты IIS и настроить проверку подлинности. Всё это можно прочитать в статье Настройка веб-клиента 1С:Предприятие 8.2 под Windows 7 x64 и IIS.

Программирование 1С
Теперь можно приступить к конфигурированию.
title

1. Создадим Web-сервис Input:
1.1. Input имеет операцию InputData которая принимает два параметра: User и Command, и возвращает параметр типа "boolean (http://www.w3.org/2001/XMLSchema)". Текст функции InputData:

Код 1C v 8.х

 Функция InputData(User, Command)



    обДанные = Справочники.Данные.СоздатьЭлемент();



    обДанные.Наименование = User + ":" + Command;



    обДанные.Записать();



    Возврат Истина;



КонецФункции

1.2. Устанавливаем для Input URI пространства имен = "http://infostart.ru". Здесь может быть любое уникальное имя, обычно это ссылка на сайт.
1.3. Устанавливаем для Input имя файла публикации = "input.1cws". Это имя web-сервиса к которому будем устанавливать соединение.
2. Для наглядности примера создадим справочник Данные, все параметры оставим по умолчанию.
3. Публикуем нашу конфигурацию и web-сервис: Администрирование -> Публикация на веб сервере...
title

На этом конфигурирование заканчивается, всё остальное сделает за нас 1С.

Разработка HTML страницы
Эта часть далась для меня тяжело, т.к. я ещё только делаю первые шаги в этой теме. Буду рад замачаниям и советам. А так, я постараюсь объяснить всё на пальцах тем, кто как и я знаком по большей части с 1С.
После установки ISS (я уже давал ссылку в начале статьи) на диске C появится каталог C:\inetpub\wwwroot, в этом каталоге располагается сайт. Для локальной машины (на которой установили ISS) он виден так http://localhost/, ну а для пользователей извне, как-то так http://infostart.ru (по правде там немного сложнее, но не суть, мы сейчас не про это). Заглавная страница сайта будет грузиться из файла index.htm каталога C:\inetpub\wwwroot
title

Исходники файлов можно скачать здесь: Скачивать файлы может только зарегистрированный пользователь!

Код файла index.htm попытаюсь объяснить как могу, т.к. сам некоторые моменты не понимаю:

Код

[html xmlns="http://www.w3.org/1999/xhtml"] // Неважно. Используется в XHTML для объявления пространства имен.
[head] // Предназначен для хранения других элементов, цель которых — помочь браузеру в работе с данными.

[meta http-equiv="Content-Type" content="text/html; charset=utf-8" /] // Неважно. Мета-теги используются для указания описания.

[title]Тест веб сервиса 1С[/title] // Неважно. Определяет заголовок документа, то что видит пользователь как текст вкладки.

[script type="text/javascript" src="../js/connect1c.js"] [/script] // Важно. Подключение JavaScript библиотек. В моём случае это мой модуль соединения с 1С.
[script type="text/javascript" src="../js/parameters.js"] [/script] // Важно. А это модуль обработки параметров строки браузера.

[/head]

[body] // Предназначен для хранения содержания веб-страницы (контента), отображаемого в окне браузера.
[p id="response1C"][/p] // Важно. Метка response1C, куда вернёться ответ запроса 1С.
[/body]

[script type="text/javascript"] // Важно. Начало основного скрипта, который выдёргивает из строки браузера всё что идёт дальше знака вопроса,
а дальше парсит по определенному алгоритму. В нашем случае будут искаться ключевые слова "user=" и "command=".

user = GetParameter("user"); // Важно. Находим значение user. Сам метод GetParameter находится в библиотеке parameters.js, о которой поговорим чуть позже.
command = GetParameter("command"); // Важно. Находим значение command.

Inquiry1C(user, command); // Важно. Запрос к 1С с найденными параметрами. Сам метод Inquiry1C находится в библиотеке connect1c.js

[/script]

[/html]

Заменил < на [, а > - ], замените перед использованием обратно.
Рассмотрим библиотеку parameters.js, которая находится в папке C:\inetpub\wwwroot\js
f

Код

unction GetParameter(pName) { // Сам метод я нашёл на просторах интернета.

search = window.location.search; // window.location - это по сути URL, метод search этого объекта возвращает часть адреса после символа "?", включая символ "?".

begin = search.indexOf(pName) + pName.length + 1; // Вычисляем позицию начала строки значения параметра для вырезания. +1 - в нашем случае это знак "=".
Итого, для search = "?user=007" мы найдём позицию начала равной 6 (нумерация с нуля).
end = search.indexOf('&', begin); // Находим позицию конца выражения. В нашем случае, разделение параметров осуществляется знаком "&", и если мы его не найдём,
то позицией конца будет последний символ строки search (смотри дальше код).

if (end == -1) {
end = search.length;
};

return unescape(search.substring(begin, end)); // Метод unescape возвращает строку, содержащую данные типа charString (не знаю зачем это надо,
но видимо такое приведение типа здесь необходимо). Ну а метод substring - извлекает подстроку из строки.

}
Теперь рассмотрим библиотеку connect1c.js, которая также находится в папке C:\inetpub\wwwroot\js
function Inquiry1C(pUser, pCommand) { // Основной метод этой библиотеки. Запрос к 1С.

XMLHTTP = CreateRequestObject(); // Создание XML HTTP запроса. Сам метод я узнал из википедии.

XMLHTTP.open('POST', '../TestWeb/ws/Input.1cws', true, "Admin", "1"); // Создаём соединение типа POST, где второй параметр - адрес; параметр true - значит асинхронное,
то есть браузер не будет ждать ответа сервера, а продолжит работу; далее пользователь и пароль с правами на операцию InputData (этот тот метод, который мы написали в 1С),
саму операцию можно выполнять в привилегированном режиме, чтобы не мучиться с правами для пользователя Admin.

XMLHTTP.onreadystatechange = function() {WhenAnswering1C(XMLHTTP)}; // Когда 1С отработает, автоматически сработает метод WhenAnswering (о нём чуть ниже по тексту этой библиотеки).

XMLHTTP.send(''
+ ' '
+ ' '
+ ''
+ pUser + ' '
+ ''
+ pCommand + ' '
+ ' '); // Отправка XML запроса, где описывается метод к исполнению в 1С, с переданными параметрами из нашей строки URL.
// Строку запроса можно раскурить минут за 5

}

function CreateRequestObject() { // Чудо метод из википедии "Пример использования". По сути, ничего сложного.
if (typeof XMLHttpRequest === 'undefined') {
XMLHttpRequest = function() {
try { return new ActiveXObject("Msxml2.XMLHTTP.6.0"); }
catch(e) {}
try { return new ActiveXObject("Msxml2.XMLHTTP.3.0"); }
catch(e) {}
try { return new ActiveXObject("Msxml2.XMLHTTP"); }
catch(e) {}
try { return new ActiveXObject("Microsoft.XMLHTTP"); }
catch(e) {}
throw new Error("This browser does not support XMLHttpRequest.");
};
}
return new XMLHttpRequest();
}

function WhenAnswering1C(pXMLHTTP) { // Метод, который срабатывает после обработки запроса 1С.

status = StausRequest(pXMLHTTP); // Вычисляется статус для отправки сообщения пользователю (о нём чуть ниже).
document.getElementById("response1C").appendChild(document.createTextNode(status)); // Вывод на экран в помеченную область response1C (о ней я писал в основном файле).
Метод getElementById возвращает ссылку на узел документа.
Метод appendChild добавляет нод в конце списка дочерных нодов элемента, т.е. встраивает в нашу область нужный нам текст.

}

function StausRequest(pXMLHTTP) // Определение статуса.
{
status = "";
if (pXMLHTTP.readyState == 4) { // Опять же, читая википедию можно понять, readyState - это текущее состояние объекта (0 — не инициализирован, 1 — открыт,
2 — отправка данных, 3 — получение данных и 4 — данные загружены).
if (pXMLHTTP.status != 200) { // status - HTTP-статус в виде числа (404 — «Not Found», 200 — «OK» и т. д.)
status = "Запрос завершился неудачно. Ответ сервера: " + pXMLHTTP.responseText; // responseText -текст ответа на запрос.
Если состояние не 3 или 4, возвращает пустую строку.
}
else {
if (RequestSuccessful(pXMLHTTP)) { // Проверка ответа от 1С (о нём чуть ниже).
status = "Запрос отработан.";
}
else {
status = "Запрос был отклонён.";
};

};
};

return status;
}

function RequestSuccessful(pXMLHTTP) { // Проверка ответа от 1С. Здесь мы получим возвращаемое от 1С значение (в нашем случае 1С может вернуть тип булево).

DOM = pXMLHTTP.responseXML.getElementsByTagName("return")[0]; // responseXML - Текст ответа на запрос в виде XML, который затем может быть обработан посредством DOM.
Если состояние не 4, возвращает null.
response = DOM.childNodes[0].data; // Достаём данные из ответа.

return response == "true"; // Если правда, то правда

По правде, я не смог преобразовать сроку в булево, поэтому пришлось оставить так.

}

Проверка
Открываем браузер и вводим строку "localhost/?user=007&command=hello world!":
title

После чего можно открыть 1С и убедиться что создался элемент справочника:
title

На этом пример ознакомления управления 1С извне можно считать законченным

Автор: Soloist

Категория: WEB-сервисы, WS-ссылки, XDTO-пакеты

Парсер сайта на 1С

В этой статье я постараюсь описать процесс парсинга сайтов средствами 1С с примером.
Это статья не является инструкцией к применению, а лишь демонстрирует возможности 1С.

Что мы имеем?
1. Сайт в интернете, на котором располагается список товаров. В моем случае – это интернет магазин салона «Связной»
2. Понимание основ сайтостроения… хотя бы знание HTML тегов
3. Умение кодить в 1С 8

Для начала парсинга стоит определиться с тем что мы хотим спарсить и какая у нас будет иерархия. В моем случае это категория сотовых телефонов. Верхний уровень иерархии будет производители. Почему именно так? Потомы что я так захотел. Вы же вправе использовать любую иерархию.

Далее нам будут интересны такие поля как: Наименование, Цена, Картинка и Описание... ну и пожалую захватим операционную систему, чтобы пример получился более наглядным.

1. Создаем внешнюю обработку. Те, кто не знают как это сделать - дальше могут не читать
2. Создаем форму обработки с командной панелью снизу и сверху (они могут быть полезными)
3. Размещаем на ней Панель и обзываем первую страницу "СамСайт"
4. Кладем на страницу "СамСайт" ПолеHTMLДокумента и обзываем его к примеру "Сайт"
5. Переименовываем кнопку "Выполнить", которая находится на нижней панели в "Загрузить сайт"
6. Описываем процедуру нажатия на эту кнопку так:

Код 1C v 8.х

   ЭлементыФормы.Сайт.Перейти("http://www.svyaznoy.ru/catalog/phone/224"); //Категория с мобильными телефонами

7. Проверяем работу нашей обработки. У меня появился сайт связного. А у Вас?

Дальше сложнее. Все еще хочешь парсить сайты? Тогда читай:

Сам парсинг сайта заключается в обходе всех элементов загруженной страницы, выдергивания необходимой информации и запихивания их в табличную часть. Для этого:
1. Создадим табличную часть "Производители" с реквизитами "Отметка" (Булево), "Наименование" (Строка 100) и "Ссылка" (Строка 300).
2. Добавляем еще одну страницу на панели и обзываем ее "Производители"
3. Размещаем на этой странице одноименную табличную часть
4. Добавляем на нижней панели кнопку "Заполнить производителей" с кодом:

Код 1C v 8.х

        Для Каждого Стр из ЭлементыФормы.Сайт.Документ.body.all Цикл

              Если Стр.tagName = "H1" и Стр.innerText = "Производители" Тогда

                  Для Каждого опСтр из Стр.nextSibling.children Цикл

                      новСтр = Производители.Добавить();

                      новСтр.Наименование = опСтр.innerText;

                      новСтр.Ссылка = опСтр.firstChild.href;

                  КонецЦикла;

                  Возврат;

              КонецЕсли;

          КонецЦикла;

Здесь напрашиваются небольшие пояснения:
tagName - имя HTML тега в HTML документе
nextSubling - следующий элемент HTML документа от текущего
children - список дочерних элементов
firstChild - первый дочерний элемент от текущего
5. Проверям. При проверке важно, находиться на странице "СамСайт", чтобы заполнять производителей

Производители заполнены. Теперь к самим телефонам

1. Создаем табличную часть "Товары" с реквизитами "Производитель" (Строка 100), "Наименование" (Строка 100), "Цена" (Число 10,2), "Картинка" (Строка 300), "Описание" (Строка Неограниченная), "ОС" (строка 100), "Ссылка" (Строка,300)
2. Добавляем еще одну страницу на панели и обзываем ее "Товары"
3. Размещаем на этой странице одноименную табличную часть
4. Добавляем на нижней панели кнопку "Заполнить товары" с кодом:

Код 1C v 8.х

       Для Каждого Стр из Производители Цикл

          //Если отметку сняли - то не трогаем этого производителя

          Если Не Стр.Отметка Тогда

              Продолжить;

          КонецЕсли;

          Форма = ПолучитьФорму("ФормаТоваров");

          Форма.ЭлементыФормы.Сайт.Перейти(Стр.Ссылка);

          Форма.ТекущийПроизводитель = Стр;

          Форма.ОткрытьМодально();

      КонецЦикла;

5. Создаем форму обработки "ФормаТоваров"
6. Кладем на "ФормаТоваров" ПолеHTMLДокумента и называем его "Сайт"
7. На событие ДкументСформирован у ПоляHTMLДокумента пишем код:

Код 1C v 8.х

  Если ЭлементыФормы.Сайт.Документ.body.all.length>1 Тогда

          ГрузимТовары();

      КонецЕсли;

8. Создаем переменную в модуле формы
перем ТекущийПроизводитель Экспорт;
9. Создаем процедуру ГрузимТовары():

Код 1C v 8.х

       Процедура ГрузимТовары()

          Для Каждого Стр из ЭлементыФормы.Сайт.Документ.body.all Цикл

              Если Стр.className = "ct_desc cleared" Тогда

                  новСтр = Товары.Добавить();

                  Для Каждого опСтр из Стр.children Цикл

                      Если опСтр.className = "pic_and_comp" Тогда

                          новСтр.Картинка = СтрЗаменить(Сред(опСтр.firstChild.style.backgroundImage,5),")","")

                      КонецЕсли;

                      Если опСтр.className = "name" Тогда

                          новСтр.Наименование = опСтр.innerText;

                          новСтр.Ссылка = опСтр.firstChild.href;

                      КонецЕсли;

                      Если опСтр.className = "price" Тогда

                          новСтр.Цена = Число(СтрЗаменить(СтрЗаменить(опСтр.innerText,"-","")," ",""));

                      КонецЕсли;

                      Если опСтр.className = "desc" Тогда

                          новСтр.Описание = опСтр.innerText;//опСтр.innerHTML - если нужно вместе с тегами 



                      КонецЕсли;

                  КонецЦикла;



              КонецЕсли;



          КонецЦикла;

          Закрыть();

      КонецПроцедуры

10. Проверям. Все работает.

Дело осталось за "операционной системой" и еще надо загрузить картинки. Давайте по порядку. Чтобы получить "ОС" нам надо открыть этот товар и считать "ОС" оттуда. Для этого делаем следующее:

1. Добавляем на нижней панели кнопку "Доп Инфо" с кодом:

Код 1C v 8.х

 Для Каждого Стр из Товары Цикл

          Форма = ПолучитьФорму("ФормаДопИнфо");

          Форма.ЭлементыФормы.Сайт.Перейти(Стр.Ссылка);

          Форма.ТекущийТовар = Стр;

          Форма.ОткрытьМодально();

      КонецЦикла;

2. Создаем форму обработки "ФормаДопИнфо"
3. Кладем на "ФормаДопИнфо" ПолеHTMLДокумента и называем его "Сайт"
4. На событие ДкументСформирован у ПоляHTMLДокумента пишем код:

Код 1C v 8.х

   Если ЭлементыФормы.Сайт.Документ.body.all.length>1 Тогда

          ГрузимДопИнфо();

      КонецЕсли;

5. Создаем переменную в модуле формы
перем ТекущийТовар Экспорт;
6. Создаем процедуру ГрузимДопИнфо():

Код 1C v 8.х

       Процедура ГрузимДопИнфо();

          Для Каждого Стр из ЭлементыФормы.Сайт.Документ.body.all Цикл

              Если Стр.className = "card_spec" Тогда

                  Для Каждого опСтр из Стр.children Цикл

                      Если Найти(опСтр.innerText,"Операционная система:") Тогда

                          ТекущийТовар.ОС = СокрЛП(СтрЗаменить(опСтр.innerText,"Операционная система:",""));

                      КонецЕсли;

                  КонецЦикла;

              КонецЕсли;

          КонецЦикла;

          Закрыть();

      КонецПроцедуры

7. Проверяем и переходим к последнему пункту

Заметили как похожи две последние инструкции? То-то же. Стремился к универсальности. Ну и наконец последний этап - Сохраним все изображения к примеру на диск "С" в папку "связной". Поехали

1. Добавляем на нижней панели кнопку "Сохранить Картинки" с кодом:

Код 1C v 8.х

       Для Каждого Стр из Товары Цикл

              путьСамФайл = Лев(Стр.Картинка,Найти(Стр.Картинка,".jpg/") + 3);

              самФайл = СтрЗаменить(СтрЗаменить(ПутьСамФайл,"http://static.svyaznoy.ru/upload/iblock/",""),"/","");

              Стр.Картинка = СохранитьКартинкуСайта("C:\Svyaznoy",ПутьСамФайл,СамФайл);

          КонецЦикла;

2. Добавляем функцию СохранитьКартинкуСайта:

Код 1C v 8.х

       Функция СохранитьКартинкуСайта(КаталогСохранения,КартинкаНаСайте,КартинкаУНас)

              ИмяФайлаКартинки = КаталогСохранения + "\" + КартинкаУНас;

              ГетЗапрос = Новый COMОбъект("WinHttp.WinHttpRequest.5.1");

              ГетЗапрос.SetTimeouts(10000, 10000, 10000, 10000);

              БазовыйУРЛ = КартинкаНаСайте;

              Хидер1 = "Content-Type";

              Хидер2 = "image/jpg"; // Тип рисунка.

              ГетЗапрос.Open("GET", БазовыйУРЛ, False); // Синхронный режим.

              ГетЗапрос.setRequestHeader(Хидер1, Хидер2);

              ГетЗапрос.Send();

              СтатусОтправки = ГетЗапрос.status;

              Если СтатусОтправки <> 200 Тогда

                  Сообщить("Ошибка отправки запроса на: "

                      + КартинкаНаСайте);

                  Возврат "";

              КонецЕсли;        



              Стрим = Новый COMОбъект("ADODB.Stream");

              Стрим.Mode = 3;

              Стрим.Type = 1;

              Стрим.Open();

              Стрим.Write(ГетЗапрос.responseBody);



              Стрим.SaveToFile(ИмяФайлаКартинки, 2);

              Стрим.Close();

              Возврат ИмяФайлаКартинки;

      КонецФункции

На этом наша эпопея с парсингом закончена. Это всего лишь пример того, как это можно сделать. Приложив сюда немного своего кода - можно сделать парсер для любого сайта. Скачивать файлы может только зарегистрированный пользователь!

Имея парсер 1С - я могу спарсить все, кроме этого парсера. Имя два парсера 1С - я могу спарсить все
Автор: opx

Категория: Работа с Интернет, Почтой (Mail), FTP

Отправка отчетов из 1С по электронной почте (E-Mail)

Автоматическая генерация отчета "Анализ заказов поставщикам"
Отчет анализ заказов является штатным отчетом конфигурации 1С Управление производственным предприятием. Обработка для генерации отчета, рассматриваемая в данной статье, позволяет программно создать и настроить форму отчета, запустить его выполнение. Полученный результат сохраняется в файл Microsoft Excel (XLS, XLSX) и может быть отправлен по электронной почте.
Предлагаемое решение состоит из трех файлов: Скачивать файлы может только зарегистрированный пользователь!

service.vbs служит для запуска 1С предприятия и генерации отчета;
emailer.vbs - VBS скрипт предназначен для отправки результатов выполнения запроса отчета на указанный при настройке адрес электронной почты;
rep_email.epf - сама внешняя обработка для генерации отчета, выполняющая настройки отображаемых показателей, группировок строк и столбцов, установки требуемых отборов отчета, обеспечивает выполнение запроса и формирования табличного документа по макету отчета и сохранение сформированного отчета в XLS файл.

Запуск отчета выполняется посредством VBS файла (vbscript) при помощи "Назначенных заданий". VBS программа обеспечивает запуск приложения 1С, устанавливает соединение с сервером 1С и передает управление внешней обработке через экспортную функцию ReportNow(), размещенную в общем модуле обработки по генерации отчета. Пример VBS Script для выполнения внешней обработки 1С из командной строки:

Код VBS

 ' Установить соединение с сервером 1С

Set v81 = CreateObject("V81.Application")

res = v81.Connect("Srvr=Server1C;Ref = db1C;Usr=User1C;Pwd=Password1C")

' Передать управление внешней обработке по генерации Отчета Анализ Заказов

res = v81.ExternalDataProcessors.Create("C:\1C\Service\rep_email.epf").ThisObject.Report()

v81.Exit(false)



' Дать возможность 1С закрыть все открытые файлы и выгрузиться из памяти

WScript.Sleep(5000)



' Вызвать VBS скрипт отправки почты по E-Mail

Dim WshShell

Set WshShell = WScript.CreateObject("WScript.Shell")

WshShell.Run "C:\1C\ Service\emailer.vbs"

VBS E-Mail скрипт для отправки готового отчета в формате Excel создает новое электронное письмо на заданный адрес, в теле письма указывает пояснение к отчету, а в качестве вложения прикрепляет файл, создание и наполнение информацией которого была произведена при запуске service.vbs

Код VBS

 'Отправить сообщение с помощью локальной службы SMTP

Const cdoSendUsingPickup = 1

'Отправить сообщение с помощью сети (SMTP через сеть)

Const cdoSendUsingPort = 2

Const cdoAnonymous = 0

Const cdoBasic = 1

Const cdoNTLM = 2



Set objMessage = CreateObject("CDO.Message")

' Тема сообщения и адрес отправителя

objMessage.Subject = "Ежедневный отчет Анализ заказов поставщикам"

objMessage.From = """Генератор отчетов"" "

' Получатели письма указываются через " ; "

objMessage.To = "email@domain.org; recv@domain.net; last@domain.ru"

' Содержимое тела письма.

objMessage.TextBody = "JSC AUTO SERVICE. Please find Orders reporting in attachment." & vbCRLF & _

"------------------------------------------" & vbCRLF & _

"Best regards, Auto report service" & vbCRLF & _

"Support line: it@domian.ru" & vbCRLF



' Добавляем файл - вложение для отправки отчета по EMail

objMessage.AddAttachment "C:\1C\Service\ЗаказыПоставщику.xls"



' Секция настроек SMTP сервера для отправки почты.

objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2



' Имя или IP адрес SMTP Server

objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "mail.domain.ru"



' Тип используемой авторизации, NONE, Basic (Base64 encoded), NTLM

objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasic



' Авторизация на SMTP server

objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = "report@domain.ru"

' Пароль SMTP server

objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "youpassword"



' Порт SMTP Server port (обычно 25, но может быть и другим)

objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25

' Использование SSL для соединения (False или True)

objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = False

' Время ожидания соединения с почтовым сервером

objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60

' Сохранить настройки CDO для отправки сообщения

objMessage.Configuration.Fields.Update



' Отправить созданное почтовое сообщение с вложением отчета в формате XLS по указанному адресу

objMessage.Send

Внешняя обработка по запуску отчета "Анализ заказов поставщику" состоит из двух процедур. Первая - "ReportNow() Экспорт" служит для определения входной точки передачи управления от VBS к 1С. Вторая - "ОткрытьОтчетПоИмени()" - выполняет действия по настройке критериев отбора отчета, группировке строк и столбцов, определению состава количественных показателей. Данный способ вызова отчетов стандартной конфигурации широко применяется в различных формах 1С, и по мере развития конфигурации может быть позаимствован как минимум из нескольких форм списка справочников (Контрагенты, Номенклатура и т.д.). Исходный код первой функции: >

Код 1C v 8.х

 Процедура ReportNow() Экспорт

 // Вызывается из vbscript, выполняет работы с отчетом.

 ОткрытьОтчетПоИмени("АнализЗаказовПоставщикам");

КонецПроцедуры

Сохранение отчета из 1С в Excel
Процедура формирования формы отчета принимает в качестве параметра название объекта метаданных конфигурации, в данном случае - "АнализЗаказовПоставщикам". Очевидно, что в зависимости от типа отчета процедура будет меняться пропорционально используемым реквизитам. В рассматриваемом примере добавляется отбор по контрагенту. Для своего ключевого поставщика заменить значение искомого наименования на нужное.

Код 1C v 8.х

 Процедура ОткрытьОтчетПоИмени(НазваниеОтчета) Экспорт



// получаем отчет и открываем форму

// для построения отчета по названию отчета

Отчет = Отчеты[НазваниеОтчета].Создать();

Форма = Отчет.ПолучитьФорму(, , );

Форма.Открыть();



// Выполнить настройку отчета по умолчанию

Отчет.УстановитьНачальныеНастройки();



// Добавить требуемый отбор по поставщику

ТекОтбор = Отчет.УниверсальныйОтчет.ПостроительОтчета.Отбор.ДоговорКонтрагентаВладелец;

ТекОтбор.Использование = Истина;

ТекОтбор.Значение = Справочники.Контрагенты.НайтиПоНаименованию("Поставщик");

ТекОтбор.ВидСравнения = ВидСравнения.Равно;



// Добавляем специфичное для нас измерение в отборе - например, "осталось отгрузить"

// в данном случае из отчета уйдут позиции, по которым все получено.

Отчет.УниверсальныйОтчет.ПостроительОтчета.Отбор.Добавить("ОсталосьОтгрузитьЕдиницОтчетов");

ТекОтбор1 = ОтчетОстатки.УниверсальныйОтчет.ПостроительОтчета.Отбор.ОсталосьОтгрузитьЕдиницОтчетов;

ТекОтбор1.Использование = Истина;

ТекОтбор1.Значение = 0;

ТекОтбор1.ВидСравнения = ВидСравнения.Больше;



// Состав отдельных ключевых показателей

// для каждого отчета можно посмотреть в конфигураторе

Отчет.СостояниеОтгрузкиПоЗаказу = истина;

Отчет.НеОтгружено = Истина;

Отчет.ОтгруженоЧастично = Истина;



// После завершения настроек нажмем программно кнопку "Сформировать"

Отчет.СформироватьОтчет(ФормаОтчета.ЭлементыФормы.ПолеТабличногоДокументаРезультат);



// Сформировать путь и имя файла для сохранения отчета

мПутьШаблон="C:\1C\Service";

мФайлШаблон="ЗаказыПоставщику.xls";

ИмяФайла = мПутьШаблон + "\" + мФайлШаблон;



// Полученные в отчете цифры и данные сохраним в файл Excel

Если Не ИмяФайла = Неопределено Тогда

Форма.ЭлементыФормы.ПолеТабличногоДокументаРезультат.СохранятьСвойстваОтображения = Истина;

Форма.ЭлементыФормы.ПолеТабличногоДокументаРезультат.Записать(ИмяФайла, ТипФайлаТабличногоДокумента.XLS97);

КонецЕсли;



// Закрыть форму отчета после завершения работы

ФормаОтчета.Закрыть();

КонецПроцедуры

Для того, чтобы отладить обработку в режиме 1С:Предприятие, запущенного из конфигуратора можно создать экранную форму обработки и разместить в ней следующую процедур автоматического запуска отлаживаемого отчета:

Код 1C v 8.х

 Процедура ПередОткрытием(Отказ, СтандартнаяОбработка)

Отказ = истина;

ОткрытьОтчетПоИмени("АнализЗаказовПоставщикам");

КонецПроцедуры

Надеемся, что успешная комбинация внешней обработки для запуска отчета по расписанию и vbscript поможет в автоматизации бизнеса вашего предприятия. Данная редакция настроек больше ориентирована на менеджера поставщика для вашей компании, что отслеживать взаимное движение товаров и документов.
Источник

Руководство компании, хочет получать оперативную сводку продаж по фирме

Категория: Работа с Интернет, Почтой (Mail), FTP

QR код в 1С

Столкнулся с интересной задачей реализации генерации QR-кода в 1С 8.2 ( QR-код — матричный код (двухмерный штрихкод) ) Для генерации было использовано api от google (http://chart.apis.google.com/chart). Вот сайт, который работает с ним. После того, как вы вводите все параметры кода и нажимаете кнопку генерировать, получаем что-то вроде такой ссылки. По сути эта ссылка нам и нужна. Создав необходимый url можно скачать картинку, которая генерируется с помощью api.
И так в чем заключается подход:
1. Генерируем текст, который надо прописать в qr-коде.
2. Используя ссылку «http://chart.apis.google.com/chart?cht=qr&chs=230?230&chl=» +»Наш текст» скачиваем картинку.
3. Размещаем картинку в нашем табличном документе.
Код реализации:

Код 1C v 8.2 УП

 &НаСервере

Функция hex(Знач Значение)

    Значение=Число(Значение);

    Если Значение<=0 Тогда

        Результат="0";

    Иначе

        Значение=Цел(Значение);

        Результат="";

        Пока Значение>0 Цикл

            Результат=Сред("0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ",Значение%16 + 1,1)+Результат;

            Значение=Цел(Значение/16) ;

        КонецЦикла;

    КонецЕсли;

    Если СтрДлина(Результат) < 2 Тогда



        Результат = "0" + Результат;



    КонецЕсли;

    Возврат "%" + Результат;

КонецФункции



&НаСервере

Функция EncodeURL(URL)

    Рез = "";

    Для Сч = 1 По СтрДлина(URL) Цикл

        ch = Сред(URL,Сч,1);

        vch = КодСимвола(ch);



        Если ("A" <= ch ) И ( ch <= "Z") Тогда      // "A".."Z"

            Рез = Рез + ch;

        ИначеЕсли ("a" <= ch ) И ( ch <= "z") Тогда // "a".."z"

            Рез = Рез + ch;

        ИначеЕсли ("0" <= ch ) И ( ch <= "9") Тогда // "0".."9"

            Рез = Рез + ch;

        ИначеЕсли (ch = " ") ИЛИ ( ch = "+") Тогда          // space

            Рез = Рез + "+";

        ИначеЕсли (ch = "-" ) ИЛИ ( ch = "_")       // unreserved

            ИЛИ (ch = ".") ИЛИ (ch = "!")

            ИЛИ (ch = "~") ИЛИ (ch = "*")

            ИЛИ (ch = "") ИЛИ (ch = "(")

            ИЛИ (ch = ")") Тогда

            Рез = Рез + ch;

        ИначеЕсли (vch <= 127) Тогда        // other ASCII

            Рез = Рез + hex(vch);

        ИначеЕсли (vch <= 2047) Тогда       // non-ASCII <= 0x7FF

            Рез = Рез + hex(192 + Цел(vch / 64));

            Рез = Рез + hex(128 + (vch % 64));

        Иначе                   // 0x7FF < ch <= 0xFFFF

            Рез = Рез + hex(224 + Цел(vch / 4096));

            Рез = Рез + hex(128 + (Цел(vch / 64) % 64));

            Рез = Рез + hex(128 + (vch % 64));

        КонецЕсли;

    КонецЦикла;



    Возврат Рез;

КонецФункции // ()



&НаСервере

Функция СохранитьДвоичныйБуферВФайл(Буфер, ИмяФайла) Экспорт

    Поток = Новый COMОбъект("ADODB.Stream");

    Поток.Type = 1;  //Бинарный

    Поток.Mode = 3;

    Поток.Open();

    Поток.Write(Буфер);

    Поток.SaveToFile(ИмяФайла);

    Поток.Close();

КонецФункции



&НаСервере

Функция НапечататьКодСервер(ЗаказСсылка)

    ТабДок = Новый ТабличныйДокумент;

    ИмяВременногоФайла = ПолучитьИмяВременногоФайла("png");

    АдресНачало = "http://chart.apis.google.com/chart?cht=qr&chs=230x230&chl=";

    АдресКонец = ЗаказСсылка.Номер  + Символы.ПС + Заказссылка.Контрагент.Наименование;

    АдресКонец = СтрЗаменить(АдресКонец, " ", "+");

    АдресКонец = EncodeURL(АдресКонец);



    Соединение = ПолучитьCOMОбъект("","Microsoft.XMLHTTP");

    Соединение.open("GET", АдресНачало + АдресКонец,0,,);

    Соединение.send(null);

    СохранитьДвоичныйБуферВФайл(Соединение.responseBody, ИмяВременногоФайла);



    //Печать

    Макет = Документы.ЗаказПокупателя.ПолучитьМакет("МакетПечатиКода");

    Область = Макет.ПолучитьОбласть("Код");

    Область.Рисунки.КодРисунок.Картинка = Новый Картинка(ИмяВременногоФайла);

    ТабДок.Вывести(Область);

    Возврат ТабДок;

КонецФункции

Источник

Категория: COM-объекты, WMI, WSH

Создание писем, событий и задач в MS Outlook из 1С

Отправка писем из 1С Предприятия – одна из самых необходимых функций, отсутствующая в штатном функционале платформы. Один из вариантов реализации – это подключение к MS Outlook по технологии OLE. В статье приведены примеры создания писем, событий и задач в MS Outlook из 1С. Автоматическое создание событий и задач используется не часто, но порой бывает очень удобно.

Для 1С 8.х замените

Код 1C v 7.x

 Outlook = СоздатьОбъект("Outlook.Application");

на

Код 1C v 8.х

 Outlook = Новый COMОбъект("Outlook.Application");

так же посмотрите: Отправка почтового сообщения на локальный MS Office Outlook с вложенным файлом

Создание сообщения

Код 1C v 7.x

  //создать новое сообщение из 1С в MS Outlook

Процедура СоздатьПисьмо(Адрес,ПутьКВложению)



       Попытка

             Outlook = СоздатьОбъект("Outlook.Application");

             ЕстьОшибка = 0;

       Исключение

             Предупреждение("Не удалось создать объект Outlook.Application");

             ЕстьОшибка = 1;

       КонецПопытки;

      

       Если ЕстьОшибка = 0 Тогда



             Письмо = Outlook.CreateItem(0);

             Письмо.Subject = "Тема письма";

             Письмо.Body = "Текст письма";

             Письмо.Recipients.Add(Адрес);



             Если ФС.СуществуетФайл(ПутьКВложению)=1 Тогда

                   Письмо.Attachments.Add(ПутьКВложению);

             КонецЕсли;



             Письмо.Display();

       Иначе

             Тема = "Тема письма";

             ТекстПисьма = "Текст письма";

             СтрокаЗапуска = "mailto:" + Адрес + "?subject=" + Тема + "&body=" + ТекстПисьма;

             ЗапуститьПриложение(СтрокаЗапуска);

       КонецЕсли;

КонецПроцедуры

Создание события

Код 1C v 7.x

 //создать запись в календаре событий из 1С в MS Outlook

Процедура СоздатьСобытие()

       Попытка

            Outlook = СоздатьОбъект("Outlook.Application");

       Исключение

             Предупреждение("Не удалось создать объект Outlook.Application");

             Возврат;

       КонецПопытки;



       Событие = Outlook.CreateItem(1);

       Событие.Subject = "Название события";

       Событие.Start = "15.01.2010 15:00:00";

       Событие.End = "15.01.2010 16:00:00";

       Событие.Body = "Описание события";

       Событие.Location = "Место события";

       Событие.ReminderMinutesBeforeStart = 15;

       Событие.BusyStatus = 0;

       Событие.MeetingStatus = 0;

       Событие.Sensitivity = 2;

       Событие.Save();

       Сообщить("Событие в календаре создано успешно","i");

КонецПроцедуры

Создание задачи

Код 1C v 7.x

 //создать новую задачу из 1С в MS Outlook

Процедура СоздатьЗадачу(ДатаСтартаЗадачи)



       Попытка

             Outlook = СоздатьОбъект("Outlook.Application");

       Исключение

             Предупреждение("Не удалось создать объект Outlook.Application");

             Возврат;

       КонецПопытки;

      

       Задача = Outlook.CreateItem(3);

       Задача.Subject = "Название задачи";

       Задача.StartDate = ДатаСтартаЗадачи;

       Задача.Body = "Описание задачи";

       Задача.Status = 0;

       Задача.Display();

       Задача.Importance = 2;

       Задача.ReminderSet = 1;

       Задача.ReminderTime = "" + ДатаСтартаЗадачи + " 9:00:00";

       //Задача.Save();

КонецПроцедуры

Категория: Работа с Microsoft Office и OpenOffice

1C и Google Maps

была поставлена задача отображения на географической карте медицинских учреждений. После обзора предлагаемых решений был выбран сервис google. Но так же подобного рода подход будет работать и с картами сервиса yandex. Во время решения задачи было решено использовать геокодирование сервиса Google и Google Visualization для отображение элементов на карте.

Геокодирование – процесс преобразования адресов·(Украина, Киевская область, Киев, Крещатик 20) в географические координаты (широта 37.423021 и долгота -122.083739), которые можно использовать для размещения маркеров или расположения карты. Подробно про геокодирование можно почитать тут.

Для работы с геокодированием необходимо зарегистрировать ключ API карт Google.

Важный момент: если у вас программа работает в локальной сети и в Internet, то вам необходимо регистрировать два ключа. В зависимости от того, с какого места подключается пользователь к базе подставлять тот или иной ключ.

И так, собственно программная реализация.

В конфигурации есть две общих формы:
* Форма подбора координат. Данная форма формирует запрос на геокодирование и обрабатывает результат.
* Форма отображения объектов. Данная форма использует API визуализации Google. В частности данная форма использует визуализацию Map.

Запрос и обработка результата геокодирования.

Формирование запроса происходит с ключом output=csv, для вывода результата запроса в csv файл. После выполнения запроса проверяется код результата запроса и разбор csv файла на широту и долготу.

Код 1C v 8.2 УП

 #НаСервере

Процедура ОтправитьЗапросНаПоискКоординат()

   Город = Параметры.ОбъектПодбора.Город.Наименование;

   Страна = Параметры.ОбъектПодбора.Город.Владелец.Владелец.Наименование;

   Адрес = Параметры.ОбъектПодбора.Адрес;

   ПараметрПоиска = Страна + " " + Город + " " + Адрес;

 

   АдресOutput = ПолучитьИмяВременногоФайла();

   Ключ = Константы.КлючКарта.Получить();

   ТекстСсылки = "maps/geo?q=" + EncodeURL(ПараметрПоиска)+"&amp;output=csv&amp;oe=utf8&amp;sensor=false&amp;key=" + Ключ;

   ПроксиСервер = Неопределено;

   HTTPСервис = Новый HTTPСоединение("maps.google.com",,,,ПроксиСервер,Ложь);

   ПравильностьВыполнения = Истина;

 

   Попытка

      HTTPСервис.Получить(ТекстСсылки, АдресOutput);

   Исключение

      Сообщить(ОписаниеОшибки(), СтатусСообщения.Важное);

      ПравильностьВыполнения = Ложь;

   КонецПопытки;

 

   Если ПравильностьВыполнения Тогда

      // Распарсить результат ответа поиска

      Текст = Новый ТекстовыйДокумент;

      Текст.Прочитать(АдресOutput);

      РезультатПоиска = Текст.ПолучитьСтроку(1);

 

      КодРезультата = Лев(РезультатПоиска,3);

      РезультатПоиска = Сред(РезультатПоиска, 7, СтрДлина(РезультатПоиска));

 

      Если КодРезультата &lt;&gt; "200" Тогда

         Возврат;

      КонецЕсли;

 

      Широта = Число(Сред(РезультатПоиска,0,10));

      Долгота = Число(Сред(РезультатПоиска,12,10));

   КонецЕсли;

КонецПроцедуры

Формирование карты отображения
При формировании отображения объекта на карте к стандартному коду визуализации добавлен следующий:

Код 1C v 8.х

 if(!google.visualization) setTimeout(checkIfGoogleLoad, 1000);

      else drawMap();

Это связано с тем, что платформа не хочет сразу обновлять фрейм поля html документа.

Код 1C v 8.2 УП

 #НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

   СсылкаНаБазу = ПолучитьНавигационнуюСсылкуИнформационнойБазы();

   APIГугла = Константы.КлючКарта.Получить();

 

   ТаблицаОбъектовДляВывода = Новый ТаблицаЗначений;

   ТаблицаОбъектовДляВывода.Колонки.Добавить("Наименование",Новый ОписаниеТипов("Строка"));

   ТаблицаОбъектовДляВывода.Колонки.Добавить("Город",Новый ОписаниеТипов("Строка"));

   ТаблицаОбъектовДляВывода.Колонки.Добавить("Адрес",Новый ОписаниеТипов("Строка"));

   ТаблицаОбъектовДляВывода.Колонки.Добавить("Широта",Новый ОписаниеТипов("Число",Новый КвалификаторыЧисла(10,6)));

   ТаблицаОбъектовДляВывода.Колонки.Добавить("Долгота",Новый ОписаниеТипов("Число",Новый КвалификаторыЧисла(10,6)));

   Если Параметры.ОтображатьСОтветственными Тогда

      ТаблицаОбъектовДляВывода.Колонки.Добавить("Ответственный",Новый ОписаниеТипов("Строка"));

   КонецЕсли;

 

   Для Каждого ТекЭлемент Из Параметры.ОбъектыДляОтображения Цикл

      КоординатыОбъекта = ОбщийМодульКартаСервер.ПолучитьКоординатыОбъекта(ТекЭлемент.Значение.ОбъектПосещения);

      Если КоординатыОбъекта = Неопределено Тогда

         Продолжить;

      Иначе

         НоваяСтрока = ТаблицаОбъектовДляВывода.Добавить();

         НоваяСтрока.Наименование = ТекЭлемент.Значение.ОбъектПосещения.Наименование;

         НоваяСтрока.Город = ТекЭлемент.Значение.ОбъектПосещения.Город.Наименование;

         НоваяСтрока.Адрес = ТекЭлемент.Значение.ОбъектПосещения.Адрес;

         НоваяСтрока.Широта = КоординатыОбъекта[0];

         НоваяСтрока.Долгота = КоординатыОбъекта[1];

         Если Параметры.ОтображатьСОтветственными Тогда

            НоваяСтрока.Ответственный = ТекЭлемент.Значение.Ответственный.Наименование;

         КонецЕсли;

      КонецЕсли;

   КонецЦикла;

 

   ТекстСкрипта = "data.addRows(" + Строка(ТаблицаОбъектовДляВывода.Количество()) + ");";

   Сч = 0;

   Для Каждого ТекСтрока Из ТаблицаОбъектовДляВывода Цикл

      ТекстСкрипта = ТекстСкрипта + " data.setCell(" + Строка(Сч) + ", 0, " +СтрЗаменить(Строка(ТекСтрока.Широта),",",".") + ");";

      ТекстСкрипта = ТекстСкрипта + " data.setCell(" + Строка(Сч) + ", 1, " +СтрЗаменить(Строка(ТекСтрока.Долгота),",",".") + ");";

      ТекстСкрипта = ТекстСкрипта + " data.setCell(" + Строка(Сч) + ", 2, '" +Строка(ТекСтрока.Наименование) + " "

      + Строка(ТекСтрока.Город) + " " + Строка(ТекСтрока.Адрес) + " " + ?(Параметры.ОтображатьСОтветственными, ".Ответственный: " + Строка(ТекСтрока.Ответственный), "") + " " + "');";

      Сч = Сч + 1;

   КонецЦикла;

СтраницаХТМЛ = "<html>

|  <head>

|    <script src=""http://maps.google.com/maps?file=api&v=2&key=" + APIГугла + """ type=""text/javascript""></script>

|    <script type=""text/javascript"" src=""http://www.google.com/jsapi""></script>

|  </head>

|

|  <body>

|    <div id=""map_div"" style=""width: 800px; height: 550px""></div>

|    <script type=""text/javascript"">

|

|      google.load(""visualization"", ""1"", {packages:[""map"">);

|      google.setOnLoadCallback(drawMap);

|      function checkIfGoogleLoad() {

|        if(!google.visualization) setTimeout(checkIfGoogleLoad, 1000);

|		else drawMap();

|      }

|      function drawMap() {

|        var data = new google.visualization.DataTable();

|        data.addColumn('number', 'Lat');

|        data.addColumn('number', 'Lon');

|        data.addColumn('string', 'Name');" + ТекстСкрипта + "

|        var map = new google.visualization.Map(document.getElementById('map_div'));

|        map.draw(data, {showTip: true, mapType: 'normal'});

|      }

|      checkIfGoogleLoad();

|    </script>

|  </body>

|</html>"; 

КонецПроцедуры

Андрей Данилюк

Категория: COM-объекты, WMI, WSH

Получения курса валют из Интернет

Код 1C v 8.х

 Соединение = Новый HTTPСоединение("export.rbc.ru"); //готовим соединение

ИмяФайла = ПолучитьИмяВременногоФайла(".txt");

//строка-образец

//http://export.rbc.ru/free/cb.0/free.fcgi?period=DAILY&tickers=USD&d1=18&m1=01&y1=2009&d2=17&m2=02&y2=2009&lastdays=30&separator=TAB&data_format=BROWSER&header=1

//http://export.rbc.ru/free/cb.5/free.fcgi?period=DAILY&tickers=USDEUR_BASKET&d1=08&m1=07&y1=2009&d2=22&m2=07&y2=2009&lastdays=14&separator=TAB&data_format=BROWSER&header=1

СтрокаСоединения="/free/"+Источник+"/free.fcgi?period=DAILY&tickers="+Валюта1+"&d1="+День1+"&m1="+Месяц1+"&y1="+Год1+"&d2="+День2+"&m2="+Месяц2+"&y2="+Год2+"&separator=%7C&data_format=BROWSER";

СтрокаСоединения=СтрЗаменить(СтрокаСоединения," ","");



Попытка //соединяемся

Соединение.Получить(СтрокаСоединения,ИмяФайла);

Исключение

Сообщить("Невозможно получить курс по адресу http://export.rbc.ru"+СтрокаСоединения);

КонецПопытки;



КурсыТекст=Новый ТекстовыйДокумент; //читаем результат запроса

КурсыТекст.Прочитать(ИмяФайла);

Код 1C v 8.х

  // еще пример

 Функция ПолучитьКакСтроку(Адресс) 

	соминет = Новый COMОбъект("MSXML2.XMLHTTP");

	соминет.open ("GET", Адресс, Ложь);

	соминет.send();

	Возврат соминет.responseText;

КонецФункции	



Функция ПреобразоватьДату(дат)

	// Медот преобразования даты времен 1Сv7

	//Т=Строка(Дат);

	//Возврат Сред(Т,7,4)+"/"+Сред(Т,4,2)+"/"+Лев(Т,2);

	Возврат Формат(Дат,"ДФ=""гггг/ММ/дд""");

КонецФункции



Процедура КнопкаЗагрузитьКурсы(Элемент)

	//Список - список валют	

	Для А = 1 по Список.Количество() цикл

		Если Список[а-1].Пометка тогда

			Сообщить("Загружаем курсы для "+Строка(Список[а-1].Значение));

			Код = Строка(Список[а-1].Значение.Код);

			Дат = ПериодС;

			Пока Дат <= ПериодПо цикл

				Стр = ПолучитьКакСтроку("http://cbrates.rbc.ru/tsv/"+Код+"/"+ПреобразоватьДату(Дат)+".tsv");

				Поз = Найти(Стр,Символы.Таб);

				Если Поз = 0 Тогда

					Дат = Дат + 86400;

					Продолжить;

				КонецЕсли;					

				Кратность = Число(СокрЛП(Лев(стр,Поз-1)));

				курс = Число(СокрЛП(Сред(Стр,Поз+1,СтрДлина(Стр)-Поз)));

				Сообщить("Дата="+Строка(Дат)+" Курс="+Строка(курс)+" Кратность="+Строка(Кратность));

				Запись = РегистрыСведений.КурсыВалют.СоздатьМенеджерЗаписи();

				Запись.Период = Дат;

				Запись.Валюта = Список[а-1].Значение.Ссылка;

				Запись.Курс = Курс;

				Запись.Кратность = Кратность;

				Запись.Записать(Истина);

				Дат = Дат + 86400;                   

			КонецЦикла;				

		КонецЕсли;			

	КонецЦикла;		

КонецПроцедуры

Код 1C v 7.x

 // Взято с http://www.1c-club.kz     IUnknown

//Небольшая обработка для получения курса валют размещенной на странице Национального Банка РК.

//Внимание: работоспособность данной обработки может быть нарушена, если дизайнеры сайта НБ РК изменят формат страницы с //официальным курсом валюта. Но не большой анализ нового формата и работоспособность обработки будет восстановлена.

// шаблон для отображаемой на форме таблице значения

перем тзПустышка;



//*******************************************

// ПриНачалеВыбораЗначения(стрНазвание, чисФлаг)

//

// Параметры:

//  стрНазвание - Строка. Наименование реквизита формы инициюрующей

//                вызов процедуры.

//  чисФлаг     - Число. Флаг станадартной обработки иницации нажатия

//                кнопки выбора значения.

//

// Возвращаемое значение:

//  Нет.

//

// Описание:

//  Переопределенная процедура инициирующая при нажатии кнопки

//  выбора значения реквизита формы.

//

процедура ПриНачалеВыбораЗначения(стрНазвание, чисФлаг)

    // Если инициировали из реквизита "стрУРЛа"

    если стрНазвание = "стрУРЛа" тогда

        // откроем страницу с введенным URL

        запуститьприложение(стрУРЛа);

    конецесли;

конецпроцедуры



//*******************************************

// кнПолучить()

//

// Параметры:

//  Нет

//

// Возвращаемое значение:

//  Нет.

//

// Описание:

//  Процедура получающая курсы валют с URL находящегося в

//  строковом реквизите формы "стрУРЛа". Пытается по указаноому URL

//  получить страницу и распарсить ее.

//

//  ПРЕДУПРЕЖДЕНИЕ:

//  В случае измения формата данных представленных на странице, возможно

//  будет работать не правильно.

//

процедура кнПолучить()

    // сгенирим имя файла для временного хранения содержимого

    // страницы курса валют Национального банка

    стрИмяФайла = каталогпользователя() + "$$$$.###";

    // создадим объект XMLHttpRequest

    олеХМЛ = создатьобъект("Microsoft.XMLHTTP");

    // иницируем его типом запроса и нужным нам URL

    олеХМЛ.Open("GET", стрУРЛа, 0);

    // отправим запрос для обработки серверу

    олеХМЛ.Send();

    // создадим "поток" через ADODDB для работы с данными

    олеАДО = создатьобъект("ADODB.Stream");

    // зададим тип и режим потока

    олеАДО.Mode = 3;

    олеАДО.Type = 1;

    // откроем его

    олеАДО.Open();

    // создадим объект для управления скриптами

    олеШелл = создатьобъект("MSScriptControl.ScriptControl");

    // установим язык сценариев

    олеШелл.Language = "vbscript";

    // добавим созданные объекты

    олеШелл.AddObject("oleADO", олеАДО);

    олеШелл.AddObject("oleXML", олеХМЛ);

    // с помощью скрипта запишем в поток ADO данные из

    // объекта XMLHttpRequest

    // то есть содержимое страницы

    олеШелл.Eval("oleADO.Write(oleXML.ResponseBody)");

    // запишем данные во временный файл

    олеАДО.SaveToFile(стрИмяФайла, 2);

    // закроем данный поток

    олеАДО.Close();

    // для ускорения парсера занесем весь файл в строковую

    // переменую с разделителем строк

    // для этого инициализуруем поток установкой

    // соотвествующим режимом и типом

    олеАДО.Mode= 3;

    олеАДО.Type = 2;

    // так как страница курса валют НБК имеет формат

    // символов UTF-8, то установим соотвествующий набор

    олеАДО.CharSet="UTF-8";

    // откроем поток

    олеАДО.Open();

    // загрузим содержимое нашего файла в поток

    олеАДО.LoadFromFile(стрИмяФайла);

    // обнулим временную строковую переменную

    стрТемп = "";

    // в цикле получим из потока все строки

    пока олеАДО.EOS() = 0 цикл

        // и запишем их во временную переменую, добавив разделитель строк

        стрТемп = стрТемп + олеАДО.ReadText(-2) + разделительстрок;

    конеццикла;

    // закроем поток

    олеАДО.Close();

    // удалим временный файл

    фс.УдалитьФайл(стрИмяФайла);

    // найдем в строке позицию начала блока с данными о курсе

    чисПозиция = найти(стрТемп, "Официальные курсы валют на");

    если чисПозиция = 0 тогда

        // если позиции нет ... то мы имем другую страницу

        // или другой формат страницы...

        предупреждение("Не получилось получить курсы валют");

    иначе

        // создаим временную таблицу значений

        // для более шустрого заполения из-за отстуствия вызова

        // функции перерисовки таблицы при изменении данных

        тзТемп = создатьобъект("ТаблицаЗначений");

        // установим для нее нужный формат

        тзПустышка.Выгрузить(тзТемп);

        // отрежем все лишнее

        стрТемп = сред(стрТемп, чисПозиция);

        // получим дату курса

        дтКурса = дата(стрзаменить(стрполучитьстроку(стрТемп, 2), "/", "."));

        // первая строка с курсом валюты находится на 18 строке от начала

        // после удаления мусора

        чисПозиция = 18;

        // узнаем сколько всего строк в многострочке

        чисКоличествоСтрок = стрколичествострок(стрТемп);

        // получим строку

        стрТекущая = стрполучитьстроку(стрТемп, чисПозиция);

        // если в строке есть подстрока ... то значит это наверное очередная валюта

        пока найти(стрТекущая, "input type=""checkbox"" name=""idval""") > 0 цикл

            // добавляем новую строку

            тзТемп.НоваяСтрока();

            // получаем строку со смещением 1 от позиции

            стрТекущая = стрполучитьстроку(стрТемп, чисПозиция + 1);

            // используя фичу 1С по преобразованию, получим число

            // за сколько единиц валюты имеем курс в тенге

            тзТемп.Количество = число(стрТекущая);

            // путем убирания "мусора" получаем наименование валюты

            тзТемп.Наименование = сокрлп(стрзаменить(стрзаменить(стрТекущая, тзТемп.Количество, ""), "</td>", ""));

            // получаем строку со смещением 2 от позиции

            стрТекущая = стрполучитьстроку(стрТемп, чисПозиция + 2);

            // убираем html мусор

            стрТекущая = сокрлп(стрзаменить(стрзаменить(стрТекущая, "<td class=""gen7"" align=""center"">", ""), "</td>", ""));

            // получаем код валюты

            тзТемп.Код1 = лев(стрТекущая, 3);

            // получаем код валюты "Тенге"

            тзТемп.Код2 = прав(стрТекущая, 3);

            // получаем строку со смещением 5 от позиции

            стрТекущая = стрполучитьстроку(стрТемп, чисПозиция + 5);

            // очищаем от мусора и преобразуем в число... получаем курс

            тзТемп.Курс = число(стрзаменить(стрзаменить(стрТекущая, "<td class=""gen7"" align=""center"">", ""), "</td>", ""));

            // увеличиваем позицию на 17 ...

            чисПозиция = чисПозиция + 17;

            если чисПозиция > чисКоличествоСтрок тогда

                // если позици дальше имеющихся строк

                // то все курсов больше нет

                стрТекущая = "";

            иначе

                // получаем очередную строку для разбора

                стрТекущая = стрполучитьстроку(стрТемп, чисПозиция);

            конецесли;

        конеццикла;

        // сформированую таблицу копируем в таблицу на форме

        тзТемп.Выгрузить(тзКурсов);

    конецесли;

конецпроцедуры



//*******************************************

// установим значение реквизита текущим URL по которому можно получить курс валют

стрУРЛа = "http://www.nationalbank.kz/?docid=460&uid=DD54B73C-802C-E8F0-E27EDF82ECF77C1D";

// формируем формат таблицы

тзПустышка = создатьобъект("ТаблицаЗначений");

тзПустышка.НоваяКолонка("Количество", "число", 3, 0, "", 5);

тзПустышка.НоваяКолонка("Наименование", "строка", , , "Наименование", 70);

тзПустышка.НоваяКолонка("Код1", "строка", 3, , "код", 10);

тзПустышка.НоваяКолонка("Код2", "строка", 3, , "код", 10);

тзПустышка.НоваяКолонка("Курс", "число", 7, 2, "Курс", 10);

// копируем получившийся формат в таблицу на форме

тзПустышка.Выгрузить(тзКурсов);

Категория: COM-объекты, WMI, WSH

Практическая работа с почтой (E-mail,The Bat, Outlook, Mozilla Thunderbird)

Код 1C v 8.х

 Попытка

    ОтправитьПоПочте2(ТекСтрока); // работает с Батом

Исключение

    Попытка

    ОтправитьПоПочте1(ТекСтрока); // работает с Аутлуком, но переспрашивает при отправке

    Исключение

        Сообщить_и_записать("Ошибка при отправке почты - "+ОписаниеОшибки(),СтатусСообщения.Важное);

    КонецПопытки;

КонецПопытки;



Процедура ОтправитьПоПочте1(ТекСтрока)

    Почта = Новый Почта;

    Сообщение = Новый ПочтовоеСообщение;

    //Работает с Аутглуком, но переспрашивает при отправке

    //не работает с Батом 3.60

    Почта.Подключиться("name@mysite.dp.ua","password");

   

    Сообщение.Вложения.Добавить(ПолучитьИмяФайлаПодразделения(ТекСтрока.филиал.наименование));

    Сообщение.Получатели.Добавить(ТекСтрока.филиал.email);

    Сообщение.Тема ="Проигнорированные документы в офисе. Письмо сгенерированно роботом";

    Сообщение.Текст="Проверьте, будь ласка эти документы ПОСЛЕ получения обновления из офиса. Ваши изменения в этих документах не попали в базу. Откройте прикрепленный файл";

    Почта.Послать(Сообщение);

    Почта.Отключиться();

    УдалитьФайлы(ПолучитьИмяФайлаПодразделения(ТекСтрока.филиал.наименование));

КонецПроцедуры           



Процедура ОтправитьПоПочте2(ТекСтрока)

    ПочтовыйПрофиль = Новый ИнтернетПочтовыйПрофиль;

    ПочтовыйПрофиль.АдресСервераPOP3   = "pop3.mysite.dp.ua";

    ПочтовыйПрофиль.АдресСервераSMTP   = "smtp.mysite.dp.ua";

    ПочтовыйПрофиль.ПортSMTP           = 25;

    ПочтовыйПрофиль.ПортPOP3           = 110;

    ПочтовыйПрофиль.Пользователь       = "name";

    ПочтовыйПрофиль.Пароль             = "password";

    ПочтовыйПрофиль.ВремяОжидания      = 60;

       

    Сообщение = Новый ИнтернетПочтовоеСообщение ;

    Сообщение.Вложения.Добавить(ПолучитьИмяФайлаПодразделения(ТекСтрока.филиал.наименование));

    Сообщение.Получатели.Добавить(ТекСтрока.филиал.email);

    Сообщение.Тема ="Проигнорированные документы в офисе. Письмо сгенерированно роботом";

    Сообщение.ИмяОтправителя="Обмен";

    Сообщение.Отправитель="name@mysite.dp.ua";

       

    Текст = Сообщение.Тексты.Добавить("Проверьте, будь ласка эти документы ПОСЛЕ получения обновления из офиса. Ваши изменения в этих документах не попали в базу. Откройте прикрепленный файл");

    Текст.ТипТекста = ТипТекстаПочтовогоСообщения.ПростойТекст;

   

    Почта = Новый ИнтернетПочта();

    Почта.Подключиться(ПочтовыйПрофиль);

    Почта.Послать(Сообщение);

    Почта.Отключиться();

    УдалитьФайлы(ПолучитьИмяФайлаПодразделения(ТекСтрока.филиал.наименование));

КонецПроцедуры

А вот так 1с работает с Мозилой Сундербердом (который хорошо поддерживает IMAP):

Код 1C v 8.х

  ПутьМозиллы = """C:/Program Files/Mozilla Thunderbird/thunderbird.exe""";

    Текст = Новый ЗаписьТекста(КаталогОбмена + "sendfiletofilial"+Строка(ТекСтрока.филиал.наименование)+".bat", КодировкаТекста.OEM);

    Текст.ЗаписатьСтроку("@echo off");

    Текст.ЗаписатьСтроку("@echo Отправка проигнорированных писем на филиал"+Строка(ТекСтрока.филиал.наименование));

    СтрокаЗапуска = " -compose to='"+ТекСтрока.филиал.email+"',cc='name@mysite.dp.ua',subject=""Проигнорированные документы в офисе. Письмо сгенерированно роботом"",body=""Проигнорированные документы в офисе. Письмо сгенерированно роботом"",attachment=""file://";

    Файл = """"+ПолучитьИмяФайлаПодразделения(ТекСтрока.филиал.наименование)+"""";

    Текст.ЗаписатьСтроку(ПутьМозиллы+СтрокаЗапуска +Файл);

    Текст.ЗаписатьСтроку("del "+Файл);

    Текст.Закрыть();

    ЗапуститьПриложение(КаталогОбмена + "sendfiletofilial"+Строка(ТекСтрока.филиал.наименование)+".bat",КаталогОбмена)

Получение почты

Код 1C v 8.х

 

Процедура КнопкаВыполнитьНажатие(Кнопка)

  Почта = Новый ИнтернетПочта;



    Профиль = Новый ИнтернетПочтовыйПрофиль;

    Профиль.АдресСервераPOP3 = "192.168.0.2";



    Профиль.Пользователь = "romix";

    Профиль.Пароль = "ТутНапишитеПароль";



    Почта.Подключиться(Профиль);



    МассивПисем = Почта.Выбрать(Ложь);



    Для Каждого Письмо из МассивПисем Цикл

        Сообщить("Получено письмо с заголовоком: "+Письмо.Тема);

        Для Каждого Вложение из Письмо.Вложения Цикл

            Сообщить("Вложение: "+Вложение.ИмяФайла);

            Вложение.Данные.Записать("c:\tempdata\"+Вложение.ИмяФайла);

        КонецЦикла;    

        Для Каждого Текст из Письмо.Тексты Цикл

            Сообщить("Текст: "+Текст.Текст);

            Текст.Данные.Записать("c:\tempdata\ТекстСообщения.txt");

        КонецЦикла;    

    КонецЦикла;



КонецПроцедуры

Автор: 1CLama

Категория: Работа с Интернет, Почтой (Mail), FTP

Запустить приложение через COMОбъект

Код 1C v 8.х

 Процедура ЗапуститьПриложениеShell(Команда)

	Попытка

		Shell = Новый COMОбъект("Shell.Application");

		Shell.ShellExecute(Команда, "", "", "open", 1);

	Исключение

		Сообщить(ОписаниеОшибки());

	КонецПопытки;

КонецПроцедуры





//Пример обращения к процедуре



//Запустить Открытие файла

ЗапуститьПриложениеShell("d:\primer.xls");



//Запустить Веб-сайт

ЗапуститьПриложениеShell("https://helpf.pro");



//Запустить Веб-сайт ICQ c информацией о контакте 12345

ЗапуститьПриложениеShell("http://wwp.icq.com/scripts/contact.dll?msgto=12345");



//Запустить Отправление письма на Info@helpf.pro и в теме указать "Вопрос!" и в тексте "Здравствуй, уважаемый Веб-мастер!"

ЗапуститьПриложениеShell("mailto:Info@helpf.pro?Subject=Вопрос!&body=Здравствуй, уважаемый Веб-мастер!");

Категория: COM-объекты, WMI, WSH