замещением » Поиск

Результаты по ключевому слову: замещением

Как удалить записи из регистра сведений, подчиненного регистратору?

Код 1C v 8.х

 //Удаление записей из регистра, подчиненного регистратору

Запрос = Новый Запрос;



Запрос.Текст = "

|ВЫБРАТЬ

|	ЦеныНоменклатурыКонтрагентов.Регистратор

|ИЗ

|	РегистрСведений.ЦеныНоменклатурыКонтрагентов КАК ЦеныНоменклатурыКонтрагентов";

	

Результат = Запрос.Выполнить();

Выборка = Результат.Выбрать();



НаборЗаписей = РегистрыСведений.ЦеныНоменклатурыКонтрагентов.СоздатьНаборЗаписей();

	

Пока Выборка.Следующий() Цикл

	НаборЗаписей.Отбор.Регистратор.Установить(Выборка.Регистратор);

	

	НаборЗаписей.Записать();	

	

КонецЦикла;

Сначала запросом получаем выборку всех документов, являющихся регистраторами для нужного регистра.
Далее создаем набор записей по данному регистру.
В цикле перебора выборки из результата запроса устанавливаем отборы для набора записей по нужным регистраторам и записываем пустые наборы записей в регистр с замещением старых наборов.

Код 1C v 8.х

 НачатьТранзакцию();



НаборЗаписей = РегистрыСведений.МестонахожденияОС.СоздатьНаборЗаписей();

НаборЗаписей.Отбор.Регистратор.Установить([документ создавший запись]); //обязательно для подчиненных регистров

НаборЗаписей.Прочитать();



сзУдаляемыеЗаписи = Новый СписокЗначений;

Для Каждого Запись Из НаборЗаписей

    Если [условие] Тогда

        сзУдаляемыеЗаписи.Добавить(Запись);

    КонецЕсли; //[условие]

КонецЦикла;



Для каждого ЭлтСз Из сзУдаляемыеЗаписи

    НаборЗаписей.Удалить(ЭлтСз.Значение);

КонецЦикла;



НаборЗаписей.Записать();



ЗафиксироватьТранзакцию();

Категория: Регистры сведений

Как в периодическом независимом регистре сведений удалить все записи по валютам с наименованиями?

Как в периодическом независимом регистре сведений «КурсыВалют» удалить все записи по валютам с наименованиями «EUR» и «USD», период которых меньше 01 января 2005 года?

Сначала получим таблицу записей, которые необходимо оставить. Поскольку условий несколько, да еще и не все они на равенство, оптимальнее это сделать при помощи запроса. Следующий запрос даст нам желаемое:

Код 1C v 8.х

 // Получение нужных записей

Запрос = Новый Запрос;

Запрос.Текст = "ВЫБРАТЬ

|	*

|ИЗ

|	РегистрСведений.КурсыВалют КАК КурсыВалют

|

|ГДЕ

|	(КурсыВалют.Период >= ДАТАВРЕМЯ(2005, 1, 1) 

|	 ИЛИ 

|	НЕ(КурсыВалют.Валюта.Наименование ПОДОБНО " "USD" ") 

|	 И 

|	НЕ(КурсыВалют.Валюта.Наименование ПОДОБНО " "EUR" "))";

Источником данных для запроса послужила таблица записей регистра.
Были применены отборы, чтобы в результат попали записи, для которых период более или равен 01 января 2005 года, или наименования не USD и не EUR. Обратите внимание: при составлении условия по периоду, чтобы не пользоваться параметром запроса, прямо в тексте запроса применили литерал даты ДАТАВРЕМЯ(), в котором части даты указываются в «обратном» порядке: год, месяц, порядковый номер дня в месяце.
Результатом запроса будет таблица, в которой по каждой записи заполнены все поля регистра сведений КурсыВалют.

Код 1C v 8.х

 // Выгрузка результата запроса

ТаблицаОставляемыхЗаписей = Запрос.Выполнить().Выгрузить();



НаборЗаписей = РегистрыСведений.КурсыВалют.СоздатьНаборЗаписей();



НаборЗаписей.Загрузить(ТаблицаОставляемыхЗаписей);



НаборЗаписей.Записать();

Далее выполняем запрос, выгружаем результат в таблицу значений ТаблицаОставляемыхЗаписей
Создаем переменную НаборЗаписей, тип значения РегистрСведенийНаборЗаписей.КурсыВалют, выгружаем в нее таблицу значений ТаблицаОставляемыхЗаписей.
Поскольку сама таблица была получена из регистра, то названия ее колонок совпадут с названиями полей регистра, а значит, загрузка пройдет успешно.
Далее записываем заполненный только нужными записями набор записей в регистр с замещением его исходных данных (как вы уже помните, параметр Замещать метода Записать() по умолчанию имеет значение Истина).

Категория: Регистры сведений

Как добавить записи в регистр сведений, подчиненный регистратору?

Если регистр сведений подчинен регистратору, то для добавления записей в него необходимо создать набор записей этого регистра с установленным отбором по нужному регистратору, заполнить этот набор записей и записать его:

Код 1C v 8.х

 // Добавление записей в регистр, подчиненный регистратору (замещение)

НаборЗаписей = РегистрыСведений.ЛимитыВозвратнойТары.СоздатьНаборЗаписей();



НаборЗаписей.Отбор.Регистратор.Установить(ВыбранныйРегистратор);



НоваяЗапись = НаборЗаписей.Добавить();



НоваяЗапись.Период = ВыбранныйРегистратор.Дата;

НоваяЗапись.Номенклатура = ВыбраннаяНоменклатура;

НоваяЗапись.ДоговорКонтрагента = ВыбранныйДоговор;

НоваяЗапись.ЛимитПоставщика = 50;



НаборЗаписей.Записать();

По умолчанию запись выполняется с замещением, т. е. существующие записи этого регистратора в регистре сведений будут удалены.
Для того чтобы добавить записи к существующим записям регистратора, необходимо указывать значение Ложь параметра метода Записать() набора записей. При этом необходимо позаботиться о том, чтобы значения измерений добавляемых записей были уникальны для записей данного регистратора в регистре сведений, иначе запись выполнена не будет:

Код 1C v 8.х

 // Добавление записей в регистр, подчиненный регистратору

НаборЗаписей = РегистрыСведений.ЛимитыВозвратнойТары.СоздатьНаборЗаписей();



НаборЗаписей.Отбор.Регистратор.Установить(ВыбранныйРегистратор);



НоваяЗапись = НаборЗаписей.Добавить();



НоваяЗапись.Период = ВыбранныйРегистратор.Дата;

НоваяЗапись.Номенклатура = ВыбраннаяНоменклатура;

НоваяЗапись.ДоговорКонтрагента = ВыбранныйДоговор;

НоваяЗапись.ЛимитПокупателю = 25;



НаборЗаписей.Записать(Ложь);

Категория: Регистры сведений

Как удалить записи независимого регистра сведений с отбором по конкретной организации? Категория: Регистры сведений

Как добавить записи в непериодический независимый регистр сведений?

Код 1C v 8.х

 НаборЗаписей = РегистрыСведений.ЗначенияСвойств.СоздатьНаборЗаписей(); 



НаборЗаписей.Отбор.Номенклатура.Установить(ТекущаяНоменклатура); 

НаборЗаписей.Отбор.Свойство.Установить(ТекущееСвойство); 



НоваяЗапись = НаборЗаписей.Добавить(); 

НоваяЗапись. Номенклатура = ТекущаяНоменклатура; 

НоваяЗапись.Свойство = ТекущееСвойство; 

НоваяЗапись.Значение = ТекущееЗначение; 



НаборЗаписей.Записать();

Создаем новую запись, заполняем ее поля. Записываем новый набор записей с замещением всех записей, соответствующих отбору. Параметр Замещение метода Записать() по умолчанию имеет значение Истина.
Для чего нужно замещение?
Дело в том, что в любом регистре запись с конкретным ключом записи всегда уникальна. Для непериодического независимого регистра сведений ключом записи является конкретная комбинация значений измерений.
То есть запись с определенной комбинацией значений измерений может присутствовать только в единственном экземпляре. Попытка записать новую запись с тем же набором значений измерений привела бы к ошибке.
Кроме того, в подобной работе можно удариться в другую крайность.
Если не применить отбор, то при записи система попытается заместить все существующие записи регистра. В результате, добавляя новый набор записей с замещением, мы бы удалили все ранее введенные записи регистра!

Как добавить записи в независимый регистр сведений?

Категория: Регистры сведений

Полная очистка НЕЗАВИСИМОГО регистра сведений Категория: Регистры сведений