демонстрирует » Поиск

Результаты по ключевому слову: демонстрирует

Как программно изменить текст, цвет, фон ячейки или области табличного документа?

Ниже приведено несколько полезных шаблонов кода по работе с табличным документом:

Код 1C v 8.х

 //Пример получения текста ячейки

ПолеТабДок = ЭлементыФормы.тдПолеТабличногоДокумента; 

ПолеТабДок.Область("R1C2").Текст = спрНоменклатура.Наименование;

ПолеТабДок.Область("R2C2").Текст = "Это Строка"; //указываем явно литерал строки

Код 1C v 8.х

 // Изменение текста в области или ячейке



Для а = 11 по ТабличныйДокумент.ВысотаТаблицы Цикл

		//Ячейка = ТабличныйДокумент.Область(а,1,а,1).Текст; 

		текстЯчейка = ТабличныйДокумент.Область("R"+а+"C2").Текст; 

		Если Строка(ТабличныйДокумент.Область("R"+а+"C2").ЦветФона)="стиль: Фон кнопки" Тогда

			ТабличныйДокумент.Область("R"+а+"C7").Текст="";

			ТабличныйДокумент.Область("R"+а+"C11").Текст="";	

			ТабличныйДокумент.Область("R"+а+"C8").Текст=""; 		

			ТабличныйДокумент.Область("R"+а+"C9").Текст=""; 		

			ТабличныйДокумент.Область("R"+а+"C10").Текст=""; 	

			

		КонецЕсли;

		

	КонецЦикла;

Код 1C v 8.х

 // Как раскрасить ячейку или область табличного документа в зависимости от условия

ТабДок = ЭлементыФормы.ПолеТабличногоДокумента; // Получаем табличный документ из формы 

ТабДок.Очистить(); // Очищаем табличный документ 

Макет = ПолучитьМакет("Макет"); // Получаем макет с именем "Макет" из текущего объекта 

ОбластьСтрокаТаб = Макет.ПолучитьОбласть("СтрокаТаб"); // Получаем область из макета 

ОбластьСтрокаТаб.Параметры.НашПараметр = 1; // Устанавливаем значение 1 параметру "НашПараметр" 

ОбластьОформления = ТабДок.Вывести(ОбластьСтрокаТаб); 

// Вот собственно и само оформление ячейки 

ТабДок.Область(ОбластьОформления.Верх, ОбластьОформления.Лево, ОбластьОформления.Низ, ОбластьОформления.Лево).ЦветФона = WebЦвета.Красный;

Код 1C v 8.х

 //Пример изменения цвета текста при выводе данных в табличный документ

        Таб.ВывестиСекцию("Контрагент");

        // Изменим Текст ячейки, имя которой заранее задали как "ТекстОСостоянии"

        Таб.Область("ТекстОСостоянии").Текст = "Хорошо ";

        // В зависимости от условия изменим Цвет Текста

        Если Раз<0 Тогда

          Таб.Область(Таб.ВысотаТаблицы(),9,Таб.ВысотаТаблицы(),9).ЦветТекста(255,0,0); 

           ИначеЕсли Раз>0 Тогда

          Таб.Область(Таб.ВысотаТаблицы(),9,Таб.ВысотаТаблицы(),9).ЦветТекста(0,0,255);

       КонецЕсли;

Для того, чтобы появилась возможность использовать свойство "Значение", необходимо явно присвоить свойству ячейки "СодержитЗначение" значение Истина или установить флажок "Содержит значение" в палитре свойств.

Для ячейки, у которой установлен признак "СодержитЗначение", можно задать тип значения, размещаемого в ячейке.

Следующий фрагмент демонстрирует, как можно управлять этими свойствами из встроенного языка://задаем нужный тип с помощью объекта "ОписаниеТипов"

Код 1C v 8.х

 МассивБулево = Новый Массив; 

МассивБулево.Добавить(Тип("Булево"));

ОписаниеТиповБулево = Новый ОписаниеТипов(МассивБулево);

//...

ПолеТабДок = ЭлементыФормы.тдПолеТабличногоДокумента; 

ПолеТабДок.Область("R3C3").СодержитЗначение = Истина; //указываем, что в ячейке будет значение

ПолеТабДок.Область("R3C3").ТипЗначения = ОписаниеТиповБулево; //указываем тип значения

ПолеТабДок.Область("R3C3").Значение = СпрНоменклатура.Услуга; //значение, типа "Булево" из справочника

Для ячейки табличного документа можно задавать формат вывода данных. Для этого используется свойство "Формат", которое содержит форматную строку. Приемы работы с форматной строкой полностью совпадают с функцией Формат()

Код 1C v 8.х

 ПолеТабДок = ЭлементыФормы.тдПолеТабличногоДокумента; 

ПолеТабДок.Область("R4C3").ТипЗначения = ОписаниеТиповДата; //указываем тип, ранее заданный для Даты

ПолеТабДок.Область("R4C3").Значение = ТекущаяДата();

//указываем форматную строку 

//будет выглядеть как "[031120-2315]-", если текущая дата '20-11-2003 23:15:00') 

ПолеТабДок.Область("R4C3").Формат = "ДФ=[ггММдд-ЧЧмм]-";

Элемент управления в табличном документе

Для ячейки, у которой установлен признак "СодержитЗначение", можно также задать элемент управления, который будет использоваться для редактирования этого значения.

Элемент управления можно назначить через палитру свойств или из встроенного языка с помощью метода "УстановитьЭлементУправления()". Чтобы проверить в программе, установлен ли элемент управления для конкретной ячейки, можно использовать свойство "ЭлементУправления", которое возвращает элемент управления, назначенный для ячейки.

Элементы управления, встроенные в ячейку, отображаются только при входе в режим редактирования значения. На приведенном ниже рисунке редактируемая ячейка обведена овалом и в ней отображается флажок:

Ниже показан пример установки элемента управления типа "Флажок" из встроенного языка://задаем нужный тип с помощью объекта "ОписаниеТипов"

Код 1C v 8.х

 МассивБулево = Новый Массив; 

МассивБулево.Добавить(Тип("Булево"));

ОписаниеТиповБулево = Новый ОписаниеТипов(МассивБулево);

...

ПолеТабДок = ЭлементыФормы.тдПолеТабличногоДокумента; 

ПолеТабДок.Область("R5C3").СодержитЗначение = Истина; //указываем, что в ячейке будет значение

ПолеТабДок.Область("R5C3").ТипЗначения = ОписаниеТиповБулево; //указываем ранее заданный тип

ПолеТабДок.Область("R5C3").Значение = СпрНоменклатура.Услуга; //значение, типа "Булево" из справочника

//а теперь указываем, что в ячейке будет отображаться флажок

ПолеТабДок.Область("R5C3").УстановитьЭлементУправления(Тип("Флажок"));

Для элементов управления, расположенных в табличном документе, расширяется набор свойств, методов и событий:

Разберем самые важные свойства и методы:

Свойство "ВстроенВЯчейку" имеет тип "булево" и говорит о том, что элемент управления встраивается в ячейку или просто привязывается к ней, о чем было рассказано выше.

Свойство "Видимость" позволяет показать или скрыть элемент управления.

Свойство "Значение" предоставляет доступ к значению, которое редактируется в элементе управления. Оно используется только для элементов управления, поддерживающих связь с данными.

Метод "Расположить" позволяет разместить элемент управления в конкретной области ячеек табличного документа. Именно этот метод был использован в вышеприведенном примере.

Код 1C v 8.х

  ПолеТабДок = ЭлементыФормы.тдПолеТабличногоДокумента;

ПолеТабДок.Область("R4C3").Защита = Истина;

Категория: Табличный документ

Парсер сайта на 1С Категория: Работа с Интернет, Почтой (Mail), FTP

Яндекс, Google, Рамблер Карты и 1С

Обработка демонстрирует возможности интеграции 1С с картографическими сервисами, в ней поддерживается работа трех поставщиков услуг / карт — Яндекс, Google. Рамблер.
Автор: Діма Головаченко - http://smaylukk.com.ua
но так вот сама обработка + еще 2 : Скачивать файлы может только зарегистрированный пользователь!

Код Модуля Обработки:

Код 1C v 8.х

 Перем СтруктураПоставщиковКарт Экспорт;

Перем СтруктураЧисел;



/////////////////////////РАБОТА С JSON //////////////////////////////////////////

Функция СформироватьСтрокуJSONИзМассива(Объект)

	

	СтрокаJSON = "[";

	

	Для каждого Элемент Из Объект Цикл

		СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент) + ",";

	КонецЦикла;

	

	Если Прав(СтрокаJSON, 1) = "," Тогда

		СтрокаJSON = Лев(СтрокаJSON, СтрДлина(СтрокаJSON)-1);

	КонецЕсли;

	

	Возврат СтрокаJSON + "]";

	

КонецФункции



Функция СформироватьСтрокуJSONИзСтруктуры(Объект)

	

	СтрокаJSON = "{";

	

	Для каждого Элемент Из Объект Цикл

		

		Если Элемент.Значение = "" Тогда

			Продолжить;

		КонецЕсли;

		

		СтрокаJSON = СтрокаJSON + """" + Элемент.Ключ + """" + ":";

		

		Если ТипЗнч(Элемент.Значение) = Тип("Строка") Тогда

			СтрокаJSON = СтрокаJSON + """" + URLEncode(Элемент.Значение) + """";

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Число") Тогда

			СтрокаJSON = СтрокаJSON + СтрЗаменить(Строка(Элемент.Значение), Символы.НПП, "");

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Булево") Тогда

			СтрокаJSON = СтрокаJSON + Формат(Элемент.Значение, "БЛ=false; БИ=true");

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Дата") Тогда

			// преобразование в unixtime

			СтрокаJSON = СтрокаJSON + Формат(ТекущаяДата() - Дата(1970,1,1,1,0,0), "ЧГ=0");

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Массив") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент.Значение);

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Структура") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент.Значение);

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("ТаблицаЗначений") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент.Значение);

			

		Иначе

			СтрокаJSON = СтрокаJSON + """" + URLEncode(Строка(Элемент.Значение)) + """";

			

		КонецЕсли;

		

		СтрокаJSON = СтрокаJSON + ",";

		

	КонецЦикла;

	

	Если Прав(СтрокаJSON, 1) = "," Тогда

		СтрокаJSON = Лев(СтрокаJSON, СтрДлина(СтрокаJSON)-1);

	КонецЕсли;

	

	Возврат СтрокаJSON + "}";

	

КонецФункции



Функция СформироватьСтрокуJSON(Объект) Экспорт

	

	СтрокаJSON = "";

	

	Если ТипЗнч(Объект) = Тип("Массив") Тогда

		СтрокаJSON = СформироватьСтрокуJSONИзМассива(Объект);

		

	ИначеЕсли ТипЗнч(Объект) = Тип("Структура") Тогда

		СтрокаJSON = СформироватьСтрокуJSONИзСтруктуры(Объект);

		

	ИначеЕсли ТипЗнч(Объект) = Тип("ТаблицаЗначений") Тогда

		// преобразуем таблицу значений в массив структур - работает дольше, но кода меньше

		// если нужна скорость, то нужно отдельно обработать таблицу значений

		

		СоставСтруктуры = "";

		Для каждого Колонка Из Объект.Колонки Цикл

			СоставСтруктуры = СоставСтруктуры + ?(ЗначениеЗаполнено(СоставСтруктуры), ",", "") + Колонка.Имя;

		КонецЦикла;

		

		МассивСтрок = Новый Массив;

		Для каждого Строка Из Объект Цикл

			СтруктураКолонок = Новый Структура(СоставСтруктуры);

			ЗаполнитьЗначенияСвойств(СтруктураКолонок, Строка);

			МассивСтрок.Добавить(СтруктураКолонок);

		КонецЦикла;

		

		СтрокаJSON = СформироватьСтрокуJSONИзМассива(МассивСтрок);

		

	КонецЕсли;

	

	Возврат СтрокаJSON;

	

КонецФункции



Процедура ЗаполнитьДанныеИзОтветаJSON(Результат, ТекстJSON, ТипДанных)

	

	ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));	// удалим открывающий символ структуры(массива)

	

	НомерЗначения = 0;

	

	Пока ТекстJSON <> "" Цикл

		

		ПервыйСимвол = Лев(ТекстJSON, 1);

		Если ПервыйСимвол = "{" Тогда

			// вложенная структура

			Значение = Новый Структура;

			ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Структура");

			

			Если ТипДанных = "Структура" Тогда

				Результат.Вставить("Значение" + ?(НомерЗначения = 0, "", НомерЗначения), Значение);

				НомерЗначения = НомерЗначения + 1;

			ИначеЕсли ТипДанных = "Массив" Тогда

				Результат.Добавить(Значение);

			КонецЕсли;

		

		ИначеЕсли ПервыйСимвол = "[" Тогда

			// вложенный массив

			Значение = Новый Массив;

			ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Массив");

			

			Если ТипДанных = "Структура" Тогда

				Результат.Вставить("Значение" + ?(НомерЗначения = 0, "", НомерЗначения), Значение);

				НомерЗначения = НомерЗначения + 1;

			Иначе

				Результат.Добавить(Значение);

			КонецЕсли;

			

		ИначеЕсли ПервыйСимвол = "}" И ТипДанных = "Структура" Тогда

			// структура закончилась

			ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			Если Лев(ТекстJSON, 1) = "," Тогда

				ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			КонецЕсли;

			

			Возврат;

			

		ИначеЕсли ПервыйСимвол = "]" И ТипДанных = "Массив" Тогда

			// массив закончился

			ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			Если Лев(ТекстJSON, 1) = "," Тогда

				ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			КонецЕсли;

			

			Возврат;

			

		Иначе

			

			Если ТипДанных = "Структура" Тогда

				//ПервыйКавычка = Ложь;

				//Если Лев(ТекстJSON, 1) = """" Тогда

				//	ПервыйКавычка = Истина;

				//КонецЕсли;

				

				Поз = Найти(ТекстJSON, ":");

				Если Поз = 0 Тогда

					// неверный формат, прервемся

					Прервать;

				КонецЕсли;

				

				//ПредпоследнийКавычка = Ложь;

				//Если Сред(ТекстJSON, Поз - 1, 1) = """" Тогда

				//	ПредпоследнийКавычка = Истина;

				//КонецЕсли;



				

				ИмяЗначения = СокрЛП(Лев(ТекстJSON, Поз - 1));

				ИмяЗначения = СтрЗаменить(ИмяЗначения, """", "");

				

				ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз+1));

								

				Если Лев(ТекстJSON, 1) = "{" Тогда

					// значение является структурой

					Значение = Новый Структура;

					ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Структура");

					

				ИначеЕсли Лев(ТекстJSON, 1) = "[" Тогда

					// значение является массивом

					Значение = Новый Массив;

					ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Массив");

					

				Иначе

					// обычное значение

					ПервыйКавычка = Ложь;

					ПредпоследнийКавычка = Ложь;

					Поз = 0;

					Для Сч = 1 По СтрДлина(ТекстJSON) Цикл

						Символ = Сред(ТекстJSON, Сч, 1);

						

						Если Символ = """" Тогда

							Если ПервыйКавычка Тогда

								ПредпоследнийКавычка = Истина;

							Иначе

								ПервыйКавычка = Истина;

							КонецЕсли;							

						КонецЕсли;

						

						Если (Символ = "," И ((ПервыйКавычка И ПредпоследнийКавычка) Или (Не ПервыйКавычка И Не ПредпоследнийКавычка))) ИЛИ Символ = "]" ИЛИ Символ = "}" Тогда

							Поз = Сч;

							Прервать;

						КонецЕсли;

					КонецЦикла;

					

					//ПредпоследнийКавычка = Ложь;

					//Если Сред(ТекстJSON, Поз - 1, 1) = """" Тогда

					//	ПредпоследнийКавычка = Истина;

					//КонецЕсли;

					

					Если Поз = 0 Тогда

						Значение = ТекстJSON;

						ТекстJSON = "";

						

					Иначе

						Значение = Лев(ТекстJSON, Поз - 1);

						Значение = СтрЗаменить(Значение, """", "");

						ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз + ?(Сред(ТекстJSON, Поз, 1) = ",", 1, 0)));						

					КонецЕсли;

					

					Значение = СокрЛП(Значение);

					

				КонецЕсли;

				

				Результат.Вставить(ИмяЗначения, Значение);

				

			ИначеЕсли ТипДанных = "Массив" Тогда

				

				// обычное значение

				Поз = 0;

				Для Сч = 1 По СтрДлина(ТекстJSON) Цикл

					Символ = Сред(ТекстJSON, Сч, 1);

					Если Символ = "," ИЛИ Символ = "]" ИЛИ Символ = "}" Тогда

						Поз = Сч;

						Прервать;

					КонецЕсли;

				КонецЦикла;

				

				//ПредпоследнийКавычка = Ложь;

				//Если Сред(ТекстJSON, Поз - 1, 1) = """" Тогда

				//	ПредпоследнийКавычка = Истина;

				//КонецЕсли;

				

				Если Поз = 0 Тогда

					Значение = ТекстJSON;

					ТекстJSON = "";

					

				Иначе

					Значение = Лев(ТекстJSON, Поз - 1);

					Значение = СтрЗаменить(Значение, """", "");

					ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз + ?(Сред(ТекстJSON, Поз, 1) = ",", 1, 0)));

					

				КонецЕсли;

				

				Значение = СокрЛП(Значение);

				

				Результат.Добавить(Значение);

				

			КонецЕсли;

				

			

		КонецЕсли;

		

	КонецЦикла;

	

КонецПроцедуры



Функция ЗаполнитьСтруктуруИзОтветаJSON(Знач ТекстJSON) Экспорт

	

	Результат = Новый Структура;

	

	ТекстJSON = СтрЗаменить(ТекстJSON, "\""", """");	// заменим последовательность \" на "

	//ТекстJSON = СтрЗаменить(ТекстJSON, """", "");		// а теперь удалим все кавычки

	

	Если Лев(ТекстJSON, 1) = "{" Тогда

		// начало структуры

		ЗаполнитьДанныеИзОтветаJSON(Результат, ТекстJSON, "Структура");

		

	ИначеЕсли Лев(ТекстJSON, 1) = "[" Тогда

		// начало массива

		МассивДанных = Новый Массив;

		ЗаполнитьДанныеИзОтветаJSON(МассивДанных, ТекстJSON, "Массив");

		

		Результат.Вставить("Значение", МассивДанных);

		

	КонецЕсли;

		

	Возврат Результат;

	

КонецФункции



Функция КодСимволаASCII(Символ) 

   КодUNICODE = КодСимвола(Символ); 

   Если ((КодUNICODE > 1039) И (КодUNICODE < 1104)) Тогда 

       Возврат (КодUNICODE - 848); 

   ИначеЕсли КодUNICODE = 8470 Тогда 

       Возврат 185; 

   ИначеЕсли КодUNICODE = 1105 Тогда 

       Возврат 184; 

   ИначеЕсли КодUNICODE = 1025 Тогда 

       Возврат 168; 

   Иначе 

       Возврат КодUNICODE; 

   КонецЕсли; 

КонецФункции



Функция URLEncode(value)



    table = "%00%01%02%03%04%05%06%07%08%09%0A%0B%0C%0D%0E%0F%10%11%12%13%14" +

            "%15%16%17%18%19%1A%1B%1C%1D%1E%1F%20%21%22%23%24%25%26%27%28" +

            "%29%2A%2B%2C%2D%2E%2F%30%31%32%33%34%35%36%37%38%39%3A%3B%3C" +

            "%3D%3E%3F%40%41%42%43%44%45%46%47%48%49%4A%4B%4C%4D%4E%4F%50" +

            "%51%52%53%54%55%56%57%58%59%5A%5B%5C%5D%5E%5F%60%61%62%63%64" +

            "%65%66%67%68%69%6A%6B%6C%6D%6E%6F%70%71%72%73%74%75%76%77%78" +

            "%79%7A%7B%7C%7D%7E%7F%80%81%82%83%84%85%86%87%88%89%8A%8B%8C" +

            "%8D%8E%8F%90%91%92%93%94%95%96%97%98%99%9A%9B%9C%9D%9E%9F%A0" +

            "%A1%A2%A3%A4%A5%A6%A7%A8%A9%AA%AB%AC%AD%AE%AF%B0%B1%B2%B3%B4" +

            "%B5%B6%B7%B8%B9%BA%BB%BC%BD%BE%BF%C0%C1%C2%C3%C4%C5%C6%C7%C8" +

            "%C9%CA%CB%CC%CD%CE%CF%D0%D1%D2%D3%D4%D5%D6%D7%D8%D9%DA%DB%DC" +

            "%DD%DE%DF%E0%E1%E2%E3%E4%E5%E6%E7%E8%E9%EA%EB%EC%ED%EE%EF%F0" +

            "%F1%F2%F3%F4%F5%F6%F7%F8%F9%FA%FB%FC%FD%FE%FF";

    

    result = "";        

            

    length = СтрДлина( value );        

    

    Для i = 1 По  length Цикл        

        symbol = Сред( value, i, 1 );        

        //code = КодСимвола( symbol );    

        code = КодСимволаASCII( symbol );

        result = result + Сред( table, code*3 + 1, 3 );        

    КонецЦикла;

    

    

    

    Возврат result;

КонецФункции

/////////////////////////РАБОТА С JSON //////////////////////////////////////////



//Функция декодирует полученный unicod текст - из ответа геокодера Рамблера

// в привычный нам

//Параметры:

// Строка

//Возвращаемое значение:

// Строка

Функция UnicodeEncode(Строка) Экспорт 

	Результат = Истина;

	

	Попытка

		//регулярное выражение

		Рег = Новый COMОбъект("VBScript.RegExp");

		Рег.IgnoreCase = Истина;

		Рег.Global = Истина;

		Рег.Multiline = Ложь;

		Рег.Pattern = "u[0-9a-f]+";

		Колекция = Рег.Execute(Строка);

		Для Каждого Элемент Из Колекция Цикл

			Если СтрДЛина(Элемент.value) = 1 Тогда

				Продолжить;

			КонецЕсли;		

			

			КодСимвола = ПереводЧислаИз16в10(Сред(ВРег(Элемент.value), 2));

			Символ = Символ(КодСимвола);

			Строка = СтрЗаменить(Строка, "\" + Элемент.value, Символ); 

		КонецЦикла;	

	Исключение

		Результат = Ложь;

		Сообщить("Ошибка преобразования из Unicode", СтатусСообщения.Информация);

	КонецПопытки;

	

	Возврат Результат;

КонецФункции



Функция ПереводЧислаИз16в10(Знач Значение)

	Результат = 0;

	

	//перевод значения в строку

	Если ТипЗнч(Значение) <> Тип("Строка") Тогда

		Значение = СокрЛП(Строка(Значение));

	КонецЕсли;

	

	МаксРазрядЦелых = 0;

	МаксРазрядЦелых = СтрДлина(Значение) - 1;

	

	н = МаксРазрядЦелых;

	Ин = 1;

	Пока н >= 0 Цикл

		ТекЗначение = СтруктураЧисел.Получить(Сред(Значение, Ин, 1)) * Pow(16, н);

		Результат = Результат + ТекЗначение;

		н = н - 1;

		Ин = Ин + 1;

	КонецЦикла;

	

	Возврат Результат;

КонецФункции



///////////////////////////

СтруктураПоставщиковКарт = Новый Соответствие;

СтруктураПоставщиковКарт.Вставить(0, "Яндекс");

СтруктураПоставщиковКарт.Вставить(1, "Гугл");

СтруктураПоставщиковКарт.Вставить(2, "2ГИС");

СтруктураПоставщиковКарт.Вставить(3, "Рамблер");





СтруктураЧисел = Новый Соответствие;

СтруктураЧисел.Вставить("0", 0);

СтруктураЧисел.Вставить("1", 1);

СтруктураЧисел.Вставить("2", 2);

СтруктураЧисел.Вставить("3", 3);

СтруктураЧисел.Вставить("4", 4);

СтруктураЧисел.Вставить("5", 5);

СтруктураЧисел.Вставить("6", 6);

СтруктураЧисел.Вставить("7", 7);

СтруктураЧисел.Вставить("8", 8);

СтруктураЧисел.Вставить("9", 9);

СтруктураЧисел.Вставить("A", 10);

СтруктураЧисел.Вставить("B", 11);

СтруктураЧисел.Вставить("C", 12);

СтруктураЧисел.Вставить("D", 13);

СтруктураЧисел.Вставить("E", 14);

СтруктураЧисел.Вставить("F", 15);

Код Формы Управляемой:

Код 1C v 8.2 УП

 



&НаКлиенте

Процедура НайтиАдрес(Команда)

	НайтиАдресНаКарте(ТекАдрес);

КонецПроцедуры



&НаКлиенте

Процедура ИнициализацияКарты(Команда)

	ИнициализироватьКарту();

КонецПроцедуры



&НаКлиенте

Процедура СправочнаяИнформация(Команда)

	Элементы.ГруппаСправка.Видимость = Не Элементы.ГруппаСправка.Видимость;

КонецПроцедуры



&НаКлиенте

Процедура Разработчик(Команда)

	ЗапуститьПриложение("http://smaylukk.com.ua/?lang=Ru");

КонецПроцедуры



&НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

	Объект.ТипКарты = Параметры.ТипКарты;

	ТекОбъект = РеквизитФормыВЗначение("Объект");

	Поставщик = ТекОбъект.СтруктураПоставщиковКарт.Получить(Объект.ТипКарты);

	

	Макет = ТекОбъект.ПолучитьМакет("Справка");

	ТекстСправки = Макет.ПолучитьОбласть("Справка" + Поставщик).Область().Текст;

	Справка = ТекстСправки;

КонецПроцедуры



&НаКлиенте

Процедура ПриОткрытии(Отказ)

	Элементы.ГруппаСправка.Видимость = Ложь;

	Заголовок = "Работа с картами. Поставщик - " + Поставщик;

	ИнициализироватьКарту();

КонецПроцедуры



&НаКлиенте

Процедура ПриЗакрытии()

	//удаление временных файлов

	Для Каждого ТекЭлемент Из МассивВременныхФайлов Цикл

		УдалитьФайлы(ТекЭлемент.Значение);

	КонецЦикла;

КонецПроцедуры



&НаКлиенте

//Процедура составляет  имя процедуры поставщика

// и запускает ее на исполнение

//Параметры:

// НачалоИмени - Строка

Процедура ВыполнитьПроцедуруПоставщика(ИмяПроцедуры)

	Выполнить ИмяПроцедуры;

КонецПроцедуры



&НаКлиенте

//процедура инициализирует карту постащика из макета

Процедура ИнициализироватьКарту()

	Текст = ПолучитьТекстМакета("Макет" + Поставщик);

	

	Эксплорер = Текст;

КонецПроцедуры



&НаСервере

Функция ПолучитьТекстМакета(ИмяМакета)

	Макет = РеквизитФормыВЗначение("Объект").ПолучитьМакет(ИмяМакета);

	Результат = Макет.ПолучитьТекст();

	Возврат Результат;

КонецФункции



&НаКлиенте

Процедура ОчисткаКарты()

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "Reset()";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



///////////////////////////////////////////////////////////////////////

///////////////////ГЕОКОДИРОВАНИЕ И ПОИСК АДРЕСА///////////////////////

///////////////////////////////////////////////////////////////////////



&НаКлиенте

Процедура НайтиАдресНаКарте(Адрес = "")	

	//поиск адреса

	Если Адрес = "" Тогда

		Адрес = "Москва";		

	КонецЕсли;

	

	// дальше пробуем с помощью геокодинга вывести данные поиска в таблицу

	ТаблицаАдресов.Очистить();

	

	ПоискАдреса(Адрес);

	Если Поставщик = "Яндекс" Тогда

		ПроизвестиГеокодинг_Яндекс();

	ИначеЕсли Поставщик = "Гугл" Тогда

		ПроизвестиГеокодинг_Гугл();

	ИначеЕсли Поставщик = "Рамблер" Тогда

		ПроизвестиГеокодинг_Рамблер();

	КонецЕсли;

КонецПроцедуры



&НаКлиенте

Процедура ПоискАдреса(Адрес)

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "FindAdres(""" + Адрес + """);";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаСервере

//Процедура выводит в таблицу данные геокдинга Яндекса

//

//Параметры:

// ТекАдрес - Строка

Процедура ПроизвестиГеокодинг_Яндекс()

	Яндекс = Новый HTTPСоединение("geocode-maps.yandex.ru");

	

	ВременныйФайл = КаталогВременныхФайлов() + "Yandex_geocode_" + СокрЛП(Новый УникальныйИдентификатор);

	Попытка

		Яндекс.Получить("/1.x/?geocode=" + ТекАдрес + "&results=10", ВременныйФайл);

	Исключение

		Сообщить("Ошибка при попытке геокодировать по яндексу адрес: " + ТекАдрес);

		Сообщить(ОписаниеОшибки());

		Возврат;

	КонецПопытки;

	

	ЧтениеXML = Новый ЧтениеXML;

	ЧтениеXML.ОткрытьФайл(ВременныйФайл);

	

	ПостроительDOM 			= Новый ПостроительDOM;

	ДокументДОМ 			= ПостроительDOM.Прочитать(ЧтениеXML);

	

	СписокText 				= ДокументДОМ.ПолучитьЭлементыПоИмени("text");

	СписокPos 				= ДокументДОМ.ПолучитьЭлементыПоИмени("pos");

		

	Если (СписокText.Количество() = 0) ИЛИ (СписокPos.Количество() = 0) Тогда

		Возврат;	

	КонецЕсли;

	

	Для ъ = 0 по СписокText.Количество()-1 Цикл

		Координаты = СписокPos[Ъ].ТекстовоеСодержимое;

		Разделитель = Найти(Координаты," ");

		Широта = Число(Сред(Координаты, Разделитель + 1));

		Долгота = Число(Лев(Координаты, Разделитель - 1));

		

		Если Широта = 0 ИЛИ Долгота = 0 Тогда

			Продолжить;

		КонецЕсли;

		

		стрАдрес = ТаблицаАдресов.Добавить();

		Если СписокText.Количество() > ъ Тогда

			стрАдрес.Адрес = СписокText[Ъ].ТекстовоеСодержимое;

			стрАдрес.Широта = Широта;

			стрАдрес.Долгота = Долгота;

		КонецЕсли;		

	КонецЦикла;	

	МассивВременныхФайлов.Добавить(ВременныйФайл);

КонецПроцедуры



&НаСервере

//Процедура выводит в таблицу данные геокдинга Гугл

//

//Параметры:

// ТекАдрес - Строка

Процедура ПроизвестиГеокодинг_Гугл()

	Гугл = Новый HTTPСоединение("maps.googleapis.com");

	

	ВременныйФайл = КаталогВременныхФайлов() + "Google_geocode_" + СокрЛП(Новый УникальныйИдентификатор);

	Попытка

		Гугл.Получить("/maps/api/geocode/xml?address=" + ТекАдрес + "&language=ru&sensor=false", ВременныйФайл);

	Исключение

		Сообщить("Ошибка при попытке геокодировать по Google адрес: " + ТекАдрес);

		Сообщить(ОписаниеОшибки());

		Возврат;

	КонецПопытки;

	

	ЧтениеXML = Новый ЧтениеXML;

	ЧтениеXML.ОткрытьФайл(ВременныйФайл);

	

	ПостроительDOM 			= Новый ПостроительDOM;

	ДокументДОМ 			= ПостроительDOM.Прочитать(ЧтениеXML);

	ТаблицаРезультатов = ДокументДОМ.ПолучитьЭлементыПоИмени("result");

	

	Если ДокументДОМ.ПолучитьЭлементыПоИмени("status")[0].ТекстовоеСодержимое <> "OK" ИЛИ ТаблицаРезультатов.Количество() = 0 Тогда 

		Возврат;

	КонецЕсли;

		

	Для ТекРезультат = 0 по ТаблицаРезультатов.Количество() -1 Цикл 

		

		СписокText 				= ТаблицаРезультатов[ТекРезультат].ПолучитьЭлементыПоИмени("formatted_address");

		ЭлементыШиротаДолгота = ТаблицаРезультатов[ТекРезультат].ПолучитьЭлементыПоИмени("location");

		Широта = ЭлементыШиротаДолгота[0].ПолучитьЭлементыПоИмени("lat")[0].ТекстовоеСодержимое;

		Долгота = ЭлементыШиротаДолгота[0].ПолучитьЭлементыПоИмени("lng")[0].ТекстовоеСодержимое;

		Если Широта = 0 ИЛИ Долгота = 0 Тогда

			Продолжить;

		КонецЕсли;

			

		стрАдрес = ТаблицаАдресов.Добавить();

		стрАдрес.Широта = Широта;

		стрАдрес.Долгота = Долгота;

		стрАдрес.Адрес = СписокText[0].ТекстовоеСодержимое;  

	КонецЦикла;

	МассивВременныхФайлов.Добавить(ВременныйФайл);

КонецПроцедуры



&НаСервере

//Процедура выводит в таблицу данные геокдинга Рамблер

//

//Параметры:

// ТекАдрес - Строка

Процедура ПроизвестиГеокодинг_Рамблер()

	ТемпАдрес = СтрЗаменить(ТекАдрес, " ", "+");

	

	Рамблер = Новый HTTPСоединение("maps.rambler.ru");	

	ВременныйФайл = КаталогВременныхФайлов() + "Рамблер_geocode_" + СокрЛП(Новый УникальныйИдентификатор);

	Попытка

		Рамблер.Получить("/search/?&a=search&q=" + ТемпАдрес + "&n=10", ВременныйФайл);

	Исключение

		Сообщить("Ошибка при попытке геокодировать по Рамблер адрес: " + ТекАдрес);

		Сообщить(ОписаниеОшибки());

		Возврат;

	КонецПопытки;

	

	а = 1;

	Т = Новый ТекстовыйДокумент;

	Т.Прочитать(ВременныйФайл);

	СтрокаОтвет = Т.ПолучитьТекст();

	Результат = РеквизитФормыВЗначение("Объект").UnicodeEncode(СтрокаОтвет);

	Если Результат Тогда

		СтруктураJSON = РеквизитФормыВЗначение("Объект").ЗаполнитьСтруктуруИзОтветаJSON(СтрокаОтвет);

	КонецЕсли;

	

	МассивРезультатов = СтруктураJSON.res;

	//обрабатываем элементы массива - только адреса. POI можно обработать отдельно пожеланию

	Для Каждого Результат Из МассивРезультатов Цикл

		Для Каждого ТекРезультат Из Результат.matches Цикл				

			стрАдрес = ТаблицаАдресов.Добавить();

			стрАдрес.Долгота = Число(ТекРезультат.x);

			стрАдрес.Широта = Число(ТекРезультат.y);

			Если Результат.type = "addr" Тогда  //Результат.type = "poi" - содержит в себе список точек интереса

				стрАдрес.Адрес = ТекРезультат.addr;

			Иначе

				стрАдрес.Адрес = ТекРезультат.name + " - " + ТекРезультат.addr;

			КонецЕсли;

		КонецЦикла;

	КонецЦикла;

	МассивВременныхФайлов.Добавить(ВременныйФайл);

КонецПроцедуры



&НаКлиенте

Процедура ОбратнПоискАдреса(Широта, Долгота, Адрес)

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "ReverseSearchAdres(" + Широта + "," + Долгота + ", """ + Адрес + """);";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

Процедура ТаблицаАдресовВыбор(Элемент, ВыбраннаяСтрока, Поле, СтандартнаяОбработка)

	Если ЗначениеЗаполнено(ТаблицаАдресов[ВыбраннаяСтрока].Широта) И ЗначениеЗаполнено(ТаблицаАдресов[ВыбраннаяСтрока].Долгота) Тогда

		СтандартнаяОбработка = Ложь;

	КонецЕсли;

	

	Широта = Формат(ТаблицаАдресов[ВыбраннаяСтрока].Широта, "ЧЦ=10; ЧДЦ=7; ЧРД=.; ЧРГ=");

	Долгота = Формат(ТаблицаАдресов[ВыбраннаяСтрока].Долгота, "ЧЦ=10; ЧДЦ=7; ЧРД=.; ЧРГ=");

	

	ОбратнПоискАдреса(Широта, Долгота, ТаблицаАдресов[ВыбраннаяСтрока].Адрес);

КонецПроцедуры



&НаКлиенте

Процедура ТекАдресПриИзменении(Элемент)

	НайтиАдресНаКарте(ТекАдрес);

КонецПроцедуры





///////////////////////////////////////////////////////////////////////

///////////////////МАРШРУТИЗАЦИЯ, КЛАСТЕРА И ПОЛИГОН///////////////////////////////////////

///////////////////////////////////////////////////////////////////////



&НаКлиенте

Процедура ЭксплорерПриНажатии(Элемент, ДанныеСобытия, СтандартнаяОбработка)

	ПолучитьКоординаты();

КонецПроцедуры



&НаКлиенте

Процедура ПостроитьМаршрут(Команда)

	Если ТаблицаТочек.Количество() <= 1 Тогда

		Предупреждение("Недостаточно точек для построение маршрута!");

		Возврат;

	КонецЕсли;

	

	Если Поставщик = "Яндекс" Тогда

		ПостроитьМаршрут_Яндекс();

	ИначеЕсли Поставщик = "Гугл" Тогда

		ПостроитьМаршрут_Гугл();

	ИначеЕсли Поставщик = "Рамблер" Тогда

		ПостроитьМаршрут_Рамблер();

	КонецЕсли;

КонецПроцедуры



&НаКлиенте

//Процедура выстраивает маршрут для Яндекса

//

//Параметры:

//

Процедура ПостроитьМаршрут_Яндекс()

	ПараметрыМаршрута = ПолучитьПараметрыМаршрутаЯндекс();

	

	ОчисткаКарты();

	

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "calcRoute(" + ПараметрыМаршрута + ")";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

//Функция получает массив точек, для передачи параметров в Яндекс

//

//Параметры:

//

//Возвращаемое значение:

// Строка

Функция ПолучитьПараметрыМаршрутаЯндекс()

	Результат = "";

	

	Результат = Результат + "[[" + СтрЗаменить(Строка(ТаблицаТочек[0].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[0].Долгота), ",", ".") + "],";

		

	Для Ин = 1 По ТаблицаТочек.Количество() - 2 Цикл

		Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ин].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ин].Долгота), ",", ".") + "],";

	КонецЦикла;

		

	Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Долгота), ",", ".") + "]]";

		

	Возврат Результат;

КонецФункции



&НаКлиенте

//Процедура выстраивает маршрут для Гугл

//

//Параметры:

//

Процедура ПостроитьМаршрут_Гугл()

	ПараметрыМаршрута = ПолучитьПараметрыМаршрутаГугл();

	

	ОчисткаКарты();

	

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "calcRoute(" + ПараметрыМаршрута + ")";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

//Функция получает массив точек, для передачи параметров в Гугл

//

//Параметры:

//

//Возвращаемое значение:

// Строка

Функция ПолучитьПараметрыМаршрутаГугл()

	Результат = "";

	ВнутрМассив = "";

	

	Результат = Результат + "[[" + СтрЗаменить(Строка(ТаблицаТочек[0].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[0].Долгота), ",", ".") + "],";

	

	Если ТаблицаТочек.Количество() = 2 Тогда

		Результат = Результат + "[],"; 

	Иначе

		Для Ин = 1 По ТаблицаТочек.Количество() - 2 Цикл

			ВнутрМассив = ВнутрМассив + "[" + СтрЗаменить(Строка(ТаблицаТочек[ин].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ин].Долгота), ",", ".") + "],";

		КонецЦикла;

		Результат = Результат + "[" + Сред(ВнутрМассив, 1, СтрДлина(ВнутрМассив) - 1) + "],";

	КонецЕсли;

	

	Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Долгота), ",", ".") + "]]";

		

	Возврат Результат;

КонецФункции



&НаКлиенте

//Процедура выстраивает маршрут для Рамблера

//

//Параметры:

//

Процедура ПостроитьМаршрут_Рамблер()

	ПараметрыМаршрута = ПолучитьПараметрыМаршрутаРамблер();

	

	ОчисткаКарты();

	

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "calcRoute(" + ПараметрыМаршрута + ")";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

//Функция получает массив точек, для передачи параметров в Рамблер

//

//Параметры:

//

//Возвращаемое значение:

// Строка

Функция ПолучитьПараметрыМаршрутаРамблер()

	Результат = "";

	

	Результат = Результат + "[[" + СтрЗаменить(Строка(ТаблицаТочек[0].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[0].Долгота), ",", ".") + "],";

		

	Для Ин = 1 По ТаблицаТочек.Количество() - 2 Цикл

		Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ин].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ин].Долгота), ",", ".") + "],";

	КонецЦикла;

		

	Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Долгота), ",", ".") + "]]";

		

	Возврат Результат;

КонецФункции



&НаКлиенте

Процедура СоздатьКластер(Команда)

	Если ТаблицаТочек.Количество() <= 1 Тогда

		Предупреждение("Недостаточно точек для построение кластера!");

		Возврат;

	КонецЕсли;

	

	ОчисткаКарты();

	

	ПостроитьКластера();

КонецПроцедуры



&НаКлиенте

Процедура ПостроитьКластера()

	Кол = ТаблицаТочек.Количество();

	Индекс = 1;

	Для Каждого ТекСтрока Из ТаблицаТочек Цикл

		Широта = формат(ТекСтрока.Широта, "ЧРД=.");

		Долгота = формат(ТекСтрока.Долгота, "ЧРД=.");

		СодержимоеТочки = "Содерижмое точки";  //опять же можно вставить свое название

		Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "addToPointArray(" + Широта + "," + Долгота + ", '" + ТекСтрока.Точка + "', """ + СодержимоеТочки + """);";

		Элементы.Эксплорер.document.getElementById("WebClient").click();

		

		Состояние("Обработан " + Индекс + " из " + кол);

		Индекс = Индекс + 1;

	КонецЦикла;

	

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "drawCluster();";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

Процедура ОчиститьВсе(Команда)

	ОчисткаКарты();

	ТаблицаТочек.Очистить();

КонецПроцедуры



&НаКлиенте

Процедура ОчиститьКарту(Команда)

	ОчисткаКарты();

КонецПроцедуры



&НаКлиенте

Процедура ОчиститьТаблицу(Команда)

	ТаблицаТочек.Очистить();

КонецПроцедуры



&НаКлиенте

//Процедура получает координаты установленной точки

Процедура ПолучитьКоординаты()

	Попытка

		ЧислоТип = Новый ОписаниеТипов("Число", Новый КвалификаторыЧисла(15, 12));

		

		КоординатаX = Элементы.Эксплорер.document.getElementById("CoordX").value;

		КоординатаX = ЧислоТип.ПривестиЗначение(КоординатаX);

		

		КоординатаY = Элементы.Эксплорер.document.getElementById("CoordY").value;

		КоординатаY = ЧислоТип.ПривестиЗначение(КоординатаY);

		

		Кол = ТаблицаТочек.Количество();

		Если КоординатаX > 0 И КоординатаY > 0 И (Кол = 0 Или КоординатаX <> ТаблицаТочек[Кол - 1].Широта И КоординатаY <> ТаблицаТочек[Кол - 1].Долгота) Тогда

			НоваяСтрока = ТаблицаТочек.Добавить();

			НоваяСтрока.Точка = "Точка" + ТаблицаТочек.Количество();

			НоваяСтрока.Широта = КоординатаX;

			НоваяСтрока.Долгота = КоординатаY;

		КонецЕсли;

	Исключение

	КонецПопытки;

КонецПроцедуры



&НаКлиенте

Процедура ПострениеПолигона(Команда)

	Если ТаблицаТочек.Количество() <= 1 Тогда

		Предупреждение("Недостаточно точек для построение полигона!");

		Возврат;

	КонецЕсли;

	

	ОчисткаКарты();

	

	ПостроитьПолигон();

КонецПроцедуры



&НаКлиенте

//Процедура выстраивает маршрут для Рамблера

//

//Параметры:

//

Процедура ПостроитьПолигон()

	МассивТочек = "[";

	Для Каждого ТекТочка Из ТаблицаТочек Цикл

		Широта = формат(ТекТочка.Широта, "ЧРД=.");

		Долгота = формат(ТекТочка.Долгота, "ЧРД=.");

		МассивТочек = МассивТочек + "[" + Широта + "," + Долгота + "],"; 

	КонецЦикла;

	МассивТочек = Сред(МассивТочек, 1, СтрДлина(МассивТочек) - 1) + "]";

	

	Цвет16 = Получить16Цвет();

	

	Название = "Полигон";//вставить свое 

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "createPolygon(" + МассивТочек + ", '" + Название + "', '" + Цвет16 + "');";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаСервере

//Функция возвращает значение случайного цвета в 16-ричном формате

//

//Параметры:

//  нет

//Возвращаемое значение:

//  Строка

Функция Получить16Цвет()

	Результат = "";

	

	Строка16 = "0123456789ABCDEF";

	ГСЧ = Новый ГенераторСлучайныхЧисел;

	Результат = "#";

	Для н = 1 По 6 Цикл

		м = ГСЧ.СлучайноеЧисло(1, 16);

		Результат = Результат + Сред(Строка16, м, 1);

	КонецЦикла;

	

	Возврат Результат;

КонецФункции

Категория: COM-объекты, WMI, WSH

Передача файлов и данных на веб-сервер из 1С методами GET и POST Категория: Работа с Интернет, Почтой (Mail), FTP

Краткий пример работы с OpenOffice.org Writer и Microsoft Office Word

Обработка демонстрирует простейший пример работы с 2-мя текстовыми процессорами - OpenOffice.org Writer и Microsoft Office Word. Нужно запустить файл обработки, в качестве шаблона она будет использовать файл "Primer.doc", который находится в одном каталоге с обработкой: Скачивать файлы может только зарегистрированный пользователь!

Файл Шаблона - Primer.doc:
От: {Организация}
Кому: {Контрагент}
Ждем акт сверки взаиморасчетов!
Директор /{Директор}/

Необходимо заменить в шаблоне ключевые слова в скобках {}, на указанные значения, вот примерный код обработки:

Код 1C v 7.x

 

//рдТаблицаЗамен - Таблица значений:

// {Организация} ООО "Контора"

// {Контрагент} ООО "Должник"

// {Директор} Дядя Вася

ПечатьИзШаблона(рдТаблицаЗамен, "Primer.doc");



// Функция преобразует Windows имя файла в URL OpenOffice                      

Функция ПреобразоватьВURL(ИмяФайла)

	Возврат "file:///" + СтрЗаменить(ИмяФайла, "\", "/"); 	

КонецФункции



Функция ОбработкаФайлаШаблона(ИмяШаблона) Экспорт

	                                              

	ИмяФайла = КаталогВременныхФайлов() + "doc.tmp";	                                                                                      

	Путь = "";	Имя = "";

	ФайлОбработки = РасположениеФайла(Путь, Имя);

	

	КаталогШаблонов = Путь;       

	ПолноеИмяШаблона = КаталогШаблонов + ИмяШаблона;

	

	РезультатОбработки = 0;

	                         

	// Проверка на существование 

	ЕстьШаблон = 0;

	Если ФС.СуществуетФайл(КаталогШаблонов + ИмяШаблона) = 0 Тогда  

		Сообщить("Файл " + ИмяШаблона + " не найден в каталоге шаблонов печатных форм! Обратитесь к системному администратору!", "!!!");    					   		

	Иначе

		ЕстьШаблон = 1;

	КонецЕсли;                  

	

	// Копирование во временный каталог

	                        

	Если ЕстьШаблон = 1 Тогда 

		ФС.КопироватьФайл(ПолноеИмяШаблона, ИмяФайла, 0);

	КонецЕсли;                                                            

	

	// Проверка копирования

	

	Если ФС.СуществуетФайл(ИмяФайла) = 1 Тогда 

		РезультатОбработки = 1;  

	Иначе

		Сообщить("Не удалось скопировать шаблон во временный файл.");

	КонецЕсли;

	

	Возврат РезультатОбработки; 	

	

КонецФункции



Процедура ОткрытьТекстовыйПроцессор(ИмяФайла, ТаблицаЗамен)  

	

	ТекПроцессор = рдТекстовыйПроцессор.ПолучитьЗначение(рдТекстовыйПроцессор.ТекущаяСтрока());

	

	Если ТекПроцессор = "OOoWriter" Тогда 

		

		// Открыть OpenOffice 

		

		ServiceManager = СоздатьОбъект("com.sun.star.ServiceManager");

		Desktop        = ServiceManager.createInstance("com.sun.star.frame.Desktop");

		

		

		Scr = СоздатьОбъект("MSScriptControl.ScriptControl");

		Scr.Language="javascript";

		Scr.Eval("Args=new Array()");

		Args = Scr.Eval("Args"); 

		Scr.AddObject("ServiceManager", ServiceManager);

		

		// Откроем шаблон

		

		ТекстовыйПроцессор = Desktop.LoadComponentFromURL(ПреобразоватьВURL(ИмяФайла), "_blank", 0, Args); 

		

		// Заменяем ключевые поля на нужные значения

		                         

		Replace = ТекстовыйПроцессор.CreateReplaceDescriptor();

		

		Для x=1 По ТаблицаЗамен.КоличествоСтрок() Цикл

			

			Replace.SearchString  = ТаблицаЗамен.ПолучитьЗначение(x, 1);

			Replace.ReplaceString = ТаблицаЗамен.ПолучитьЗначение(x, 2);

			ТекстовыйПроцессор.ReplaceAll(Replace);

			

		КонецЦикла;

		

	Иначе                        		

		

		// Открываем MS Office Word

		

		Попытка

			ТекстовыйПроцессор = СоздатьОбъект("Word.Application"); 

		Исключение 			

			Сообщить("Не удалось создать объект Microsoft Office Word!", "!!!");

			Возврат;			

		КонецПопытки;        

		

		// Открываем шаблон

		

		ТекстовыйПроцессор.Visible = 0; 

		ТекстовыйПроцессор.Documents.Open(ИмяФайла,, -1);

		Fnd = ТекстовыйПроцессор.ActiveDocument.Range().Find;

		Fnd.ClearFormatting();

		Fnd.Forward = -1;  

		

		// Заменяем ключевые поля на нужные значения

		

		ТаблицаЗамен.ВыбратьСтроки();

		Пока ТаблицаЗамен.ПолучитьСтроку() = 1 Цикл  

			Fnd.Execute(ТаблицаЗамен.Найти,,,,,,,,, ТаблицаЗамен.Заменить, 2);   

		КонецЦикла;  

		

		ТекстовыйПроцессор.Visible = -1;    

		ТекстовыйПроцессор.Activate(); 

		

	КонецЕсли;

	



КонецПроцедуры

//*****************************************************************************

Процедура ПечатьИзШаблона(ТаблицаЗамен, ИмяФайлаШаблона) Экспорт

	            

	// Проверим, есть ли нужный шаблон	

	Если ОбработкаФайлаШаблона(ИмяФайлаШаблона) = 0 Тогда

		Возврат;

	КонецЕсли;              

	

	ИмяФайла = КаталогВременныхФайлов() + "doc.tmp";	

	

	// Открываем в текстовом процессоре файл шаблона	

	ОткрытьТекстовыйПроцессор(ИмяФайла, ТаблицаЗамен);

	

КонецПроцедуры

Категория: Работа с Microsoft Office и OpenOffice

Скрипт принудительного завершения процессов 1С на всех компьютерах

В примере "1cv7s.exe", для 8-ки замениете на "1cv8.exe"

Код VBS

 

'Скрипт демонстрирует возможность принудительного завершения процессов 1С

'на всех компьютерахуказанного домена. Данный код можно применять непосредственно перед пакетным запуском 1С:Предприятия,

'требующим монопольного входа в базу данных (например, при резервном копировании).



'ВНИМАНИЕ! Задайте нужное значение переменной "DomainName"!



'ВНИМАНИЕ! Для успешной работы скрипта его желательно запускать с правами администратора домена.



'ВНИМАНИЕ! Чтобы опробовать скрипт, не производя деструктивных действий, достаточно закомментировать

'оператор "Proc.Terminate".



Option Explicit

On Error Resume Next



Dim DomainName 'Имя домена

DomainName = "MYDOMAIN"



Dim StrResult 'строка результата работы всей программы

StrResult = StrResult & CStr(Now) & " начало работы скрипта" & VbCrLf



Dim ADSI

Set ADSI = GetObject("WinNT://" & DomainName)

ADSI.Filter = Array("computer")



Dim Comp 'компьютер

Dim WMI 'объект WMI

Dim Proc 'процесс



Dim CurrName 'имя текущего компьютера

CurrName = GetNameComp()



'Цикл по компьютерам домена

For Each Comp In ADSI

    If Comp.Name <> CurrName Then

        Set WMI = GetObject("winmgmts:{ImpersonationLevel=Impersonate}!\\" & Trim(Comp.Name) & "\Root\CIMV2")

        If Err.Number=0 Then

            'Цикл по процессам компьютера

            For Each Proc In WMI.ExecQuery("S_elect * FROM Win32_Process WHERE Name = '1cv7s.exe'")

                StrResult = StrResult & _

                            CStr(Now) & " Computer=" & Comp.Name & " PID=" & Proc.ProcessId & _

                            VbCrLf

                'Завершение процесса

                Proc.Terminate

            Next 'Цикл по процессам компьютера

        Else 'Не удалось соединиться с компьютером

            If Err.Number <> 462 Then 'The remote server machine does not exist or is unavailable

                StrResult = StrResult & _

                  	        "    " & CStr(Now) & " Computer=" & Comp.Name & " ERROR " & Err.Number & _

                      	    VbCrLf

            End If

        End If

        Err.Clear

    End If

Next 'Цикл по компьютерам домена



StrResult = StrResult & CStr(Now) & " конец работы скрипта" & VbCrLf



'Отображение результата

ShowInNotepad("Процессы 1cv7s.exe:" & VbCrLf & VbCrLf & StrResult)

'==========================================================================

'Процедура отображает переданную строку в блокноте

Sub ShowInNotepad(StrToFile)

    Dim FSO 'Объект файловой системы Scripting.FileSystemObject

    Dim TempPath 'Путь к временному файлу

    Dim TxtFile 'Поток текстового файла

    

    Set FSO = CreateObject("Scripting.FileSystemObject")

    TempPath = GetTempPath() & "\" & FSO.GetTempName

    Set TxtFile = FSO.CreateTextFile(TempPath)

    TxtFile.WriteLine(StrToFile)

    TxtFile.Close

    CreateObject("WScript.Shell").Run "notepad.exe " & TempPath

    WScript.Sleep 1000

    FSO.DeleteFile TempPath

End Sub 'ShowInNotepad

'==========================================================================

'Функция возвращает путь к каталогу временных файлов текущего пользователя

Function GetTempPath()

    GetTempPath = CreateObject("WScript.Shell").ExpandEnvironmentStrings("%TEMP%")

End Function 'GetTempPath

'==========================================================================

'Функция возвращает имя текущего компьютера

Function GetNameComp()

    GetNameComp = CreateObject("WScript.Network").ComputerName

End Function 'GetNameComp

Категория: Администрирование