В версии 8.3.9.2170 была усилена безопасность - теперь система запрашивает подтверждение на запуск внешних обработок, расширений и прочее. Видимо после трояна: Внимание! Первый троян для 1С -запускающий шифровальщика-вымогателя

Реализован механизм защиты от опасных действий. При выполнении потенциально опасного действия система выдает предупреждение, содержащее информацию о выполняемом действии и потенциальной опасности этого действия. К потенциально опасным действиям относятся:

• Загрузка внешнего отчета, обработки или расширения конфигурации.
• Загрузка или обновление конфигурации/расширения.
• Доступ из внешнего отчета/обработки или расширения к следующим возможностям:
• Исполнение команды операционной системы.
• Управление пользователями.
• Загрузка внешней компоненты.

Пользователь имеет возможность разрешить или отклонить потенциально опасное действие. Если действие разрешено, в ряде случаев может потребоваться повторно выполнить разрешенное действие. 

Сообщение выглядит так:

Предупреждение безопасности

Открывается "" из файла " C:\.......epf". Рекомендуется обращать внимание на источник, из которого был получен данный файл. Если с источником нет договоренности о разработке дополнительных модулей, или есть сомнения в содержимом файла, то его не рекомендуется открывать, поскольку это может нанести вред компьютеру и данным. Разрешить открывать данный файл. ДА, НЕТ

Решение:

В конфигураторе в свойствах пользователя ИБ убрать флажок "Защита от опасных действий".

Из документации: Отключение механизма защиты от опасных действий

В ряде случае необходимо отключить механизм защиты от опасных действий. Для этого можно воспользоваться следующими возможностями:

1. Выключить флажок Защита от опасных действий (ЗащитаОтОпасныхДействий) в свойствах конкретного пользователя. Это отключит защиту для этого пользователя.

2. Воспользоваться параметром ЗащитаОтОпасныхДействий методов Подключить() менеджеров внешних обработок (отчетов). В этом случае имеется возможность загрузить внешнюю обработку (отчет) без запросов пользователя.

3. Воспользоваться свойством ЗащитаОтОпасныхДействий объекта РасширениеКонфигурации перед вызовом метода Записать() этого объекта.

4. Воспользоваться параметром DisableUnsafeActionProtection файла conf.cfg. В этом случае механизм защиты от опасных действий будет отключаться для всех пользователей информационных баз, строки соединения которых удовлетворяют указанным маскам.

Отключение защиты от опасных действий выполняется по следующим правилам (в указанном порядке):

1. Защита считается отключенной, если у текущего пользователя сброшен флажок Защита от опасных действий.

2. Защита считается отключенной, если строка соединения с информационной базой удовлетворяет одному из шаблонов, указанных в параметре DisableUnsafeActionProtection файла conf.cfg.

3. Если внешняя обработка (отчет) подключается с явным образом отключенной защитой с помощью параметра ЗащитаОтОпасныхДействий.

4. Если защита явным образом отключена с помощью свойства расширения ЗащитаОтОпасныхДействий. 

Установили мини сервер 1С на Cent OS 7 + Postgree SQL , Подключились через консоль, создали базу, загрузи DT и при открытии программы:

Ошибка загрузки библиотеки libWand.so по причине:Библиотека не обнаружена. Часть функций будет недоступна.

Обратитесь к разделу справочной системы «1С:Предприятие - Работа пользователя – Особенности работы в Linux – Внешние библиотеки»

Решение:

Ошибку libwand.so лечится установкой старого пакета libwand

Для 1С 32х:

apt-get install imagemagick-6.q16:i386

apt-get install imagemagick:i386

Для 1С 64х

apt-get install imagemagick-6.q16

apt-get install imagemagick

+ В интернете нашлись рекомендации 1Справда они от 2013г)

Если при запуске из командной строки /opt/1C/v8.3/i386/1cv8 (или для 64разр /opt/1C/v8.3/x86_64/1cv8) ругается на отсутствие libWand.so то:

либо не установлен imagemagick, либо отсутствует символьная ссылка на эту библиотеку.

Во втором случае ищем что у нас есть:

sudo find /usr/lib/ -name "libMagickWand.so*" -print

получим например:

/usr/lib/libMagickWand.so.3.0.0

/usr/lib/libMagickWand.so.3

создадим ссылку на любой из них

ln -s -T /usr/lib/libMagickWand.so.3 /usr/lib/libWand.so

В данном примере хочу привести несколько универсальных функций по выгрузке таблицы значений в файл и дальнейшего чтения из файла:

Порядок программных действий при выгрузке в файл выглядит так:

• Подготавливаем таблицу значений (выгружаем из табличной части, выбираем колонки);
• Конвертируем таблицу значений в табличный документ;
• Сохраняем табличный документ в MXL.

При загрузке таблицы порядок действий такой:

• Читаем из файла табличный документ;
• Конвертируем табличный документ в таблицу значений;
• Используем эту таблицу значений в своих целях (загружаем в табличную часть).

Соответственно файл для хранения данных таблицы имеет расширение *.mxl.

Основные функции для реализации поставленной задачи следующие:

ПреобразоватьТДвТЗ – Функция преобразования табличного документа в таблицу значений.

ПреобразоватьТЗвТД – Функция обратного преобразования таблицы значений в табличный документ.

ПрочитатьТЗИзMXL – Читает из файла данные, определяет колонки таблицы и преобразует эти данные в таблицу значений.

ЗаписатьТЗВMXL – Преобразует таблицу значений в табличный документ и записывает его в файл.

 // Преобразовать табличный документ в таблицу значений.

//

// Параметры:

//	ТабДок - <ТабличныйДокумент> - Исходный табличный документ;

//	СтруктураКолонок - <Структура>, <ТаблицаЗначений> - Структура колонок;

//	НачалоСтрока - <Число> - Строка начала области;

//	НачалоСтолбец - <Число> - Столбец начала области;

//	КонецСтрока - <Число> - Строка конца области;

//	КонецСтолбец - <Число> - Столбец конца области.

//	

// Возвращаемое значение:

//	<ТаблицаЗначений> - Полученная таблица значений.

//

Функция ПреобразоватьТДвТЗ(ТабДок, СтруктураКолонок, Знач НачалоСтрока = Неопределено, Знач НачалоСтолбец = Неопределено, Знач КонецСтрока = Неопределено, Знач КонецСтолбец = Неопределено) Экспорт

 

	// Определение габаритов таблицы

	Если НачалоСтрока = Неопределено И НачалоСтолбец = Неопределено Тогда

		НачалоСтрока = 1;

		НачалоСтолбец = 1;

	КонецЕсли;

 

	Если НачалоСтрока = Неопределено Тогда

		НачалоСтрока = 1;

		Пока НЕ ТабДок.Область(НачалоСтрока, НачалоСтолбец).СодержитЗначение 

		 И НачалоСтрока < ТабДок.ВысотаТаблицы 

		Цикл

			НачалоСтрока = НачалоСтрока + 1;

		КонецЦикла;

	ИначеЕсли НачалоСтолбец = Неопределено Тогда

		НачалоСтолбец = 1;

		Пока НЕ ТабДок.Область(НачалоСтрока, НачалоСтолбец).СодержитЗначение 

		 И НачалоСтолбец < ТабДок.ШиринаТаблицы

		Цикл

			НачалоСтолбец = НачалоСтолбец + 1;

		КонецЦикла;

	КонецЕсли;

 

	КонецСтрока = ?(КонецСтрока = Неопределено, ТабДок.ВысотаТаблицы, КонецСтрока);

	КонецСтолбец = ?(КонецСтолбец = Неопределено, ТабДок.ШиринаТаблицы, КонецСтолбец);

 

	// Преобразование

	ЭтоТаблица = (ТипЗнч(СтруктураКолонок) = Тип("ТаблицаЗначений"));

	ТабЗначений = ПолучитьТаблицуВывода(СтруктураКолонок);

 

	Для ИндексСтроки = НачалоСтрока По КонецСтрока Цикл

		СтрокаТЗ = ТабЗначений.Добавить();

 

		ИндексКолонки = НачалоСтолбец;

		Для Каждого Колонка Из СтруктураКолонок Цикл

			НаименованиеКолонки = ?(ЭтоТаблица, Колонка.Наименование, Колонка.Ключ);

			пИндексКолонки = ?(ЭтоТаблица, Колонка.СтолбецОтчёт, ИндексКолонки);

 

			Если ТабДок.Область(ИндексСтроки, пИндексКолонки).СодержитЗначение Тогда

				СтрокаТЗ[НаименованиеКолонки] = ТабДок.Область(ИндексСтроки, пИндексКолонки).Значение;

			Иначе

				СтрокаТЗ[НаименованиеКолонки] = ТабДок.Область(ИндексСтроки, пИндексКолонки).Текст;

			КонецЕсли;

 

			ИндексКолонки = ИндексКолонки + 1;

		КонецЦикла;

	КонецЦикла;

 

	Возврат ТабЗначений;

КонецФункции;



// Преобразовать таблицу значений в табличный документ.

//

// Параметры:

//	ТабЗначений - <ТаблицаЗначений> - Исходная таблица значений;

//	ТабДок - <ТабличныйДокумент> - Полученный табличный документ. Если параметр не задан, 

//	 то документ создаётся заново и возвращается функцией;

//	НачалоСтрока - <Число> - Строка начала области;

//	НачалоСтолбец - <Число> - Столбец начала области;

//	ВыводитьЗаголовки - <Булево> - Определяет выводить ли имена колонок или нет.

//	

// Возвращаемое значение:

//	<ТабличныйДокумент> - Полученный табличный документ (возвращает параметр "ТабДок").

//

Функция ПреобразоватьТЗвТД(ТабЗначений, ТабДок = Неопределено, Знач НачалоСтрока = Неопределено, Знач НачалоСтолбец = Неопределено, ВыводитьЗаголовки = Ложь) Экспорт

 

	Если ТабДок = Неопределено Тогда

		ТабДок = Новый ТабличныйДокумент;

	КонецЕсли;

 

	// Определение габаритов таблицы

	НачалоСтрока = ?(НачалоСтрока = Неопределено, 1, НачалоСтрока);

	НачалоСтолбец = ?(НачалоСтолбец = Неопределено, 1, НачалоСтолбец);

 

	// Преобразование

	ИндексСтроки = НачалоСтрока;

	Если ВыводитьЗаголовки Тогда

		ИндексКолонки = НачалоСтолбец;

		Для Каждого Колонка Из ТабЗначений.Колонки Цикл

			ТабДок.Область(ИндексСтроки, ИндексКолонки).Текст = ?(ПустаяСтрока(Колонка.Заголовок), Колонка.Имя, Колонка.Заголовок);

			ИндексКолонки = ИндексКолонки + 1;

		КонецЦикла;

		ИндексСтроки = ИндексСтроки + 1;

	КонецЕсли;

 

	Для Каждого Элемент Из ТабЗначений Цикл

		ИндексКолонки = НачалоСтолбец;

		Для Каждого Колонка Из ТабЗначений.Колонки Цикл

			ТабДок.Область(ИндексСтроки, ИндексКолонки).СодержитЗначение = Истина;

			ТабДок.Область(ИндексСтроки, ИндексКолонки).ТипЗначения = Новый ОписаниеТипов(Колонка.ТипЗначения);

			ТабДок.Область(ИндексСтроки, ИндексКолонки).Значение = Элемент[Колонка.Имя];

			ИндексКолонки = ИндексКолонки + 1;

		КонецЦикла;

		ИндексСтроки = ИндексСтроки + 1;

	КонецЦикла;

 

	Возврат ТабДок;

КонецФункции;



// Читает табличный документ из файла MXL и преобразует его в таблицу значений.

//

// Параметры:

//	ИмяФайла - <Строка> - Путь к файлу MXL;

//	СтруктураКолонок - <Структура>, <ТаблицаЗначений> - Структура колонок. Если этот параметр

//		не задан, то структура колонок формируется из самого табличного документа;

//	ЕстьЗаголовок - <Булево> - Есть ли первая строка с заголовками или нет.

//	

// Возвращаемое значение:

//	<ТаблицаЗначений> - Полученная таблица значений.

//

Функция ПрочитатьТЗИзMXL(ИмяФайла, СтруктураКолонок = Неопределено, ЕстьЗаголовок = Истина) Экспорт

 

	ТабДок = Новый ТабличныйДокумент;

	ТабДок.Прочитать(ИмяФайла);

 

	Если СтруктураКолонок = Неопределено И ЕстьЗаголовок Тогда

		СтруктураКолонок = Новый Структура;

		Для ИндексКолонки = 1 По ТабДок.ШиринаТаблицы Цикл

			Обл1 = ТабДок.Область(1, ИндексКолонки);

			Обл2 = ТабДок.Область(2, ИндексКолонки);

			ИмяКолонки = СокрЛП(Обл1.Текст);

			ИмяКолонки = ?(Найти(ИмяКолонки, " ") > 0, СтрЗаменить(ТРег(ИмяКолонки), " ", ""), ИмяКолонки);

			СтруктураКолонок.Вставить(ИмяКолонки, ?(Обл2.СодержитЗначение, Обл2.ТипЗначения, Новый ОписаниеТипов));

		КонецЦикла;

	ИначеЕсли СтруктураКолонок = Неопределено И НЕ ЕстьЗаголовок Тогда

		СтруктураКолонок = Новый Структура;

		Для ИндексКолонки = 1 По ТабДок.ШиринаТаблицы Цикл

			Обл2 = ТабДок.Область(1, ИндексКолонки);

			ИмяКолонки = "К" + Формат(ИндексКолонки, "ЧДЦ=0; ЧН=0; ЧГ=0");

			СтруктураКолонок.Вставить(ИмяКолонки, ?(Обл2.СодержитЗначение, Обл2.ТипЗначения, Новый ОписаниеТипов));

		КонецЦикла;

	КонецЕсли;

 

    Таблица = ПреобразоватьТДвТЗ(ТабДок, СтруктураКолонок, ?(ЕстьЗаголовок, 2, 1), 1);

 

	Возврат Таблица;

КонецФункции;



// Сохраняет таблицу значений в файле в виде табличного документа.

//

// Параметры:

//	ИмяФайла - <Строка> - Путь к файлу MXL;

//	ТабЗначений - <ТаблицаЗначений> - Сохраняемая таблица значений;

//	ЕстьЗаголовок - <Булево> - Есть ли первая строка с заголовками или нет.

//

Процедура ЗаписатьТЗВMXL(ИмяФайла, ТабЗначений, ЕстьЗаголовок = Истина) Экспорт

 

	ТабДок = ПреобразоватьТЗвТД(ТабЗначений, Неопределено, 1, 1, ЕстьЗаголовок);

	ТабДок.Записать(ИмяФайла, ТипФайлаТабличногоДокумента.MXL);

 

КонецПроцедуры;   

Еще небольшой набор функций для вывода таблицы значений в табличный документ. После формирования табличного документа, - сохраняем его в файл mxl.

Табличный документ можно сохранить a файлы следующих типов:

• ANSITXT - Текстовый документ
• DOCX - документ MS Word
• HTML
• HTML3
• HTML4
• HTML5
• MXL
• MXL7
• ODS - Файл Open Office
• PDF - файл Acrobat Readr
• TXT - Текстовый документ
• XLS - файл Excel
• XLS95 - файл Excel95
• XLS97 - файл Excel97
• XLSX - файл Excel2010

 // Получаем таблицу значения из файла. 

Функция ЗагрузитьТЗизФайла(ИмяФайла)    

    Путь = КаталогВременныхФайлов() + ИмяФайла; 

    Текст = Новый ЧтениеТекста(Путь, КодировкаТекста.UTF8); 

    стрТЗ = Текст.Прочитать(); 

    Текст.Закрыть(); 

    // получим таблицу значений из строки

    ТЗ = ЗначениеИзСтрокиВнутр(стрТЗ);    

    Возврат ТЗ;    

КонецФункции    



// Заполнить ячейки в строке  значениями 

//

Функция ЗаписьТЗ2ТабДок(записьТЗ,НомерСтроки,ТабличныйДокумент)

    НомерКолонки = 1;

    Символ160 = Символ(160);    

    // цикл по колонкам таблицы

    // РезультатЗапроса.Колонки.Количество()    // - количество колонок

    Для каждого полеТЗ из ЗаписьТЗ цикл 

        // значения ячейки в Excel

        типПоляТЗ = ТипЗнч(полеТЗ);

        если типПоляТЗ = Тип("Число") тогда             

            полеТЗ=Строка(полеТЗ); 

            полеТЗ=СтрЗаменить(полеТЗ,Символ160,"");

            полеТЗ=СтрЗаменить(полеТЗ,",",".");

        иначеесли типПоляТЗ = Тип("Строка") тогда      

        иначе        

            полеТЗ = строка(полеТЗ);

        КонецЕсли;    

        имяОбласти = "R" + номерСтроки + "C" + НомерКолонки;

        имяОбласти = СтрЗаменить(имяОбласти,Символ(160),"");         

        Ячейка = ТабличныйДокумент.Область(имяОбласти);

        Ячейка.Текст = полеТЗ;

        НомерКолонки = НомерКолонки + 1;

    КонецЦикла;            

КонецФункции



// Заполнить наименованиями колонок таблицу

Функция НаимКолонок2Mxl(ТаблицаЗначений,ТабличныйДокумент)

    // массКолонки = новый массив();

    номерСтроки=1;

    номКолонки=1; 

    ТабличныйДокумент = новый ТабличныйДокумент;

    // цикл по коллекции колонок

    Для НомКол=0 по ТаблицаЗначений.Колонки.Количество() - 1 Цикл

        //Сообщить(Колонка.Имя + "(" + Колонка.ТипЗначения + ")" );            

        имяКолонки=ТаблицаЗначений.Колонки[НомКол].Имя;

        //ТабличныйДокумент.Область(

        имяОбласти = "R" + номерСтроки + "C" + номКолонки;

        имяОбласти = СтрЗаменить(имяОбласти,Символ(160),"");         

        Ячейка = ТабличныйДокумент.Область(имяОбласти);

        //значениеЯчейки = СтрЗаменить(имяОбласти,Символ(160),"");         

        Ячейка.Текст = имяКолонки;

        // на основе текущего шрифта сделаем Жирный

        ЖирныйШрифт = ?(ЖирныйШрифт = Неопределено,Новый Шрифт(Ячейка.Шрифт,,,Истина),ЖирныйШрифт);         

        Ячейка.Шрифт = ЖирныйШрифт;

        номКолонки = номКолонки + 1;        

    КонецЦикла;

КонецФункции





// Заполнить построчно табличный документ

Функция Таблица2Mxl(ТаблицаЗначений,ТабличныйДокумент)

    //Выборка = РезультатЗапроса.Выбрать();

    НомСтр=1; // заполняем данными начиная со 2-й строки    

    // цикл по строкам таблицы

    Для каждого записьТЗ из ТаблицаЗначений Цикл

        НомСтр = НомСтр + 1;

        // цикл по колонкам таблицы        

        ЗаписьТЗ2ТабДок(записьТЗ,НомСтр,ТабличныйДокумент);         

    КонецЦикла;    

КонецФункции



// Таблица значений в табличный документ

Функция ТаблицаЗначений2Mxl(ТаблицаЗначений,ФайлMxl)

    ТабличныйДокумент = новый ТабличныйДокумент;

    // вывести колонки

    НаимКолонок2Mxl(ТаблицаЗначений,ТабличныйДокумент);

    // вывести содержимое таблицы    

    Таблица2Mxl(ТаблицаЗначений,ТабличныйДокумент);

    ТабличныйДокумент.Записать(ФайлMxl,ТипФайлаТабличногоДокумента.MXL);

    ТабличныйДокумент.Показать(ФайлMxl,ФайлMxl);

    Возврат 0;

КонецФункции





Функция    Тест_ВыгрузитьТЗвMxl();

    файл_мТЗИсходныеДанные = "мТЗИсходныеДанные.dat";        

    ТЗ = ЗагрузитьТЗизФайла(файл_мТЗИсходныеДанные);    

    ФайлMxl = КаталогВременныхФайлов() + СтрЗаменить(файл_мТЗИсходныеДанные,".dat",".mxl");  

    ТаблицаЗначений2Mxl(ТЗ,ФайлMxl);

КонецФункции



Тест_ВыгрузитьТЗвMxl();   

Пример выгруженной таблицы значений в файл:

В рамках выполнения проекта столкнулся с интересной задачей ускорения загрузки данных из других информационных баз. Задача загрузки данных предполагала выполнение к внешней базе несвязанных между собой запросов, результаты которых помещаются в одну таблицу значений. Когда на оптимизацию запроса рука уже не поднималась, приступил к ускорению загрузки с помощью распараллеливания процессов. Отмечу, что элементы кода в данном посте приведены для клиент-серверного варианта и укрупнено для общего понимания подхода.

Что у нас в 1с Предприятии 8.2 имеется для распараллеливания & это фоновые задачи. Метод, который будет вызываться в фоновой задаче, должен быть прописан в серверном общем модуле и быть экспортным. Естественно нам понадобиться в фоновую задачу передавать и забирать значения.

В моем случае передача значений в фоновую задачу происходила через параметры. Метод ЗагрузитьИзВИБ имеет два параметра это ВходнойПараметр и АдресВХранилище. ВходнойПараметр это структура, в которую сгружаются все данные, необходимые для проведения загрузки. АдресВХранилище это адрес во временном хранилище, по которому будет передан результат загрузки. Сам код метода фонового задания выглядит так:

 Процедура ЗагрузитьИзВИБ(ВходнойПараметр,АдресВХранилище) Экспорт

    //Из структуры перегоняем данные в переменные

    ТаблицаДляЗаполнения = ВходнойПараметр.ТаблицаДляЗаполнения;

    ДанныеОбъекта = ВходнойПараметр.ДанныеОбъекта;



    //Тут идет собственно загрузка данных

    ВыполнитьЗагрузку(ТаблицаДляЗаполнения,ДанныеОбъекта);



    //Возвращаем данные из фоновой задачи в хранилище

    ПоместитьВоВременноеХранилище(ТаблицаДляЗаполнения, АдресВХранилище);

КонецПроцедуры   

Зачем нам в фоновую задачу передавать адрес во временном хранилище. Наша фоновая задача должна куда-то положить результат, причем так чтобы мы знали где его потом взять.

Для того чтобы запустить фоновые задачи выполняется следующий код:

 МассивАдресовВХранилище = Новый Массив;

МассивЗапущенныхЗаданий = Новый Массив;

Сч = 1;

Пока Сч <=  КоличествоПотоков Цикл

    Ключ = Новый УникальныйИдентификатор;

    ВходнойПараметр = Новый Структура;

    ВходнойПараметр.Вставить("ТаблицаДляЗаполнения",ТаблицаДляЗаполнения);

    ВходнойПараметр.Вставить("ДанныеОбъекта",ДанныеОбъекта);



    //Подготовим адрес в хранилище

    АдресВХранилище = ПоместитьВоВременноеХранилище(Неопределено);

    МассивПараметров = Новый Массив;

    МассивПараметров.Добавить(ВходнойПараметр);

    МассивПараметров.Добавить(АдресВХранилище);

    МассивАдресовВХранилище.Добавить(АдресВХранилище);



    МассивЗапущенныхЗаданий.Добавить(ФоновыеЗадания.Выполнить("ОбщийМодульСервер.ЗагрузитьИзВИБ",МассивПараметров, Ключ, "Загрузка"));

    Сч = Сч + 1;

КонецЦикла;   

Перед запуском фоновой задачи через ФоновыеЗадания.Выполнить() мы формируем массив параметров. Значения из массива параметров переходят в метод фонового задания в качестве параметров. В МассивЗапущенныхЗаданий хранятся все фоновые задачи, которые мы запустили. Теперь надо подождать их ожидания.

ФоновыеЗадания.ОжидатьЗавершения(МассивЗапущенныхЗаданий);

После того как все задачи были завершены, можем приступить к получению из них данных. Для этого мы проходим по всем адресам в хранилище, которые хранятся в массиве МассивАдресовВХранилище. После получения результата фонового задания перегоняем его в общую таблицу.

 Для Каждого ТекАдресВХранилище Из МассивАдресовВХранилище Цикл

    ТекТаблица = ПолучитьИзВременногоХранилища(ТекАдресВХранилище);





    Для Каждого ТекСтрокаДанные Из ТекТаблица Цикл

        НоваяСтрока = НашаОбщаяТаблица.Добавить();

        ЗаполнитьЗначенияСвойств(НоваяСтрока,ТекСтрокаДанные);

    КонецЦикла;

КонецЦикла;   

Вопрос определения оптимального количества потоков выходит за рамки данного поста. А после получения некоторых результатов на рабочих данных пока что выходит и за рамки моего сознания . Но если у вас есть идеи как посчитать нужное количество потоков, пишите в комментариях, с радостью почитаю.

Источник

PostgreSQL напрямую "из коробки" применяться для использования с 1С Предприятем не может. Необходима именно адаптированная версия от 1С, превращающая PostgreSQL в блокировочник, причем нужно понимать, что блокировки будут накладываться на всю таблицу сразу. Если нужны блокировки на уровне записей, включаем в 1С режим управляемых блокировок и прописываем их в конфигурации ручками. Вывод: необходимо скачать специальный дистрибутив с сайта 1С или взять на диске ИТС.

Установка

Сама установка особых затруднений не вызывает, обратить внимание нужно на правильную инициализацию базы данных, а именно настройку локали, изменить потом это можно только повторной начальной инициализацией. Например, база 1С с украинскими региональными установками в СУБД с установленной русской локалью не загрузится. Да и проблемы с сортировкой потом не нужны. Поэтому делаем init в соответствии с нужным языком.

Для русского языка

initdb --locale=ru_RU.UTF-8 --lc-collate=ru_RU.UTF-8 --lc-ctype=ru_RU.UTF-8 --encoding=UTF8 -D /db/postgresql

Для украинского языка

initdb --locale=uk_UA.UTF-8 --lc-collate=uk_UA.UTF-8 --lc-ctype=uk_UA.UTF-8 --encoding=UTF8 -D /db/postgresql

где /db/postgresql ваш каталог данных PostgreSQL. Кодировка, конечно же, UTF-8.

Подробный вариант пересоздания кластера

1.Необходимо выдать полные права на папку в которую мы установили PostgreSQL, обычно это C:\Program Files\PostgreSQL

2.Из под админских прав запускаем cmd. Если это делаете в win7, то запускаем от Администратора.

3.Создаем папку где будет храниться кластер. Например d:\postgredata.

md d:\postgredata

4.Проводим инициализацию кластера вручную с указанием пути где он будет находиться.

“C:\Program Files\PostgreSQL\9.1.2-1.1C\bin\initdb.exe” -D d:\postgredata --locale=Russian_Russia --encoding=UTF8 -U postgres

5.Удаляем службу PostgreSQL, которая была установлена в ходе установки.

sc delete pgsql-9.1.2-1.1C-x64

Где pgsql-9.1.2-1.1C-x64 – Это название службы. Если не знаете название точно, можно посмотреть свойствах службы “PostgreSQL Database Server…” (Пуск – Панель управления – Администрирование – Службы )

6.Создаем новый сервис с указанием нашего кластера

“C:\Program Files\PostgreSQL\9.1.2-1.1C\bin\pg_ctl” register -N pgsql -U postgresql -P пароль -D d:/postgredata

7.Теперь заходим в службы. Пуск – Панель управления – Администрирование – Службы и стартуем нашу службу.

Ошибка СУБД: ERROR: new encoding (UTF8) is incompatible with the encoding of the template database (WIN1251).

HINT: Use the same encoding as in the template database, or use template0 as template.

Вы выбрали неправильную локаль при установке СУБД (WIN1251) для сервера и клиента, нужно изменить на UTF-8 в конфигурации или переустановить СУБД со следующими параметрами:

Внимание при установке НЕ выбирайте локаль Настройки ОС, выбирайте из списка Russian, Russia

Настройка PostgreSQL

Следует помнить о рекомендации 1С не использовать в запросах конструкции ПОЛНОЕ ВНЕШНЕЕ СОЕДИНЕНИЕ и заменять его, используя, например, комбинацию из нескольких левых соединений. Известна также проблема с потерей производительности в запросах, где применяется соединение с виртуальной таблицей СрезПоследних, к ней рекомендуется делать отдельные запросы и сохранять результаты во временных таблицах.

Настройка конфигурации производится редактированем файла postgresql.conf.

Наиболее важные параметры

effective_cache_size = 0,5 от ёмкости RAM

fsync = off отключаем сброс на диск после каждой транзации (Внимание! Применять только при использовании надежного UPS, есть опасность потери данных при неожиданном отключении)

synchronous_commit = off отключаем синхронную запись в лог (риски теже, что и у fsync)

wal_buffers = 0,25 от ёмкости RAM

После настройки не забываем выполнить перезапуск службы:

service postgresql restart

Настройка сети

Для подключения клиентов 1С к серверу извне и работы сервера баз данных, на файрволе, должны быть открыты следующие порты:

Агент сервера (ragent) & tcp:1540 Главный менеджер кластера (rmngr) & tcp:1541 Диапазон сетевых портов, для динамического распределения рабочих процессов & tcp:1560&1591, tcp:5432 & Postgresql. Создадим правило через стандартный интерфейс, либо с помощью команды:

netsh advfirewall firewall add rule name="1Cv8-Server" dir=in action=allow protocol=TCP localport=1540,1541,5432,1560-1590 enable=yes profile=ANY remoteip=ANY interfacetype=LAN

Теперь с другого компьютера мы спокойно запускаем клиент 1С:Предприятия, добавляем существующую информационную базу newdb. Не забываем про лицензии, программной / аппаратной защиты. 

Резервное копирование

Создание дампа базы данных делаем командой

su postgres -c 'pg_dump -U postgres -Fc -Z9 -f baza1.sql baza1'

Восстановление из дампа

su postgres -c 'pg_restore -U postgres -c -d baza1 -v baza1.sql'

Периодическое обслуживание

Рекомендуется настроить AVTO VACUUM в файле конфигурации. Но не пренебрегаем и запуском через планировщик принудительной команды.

su postgres -c '/usr/bin/vacuumdb --dbname=$i --analyze --full --quiet'

Просмотр активности PostgreSQL

Иногда полезно видеть чем сейчас занимается сервер. Поможет такая конструкция:

watch -n 1 'ps auxww | grep ^postgres'

 Процедура ПреобразоватьТЗвТЗсОписаниемТипов(ТЗ)

	ТипизированнаяТЗ = Новый ТаблицаЗначений;

    Для й=1 По Тз.Количество() Цикл ТипизированнаяТЗ.Добавить(); //Создаем строки

    КонецЦикла;    

    

    ДЗТипов = Новый ДеревоЗначений;

    ДЗТипов.Колонки.Добавить("ИмяКолонки");

    ДЗТипов.Колонки.Добавить("ТипЗначений");

    

    Для Каждого Колонка из Тз.Колонки Цикл

        СтрокаКолонки = ДЗТипов.Строки.Добавить();

        СтрокаКолонки.ИмяКолонки = Колонка.Имя;

        

        ТекСТрокаТипа = СтрокаКолонки.Строки.Добавить();

        ТекСТрокаТипа.ИмяКолонки = Колонка.Имя; //Заполняется для красоты

        ТекСТрокаТипа.ТипЗначений = ТипЗнч(тз[0][Колонка.Имя]);

        Для Каждого СтокаТЗ из Тз Цикл

            ТекТип = ТипЗнч(СтокаТЗ[Колонка.Имя]);

            Если НЕ ТекТип = ТекСТрокаТипа.ТипЗначений Тогда

                Если СтрокаКолонки.Строки.Найти(ТекТип, "ТипЗначений")=Неопределено Тогда

                    ТекСТрокаТипа = СтрокаКолонки.Строки.Добавить();

                    ТекСТрокаТипа.ИмяКолонки = Колонка.Имя;//Заполняется для красоты

                    ТекСТрокаТипа.ТипЗначений = ТекТип;

                КонецЕслИ;

            КонецЕслИ;

        КонецЦикла;

        

        МассивТипов = СтрокаКолонки.Строки.ВыгрузитьКолонку("ТипЗначений");

        ТипизированнаяТЗ.Колонки.Добавить(Колонка.Имя, Новый ОписаниеТипов(МассивТипов),Колонка.Заголовок);

        ТипизированнаяТЗ.ЗагрузитьКолонку(Тз.ВыгрузитьКолонку(Колонка),Колонка.Имя);

    КонецЦикла;

КонецПроцедуры   

Источник

Меня часто спрашивают: КАК в 1C Бухгалтерии 3.0 обновить классификатор банков?

Все просто, идем по меню:

"Администрирование - Поддержка и обслуживание - "Загрузить классификатор банков"

После этого классификатор будет загружен и обновлен. Можете по БИКу искать нужный вам банк.

Бывает, что при нажатии Загрузить классификатор банков выходит сообщение: Классификатор актуален и ничего не грузит

Тогда необходимо в Меню (маленький черный треугольник в верхнем левом углу) 

Все функции - Справочники - Классификатор банков - жмем "Загрузить классификатор"

У кого нету строки "Все функции": Меню - Сервис - Параметры - ставим галочку "Отображать "Все функции"

Можно просто перенести все данные из Проф версии в базовую используя обработку ЗагрузкаВыгрузкаXML. Но мы пойдем другим путем:

1. Версии проф и базовой версии должны быть одинаковыми

2. Сохраняем конфигурацию Базовой версии в файл.

3. В конфигураторе ПРОФ версии снимаемся с поддержки.

4. Загружаем конфигурацию без проверок. ("Загрузить конфигурацию из файла") показываем файл из п.2

5. Получаем базовую версию с поддержкой обновлений.

Подробнее:

Для перехода с профессиональной версии 1С на базовую потребуется произвести несколько действий:

1) Создать файл 1Cv8.cf (из базовой версии) для этого зайти в конфигуратор (Бухгалтерия Предприятия Базовая)

Конфигурация - Конфигурация базы данных - сохранить конфигурацию БД в файл - сохраняем в папку файл 1Cv8.cf

2) Заходим в конфигуратор Бухгалтерия Предприятия (ПРОФ)

Конфигурация - поддержка - настройка поддержки - включить возможность изменения - кнопка снять с поддержки - Да - закрыть 

Конфигурация - Загрузить конфигурацию из файла - указываем ранее сохранённый файл 1Cv8.cf из Базовой конфигурации 

 - Да

 - Да

поставить на поддержку - ДА (после вылезет табличка) - Выполнить - ОК.

Всё готово, теперь это Базовая версия, все документы должны быть на своём месте.

На виртуальном сервере установлена CentOS 6.5 и сервер 1С 8.3 - все 64 бит. 

Нужно опубликовать 1С на веб сервере, инструкция примерно такая:

1) Ставишь httpd.

2) Создаешь папки, где будут хранится конф. файлы, например /var/www/html/baza

3) Прописываешь базу штатной утилиткой:

* заходим в папку с 1с (для х32): cd /opt/1c/v8.2/i386

* ./webinst -apache22 -wsdir baza -dir '/var/www/html/baza/' -connStr 'Srvr="1c.mydomain.com";Ref="baza"' -confPath /etc/httpd/conf/httpd.conf

* проверям, что в созданном файлике /var/www/html/baza/default.vrd и нет лишних (двойных) "/" . У меня они каждый раз появлялись и каждый раз мне проще было их удалить чем вникать, где в команде я напортачил. (также стоит проверить /etc/httpd/conf/httpd.conf, база прописывается в самый конец конфига).

4) ставишь на папку права для пользователя apache: chown apache:apache /var/www/html/baza и перезагружаешь апач.

Вот, в общем то и все.

Делаем публикацию 1С на веб сервере:

 ./webinst -apache22 -wsdir base -dir '/var/www/html/base/' -connStr 'Srvr=5.101.113.142;Ref=tur;' -confPath /etc/httpd/conf/httpd.conf   

Публикация прошла успешно. 

В файл httpd.conf добавляется

LoadModule _1cws_module "/opt/1C/v8.3/i386/wsap22.so"

# 1c publication

Alias "/base" "/var/www/html/base/"

<Directory "/var/www/html/base/">

AllowOverride All

Options None

Order allow,deny

Allow from all

SetHandler 1c-application

ManagedApplicationDescriptor "/var/www/html/base/default.vrd"

</Directory>

содержимое default.vrd

<?xml version="1.0" encoding="UTF-8"?>

http://v8.1c.ru/8.2/virtual-resource-system"

xmlns:xs="http://www.w3.org/2001/XMLSchema"

xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"

base="/base"

ib="Srvr=5.101.113.142;Ref=tur;"/>

Перезапускам Апач и apache2: Syntax error on line 202 of /etc/apache2/apache2.conf: Syntax error on line 1 of /etc/apache2/httpd.conf:

Cannot load /opt/1C/v8.3/i386/wsap22.so into server: /opt/1C/v8.2/i386/wsap22.so: wrong ELF class: ELFCLASS32

Т.е. ему не нравится вот это

LoadModule _1cws_module "/opt/1C/v8.2/i386/wsap22.so"

Выглядит это так:

Проблема в том, что 64-битный апач не хочет работать ( нужно заменить его на 32-битный!

Порядок действий такой:

1. Нужно подкорректировать файлы репозитария, чтобы он загружал 32-битные версии: Открываем /etc/yum.repos.d/, копируете эти файлы для архива и исправляете в текущих $basearch на i686.

2. чистим кэш так: yum clean all   или в папке  /var/cache/yum/

3. yum install httpd.i686

4. reboot

После перезапуска 

./webinst -apache22 -wsdir base -dir '/var/www/html/base/' -connStr 'Srvr=5.101.113.142;Ref=tur;' -confPath /etc/httpd/conf/httpd.conf

Задаем владельца для файла default.vrd:

chown apache:apache /var/www/html/base/default.vrd

Перезагрузим сервера 1с и апач:

/etc/init.d/httpd restart

/etc/init.d/srv1cv82 restart

Еще раз перезагружаем 

 проверяем - Все будет ОК

В одном документе для расчета потребовалось получать данные из отчета на СКД, реализовал следующим образом:

 	//Програмное формирование отчета СКД	

	СхемаОст = Отчеты.ТоннажПоЭкспедиторам.ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных");

	

	КомпоновщикНастроекНастройки = Новый КомпоновщикНастроекКомпоновкиДанных;

	КомпоновщикНастроекНастройки.Инициализировать(Новый ИсточникДоступныхНастроекКомпоновкиДанных(СхемаОст));

	КомпоновщикНастроекНастройки.ЗагрузитьНастройки(СхемаОст.НастройкиПоУмолчанию); 

	

	КомпоновщикНастроекНастройки.Настройки.ПараметрыДанных.УстановитьЗначениеПараметра("НачалоПериода", НачалоМесяца(МесяцРасчета));

	КомпоновщикНастроекНастройки.Настройки.ПараметрыДанных.УстановитьЗначениеПараметра("КонецПериода", КонецМесяца(МесяцРасчета));

	

	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;

	МакетКомпоновкиДанных = КомпоновщикМакета.Выполнить(СхемаОст, КомпоновщикНастроекНастройки.Настройки, , , Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));

	ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных; 

	ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновкиДанных);

	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;

	

	ДанныеТЗ = Новый ТаблицаЗначений;

	ПроцессорВывода.УстановитьОбъект(ДанныеТЗ);

	ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);

	

	ТоннажПоЭкспедиторам.Очистить();

	//	ДанныеТЗ.ВыбратьСтроку();		

	Для каждого СтрокаТЗ Из ДанныеТЗ Цикл

		Если ЗначениеЗаполнено(СтрокаТЗ.Экспедитор) и СтрокаТЗ.Доставка=Неопределено Тогда

		нСтр = ТоннажПоЭкспедиторам.Добавить();

		ЗаполнитьЗначенияСвойств(нСтр,СтрокаТЗ);

		нСтр.Сотрудник=СтрокаТЗ.Экспедитор; 

	Иначе

		Продолжить;

	КонецЕсли;	

	КонецЦикла; 

   

У управляемой формы реквизиты заведенные как реквизиты формы, при закрытии и открытии ее заново могут сохраняться и восстанавливаться, достаточно только поставить напротив галочку сохранять и в свойствах формы выбрать "АвтоматическоеСохранениеДанныхВНастройках" - Использовать.

Подробнее в этой статье Как сохранять и восстанавливать значения реквизитов на форме? и там же пример для обычных форм.

А что же делать с реквизитами, которые выступают в роли реквизитов объектов ?

у них такой настройки нет нет - напишем:

 &НаСервере

Процедура ВосстановитьНастройки()

КлючОбъекта = "ЗагрузкаИЗPDF_All4CF.ru";

КлючНастроек = "ЗагрузкаИЗPDF_All4CF.ru";

ОписаниеНастроек = "ЗагрузкаИЗPDF_All4CF.ru";

ИмяПользователя = "";



ЗначениеНастроек = ХранилищеОбщихНастроек.Загрузить(КлючОбъекта, КлючНастроек, ОписаниеНастроек, ИмяПользователя);



Если ТипЗнч(ЗначениеНастроек) = Тип("Соответствие") Тогда

	Объект.Склад = ЗначениеНастроек.Получить("Склад");

	Объект.Организация = ЗначениеНастроек.Получить("Организация");	

	Объект.ПутьКPDF2TXT = ЗначениеНастроек.Получить("ПутьКPDF2TXT");

	Объект.ПутьКPDF = ЗначениеНастроек.Получить("ПутьКPDF");

КонецЕсли;

КонецПроцедуры





&НаКлиенте

Процедура ПриОткрытии(Отказ)

	 ВосстановитьНастройки();

КонецПроцедуры	





&НаСервере

Процедура СохранитьНастройки()  

КлючОбъекта = "ЗагрузкаИЗPDF_All4CF.ru";

КлючНастроек = "ЗагрузкаИЗPDF_All4CF.ru";

ОписаниеНастроек = "ЗагрузкаИЗPDF_All4CF.ru";

ИмяПользователя = "";





Настройки = Новый Соответствие;

Настройки.Вставить("ПутьКPDF2TXT", Объект.ПутьКPDF2TXT);

Настройки.Вставить("ПутьКPDF", Объект.ПутьКPDF);

Настройки.Вставить("Склад", Объект.Склад);

Настройки.Вставить("Организация", Объект.Организация);



ХранилищеОбщихНастроек.Сохранить(КлючОбъекта, КлючНастроек, Настройки, ОписаниеНастроек, ИмяПользователя);

КонецПроцедуры  





&НаКлиенте

Процедура ПередЗакрытием(Отказ, СтандартнаяОбработка)

	  СохранитьНастройки();

КонецПроцедуры   

Открыв обработку и заполним поля закрываем ее, при следующем открытии все поля заполнены из сохраненных настроек:

При разработке конфигурации, для упрощении ввода документов потребовалось настроить ввод номенклатуры по совпадению любой части наименования!

В 1С 8.3 по умолчанию настройки справочника номенклатуры такие:

При такой настройке, механизм поиска в справочнике номенклатуры работает так:

 - в справочнике

- в документе вводим первые символы Пета и видим такой результат подсказки:

Но, такой поиск не удобен и менеджеры захотели подбирать номенклатуру по артикулу, например 1320

Для этого изменим настройки указав поиск по Любой части и включив полнотекстовый поиск:

Сохраняем конфигурацию и в режиме предприятие обновляем Полнотекстовый поиск: Меню - Все функции - Стандартные  - Управление полнотекстовый поиском

После этого пробуем в документе выполнить поиск по 1320 и видим:

Все Менеджеры пищат как дети на новогодней елке!

Пока писал эту статью нашел в интернете другое решение для платформы 8.2:

СправочникМенеджер.<Имя справочника> (CatalogManager.<Имя справочника>)

ОбработкаПолученияДанныхВыбора (ChoiceDataGetProcessing)

Синтаксис:

ОбработкаПолученияДанныхВыбора(<ДанныеВыбора>, <Параметры>, <СтандартнаяОбработка>)

В модуле менеджера справочника "Номенклатура" пишем:

 Процедура ОбработкаПолученияДанныхВыбора(ДанныеВыбора, Параметры, СтандартнаяОбработка)

    

    Запрос = Новый Запрос;

    Запрос.Текст = 

        "ВЫБРАТЬ

        |    Номенклатура.Ссылка

        |ИЗ

        |    Справочник.Номенклатура КАК Номенклатура

        |ГДЕ

        |    Номенклатура.Наименование ПОДОБНОНаименование";

        

        

    Запрос.УстановитьПараметр("Наименование", "%" + Параметры.СтрокаПоиска + "%");

    

    РезультатЗапроса = Запрос.Выполнить();

    Таблица = РезультатЗапроса.Выгрузить();

    Массив = Таблица.ВыгрузитьКолонку("Ссылка");

    

    ДанныеВыбора = Новый СписокЗначений;

    ДанныеВыбора.ЗагрузитьЗначения(Массив);

    СтандартнаяОбработка = Ложь;

    

КонецПроцедуры   

В  обработчике - ОбработкаПолученияДанныхВыбора(ДанныеВыбора, Параметры, СтандартнаяОбраблтка) для нас важны все три параметра. В первый "ДанныеВыбора" мы загружаем наш список номенклатуры, полученный по нашему алгоритму. Из параметра "Параметры" мы получим значение введенное пользователем, а третьему параметру "СтандартнаяОбработка" мы должны поставить значение "Ложь"(отключаем стандартный алгоритм системы).

В результате одной небольшой процедурой мы полностью решили поставленную задачу.

Обновлял клиенту бухгалтерию 2.0 и в момент сохранения изменений, на этапе Таблица регистрации изменении конфигурации(1000, 2000 или 3000 и т.д.)

Нажав подробнее, видим: Ошибка SDBL: Выход за пределы размерности результата

Первое что приходит в голову - Перезапуск агента 1С (можно и сервер целиком перезагрузить)

После перезапуска пробую обновить и получаю другую ошибку:

Каталог не обнаружен 'v8srvr://sql/acc_main/configsave/e0666db2-45d6-49b4-a200-061c6ba7d569.6b9d6525-ee94-4e13-b73d-82d3e8e8441d'

по причине: Каталог не обнаружен 'ConfigSave\e0666db2-45d6-49b4-a200-061c6ba7d569.6b9d6525-ee94-4e13-b73d-82d3e8e8441d'

по причине: Ошибка СУБД: Microsoft SQL Server Native Client 11.0: Журнал транзакций для базы данных "acc_main" переполнен. Причина: "LOG_BACKUP". HRESULT=80040E14, SQLSrvr: SQLSTATE=42000, state=2, Severity=11, native=9002, line=1

Открываем SQL Server Management Studio

Это ошибка Microsoft SQL Server - переполняется лог транзакций и не очищается. Урезать его возможно различными способами, в том числе и с помощью стандартной оснастки, но не всегда данная операция получается, и размер файла лога остается прежним. Как вариант предлагаю следующее решение из двух строчек( где acc_main - название базы Бух)

  USE acc_main

ALTER DATABASE acc_main SET RECOVERY SIMPLE

DBCC SHRINKFILE (acc_main, 50);

ALTER DATABASE acc_main SET RECOVERY FULL    

После выполнения пробуем еще раз обновиться, и.... база обновлена

Вообще, пока ждал обновления, поискал в интернет - что пишут по этому поводу. Вот несколько основных решений:

1. Перезагрузить службу сервера 1С Предприятия или сервер целиком
2. Очистить кеш сервера
3. Обновить платформу 1С на более свежий релиз платформы 1С. Для этого вы можете воспользоваться инструкцией по установки платформы 1С.
4. В менеджере SQL сервера очистить таблицы _ConfigChngR и _ConfigChngR_ExtProps (используя команду delete)

Действия из этого списка - успешно помогут решить проблему и вернуться к полноценной работе.

В 1С есть такая замечательная вещь, как МенеджерВременныхТаблиц. Этот объект позволяет передавать временные таблицы из одного запроса в другой. То есть, мы можем создать временную таблицу в запросе, прерваться, выполнить какой-нибудь код, и продолжить работу с этой временной таблицей дальше. 

  Запрос = Новый Запрос;

    МВТ = Новый МенеджерВременныхТаблиц;

    Запрос.МенеджерВременныхТаблиц = МВТ;

    

    Запрос.Текст = "ВЫБРАТЬ

                   |    ТЧ.Номенклатура

                   |ПОМЕСТИТЬ ВременнаяТЗ

                   |ИЗ

                   |    &ТЧ КАК ТЧ

                   |ГДЕ

                   |    ТЧ.Номенклатура В ИЕРАРХИИ(&Номенклатура)

                   |    И ТЧ.Цена < 5";

    Запрос.УстановитьПараметр("Номенклатура", Номенклатура);

    Запрос.УстановитьПараметр("ТЧ", ТЧ);

    РезультатЗапроса = Запрос.Выполнить();

                   

    Запрос2 = Новый Запрос;

    Запрос2.Текст = "ВЫБРАТЬ

                    | ВременнаяТЗ.Номенклатура

                    |ИЗ

                    | ВременнаяТЗ КАК ВременнаяТЗ"; 

    Запрос2.МенеджерВременныхТаблиц    = МВТ;   

    РезультатЗапроса = Запрос2.Выполнить().Выгрузить();   

Например, в отчете в зависимости от выбранных настроек первичные данные обрабатываются тем или иным способом. Тогда имеет смысл в одной процедуре сформировать эти данные и поместить их во временную таблицу, которую уже передаем через менеджер временных таблиц в другую процедуру, отвечающую за выбранный способ обработки. Это позволит сократить код, сделать запросы более читаемыми. А так же в случае, если возникнут изменения в методике подготовки первичных данных для обработки, то потребуется внести изменения только в один запрос, а не в каждый.

В качестве примера работы с менеджером временных таблиц приведу следующую обработку.

Я создаю менеджер временных таблиц, и передаю его последовательно в каждую процедуру, для создания и объединения временных таблиц. Результат выводится в сводную таблицу.

 &НаКлиенте

Процедура ЗаполнитьСводную(Команда)

 ЗаполнитьСводнуюНаСервере();

КонецПроцедуры



&НаСервере

Процедура ЗаполнитьСводнуюНаСервере()

 

 МенВТ = Новый МенеджерВременныхТаблиц;

 ПолучитьДанныеА(МенВТ);

 ПолучитьДанныеБ(МенВТ);

 ЗагрузитьСводные(МенВТ);

 МенВТ.Закрыть();

 

КонецПроцедуры





&НаСервере

Процедура ПолучитьДанныеА(МенВремТаб)



 Запрос = Новый Запрос;

 Запрос.МенеджерВременныхТаблиц = МенВремТаб;

 Запрос.Текст = "ВЫБРАТЬ

                | ТаблицаА.Контрагент КАК Контрагент,

                | ТаблицаА.Сумма

                |ПОМЕСТИТЬ ТабА

                |ИЗ

                |ТаблицаА КАК ТаблицаА

                |

                |ИНДЕКСИРОВАТЬ ПО

                | Контрагент";

 Запрос.УстановитьПараметр("ТаблицаА", ТаблицаА.Выгрузить());

 Запрос.Выполнить();

 

КонецПроцедуры // ПолучитьДанныеА()





&НаСервере

Процедура ПолучитьДанныеБ(МенВремТаб)





 Запрос = Новый Запрос;

 Запрос.МенеджерВременныхТаблиц = МенВремТаб;

 Запрос.Текст = "ВЫБРАТЬ

                | ТаблицаБ.Контрагент КАК Контрагент,

                | ТаблицаБ.Комментарий

                |ПОМЕСТИТЬ ТабБ

                |ИЗ

                |ТаблицаБ КАК ТаблицаБ

                |

                |ИНДЕКСИРОВАТЬ ПО

                | Контрагент";

 Запрос.УстановитьПараметр("ТаблицаБ", ТаблицаБ.Выгрузить());

 Запрос.Выполнить();

 

КонецПроцедуры // ПолучитьДанныеА()



&НаСервере

Процедура ЗагрузитьСводные(МенВремТаб)



 Запрос = Новый Запрос;

 Запрос.МенеджерВременныхТаблиц = МенВремТаб;

 Запрос.Текст = "ВЫБРАТЬ

                | ЕСТЬNULL(ТабА.Контрагент, ТабБ.Контрагент) КАК Контрагент,

                | ЕСТЬNULL(ТабА.Сумма, 0) КАК Сумма,

                | ЕСТЬNULL(ТабБ.Комментарий, """") КАК Комментарий

                |ИЗ

                | ТабА КАК ТабА

                |  ПОЛНОЕ СОЕДИНЕНИЕ ТабБ КАК ТабБ

                |  ПО ТабА.Контрагент = ТабБ.Контрагент

                |

                |УПОРЯДОЧИТЬ ПО

                | Контрагент

                |АВТОУПОРЯДОЧИВАНИЕ";

       

 ТаблицаСводная.Загрузить(Запрос.Выполнить().Выгрузить());



КонецПроцедуры // ЗагрузитьСводные()   

На днях делал несколько однотипных отчетов на СКД. 

Общий принцип: формируются все варианты отчета, указанные в настройках схемы и каждый вариант выводится на отдельной вкладке.

Потом возникла мысль попробовать объединить все схемы в один отчет, чтобы не плодить лишних объектов в конфигурации. При этом количество вариантов в этих схемах заранее неизвестно. Ok, challenge accepted.

В тестовой конфигурации создаю для отчета две схемы компоновки, "Склад" и "Заявки".

Запросы наборов данных приводить не буду, для каждой схемы в настройках добавляю несколько вариантов отчетов.

Теперь переходим к созданию формы. Практически все реквизиты формы будут создаваться при выборе необходимого макета отчета.

 &НаСервере

Процедура СоздатьПереченьОтчетов()





 Для Каждого Макет Из РеквизитФормыВЗначение("Отчет").Метаданные().Макеты Цикл

  Элементы.МакетОтчета.СписокВыбора.Добавить(Макет.Имя, Макет.Синоним);

 КонецЦикла;





КонецПроцедуры // СоздатьПереченьОтчетов()





&НаСервере

Процедура ОбработатьВыборМакета()





 Макет = РеквизитФормыВЗначение("Отчет").ПолучитьМакет(МакетОтчета);

 

 мУдалить = ?(ПустаяСтрока(РеквизитыКУдалению), Новый Массив, ПолучитьИзВременногоХранилища(РеквизитыКУдалению));

 мДобавить = Новый Массив;

 кУдалению = Новый Массив;

 

 Для Каждого Вариант Из Макет.ВариантыНастроек Цикл

  ИмяРеквизита = "ТабДок_" + Вариант.Имя;

  тРеквизит = Новый РеквизитФормы(ИмяРеквизита, Новый ОписаниеТипов("ТабличныйДокумент"));

  мДобавить.Добавить(тРеквизит);

  кУдалению.Добавить(ИмяРеквизита);

 КонецЦикла;

 

 ИзменитьРеквизиты(мДобавить, мУдалить);

 

 Пока Элементы.СтраницыОтчета.ПодчиненныеЭлементы.Количество() Цикл

  Элементы.Удалить(Элементы.СтраницыОтчета.ПодчиненныеЭлементы[0]);

 КонецЦикла;

 

 Для Каждого Вариант Из Макет.ВариантыНастроек Цикл

  

  Страница = Элементы.Добавить("Страница_" + Вариант.Имя, Тип("ГруппаФормы"), Элементы.СтраницыОтчета);

  Страница.Вид = ВидГруппыФормы.Страница;

  Страница.Заголовок = Вариант.Представление;

  

  ИмяРеквизита = "ТабДок_" + Вариант.Имя;

  ТабДок = Элементы.Добавить(ИмяРеквизита, Тип("ПолеФормы"), Страница);

  ТабДок.Вид = ВидПоляФормы.ПолеТабличногоДокумента;

  ТабДок.ПутьКДанным = ИмяРеквизита;

  ТабДок.ПоложениеЗаголовка = ПоложениеЗаголовкаЭлементаФормы.Нет;

  

  ЭтаФорма[ИмяРеквизита].Очистить();





 КонецЦикла;

 

 РеквизитыКУдалению = ПоместитьВоВременноеХранилище(кУдалению, УникальныйИдентификатор);





КонецПроцедуры // ОбработатьВыборМакета()





&НаСервере

Процедура СформироватьОтчеты()





 Схема = РеквизитФормыВЗначение("Отчет").ПолучитьМакет(МакетОтчета);

 

 Для Каждого Вариант Из Схема.ВариантыНастроек Цикл

  

  Отчет.КомпоновщикНастроек.ЗагрузитьНастройки(Вариант.Настройки);

     

     КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;

     Макет = КомпоновщикМакета.Выполнить(Схема, Отчет.КомпоновщикНастроек.ПолучитьНастройки());

     

     ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;

     ПроцессорКомпоновки.Инициализировать(Макет);

     

     ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;

     ПроцессорВывода.УстановитьДокумент(ЭтаФорма["ТабДок_" + Вариант.Имя]);

     ПроцессорВывода.Вывести(ПроцессорКомпоновки); 

  

 КонецЦикла;





КонецПроцедуры // СформироватьОтчеты()





&НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

 

 СоздатьПереченьОтчетов();

 

КонецПроцедуры





&НаКлиенте

Процедура МакетОтчетаПриИзменении(Элемент)

 

 ОбработатьВыборМакета();

 

КонецПроцедуры





&НаКлиенте

Процедура Сформировать(Команда)

 

 СформироватьОтчеты();

 

КонецПроцедуры   

Смотрим, что получилось.

Выгрузка базы 1Cv8skd.rar 

Источник