count » Поиск » HelpF.pro

Результаты по ключевому слову: count

Перезагрузка сервера 1С:Предприятия

Перезагрузка сервера выполняется автоматически, если в течение некоторого времени (обычно 3 минут) к серверу 1С:Предприятия не подсоединен ни один пользователь. Если этого добиться затруднительно, то сервер можно перезагрузить принудительно при помощи утилиты Start/ Settings/ Control Panel/ Administrative Tools/ Component Services, на том компьютере, на котором установлен сервер 1С:Предприятия. Для этого в ней необходимо найти ветку Console Root/ Component Services/ Computers/ My Computer/ COM+ Applications/ 1CV8 и выполнить пункт Shut down ее локального меню.

Перезагрузка сервера может быть выполнена программно. Это можно сделать, например, при помощи следующего кода на встроенном языке 1С:Предприятия 8.0:

Код 1C v 8.х

 COMPlus = Новый COMОбъект("COMAdmin.COMAdminCatalog");

Приложения = COMPlus.GetCollection("Applications");

Приложения.Populate();

ПоследнийНомер = Приложения.Count - 1;

Для Номер = 0 по ПоследнийНомер Цикл

    Приложение = Приложения.Item(Номер);

    Если Приложение.Name = "1CV8" Тогда

        COMPlus.ShutdownApplication(Приложение.Name);

        Прервать;

    КонецЕсли;

КонецЦикла;

ВНИМАНИЕ! Если в момент перезагрузки серверного приложения 1CV8 к нему были подсоединены пользователи, то их работа завершится аварийно. При этом какие-то данные могут оказаться не сохраненными.

Категория: Администрирование

Функция проверки типа значения

Код 1C v 8.х

 

// Функция возвращает Истина при соответствии типов, ложь в обратном случае

Функция НужныйТипЗнач(ИсхЗнач,ТипЗнач)

	Возврат ТипЗнч(ИсхЗнач) = Тип(ТипЗнач);

КонецФункции



// Некоторые примеры обращения

// ИсхЗнач  - проверяемое значение

// НужныйТипЗнач(ИсхЗнач,"Строка")

// НужныйТипЗнач(глЗначениеПеременной("глТекущийПользователь"),"СправочникСсылка.Пользователи")

// НужныйТипЗнач(ИсхЗнач,"Форма")

// НужныйТипЗнач(ИсхЗнач,"Булево")

// НужныйТипЗнач(ИсхЗнач,"Строка") 

// НужныйТипЗнач(ИсхЗнач,"Число")

// НужныйТипЗнач(ИсхЗнач,"Дата"))

// НужныйТипЗнач(ИсхЗнач,"Массив") 

// НужныйТипЗнач(ИсхЗнач,"Структура") 

// НужныйТипЗнач(ИсхЗнач,"Соответствие")

// НужныйТипЗнач(ИсхЗнач,"СписокЗначений")

// НужныйТипЗнач(ИсхЗнач,"ТаблицаЗначений")

// НужныйТипЗнач(ИсхЗнач,"ДеревоЗначений")

// НужныйТипЗнач(ИсхЗнач,"ПланСчетовСсылка.Хозрасчетный") 

// НужныйТипЗнач(ИсхЗнач,"ПланСчетовСсылка.Налоговый") 

// НужныйТипЗнач(ИсхЗнач,"ХранилищеЗначения")

// НужныйТипЗнач(ИсхЗнач,"Картинка")

// НужныйТипЗнач(ИсхЗнач,"ПолеВвода")

// НужныйТипЗнач(ИсхЗнач,"Панель")

// НужныйТипЗнач(ИсхЗнач,"Флажок")	

// НужныйТипЗнач(ИсхЗнач,"РегистрРасчетаНаборЗаписей.УправленческиеНачисления")

// НужныйТипЗнач(ИсхЗнач,"ПланВидовРасчетаСсылка.ОсновныеНачисленияОрганизаций") 

// НужныйТипЗнач(ИсхЗнач,"ДокументСсылка.ОтпускПоУходуЗаРебенком")

// НужныйТипЗнач(ИсхЗнач,"ИнтернетПочтовоеСообщение")

// НужныйТипЗнач(ИсхЗнач, "БизнесПроцессСсылка.м_Документооборот")

Код 1C v 7.x

 

// Функция возвращает 1 при соответствии типов, 0 в обратном случае

Функция НужныйТипЗнач(ИсхЗнач,ТипЗнач)

	Если ТипЗначенияСтр((ИсхЗнач) = ТипЗнач тогда

		Возврат 1;

	Иначе

		Возврат 0;

	КонецЕсли;

КонецФункции



// Некоторые примеры обращения

// ИсхЗнач  - проверяемое значение

// НужныйТипЗнач(ИсхЗнач,"Строка")



// Значения типов данных:

// ''Число'' (''Number'') - числовой тип данных;

// ''Строка'' (''String'') - строковый тип данных;

// ''Дата'' (''Date'') - тип данных Дата;

// ''Перечисление'' (''Enum'') - агрегатный тип данных ''Перечисление'';

// ''Справочник'' (''Reference'') - агрегатный тип данных ''Справочник'';

// ''Документ'' (''Document'') - агрегатный тип данных ''Документ'';

// ''Регистр'' (''Register'') - агрегатный тип данных ''Регистр'';

// ''Календарь'' (''Calendar'') - агрегатный тип данных ''Календарь'';

// ''ВидРасчета'' (''Calculation'') - агрегатный тип данных ''ВидРасчета'';	

// ''ЖурналРасчетов'' (''CalcJournal'') - агрегатный тип данных ''ЖурналРасчетов'';

// ''ПланСчетов'' (''ChartOfAccounts'') - агрегатный тип данных ''ПланСчетов'';

// ''Счет'' (''Account'') - агрегатный тип данных ''Счет'';

// ''Операция'' (''Operation'') - агрегатный тип данных ''Операция'';

// ''КорректныеПроводки'' (''CorrectEntries'') - агрегатный тип данных ''КорректныеПроводки'';

// ''БухгалтерскиеИтоги'' (''BookkeepingTotals'') - агрегатный тип данных ''БухгалтерскиеИтоги'';

// ''Таблица'' (''Table'') - агрегатный тип данных ''Таблица'';

// ''Текст'' (''Text'') - агрегатный тип данных ''Текст'';

// ''Запрос'' (''Query'') - агрегатный тип данных ''Запрос'';

// ''СписокЗначений'' (''ValueList'') - агрегатный тип данных ''СписокЗначений'';

// ''ТаблицаЗначений'' (''ValueTable'') - агрегатный тип данных ''ТаблицаЗначений'';

// ''Периодический'' (''Periodic'') - агрегатный тип данных ''Периодический'';

// ''Картинка'' (''Picture'') - агрегатный тип данных ''Картинка'';

// ''ГрупповойКонтекст'' (''GroupContext'') - контекст программного модуля или Формы;

// ''OLE'' (''OLE'') - OLE-объект.

// ''НеизвестныйОбьект'' (''UnknownObject'') - для типов, для которых в системе не предусмотрено специальное строковое обозначение;

// '''' (пустая строка)  - неопределенный тип данных.

Категория: Работа с Типами данных

Кратко: Установка на сервер MS SQL Server 7.0-2000 и 1С 7.7 SQL: Категория: Администрирование

Подключение к EXCEL и чтение данных из листа Excel

Код 1C v 8.х

 Ex = Новый COMObject("Excel.Application");

   Ex.Workbooks.Open(Путь);

   Ex.Visible = 1;    

   ТекЛист=Ex.WorkSheets(1);        

   Для Ячейка = 1 по 400 цикл

       Если НЕ  ТекЛист.Cells(Ячейка,1).Value  = Неопределено тогда

           Сообщить(Строка(ТекЛист.Cells(Ячейка,1).Value));    

           Карта = Справочники.Номенклатура.НайтиПоКоду(ИзЧислаВСтроку(ТекЛист.Cells(Ячейка,1).Value));    

           Если Карта.Пустая() тогда        

               Сообщить(" Пустой элемент "  + ТекЛист.Cells(Ячейка,1));

           иначе

               Объект = Карта.ПолучитьОбъект();

               Объект.ОсновнойПоставщик = ОсновнойКлиент;

               Объект.Записать();

               конецесли;    

       конецесли;

   конеццикла;

Примеры процедур для чтения данных из EXCEL

Код 1C v 8.х

 

// Функция получает данные из файла Excel

//

// Параметры:

//   пФайл - Имя файла

//   пЛист - Имя листа с данными

//   СтруктураКолонок - Структура вида "ИмяКолонки" - "НомерКолонки"

//                      если не задано, созадуться колонки вида "К1", "К2"

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция Excel_ПолучитьДанные_ADO(пФайл, пЛист, СтруктураКолонок = Неопределено, Знач НачСтрока = 0, Знач КонСтрока = 0) Экспорт



    #Если Клиент Тогда

    Состояние("Установка соединения с Excel");

    #КонецЕсли



    //ЗаголовкиВСтроке1 = "HDR=YES;"

    ЗаголовкиВСтроке1 = "HDR=NO;";



    СтрокаСоединения ="Provider=Microsoft.Jet.OLEDB.4.0;Data Source= " + СокрЛП(пФайл) +" ;Extended Properties=""Excel 8.0;" + ЗаголовкиВСтроке1 + "IMEX=1;""";



    Connection = Новый COMОбъект("ADODB.Connection");

    Connection.ConnectionString =  СтрокаСоединения;



    Попытка

        Connection.Open();

    Исключение

        Сообщить ("Проблемы с подключением к Excel" );

        Возврат Неопределено;

    КонецПопытки;



    RS = Новый COMОбъект("ADODB.Recordset");



    ТекстЗапроса =

    "S_elect

    |    Лист.*

    |FROM

    |    [" + пЛист + "$] as Лист";



    Попытка

        RS.Open(ТекстЗапроса, Connection);

    Исключение

        Сообщить ("Проблемы с выполнением запроса");

        Возврат Неопределено;

    КонецПопытки;



    Таблица = Новый ТаблицаЗначений;



    Если СтруктураКолонок = Неопределено Тогда



        Для Счетчик = 1 По RS.Fields.Count Цикл

            Поле = RS.Fields.Item(Счетчик - 1);

            Колонка = Таблица.Колонки.Добавить("К" + Счетчик, , Поле.Name);

        КонецЦикла;



    Иначе



        Для каждого КлючИЗначение Из СтруктураКолонок Цикл

            Колонка = Таблица.Колонки.Добавить(КлючИЗначение.Ключ);

        КонецЦикла;



    КонецЕсли;



    НомерСтроки = 0;

    КолвоСтрок  = RS.RecordCount;



    Пока RS.EOF() = 0 Цикл



        НомерСтроки = НомерСтроки + 1;



        #Если Клиент Тогда

        Состояние("Чтение файла: " + Формат(НомерСтроки) + " из " + Формат(КолвоСтрок));

        ОбработкаПрерыванияПользователя();

        #КонецЕсли



        Если НомерСтроки < НачСтрока Тогда

            RS.MoveNext();

            Продолжить;

        КонецЕсли;



        Если КонСтрока > 0 И НомерСтроки > КонСтрока Тогда

            Прервать;

        КонецЕсли;



        НоваяСтрока = Таблица.Добавить();



        Если СтруктураКолонок = Неопределено Тогда



            Для Счетчик = 1 По RS.Fields.Count Цикл



                Поле = RS.Fields.Item(Счетчик - 1);

                НоваяСтрока["К" + Счетчик] = Поле.Value;



            КонецЦикла;



        Иначе



            Для каждого КлючИЗначение Из СтруктураКолонок Цикл



                Поле = RS.Fields.Item(КлючИЗначение.Значение - 1);

                НоваяСтрока[КлючИЗначение.Ключ] = Поле.Value;



            КонецЦикла;



        КонецЕсли;



        // Обработка других полей

        RS.MoveNext();



    КонецЦикла;



    // Завершение работы



    RS.Close();

    Connection.Close();



    Возврат Таблица;



КонецФункции



// Функция получает данные из файла Excel

//

// Параметры:

//   пФайл     - Имя файла

//   пЛист     - Имя листа с данными

//   СтруктураКолонок - Структура вида "ИмяКолонки" - "НомерКолонки"

//                      если не задано, созадуться колонки вида "К1", "К2"

//   XLSОбъект - COM объект типа "Excel.Application"

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция Excel_ПолучитьДанные_COM(пФайл, пЛист, СтруктураКолонок = Неопределено, Знач НачСтрока = 0, Знач КонСтрока = 0, XLSОбъект = Неопределено) Экспорт



    #Если Клиент Тогда

    Состояние("Открытие Excel");

    #КонецЕсли



    Если XLSОбъект = Неопределено Тогда

        XLSОбъект = Новый COMОбъект("Excel.Application");

        XLSОбъект.Visible       = Ложь;

        XLSОбъект.DisplayAlerts = Ложь;

    КонецЕсли;



    Попытка

        Book = XLSОбъект.Workbooks.Open(пФайл, , Истина);

    Исключение

        Сообщить ("Проблемы с подключением к Excel" );

        Возврат Неопределено;

    КонецПопытки;



    Лист = Book.Sheets(1);

    КолвоКолонок = Лист.Cells(1,1).SpecialCells(11).Column;

    КолвоСтрок   = Лист.Cells(1,1).SpecialCells(11).Row;



    Таблица = Новый ТаблицаЗначений;



    Если СтруктураКолонок = Неопределено Тогда



        Для Счетчик = 1 По КолвоКолонок Цикл

            Колонка = Таблица.Колонки.Добавить("К" + Счетчик);

        КонецЦикла;



    Иначе



        Для каждого КлючИЗначение Из СтруктураКолонок Цикл

            Колонка = Таблица.Колонки.Добавить(КлючИЗначение.Ключ);

        КонецЦикла;



    КонецЕсли;



    НачСтрока = ?(НачСтрока = 0, 1, НачСтрока);

    КонСтрока = ?(КонСтрока = 0, КолвоСтрок, КонСтрока);

    КонСтрока = Мин(КонСтрока, КолвоСтрок);



    Для НомерСтроки = НачСтрока По КонСтрока Цикл



        #Если Клиент Тогда

        Состояние("Чтение файла: " + Формат(НомерСтроки) + " из " + Формат(КонСтрока));

        ОбработкаПрерыванияПользователя();

        #КонецЕсли



        НоваяСтрока = Таблица.Добавить();



        Если СтруктураКолонок = Неопределено Тогда



            Для НомерКолонки = 1 По КолвоКолонок Цикл



                Поле = Лист.Cells(НомерСтроки, НомерКолонки);

                НоваяСтрока["К" + Формат(НомерКолонки, "ЧГ=0")] = Поле.Value;



            КонецЦикла;



        Иначе



            Для каждого КлючИЗначение Из СтруктураКолонок Цикл



                Поле = Лист.Cells(НомерСтроки, КлючИЗначение.Значение);

                НоваяСтрока[КлючИЗначение.Ключ] = Поле.Value;



            КонецЦикла;



        КонецЕсли;



    КонецЦикла;



    XLSОбъект.Application.Quit();

    Возврат Таблица;



КонецФункции



// Функция получает данные из файла Excel

//

// Параметры:

//   пФайл     - Имя файла

//   пЛист     - Имя листа с данными

//   СтруктураКолонок - Структура вида "ИмяКолонки" - "НомерКолонки"

//                      если не задано, созадуться колонки вида "К1", "К2"

//   XLSОбъект - COM объект типа "Excel.Application"

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция Excel_ПолучитьДанные_COMArray(пФайл, пЛист, СтруктураКолонок = Неопределено, Знач НачСтрока = 0, Знач КонСтрока = 0, XLSОбъект = Неопределено) Экспорт



    #Если Клиент Тогда

    Состояние("Открытие Excel");

    #КонецЕсли



    Если XLSОбъект = Неопределено Тогда

        XLSОбъект = Новый COMОбъект("Excel.Application");

        XLSОбъект.Visible       = Ложь;

        XLSОбъект.DisplayAlerts = Ложь;

    КонецЕсли;



    Попытка

        Book = XLSОбъект.Workbooks.Open(пФайл, , Истина);

    Исключение

        Сообщить ("Проблемы с подключением к Excel" );

        Возврат Неопределено;

    КонецПопытки;



    Лист = Book.Sheets(1);

    КолвоКолонок = Лист.Cells(1,1).SpecialCells(11).Column;

    КолвоСтрок   = Лист.Cells(1,1).SpecialCells(11).Row;



    Таблица = Новый ТаблицаЗначений;



    Если СтруктураКолонок = Неопределено Тогда



        Для Счетчик = 1 По КолвоКолонок Цикл

            Колонка = Таблица.Колонки.Добавить("К" + Счетчик);

        КонецЦикла;



    Иначе



        МаксимальныйНомерКолонки = 0;

        Для каждого КлючИЗначение Из СтруктураКолонок Цикл

            Колонка = Таблица.Колонки.Добавить(КлючИЗначение.Ключ);

            МаксимальныйНомерКолонки = Макс(МаксимальныйНомерКолонки, КлючИЗначение.Значение);

        КонецЦикла;



        КолвоКолонок = Мин(КолвоКолонок, МаксимальныйНомерКолонки);



    КонецЕсли;



    НачСтрока = ?(НачСтрока = 0, 1, НачСтрока);

    КонСтрока = ?(КонСтрока = 0, КолвоСтрок, КонСтрока);

    КонСтрока = Мин(КонСтрока, КолвоСтрок);



    // Массив типа COMSafeArray

    Массив = Лист.Range(Лист.Cells(НачСтрока, 1), Лист.Cells(КонСтрока, КолвоКолонок)).Value;

    КолвоСтрок   = Массив.GetUpperBound(1);



    Для НомерСтроки = 1 По КолвоСтрок Цикл



        #Если Клиент Тогда

        Состояние("Чтение файла: " + Формат(НомерСтроки) + " из " + Формат(КолвоСтрок));

        ОбработкаПрерыванияПользователя();

        #КонецЕсли



        НоваяСтрока = Таблица.Добавить();



        Если СтруктураКолонок = Неопределено Тогда



            Для НомерКолонки = 1 По КолвоКолонок Цикл



                НоваяСтрока["К" + Формат(НомерКолонки, "ЧГ=0")] = Массив.GetValue(НомерКолонки, НомерСтроки);



            КонецЦикла;



        Иначе



            Для каждого КлючИЗначение Из СтруктураКолонок Цикл



                НоваяСтрока[КлючИЗначение.Ключ] = Массив.GetValue(КлючИЗначение.Значение, НомерСтроки);



            КонецЦикла;



        КонецЕсли;



    КонецЦикла;



    XLSОбъект.Application.Quit();

    Возврат Таблица;



КонецФункции



// Функция получает список листов Excel

//

// Параметры:

//   пФайл - Имя файла

//   XLSОбъект - COM объект типа "Excel.Application"

//

// Возвращаемое значение:

//   СписокЗначений

//

Функция Excel_ПолучитьСписокЛистов(пФайл, XLSОбъект = Неопределено) Экспорт



    Если XLSОбъект = Неопределено Тогда

        XLSОбъект = Новый COMОбъект("Excel.Application");

        XLSОбъект.Visible       = Ложь;

        XLSОбъект.DisplayAlerts = Ложь;

    КонецЕсли;



    Попытка

        Book = XLSОбъект.Workbooks.Open(пФайл, , Истина);

    Исключение

        Возврат Новый СписокЗначений;

    КонецПопытки;



    СписокЛистов = Новый СписокЗначений;

    Для каждого Лист Из XLSОбъект.Sheets Цикл

        СписокЛистов.Добавить(Лист.Name);

    КонецЦикла;



    XLSОбъект.Application.Quit();

    Возврат СписокЛистов;



КонецФункции

Код 1C v 7.x

 Попытка

  Excel = СоздатьОбъект("Excel.Application");

 Исключение

  Сообщить(ОписаниеОшибки()+"; программа Excel не установлена на данном компьютере!");

     Возврат;

 КонецПопытки;

РабочиеКниги=Excel.WorkBooks;  // создаем рабочую книгу



 Попытка // открываем файл

  Отчет=РабочиеКниги.Open(Каталог+ИмяФайла); 

 Исключение 

  Сообщить(ОписаниеОшибки()+"; фаил с макросом не найден!");

  Возврат;

 КонецПопытки;



// заносим в таблицу какие-либо данные



 Лист = Отчет.Worksheets(1);



 Для Ном=1 По 20 Цикл

      Ячейка = Лист .Cells(ном,1); Ячейка.Value;

      Сообщить(Ячейка );

 КонецЦикла; 



Excel.Visible=1;



Попытка

      Отчет.Save();

Исключение

     Сообщить(ОписаниеОшибки()+"; не могу сохранить отчет!");

  Возврат;

 КонецПопытки;

Категория: Работа с Microsoft Office и OpenOffice

Получение списка баз 1С 7.7 из реестра

Ниже приведено несколько способов получения списка баз 1С 7.7 из реестра:
Код получения списка баз 1С 7.7 из 8.х

Код 1C v 8.х

 функция сзПолучитьСписокБаз()

    попытка

        олеСкрипт = новый COMОбъект("MSScriptControl.ScriptControl");

        олеСкрипт.Language = "VBScript";

        стрКод =

        "function strGetListBase()

        |  const RootKey = &H80000001

        |  set Reg = GetObject(""winmgmts:{impersonationLevel=impersonate}!\\."" &_

        |                      ""\root\default:StdRegProv"")

        |  PathKey = ""Software\1C\1Cv7\7.7\Titles""

        |  Reg.EnumValues RootKey, PathKey, Arr

        |  Answer = ""{""""#"""",4772b3b4-f4a3-49c0-a1a5-8cb5961511a3,"" & chr(10)

        |  Answer = Answer & ""{3,1e512aab-1b41-4ef6-9375-f0137be9dd91,0,0,"" & chr(10)

        |  Answer = Answer & ""{"" & (UBound(Arr) + 1) & "","" & chr(10)

        |  for x = LBound(Arr) to UBound(Arr)

        |    call Reg.GetStringValue(RootKey, PathKey, Arr(x), Value)

        |    Answer = Answer & ""{1e512aab-1b41-4ef6-9375-f0137be9dd91,"" & chr(10) &_

        |             ""{"""""" & replace(Value, """""""", """""""""""") & """""",0,"" &_

        |             chr(10) & ""{""""S"""","""""" & Arr(x)& """"""},"" &_

        |             chr(10) & ""{3,0,"" & chr(10) & ""{0},"""""""",-1,-1,0,0}"" &_

        |             chr(10) & ""}"" & chr(10) & ""}""

        |    if x <> UBound(Arr) then Answer = Answer & "",""

        |    Answer = Answer & chr(10)

        |  next

        |  Answer = Answer & ""},"" & chr(10) & ""{""""Pattern""""}"" & chr(10) &_

        |           ""}"" & chr(10) & ""}""

        |  strGetListBase = Answer

        |end function";

        олеСкрипт.AddCode(стрКод);

        стрОтвет = олеСкрипт.Run("strGetListBase");

        Ответ = ЗначениеИзСтрокиВнутр(стрОтвет);

        Ответ.СортироватьПоПредставлению();

    исключение

        Ответ = новый СписокЗначений;

        Ответ.Добавить("Базы 1С:Передприятия 7.7 не обнаруженны!");

    конецпопытки;

    возврат Ответ;

конецфункции

Код для 1С 7.7

Код 1C v 7.x

 

Функция ПолучитьСписокБаз1()

    Перем Value,arrValues;

    Scr = CreateObject("MSScriptControl.ScriptControl");

    Scr.Language = "vbscript";

    Scr.Timeout=-1;

    HKEY_CURRENT_USER = 2147483649;

    strKeyPath = "Software\1C\1Cv7\7.7\Titles";

    Locator=СоздатьОбъект("WbemScripting.SWbemLocator");

    ServiceDef=Locator.ConnectServer(".","root\default");

    oReg = ServiceDef.Get("StdRegProv");

    Dict=СоздатьОбъект("Scripting.Dictionary");

    Scr.AddObject("Dict",Dict);

    Scr.AddObject("oReg",oReg);

    Scr.ExecuteStatement("dim arrValues,Value:");

    Scr.ExecuteStatement("oReg.EnumValues "+HKEY_CURRENT_USER+","""+strKeyPath+""",arrValues:");

    Scr.ExecuteStatement("for i=lbound(arrValues) to ubound(arrValues):Dict.add ""pj"" & i, arrValues(i):next");

    ТЗБаз=СоздатьОбъект("ТаблицаЗначений");

    ТЗБаз.НоваяКолонка("Путь");

    ТЗБаз.НоваяКолонка("Описание");

    Для к=0 По Dict.count Цикл

        Д=Dict.Item("pj"+к);

        Scr.ExecuteStatement("oReg.GetStringValue "+HKEY_CURRENT_USER+","""+strKeyPath+""","""+Д+""",Value");

        ТЗБаз.НоваяСтрока();

        ТЗБаз.Путь = Д;

        ТЗБаз.Описание = Scr.eval("Value");

    КонецЦикла;

	//Посмотрим что в ТЗ

	//ТЗБаз.ВыбратьСтроку();

    Возврат ТЗБаз;

КонецФункции



Процедура ПолучитьСписокБаз2()

     Попытка

          scrptCtrl=createobject("MSScriptControl.ScriptControl");

          scrptCtrl.language="vbscript";

          scrptCtrl.addcode("Function Get1CV77Titles()

          |const HKEY_CURRENT_USER = &H80000001

          |Set oReg=GetObject(""winmgmts:{impersonationLevel=impersonate}!\\."" &_

          |""\root\default:StdRegProv"")

          |strKeyPath = ""Software\1C\1Cv7\7.7\Titles""

          |oReg.EnumValues HKEY_CURRENT_USER, strKeyPath, arrValues

          |strInfo=vbNullString

          |For i = LBound(arrValues) To UBound(arrValues)

          | call oReg.GetStringValue(HKEY_CURRENT_USER,strKeyPath,arrValues(i),Value)

          | strInfo=strInfo & arrValues(i) & ""="" & Value & vbCrLF

          |Next

          |Get1CV77Titles = strInfo 

          |End Function");

          Сообщить(scrptCtrl.run("Get1CV77Titles"));

     Исключение

          Сообщить(ОписаниеОшибки()); 

     КонецПопытки;

КонецПроцедуры

<Сообщил Gloom>

                  

Процедура ПолучитьСписокБаз3()

     Ключ="HKEY_CURRENT_USER\Software\1C\1Cv7\7.7\Titles";

     ИмяКаталога=СокрЛП(КаталогПользователя());

     ИмяБазы=СокрЛП(каталогИБ());

     Если прав(ИмяКаталога,1)<>"\" Тогда ИмяКаталога=ИмяКаталога+"\" КонецЕсли;

     Если прав(ИмяБазы,1)<>"\" Тогда ИмяБазы=ИмяБазы+"\" КонецЕсли;

     ИмяБазыСтр=Симв(34)+СтрЗаменить(ИмяБазы,"\","\\")+Симв(34);

     ИмяФайла="USER.TXT";

     Команда="Regedit /ea "+Симв(34)+ИмяКаталога+ИмяФайла+Симв(34)+" "+Симв(34)+Ключ+Симв(34);

     КомандаСистемы(Команда);

     Текст=СоздатьОбъект("Текст");

     Текст.КодоваяСтраница(0);

     Текст.Открыть(ИмяКаталога+ИмяФайла);

     Текст.Показать();

     Стр=""; Нашли=0;

     Для сч=1 по Текст.КоличествоСтрок() Цикл

          Стр=СокрЛП(Текст.ПолучитьСтроку(сч));

          Сообщить(Стр);

          Если Найти(стр,ИмяБазыСтр)<>0 Тогда

               Нашли=1;

               прервать;

          КонецЕсли;

     КонецЦикла;

КонецПроцедуры

Категория: COM-объекты, WMI, WSH

Не запускается 1С SQL в Windows Vista Категория: Администрирование

Как сравнить похожие строки (неполное совпадение строк)?

Ниже привожу пример функции нечеткого сравнения строк. Возвращаемое значение - от 0 (вообще не совпадает) до 1 (совпадает полностью)
По опыту, результат сравнения можно считать достоверным при совпадении больше 0.8 (80%)

Код

CREATE FUNCTION fn_FuzzyCompareString(
@Stri1 varchar(250),
@Stri2 varchar(250),
@MaxLen int)
RETURNS float
AS
BEGIN

DECLARE @Str1 varchar(250), @Str2 varchar(250), @SCountVar int,
@SCountEq int, @LenStr int, @Res float
DECLARE @NumSymbStr2 int
DECLARE @Cnt1 int, @Cnt2 int
DECLARE @SubStr varchar(250)

SELECT
@LenStr=1,
@SCountVar=0 ,
@SCountEq=0,
@res=0

Set @Str1 = replace(LTRIM(RTRIM(upper(@Stri1))),'.',' ')
Set @Str2 = replace(LTRIM(RTRIM(upper(@Stri2))),'.',' ')

if ((@MaxLen <= 0) or (Len(@Str1)=0) or (Len(@Str2)=0))
Begin
Set @Res=0
End
else
begin
While (@LenStr<=@MaxLen)
BEGIN
Set @NumSymbStr2=1
Set @Cnt2=0

While ((@Cnt2+@LenStr)<=LEN(@Str2))
BEGIN

Set @SubStr = '%'+SUBSTRING(@Str2,@NumSymbStr2,@LenStr)+'%'
if (PATINDEX(@SubStr, @Str1)<>0)
begin
Set @SCountEq=@SCountEq+1
end

Set @SCountVar=@SCountVar+1
Set @NumSymbStr2=@NumSymbStr2+1
Set @Cnt2 = @Cnt2+1
END

Set @NumSymbStr2=1
Set @Cnt2=0

While ((@Cnt2+@LenStr)<=LEN(@Str1))
BEGIN

Set @SubStr = '%'+SUBSTRING(@Str1,@NumSymbStr2,@LenStr)+'%'
if (PATINDEX(@SubStr, @Str2)<>0)
begin
Set @SCountEq=@SCountEq+1
end

Set @SCountVar=@SCountVar+1
Set @NumSymbStr2=@NumSymbStr2+1
Set @Cnt2 = @Cnt2+1
END

Set @LenStr=@LEnStr+1
END

end
if @SCountVar=0
SET @Res=0
Else
BEGIN
SET @Res=Convert(Numeric (10,5),@SCountEq)/Convert(Numeric (10,5),@SCountVar)
END

RETURN @Res
END

Использование этой функции (на примере прямого запроса к справочнику ФизЛица для 1С:ТиС 7.7): в выборку попадут все физлица, у которых релевантность выше 0.8

Код

DECLARE @FIO varchar(250)

Set @FIO = 'Иванов Петр'

SELECT
Спр.Code as [ФизЛицоКод],
Спр.ID as [ФизЛицо],
Спр.DESCR as [ФИО],
dbo.fn_FuzzyCompareString(dbo.fn_FIO(Спр.DESCR),@FIO,3) As [Релевантность]
FROM
SC503 as Спр (nolock)
where
ISMARK = 0
and
ISFOLDER = 2
and
dbo.fn_FuzzyCompareString(dbo.fn_FIO(Спр.DESCR),@FIO,3)>=0.8
GO

Категория: Полезные, Универсальные Функции

Как переиндексировать все пользовательские таблицы? Категория: Администрирование

При установке конфигурации 1С:Предприятия 8 под ОС Windows Vista - "Ошибка при инсталляции"

Для конфигураций на платформе "1С:Предприятие 8" используется цифровая подпись. Для подписанных программ виртуализация защищенных каталогов в Windows Vista отключена, в том числе и для каталога Program Files, в который записываются шаблоны конфигураций по умолчанию. При включенном UAC прав на запись в этот каталог нет, что и вызывает ошибку записи. Для решения проблемы установки необходимо либо отключать UAC, либо устроить каталог шаблонов в другом месте, доступном для записи.

Отключить Контроль учетных записей (User Account Control, UAC) можно в Панели управления, раздел "Учетные записи пользователей (User Accounts)", пункт "Включение или отключение контроля учетных записей (Turn User Account Control off/on)". В появившемся диалоге убрать галку (единственную) около "Используйте контроль учетных записей (use User Account Control...)".
После установки конфигурации значение использования UAC можно восстановить.

Из справки по MS Vista:
Средство контроля учетных записей, обеспечивающее защиту системы путем принудительного запуска программ из стандартной учетной записи даже в том случае, если пользователь работает в системе с правами администратора.

Категория: Системные Ошибки