закроем » Поиск

Результаты по ключевому слову: закроем

Передача файлов и данных на веб-сервер из 1С методами GET и POST Категория: Работа с Интернет, Почтой (Mail), FTP

Форма ~ Отбор, Группировка, Порядок и Условное оформление через компоновку данных

Выполним отбор по подразделению, если основной интерфейс пользователя кассир.

Код 1C v 8.х

 Если ПользователиИнформационнойБазы.ТекущийПользователь().ОсновнойИнтерфейс.Имя = "ИнтерфейсКассира" Тогда

		//Установим отбор	

		ДокументСписок.Отбор.Сбросить();

		ДокументСписок.Отбор.Подразделение.ВидСравнения=ВидСравнения.Равно;

		ДокументСписок.Отбор.Подразделение.Значение=ПараметрыСеанса.ТекущийПользователь.Подразделение;

		ДокументСписок.Отбор.Подразделение.Установить();  	

		//Закроем отбор от изменений

		Элементыформы.Список.НастройкаОтбора.Подразделение.Доступность = Ложь; 		

	КонецЕсли;

Выполним отбор по дате в форме списка документа.

Код 1C v 8.2 УП

 ЭлементОтбора = Список.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));

      ЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Дата");

      ЭлементОтбора.Использование = Истина;

      ЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.БольшеИлиРавно;

      ЭлементОтбора.ПравоеЗначение = Дата1;

      ЭлементОтбора.РежимОтображения = РежимОтображенияЭлементаНастройкиКомпоновкиДанных.Обычный;

      Элементы.Список.Обновить();

Группировка. Сгруппируем список документов по полю Клиент.

Код 1C v 8.2 УП

 ЭлементГруппировки = Список.Группировка.Элементы.Добавить(Тип("ПолеГруппировкиКомпоновкиДанных"));

      ЭлементГруппировки.Использование = Истина;

      ЭлементГруппировки.Поле = Новый ПолеКомпоновкиДанных("Клиент");

      Элементы.Список.Обновить();

Порядок. Отсортируем список документов по полю ПлановаяДатаПоставки.

Код 1C v 8.2 УП

       Список.Порядок.Элементы.Очистить();

      НовыйПорядок = Список.Порядок.Элементы.Добавить(Тип("ЭлементПорядкаКомпоновкиДанных"));

      НовыйПорядок.Поле = Новый ПолеКомпоновкиДанных("Список.ПлановаяДатаПоставки");

      НовыйПорядок.Использование = Истина;

      НовыйПорядок.РежимОтображения = РежимОтображенияЭлементаНастройкиКомпоновкиДанных.Обычный;

      НовыйПорядок.ТипУпорядочивания = НаправлениеСортировкиКомпоновкиДанных.Возр;

      Элементы.Список.Обновить();

Условное оформление. Покрасим в красный цвет строки списка документов с незаполненной датой согласования счета.

Код 1C v 8.2 УП

      ЭлементОформления = Список.УсловноеОформление.Элементы.Добавить();

      

      ЭлементОтбора = ЭлементОформления.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));

      ЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("ДатаСогласованияСчета");

      ЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.НеЗаполнено;

      ЭлементОтбора.Использование = Истина;

      

      Элемент = ЭлементОформления.Оформление.Элементы[1];

      Элемент.Использование = Истина;

      Элемент.Значение = Новый Цвет(255,0,0);

Категория: Работа с Формой (Диалог) и её элементами

Поле выбора ~ Как ограничить список выбора?

Ограничим список элементов, установив отбор в открываемой форме

Код 1C v 8.х

  //Пример 1

Процедура СтатьяПДРНачалоВыбора(Элемент, СтандартнаяОбработка)

    ФормаВыбора = Справочники.ПрочиеДоходыИРасходы.ПолучитьФормуВыбора(, Элемент);

    ЭлементОтбораВидПДР = ФормаВыбора.Отбор.ВидПрочихДоходовИРасходов;

    Если ЭлементОтбораВидПДР <> Неопределено Тогда

        ЭлементОтбораВидПДР.ВидСравнения  = ВидСравнения.Равно;

        ЭлементОтбораВидПДР.Значение      = Перечисления.ВидыПрочихДоходовИРасходов.ПрочиеВнереализационныеДоходыРасходы;

        ЭлементОтбораВидПДР.Использование = Истина;

    КонецЕсли;

   // Закроем доступ к настройке отбора. Таким образом, пользователь не может отключить заданный программно отбор

   //  и имеет возможность сделать выбор значения только из ограниченного списка.

    ФормаВыбора.ЭлементыФормы.СправочникСписок.НастройкаОтбора.ВидПрочихДоходовИРасходов.Доступность = Ложь;

    ФормаВыбора.Открыть();

    СтандартнаяОбработка = Ложь; 

КонецПроцедуры



//Пример 2

Процедура СчетДтНачалоВыбора(Элемент, СтандартнаяОбработка)

    Запрос = Новый Запрос;

    Запрос.Текст = "ВЫБРАТЬ

                   | Хозрасчетный.Ссылка

                   |ИЗ

                   | ПланСчетов.Хозрасчетный КАК Хозрасчетный

                   |ГДЕ

                   | Хозрасчетный.Родитель В ИЕРАРХИИ (ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.Материалы))

                   | И Хозрасчетный.ЗапретитьИспользоватьВПроводках = ЛОЖЬ";

    СписокСчетов = Новый СписокЗначений;

    СписокСчетов.ЗагрузитьЗначения(Запрос.Выполнить().Выгрузить().ВыгрузитьКолонку("Ссылка"));



    ФормаВыбора = ПланыСчетов.Хозрасчетный.ПолучитьФормуВыбора(, Элемент);

    ЭлементОтбораСсылка = ФормаВыбора.Отбор.Ссылка;

    Если ЭлементОтбораСсылка <> Неопределено Тогда

        ЭлементОтбораСсылка.ВидСравнения  = ВидСравнения.ВСписке;

        ЭлементОтбораСсылка.Значение      = СписокСчетов;

        ЭлементОтбораСсылка.Использование = Истина;

    КонецЕсли;

    ФормаВыбора.ЭлементыФормы.Список.НастройкаОтбора.Ссылка.Доступность = Ложь;

    ФормаВыбора.Открыть();

    СтандартнаяОбработка = Ложь; 

КонецПроцедуры

Использование выбора из списка

Код 1C v 8.х

 //Пример 1

Процедура ВидПДРНачалоВыбора(Элемент, СтандартнаяОбработка)

    ВидыПДР = Новый СписокЗначений;

    ВидыПДР.Добавить(Перечисления.ВидыПрочихДоходовИРасходов.ПрочиеВнереализационныеДоходыРасходы);

    ВидыПДР.Добавить(Перечисления.ВидыПрочихДоходовИРасходов.ПрочиеОперационныеДоходыРасходы);

    ВыбранныйЭлемент = ВыбратьИзСписка(ВидыПДР, Элемент, ВидыПДР.НайтиПоЗначению(Элемент.Значение));

    Если ВыбранныйЭлемент <> Неопределено Тогда

        Элемент.Значение = ВыбранныйЭлемент.Значение;

    КонецЕсли;

    СтандартнаяОбработка = Ложь;

КонецПроцедуры



//Пример 2

Процедура СчетКтНачалоВыбора(Элемент, СтандартнаяОбработка)

    СчетаКт = Новый СписокЗначений;

    СчетаКт.Добавить(ПланыСчетов.Хозрасчетный.РасчетыСПоставщиками);

    СчетаКт.Добавить(ПланыСчетов.Хозрасчетный.РасчетыСПодотчетнымиЛицами);

    СчетаКт.Добавить(ПланыСчетов.Хозрасчетный.РасчетыСПрочимиПоставщикамиИПодрядчиками);

    СчетаКт.Добавить(ПланыСчетов.Хозрасчетный.РасчетыПоТекущимОперациям);

    СчетаКт.Добавить(ПланыСчетов.Хозрасчетный.ПрочиеДоходы);

    ВыбранныйЭлемент = ВыбратьИзСписка(СчетаКт, Элемент, СчетаКт.НайтиПоЗначению(Элемент.Значение));

    Если ВыбранныйЭлемент <> Неопределено Тогда

        Элемент.Значение = ВыбранныйЭлемент.Значение;

    КонецЕсли;

    СтандартнаяОбработка = Ложь;

КонецПроцедуры

Категория: Работа с Формой (Диалог) и её элементами

Экспорт и Импорт данных 1С - Microsoft Excel

Экспорт
Процедура ОсновныеДействияФормыЭкспорт(Кнопка) - выгружает из указанного справочника данные в режиме экспорта в файл в формате Microsoft Excel с указанным именем, используя преобразование данных к типу число и типу строка;

Код 1C v 8.х

 Процедура ОсновныеДействияФормыЭкспорт(Кнопка)

  Попытка

    Попытка



      // Загрузка объекта Microsoft Excel

      Состояние("Выгрузка данных из 1С в Microsoft Excel...");

      ExcelПриложение = Новый COMОбъект("Excel.Application");

    Исключение

      Сообщить("Ошибка при запуске Microsoft Excel."

        + Символы.ПС + ОписаниеОшибки(), СтатусСообщения.Внимание);

      Возврат;

    КонецПопытки;



    // Создадим книгу, по умолчанию в ней уже есть листы

    Книга = ExcelПриложение.WorkBooks.Add();



    // Используем первый лист книги Excel

    Лист = Книга.WorkSheets(1);



    // Сформировать шапку документа в первой строке листа

    Колонка = 1;

    Для каждого стр из ТП цикл

      Если стр.Выгружать Тогда

        Лист.Cells(1, Колонка).Value = стр.НазваниеРеквизита;

        Колонка = Колонка + 1;

      КонецЕсли;

    КонецЦикла;



    // Выгрузить данные справочника

    выборка = Справочники[ИмяСправочника].Выбрать();

    СтрокаЛиста = 2;

    Пока выборка.Следующий() Цикл

      Колонка = 1;

      Для каждого стр из ТП цикл



      Если стр.Выгружать Тогда

      Попытка

        // Установить значение в строке и колонке

        Если ТипЗнч(выборка[стр.НазваниеРеквизита])=Тип("Число") Тогда

        // Установить формат для типа Число

        Лист.Cells(СтрокаЛиста, Колонка).NumberFormat = "0,00";

        Лист.Cells(СтрокаЛиста, Колонка).Value =

          Формат(выборка[стр.НазваниеРеквизита],"ЧГ=0");

        иначе

          // Для всех других типов установим формат "Текстовый"

          Лист.Cells(СтрокаЛиста, Колонка).NumberFormat = "@";

          Лист.Cells(СтрокаЛиста, Колонка).Value =

            Строка(выборка[стр.НазваниеРеквизита]);

        КонецЕсли;

      исключение

        // в случае ошибки вывести номер строки и колонки

        Сообщить("Ошибка установки значения для: " +

          выборка[стр.НазваниеРеквизита]);

        Сообщить("Стр: " +СтрокаЛиста+ " Кол: " +

          Колонка+ " Рек: " + стр.НазваниеРеквизита);

      КонецПопытки;

      Колонка = Колонка + 1;

      КонецЕсли;



    КонецЦикла;

    СтрокаЛиста = СтрокаЛиста + 1;

    Состояние("Экспорт из 1С в Excel " + СтрокаЛиста);

    КонецЦикла;



    // Сохраним созданную книгу в файл xls

    Книга.SaveAs(имяФайла);



    // Обязательно закроем соединение с COM объектом для освобождения памяти

    ExcelПриложение.Quit();



    Сообщить("Файл выгружен успешно: " + имяФайла );



  Исключение

    // Обработка ошибок экспорта данных из 1С в Excel

    Сообщить("Ошибка записи данных файла :" + имяФайла);

    Сообщить(ОписаниеОшибки());

    Попытка

      ExcelПриложение.Quit();

    Исключение

    КонецПопытки;

  КонецПопытки;

КонецПроцедуры

Импорт
Исходный код процедуры 1С для загрузки XLS файла:

Код 1C v 8.х

 Процедура ЧтениеXLSФайла(Элемент)



  Если ПустаяСтрока(ИмяФайла) Тогда

    Предупреждение("Для запуска обработки необходимо предварительно выбрать файл Microsoft Excel.");

    Возврат;

  КонецЕсли;



  Попытка

    // Загрузка Microsoft Excel

    Состояние("Загрузка Microsoft Excel...");

    ExcelПриложение = Новый COMОбъект("Excel.Application");

  Исключение

    Сообщить("Ошибка при загрузке Microsoft Excel." + Символы.ПС + ОписаниеОшибки(), СтатусСообщения.Внимание);

    Возврат;

  КонецПопытки;



  Попытка

    // Открытие файла Microsoft Excel

    Состояние("Открытие файла Microsoft Excel...");

    ExcelФайл = ExcelПриложение.WorkBooks.Open(ИмяФайла);

  Исключение

    Сообщить("Ошибка открытия файла Microsoft Excel." + ИмяФайла + Символы.ПС + ОписаниеОшибки(), СтатусСообщения.Внимание);

  КонецПопытки;



  Попытка

    // Обработка файла Microsoft Excel

    Состояние("Обработка файла Microsoft Excel...");

    // Читаем данные первого листа книги

    ExcelЛист = ExcelФайл.Sheets(1);



    // Определить количество строк и колонок выбранного листа книги Excel

    xlCellTypeLastCell = 11;

    ExcelПоследняяСтрока = ExcelЛист.Cells.SpecialCells(xlCellTypeLastCell).Row;

    ExcelПоследняяКолонка = ExcelЛист.Cells.SpecialCells(xlCellTypeLastCell).Column;

  Исключение

    Сообщить("Ошибка открытия листа №1 Microsoft Excel." + Символы.ПС + ОписаниеОшибки(), СтатусСообщения.Внимание);

    // Закрыть COM соединение для экономии памяти

    ExcelПриложение.Quit();

  КонецПопытки;



  // Создание описателя типов для таблицы значений

  КЧ = Новый КвалификаторыЧисла(15,2);

  КС = Новый КвалификаторыСтроки(50);

  Массив = Новый Массив;

  Массив.Добавить(Тип("Строка"));

  ОписаниеТиповС = Новый ОписаниеТипов(Массив, , КС);

  Массив.Очистить();

  Массив.Добавить(Тип("Число"));

  ОписаниеТиповЧ = Новый ОписаниеТипов(Массив, , ,КЧ);



  // Очистить предыдущие значения

  ТаблицаДокумента.Очистить();

  ТаблицаДокумента.Колонки.Очистить();



  // Создать колонки табличного документа

  ТаблицаДокумента.Колонки.Добавить("Номер",ОписаниеТиповС,"Номер",5);

  ТаблицаДокумента.Колонки.Добавить("Артикул",ОписаниеТиповС,"Артикул",11);

  ТаблицаДокумента.Колонки.Добавить("Описание",ОписаниеТиповС,"Описание",25);

  ТаблицаДокумента.Колонки.Добавить("Цена",ОписаниеТиповЧ,"Цена",6);



  // Последовательное чтение строк с выбранного листа

  Для Строка = 1 По ExcelПоследняяСтрока Цикл



    // Обработка нажатия Ctrl + Break

    ОбработкаПрерыванияПользователя();



    // Добавить данные в табличную часть экранной формы

    Стр=ТаблицаДокумента.Добавить();

    Стр.Номер = Строка;

    Попытка

      Стр.Артикул = ExcelЛист.Cells(Строка, 1).Value;

      Стр.Описание = ExcelЛист.Cells(Строка, 2).Value;

      Стр.Цена = ExcelЛист.Cells(Строка, 3).Value;

    Исключение

      // Не редко происходит ошибка конвертации отдельной ячейки документа

      Сообщить("Ошибка чтения строки файла Microsoft Excel." + Строка + Символы.ПС + ОписаниеОшибки(), СтатусСообщения.Внимание);

    КонецПопытки;

    // Отобразить информацию о ходе выполнения обработки

    Состояние("Обработка файла Microsoft Excel : "

      + "строка " + Строка + " из " + ExcelПоследняяСтрока);



  КонецЦикла;



  // Закрыть COM соединение для экономии памяти

  ExcelПриложение.Quit();



  // Отобразить результаты загрузки в форме элемента

  ЭлементыФормы.ТаблицаДокумента.Значение = ТаблицаДокумента;

  ЭлементыФормы.ТаблицаДокумента.СоздатьКолонки();



КонецПроцедуры // ЧтениеXLSФайла(Элемент)

Категория: Работа с Microsoft Office и OpenOffice

Выгрузка данных в Excel с установкой разных параметров

Код 1C v 8.х

 // Процедура выгружает из указанного справочника данные в режиме экспорта в файл в формате Microsoft Excel

// с указанным именем, используя преобразование данных к типу число и типу строка;

Процедура ОсновныеДействияФормыЭкспорт(Кнопка)

  Попытка

    Попытка

      // Загрузка объекта Microsoft Excel

      Состояние("Выгрузка данных из 1С в Microsoft Excel...");

      ExcelПриложение = Новый COMОбъект("Excel.Application");

    Исключение

      Сообщить("Ошибка при запуске Microsoft Excel."

        + Символы.ПС + ОписаниеОшибки(), СтатусСообщения.Внимание);

      Возврат;

    КонецПопытки;



    // Создадим книгу, по умолчанию в ней уже есть листы

    Книга = ExcelПриложение.WorkBooks.Add();



    // Используем первый лист книги Excel

    Лист = Книга.WorkSheets(1);



    // Сформировать шапку документа в первой строке листа

    Колонка = 1;

    Для каждого стр из ТП цикл

      Если стр.Выгружать Тогда

        Лист.Cells(1, Колонка).Value = стр.НазваниеРеквизита;

        Колонка = Колонка + 1;

      КонецЕсли;

    КонецЦикла;



    // Выгрузить данные справочника

    выборка = Справочники[ИмяСправочника].Выбрать();

    СтрокаЛиста = 2;

    Пока выборка.Следующий() Цикл

      Колонка = 1;

      Для каждого стр из ТП цикл



      Если стр.Выгружать Тогда

      Попытка

        // Установить значение в строке и колонке

        Если ТипЗнч(выборка[стр.НазваниеРеквизита])=Тип("Число") Тогда

        // Установить формат для типа Число

        Лист.Cells(СтрокаЛиста, Колонка).NumberFormat = "0,00";

        Лист.Cells(СтрокаЛиста, Колонка).Value =

          Формат(выборка[стр.НазваниеРеквизита],"ЧГ=0");

        иначе

          // Для всех других типов установим формат "Текстовый"

          Лист.Cells(СтрокаЛиста, Колонка).NumberFormat = "@";

          Лист.Cells(СтрокаЛиста, Колонка).Value =

            Строка(выборка[стр.НазваниеРеквизита]);

        КонецЕсли;

      исключение

        // в случае ошибки вывести номер строки и колонки

        Сообщить("Ошибка установки значения для: " +

          выборка[стр.НазваниеРеквизита]);

        Сообщить("Стр: " +СтрокаЛиста+ " Кол: " +

          Колонка+ " Рек: " + стр.НазваниеРеквизита);

      КонецПопытки;

      Колонка = Колонка + 1;

      КонецЕсли;



    КонецЦикла;

    СтрокаЛиста = СтрокаЛиста + 1;

    Состояние("Экспорт из 1С в Excel " + СтрокаЛиста);

    КонецЦикла;



    // Сохраним созданную книгу в файл xls

    Книга.SaveAs(имяФайла);



    // Обязательно закроем соединение с COM объектом для освобождения памяти

    ExcelПриложение.Quit();



    Сообщить("Файл выгружен успешно: " + имяФайла );



  Исключение

    // Обработка ошибок экспорта данных из 1С в Excel

    Сообщить("Ошибка записи данных файла :" + имяФайла);

    Сообщить(ОписаниеОшибки());

    Попытка

      ExcelПриложение.Quit();

    Исключение

    КонецПопытки;

  КонецПопытки;

КонецПроцедуры

Код 1C v 7.x

 //Простейший пример вывода из 1С:Предприятия 7.7 в MS Excel. Обеспечение наличия у рабочей книги единственного листа,

//установка размера, жирности и цвета шрифта, ширины колонок, рамок и заливки ячеек. Выравнивание текста

//ячеек, группировка строк, установка числового формата ячеек, закрепление области.

 

Процедура Вывод()

    Попытка

        Application=СоздатьОбъект("Excel.Application");

    Исключение

        Сообщить(ОписаниеОшибки(),"!!!");

        Сообщить("Возможно, MS Excel не установлен на этом компьютере.");

        Возврат;

    КонецПопытки;

    

    //Создание рабочей книги

 

    WorkBook=Application.WorkBooks.Add();

    //Получение окна

 

    Window=WorkBook.Windows(1);

    //Установка невидимости окна для убыстрения вывода

 

    Window.Visible=0;

    //Обеспечение наличия у рабочей книги единственного листа

 

    Если WorkBook.Worksheets.Count=0 Тогда

        WorkBook.Worksheets.Add();

    Иначе

        Application.DisplayAlerts=0;//не выдавать предупреждений

 

        Пока WorkBook.Worksheets.Count>1 Цикл

            WorkBook.Worksheets(1).Delete();

        КонецЦикла;

        Application.DisplayAlerts=-1;//восстановление флага выдачи предупреждений

 

    КонецЕсли;

    //Получение рабочего листа

 

    Worksheet=WorkBook.Worksheets(1);

    //Задание имени рабочего листа

 

    Worksheet.Name="Пример вывода";

    

    //Заголовок документа

 

    Worksheet.Range("A1").Value="Пример вывода из 1С:Предприятия в MS Excel";

    Worksheet.Range("A2").Value="сегодня "+ТекущаяДата();

    Worksheet.Range("A1:A2").Font.Size=14;//размер шрифта

 

    Worksheet.Range("A1:A2").Font.Bold=-1;//жирный шрифт

 

    

    //Задание ширины колонок

 

    Worksheet.Columns(1).ColumnWidth=60;

    Worksheet.Columns(2).ColumnWidth=15;

    Worksheet.Columns(3).ColumnWidth=15;

    

    //Шапка документа

 

    Worksheet.Range("A4").Value="Первая колонка";

    Для ы=7 по 10 Цикл//рамки

 

        Worksheet.Range("A4").Borders(ы).LineStyle=1;

        Worksheet.Range("A4").Borders(ы).Weight=-4138;//xlMedium

 

    КонецЦикла;

    Worksheet.Range("A4").Interior.ColorIndex=15;//заливка серым

 

    Worksheet.Range("A4").HorizontalAlignment=-4108;//выравнивание текста по центру

 

    

    Worksheet.Range("B4").Value="Вторая";

    Для ы=7 по 10 Цикл

        Worksheet.Range("B4").Borders(ы).LineStyle=1;

        Worksheet.Range("B4").Borders(ы).Weight=-4138;

    КонецЦикла;

    Worksheet.Range("B4").Interior.ColorIndex=15;

    Worksheet.Range("B4").HorizontalAlignment=-4108;

    

    Worksheet.Range("C4").Value="Третья";

    Для ы=7 по 10 Цикл

        Worksheet.Range("C4").Borders(ы).LineStyle=1;

        Worksheet.Range("C4").Borders(ы).Weight=-4138;

    КонецЦикла;

    Worksheet.Range("C4").Interior.ColorIndex=15;

    Worksheet.Range("C4").HorizontalAlignment=-4108;

    

    //Для группировки строк:

     Worksheet.Outline.SummaryRow=0;//"итоговые" строки отображать сверху (если снизу, то 1)

     

    //Вывод строк

     Worksheet.Range("A5").Value="Объект аналитики";

    Worksheet.Range("A5").Font.ColorIndex=5;//цвет шрифта - синий

 

    Worksheet.Range("B5").Value=123.45;

    Worksheet.Range("B5").Font.ColorIndex=5;

    Worksheet.Range("C5").Value=678.9;

    Worksheet.Range("C5").Font.ColorIndex=5;

    

    Worksheet.Range("A6").Value="Объект аналитики";

    Worksheet.Range("A6").Font.ColorIndex=3;//цвет шрифта - красный

 

    Worksheet.Range("B6").Value=123.45;

    Worksheet.Range("B6").Font.ColorIndex=3;

    Worksheet.Range("C6").Value=678.9;

    Worksheet.Range("C6").Font.ColorIndex=3;

    

    Worksheet.Range("A7").Value="Объект аналитики";

    Worksheet.Range("B7").Value=123.45;

    Worksheet.Range("C7").Value=678.9;

    

    Worksheet.Range("A8").Value="Объект аналитики";

    Worksheet.Range("B8").Value=123.45;

    Worksheet.Range("C8").Value=678.9;

    

    Worksheet.Range("A9").Value="Объект аналитики";

    Worksheet.Range("A9").Font.ColorIndex=3;//цвет шрифта - красный

 

    Worksheet.Range("B9").Value=123.45;

    Worksheet.Range("B9").Font.ColorIndex=3;

    Worksheet.Range("C9").Value=678.9;

    Worksheet.Range("C9").Font.ColorIndex=3;

    

    Worksheet.Range("A10").Value="Объект аналитики";

    Worksheet.Range("B10").Value=123.45;

    Worksheet.Range("C10").Value=678.9;

    

    Worksheet.Range("A11").Value="Объект аналитики";

    Worksheet.Range("B11").Value=123.45;

    Worksheet.Range("C11").Value=678.9;

    

    Worksheet.Range("A12").Value="Объект аналитики";

    Worksheet.Range("A12").Font.ColorIndex=5;//цвет шрифта - синий

 

    Worksheet.Range("B12").Value=123.45;

    Worksheet.Range("B12").Font.ColorIndex=5;

    Worksheet.Range("C12").Value=678.9;

    Worksheet.Range("C12").Font.ColorIndex=5;

    

    Worksheet.Range("A13").Value="Объект аналитики";

    Worksheet.Range("A13").Font.ColorIndex=3;//цвет шрифта - красный

 

    Worksheet.Range("B13").Value=123.45;

    Worksheet.Range("B13").Font.ColorIndex=3;

    Worksheet.Range("C13").Value=678.9;

    Worksheet.Range("C13").Font.ColorIndex=3;

    

    Worksheet.Range("A14").Value="Объект аналитики";

    Worksheet.Range("B14").Value=123.45;

    Worksheet.Range("C14").Value=678.9;

    

    Worksheet.Range("A15").Value="Объект аналитики";

    Worksheet.Range("B15").Value=123.45;

    Worksheet.Range("C15").Value=678.9;

    

    Worksheet.Range("A16").Value="Объект аналитики";

    Worksheet.Range("A16").Font.ColorIndex=3;//цвет шрифта - красный

 

    Worksheet.Range("B16").Value=123.45;

    Worksheet.Range("B16").Font.ColorIndex=3;

    Worksheet.Range("C16").Value=678.9;

    Worksheet.Range("C16").Font.ColorIndex=3;

    

    Worksheet.Range("A17").Value="Объект аналитики";

    Worksheet.Range("B17").Value=123.45;

    Worksheet.Range("C17").Value=678.9;

    

    Worksheet.Range("A18").Value="Объект аналитики";

    Worksheet.Range("B18").Value=123.45;

    Worksheet.Range("C18").Value=678.9;

    

    //Установка рамок

 

    Для НомСтр=5 по 18 Цикл

        Для ы=7 по 10 Цикл

            Worksheet.Range("A"+НомСтр).Borders(ы).LineStyle=1;

            Worksheet.Range("B"+НомСтр).Borders(ы).LineStyle=1;

            Worksheet.Range("C"+НомСтр).Borders(ы).LineStyle=1;

        КонецЦикла;

    КонецЦикла;

    

    //Группировка строк

 

    Worksheet.Range("7:8").Rows.Group();

    Worksheet.Range("10:11").Rows.Group();

    Worksheet.Range("14:15").Rows.Group();

    Worksheet.Range("17:18").Rows.Group();

    Worksheet.Range("6:11").Rows.Group();

    Worksheet.Range("13:18").Rows.Group();

    

    //Свёртка группировок до первого уровня

 

    Worksheet.Outline.ShowLevels(1);

    

    //Установка числового формата

 

    Попытка

        Worksheet.Range("B5:C18").NumberFormat="# ##0.00";

 

    Исключение

        Попытка

            Worksheet.Range("B5:C18").NumberFormat="# ##0,00";

 

        Исключение

        КонецПопытки;

    КонецПопытки;

    

    //Установка видимости приложения и его окна 

 

    Application.Visible=-1;

    Window.Visible=-1;

    

    //Закрепление области

 

    Worksheet.Range("A5").S_elect();

    Window.FreezePanes = -1;

КонецПроцедуры //Вывод

Категория: Работа с Microsoft Office и OpenOffice

Проверка правописания и орфографии

Код 1C v 8.х

 ТекстДляПроверки = "Данный текст садержит как минемум три ошипки !";



Процедура КнопкаВыполнитьНажатие(Кнопка)

   // Создадим объект MS Word, он должен быть установлен  

   Попытка

      Word = Новый COMОбъект("Word.Application");

   Исключение

      Предупреждение("Microsoft Word не установлен!",,"Ошибка!");

      Возврат;

   КонецПопытки;

   

   НетОшибок = Word.CheckSpelling(ТекстДляПроверки);

   Если НетОшибок Тогда // Все правильно  

      Сообщить("Нет ошибок");

   Иначе // текст содержит ошибки. Проверим каждое слово и выведем ошибочные.  

      Док = Word.Documents.Add(); // Создадим новый документ  

      Область = Док.Range(0,0); // Получим пустую область в начале документа  

      Область.I_nsertBefore(ТекстДляПроверки); // Добавим в документ текст  

      Для каждого Слово Из Область.Words Цикл

         СловоДляПроверки = СокрЛП(Слово.Text);

         НетОшибок = Word.CheckSpelling(СловоДляПроверки);

         Если НЕ НетОшибок Тогда // Слово ошибочно  

            // покажем возможные замены неправильного слова  

            СтрокаВариантов = "";

            // Получим варианты правописания  

            Варианты = Слово.GetSpellingSuggestions( ,1, ,0);

            Для каждого Вариант Из Варианты Цикл

               СтрокаВариантов = СтрокаВариантов + ", " + Вариант.Name;

            КонецЦикла;

            СтрокаВариантов = ". Варианты замены: " + Сред(СтрокаВариантов, 2);

            Сообщить("Ошибка в слове: " + СловоДляПроверки + СтрокаВариантов);

         КонецЕсли;

      КонецЦикла;

   КонецЕсли;

   Док.Close(0,,); // закроем документ без сохранения wdDoNotSaveChanges  

   Word.Quit(); // закроем Word  

КонецПроцедуры

Еще посмотрите ActiveX-компоненту, которая проверяет правописание текста.
Основана на технологии OpenOffice MySpell. Не требует установленного офиса.
В комплекте словари для 10 языков, включая русский (с "ё"). Автор: dushelov

Категория: Полезные, Универсальные Функции

Получения курса валют из Интернет

Код 1C v 8.х

 Соединение = Новый HTTPСоединение("export.rbc.ru"); //готовим соединение

ИмяФайла = ПолучитьИмяВременногоФайла(".txt");

//строка-образец

//http://export.rbc.ru/free/cb.0/free.fcgi?period=DAILY&tickers=USD&d1=18&m1=01&y1=2009&d2=17&m2=02&y2=2009&lastdays=30&separator=TAB&data_format=BROWSER&header=1

//http://export.rbc.ru/free/cb.5/free.fcgi?period=DAILY&tickers=USDEUR_BASKET&d1=08&m1=07&y1=2009&d2=22&m2=07&y2=2009&lastdays=14&separator=TAB&data_format=BROWSER&header=1

СтрокаСоединения="/free/"+Источник+"/free.fcgi?period=DAILY&tickers="+Валюта1+"&d1="+День1+"&m1="+Месяц1+"&y1="+Год1+"&d2="+День2+"&m2="+Месяц2+"&y2="+Год2+"&separator=%7C&data_format=BROWSER";

СтрокаСоединения=СтрЗаменить(СтрокаСоединения," ","");



Попытка //соединяемся

Соединение.Получить(СтрокаСоединения,ИмяФайла);

Исключение

Сообщить("Невозможно получить курс по адресу http://export.rbc.ru"+СтрокаСоединения);

КонецПопытки;



КурсыТекст=Новый ТекстовыйДокумент; //читаем результат запроса

КурсыТекст.Прочитать(ИмяФайла);

Код 1C v 8.х

  // еще пример

 Функция ПолучитьКакСтроку(Адресс) 

	соминет = Новый COMОбъект("MSXML2.XMLHTTP");

	соминет.open ("GET", Адресс, Ложь);

	соминет.send();

	Возврат соминет.responseText;

КонецФункции	



Функция ПреобразоватьДату(дат)

	// Медот преобразования даты времен 1Сv7

	//Т=Строка(Дат);

	//Возврат Сред(Т,7,4)+"/"+Сред(Т,4,2)+"/"+Лев(Т,2);

	Возврат Формат(Дат,"ДФ=""гггг/ММ/дд""");

КонецФункции



Процедура КнопкаЗагрузитьКурсы(Элемент)

	//Список - список валют	

	Для А = 1 по Список.Количество() цикл

		Если Список[а-1].Пометка тогда

			Сообщить("Загружаем курсы для "+Строка(Список[а-1].Значение));

			Код = Строка(Список[а-1].Значение.Код);

			Дат = ПериодС;

			Пока Дат <= ПериодПо цикл

				Стр = ПолучитьКакСтроку("http://cbrates.rbc.ru/tsv/"+Код+"/"+ПреобразоватьДату(Дат)+".tsv");

				Поз = Найти(Стр,Символы.Таб);

				Если Поз = 0 Тогда

					Дат = Дат + 86400;

					Продолжить;

				КонецЕсли;					

				Кратность = Число(СокрЛП(Лев(стр,Поз-1)));

				курс = Число(СокрЛП(Сред(Стр,Поз+1,СтрДлина(Стр)-Поз)));

				Сообщить("Дата="+Строка(Дат)+" Курс="+Строка(курс)+" Кратность="+Строка(Кратность));

				Запись = РегистрыСведений.КурсыВалют.СоздатьМенеджерЗаписи();

				Запись.Период = Дат;

				Запись.Валюта = Список[а-1].Значение.Ссылка;

				Запись.Курс = Курс;

				Запись.Кратность = Кратность;

				Запись.Записать(Истина);

				Дат = Дат + 86400;                   

			КонецЦикла;				

		КонецЕсли;			

	КонецЦикла;		

КонецПроцедуры

Код 1C v 7.x

 // Взято с http://www.1c-club.kz     IUnknown

//Небольшая обработка для получения курса валют размещенной на странице Национального Банка РК.

//Внимание: работоспособность данной обработки может быть нарушена, если дизайнеры сайта НБ РК изменят формат страницы с //официальным курсом валюта. Но не большой анализ нового формата и работоспособность обработки будет восстановлена.

// шаблон для отображаемой на форме таблице значения

перем тзПустышка;



//*******************************************

// ПриНачалеВыбораЗначения(стрНазвание, чисФлаг)

//

// Параметры:

//  стрНазвание - Строка. Наименование реквизита формы инициюрующей

//                вызов процедуры.

//  чисФлаг     - Число. Флаг станадартной обработки иницации нажатия

//                кнопки выбора значения.

//

// Возвращаемое значение:

//  Нет.

//

// Описание:

//  Переопределенная процедура инициирующая при нажатии кнопки

//  выбора значения реквизита формы.

//

процедура ПриНачалеВыбораЗначения(стрНазвание, чисФлаг)

    // Если инициировали из реквизита "стрУРЛа"

    если стрНазвание = "стрУРЛа" тогда

        // откроем страницу с введенным URL

        запуститьприложение(стрУРЛа);

    конецесли;

конецпроцедуры



//*******************************************

// кнПолучить()

//

// Параметры:

//  Нет

//

// Возвращаемое значение:

//  Нет.

//

// Описание:

//  Процедура получающая курсы валют с URL находящегося в

//  строковом реквизите формы "стрУРЛа". Пытается по указаноому URL

//  получить страницу и распарсить ее.

//

//  ПРЕДУПРЕЖДЕНИЕ:

//  В случае измения формата данных представленных на странице, возможно

//  будет работать не правильно.

//

процедура кнПолучить()

    // сгенирим имя файла для временного хранения содержимого

    // страницы курса валют Национального банка

    стрИмяФайла = каталогпользователя() + "$$$$.###";

    // создадим объект XMLHttpRequest

    олеХМЛ = создатьобъект("Microsoft.XMLHTTP");

    // иницируем его типом запроса и нужным нам URL

    олеХМЛ.Open("GET", стрУРЛа, 0);

    // отправим запрос для обработки серверу

    олеХМЛ.Send();

    // создадим "поток" через ADODDB для работы с данными

    олеАДО = создатьобъект("ADODB.Stream");

    // зададим тип и режим потока

    олеАДО.Mode = 3;

    олеАДО.Type = 1;

    // откроем его

    олеАДО.Open();

    // создадим объект для управления скриптами

    олеШелл = создатьобъект("MSScriptControl.ScriptControl");

    // установим язык сценариев

    олеШелл.Language = "vbscript";

    // добавим созданные объекты

    олеШелл.AddObject("oleADO", олеАДО);

    олеШелл.AddObject("oleXML", олеХМЛ);

    // с помощью скрипта запишем в поток ADO данные из

    // объекта XMLHttpRequest

    // то есть содержимое страницы

    олеШелл.Eval("oleADO.Write(oleXML.ResponseBody)");

    // запишем данные во временный файл

    олеАДО.SaveToFile(стрИмяФайла, 2);

    // закроем данный поток

    олеАДО.Close();

    // для ускорения парсера занесем весь файл в строковую

    // переменую с разделителем строк

    // для этого инициализуруем поток установкой

    // соотвествующим режимом и типом

    олеАДО.Mode= 3;

    олеАДО.Type = 2;

    // так как страница курса валют НБК имеет формат

    // символов UTF-8, то установим соотвествующий набор

    олеАДО.CharSet="UTF-8";

    // откроем поток

    олеАДО.Open();

    // загрузим содержимое нашего файла в поток

    олеАДО.LoadFromFile(стрИмяФайла);

    // обнулим временную строковую переменную

    стрТемп = "";

    // в цикле получим из потока все строки

    пока олеАДО.EOS() = 0 цикл

        // и запишем их во временную переменую, добавив разделитель строк

        стрТемп = стрТемп + олеАДО.ReadText(-2) + разделительстрок;

    конеццикла;

    // закроем поток

    олеАДО.Close();

    // удалим временный файл

    фс.УдалитьФайл(стрИмяФайла);

    // найдем в строке позицию начала блока с данными о курсе

    чисПозиция = найти(стрТемп, "Официальные курсы валют на");

    если чисПозиция = 0 тогда

        // если позиции нет ... то мы имем другую страницу

        // или другой формат страницы...

        предупреждение("Не получилось получить курсы валют");

    иначе

        // создаим временную таблицу значений

        // для более шустрого заполения из-за отстуствия вызова

        // функции перерисовки таблицы при изменении данных

        тзТемп = создатьобъект("ТаблицаЗначений");

        // установим для нее нужный формат

        тзПустышка.Выгрузить(тзТемп);

        // отрежем все лишнее

        стрТемп = сред(стрТемп, чисПозиция);

        // получим дату курса

        дтКурса = дата(стрзаменить(стрполучитьстроку(стрТемп, 2), "/", "."));

        // первая строка с курсом валюты находится на 18 строке от начала

        // после удаления мусора

        чисПозиция = 18;

        // узнаем сколько всего строк в многострочке

        чисКоличествоСтрок = стрколичествострок(стрТемп);

        // получим строку

        стрТекущая = стрполучитьстроку(стрТемп, чисПозиция);

        // если в строке есть подстрока ... то значит это наверное очередная валюта

        пока найти(стрТекущая, "input type=""checkbox"" name=""idval""") > 0 цикл

            // добавляем новую строку

            тзТемп.НоваяСтрока();

            // получаем строку со смещением 1 от позиции

            стрТекущая = стрполучитьстроку(стрТемп, чисПозиция + 1);

            // используя фичу 1С по преобразованию, получим число

            // за сколько единиц валюты имеем курс в тенге

            тзТемп.Количество = число(стрТекущая);

            // путем убирания "мусора" получаем наименование валюты

            тзТемп.Наименование = сокрлп(стрзаменить(стрзаменить(стрТекущая, тзТемп.Количество, ""), "</td>", ""));

            // получаем строку со смещением 2 от позиции

            стрТекущая = стрполучитьстроку(стрТемп, чисПозиция + 2);

            // убираем html мусор

            стрТекущая = сокрлп(стрзаменить(стрзаменить(стрТекущая, "<td class=""gen7"" align=""center"">", ""), "</td>", ""));

            // получаем код валюты

            тзТемп.Код1 = лев(стрТекущая, 3);

            // получаем код валюты "Тенге"

            тзТемп.Код2 = прав(стрТекущая, 3);

            // получаем строку со смещением 5 от позиции

            стрТекущая = стрполучитьстроку(стрТемп, чисПозиция + 5);

            // очищаем от мусора и преобразуем в число... получаем курс

            тзТемп.Курс = число(стрзаменить(стрзаменить(стрТекущая, "<td class=""gen7"" align=""center"">", ""), "</td>", ""));

            // увеличиваем позицию на 17 ...

            чисПозиция = чисПозиция + 17;

            если чисПозиция > чисКоличествоСтрок тогда

                // если позици дальше имеющихся строк

                // то все курсов больше нет

                стрТекущая = "";

            иначе

                // получаем очередную строку для разбора

                стрТекущая = стрполучитьстроку(стрТемп, чисПозиция);

            конецесли;

        конеццикла;

        // сформированую таблицу копируем в таблицу на форме

        тзТемп.Выгрузить(тзКурсов);

    конецесли;

конецпроцедуры



//*******************************************

// установим значение реквизита текущим URL по которому можно получить курс валют

стрУРЛа = "http://www.nationalbank.kz/?docid=460&uid=DD54B73C-802C-E8F0-E27EDF82ECF77C1D";

// формируем формат таблицы

тзПустышка = создатьобъект("ТаблицаЗначений");

тзПустышка.НоваяКолонка("Количество", "число", 3, 0, "", 5);

тзПустышка.НоваяКолонка("Наименование", "строка", , , "Наименование", 70);

тзПустышка.НоваяКолонка("Код1", "строка", 3, , "код", 10);

тзПустышка.НоваяКолонка("Код2", "строка", 3, , "код", 10);

тзПустышка.НоваяКолонка("Курс", "число", 7, 2, "Курс", 10);

// копируем получившийся формат в таблицу на форме

тзПустышка.Выгрузить(тзКурсов);

Категория: COM-объекты, WMI, WSH

Функция открывает таблицу в MS Excel

Код 1C v 7.x

 Код

//Функция открывает таблицу в MS Excel

//Таблица         - печатная форма 1С

//ИмяЛиста         - имя, которое будет присвоено листу книги MS Excel (если не задано, то остается "Sheet1")

//ОтображатьЯрлычки   - показывать/скрыть ярлычки листов в MS Excel

//ОтображатьСетку   - показывать/скрыть линии сетки в MS Excel

//УдалитьСтроки      - позволяет удалить указанное количество верхних строк таблицы

//УдалитьСтроки      - позволяет удалить указанное количество левых столбцов таблицы

Функция глОткрытьТаблицуВExcel(Таблица, ИмяЛиста = "", ОтображатьЯрлычки = 1, ОтображатьСетку = 1, УдалитьСтроки = 0, УдалитьСтолбцы = 0) Экспорт

   Перем Excel, ExcelWB, ExcelSh, ExcelPS, ИмяФайла, Рез, Зн, Зн1;

   

   Если ТипЗначенияСтр(Таблица) <> "Таблица" Тогда

      Возврат 0;

   КонецЕсли;    

   

   Попытка

      Excel = СоздатьОбъект("Excel.Application")

   Исключение

      Сообщить("Не удалось открыть MS Excel","!");

      Возврат 0;

   КонецПопытки;

   

   Пока 1=1 Цикл

      //Подберем уникальное имя для временного файла

      ИмяФайла = КаталогВременныхФайлов() + "1c" + СтрЗаменить(ТекущееВремя(), ":", "");

      Если (ФС.СуществуетФайл(ИмяФайла+".tmp") = 1) или (ФС.СуществуетФайл(ИмяФайла+".xls") = 1) Тогда

         ФС.УдалитьФайл(ИмяФайла+".tmp");

         ФС.УдалитьФайл(ИмяФайла+".xls")

      Иначе

         Прервать;

      КонецЕсли

   КонецЦикла;

   

   Таблица.Записать(ИмяФайла+".tmp", "XLS");

   

   Если ФС.СуществуетФайл(ИмяФайла+".tmp") = 0 Тогда

      Сообщить("Ошибка записи файла """ + ИмяФайла + "tmp""","!");

      Excel = "";

      Возврат 0;

   КонецЕсли;    

   

   Рез = 1;

   

   Попытка

      ExcelWB = Excel.Workbooks.Add(ИмяФайла+".tmp");   //Откроем временный файл в Excel в режиме шаблона (чтобы не блокировать файл)

      Попытка                                 //Если на клиентской машине не установлен принтер, обращение к настройкам страницы вызывает ошибку. Поэтому работаем в "Попытка ... КонецПопытки"

         ExcelPS = ExcelWB.Sheets(1).PageSetup;      //Исправим спецсимволы в колонтитулах

         Зн = ExcelPS.LeftHeader;   Зн1 = СтрЗаменить(СтрЗаменить(СтрЗаменить(СтрЗаменить(Зн, "#P", "&P"), "#Q", "&N"), "#T", "&T"), "#D", "&D"); Если Зн <> Зн1 Тогда ExcelPS.LeftHeader   = Зн1 КонецЕсли;

         Зн = ExcelPS.CenterHeader;   Зн1 = СтрЗаменить(СтрЗаменить(СтрЗаменить(СтрЗаменить(Зн, "#P", "&P"), "#Q", "&N"), "#T", "&T"), "#D", "&D"); Если Зн <> Зн1 Тогда ExcelPS.CenterHeader   = Зн1 КонецЕсли;

         Зн = ExcelPS.RightHeader;   Зн1 = СтрЗаменить(СтрЗаменить(СтрЗаменить(СтрЗаменить(Зн, "#P", "&P"), "#Q", "&N"), "#T", "&T"), "#D", "&D"); Если Зн <> Зн1 Тогда ExcelPS.RightHeader   = Зн1 КонецЕсли;

         Зн = ExcelPS.LeftFooter;   Зн1 = СтрЗаменить(СтрЗаменить(СтрЗаменить(СтрЗаменить(Зн, "#P", "&P"), "#Q", "&N"), "#T", "&T"), "#D", "&D"); Если Зн <> Зн1 Тогда ExcelPS.LeftFooter   = Зн1 КонецЕсли;

         Зн = ExcelPS.CenterFooter;   Зн1 = СтрЗаменить(СтрЗаменить(СтрЗаменить(СтрЗаменить(Зн, "#P", "&P"), "#Q", "&N"), "#T", "&T"), "#D", "&D"); Если Зн <> Зн1 Тогда ExcelPS.CenterFooter   = Зн1 КонецЕсли;

         Зн = ExcelPS.RightFooter;   Зн1 = СтрЗаменить(СтрЗаменить(СтрЗаменить(СтрЗаменить(Зн, "#P", "&P"), "#Q", "&N"), "#T", "&T"), "#D", "&D"); Если Зн <> Зн1 Тогда ExcelPS.RightFooter   = Зн1 КонецЕсли;

      Исключение

      КонецПопытки;

      

      ExcelWB.SaveAs(ИмяФайла+".xls", -4143);         //Сохраним, чтобы обновить формат файла до текущего (xlNormal = -4143)

      ExcelWB.Close(0);                        //Закроем книгу ...

      ExcelWB = Excel.Workbooks.Add(ИмяФайла+".xls");   //... и вновь откроем в режиме шаблона

      

      Попытка

         ExcelSh = ExcelWB.Sheets(1);

         

         Если ПустаяСтрока(ИмяЛиста) = 0 Тогда         //Зададим имя ярлычка

            ExcelSh.Name = ИмяЛиста

         КонецЕсли;

         

         Если ОтображатьЯрлычки = 1 Тогда            //Сделаем видимыми ярлычки листов

             ExcelWB.Windows(1).DisplayWorkbookTabs = 1;

            ExcelWB.Windows(1).TabRatio = 0.6         //... и отодвинем горизонтальную полосу прокрутки от левого края

         КонецЕсли;

         

         Если ОтображатьСетку = 0 Тогда               //Скроем линии сетки

            ExcelWB.Windows(1).DisplayGridlines = 0

         КонецЕсли;

      

         Если УдалитьСтроки > 0 Тогда               //Удалим верхние строки

            ExcelSh.Range(ExcelSh.Rows(1), ExcelSh.Rows(УдалитьСтроки)).Delete()

         КонецЕсли;

         

         Если УдалитьСтолбцы > 0 Тогда               //Удалим левые столбцы

            ExcelSh.Range(ExcelSh.Columns(1), ExcelSh.Columns(УдалитьСтолбцы)).Delete()

         КонецЕсли;

      Исключение

      КонецПопытки;

      

      ExcelWB.Saved = 0;

   Исключение

      Сообщить("Ошибка открытия файла в MS Excel","!"); Рез = 0

   КонецПопытки;

   

   Попытка

      Excel.Visible = 1

   Исключение

   КонецПопытки;  

   

   ExcelWB = ""; ExcelSh = ""; ExcelPS = ""; Excel = "";

   ФС.УдалитьФайл(ИмяФайла+".tmp");

   ФС.УдалитьФайл(ИмяФайла+".xls");

   Возврат Рез

КонецФункции //глОткрытьТаблицуВExcel

Автор неизвестен, если код ваш, напишите в комментариях

Категория: Работа с Microsoft Office и OpenOffice