comsafearray » Поиск

Результаты по ключевому слову: comsafearray

Синтаксический анализ JSON - выражения средствами 1С 7.7 Категория: HTML, JS, VML

Работа с бинарными файлами, Двоичные данные и кодировка Base64 Категория: OLE, ActiveX

Добавим документы ODF (OpenOffice/LibreOffice) в стандартную обработку Загрузки Табличного документа Категория: Работа с Microsoft Office и OpenOffice

Полезные процедуры работы с Active Directory (AD)

Надоели просить меня запостить рабочие модули работы с AD, вот запостил, в качестве бонуса убийца любого процесса в памяти любого компа.
p.s. для работы нужны определенные права.
Автор: vde69

Код 1C v 8.х

 Функция ПолучитьСписокДоменов () Экспорт  

	Результат = Новый Массив(); 

	objNameSpace = "";                   

	Попытка  objNameSpace = ПолучитьCOMОбъект("WinNT:");   

		м = Новый Массив();  м.Добавить("domain"); // Computer User Group GlobalGroup domain  

		м2 = Новый COMSafeArray(м, "VT_VARIANT");  

		objNameSpace.Filter = м2;  

		Для каждого item Из objNameSpace Цикл   

			Результат.Добавить(item.Name);  

		КонецЦикла; 

	Исключение  

		Результат.Очистить(); 

	КонецПопытки;  

	Возврат Результат;

КонецФункции





Функция ПолучитьСписокГруппВДомене (ИмяДомена, ТипГрупп = "GlobalGroup") Экспорт  

	Результат = Новый Массив(); 

	objNameSpace = "";  

	Попытка  objNameSpace = ПолучитьCOMОбъект("WinNT://"+СокрЛП(ИмяДомена));   

		м = Новый Массив();  

		м.Добавить(ТипГрупп); // Computer User Group GlobalGroup domain  

		м2 = Новый COMSafeArray(м, "VT_VARIANT");  

		objNameSpace.Filter = м2;  

		Для каждого item Из objNameSpace Цикл   

			Результат.Добавить(item.Name);  

		КонецЦикла; 

	Исключение  

		Результат.Очистить(); 

	КонецПопытки;  

	

	Возврат Результат;

КонецФункции

	

Функция ПолучитьСписокПользователейВГруппеДомена (ИмяДомена, ИмяГруппы) Экспорт  

	Результат = Новый Массив(); 

	objNameSpace = "";  

	Попытка  

		objNameSpace = ПолучитьCOMОбъект("WinNT://" + СокрЛП(ИмяДомена) + "/" + СокрЛП(ИмяГруппы) + ", Group");   

		Для каждого item Из objNameSpace.Members() Цикл   

			Результат.Добавить(item.Name);  

		КонецЦикла; 

	Исключение  

		Результат.Очистить(); 

	КонецПопытки;  

	

	Возврат Результат;	

КонецФункции



Функция ПользовательВГруппеДомена (ИмяДомена, ИмяГруппы, ИмяПользователя) Экспорт  

	Результат = Ложь;  

	Массив = ПолучитьСписокПользователейВГруппеДомена (СокрЛП(ИмяДомена), ИмяГруппы);

	Для каждого элМассив из Массив Цикл  

		Если ВРег(элМассив) = ВРег(СокрЛП(ИмяПользователя)) Тогда   // пользователь уже в группе   

			Результат = Истина;    

			Прервать;  

		КонецЕсли; 

	КонецЦикла;  

	

	Возврат Результат;

КонецФункции



Функция ДобавитьПользователяВГруппуДомена (ИмяДомена, ИмяГруппы, ИмяПользователя) Экспорт  

	Результат = Ложь; 

	element_user = ""; 

	element_group = "";  

	Попытка  

		element_user = ПолучитьCOMОбъект("WinNT://" + ИмяДомена + "/" + ИмяПользователя + ", user");  

		element_group = ПолучитьCOMОбъект("WinNT://" + ИмяДомена + "/" + ИмяГруппы + ", group");  

		element_group.Add(element_user.ADsPath);  element_group.SetInfo();  

		Результат = Истина; 

	Исключение  

		Результат = Ложь; 

	КонецПопытки;  

	

	Возврат Результат;

КонецФункции



Функция УдалитьПользователяИзГруппыДомена (ИмяДомена, ИмяГруппы, ИмяПользователя) Экспорт  

	Результат = Ложь; 

	element_user = ""; 

	element_group = "";  

	Попытка  element_user = ПолучитьCOMОбъект("WinNT://" + ИмяДомена + "/" + ИмяПользователя + ", user");  

		element_group = ПолучитьCOMОбъект("WinNT://" + ИмяДомена + "/" + ИмяГруппы + ", group");  

		element_group.Remove(element_user.ADsPath);  

		element_group.SetInfo();  

		Результат = Истина; 

	Исключение  

		Результат = Ложь; 

	КонецПопытки;  

	

	Возврат Результат;	

КонецФункции



Процедура ЗаполнитьПочтовыеАдресаИзAD() 

	Попытка      

		conn = ПолучитьCOMОбъект("","ADODB.Connection");  

		conn.Provider = "ADSDSOObject";  

		conn.Open("Active Directory Provider"); 

	Исключение  Предупреждение("Ошибка подключения к Active Directory!");  

		Возврат; 

	КонецПопытки;   

	

	Для Каждого Стр из Таблица Цикл  

		Если НЕ ПустаяСтрока(Стр.Логин) Тогда   

			Попытка        

				query = "SEL ECT ADsPath FR OM 'LDAP://DC="+СокрЛП(Домен.Код)+"' WHERE SAMAccountName='"+Стр.Логин+"'";    

				rs = conn.Execute(query);    

				Пока НЕ rs.EOF() Цикл     

					obj = ПолучитьCOMОбъект(rs.Fields(0).Value);     

					Если obj.Class="user" Тогда      

						Стр.НоваяПочта=СокрЛП(obj.EmailAddress);      

						Если Стр.НоваяПочта<>Стр.СтараяПочта Тогда       

							Стр.Установить=Истина;      

						КонецЕсли;     

					КонецЕсли;     

					rs.MoveNext();    

				КонецЦикла;   

			Исключение

				Сообщить("Ошибка получения почты для логина :"+Стр.Логин);				                                                      

			КонецПопытки;

		КонецЕсли;

	КонецЦикла;

	conn.Close();	

КонецПроцедуры



Функция УдалитьПроцесс (ИмяКомпьютера, НазваниеПроцесса, Логин, Пароль) Экспорт  

	Попытка  COM = Новый COMОбъект ("WbemScripting.SWbemLocator");  

		Серв = COM.ConnectServer(СокрЛп(ИмяКомпьютера), "\root\cimv2", СокрЛП(Логин), СокрЛП(Пароль));  

		СписокПроцессов = Серв.execQuery("Sel ect * fr om Win32_Process Where Name = '"+СокрЛП(НазваниеПроцесса)+"'");  

		Для каждого item Из СписокПроцессов Цикл   

			item.Terminate();  

		КонецЦикла; 

	Исключение  

		Возврат Ложь; 

	КонецПопытки;  

	

	Возврат Истина;

КонецФункции

Код 1C v 8.х

 // coder1cv8 - Мой вариант получения почты 1С-ного пользователя:

Функция ПолучитьMailПоПользователю(СсылкаПользователь)

Адрес="";

ПользовательИБ=ПользователиИнформационнойБазы.НайтиПоИмени(СокрЛП(СсылкаПользователь.Код));

Если ПользовательИБ<>Неопределено Тогда

   Если ПользовательИБ.АутентификацияОС Тогда

     ПользовательОС=СтрЗаменить(ПользовательИБ.ПользовательОС,"\","/");

       Попытка

         ЮзерАД=ПолучитьCOMОбъект("WinNT:"+ПользовательОС+",user");

         LDAP=ПолучитьCOMОбъект("LDAP://CN="+ЮзерАД.FullName+",OU=Common Users,OU=Regular Users,DC="+Домен+",DC=local");

         Адрес=LDAP.Mail;

       Исключение

       КонецПопытки;

  КонецЕсли;

КонецЕсли;

Возврат Адрес;

КонецФункции

Категория: COM-объекты, WMI, WSH

Выгрузка в PDF из 1С (Средствами OpenOffice)

Возникла задача отправлять счета почтой. PDFcreator не подошёл поскольку не удалось вместить счёт на одну страницу по ширине. Решил попробовать OpenOffice. Как сохранять в PDF нашёл быстро, а вот как уместить счёт на одну страницу вширь искал долго.
В версии 1С 8.2.232 появилась возможность сохранять табличный документ в xls файл на сервера под линуксом. А вот работать с Опеном офисом из-под линукса пока не получается. Собственно комментари ненужны. Вот весь код. Самое интересное это бодание со стилями страниц в Опене Офисе. Жаль что этот фрагмент работает только на клиенте. На сервере вопрос не решается *08

Код 1C v 8.2 УП

 Процедура КнопкаВыполнитьНажатие(Кнопка)

    Если Письмо.Основание.Пустая() Тогда

        Возврат

    КонецЕсли;



    // Открыть OpenOffice

    Попытка

        ServiceManager = Новый COMОбъект("com.sun.star.ServiceManager");

    Исключение

        Возврат // опен офис не установлен :-(

    КонецПопытки;



    // получим печатную форму и запишем её во временный XLS файл

    Заказ = Письмо.Основание.ПолучитьОбъект();



    //Получим печатную форму

    Расшифровка=Новый Структура;

    Расшифровка.Вставить("СсылкаНаВнешнююОбработку",Константы.ПФСчетаДляКлиента.Получить());

    Расшифровка.Вставить("ВидПечатнойФормы",Перечисления.ВидыДополнительныхВнешнихОбработок.ПечатнаяФорма);

    Расшифровка.Вставить("НомерСтроки",1);

    тд = УниверсальныеМеханизмы.НапечататьВнешнююФорму(Заказ, Расшифровка);



    ВременныйФайл =ПолучитьИмяВременногоФайла();

    ВременныйФайлXLS =ВременныйФайл + ".xls";

    ВременныйФайлPDF =ВременныйФайл + ".pdf";

    тд.Записать(ВременныйФайлXLS, ТипФайлаТабличногоДокумента.XLS97);



    // Преобразовываем временный xls файл В PDF

    Desktop        = ServiceManager.createInstance("com.sun.star.frame.Desktop");



    НастройкиОткрытия = Новый COMSafeArray("VT_VARIANT", 1);

    PropertyValue = ServiceManager.Bridge_GetStruct("com.sun.star.beans.PropertyValue");

    PropertyValue.Name = "Hidden";

    PropertyValue.Value = Истина;

    НастройкиОткрытия.SetValue(0, PropertyValue);

    ВременныйФайлXLS_какУРЛ = "file:///" + СтрЗаменить(ВременныйФайлXLS, "\", "/"); // приводим путь к файлу из виндового формата в опен офисный



    // Откроем файл в опене офисе

    ОпенОфис = Desktop.LoadComponentFromURL(ВременныйФайлXLS_какУРЛ, "_blank", 0, НастройкиОткрытия);



    //ПараметрыСтраницы = ОпенОфис.createInstance("com.sun.star.style.PageStyle");

    //ПараметрыСтраницы.ScaleToPagesX = 1;

    //

    // Установим масштаб, чтобы счёт помещался на одной странице вширь

    // страниц почему-то много, поэтому устанавливаем масштаб для всех

    Стили = ОпенОфис.StyleFamilies.getByName("PageStyles");

    Для поз = 0 по Стили.count - 1 Цикл

        МойСтиль = Стили.getByIndex(поз);

        МойСтиль.ScaleToPagesX = 1; // уместить на одной странице вширь

        //МойСтиль.PageScale = 50; // масштаб 50%

    КонецЦикла;



    НастройкиСохранения = Новый COMSafeArray("VT_VARIANT", 1);

    PropertyValue = ServiceManager.Bridge_GetStruct("com.sun.star.beans.PropertyValue");

    PropertyValue.Name = "FilterName";

    PropertyValue.Value = "calc_pdf_Export";

    НастройкиСохранения.SetValue(0, PropertyValue);



    ВременныйФайлPDF_какУРЛ = "file:///" + СтрЗаменить(ВременныйФайлPDF, "\", "/"); // приводим путь к файлу из виндового формата в опен офисный

    ОпенОфис.storeToURL(ВременныйФайлPDF_какУРЛ, НастройкиСохранения); // сохранили PDF файл

    ОпенОфис.close(-1);

    ОпенОфис = Неопределено;



    // С опеном офисом разобрались. Прикрепляем вложение к письму и удаляем временные файлы.

    //Файл = Новый Файл(ВременныйФайлPDF);

    объектПисьмо = Письмо.ПолучитьОбъект();

    стрВложение = объектПисьмо.Вложения.Добавить();

    стрВложение.ИмяФайла = "Счёт " + Строка(Заказ.Номер) + ".pdf";

    стрВложение.Файл = Новый ХранилищеЗначения(Новый ДвоичныеДанные(ВременныйФайлPDF));

    объектПисьмо.Записать();

    Попытка

        УдалитьФайлы(ВременныйФайлXLS);

        УдалитьФайлы(ВременныйФайлPDF);

    Исключение

    КонецПопытки;



КонецПроцедуры

Автор: Трактор

Функция позволяющая выполнить выгрузку табличного документа в PDF средствами OpenOffice

Код 1C v 8.х

 // Функция превращает табличный документ в PDF документ

// Возвращаемое значение: тип "Строка" - имя созданного PDF файла, 0 - в случае ошибки

// Параметры: ДанныеВыгрузки - Табличный или текстовый документ, который нужно выгрузить в PDF

//            ПутьВыгрузки - тип "Строка", путь для сохраниения PDF файла (без имени и расширения файла)

//            ИмяФайлаБезРасширения - тип "Строка", имя для вновь сформированного PDF файла

// Тестировалось на OpenOffice 3.x

Функция ВыгрузитьТабличныйДокументВPDF(ДанныеВыгрузки, ПутьВыгрузки, ИмяФайлаБезРасширения)       

    Если НЕ ЗначениеЗаполнено(ПутьВыгрузки) Тогда

        ПутьВыгрузки = КаталогВременныхФайлов();

    КонецЕсли;   

    ПутьВыгрузки         = ?(Прав(ПутьВыгрузки, 1) = "\", ПутьВыгрузки, ПутьВыгрузки + "\");

   

    РасширениеXSL         = ".xls";

    РасширениеPDF         = ".pdf";

    ПолноеИмяФайлаXLS     = ПутьВыгрузки + ИмяФайлаБезРасширения + РасширениеXSL;

    //Выгрузка данных печати в файл XLS   

#Если Клиент Тогда

    Состояние("Создание временного файла...");

#КонецЕсли

    Попытка

        Если         ТипЗнч(ДанныеВыгрузки) = Тип("ТабличныйДокумент") Тогда        

            ДанныеВыгрузки.Записать(ПолноеИмяФайлаXLS, "XLS");

        ИначеЕсли     ТипЗнч(ДанныеВыгрузки) = Тип("ТекстовыйДокумент") Тогда

            ДанныеВыгрузки.Записать(ПолноеИмяФайлаXLS, "XLS");

        Иначе

#Если Клиент Тогда

            Сообщить("Данные для выгрузки переданы в неподдерживаемом формате. Дальнейшее выполнение невозможно." + Символы.ПС + ОписаниеОшибки());

#КонецЕсли

            Возврат 0;

        КонецЕсли;

    Исключение

#Если Клиент Тогда

        Сообщить("Произошла ошибка при выгрузке временного файла. Возможно ошибка доступа к папке, в которую происходит запись." + Символы.ПС + ОписаниеОшибки());

#КонецЕсли

        Возврат 0;

    КонецПопытки;

   

    Попытка

#Если Клиент Тогда

        Состояние("Открытие компоненты OpenOffice...");

#КонецЕсли

        ServiceManager    = Новый COMОбъект("com.sun.star.ServiceManager");       

       

        Скрипт             = Новый COMОбъект("MSScriptControl.ScriptControl");

        Скрипт.language    = "javascript";

        Скрипт.AddObject("OpenOffice", ServiceManager);

       

        //Открытие временного файла без отображения его окна

#Если Клиент Тогда           

        Состояние("Открытие временного файла...");

#КонецЕсли

        Скрипт.eval("Массив=new Array()");       

        Массив             = Скрипт.eval("Массив");   

        Скрипт.eval("Массив[0] = OpenOffice.Bridge_GetStruct('com.sun.star.beans.PropertyValue')");

        Скрипт.eval("Массив[0].Name     = 'Hidden'");

        Скрипт.eval("Массив[0].Value = true");

       

        Скрипт.AddCode("function SetItem(ind,val){Массив[ind]=val}");       

        Скрипт.AddObject("ServiceManager",ServiceManager);

        Desktop         = ServiceManager.createInstance("com.sun.star.frame.Desktop");       

        Document         = Desktop.LoadComponentFromURL("file:///" + ПолноеИмяФайлаXLS, "_blank", 0, Массив);

       

        //Сохранение в PDF встроенными средствами OpenOffice

#Если Клиент Тогда           

        Состояние("Запись в PDF...");

#КонецЕсли

        Скрипт.eval("Массив2=new Array()");       

        Массив2     = Скрипт.eval("Массив2");       

        Скрипт.eval("Массив2[0] = OpenOffice.Bridge_GetStruct('com.sun.star.beans.PropertyValue')");       

        Скрипт.eval("Массив2[0].Name  = 'FilterName'");

        Скрипт.eval("Массив2[0].Value = 'writer_pdf_Export'");

       

        ПолноеИмяФайлаPDF         = "file:///" + СтрЗаменить(ПолноеИмяФайлаXLS, РасширениеXSL, РасширениеPDF);

        ПолноеИмяФайлаPDF         = СтрЗаменить(ПолноеИмяФайлаPDF, ВРег(РасширениеXSL), РасширениеPDF);

        ПолноеИмяФайлаPDF        = СтрЗаменить(ПолноеИмяФайлаPDF, "\", "/");       

               

        Document.storeToURL(ПолноеИмяФайлаPDF, Массив2);

        Document.close(-1);        //Закрыть документ

       

        //Контрольная очистка переменных

        Document     = Неопределено;

        Desktop     = Неопределено;

       

        //Удаление временного файла

#Если Клиент Тогда           

        Состояние("Удаление временного файла...");

#КонецЕсли       

        Попытка

            УдалитьФайлы(ПолноеИмяФайлаXLS);

        Исключение

#Если Клиент Тогда           

            Сообщить("Произошла ошибка при удалении временного файла. Возможно, потребуется удалить его вручную." + Символы.ПС + ОписаниеОшибки());

#КонецЕсли

        КонецПопытки;

       

        ПолноеИмяФайлаPDF = СтрЗаменить(ПолноеИмяФайлаPDF, "file:///", "");

        ПолноеИмяФайлаPDF = СтрЗаменить(ПолноеИмяФайлаPDF, "/", "\");

#Если Клиент Тогда

        Состояние("Выгрузка выполнена.");

        Предупреждение("Выгрузка выполнена." + Символы.ПС + ПолноеИмяФайлаPDF);       

#КонецЕсли

        Возврат ПолноеИмяФайлаPDF;

    Исключение

        Document.close(-1);

#Если Клиент Тогда

        Предупреждение(ОписаниеОшибки());

#КонецЕсли

        Возврат 0;

    КонецПопытки   

КонецФункции

Автор: doom_2001

Категория: Работа с Microsoft Office и OpenOffice

Как сформировать новый документ на основании файла, шаблона Microsoft Office Word и OpenOffice?

Код 1C v 8.х

  Перем СсылкаНаДокумент;



Процедура СформироватбФайл_MS_Word_И_OpenOffice(Кнопка)

	

	ДокументСсылка = СсылкаНаДокумент;

	ИмяФайла = ПолучитьИмяВременногоФайла();



	// Теперь формируем файл из MS Wordа

	Попытка

		

		MSWord = новый COMОбъект("Word.Application");

		//Передаем текущие параметры форм в MSWord

		MSWord.Documents.Open(ИмяФайла);	

		MSWordDoc = MSWord.ActiveDocument();

		

		WordContent =  MSWord.ActiveDocument().ActiveWindow.S_election;

		

		//------------------------------------------------------------

		// Перебираем таблицы в документе, и сопоставляем имена переменных

		// с именами табличных частей.

		Для ТекущаяТаблица = 1 ПО MSWordDoc.Tables.Count Цикл 

			мТабличнаяЧасть = Неопределено;

			Для ТекущаяСтрока  = 1 ПО MSWordDoc.Tables(ТекущаяТаблица).Rows.Count Цикл 

				Для ТекущаяКолонка = 1 ПО MSWordDoc.Tables(ТекущаяТаблица).Columns.Count Цикл 

					

					мТабличнаяЧасть = ИмяТабличнойЧастиВСтроке(

					ПолучитьСтартПеременной( MSWordDoc.Tables(ТекущаяТаблица).Cell(ТекущаяСтрока,ТекущаяКолонка).Range.Text	) 

					,ДокументСсылка);

					

					Если  мТабличнаяЧасть <> Неопределено Тогда

						Прервать;;	

					КонецЕсли;	

					

				КонецЦикла;

				Если  мТабличнаяЧасть <> Неопределено Тогда

					Прервать;;	

				КонецЕсли;	

			КонецЦикла;

			

			//Итак мы имеем номер текущей таблицы  и имя табличной части

			Если  мТабличнаяЧасть <> Неопределено Тогда

				//Производим редактирование нашей таблицы в соответствии с количеством строк

				ВсегоСтрокТЧ = 0;

				Для Каждого строкаТЧ Из  ДокументСсылка[мТабличнаяЧасть.Имя] Цикл

					ВсегоСтрокТЧ = ВсегоСтрокТЧ+1;

				КонецЦикла;

				//ВсегоСтрокТЧ = ДокументСсылка[мТабличнаяЧасть.Имя].Количество;

				// Добавляем строки

				Для ТекущаяСтрокаТЧ  = 1  По ВсегоСтрокТЧ Цикл

					Если ТекущаяСтрокаТЧ <> ВсегоСтрокТЧ  Тогда

						MSWordDoc.Tables(ТекущаяТаблица).Rows.Add(MSWordDoc.Tables(ТекущаяТаблица).Rows(ТекущаяСтрока+ТекущаяСтрокаТЧ-1));

					КонецЕсли;	

					//MSWordDoc.Tables(ТекущаяТаблица).Cell(ТекущаяСтрока+ТекущаяСтрокаТЧ-1,2).Range.Text = Строка(ТекущаяСтрокаТЧ);

					Для ТекКол = 1 ПО MSWordDoc.Tables(ТекущаяТаблица).Columns.Count Цикл 

						Если ТекущаяСтрокаТЧ <> ВсегоСтрокТЧ  Тогда

							ТекстПеременной = ПолучитьПеременнуюИзСтроки(СокрЛП(MSWordDoc.Tables(ТекущаяТаблица).Cell(ТекущаяСтрока+ТекущаяСтрокаТЧ,ТекКол).Range.Text));

							ТекстПеременной = ?(ПустаяСтрока(ТекстПеременной),"", "["+"_"+Строка(ТекущаяСтрокаТЧ)+"_"+ТекстПеременной+"]");

							MSWordDoc.Tables(ТекущаяТаблица).Cell(ТекущаяСтрока+ТекущаяСтрокаТЧ-1,ТекКол).Range.Text = ТекстПеременной;

						Иначе

							ТекстПеременной = ПолучитьПеременнуюИзСтроки(СокрЛП(MSWordDoc.Tables(ТекущаяТаблица).Cell(ТекущаяСтрока+ТекущаяСтрокаТЧ-1,ТекКол).Range.Text));

							ТекстПеременной = ?(ПустаяСтрока(ТекстПеременной),"", "["+"_"+Строка(ТекущаяСтрокаТЧ)+"_"+ТекстПеременной+"]");

							MSWordDoc.Tables(ТекущаяТаблица).Cell(ТекущаяСтрока+ТекущаяСтрокаТЧ-1,ТекКол).Range.Text = ТекстПеременной;

						КонецЕсли;	

					КонецЦикла;	

				КонецЦикла;	

				//MSWordDoc.Tables(ТекущаяТаблица).Rows.Delete();

				//MSWordDoc.Tables(ТекущаяТаблица).Rows(3).Delete();

			КонецЕсли;	

		КонецЦикла;

		

		//------------------------------------------------------------

		// Вытаскивам из шаблона текст 

		ТекстДокумента = MSWordDoc.Range(0, MSWordDoc.Characters.Count).Text;

		

		// Из текста вытаскиваем Имена переменных залюченных а скобки []

		Список = ПолучитьСписокПеременных(ТекстДокумента);

		//Список.ВыбратьЭлемент();

		

		// Заполняем в структуру ревизитовперечень переменных

		СтруктураРеквизитов=СтруктураРеквизитовДокумента(ДокументСсылка);

		ЗначениеРеквизита="";

		Для Каждого ЭлементСписка Из Список Цикл

			

			// Если находится соответствие переменной из документа и шаблона то производим замену

			Если СтруктураРеквизитов.Свойство(ЭлементСписка.Значение, ЗначениеРеквизита ) Тогда

				//Сообщить("["+ЭлементСписка.Значение+"]"+" : "+ЗначениеРеквизита);

				WordContent.Find.Execute("["+ЭлементСписка.Значение+"]",0,0,0,0,0,-1,,,Строка(ЗначениеРеквизита),2);		

			Иначе

				Сообщить("-> " + ЭлементСписка.Значение+" - Не найден в структуре документа");

				// Заменим переменную на пустую строку

				WordContent.Find.Execute("["+ЭлементСписка.Значение+"]",0,0,0,0,0,-1,,," ",2);		

			КонецЕсли;

			

		КонецЦикла;

		

		//автоматически обновляем поля документа

		MSWord.S_election.WholeStory();

		MSWord.S_election.Fields.Update();

		MSWord.S_election.HomeKey();	

		

		//MSWordDoc.SaveAs(ИмяФайла);

		

		//отображаем MSWord

		MSWord.Visible=1;

		MSWord.Activate();

		

	Исключение

		Предупреждение(ОписаниеОшибки());

		MSWord.Quit();

	КонецПопытки;

	

	

	// Теперь формируем файл из OpenOffice

	

	Попытка

		ServiceManager = Новый COMОбъект("com.sun.star.ServiceManager");

		Reflection = ServiceManager.createInstance("com.sun.star.reflection.CoreReflection");

		Desktop = ServiceManager.createInstance("com.sun.star.frame.Desktop");

		

		Args = Новый COMSafeArray("VT_DISPATCH", 1);

		OOДокумент = Desktop.loadComponentFromURL(ПреобразоватьВURL(ИмяФайла), "_blank", 0, Args);

		

		//------------------------------------------------------------

		// Перебираем таблицы в документе, и сопоставляем имена переменных

		// с именами табличных частей.

		Для ТекущаяТаблица = 0 ПО OOДокумент.getTextTables().Count-1 Цикл 

			мТабличнаяЧасть = Неопределено;

			Для ТекущаяСтрока  = 0 ПО OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).Rows.Count-1 Цикл 

				Для ТекущаяКолонка = 0 ПО OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).Columns.Count-1 Цикл 

					

					мТабличнаяЧасть = ИмяТабличнойЧастиВСтроке(

					ПолучитьСтартПеременной( OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).getCellByPosition(ТекущаяКолонка, ТекущаяСтрока).string	) 

					,ДокументСсылка);

					

					Если  мТабличнаяЧасть <> Неопределено Тогда

						Прервать;;	

					КонецЕсли;	

					

				КонецЦикла;

				Если  мТабличнаяЧасть <> Неопределено Тогда

					Прервать;;	

				КонецЕсли;	

			КонецЦикла;

			

			//Итак мы имеем номер текущей таблицы  и имя табличной части

			Если  мТабличнаяЧасть <> Неопределено Тогда

				//Производим редактирование нашей таблицы в соответствии с количеством строк

				ВсегоСтрокТЧ = 0;

				Для Каждого строкаТЧ Из  ДокументСсылка[мТабличнаяЧасть.Имя] Цикл

					ВсегоСтрокТЧ = ВсегоСтрокТЧ+1;

				КонецЦикла;

				//ВсегоСтрокТЧ = ДокументСсылка[мТабличнаяЧасть.Имя].Количество;

				// Добавляем строки

				Для ТекущаяСтрокаТЧ  = 1  По ВсегоСтрокТЧ Цикл

					Если ТекущаяСтрокаТЧ <> ВсегоСтрокТЧ  Тогда

						// Добавляем строку перед нашей

						OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).Rows.I_nsertByIndex(ТекущаяСтрока+ТекущаяСтрокаТЧ-1, 1);

					КонецЕсли;	

					

					Для ТекКол = 0 ПО OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).Columns.Count-1 Цикл 

						

						Если ТекущаяСтрокаТЧ <> ВсегоСтрокТЧ  Тогда             

							ТекстПеременной = ПолучитьПеременнуюИзСтроки(СокрЛП(OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).getCellByPosition(ТекКол, ТекущаяСтрока+ТекущаяСтрокаТЧ).string));

							ТекстПеременной = ?(ПустаяСтрока(ТекстПеременной),"", "["+"_"+Строка(ТекущаяСтрокаТЧ)+"_"+ТекстПеременной+"]");

							OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).getCellByPosition(ТекКол, ТекущаяСтрока+ТекущаяСтрокаТЧ-1).string = ТекстПеременной;

						Иначе                                                   

							ТекстПеременной = ПолучитьПеременнуюИзСтроки(СокрЛП(OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).getCellByPosition(ТекКол, ТекущаяСтрока+ТекущаяСтрокаТЧ-1).string));

							ТекстПеременной = ?(ПустаяСтрока(ТекстПеременной),"", "["+"_"+Строка(ТекущаяСтрокаТЧ)+"_"+ТекстПеременной+"]");

							

							OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).getCellByPosition(ТекКол, ТекущаяСтрока+ТекущаяСтрокаТЧ-1).string = ТекстПеременной;

						КонецЕсли;	

					КонецЦикла;	

				КонецЦикла;	

			КонецЕсли;	

		КонецЦикла;

		

		//------------------------------------------------------------

		// Вытаскивам из шаблона текст 

		//ТекстДокумента = MSWordDoc.Range(0, MSWordDoc.Characters.Count).Text;

		ТекстДокумента = ООПолучитьТекст(OOДокумент);

		

		// Из текста вытаскиваем Имена переменных залюченных а скобки []

		Список = ПолучитьСписокПеременных(ТекстДокумента);

		//Список.ВыбратьЭлемент();

		

		// Заполняем в структуру ревизитовперечень переменных

		СтруктураРеквизитов=СтруктураРеквизитовДокумента(ДокументСсылка);

		ЗначениеРеквизита="";

		

		OOЗамена = OOДокумент.CreateReplaceDescriptor();

		

		Для Каждого ЭлементСписка Из Список Цикл

			

			// Если находится соответствие переменной из документа и шаблона то производим замену

			Если СтруктураРеквизитов.Свойство(ЭлементСписка.Значение, ЗначениеРеквизита ) Тогда

				OOЗамена.SearchString  = "["+ЭлементСписка.Значение+"]";

				OOЗамена.ReplaceString = Строка(ЗначениеРеквизита);

				OOДокумент.ReplaceAll(OOЗамена);

			Иначе

				Сообщить("-> " + ЭлементСписка.Значение+" - Не найден в структуре документа");

				// Заменим переменную на пустую строку

				OOЗамена.SearchString  = "["+ЭлементСписка.Значение+"]";

				OOЗамена.ReplaceString = " ";

				OOДокумент.ReplaceAll(OOЗамена);

				

			КонецЕсли;

			

		КонецЦикла;

		OOДокумент.getCurrentController().getFrame().getContainerWindow().setFocus();

		

	Исключение

		Предупреждение(ОписаниеОшибки());

	КонецПопытки;			

	

КонецПроцедуры

Код 1C v 8.х

   //ДОПОЛНИТЕЛЬНО НЕОБХОДИМЫЕ ФУНКЦИИ

// Добавлем форматы представления полей и дополнительную информацию о полях

Процедура ДобавитьФорматы(ПереченьРеквизитов,Значение,пПредставлениеРеквизита, ДокументСсылка = Неопределено)

	Если ТипЗнч(Значение) = Тип("Дата")  Тогда  // расширяем представление даты

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"ДФddMMyyyy",Формат(Значение,"ДФ=dd.MM.yyyy"));

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"ДЛФDD",Формат(Значение,"ДЛФ=DD"));

	ИначеЕсли ТипЗнч(Значение) = Тип("Число") Тогда  // расширяем представление числа

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"ЧДЦ2ЧГ0",Формат(Значение,"ЧДЦ=2; ЧГ=0"));

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"ЧДЦ2",Формат(Значение,"ЧДЦ=2"));

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"ЧПропись",Значение);

	ИначеЕсли  (ТипЗнч(Значение) = Тип("СправочникСсылка.КонтактныеЛица"))  или  (ТипЗнч(Значение) = Тип("СправочникСсылка.ФизическиеЛица")) Тогда

		// Расширяем выводимые поля для типов физ. лица, контакные лица сокращением инициалов	

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"ФИО",Строка(Значение));

	КонецЕсли

КонецПроцедуры



Процедура ЗаполнитьРеквизиты(мГлубинаРекурсии,ПереченьРеквизитов,РеквизитСсылка,Реквизит,пПредставлениеРеквизита)

	

	мГлубинаРекурсии = мГлубинаРекурсии+1;

	ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"Код",РеквизитСсылка["Код"]);

	ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"Наименование",РеквизитСсылка["Наименование"]);

	

	Для Каждого ЭлементРеквизита Из Реквизит.Реквизиты  Цикл

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+ЭлементРеквизита.Имя,РеквизитСсылка[ЭлементРеквизита.Имя]);

		Если (Найти(ЭлементРеквизита.Тип,"Справочник ссылка")>0) И (мГлубинаРекурсии <=3) И (Найти(ЭлементРеквизита.Тип,",")=0) Тогда

			///+++

			ЗаполнитьРеквизиты(мГлубинаРекурсии, ПереченьРеквизитов,РеквизитСсылка[ЭлементРеквизита.Имя],РеквизитСсылка[ЭлементРеквизита.Имя].Метаданные(),пПредставлениеРеквизита+"_"+ЭлементРеквизита.Имя);

		Иначе

			ДобавитьФорматы(ПереченьРеквизитов,РеквизитСсылка[ЭлементРеквизита.Имя],пПредставлениеРеквизита+"_"+ЭлементРеквизита.Имя);

		КонецЕсли

	КонецЦикла;	

	

КонецПроцедуры



Функция ПолучитьСписокПеременных(ТекстШаблона)

	СписокПеременных = Новый СписокЗначений();

	ЕщеЕсть = Истина;

	Пока ЕщеЕсть Цикл

		ПервыйСимвол = Найти(ТекстШаблона,"[");

		Если ПервыйСимвол > 0 Тогда

			ВторойСимвол = Найти(ТекстШаблона,"]");

			Если (ВторойСимвол > 0 И ВторойСимвол > ПервыйСимвол) Тогда

				СписокПеременных.Добавить(Сред(ТекстШаблона,ПервыйСимвол + 1,ВторойСимвол - ПервыйСимвол - 1));

				ТекстШаблона = Сред(ТекстШаблона,ВторойСимвол + 1);

			Иначе

				ЕщеЕсть = Ложь;

			КонецЕсли;

		Иначе

			ЕщеЕсть = Ложь;

		КонецЕсли;

	КонецЦикла;

	Возврат СписокПеременных;

КонецФункции



Функция СтруктураРеквизитовДокумента(ДокументСсылка)  Экспорт

	ПереченьРеквизитов = Новый Структура;

	ПереченьРеквизитов.Вставить("Дата",ДокументСсылка["Дата"]);

	ДобавитьФорматы(ПереченьРеквизитов,ДокументСсылка["Дата"],"Дата");

	ПереченьРеквизитов.Вставить("Номер",ДокументСсылка["Номер"]);

	Реквизиты = ДокументСсылка.Метаданные().Реквизиты;

	Для Каждого Реквизит Из Реквизиты  Цикл

		мГлубинаРекурсии = 1;

		ПереченьРеквизитов.Вставить(Реквизит.Имя,ДокументСсылка[Реквизит.Имя]);

			ДобавитьФорматы(ПереченьРеквизитов,ДокументСсылка[Реквизит.Имя],Реквизит.Имя,ДокументСсылка);

		Если Найти(Реквизит.Тип,"Справочник ссылка")>0 Тогда

			ЗаполнитьРеквизиты(мГлубинаРекурсии,ПереченьРеквизитов,ДокументСсылка[Реквизит.Имя],ДокументСсылка[Реквизит.Имя].Метаданные(),Реквизит.Имя);

		Иначе

			//ДобавитьФорматы(ПереченьРеквизитов,ДокументСсылка[Реквизит.Имя],Реквизит.Имя);

		КонецЕсли;

	КонецЦикла;	

	ТабличныеЧасти = ДокументСсылка.Метаданные().ТабличныеЧасти;

	Для Каждого ТабличнаяЧасть Из ТабличныеЧасти  Цикл

		// Сообщить(ТабличнаяЧасть); // Для таблицы характеристик отрабатываем свой код // с выводом табличной части как набора реквизитов

		Если ТабличнаяЧасть.Имя = "Характеристики" Тогда

			Для Каждого СтрокаТабличнойЧасти Из ДокументСсылка[ТабличнаяЧасть.Имя]  Цикл

				мПредставлениеРеквизита = "Характеристика"+"_"+СтрЗаменить(СтрокаТабличнойЧасти["ВидХарактеристики"], " ", "_");

				мЗначение = СтрокаТабличнойЧасти["ЗначениеХарактеристики"];

				ПереченьРеквизитов.Вставить(мПредставлениеРеквизита,мЗначение);

				ДобавитьФорматы(ПереченьРеквизитов,мЗначение,мПредставлениеРеквизита,ДокументСсылка);

				Если Найти(ТипЗнч(мЗначение),"Справочник ссылка")>0 Тогда

					ЗаполнитьРеквизиты(мГлубинаРекурсии,ПереченьРеквизитов,мЗначение,мЗначение.Метаданные(),мПредставлениеРеквизита);

				КонецЕсли;

				

			КонецЦикла;	

		КонецЕсли;	

		//Перечень реквизитов табличной части

		Реквизиты = ТабличнаяЧасть.Реквизиты;

		Для Каждого Реквизит Из Реквизиты  Цикл

			Для Каждого СтрокаТабличнойЧасти Из ДокументСсылка[ТабличнаяЧасть.Имя]  Цикл

				мГлубинаРекурсии = 1;

				мПредставлениеРеквизита = "_"+СтрокаТабличнойЧасти.НомерСтроки+"_"+ТабличнаяЧасть.Имя+"_НомерСтроки";

				ПереченьРеквизитов.Вставить(мПредставлениеРеквизита,Строка(СтрокаТабличнойЧасти.НомерСтроки));

				мПредставлениеРеквизита = "_"+СтрокаТабличнойЧасти.НомерСтроки+"_"+ТабличнаяЧасть.Имя+"_"+Реквизит.Имя;

				мЗначение = СтрокаТабличнойЧасти[Реквизит.Имя];

				ПереченьРеквизитов.Вставить(мПредставлениеРеквизита,мЗначение);

				ДобавитьФорматы(ПереченьРеквизитов,мЗначение,мПредставлениеРеквизита,ДокументСсылка);

				Если Найти(ТипЗнч(мЗначение),"Справочник ссылка")>0 Тогда

					ЗаполнитьРеквизиты(мГлубинаРекурсии,ПереченьРеквизитов,мЗначение,мЗначение.Метаданные(),мПредставлениеРеквизита);

				Иначе

					//ДобавитьФорматы(ПереченьРеквизитов,мЗначение,мПредставлениеРеквизита);

				КонецЕсли;

			КонецЦикла;	

			//Если реквизит числовой, то подсчитываем итог  

			Если Реквизит.Тип.СодержитТип(Тип("Число"))  Тогда

				мЗначение = ДокументСсылка[ТабличнаяЧасть.Имя].Итог(Реквизит.Имя);

				мПредставлениеРеквизита = "Итог"+"_"+ТабличнаяЧасть.Имя+"_"+Реквизит.Имя;

				ПереченьРеквизитов.Вставить(мПредставлениеРеквизита,мЗначение);

				ДобавитьФорматы(ПереченьРеквизитов,мЗначение,мПредставлениеРеквизита,ДокументСсылка);

			КонецЕсли;

		КонецЦикла;			

	КонецЦикла;	    	

	Возврат ПереченьРеквизитов;

КонецФункции



Функция ИмяТабличнойЧастиВСтроке(Строка,ДокументСсылка)

	ТабличнаяЧасть=Неопределено;

	Если НЕ ПустаяСтрока(Строка) Тогда

		ТабличнаяЧасть = ДокументСсылка.Метаданные().ТабличныеЧасти.Найти(Строка) 

	КонецЕсли;	

	Возврат ТабличнаяЧасть;

	

КонецФункции



//Получает первый кусок переменной до _

Функция ПолучитьСтартПеременной(ПереданнаяСтрока) Экспорт

	СтартПеременной = "";

	ПервыйСимвол = Найти(ПереданнаяСтрока,"[");

	Если  ПервыйСимвол > 0 Тогда

		ВторойСимвол = Найти(ПереданнаяСтрока,"]");

		Если  (ВторойСимвол > 0) И (ВторойСимвол > ПервыйСимвол) Тогда

			Переменная = (Сред(ПереданнаяСтрока,ПервыйСимвол+1,ВторойСимвол-ПервыйСимвол-1));

			ВторойСимвол = Найти(Переменная,"_");

			Если  (ВторойСимвол > 0) И (ВторойСимвол > 1) Тогда

				СтартПеременной = Сред(Переменная,1,ВторойСимвол-1);

			КонецЕсли;	

		КонецЕсли;	

		

	КонецЕсли;	

	

	Возврат СтартПеременной;	

КонецФункции



// Получает переменную заключенную в скобки

Функция ПолучитьПеременнуюИзСтроки(ПереданнаяСтрока) Экспорт

	Переменная = "";

	ПервыйСимвол = Найти(ПереданнаяСтрока,"[");

	Если  ПервыйСимвол > 0 Тогда

		ВторойСимвол = Найти(ПереданнаяСтрока,"]");

		Если  (ВторойСимвол > 0) И (ВторойСимвол > ПервыйСимвол) Тогда

			Переменная = (Сред(ПереданнаяСтрока,ПервыйСимвол+1,ВторойСимвол-ПервыйСимвол-1));

		КонецЕсли;	

		

	КонецЕсли;	

	Возврат Переменная;	

КонецФункции// Идентифицирует табличную часть в строке



// Функция преобразует Windows имя файла в URL OpenOffice

Функция ПреобразоватьВURL(ИмяФайла)

	Возврат "file:///" + СтрЗаменить(ИмяФайла, "\", "/");

КонецФункции



// Функция извлекает текст из документа

Функция ООПолучитьТекст(OOДокумент)

	Текст = "";

	oParEnum = OOДокумент.getText().createEnumeration();

	Пока  oParEnum.hasMoreElements() Цикл

		oPar = oParEnum.nextElement();

		Если  oPar.supportsService("com.sun.star.text.Paragraph") ТОгда

			Текст = Текст + oPar.getString();

		ИначеЕсли oPar.supportsService("com.sun.star.text.TextTable") Then

			//Сообщить(oPar.getString());

		КонецЕсли;

	КонецЦикла;

	Для ТекущаяТаблица = 0 ПО OOДокумент.getTextTables().Count-1 Цикл 

		Для ТекущаяСтрока  = 0 ПО OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).Rows.Count-1 Цикл 

			Для ТекущаяКолонка = 0 ПО OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).Columns.Count-1 Цикл 

				Текст = Текст + OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).getCellByPosition(ТекущаяКолонка, ТекущаяСтрока).string;

			КонецЦикла;

		КонецЦикла;

	КонецЦикла;

	Возврат Текст;

КонецФункции

Категория: Работа с Microsoft Office и OpenOffice

Подключение к EXCEL и чтение данных из листа Excel

Код 1C v 8.х

 Ex = Новый COMObject("Excel.Application");

   Ex.Workbooks.Open(Путь);

   Ex.Visible = 1;    

   ТекЛист=Ex.WorkSheets(1);        

   Для Ячейка = 1 по 400 цикл

       Если НЕ  ТекЛист.Cells(Ячейка,1).Value  = Неопределено тогда

           Сообщить(Строка(ТекЛист.Cells(Ячейка,1).Value));    

           Карта = Справочники.Номенклатура.НайтиПоКоду(ИзЧислаВСтроку(ТекЛист.Cells(Ячейка,1).Value));    

           Если Карта.Пустая() тогда        

               Сообщить(" Пустой элемент "  + ТекЛист.Cells(Ячейка,1));

           иначе

               Объект = Карта.ПолучитьОбъект();

               Объект.ОсновнойПоставщик = ОсновнойКлиент;

               Объект.Записать();

               конецесли;    

       конецесли;

   конеццикла;

Примеры процедур для чтения данных из EXCEL

Код 1C v 8.х

 

// Функция получает данные из файла Excel

//

// Параметры:

//   пФайл - Имя файла

//   пЛист - Имя листа с данными

//   СтруктураКолонок - Структура вида "ИмяКолонки" - "НомерКолонки"

//                      если не задано, созадуться колонки вида "К1", "К2"

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция Excel_ПолучитьДанные_ADO(пФайл, пЛист, СтруктураКолонок = Неопределено, Знач НачСтрока = 0, Знач КонСтрока = 0) Экспорт



    #Если Клиент Тогда

    Состояние("Установка соединения с Excel");

    #КонецЕсли



    //ЗаголовкиВСтроке1 = "HDR=YES;"

    ЗаголовкиВСтроке1 = "HDR=NO;";



    СтрокаСоединения ="Provider=Microsoft.Jet.OLEDB.4.0;Data Source= " + СокрЛП(пФайл) +" ;Extended Properties=""Excel 8.0;" + ЗаголовкиВСтроке1 + "IMEX=1;""";



    Connection = Новый COMОбъект("ADODB.Connection");

    Connection.ConnectionString =  СтрокаСоединения;



    Попытка

        Connection.Open();

    Исключение

        Сообщить ("Проблемы с подключением к Excel" );

        Возврат Неопределено;

    КонецПопытки;



    RS = Новый COMОбъект("ADODB.Recordset");



    ТекстЗапроса =

    "S_elect

    |    Лист.*

    |FROM

    |    [" + пЛист + "$] as Лист";



    Попытка

        RS.Open(ТекстЗапроса, Connection);

    Исключение

        Сообщить ("Проблемы с выполнением запроса");

        Возврат Неопределено;

    КонецПопытки;



    Таблица = Новый ТаблицаЗначений;



    Если СтруктураКолонок = Неопределено Тогда



        Для Счетчик = 1 По RS.Fields.Count Цикл

            Поле = RS.Fields.Item(Счетчик - 1);

            Колонка = Таблица.Колонки.Добавить("К" + Счетчик, , Поле.Name);

        КонецЦикла;



    Иначе



        Для каждого КлючИЗначение Из СтруктураКолонок Цикл

            Колонка = Таблица.Колонки.Добавить(КлючИЗначение.Ключ);

        КонецЦикла;



    КонецЕсли;



    НомерСтроки = 0;

    КолвоСтрок  = RS.RecordCount;



    Пока RS.EOF() = 0 Цикл



        НомерСтроки = НомерСтроки + 1;



        #Если Клиент Тогда

        Состояние("Чтение файла: " + Формат(НомерСтроки) + " из " + Формат(КолвоСтрок));

        ОбработкаПрерыванияПользователя();

        #КонецЕсли



        Если НомерСтроки < НачСтрока Тогда

            RS.MoveNext();

            Продолжить;

        КонецЕсли;



        Если КонСтрока > 0 И НомерСтроки > КонСтрока Тогда

            Прервать;

        КонецЕсли;



        НоваяСтрока = Таблица.Добавить();



        Если СтруктураКолонок = Неопределено Тогда



            Для Счетчик = 1 По RS.Fields.Count Цикл



                Поле = RS.Fields.Item(Счетчик - 1);

                НоваяСтрока["К" + Счетчик] = Поле.Value;



            КонецЦикла;



        Иначе



            Для каждого КлючИЗначение Из СтруктураКолонок Цикл



                Поле = RS.Fields.Item(КлючИЗначение.Значение - 1);

                НоваяСтрока[КлючИЗначение.Ключ] = Поле.Value;



            КонецЦикла;



        КонецЕсли;



        // Обработка других полей

        RS.MoveNext();



    КонецЦикла;



    // Завершение работы



    RS.Close();

    Connection.Close();



    Возврат Таблица;



КонецФункции



// Функция получает данные из файла Excel

//

// Параметры:

//   пФайл     - Имя файла

//   пЛист     - Имя листа с данными

//   СтруктураКолонок - Структура вида "ИмяКолонки" - "НомерКолонки"

//                      если не задано, созадуться колонки вида "К1", "К2"

//   XLSОбъект - COM объект типа "Excel.Application"

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция Excel_ПолучитьДанные_COM(пФайл, пЛист, СтруктураКолонок = Неопределено, Знач НачСтрока = 0, Знач КонСтрока = 0, XLSОбъект = Неопределено) Экспорт



    #Если Клиент Тогда

    Состояние("Открытие Excel");

    #КонецЕсли



    Если XLSОбъект = Неопределено Тогда

        XLSОбъект = Новый COMОбъект("Excel.Application");

        XLSОбъект.Visible       = Ложь;

        XLSОбъект.DisplayAlerts = Ложь;

    КонецЕсли;



    Попытка

        Book = XLSОбъект.Workbooks.Open(пФайл, , Истина);

    Исключение

        Сообщить ("Проблемы с подключением к Excel" );

        Возврат Неопределено;

    КонецПопытки;



    Лист = Book.Sheets(1);

    КолвоКолонок = Лист.Cells(1,1).SpecialCells(11).Column;

    КолвоСтрок   = Лист.Cells(1,1).SpecialCells(11).Row;



    Таблица = Новый ТаблицаЗначений;



    Если СтруктураКолонок = Неопределено Тогда



        Для Счетчик = 1 По КолвоКолонок Цикл

            Колонка = Таблица.Колонки.Добавить("К" + Счетчик);

        КонецЦикла;



    Иначе



        Для каждого КлючИЗначение Из СтруктураКолонок Цикл

            Колонка = Таблица.Колонки.Добавить(КлючИЗначение.Ключ);

        КонецЦикла;



    КонецЕсли;



    НачСтрока = ?(НачСтрока = 0, 1, НачСтрока);

    КонСтрока = ?(КонСтрока = 0, КолвоСтрок, КонСтрока);

    КонСтрока = Мин(КонСтрока, КолвоСтрок);



    Для НомерСтроки = НачСтрока По КонСтрока Цикл



        #Если Клиент Тогда

        Состояние("Чтение файла: " + Формат(НомерСтроки) + " из " + Формат(КонСтрока));

        ОбработкаПрерыванияПользователя();

        #КонецЕсли



        НоваяСтрока = Таблица.Добавить();



        Если СтруктураКолонок = Неопределено Тогда



            Для НомерКолонки = 1 По КолвоКолонок Цикл



                Поле = Лист.Cells(НомерСтроки, НомерКолонки);

                НоваяСтрока["К" + Формат(НомерКолонки, "ЧГ=0")] = Поле.Value;



            КонецЦикла;



        Иначе



            Для каждого КлючИЗначение Из СтруктураКолонок Цикл



                Поле = Лист.Cells(НомерСтроки, КлючИЗначение.Значение);

                НоваяСтрока[КлючИЗначение.Ключ] = Поле.Value;



            КонецЦикла;



        КонецЕсли;



    КонецЦикла;



    XLSОбъект.Application.Quit();

    Возврат Таблица;



КонецФункции



// Функция получает данные из файла Excel

//

// Параметры:

//   пФайл     - Имя файла

//   пЛист     - Имя листа с данными

//   СтруктураКолонок - Структура вида "ИмяКолонки" - "НомерКолонки"

//                      если не задано, созадуться колонки вида "К1", "К2"

//   XLSОбъект - COM объект типа "Excel.Application"

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция Excel_ПолучитьДанные_COMArray(пФайл, пЛист, СтруктураКолонок = Неопределено, Знач НачСтрока = 0, Знач КонСтрока = 0, XLSОбъект = Неопределено) Экспорт



    #Если Клиент Тогда

    Состояние("Открытие Excel");

    #КонецЕсли



    Если XLSОбъект = Неопределено Тогда

        XLSОбъект = Новый COMОбъект("Excel.Application");

        XLSОбъект.Visible       = Ложь;

        XLSОбъект.DisplayAlerts = Ложь;

    КонецЕсли;



    Попытка

        Book = XLSОбъект.Workbooks.Open(пФайл, , Истина);

    Исключение

        Сообщить ("Проблемы с подключением к Excel" );

        Возврат Неопределено;

    КонецПопытки;



    Лист = Book.Sheets(1);

    КолвоКолонок = Лист.Cells(1,1).SpecialCells(11).Column;

    КолвоСтрок   = Лист.Cells(1,1).SpecialCells(11).Row;



    Таблица = Новый ТаблицаЗначений;



    Если СтруктураКолонок = Неопределено Тогда



        Для Счетчик = 1 По КолвоКолонок Цикл

            Колонка = Таблица.Колонки.Добавить("К" + Счетчик);

        КонецЦикла;



    Иначе



        МаксимальныйНомерКолонки = 0;

        Для каждого КлючИЗначение Из СтруктураКолонок Цикл

            Колонка = Таблица.Колонки.Добавить(КлючИЗначение.Ключ);

            МаксимальныйНомерКолонки = Макс(МаксимальныйНомерКолонки, КлючИЗначение.Значение);

        КонецЦикла;



        КолвоКолонок = Мин(КолвоКолонок, МаксимальныйНомерКолонки);



    КонецЕсли;



    НачСтрока = ?(НачСтрока = 0, 1, НачСтрока);

    КонСтрока = ?(КонСтрока = 0, КолвоСтрок, КонСтрока);

    КонСтрока = Мин(КонСтрока, КолвоСтрок);



    // Массив типа COMSafeArray

    Массив = Лист.Range(Лист.Cells(НачСтрока, 1), Лист.Cells(КонСтрока, КолвоКолонок)).Value;

    КолвоСтрок   = Массив.GetUpperBound(1);



    Для НомерСтроки = 1 По КолвоСтрок Цикл



        #Если Клиент Тогда

        Состояние("Чтение файла: " + Формат(НомерСтроки) + " из " + Формат(КолвоСтрок));

        ОбработкаПрерыванияПользователя();

        #КонецЕсли



        НоваяСтрока = Таблица.Добавить();



        Если СтруктураКолонок = Неопределено Тогда



            Для НомерКолонки = 1 По КолвоКолонок Цикл



                НоваяСтрока["К" + Формат(НомерКолонки, "ЧГ=0")] = Массив.GetValue(НомерКолонки, НомерСтроки);



            КонецЦикла;



        Иначе



            Для каждого КлючИЗначение Из СтруктураКолонок Цикл



                НоваяСтрока[КлючИЗначение.Ключ] = Массив.GetValue(КлючИЗначение.Значение, НомерСтроки);



            КонецЦикла;



        КонецЕсли;



    КонецЦикла;



    XLSОбъект.Application.Quit();

    Возврат Таблица;



КонецФункции



// Функция получает список листов Excel

//

// Параметры:

//   пФайл - Имя файла

//   XLSОбъект - COM объект типа "Excel.Application"

//

// Возвращаемое значение:

//   СписокЗначений

//

Функция Excel_ПолучитьСписокЛистов(пФайл, XLSОбъект = Неопределено) Экспорт



    Если XLSОбъект = Неопределено Тогда

        XLSОбъект = Новый COMОбъект("Excel.Application");

        XLSОбъект.Visible       = Ложь;

        XLSОбъект.DisplayAlerts = Ложь;

    КонецЕсли;



    Попытка

        Book = XLSОбъект.Workbooks.Open(пФайл, , Истина);

    Исключение

        Возврат Новый СписокЗначений;

    КонецПопытки;



    СписокЛистов = Новый СписокЗначений;

    Для каждого Лист Из XLSОбъект.Sheets Цикл

        СписокЛистов.Добавить(Лист.Name);

    КонецЦикла;



    XLSОбъект.Application.Quit();

    Возврат СписокЛистов;



КонецФункции

Код 1C v 7.x

 Попытка

  Excel = СоздатьОбъект("Excel.Application");

 Исключение

  Сообщить(ОписаниеОшибки()+"; программа Excel не установлена на данном компьютере!");

     Возврат;

 КонецПопытки;

РабочиеКниги=Excel.WorkBooks;  // создаем рабочую книгу



 Попытка // открываем файл

  Отчет=РабочиеКниги.Open(Каталог+ИмяФайла); 

 Исключение 

  Сообщить(ОписаниеОшибки()+"; фаил с макросом не найден!");

  Возврат;

 КонецПопытки;



// заносим в таблицу какие-либо данные



 Лист = Отчет.Worksheets(1);



 Для Ном=1 По 20 Цикл

      Ячейка = Лист .Cells(ном,1); Ячейка.Value;

      Сообщить(Ячейка );

 КонецЦикла; 



Excel.Visible=1;



Попытка

      Отчет.Save();

Исключение

     Сообщить(ОписаниеОшибки()+"; не могу сохранить отчет!");

  Возврат;

 КонецПопытки;

Категория: Работа с Microsoft Office и OpenOffice