Циклы применяются для выполнения каких либо повторяющихся действий, возможные варианты перебора в цикле:

Перебираем строки с помощью цикла Для каждого

 Для каждого ТекСтрока Из КоллекцияСтрок Цикл

// код обработки

КонецЦикла;   

Перебираем строки с помощью цикла Пока

 Пока л < КолСтрок Цикл

	// код обработки, например л=л+1;

КонецЦикла;   

Перебираем строки с помощью цикла Для

 Для л=0 по КолСтрок Цикл

// код обработки, например л=л+1;

КонецЦикла   

Еще вариант, но советую его использовать только в без выходных ситуациях, Если

 ~НачалоЦикла:

Если л <> КоличествоИтераций Тогда 

// код обработки, например л=л+1;

	Перейти ~НачалоЦикла;

КонецЕсли;   

Примеры циклов

 &НаКлиенте

Процедура ВыполнитьКод(Команда)

 

    /// Как организовать цикл в 1с 8.3, 8.2

 

    // Для Цикл

    Для Счетчик = 1 По 5 Цикл

        Сообщить(Счетчик); // 1 2 3 4 5

    КонецЦикла;

 

    // Для Каждого Цикл

 

    Дни = Новый Массив();

    Дни.Добавить("Понедельник");

    Дни.Добавить("Вторник");

    Дни.Добавить("Среда");

 

    Для Каждого Элемент Из Дни Цикл

        Сообщить(Элемент); // Понедельник Вторник Среда

    КонецЦикла;

 

    // Пока Цикл

    Счетчик = 0;

    Пока Счетчик < Дни.Количество() Цикл        

        Сообщить(Дни[Счетчик]); // Понедельник Вторник Среда

        Счетчик = Счетчик + 1;     

    КонецЦикла;     

 

    /// Как организовать обратный цикл в 1с 8.3, 8.2     

 

    Счетчик = Дни.Количество() - 1;     

    Пока Счетчик >= 0 Цикл

        Сообщить(Дни[Счетчик]); // Среда Вторник Понедельник

        Счетчик = Счетчик - 1;

    КонецЦикла;

 

    /// Как прервать цикл в 1с 8.3, 8.2

 

    Для Счетчик = 1 По 5 Цикл

        Если Счетчик > 2 Тогда

            Прервать;

        КонецЕсли;

        Сообщить(Счетчик); // 1 2

    КонецЦикла;

 

    /// Как принудительно продолжить цикл в 1с 8.3, 8.2

 

    Для Счетчик = 1 По 5 Цикл

        Если Счетчик <> 3 Тогда

            Продолжить;

        КонецЕсли;

 

        Сообщить(Счетчик); // 3

    КонецЦикла;   

 

КонецПроцедуры

   

А какой цикл работает быстрее?

Итак, я нашел пять способов, как можно организовать цикл средствами 1С.

Первый вид цикла, назовем его условно «Для По» выглядит так:

 Для н = 0 по КоличествоИтераций Цикл

КакиеТоДействия();

КонецЦикла;   

Второй вид «Для Каждого»:

 Для Каждого ЭлементКоллекции из Коллекция Цикл

КакиеТоДействия();

КонецЦикла;   

Третий «Пока»:

 Пока н <> КоличествоИтераций Цикл

КакиеТоДействия();

н = н + 1;

КонецЦикла;   

Далее вспомнил ассемблерную молодость & цикл «Если»:

 ~НачалоЦикла:

Если н <> КоличествоИтераций Тогда

КакиеТоДействия();

н = н + 1;

Перейти ~НачалоЦикла;

КонецЕсли;   

Ну и напоследок «Рекурсия»

 Процедура РекурсивныйЦикл(н, КоличествоИтераций)

КакиеТоДействия();

Если н <> КоличествоИтераций Тогда

РекурсивныйЦикл(н+1, КоличествоИтераций);

КонецЕсли;

КонецПроцедуры   

Естественно, что относить рекурсию к циклам не совсем корректно, но тем ни менее с её помощью можно добиться похожих результатов. Сразу оговорюсь, что в дальнейшем тестировании рекурсия не участвовала. Во первых все тесты проводились при 1 000 000 итераций, а рекурсия выпадает уже при 2 000. Во вторых скорость рекурсии в десятки раз меньше, чем скорость остальных циклов.

Последнее отступление. Одним из условий было выполнение в цикле каких-либо действий. Во первых пустой цикл используется очень редко. Во вторых цикл «ДляКаждого» используется для какой-либо коллекции, а значит и остальные циклы должны работать с коллекцией, чтобы тестирование проходило в одинаковых условиях.

Ну что ж, поехали. В качестве тела цикла использовалось чтение из заранее заполненного массива.

 ПриемникТестовогоЗначения = ТестовыйМассив.Получить(н);   

или, при использовании цикла «Для Каждого»

 ПриемникТестовогоЗначения = Элем;   

Тестирование проводилось на платформе 8.3.5.1231 для трех видов интерфейса (Обычное приложение, Управляемое приложение и Такси).

Числа это время в миллисекундах полученное с помощью функции ТекущаяУниверсальнаяДатаВМиллисекундах(), которую я вызывал до цикла и после его завершения. Числа дробные, потому что я использовал среднее арифметическое пяти замеров. Почему я не использовал Замер производительности? У меня не было цели замерить скорость каждой строчки кода, только скорость циклов с одинаковым результатом работы.

Казалось бы и все, но & тестировать так тестировать!

В среднем платформа 8.2 на 25% быстрее, чем 8.3. Я немножко не ожидал такой разницы и решил провести тест на другой машине. Скажу только, что там 8.2 была быстрее процентов на 20.

Почему? Не знаю, дезасемблировать ядро в мои планы не входило, но в замер производительности я все же заглянул. Оказалось, что сами циклические операции в 8.3 проходят несколько быстрее, чем в 8.2. Но на строке

 ПриемникТестовогоЗначения = ТестовыйМассив.Получить(н);   

то есть при считывании элемента коллекции в переменную происходит значительное снижение производительность.

Для себя я сделал несколько выводов:

1. Если есть возможность использовать специализированный цикл & «Для Каждого», то лучше использовать его. Кстати, сам по себе он отрабатывает дольше чем другие циклы, но скорость доступа к элементу коллекции у него на много выше.

2. Если заранее знаешь количество итераций & используй «Для По». «Пока» отработает медленнее.

3. Если использовать цикл «Если» & другие программисты тебя явно не поймут.

В статье использованы материалы с хабра и хелпме

PostgreSQL напрямую "из коробки" применяться для использования с 1С Предприятем не может. Необходима именно адаптированная версия от 1С, превращающая PostgreSQL в блокировочник, причем нужно понимать, что блокировки будут накладываться на всю таблицу сразу. Если нужны блокировки на уровне записей, включаем в 1С режим управляемых блокировок и прописываем их в конфигурации ручками. Вывод: необходимо скачать специальный дистрибутив с сайта 1С или взять на диске ИТС.

Установка

Сама установка особых затруднений не вызывает, обратить внимание нужно на правильную инициализацию базы данных, а именно настройку локали, изменить потом это можно только повторной начальной инициализацией. Например, база 1С с украинскими региональными установками в СУБД с установленной русской локалью не загрузится. Да и проблемы с сортировкой потом не нужны. Поэтому делаем init в соответствии с нужным языком.

Для русского языка

initdb --locale=ru_RU.UTF-8 --lc-collate=ru_RU.UTF-8 --lc-ctype=ru_RU.UTF-8 --encoding=UTF8 -D /db/postgresql

Для украинского языка

initdb --locale=uk_UA.UTF-8 --lc-collate=uk_UA.UTF-8 --lc-ctype=uk_UA.UTF-8 --encoding=UTF8 -D /db/postgresql

где /db/postgresql ваш каталог данных PostgreSQL. Кодировка, конечно же, UTF-8.

Подробный вариант пересоздания кластера

1.Необходимо выдать полные права на папку в которую мы установили PostgreSQL, обычно это C:\Program Files\PostgreSQL

2.Из под админских прав запускаем cmd. Если это делаете в win7, то запускаем от Администратора.

3.Создаем папку где будет храниться кластер. Например d:\postgredata.

md d:\postgredata

4.Проводим инициализацию кластера вручную с указанием пути где он будет находиться.

“C:\Program Files\PostgreSQL\9.1.2-1.1C\bin\initdb.exe” -D d:\postgredata --locale=Russian_Russia --encoding=UTF8 -U postgres

5.Удаляем службу PostgreSQL, которая была установлена в ходе установки.

sc delete pgsql-9.1.2-1.1C-x64

Где pgsql-9.1.2-1.1C-x64 – Это название службы. Если не знаете название точно, можно посмотреть свойствах службы “PostgreSQL Database Server…” (Пуск – Панель управления – Администрирование – Службы )

6.Создаем новый сервис с указанием нашего кластера

“C:\Program Files\PostgreSQL\9.1.2-1.1C\bin\pg_ctl” register -N pgsql -U postgresql -P пароль -D d:/postgredata

7.Теперь заходим в службы. Пуск – Панель управления – Администрирование – Службы и стартуем нашу службу.

Ошибка СУБД: ERROR: new encoding (UTF8) is incompatible with the encoding of the template database (WIN1251).

HINT: Use the same encoding as in the template database, or use template0 as template.

Вы выбрали неправильную локаль при установке СУБД (WIN1251) для сервера и клиента, нужно изменить на UTF-8 в конфигурации или переустановить СУБД со следующими параметрами:

Внимание при установке НЕ выбирайте локаль Настройки ОС, выбирайте из списка Russian, Russia

Настройка PostgreSQL

Следует помнить о рекомендации 1С не использовать в запросах конструкции ПОЛНОЕ ВНЕШНЕЕ СОЕДИНЕНИЕ и заменять его, используя, например, комбинацию из нескольких левых соединений. Известна также проблема с потерей производительности в запросах, где применяется соединение с виртуальной таблицей СрезПоследних, к ней рекомендуется делать отдельные запросы и сохранять результаты во временных таблицах.

Настройка конфигурации производится редактированем файла postgresql.conf.

Наиболее важные параметры

effective_cache_size = 0,5 от ёмкости RAM

fsync = off отключаем сброс на диск после каждой транзации (Внимание! Применять только при использовании надежного UPS, есть опасность потери данных при неожиданном отключении)

synchronous_commit = off отключаем синхронную запись в лог (риски теже, что и у fsync)

wal_buffers = 0,25 от ёмкости RAM

После настройки не забываем выполнить перезапуск службы:

service postgresql restart

Настройка сети

Для подключения клиентов 1С к серверу извне и работы сервера баз данных, на файрволе, должны быть открыты следующие порты:

Агент сервера (ragent) & tcp:1540 Главный менеджер кластера (rmngr) & tcp:1541 Диапазон сетевых портов, для динамического распределения рабочих процессов & tcp:1560&1591, tcp:5432 & Postgresql. Создадим правило через стандартный интерфейс, либо с помощью команды:

netsh advfirewall firewall add rule name="1Cv8-Server" dir=in action=allow protocol=TCP localport=1540,1541,5432,1560-1590 enable=yes profile=ANY remoteip=ANY interfacetype=LAN

Теперь с другого компьютера мы спокойно запускаем клиент 1С:Предприятия, добавляем существующую информационную базу newdb. Не забываем про лицензии, программной / аппаратной защиты. 

Резервное копирование

Создание дампа базы данных делаем командой

su postgres -c 'pg_dump -U postgres -Fc -Z9 -f baza1.sql baza1'

Восстановление из дампа

su postgres -c 'pg_restore -U postgres -c -d baza1 -v baza1.sql'

Периодическое обслуживание

Рекомендуется настроить AVTO VACUUM в файле конфигурации. Но не пренебрегаем и запуском через планировщик принудительной команды.

su postgres -c '/usr/bin/vacuumdb --dbname=$i --analyze --full --quiet'

Просмотр активности PostgreSQL

Иногда полезно видеть чем сейчас занимается сервер. Поможет такая конструкция:

watch -n 1 'ps auxww | grep ^postgres'

Понимание архитектуры используемой СУБД очень важно для правильной эксплуатации, но местами переоценено: администратору, DevOps-специалисту или разработчику прикладных систем вовсе необязательно знать подробности внутреннего устройства B-дерева или тонкости работы легковесных блокировок. Это, конечно, все очень интересно, но существенно загромождает главы Concepts соответствующих руководств или доклады про архитектуру СУБД и оставляет практическим специалистам существенно меньше времени на более важные и насущные с точки зрения повседневной эксплуатации базы данных проблемы.

В рамках данного семинара, мы эту проблему попробовали устранить и рассмотреть несколько жизненно-важных систем PostgreSQL со следующих точек зрения:

• теоретические основы;
• практическая реализация и суровая практика ежедневной эксплуатации.

Главной основой любой базы данных является транзакционная машина: 

• Как она реализованная в PostgreSQL? 
• Какие алгоритмы и протоколы лежат в основе? 
• Как в PostgreSQL реализованы Undo и Redo? 
• Как устроен Write Ahead Log? 
• Для чего нужен и как работает автовакуум? 
• Какие могут быть проблемы в работе всех этих систем? 
• Их мониторинг и настройка: как найти и исправить проблемы? 

Говоря о каждой системе PostgreSQL мы сравнивали их с другими СУБД, такими как Oracle, IBM DB2 LUW, MS SQL Server & чтобы специалистам, имеющим опыт с другими СУБД было быстрее и проще разобраться.

 // Выводит данные ДереваЗначений в ТекстовыйДокумент, пригодный к рассмотрению в отладчике, окне сообщений и показу.

//

// Параметры:

//    рВетка - дерево значений, подлежащее выводу. Может иметь почти любую глубину иерархии, количество и тип колонок. Если хватит

//        объявленных позиционных строк-заполнителей, всё поместится. Если иерархия слишком глубока, строки просто надо нарастить;

//    рТекст - на входе должен быть равен Неопределено; на выходе по окончании работы содержит результатный текстовый документ;

//    рПараметры - структура дополнительных настроек, допустимые ключи:

//        Колонки - структура колонок, которые подлежат выводу. Если пуста или имеет тип, отличный от структуры, выводятся все колонки;

//           если в ключах структуры указаны имена колонок, будут выведены только они. В значениях структуры можно передать строковое

//           представление формата, согласно которому должны будут форматироваться выводимые значения. По умолчанию формата нет;

//        ПоказыватьУровни - булево, управляет выводом №№ уровней (метод Уровень()), по умолчанию выключено;

//        ШагОтступа - число, определяющее шаг в символах, используемый для показа псевдографики иерархии веток в дереве.

//

&НаСервереБезКонтекста

Процедура ВывестиДеревоЗначенийВТекст(Знач рВетка,рТекст,Знач рПараметры=Неопределено)

Попытка

    Если рТекст=Неопределено Тогда // первая итерация, шапочный вызов исходной части

        //---------------------------------------------------------------------------------------------------------------------------

        // Разбираем входные данные

        Если ТипЗнч(рВетка)<>Тип("ДеревоЗначений") Тогда Возврат КонецЕсли;

        Если ТипЗнч(рПараметры)<>Тип("Структура") Тогда рПараметры=Новый Структура КонецЕсли;

        стрКолонок=?(рПараметры.Свойство("Колонки"),рПараметры.Колонки,Неопределено);

        Если ТипЗнч(стрКолонок)<>Тип("Структура") Тогда стрКолонок=Новый Структура КонецЕсли;

        рПоказыватьУровни=?(рПараметры.Свойство("ПоказыватьУровни"),рПараметры.ПоказыватьУровни,Ложь); // затратное дело, кстати

        рШагОтступа=?(рПараметры.Свойство("ШагОтступа"),рПараметры.ШагОтступа,2); // для отображения отступа в колонке иерархии





        //---------------------------------------------------------------------------------------------------------------------------

        // Определяем максимальное количество уровней

        // Также можно получить максимальный уровень, "плоско" перебрав все строки (например, получив их через НайтиСтроки)

        // и в цикле для каждой вызывая Уровень() и определяя максимум.

        // Вариант через СКД и служебное поле "Уровень" ни на одной известной мне платформе не работоспособен (нехватка памяти).

        //

        //

        //рДеревоДляТеста=КакНибудьСкопироватьДерево(рВетка);

        //рДеревоДляТеста.Колонки.Вставить(0,"_Level",Новый ОписаниеТипов("Булево")); // самый экономный вариант, с сохранением иерархии

        //мНенужных=Новый Массив;

        //Для й=1 По рДеревоДляТеста.Колонки.Количество()-1 Цикл

        //  мНенужных.Добавить(рДеревоДляТеста.Колонки[й]);

        //КонецЦикла;

        //Для каждого кол Из мНенужных Цикл

        //  рДеревоДляТеста.Колонки.Удалить(кол);

        //КонецЦикла;

        //

        рДеревоДляТеста=рВетка; // пока сериализуем прямо всё дерево (неоптимально, но...)

        рЗапись=Новый ЗаписьXML;

        рЗапись.УстановитьСтроку();

        СериализаторXDTO.ЗаписатьXML(рЗапись,рДеревоДляТеста);

        стро=рЗапись.Закрыть();

        //

        стро=СтрЗаменить(стро,"xmlns=","xmlns:myns1C="); // иначе не будет работать XPath

        //

        рЧтение=Новый ЧтениеXML;

        рЧтение.УстановитьСтроку(стро);

        постр=Новый ПостроительDOM;

        рДокументДОМ=постр.Прочитать(рЧтение);





        рВыражение="/ValueTree/row"; максКолвоУровней=1;

        рРазыменователь=Новый РазыменовательПространствИменDOM(рДокументДОМ);

        Пока Истина Цикл

            #Если Клиент Тогда

                ОбработкаПрерыванияПользователя();

            #КонецЕсли

            рРезультат=рДокументДОМ.ВычислитьВыражениеXPath(рВыражение,рДокументДОМ,рРазыменователь,ТипРезультатаDOMXPath.Любой);

            Если рРезультат.ПолучитьСледующий()=Неопределено Тогда Прервать КонецЕсли;

            рВыражение=рВыражение+"/row";

            максКолвоУровней=максКолвоУровней+1;

        КонецЦикла;

        максКолвоУровней=максКолвоУровней-1; // можно и так: СтрЧислоВхождений(рВыражение,"/row")-1;





        //---------------------------------------------------------------------------------------------------------------------------

        // готовим исходный макет вывода

        строПробелы="                                                                                                                                                                                                                 ";

        строРазделители="===============================================================================================";

        строОтступы="___________________________________________________________________________________________"; // тут нужны чуть для другого

        //

        секШапка1="|[_HCS"+Лев(строПробелы,максКолвоУровней*рШагОтступа)+"]|"; // HierarchyColumnShow

        секГорРазделитель1="|"+Лев(строОтступы,максКолвоУровней*рШагОтступа+6)+"|"; // здесь именно Отступы!

        рШиринаКолонкиИерархии=СтрДлина(секШапка1)-2;

        строПолейШапки="#Поле _HCS

        |   #Выравнивание Центр";

        строПолейЗаписи="";

        //

        Если рПоказыватьУровни Тогда

            секШапка1=секШапка1+"[_Level]|";

            секГорРазделитель1=секГорРазделитель1+Лев(строРазделители,8)+"|";

            строПолейШапки=строПолейШапки+"

            |#Поле _Level

            |   #Выравнивание Центр";

            строПолейЗаписи="#Поле _Level

            |   #Выравнивание Центр

            |   #Забивать Истина";

        КонецЕсли;

        //

        мИменКолонок=Новый Массив;

        Для каждого кол Из рВетка.Колонки Цикл

            Если стрКолонок.Количество()<>0 и не стрКолонок.Свойство(кол.Имя) Тогда Продолжить КонецЕсли; // чётко указаны конкретные колонки

            рДлинаИмениКолонки=СтрДлина(кол.Имя);

            рНужнаяШирина=Макс(?(кол.Ширина<3,10,кол.Ширина),рДлинаИмениКолонки);

            // к сожалению, ключевое слово "#Поля" неприменимо - платформа падает - поэтому делаем всё сами

            секШапка1=секШапка1+"["+кол.Имя+Лев(строПробелы,рНужнаяШирина-рДлинаИмениКолонки)+"]|";

            секГорРазделитель1=секГорРазделитель1+Лев(строРазделители,рНужнаяШирина+1)+"=|";

            строПолейШапки=строПолейШапки+"

            |#Поле "+кол.Имя+"

            |   #Выравнивание Центр";

            рОписТипов=кол.ТипЗначения;

            Если рОписТипов.Типы().Количество()=1 и рОписТипов.СодержитТип(Тип("Булево")) Тогда

                рВыравнивание="Центр";

            ИначеЕсли рОписТипов.СодержитТип(Тип("Число")) Тогда

                рВыравнивание="Право";

            ИначеЕсли рОписТипов.СодержитТип(Тип("Строка")) и рОписТипов.КвалификаторыСтроки.Длина=0 Тогда

                рВыравнивание="ПоШирине";

            Иначе

                рВыравнивание="Лево";

            КонецЕсли;

            строПолейЗаписи=строПолейЗаписи+?(ПустаяСтрока(строПолейЗаписи),"",Символы.ПС)+"#Поле "+кол.Имя+"

            |   #Выравнивание "+рВыравнивание;

            Попытка

                Если ЗначениеЗаполнено(стрКолонок[кол.Имя]) Тогда // указан формат, уточняющий показ колонки

                    строПолейЗаписи=строПолейЗаписи+"

                    |   #Формат """+СокрЛП(стрКолонок[кол.Имя])+"""";

                КонецЕсли;

            Исключение

            КонецПопытки;

            мИменКолонок.Добавить(кол.Имя);

        КонецЦикла;

        секШапка2=СтрЗаменить(СтрЗаменить(секШапка1,"[","<"),"]",">");

        секЗапись1=секШапка1; секЗапись2=секШапка2; // пусть они по дизайну пока не отличаются

        секГорРазделитель2=СтрЗаменить(СтрЗаменить(секГорРазделитель1,"=","-"),"|","+");

        // обработаем нормальное обрамление шапки колонки иерархии

        секГорРазделитель1=СтрЗаменить(секГорРазделитель1,"_","=");

        секГорРазделитель2=СтрЗаменить(секГорРазделитель2,"_"," ");

        //

        тМакет=Новый ТекстовыйДокумент;

        тМакет.ДобавитьСтроку("#Область Шапка");

        тМакет.ДобавитьСтроку(строПолейШапки);

        тМакет.ДобавитьСтроку(секГорРазделитель1);

        тМакет.ДобавитьСтроку(секШапка1);

        тМакет.ДобавитьСтроку(секШапка2);

        тМакет.ДобавитьСтроку(секГорРазделитель1);

        тМакет.ДобавитьСтроку("#КонецОбласти");

        тМакет.ДобавитьСтроку("");

        тМакет.ДобавитьСтроку("#Область Запись");

        тМакет.ДобавитьСтроку(строПолейЗаписи);

        тМакет.ДобавитьСтроку(секЗапись1);

        тМакет.ДобавитьСтроку(секЗапись2);

        тМакет.ДобавитьСтроку(секГорРазделитель2);

        тМакет.ДобавитьСтроку("#КонецОбласти");

        рПараметры.Вставить("ИсходныйМакет",тМакет); // пусть будет





        //---------------------------------------------------------------------------------------------------------------------------

        // Запускаем вывод в итоговый документ

        рТекст=Новый ТекстовыйДокумент;

        сек=тМакет.ПолучитьОбласть("Шапка");

        сек.Параметры._HCS="Иерархия";

        Для каждого имякол Из мИменКолонок Цикл

            кол=рВетка.Колонки[имякол];

            сек.Параметры[кол.Имя]=?(ПустаяСтрока(кол.Заголовок),кол.Имя,кол.Заголовок);

        КонецЦикла;

        рТекст.Вывести(сек);

        //

        пар=Новый Структура;

        пар.Вставить("МассивИмёнКолонок",мИменКолонок);

        пар.Вставить("ТекущаяСекция",тМакет.ПолучитьОбласть("Запись"));

        пар.Вставить("ШиринаКолонкиИерархии",рШиринаКолонкиИерархии);

        пар.Вставить("ПоказыватьУровни",рПоказыватьУровни);

        пар.Вставить("Отступ",0);

        пар.Вставить("ШагОтступа",рШагОтступа);

        ВывестиДеревоЗначенийВТекст(рВетка,рТекст,пар);





    Иначе

        // очередная итерация, вывод в текстовый документ

        мИменКолонок=рПараметры.МассивИмёнКолонок;

        рСекция=рПараметры.ТекущаяСекция;

        рОтступ=рПараметры.Отступ;

        рШиринаКолонкиИерархии=рПараметры.ШиринаКолонкиИерархии;

        рПоказыватьУровни=рПараметры.ПоказыватьУровни;

        //

        строОтступы="_________________________________________________________________________________________________________";

        строПробелы="                                                                                                                                                                                                                 ";

        //

        пар=Новый Структура;

        пар.Вставить("МассивИмёнКолонок",мИменКолонок);

        пар.Вставить("ТекущаяСекция",рПараметры.ТекущаяСекция);

        пар.Вставить("ШиринаКолонкиИерархии",рШиринаКолонкиИерархии);

        пар.Вставить("ПоказыватьУровни",рПоказыватьУровни);

        пар.Вставить("ШагОтступа",рПараметры.ШагОтступа);

        пар.Вставить("Отступ",рОтступ+рПараметры.ШагОтступа);

        //

        Для каждого рПодветка Из рВетка.Строки Цикл

            рСекция.Параметры._HCS=Лев(строПробелы,рОтступ)+"\"+Лев(строОтступы,рШиринаКолонкиИерархии-рОтступ-1);

            Если рПоказыватьУровни Тогда

                рСекция.Параметры._Level=рПодветка.Уровень();

            КонецЕсли;

            Для каждого имякол Из мИменКолонок Цикл

                рСекция.Параметры[имякол]=рПодветка[имякол];

            КонецЦикла;

            рТекст.Вывести(рСекция);

            ВывестиДеревоЗначенийВТекст(рПодветка,рТекст,пар)

        КонецЦикла;

        //

    КонецЕсли;

Исключение

    Сообщить("ВывестиДеревоЗначенийВТекст, ошибка: "+ОписаниеОшибки(),СтатусСообщения.ОченьВажное);

КонецПопытки;

КонецПроцедуры   

Источник

Мне частенько приходится взаимодействовать с 1С-разработчиками, и во время совместной работы над проектами замечаю, что далеко не все из них хорошо знают свой главный инструмент – «Конфигуратор». Причем это не относится к степени крутости девелопера. Как оказалось, даже синьоры пользуются далеко не всеми возможностями «Конфигуратора», а ведь они могут сэкономить кучу времени, а тем самым повысить продуктивность разработчика.

Под катом я решил собрать несколько полезных фишек стандартного конфигуратора, которыми пользуюсь регулярно. Многие из них появились в платформе «1С:Предприятие 8.3.х», поэтому перед тестированием обязательно проверьте номер версии установленной у вас платформы.

Закладки

Функция установки в коде закладок появилось еще с первых релизов 8-й версии платформы «1С:Предприятие». Штука чрезвычайно полезная и помогает разработчику быстрей передвигаться по коду. Например, у нас есть большой модуль, в который мы решили добавить ряд функций. Естественно, потом нам предстоит их отлаживать, а соответственно постоянно между ними переключаться.

Хорошо, если новые функции добавлены в самый конец модуля, а если потребовалось расположить в разных частях? Вот тут начинается самое интересное. Одни программисты начинают скролить текст (как правило, этим страдают новички). Более продвинутые применяют поиск по тексту (Ctrl + F).

Оба способа рабочие, но пользоваться ими долго. Куда правильней использовать функцию «закладки». Например, переходим к какой-нибудь строке. Нажимаем ALT + F2 и получаем закладку (слева от строки отобразиться квадратик).

Убирается закладка тем же сочетанием клавиш. Так вот, закладок может быть в модуле расставлено много. По ним легко передвигаться нажатием клавиши F2. Фича крутая, но она была изначально не доделана и не позволяла, например, передвигаться по закладкам в разных модулях. Это досадное ограничение создавало лишние тормоза для программистов, привыкших к хорошим IDE (например, Visual Studio, PHP Storm).

В версии 8.3 недочет исправили и сделали классную вещь – «Список закладок». Нажимаем клавиши «Ctrl + Shift + F2», и перед нами откроется окно с полным списком установленных закладок:

В нем перечислены все закладки в разрезе модулей. Для каждой закладки указан номер строк и доступен перечень действий: перейти к коду, удалить закладку, удалить все закладки.

Таким образом, работать с закладками стало на порядок проще. Еще бы добавили возможность установки горячих клавиш на закладки, и стало бы совсем хорошо. Помню еще со времен «Delphi 6» привык к установке закладок по горячим клавишам Alt + <Цифра>. Наставил закладок и быстро перемещайся по ним.

Группировка строк

В «1С:Предприятие» с самого начала была одна большая проблема – отсутствие возможности создавать дополнительные модули для определенных объектов. Например, есть у меня справочник «Контрагенты» и мне хочется разделить его функционал на модули. Допустим, функционала очеееень много. Так вот, в моем распоряжении все равно стандартный набор: Модуль объекта, Модуль менеджера и модуль формы. Понятное дело, что у каждого модуля своя роль, но что делать мне с моими 100500 функциями, которые относятся непосредственно к справочнику «Контрагенты»?

По мнению 1С я должен оформить их в виде общего модуля. С одной стороны, идея классная. Делаем модуль, его сразу видно и т.д., и т.п. Правда всегда есть один нюанс. Если следователь этой методике, то при наличии кучу объектов в конфигурации число общих модулей будет зашкаливать.

Вот взять хотя бы библиотеку БСП. Стоит ее внедрить и в количестве модулей начинает теряться. Я уже молчу про конфигурации, которые построены на базе БСП. Там и сто пятьсот модулей от БСП, и еще столько же специально для конфигурации.

В общем, неудобство налицо (особенно после опыта разработки в языках, где нет подобных ограничений). Увы, спастись от этой проблемы в настоящее время не получится. Зато, мы можем использовать возможности группировки функций/процедур в модулях.+

Например, есть у нас общий модуль «РаботаСКонтрагентами». В нем часть функций отвечают за поиск контрагента, другая часть за загрузку контрагентов из внешних источников и т.д. Чтобы не потеряться во всем этом многообразии возможностей, можно логически сгруппировать все функции/процедуру. Для этого в платформе 8.3 появилась функция под названием «Области». Рассмотрим пример:

 #Область ПОИСК_КОНТРАГЕНТОВ

Функция ПоискКонтрагентаПоПаспортнымДанным()

	//Код	

КонецФункции

Функция ПоискКонтрагентаПоНаименованию()

	//Код

КонецФункции

#КонецОбласти

#Область ИМПОРТ_КОНТРАГЕНТОВ

Функция ИмпортКонтрагентаИзExcel()

	//Код	

КонецФункции

Функция ИмпортКонтрагентаИзJSON()

	//Код

КонецФункции

#КонецОбласти   

После добавление областей (язык препроцессора) наш код будет сгруппирован. Если их свернуть (области), то в итоге мы увидим симпатичный комментарий (см. рисунок ниже):

Клик мышкой по плюсику развернет область, и мы увидим свернутые функции. Если хочется сразу развернуть все имеющиеся функции (в пределах области), то кликаем по плюсику удерживая Ctrl.

Вот такая мега удобная вещь и в модулях с большим количеством функций спасает очень даже. В предыдущих версиях платформы было модно использовать для подобных целей блоки комментариев, но управлять/добавлять областями явно удобней.

Форматирование кода

Собственно говоря, тут и рассказывать особо нечего – выделяем код, нажимаем «Alt + Shift + F» и редактор попытается привести его в божеский вид в соответствии с вшитым code-style. Функция работает вполне сносно и ей обязательно надо пользоваться. Пишу это потому, что неоднократно видел, как разработчики пытаются отбивать отступы самостоятельно. Это конечно круто, но зачем тратить время, если большую часть работы можно выполнить одной горячей клавишей?

Комментирование

Опять же, никаких секретных действий – выделили код, нажали “Ctrl + num /” (слеш на дополнительной области клавиатуры) и получили закомментированный участок. Захотели вернуть обратно? Не беда! Выделяем закомментированный участок кода, нажимаем «Ctrl + Shift + num /» и мгновенно приводим его в боевой режим. Фишка попсовая, но опять же, новички про нее не знают, и тратят кучу времени на расстановку слешей. Да еще и матерят компанию «1С», за отсутствие возможности многострочного комментирования, как в продвинутых язык программирования.

Быстрая вставка специальных символов

Иногда возникает необходимость быстро вставить в редактор специальный символ (которого нет на клавиатуре). В большинстве случаев разработчики используют для этого функции встроенного языка (например, символ). А ведь есть способ проще. Если удерживать клавишу Alt и набрать на доп. клавиатуре код нужного символа (из таблицы ASKII), то он тут же будет вставлен. Например, держим ALT и набираем 65. На выходе получаем букву «А». Или вводим 4 и получаем бубновую масть.

Вставка специальных символов

Хорошо, с этим понятно, но какой от этого еще можно получить профит? Лично я, таким образом вставляю символ амперсанда (&). Все знают, что этот символ используется для определения параметров в языке запросов. Неудобство состоит в том, что текст запроса мы пишем на русском языке, а для добавления этого символа перед параметром приходится переключить на английский, затем нажать Shift + 7, а потом вернуться обратно на русский.

Чтобы избавить себя от этой рутиной последовательности действий, я использую выше озвученную функцию. С ее помощью для установки амперсанда требуется лишь набрать с удержанной клавишей «alt» последовательность цифр 38. При этом надобность в двойном переключении языка отпадает.

Многие могут подумать, что я искусственно раздул проблему из ничего, но тут просто дело привычки. Кода приходится писать много и вот такие мелочи немного повышают производительность и избавляют от лишних нажатий клавиши backspace (для удаления случайно набранных символов). Не убедил? Тогда просто выделите время и попробуйте себя переучить

Автор: Игорь Антонов

Часто возникает необходимость в частичном ограничении доступа к данным. Например, когда пользователь должен видеть документы только своей организации. В таких случаях в 1С используется механизм ограничения доступа на уровне записей (так называемый, RLS – Record Level Securiy).

Для примера предположим, что перед нами стоит следующая задача. На предприятии ведется многофирменный учет и каждый контрагент и пользователь базы данных относится к определенной организации. Необходимо обеспечить доступ к справочнику “Контрагенты” таким образом, чтобы каждый пользователь мог просматривать, редактировать и добавлять контрагентов только своей организации.

Для решения задачи будем использовать платформу “1С:Предприятие 8.2″. Создадим новую конфигурацию в свойствах которой в качестве основного режима запуска будет выбран вариант “Управляемое приложение”.

Далее создадим справочник “Организации” и ещё два справочника – “Контрагенты” и “Пользователи” с реквизитом “Организация”. Кроме справочников нам понадобятся два параметра сеанса – “Организация” и “Пользователь” (соответствующих типов). Значения этих параметров устанавливаются при запуске сеанса работы с конфигурацией и хранятся до его завершения. Именно значения этих параметров мы и будем использовать при добавлении условий ограничения доступа на уровне записей.

Установка параметров сеанса выполняется в специальном модуле – “Модуль сеанса”

В этом модуле опишем предопределенную процедуру “УстановкаПараметровСеанса” в которой вызовем функцию заранее подготовленного общего модуля “ПолныеПрава”. Это необходимо в силу особенностей работы базы данных в режиме управляемого приложения, когда часть программного кода может выполняться только на стороне сервера (подробно на объяснении этих принципов в данной статье я останавливаться не буду).

 Процедура УстановкаПараметровСеанса(ТребуемыеПараметры)

    ПолныеПрава.УстановитьПараметрыСеанса();

КонецПроцедуры<br>   

В свойствах модуля “ПолныеПрава” необходимо отметить флажки “Сервер”, “Вызов сервера” и “Привилегированный” (последнее означает, что процедуры и функций данного модуля будут выполнятся без контроля прав доступа). Текст модуля будет выглядеть так:

 Функция ОпределитьТекущегоПользователя()

    ТекПользователь = Справочники.Пользователи.НайтиПоНаименованию(ИмяПользователя(),Истина);

    Возврат ТекПользователь;

КонецФункции





Процедура УстановитьПараметрыСеанса() Экспорт

    ТекущийПользователь = ОпределитьТекущегоПользователя();

    ТекущаяОрганизация = Справочники.Организации.ПустаяСсылка();

    Если ЗначениеЗаполнено(ТекущийПользователь) Тогда

        ТекущаяОрганизация = ТекущийПользователь.Организация;

    КонецЕсли;

    ПараметрыСеанса.Пользователь = ТекущийПользователь;

    ПараметрыСеанса.Организация = ТекущаяОрганизация;

КонецПроцедуры





Функция ПараметрСеансаУстановлен(ИмяПараметра) Экспорт

    Возврат ЗначениеЗаполнено(ПараметрыСеанса[ИмяПараметра]);

КонецФункции





Функция РольДоступнаПользователю(ИмяРоли) Экспорт

    Возврат РольДоступна(ИмяРоли);

КонецФункции<br>   

В модуле управляемого приложения будем проверять наличие пользователя конфигурации в справочнике “Пользователи” (для простоты будем искать его по наименованию) и завершать работу системы если он не найден. Это необходимо для того, чтобы обеспечить заполнение параметров сеанса.

 Процедура ПередНачаломРаботыСистемы(Отказ)

    // всех кроме администратора будем проверять на наличие в справочнике "Пользователи"

    Если Не ПолныеПрава.РольДоступнаПользователю("ПолныеПрава") Тогда

        Если НЕ ПолныеПрава.ПараметрСеансаУстановлен("Пользователь") Тогда

            Предупреждение("Пользователь """ + ИмяПользователя() + """ не найден в справочнике!");

            Отказ = Истина;

            Возврат;

        КонецЕсли;

    КонецЕсли;

КонецПроцедуры<br>   

Теперь можем перейти непосредственно к описанию ограничений доступа. Для этого создадим роль “Пользователь” и перейдем на закладку “Шаблоны ограничений”, где добавим новый шаблон “КонтрагентыЧтениеИзменение” со следующим текстом шаблона: ГДЕ Организация =Организация #Параметр(1)

Текст шаблона ограничений является расширением языка запросов. В отличии от обычного запроса, текст ограничения должен в обязательном порядке содержать условие “ГДЕ”. В качестве значений параметров запроса (в нашем случае это “&Организация”) используются значения одноименных параметров сеанса. Конструкция вида #Параметр(1) означает, что на это место система подставит текст, переданный в качестве первого параметра в месте использования шаблона. С помощь приведенного шаблона будет выполняться проверка каждой записи таблицы (в нашем случае это будет справочник “Контрагены”). Для записей, значение реквизита “Организация” которых совпадает с заданным в соответствующем параметре сеанса, условие описанное в шаблоне будет выполняться. Таким образом эти записи будут доступны для чтения, изменения или добавления (в зависимости от того для какого из этих прав применяется шаблон). Продемонстрирую вышеизложенное на нашем примере.

Перейдем на закладку “Права” роли “Пользователь” и откроем список прав справочника “Контрагенты”. Будем использовать шаблон ограничений “КонтрагентыЧтениеИзменеие” для прав “Чтение”, “Изменение” и “Доблавление”.

Для права “Чтение” будем использовать шаблон с параметром “ИЛИ ЭтоГруппа”. При этом пользователям данной роли будет разрешено чтение не только элементов справочника “Контрагенты” своей организации, но и всех групп этого справочника.

#КонтрагентыЧтениеИзменение("ИЛИ ЭтоГруппа")

Поскольку при добавлении новых элементов справочника системой выполняется неявное чтение предопределенных реквизитов (это нужно, например, для нумерации), то необходимо обеспечить беспрепятственное чтение этих полей. Для этого добавим дополнительную строку с пустым текстом ограничения в таблицу ограничения доступа к данным и перечислим поля для которых действует данное правило – Ссылка, Версия данных, Родитель, Код.

Таким образом, поставленная задача ограничения доступа на уровне записей решена. Пользователи с действующими ограничениями получат доступ на просмотр и редактирование данных только своей организации.

Источник

В 1С хранится номенклатура, которая в последствии выгружается на сайт. 

Для каждой выгружаемой номенклатуры нужно указать описание! Но не обычный текст, а хорошо оформленный, со списками, курсив, выделение:

Реализовано следующим образом:

• Реквизит объекта ОписаниеОсновное
• Реквизит формы фдОсновноеОписание

Код, который при изменении форматированного документа, помещает кусок HTML кода находящегося в BODY в реквизит ОписаниеОсновное:

 &НаКлиенте

Процедура фдОсновноеОписаниеПриИзменении(Элемент)

	Вложение = Новый Структура; текТекст ="";

	фдОсновноеОписание.ПолучитьHTML(текТекст,Вложение); 

	//Поправим валидность кода

	текТекст=СтрЗаменить (текТекст, "center'", "center;'");

	текТекст=СтрЗаменить (текТекст, "right'", "right;'");

	текТекст=СтрЗаменить (текТекст, "justify'", "justify;'");

	

	//Получим текст из BODY

	Содержимое=текТекст; НачалоБлока = "<body>"; КонецБлока = "</body>";

	текТекст = Сред(Содержимое, Найти(Содержимое, НачалоБлока) + СтрДлина(НачалоБлока), Найти(Содержимое, КонецБлока) - Найти(Содержимое, НачалоБлока) - СтрДлина(НачалоБлока));	  				

	

	Объект.ОписаниеОсновное = СокрЛП(текТекст);

КонецПроцедуры   

При открытии:

 &НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

	фдОсновноеОписание.УстановитьHTML(Объект.ОписаниеОсновное,Новый Структура);

КонецПроцедуры   

Что такое маска и для чего она нужна описано в статье: Поле ввода ~ Маска

В данном примере я хочу показать, как правильно ввести маску для ввода телефона

Телефонный номер это основной реквизит и используется в каждой базе - его корректное отображение упростит ввод и восприятие информации!

В поле Маска введите: 9 (999) 999 99 99

в режиме предприятие будет выглядеть так:

Еще примеры:

• сотовый телефон клиента: 9 (999) 999-99-99
• городской (без указания кода города): 999-99-99

В процессе работы предприятия нередко возникает необходимость узнать кто, когда и что именно изменял в документе или справочнике программы. 

Очень часто мне задают вопросы: 

• Как в 1С 8.2 посмотреть поменявшего документ?
• Как в 1с посмотреть изменившего документ?
• Как в 1С узнать кто и когда изменял документы?
• Как в 1С узнать кто изменил проводку в документе?
• Как посмотреть кто изменял документ в 1с?

Журнал регистрации 

Содержит информацию о том, какие события происходили в информационной базе в определенный момент времени или какие действия выполнял тот или иной пользователь. Для каждой записи журнала, отражающей изменение данных, отображается статус завершения транзакции (транзакция завершена успешно, или же транзакция отменена).

Журнал регистрации доступен как в режиме 1С:Предприятие, так и в режиме Конфигуратор.

Доступ к журналу регистрации возможен как из режима Конфигуратора (через меню Администрирование - Журнал регистрации), так и из режима Предприятия (меню Сервис - Журнал регистрации). В режиме Такси (Основное меню - Все функции - Стандартные - Журнал регистрации)

Вид журнала регистрации (Обычные формы и Такси):

Отбор в журнале регистрации (Обычные формы и Такси):

Используя средства работы со списками имеется возможность выгрузить журнал регистрации в табличный или, при необходимости, текстовый документ (через Действия - Вывести список) , который в дальнейшем может быть сохранен например в формате Excel , TXT или HTML. При этом существует возможность настройки уровня событий, которые будут фиксироваться в журнале регистрации, а также периодичности разделения журнала на отдельные файлы (в режиме конфигуратора меню Администрирование - Настройка журнала регистрации). 

И там же есть возможность сократить количество записей данного журнала до определенной даты, что делается для ускорения работы с механизмом анализа и регистрации событий в системе или за ненадобностью неактуальной информации.

Где хранится журнал регистрации

В Файловой базе: в каталоге базы папка 1Cv8Log - это и есть директория содержащая журнал регистрации.

Если вы планируете перенести файловую базу данных и хотите сохранить историю журнала регистрации & вам обязательно надо скопировать папку 1Cv8Log в категорию новой базы 1С. Если необходимо очистить журнал регистрации 1С в файловой базе просто удалите папку 1Cv8Log.

В Клиент-серверной базе: C:\Program Files\1cv8\srvinfo\<Имя кластера сервера>\<Идентификатор базы на сервере>\1Cv8Log

С версии 8.3.5.1068. Значительно переработали журнал регистрации для того, чтобы увеличить скорость выполнения запросов к журналу и повысить надёжность хранения данных.

Для этого, в том числе, потребовалось изменить формат хранения журнала регистрации. Теперь он хранится в одном файле базы данных SQLite. Этот файл имеет расширение lgd.

Версионирование объектов

В некоторых конфигурациях 1С внедрен специальный механизм «Версионирование объектов».

По умолчанию версионирование выключено, чтобы включить откройте Сервис - Настройки учета - Настройка параметров учета

По кнопке «Настройка версионирования объектов» выбираем, какие справочники и документы нужно версионировать (наблюдать за тем, кто, что и когда изменил).

По умолчанию наблюдение за объектами информационной базы не ведется, поетому напротив каждого типа документов установлен признак «Не версионировать». Если нужно чтоб наблюдение велось, нужно установить «Версионировать» напротив интересующего журнала документов.

Все, при закрытии окна и нажатии на кнопку «Оk» наблюдение за объектами будет вестись.

Для того чтоб просмотреть все изменения которые кто-то делал в документе или справочнике нужно перейти в меню: Сервис - История изменений объектов

Нужно выводить на каждой странице отчета, шапку. Отчет сделан через СКД (Схема компоновки данных). В схеме есть макет, в нем есть ячейки шапки.

Для этого используется метод - ПовторятьПриПечатиСтроки, о нем я уже писал: Как при печати выводить шапку на каждой странице (ПовторятьПриПечатиСтроки)?

Код кнопки формирования отчета:

 СводнаяКартаРезультат = Новый ТабличныйДокумент;

   

ПечатьСводнойКартыНаСервере(СводнаяКартаРезультат);

СводнаяКартаРезультат.Показать("СводнаяКарта");   

Процедура вывода отчета:

 &НаСервере

Процедура ПечатьСводнойКартыНаСервере(СводнаяКартаРезультат)   

   СхемаКомпоновкиДанных = Справочники.Номенклатура.ПолучитьМакет("МакетСводнаяКарта");   

   

   СводнаяКартаРезультат.ПовторятьПриПечатиСтроки = СводнаяКартаРезультат.Область(7, , 7); // <- Строки вывода повторения нужно считать в уже результате вывода, а не в макете!

   

   Настройки = СхемаКомпоновкиДанных.НастройкиПоУмолчанию;

      

   НомеклатураСсылка = Настройки.ПараметрыДанных.Элементы.Найти("НоменклатураСсылка");   

   НомеклатураСсылка.Значение = Объект.Ссылка;

   НомеклатураСсылка.Использование = Истина;

   

   ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;

   КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;



   МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных,Настройки, ДанныеРасшифровки);



   ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;

   ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки,,ДанныеРасшифровки);



   ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;

   ПроцессорВывода.УстановитьДокумент(СводнаяКартаРезультат);

   //ПроцессорВывода.ОтображатьПроцентВывода = Истина;

   

   ПроцессорВывода.НачатьВывод();

   ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных, Истина);   

   ПроцессорВывода.ЗакончитьВывод();

   

КонецПроцедуры   

Если дополнительно нужно вывести колонтитулы, 

тогда:

 // Верхний колонтитул 

ТабДок.ВерхнийКолонтитул.Выводить = Истина;

ТабДок.ВерхнийКолонтитул.НачальнаяСтраница = 2;

ТабДок.ВерхнийКолонтитул.Шрифт = Новый Шрифт(Результат.ВерхнийКолонтитул.Шрифт, , , , Истина);

ТабДок.ВерхнийКолонтитул.ТекстСлева = "Заголовок отчета";

ТабДок.ВерхнийКолонтитул.ТекстВЦентре = "Стр. [&НомерСтраницы] из [&СтраницВсего]";

ТабДок.ВерхнийКолонтитул.ТекстСправа = "Дата/время печати: [&Дата]/[&Время]";

	

// Нижний колонтитул 

ТабДок.НижнийКолонтитул.Выводить = Истина;

ТабДок.НижнийКолонтитул.Шрифт = Новый Шрифт(Результат.ВерхнийКолонтитул.Шрифт, , , , Истина);

ТабДок.НижнийКолонтитул.ТекстВЦентре = "Заголовок отчета";   

Необходимо при печати, если происходит переход на следующую страницу таблицы, выводить шапку таблицы вверху на новой странице.

для печати шапки на каждой странице в языке программирования есть специальный метод - ПовторятьПриПечатиСтроки

Примеры его использования:

 ТабДок.ПовторятьПриПечатиСтроки = ТабДок.Область(1, , 2, );

ЭлементыФормы.Поле_ТД.ПовторятьПриПечатиСтроки = Макет.Область("Шапка_Спецификации"); //или так  

ЭлементыФормы.Поле_ТД.ПовторятьПриПечатиСтроки = Макет.Область("R777:R778");   

Полный код вывода табличного документа с повторением шапки на каждой странице:

 Функция ПечатьПриказаТ11а()



	ТабДокумент = Новый ТабличныйДокумент;

	ТабДокумент.ИмяПараметровПечати = "ПАРАМЕТРЫ_ПЕЧАТИ_ПечатнаяФорма_МатериальнаяПомощь_Т11а";

	ТабДокумент.ПовторятьПриПечатиСтроки = ТабДокумент.Область("R21:R22");

	

	Макет 		= ПолучитьМакет("Т11а");

	ОбластьМакетаШапкаДокумента = Макет.ПолучитьОбласть("Шапка");

	ОбластьПовторятьПриПечати	= Макет.ПолучитьОбласть("ПовторятьПриПечати");

	ОбластьМакетаСтрока 		= Макет.ПолучитьОбласть("Строка");

	ОбластьМакетаПодвал 		= Макет.ПолучитьОбласть("Подвал");





	ВыборкаДляШапкиДокумента = СформироватьЗапросДляШапкиДокумента().Выбрать();

	ВыборкаРаботники = СформироватьЗапросДляТабличнойЧасти(1).Выбрать();  		// ТЧ "Начисления"

	Если ВыборкаРаботники.Количество() = 0 Тогда

		ВыборкаРаботники = СформироватьЗапросДляТабличнойЧасти(2).Выбрать();	// ТЧ "Доп.Начисления"

	КонецЕсли;		

	

	// Массив с двумя строками - для разбиения на страницы

	ВыводимыеОбласти = Новый Массив();

	ВыводимыеОбласти.Добавить(ОбластьМакетаСтрока);

	

	// Вывод шапки документа

	Пока ВыборкаДляШапкиДокумента.Следующий() Цикл

		ОбластьМакетаШапкаДокумента.Параметры.Заполнить(ВыборкаДляШапкиДокумента);

 		ОбластьМакетаШапкаДокумента.Параметры.НазваниеОрганизации = СокрЛП(ОбластьМакетаШапкаДокумента.Параметры.НазваниеОрганизации);

	КонецЦикла;

	ТабДокумент.Вывести(ОбластьМакетаШапкаДокумента);

	ном=0;

	Пока ВыборкаРаботники.Следующий() Цикл

		ОбластьМакетаСтрока.Параметры.Заполнить(ВыборкаРаботники);

		ном=ном+1;

		ОбластьМакетаСтрока.Параметры.ПодразделениеОрганизации	= ВыборкаРаботники.ПодразделениеОрганизации.ПолноеНаименование();		

		ОбластьМакетаСтрока.Параметры.ном=ном;

		ТабДокумент.Вывести(ОбластьМакетаСтрока);

	КонецЦикла;

	

	ОбластьМакетаПодвал.Параметры.Заполнить(ВыборкаДляШапкиДокумента); // Из запроса шапка документа.

	ТабДокумент.Вывести(ОбластьМакетаПодвал);





	Если ТабДокумент.ВысотаТаблицы > 0 Тогда

		Возврат УниверсальныеМеханизмы.НапечататьДокумент(ТабДокумент, 1, Ложь, ОбщегоНазначения.СформироватьЗаголовокДокумента(СсылкаНаОбъект,"Приказ о поощрении работника "));

	КонецЕсли;

	//Возврат ТабДокумент;



КонецФункции   

На днях делал несколько однотипных отчетов на СКД. 

Общий принцип: формируются все варианты отчета, указанные в настройках схемы и каждый вариант выводится на отдельной вкладке.

Потом возникла мысль попробовать объединить все схемы в один отчет, чтобы не плодить лишних объектов в конфигурации. При этом количество вариантов в этих схемах заранее неизвестно. Ok, challenge accepted.

В тестовой конфигурации создаю для отчета две схемы компоновки, "Склад" и "Заявки".

Запросы наборов данных приводить не буду, для каждой схемы в настройках добавляю несколько вариантов отчетов.

Теперь переходим к созданию формы. Практически все реквизиты формы будут создаваться при выборе необходимого макета отчета.

 &НаСервере

Процедура СоздатьПереченьОтчетов()





 Для Каждого Макет Из РеквизитФормыВЗначение("Отчет").Метаданные().Макеты Цикл

  Элементы.МакетОтчета.СписокВыбора.Добавить(Макет.Имя, Макет.Синоним);

 КонецЦикла;





КонецПроцедуры // СоздатьПереченьОтчетов()





&НаСервере

Процедура ОбработатьВыборМакета()





 Макет = РеквизитФормыВЗначение("Отчет").ПолучитьМакет(МакетОтчета);

 

 мУдалить = ?(ПустаяСтрока(РеквизитыКУдалению), Новый Массив, ПолучитьИзВременногоХранилища(РеквизитыКУдалению));

 мДобавить = Новый Массив;

 кУдалению = Новый Массив;

 

 Для Каждого Вариант Из Макет.ВариантыНастроек Цикл

  ИмяРеквизита = "ТабДок_" + Вариант.Имя;

  тРеквизит = Новый РеквизитФормы(ИмяРеквизита, Новый ОписаниеТипов("ТабличныйДокумент"));

  мДобавить.Добавить(тРеквизит);

  кУдалению.Добавить(ИмяРеквизита);

 КонецЦикла;

 

 ИзменитьРеквизиты(мДобавить, мУдалить);

 

 Пока Элементы.СтраницыОтчета.ПодчиненныеЭлементы.Количество() Цикл

  Элементы.Удалить(Элементы.СтраницыОтчета.ПодчиненныеЭлементы[0]);

 КонецЦикла;

 

 Для Каждого Вариант Из Макет.ВариантыНастроек Цикл

  

  Страница = Элементы.Добавить("Страница_" + Вариант.Имя, Тип("ГруппаФормы"), Элементы.СтраницыОтчета);

  Страница.Вид = ВидГруппыФормы.Страница;

  Страница.Заголовок = Вариант.Представление;

  

  ИмяРеквизита = "ТабДок_" + Вариант.Имя;

  ТабДок = Элементы.Добавить(ИмяРеквизита, Тип("ПолеФормы"), Страница);

  ТабДок.Вид = ВидПоляФормы.ПолеТабличногоДокумента;

  ТабДок.ПутьКДанным = ИмяРеквизита;

  ТабДок.ПоложениеЗаголовка = ПоложениеЗаголовкаЭлементаФормы.Нет;

  

  ЭтаФорма[ИмяРеквизита].Очистить();





 КонецЦикла;

 

 РеквизитыКУдалению = ПоместитьВоВременноеХранилище(кУдалению, УникальныйИдентификатор);





КонецПроцедуры // ОбработатьВыборМакета()





&НаСервере

Процедура СформироватьОтчеты()





 Схема = РеквизитФормыВЗначение("Отчет").ПолучитьМакет(МакетОтчета);

 

 Для Каждого Вариант Из Схема.ВариантыНастроек Цикл

  

  Отчет.КомпоновщикНастроек.ЗагрузитьНастройки(Вариант.Настройки);

     

     КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;

     Макет = КомпоновщикМакета.Выполнить(Схема, Отчет.КомпоновщикНастроек.ПолучитьНастройки());

     

     ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;

     ПроцессорКомпоновки.Инициализировать(Макет);

     

     ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;

     ПроцессорВывода.УстановитьДокумент(ЭтаФорма["ТабДок_" + Вариант.Имя]);

     ПроцессорВывода.Вывести(ПроцессорКомпоновки); 

  

 КонецЦикла;





КонецПроцедуры // СформироватьОтчеты()





&НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

 

 СоздатьПереченьОтчетов();

 

КонецПроцедуры





&НаКлиенте

Процедура МакетОтчетаПриИзменении(Элемент)

 

 ОбработатьВыборМакета();

 

КонецПроцедуры





&НаКлиенте

Процедура Сформировать(Команда)

 

 СформироватьОтчеты();

 

КонецПроцедуры   

Смотрим, что получилось.

Выгрузка базы 1Cv8skd.rar 

Источник

Задача

Передать информацию о контрагентах из УП в БП. Данные передаются в одностороннем порядке, идентификация производится по уникальному идентификатору.Настройка правил конвертации выполняется с помощью специальной конфигурации Конвертация данных, редакция 3.0 (далее – КД 3.0).

Выполняемые действия

Этап 1. Подготовка к настройке правил.

Для настройки правил конвертации в конфигурации КД 3.0 должны содержаться сведения о структуре информационных баз, между которыми производится синхронизация данных, а также о структуре формата Enterprise Data.

Шаг 1. Выгрузка структуры информационных баз УП и БП.

Для выгрузки информации о структуре информационной базы используется обработкаMD83Exp.epf, входящая в комплект поставки конфигурации КД 3.0.

Для каждой информационной базы (УП и БП) необходимо выполнить следующие действия:

1. Открыть информационную базу в режиме “Предприятие”.
2. Открыть внешнюю обработку MD83Exp.epf (Меню Файл & Открыть).
3. Указать имя файла, в который следует сохранить структуру информационной базы.
4. Проверить настройки в форме обработки (все флаги должны быть сняты).
5. Нажать кнопку Выгрузить.

Шаг 2. Экспорт xml-схемы формата обмена

Для выгрузки схемы формата обмена используются стандартные возможности платформы.

Необходимо выполнить следующие действия:

1. Открыть одну из информационных баз (либо УП либо БП) в режиме “Конфигуратор”.
2. В дереве метаданных найти XDTO пакеты с именами ExchangeMessage иEnterpriseData_1_0_beta.
3. Установить курсор на пакет XDTO, нажать правую кнопку мыши и в контекстном меню выбрать пункт Экспорт XML-схемы. Указать путь и имя файла для экспорта. Выполнить это действие для каждого из двух пакетов, сохранив XML-схемы в два разных файла.

Шаг 3. Загрузка структуры информационных баз в конфигурацию КД 3.0

Загрузка выполняется в конфигурацию КД 3.0 в режиме “Предприятие”. Перечисленные ниже действия следует выполнить для каждой из конфигураций, для которых настраиваются правила конвертации (УП и БП).

1. Перейти в раздел Конфигурации, и выбрать команду Загрузка структуры конфигурации.
2. Указать путь к файлу со структурой информационной базы (см. Этап 1, Шаг 1).
3. Указать способ загрузки & в новую версию конфигурации.
4. Нажать кнопку Выполнить загрузку, дождаться окончания загрузки.

Шаг 4. Загрузка структуры формата обмена в конфигурацию КД 3.0

Загрузка выполняется в конфигурацию КД 3.0 в режиме “Предприятие”.

1. Перейти в раздел Формат данных, и выбрать команду Загрузка структуры формата.
2. Указать файлы со структурой формата (см. Этап 1, Шаг 2). Необходимо указать сразу оба файла, используя множественный выбор.
3. Проверить имя основного пакета XDTO – должен совпадать с пространством имен пакета XDTO EnterpriseData_1_0_beta (см. в конфигураторе УП или БП).
4. Указать способ загрузки & в новую версию формата.
5. Нажать кнопку Выполнить загрузку, дождаться окончания загрузки.

Этап 2. Создание конвертаций

Для решения описанной задачи необходимо создать две конвертации:

• УП (для выгрузки данных из УП в формат обмена)
• БП (для загрузки данных из формата обмена в БП)

Создание конвертаций производится в разделе Конвертации, команда Конвертации. Для новой конвертации необходимо указать наименование, конфигурацию и формат обмена. Например, конвертация для конфигурации УП:

• Наименование & “УП2.0.7”.
• Конфигурация & “УправлениеПредприятием”.
• Поддерживаемые версии формата & одна строка, в которой выбрана единственная позиция справочника Версии формата.

Далее для каждой из двух конвертаций требуется настроить правила:

• правила обработки данных,
• правила конвертации объектов,
• правила конвертации предопределенных данных.

Для перехода к комплекту правил конкретной конвертации необходимо перейти в разделКонвертации, выбрать команду Настройка правил конвертации и выбрать в списке конкретную конвертацию, для которой будут настраиваться правила. В результате будет открыта форма Настройка правил обмена, в которой собраны все правила для конкретной конвертации.

Этап 3. Создание правил конвертации объектов

Шаг 1. Правило конвертации для выгрузки контрагентов из УП

1. Открыть настройку правил обмена для конвертации УП.
2. Перейти на закладку Правила конвертации объектов.
3. Создать новое правило конвертации и заполнить данные на закладке Основные сведения:
   1. Идентификатор правила: “Справочник_Контрагенты_Отправка”,
   2. Объект конфигурации: “СправочникСсылка.Контрагенты”,
   3. Объект формата: “Справочник.Контрагенты”,
   4. Область применения: Для отправки.
4. Нажать кнопку Записать и перейти на закладку Правила конвертации свойств:
   1. Воспользоваться сервисом автоматического сопоставления свойств
      1. Нажать кнопку Настройка ПКС
      2. В открывшейся форме нажать Автосопоставление. Сопоставятся свойства “ИНН”, “КПП”, “Наименование”, “НаименованиеПолное”, “ДополнительнаяИнформация”, “ЮридическоеФизическоеЛицо”
      3. Сохранить результат автоматического сопоставления & нажать кнопкуСоздать правила конвертации свойств и закрыть форму настройки правил конвертации свойств
   2. Вручную добавить правило конвертации свойства для ОКПО (свойство конфигурации & “КодПоОКПО”, свойство формата & “ОКПО”).
   3. Позже потребуется вернуться к правилам конвертации свойств, чтобы заполнить правило конвертации свойства для свойства “ЮридическоеФизическоеЛицо”, которое является перечислением.
5. Нажать кнопку Записать и закрыть.

Шаг 2. Правило конвертации для загрузки контрагентов в БП

1. Открыть настройку правил обмена для конвертации БП.
2. Перейти на закладку Правила конвертации объектов.
3. Создать новое правило конвертации и заполнить данные на закладке Основные сведения:
   1. Идентификатор правила: “Справочник_Контрагенты_Получение”,
   2. Объект конфигурации: “СправочникСсылка.Контрагенты”,
   3. Объект формата: “Справочник.Контрагенты”,
   4. Область применения: Для получения.
4. Нажать кнопку Записать и перейти на закладку Идентификация. Указать способ идентификации «По уникальному идентификатору».
5. Перейти на закладку Правила конвертации свойств
   1. Воспользоваться сервисом автоматического сопоставления свойств:
      1. Нажать кнопку Настройка ПКС
      2. В открывшейся форме нажать Автосопоставление. Сопоставятся свойства “ИНН”, “КПП”, “Наименование”, “НаименованиеПолное”, “ДополнительнаяИнформация”, “ЮридическоеФизическоеЛицо”.
      3. Сохранить результат автоматического сопоставления & нажать кнопкуСоздать правила конвертации свойств и закрыть форму настройки правил конвертации свойств.
   2. Вручную добавить правило конвертации свойства для ОКПО (свойство конфигурации & “КодПоОКПО”, свойство формата & “ОКПО”).
   3. Позже потребуется вернуться к правилам конвертации свойств, чтобы заполнить правило конвертации свойства для свойства “ЮридическоеФизическоеЛицо”, которое является перечислением.
6. Перейти на закладку ПередЗаписьюПолученныхДанных и написать алгоритм для заполнения страны регистрации нового контрагента. Алгоритм содержит следующий текст: «ПолученныеДанные.СтранаРегистрации = Справочники.СтраныМира.Россия;».
7. Нажать кнопку Записать и закрыть.

Этап 4. Создание правил конвертации предопределенных данных

Порядок действий одинаков для обоих конвертаций.

1. Открыть настройку правил обмена для конвертации (УП или БП)
2. Перейти на закладку Правила конвертации предопределенных данных
3. Создать новое правило конвертации и заполнить его свойства:
   1. Идентификатор правила: “Перечисление_ЮридическоеФизическоеЛицо”
   2. Объект конфигурации: “ПеречислениеСсылка.ЮридическоеФизическоеЛицо”
   3. Объект формата: “ЮридическоеФизическоеЛицо”
   4. Область применения: для отправки и получения
   5. В табличном поле заполнить соответствия значений перечисления конфигурации и формата: “ФизическоеЛицо” & “ФизическоеЛицо” и “ЮридическоеЛицо” & “ЮридическоеЛицо”
   6. Нажать кнопку Записать и закрыть
4. Указать новое правило в правиле конвертации свойства “ЮридическоеФизическоеЛицо” справочника Контрагенты
   1. Перейти на закладку Правила конвертации объектов
   2. Найти правило конвертации справочника Контрагенты, открыть форму правила
   3. Перейти на закладку Правила конвертации свойств и найти правило для свойства “ЮридическоеФизическоеЛицо”
   4. Открыть форму правила конвертации свойства и указать в нем правило конвертации объекта & “Перечисление_ЮридическоеФизическоеЛицо”.
   5. Сохранить внесенные изменения

Этап 5. Создание правил обработки данных

Порядок действий одинаков для обоих конвертаций.

1. Открыть настройку правил обмена для конвертации (УП или БП)
2. Перейти на закладку Правила конвертации объектов
3. Найти правило конвертации справочника Контрагенты, открыть форму правила
4. Нажать кнопку Создать на основании & Правило обработки данных
5. В созданном правиле обработки данных проверить заполнившиеся автоматически свойства:
   1. Идентификатор правила & указать такой же как для правила обработки данных (“Справочник_Контрагенты_Отправка” либо “Справочник_Контрагенты_Получение”)
   2. Область применения & такая же как для правила обработки данных
   3. Объект выборки:
      1. для конвертации УП & “СправочникСсылка.Контрагенты”
      2. для конвертации БП & “Справочник.Контрагенты”
   4. Правило конвертации объекта & ссылка на правило конвертации объекта.
6. Нажать кнопку Записать и закрыть.

Этап 6. Получение модулей менеджера обмена данными

Модуль менеджера обмена данными необходим для обмена данными между конфигурациями в соответствии с настроенными в КД 3.0 правилами.

Порядок действий одинаков для обеих конвертаций:

1. Открыть информационную базу УП или БП в режиме “Конфигуратор”. Найти в дереве метаданных общий модуль МенеджерОбменаЧерезУниверсальныйФормат и открыть его для редактирования. Модуль должен быть пустым.
2. Открыть информационную базу КД 3.0 в режиме “Предприятие”.
3. Перейти в раздел Конвертации и выбрать команду Выгрузка модуля.
4. В открывшейся форме указать соответствующую конвертацию и нажать кнопку Выгрузить. Модуль будет скопирован в буфер обмена.
5. Перейти в конфигуратор информационной базы УП или БП и вставить содержимое буфера обмена в общий модуль МенеджерОбменаЧерезУниверсальныйФормат.
6. Сохранить конфигурацию.

Выгрузка модуля в буфер обмена также может производиться из формы настройки правил обмена по кнопке Сохранить модуль менеджера обмена.

Для того чтобы по настроенным правилам выполнялся обмен данными, необходимо в обеих информационных базах в режиме “Предприятие” настроить синхронизацию данных через универсальный формат.

Источник

Для управления регистрацией документа в последовательности документов служит набор записей регистрации в последовательности документов. 

У документа есть свойство ПринадлежностьПоследовательностям. Значением свойства является коллекция наборов записей регистрации в последовательности документов. Для каждой последовательности, в которой участвует документ, существует свой собственный экземпляр набора записей. Если у документа стоит режим автоматического заполнения последовательностей, то перед записью документа наборы записей регистрации будут автоматически заполнены. Для последовательностей без измерений набор записей будет содержать только одну запись. Для последовательностей с измерениями число записей зависит от содержания документа и настройки соответствия измерений последовательности реквизитам документа.

Набор записей автоматически заполняется до записи документа и записывается после записи документа в одной транзакции с ним. Это позволяет в обработчиках событий документа ПередЗаписью() и ПриЗаписи() переопределить набор записей регистрации. Так, например, если документ входит в последовательность Последовательность1 и у документа стоит признак автоматического заполнения последовательности, то для того что бы отменить его регистрацию в последовательности в зависимости от значения реквизита документа достаточно в модуль документа вставить обработчик события ПередЗаписью() следующего содержания:

 Процедура ПередЗаписью(Отказ, РежимЗаписи, РежимПроведения)

	Если Не Регистрировать Тогда

		ПринадлежностьПоследовательностям.Последовательность1.Очистить();

	КонецЕсли;

КонецПроцедуры   

В этом случае если реквизит Регистрировать имеет значение "Ложь", то документ не будет зарегистрирован в последовательности Последовательность1. Кроме отмены регистрации документа в последовательности, доступна возможность написания собственного алгоритма регистрации документа в последовательности. Для этого надо очистить набор записей регистрации и заполнить его новыми записями.

 Процедура ПередЗаписью(Отказ, РежимЗаписи, РежимПроведения) 

	ПринадлежностьПоследовательностям.Последовательность1.Очистить();

	Если ВидРегистрации = 1 Тогда

		ЗП = ПринадлежностьПоследовательностям.Последовательность1.Добавить();

		ЗП.Измерение = Реквизит1;

	ИначеЕсли ВидРегистрации = 2 Тогда

		ПринадлежностьПоследовательностям.Последовательность1.Добавить();

		ЗП.Измерение = Реквизит2;

	КонецЕсли;

КонецПроцедуры

   

Пример

 	// Зарегистрируем в последовательности УУ

		Если ОтражатьВУправленческомУчете Тогда

			ЗаписьРегистрации = ПринадлежностьПоследовательностям.ПартионныйУчет.Добавить();

			ЗаписьРегистрации.Период      = Дата;

		КонецЕсли;



Процедура ПоследовательностьВзаиморачеты(ДокумСсылка) Экспорт 

	ДокументМоментВремени = Новый МоментВремени(ДокумСсылка.дата, ДокумСсылка);

	

	НаборЗаписей = Последовательности.Взаиморасчеты.СоздатьНаборЗаписей();

	НаборЗаписей.Отбор.Регистратор.Установить(ДокумСсылка);

	НоваяЗапись = НаборЗаписей.Добавить();

	НоваяЗапись.Регистратор = ДокумСсылка;

	НоваяЗапись.Период = ДокумСсылка.Дата;

	НаборЗаписей.Записать(); 

	

	//Установим границу последовательности на документ

	Последовательности.Взаиморасчеты.УстановитьГраницу(ДокументМоментВремени);

КонецПроцедуры



Функция ПолучитьГраницуПоследовательности(Организация = Неопределено) Экспорт

	

	Запрос = Новый Запрос;

	Запрос.Текст = 

	"ВЫБРАТЬ

	|	ПартионныйУчетГраницы.МоментВремени

	|ИЗ

	|	Последовательность.ПартионныйУчет.Границы КАК ПартионныйУчетГраницы

	|";

	

	Выборка = Запрос.Выполнить().Выбрать();

	Если Выборка.Следующий() Тогда

		Возврат  Выборка.МоментВремени;

	Иначе

		Возврат Новый МоментВремени('00010101');

	КонецЕсли;



КонецФункции



Процедура ОбновитьСписокПоследовательностей()

	

	Для каждого Последовательность Из Обр.СписокПоследовательностей Цикл

		ИмяПоследовательности = Последовательность.ИмяПоследовательности;

		ГраницаПоследовательности = Последовательности[ИмяПоследовательности].ПолучитьГраницу();

		ДатаГраницы = ГраницаПоследовательности.Дата;

		Последовательность.Актуальность = "" + ДатаГраницы + " " + ГраницаПоследовательности.Ссылка;

		Последовательность.ДатаГраницы = ДатаГраницы;

	КонецЦикла;

	

КонецПроцедуры



// Процедура выполняет поиск и исправление ошибок в последовательности.

//

Процедура КорректировкаРегистрацииВПоследовательности()





	Для Каждого ТекПоследовательность Из Метаданные.Последовательности Цикл

		ТекстЕстьДвижения = "

						|	ВЫБОР

						|		КОГДА СписанныеТоварыСрезПоследних.Регистратор ЕСТЬ NULL";

		Для Каждого ДвиженияВлияющиеНаПоследовательность Из ТекПоследовательность.Движения Цикл

			ТекстЕстьДвижения = ТекстЕстьДвижения + "

						|				И РегистрНакопления" + ДвиженияВлияющиеНаПоследовательность.Имя + ".Регистратор ЕСТЬ NULL";

		КонецЦикла;

		ТекстЕстьДвижения = ТекстЕстьДвижения + "

						|			ТОГДА ЛОЖЬ

						|		ИНАЧЕ ИСТИНА

						|	КОНЕЦ";





		ТекстЗапроса = "ВЫБРАТЬ

						|	Последовательность.Регистратор КАК Регистратор,

						|	Последовательность.Регистратор.Проведен КАК Проведен,

						|	Последовательность.Регистратор.Дата КАК Дата,

						|	Последовательность.Период КАК Период,

						|" + ТекстЕстьДвижения + " КАК ЕстьДвижения

						|ИЗ

						|	Последовательность." + ТекПоследовательность.Имя + " КАК Последовательность

						|		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.СписанныеТовары КАК СписанныеТоварыСрезПоследних

						|		ПО Последовательность.Регистратор = СписанныеТоварыСрезПоследних.Регистратор

						|		И СписанныеТоварыСрезПоследних.НомерСтроки = 1";

		Для Каждого ДвиженияВлияющиеНаПоследовательность Из ТекПоследовательность.Движения Цикл

			ТекстЗапроса = ТекстЗапроса + "

						|		ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления." +ДвиженияВлияющиеНаПоследовательность.Имя + ".Обороты(, , Регистратор, ) КАК РегистрНакопления" + ДвиженияВлияющиеНаПоследовательность.Имя + "

						|		ПО Последовательность.Регистратор = РегистрНакопления" + ДвиженияВлияющиеНаПоследовательность.Имя + ".Регистратор";

		КонецЦикла;





		ТекстЗапроса = ТекстЗапроса + "

						|ГДЕ

						|	НЕ (Последовательность.Регистратор.Проведен

						|	    И (Последовательность.Регистратор ССЫЛКА Документ.КорректировкаСтоимостиСписанияТоваров

						|	       ИЛИ Последовательность.Регистратор.Дата = Последовательность.Период)

						|       И " + ТекстЕстьДвижения + ")

						|";





		Запрос = Новый Запрос(ТекстЗапроса);





		Выборка = Запрос.Выполнить().Выбрать();

		Пока Выборка.Следующий() Цикл

			Если Не Выборка.Проведен Тогда

				НаборЗаписей = Последовательности[ТекПоследовательность.Имя].СоздатьНаборЗаписей();

				НаборЗаписей.Отбор.Регистратор.Установить(Выборка.Регистратор);

				НаборЗаписей.Записать();

			ИначеЕсли (Выборка.Дата <> Выборка.Период)

			        И (ТипЗнч(Выборка.Регистратор) <> Тип("ДокументСсылка.КорректировкаСтоимостиСписанияТоваров")) Тогда

				НаборЗаписей = Последовательности[ТекПоследовательность.Имя].СоздатьНаборЗаписей();

				НаборЗаписей.Отбор.Регистратор.Установить(Выборка.Регистратор);

				НаборЗаписей.Прочитать();

				Для Каждого СтрокаНабора Из НаборЗаписей Цикл

					СтрокаНабора.Период = Выборка.Дата;

				КонецЦикла;

				НаборЗаписей.Записать();

			КонецЕсли;





			Если Не Выборка.ЕстьДвижения Тогда

				НаборЗаписей = Последовательности[ТекПоследовательность.Имя].СоздатьНаборЗаписей();

				НаборЗаписей.Отбор.Регистратор.Установить(Выборка.Регистратор);

				НаборЗаписей.Записать();

			КонецЕсли;

		КонецЦикла;

	КонецЦикла;





КонецПроцедуры



Процедура УдалитьРегистрациюДокументаВПоследовательностях(ДокументОбъект, ПроверятьДвижения = Ложь)Экспорт

	// получение списка последовательностей в которых зарегистрирован документ

	Если ПроверятьДвижения Тогда

		ТаблицаРегистраций = ОпределитьНаличиеРегистрацииДокументаВПоследовательности(ДокументОбъект);

	КонецЕсли;      

	КоллекцияПоследовательностей = ДокументОбъект.ПринадлежностьПоследовательностям;

	Для Каждого НаборЗаписейРегистрацииВПоследовательности ИЗ КоллекцияПоследовательностей Цикл

		Если (НаборЗаписейРегистрацииВПоследовательности.Количество() > 0)

		  ИЛИ (ПроверятьДвижения И (НЕ ТаблицаРегистраций.Найти(НаборЗаписейРегистрацииВПоследовательности.Метаданные().Имя,"Имя") = Неопределено)) Тогда

		   НаборЗаписейРегистрацииВПоследовательности.Очистить();

		КонецЕсли;

	КонецЦикла;

КонецПроцедуры//УдалитьРегистрациюДокументаВПоследовательностях



Функция ОпределитьНаличиеРегистрацииДокументаВПоследовательности(ДокументОбъект) Экспорт

	ТекстЗапроса = "";	

	

	Для Каждого Последовательность ИЗ ДокументОбъект.ПринадлежностьПоследовательностям Цикл

		// в запросе получаем имена последовательностей, в которых документ зарегистрирован

		ТекстЗапроса = ТекстЗапроса + "

		|" + ?(ТекстЗапроса = "", "", "ОБЪЕДИНИТЬ ВСЕ ") + "

		|ВЫБРАТЬ """ + Последовательность.Метаданные().Имя 

		+  """ КАК Имя ИЗ " + Последовательность.Метаданные().ПолноеИмя()  

		+ " ГДЕ Регистратор =Регистратор";

		

	КонецЦикла;

	

	Если ТекстЗапроса = "" Тогда

		Возврат Новый ТаблицаЗначений();

	Иначе

		Запрос = Новый Запрос(ТекстЗапроса);

		Запрос.УстановитьПараметр("Регистратор", ДокументОбъект.Ссылка);

		ТаблицаЗапроса = Запрос.Выполнить().Выгрузить();	

		Возврат ТаблицаЗапроса;

	КонецЕсли;

	

КонецФункции   

Бывает необходимо разделить текстовый файл большого размера на несколько маленьких файлов. Ниже представлены функции при помощи которых можно разделить файл:

РазделитьФайл(<ИмяФайла>, <РазмерЧасти>, <Путь>)

Разделяет указанный файл на несколько частей (файлов) заданного размера. Имя каждой части образуется из имени исходного файла с прибавлением ему расширения в виде порядкового номера, включая лидирующие нули.

 РазделитьФайл("C:WindowsTempPresentation.ppt", 1024 * 1024 )   

В результате получим несколько файлов:

C:\Windows\Temp\Presentation.ppt.001

C:\Windows\Temp\Presentation.ppt.002

...

C:\Windows\Temp\Presentation.ppt.n-1

C:\Windows\Temp\Presentation.ppt.n

А для объединения файлов в один используйте:

ОбъединитьФайлы(<ШаблонПоиска>, <ИмяРезультирующегоФайла>)

При объединении файлов по маске необходимо задать маску поиска файлов и имя файла, который требуется создать.

Например, в каталоге "C:\MySplittedData\" содержатся файлы:

C:\MySplittedData\BigSplittedData.zip.001

C:\MySplittedData\BigSplittedData.zip.002

C:\MySplittedData\BigSplittedData.zip.003

C:\MySplittedData\BigSplittedData.zip.004

Выполнение кода вида:

 ОбъединитьФайлы("C:\MySplittedData\BigSplittedData.zip.*", "C:\MySplittedData\BigSplittedData.zip")    

приведет к объединению вышеперечисленных файлов в файл с заданным именем.

Внимание! Файлы объединяются в порядке возрастания имен. 

 МассивИмен = Новый Массив(3); МассивИмен.Добавить("C:\Windows\ \Presentation.ppt.1");МассивИмен.Добавить("C:\Windows\Temp\Presentation.ppt.2"); МассивИмен.Добавить("C:\Windows\Temp\Presentation.ppt.3"); ОбъединитьФайлы(МассивИмен,"C:\Windows\Temp\Presentation.ppt");