большем » Поиск

Результаты по ключевому слову: большем

Дерево значений в таблицу значений или в табличную часть и обратно

Для одной организации надо было реализовать документы, где вместо табличной части надо использовать дерево и все это на управляемых формах. Но дерево нельзя сохранить в базе в текущем виде. Пришлось использовать табличную часть документа для хранения данных дерева. И при открытии формы получать данные из ТЧ и выводить их в дерево. Далее все манипуляции производить с деревом и при сохранении документа помещать данные в обратно в ТЧ.

Поиск по интернету не дал нужного варианта, пришлось реализовавыть свой механизм, используя информацию которая была на просторах интернета.

Для реализации такого механизма в ТЧ был добавлен реквизит “КлючСвязи” (обязательный реквизит) с типом число, куда помещался “НомерСтроки” (стандартный реквизит ТЧ) родителя (верхний уровень). А самый верхний элемент дерева имеет “КлючСвязи” равный 0.

На картинке ниже видно структуру дерева и структуру ТЧ

Нагрузка на сервер осуществляется при окрытии и при сохранении документа. А с деревом работают уже на клиенте.

На рабочей базе обрабатывается около 200 строк в одном документе.

Открытие и сохранение документа происходит моментально. С большем количеством строк не тестировалось.

Чтобы алгорит правильно работал, у рекизита фомы с типом дерево значений должны быть все реквизиты табличной части, кроме “КлючСвязи” и “НомерСтроки”. Иначе платформа выдаст ошибку. В дерево можо добавлять свои реквизиты отличные от ТЧ, они будут использоваться только в дереве.

Ниже приведен код преобразования дерева в таблицу и обратно.

Код 1C v 8.2 УП

 &НаКлиенте

Процедура КомандаТаблицуВДерево(Команда)

	КомандаТаблицуВДеревоНаСервере();

КонецПроцедуры





&НаСервере

Процедура КомандаТаблицуВДеревоНаСервере()

	Дерево = ТаблицаВДерево(РеквизитФормыВЗначение("Объект"), "Товары");//Товары - имя табличной части

	ЗначениеВРеквизитФормы(Дерево, "ДеревоЗначений");//ДеревоЗначений - реквизит формы с типом дерево значений

	Элементы.ДеревоЗначений.Обновить();

КонецПроцедуры





&НаКлиенте

Процедура КомандаДеревоВТаблицу(Команда)

	КомандаДеревоВТаблицуНаСервере();

КонецПроцедуры





&НаСервере

Процедура КомандаДеревоВТаблицуНаСервере()

	Объект.Товары.Очистить();

	ДОбъект = РеквизитФормыВЗначение("Объект");

	ДеревоВТаблицу(ДОбъект, РеквизитФормыВЗначение("ДеревоЗначений"), "Товары");

	ЗначениеВРеквизитФормы(ДОбъект, "Объект");

КонецПроцедуры

Формирование дерева из таблицы значений

Код 1C v 8.2 УП

 //ФОРМИРОВАНИЕ ДЕРЕВА ИЗ ТАБЛИЦЫ

&НаСервере

Функция ТаблицаВДерево(ДокОбъект, НаименованиеТабличнойЧастиДокумента, КлючСвязи = NULL, ЭлементРодитель = NULL) Экспорт	

	//ПОДГОТОВКА КОЛОНОК ДЕРЕВА

	КолонкиТаблицы = ДокОбъект.Метаданные().ТабличныеЧасти[НаименованиеТабличнойЧастиДокумента].Реквизиты;

	ДеревоЗначений2 = Новый ДеревоЗначений;

	Для каждого Кол из КолонкиТаблицы Цикл

		Если Кол.Имя = "НомерСтроки" ИЛИ Кол.Имя = "КлючСвязи" Тогда

			Продолжить;

		Иначе

			ДеревоЗначений2.Колонки.Добавить(Кол.Имя, Новый ОписаниеТипов(Кол.Тип));

		КонецЕсли;

	КонецЦикла;//ДеревоЗначений.Строки.Очистить();

	

	Если КлючСвязи = NULL И ЭлементРодитель = NULL Тогда

		//ПЕРВЫЙ ВЫЗОВ ПРОЦЕДУРЫ (КОРНЕВЫЕ ЭЛЕМЕНТЫ)

		ИсточникВыборки = ДеревоЗначений2.Строки;

		КлючСвязи = 0; // ЭЛЕМЕНТ ВЕРХНЕГО УРОВНЯ ИМЕЕТ НОМЕР СТРОКИ РОДИТЕЛЯ 0 (ОБЯЗАТЕЛЬНЫЙ РЕКВИЗИТ)

	Иначе

		//ВНУТРЕННИЙ ВЫЗОВ ПРОЦЕДУРЫ (ПОДЧИНЕННЫЕ ЭЛЕМЕНТЫ)

		ИсточникВыборки = ЭлементРодитель.Строки;

	КонецЕсли;

	Фильтр = Новый Структура("КлючСвязи", КлючСвязи);

	М = ДокОбъект[НаименованиеТабличнойЧастиДокумента].НайтиСтроки(Фильтр);

	Если М.Количество() = 0 Тогда

		Возврат ДеревоЗначений2;

	КонецЕсли;

	Для каждого Стр из М Цикл

		Элемент = ИсточникВыборки.Добавить();

		Для каждого Кол из КолонкиТаблицы Цикл

			Если Кол.Имя = "НомерСтроки" ИЛИ Кол.Имя = "КлючСвязи" Тогда

				Продолжить;

			Иначе

				Элемент[Кол.Имя] = Стр[Кол.Имя];

			КонецЕсли;

		КонецЦикла;

		ТаблицаВДерево(ДокОбъект, НаименованиеТабличнойЧастиДокумента, Стр.НомерСтроки, Элемент); //ДОБАВЛЕНИЕ ПОДЧИНЁННЫХ ЭЛЕМЕНТОВ В ДЕРЕВО

	КонецЦикла;

	Возврат ДеревоЗначений2;

КонецФункции

Формирование таблицы из дерева

Код 1C v 8.2 УП

 //ФОРМИРОВАНИЕ ТАБЛИЦЫ ИЗ ДЕРЕВА

&НаСервере

Процедура ДеревоВТаблицу(ДокОбъект, ДеревоЗначений, НаименованиеТабличнойЧастиДокумента, СтрокаДерева = NULL, КлючСвязи = NULL) Экспорт

	Если СтрокаДерева = NULL И КлючСвязи = NULL Тогда

		//ПЕРВЫЙ ВЫЗОВ ПРОЦЕДУРЫ (КОРНЕВЫЕ ЭЛЕМЕНТЫ)

		ПервыйВызов = Истина;

		ДокОбъект[НаименованиеТабличнойЧастиДокумента].Очистить();

		ИсточникВыборки = ДеревоЗначений.Строки;

		КлючСвязи = 0; // ЭЛЕМЕНТ ВЕРХНЕГО УРОВНЯ ИМЕЕТ НОМЕР СТРОКИ РОДИТЕЛЯ 0 (ОБЯЗАТЕЛЬНЫЙ РЕКВИЗИТ)

	Иначе

		//ВНУТРЕННИЙ ВЫЗОВ ПРОЦЕДУРЫ (ПОДЧИНЕННЫЕ ЭЛЕМЕНТЫ)

		ПервыйВызов = Ложь;

		ИсточникВыборки = СтрокаДерева.Строки;

	КонецЕсли;

	Для каждого Стр из ИсточникВыборки Цикл

		НС = ДокОбъект[НаименованиеТабличнойЧастиДокумента].Добавить();

		Для каждого Кол из ДокОбъект.Метаданные().ТабличныеЧасти[НаименованиеТабличнойЧастиДокумента].Реквизиты Цикл

			Если Кол.Имя = "КлючСвязи" Тогда

				НС.КлючСвязи = КлючСвязи

			ИначеЕсли Кол.Имя = "НомерСтроки" Тогда

				Продолжить;

			Иначе 

				НС[Кол.Имя] = Стр[Кол.Имя];

			КонецЕсли;

		КонецЦикла;

		Если НЕ Стр.Строки.Количество() = 0 Тогда

			ДеревоВТаблицу(ДокОбъект,,НаименованиеТабличнойЧастиДокумента, Стр, НС.НомерСтроки);

		КонецЕсли;

	КонецЦикла;

КонецПроцедуры

Категория: Работа с Деревом Значений

Метод сортировки числового ряда "пузырьком" Категория: Полезные, Универсальные Функции

Ошибка доступа к таблице DT*

Превышено максимально допустимое количество одновременно открытых файлов в Windows 9x.
Дело в том, что Windows 95/98 позволяют одновременно открывать не более 1024 файлов. Это ограничение вступает в силу, если в сетевом режиме работы база лежит на расшаренном диске компьютера, работающего под управлением Windows 95/98. При запуске 1С каждый подключившийся пользователь открывает все .dbf и .cdx файлы, входящие в состав конфигурации. В зависимости от сложности конфигурации, одновременно работать с 1С в таком режиме могут 3-6 пользователей.
Если Вы столкнулись с такой проблемой, следует использовать в качестве файл-сервера (т.е. компьютера, на котором хранится каталог информационной базы) компьютер с WinNT/2000/2003. Надо только иметь ввиду, что WinNT Workstation (2000 Professional) не имеет ограничения на количество открытых файлов, но допускает не более 10 одновременных подключений. Т.е. с базами на таком компьютере смогут работать одновременно не более 10 пользователей. Если требуется работать большему количеству пользователей одновременно, то есть смысл рассматривать вариант с выделенным сервером и операционными системами Windows 2000/2003 Server.

Если Вы перенесли базу на Windows 2003 Server, и у Вас продолжает появляться та же ошибка? То проверьте количество лицензий на подключение пользователей (компьютеров) в Win Server 2003 – там по умолчанию стоит всего 5…

А лучше перейти на SQL, и этой ошибки больше не будет никогда!

Категория: Системные Ошибки