квалификаторычисла » Поиск

Результаты по ключевому слову: квалификаторычисла

Загрузить данные в 1с из текстового файла с разделителями Категория: Текстовый документ

Яндекс, Google, Рамблер Карты и 1С

Обработка демонстрирует возможности интеграции 1С с картографическими сервисами, в ней поддерживается работа трех поставщиков услуг / карт — Яндекс, Google. Рамблер.
Автор: Діма Головаченко - http://smaylukk.com.ua
но так вот сама обработка + еще 2 : Скачивать файлы может только зарегистрированный пользователь!

Код Модуля Обработки:

Код 1C v 8.х

 Перем СтруктураПоставщиковКарт Экспорт;

Перем СтруктураЧисел;



/////////////////////////РАБОТА С JSON //////////////////////////////////////////

Функция СформироватьСтрокуJSONИзМассива(Объект)

	

	СтрокаJSON = "[";

	

	Для каждого Элемент Из Объект Цикл

		СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент) + ",";

	КонецЦикла;

	

	Если Прав(СтрокаJSON, 1) = "," Тогда

		СтрокаJSON = Лев(СтрокаJSON, СтрДлина(СтрокаJSON)-1);

	КонецЕсли;

	

	Возврат СтрокаJSON + "]";

	

КонецФункции



Функция СформироватьСтрокуJSONИзСтруктуры(Объект)

	

	СтрокаJSON = "{";

	

	Для каждого Элемент Из Объект Цикл

		

		Если Элемент.Значение = "" Тогда

			Продолжить;

		КонецЕсли;

		

		СтрокаJSON = СтрокаJSON + """" + Элемент.Ключ + """" + ":";

		

		Если ТипЗнч(Элемент.Значение) = Тип("Строка") Тогда

			СтрокаJSON = СтрокаJSON + """" + URLEncode(Элемент.Значение) + """";

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Число") Тогда

			СтрокаJSON = СтрокаJSON + СтрЗаменить(Строка(Элемент.Значение), Символы.НПП, "");

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Булево") Тогда

			СтрокаJSON = СтрокаJSON + Формат(Элемент.Значение, "БЛ=false; БИ=true");

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Дата") Тогда

			// преобразование в unixtime

			СтрокаJSON = СтрокаJSON + Формат(ТекущаяДата() - Дата(1970,1,1,1,0,0), "ЧГ=0");

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Массив") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент.Значение);

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("Структура") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент.Значение);

			

		ИначеЕсли ТипЗнч(Элемент.Значение) = Тип("ТаблицаЗначений") Тогда

			СтрокаJSON = СтрокаJSON + СформироватьСтрокуJSON(Элемент.Значение);

			

		Иначе

			СтрокаJSON = СтрокаJSON + """" + URLEncode(Строка(Элемент.Значение)) + """";

			

		КонецЕсли;

		

		СтрокаJSON = СтрокаJSON + ",";

		

	КонецЦикла;

	

	Если Прав(СтрокаJSON, 1) = "," Тогда

		СтрокаJSON = Лев(СтрокаJSON, СтрДлина(СтрокаJSON)-1);

	КонецЕсли;

	

	Возврат СтрокаJSON + "}";

	

КонецФункции



Функция СформироватьСтрокуJSON(Объект) Экспорт

	

	СтрокаJSON = "";

	

	Если ТипЗнч(Объект) = Тип("Массив") Тогда

		СтрокаJSON = СформироватьСтрокуJSONИзМассива(Объект);

		

	ИначеЕсли ТипЗнч(Объект) = Тип("Структура") Тогда

		СтрокаJSON = СформироватьСтрокуJSONИзСтруктуры(Объект);

		

	ИначеЕсли ТипЗнч(Объект) = Тип("ТаблицаЗначений") Тогда

		// преобразуем таблицу значений в массив структур - работает дольше, но кода меньше

		// если нужна скорость, то нужно отдельно обработать таблицу значений

		

		СоставСтруктуры = "";

		Для каждого Колонка Из Объект.Колонки Цикл

			СоставСтруктуры = СоставСтруктуры + ?(ЗначениеЗаполнено(СоставСтруктуры), ",", "") + Колонка.Имя;

		КонецЦикла;

		

		МассивСтрок = Новый Массив;

		Для каждого Строка Из Объект Цикл

			СтруктураКолонок = Новый Структура(СоставСтруктуры);

			ЗаполнитьЗначенияСвойств(СтруктураКолонок, Строка);

			МассивСтрок.Добавить(СтруктураКолонок);

		КонецЦикла;

		

		СтрокаJSON = СформироватьСтрокуJSONИзМассива(МассивСтрок);

		

	КонецЕсли;

	

	Возврат СтрокаJSON;

	

КонецФункции



Процедура ЗаполнитьДанныеИзОтветаJSON(Результат, ТекстJSON, ТипДанных)

	

	ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));	// удалим открывающий символ структуры(массива)

	

	НомерЗначения = 0;

	

	Пока ТекстJSON <> "" Цикл

		

		ПервыйСимвол = Лев(ТекстJSON, 1);

		Если ПервыйСимвол = "{" Тогда

			// вложенная структура

			Значение = Новый Структура;

			ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Структура");

			

			Если ТипДанных = "Структура" Тогда

				Результат.Вставить("Значение" + ?(НомерЗначения = 0, "", НомерЗначения), Значение);

				НомерЗначения = НомерЗначения + 1;

			ИначеЕсли ТипДанных = "Массив" Тогда

				Результат.Добавить(Значение);

			КонецЕсли;

		

		ИначеЕсли ПервыйСимвол = "[" Тогда

			// вложенный массив

			Значение = Новый Массив;

			ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Массив");

			

			Если ТипДанных = "Структура" Тогда

				Результат.Вставить("Значение" + ?(НомерЗначения = 0, "", НомерЗначения), Значение);

				НомерЗначения = НомерЗначения + 1;

			Иначе

				Результат.Добавить(Значение);

			КонецЕсли;

			

		ИначеЕсли ПервыйСимвол = "}" И ТипДанных = "Структура" Тогда

			// структура закончилась

			ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			Если Лев(ТекстJSON, 1) = "," Тогда

				ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			КонецЕсли;

			

			Возврат;

			

		ИначеЕсли ПервыйСимвол = "]" И ТипДанных = "Массив" Тогда

			// массив закончился

			ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			Если Лев(ТекстJSON, 1) = "," Тогда

				ТекстJSON = СокрЛП(Сред(ТекстJSON, 2));

			КонецЕсли;

			

			Возврат;

			

		Иначе

			

			Если ТипДанных = "Структура" Тогда

				//ПервыйКавычка = Ложь;

				//Если Лев(ТекстJSON, 1) = """" Тогда

				//	ПервыйКавычка = Истина;

				//КонецЕсли;

				

				Поз = Найти(ТекстJSON, ":");

				Если Поз = 0 Тогда

					// неверный формат, прервемся

					Прервать;

				КонецЕсли;

				

				//ПредпоследнийКавычка = Ложь;

				//Если Сред(ТекстJSON, Поз - 1, 1) = """" Тогда

				//	ПредпоследнийКавычка = Истина;

				//КонецЕсли;



				

				ИмяЗначения = СокрЛП(Лев(ТекстJSON, Поз - 1));

				ИмяЗначения = СтрЗаменить(ИмяЗначения, """", "");

				

				ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз+1));

								

				Если Лев(ТекстJSON, 1) = "{" Тогда

					// значение является структурой

					Значение = Новый Структура;

					ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Структура");

					

				ИначеЕсли Лев(ТекстJSON, 1) = "[" Тогда

					// значение является массивом

					Значение = Новый Массив;

					ЗаполнитьДанныеИзОтветаJSON(Значение, ТекстJSON, "Массив");

					

				Иначе

					// обычное значение

					ПервыйКавычка = Ложь;

					ПредпоследнийКавычка = Ложь;

					Поз = 0;

					Для Сч = 1 По СтрДлина(ТекстJSON) Цикл

						Символ = Сред(ТекстJSON, Сч, 1);

						

						Если Символ = """" Тогда

							Если ПервыйКавычка Тогда

								ПредпоследнийКавычка = Истина;

							Иначе

								ПервыйКавычка = Истина;

							КонецЕсли;							

						КонецЕсли;

						

						Если (Символ = "," И ((ПервыйКавычка И ПредпоследнийКавычка) Или (Не ПервыйКавычка И Не ПредпоследнийКавычка))) ИЛИ Символ = "]" ИЛИ Символ = "}" Тогда

							Поз = Сч;

							Прервать;

						КонецЕсли;

					КонецЦикла;

					

					//ПредпоследнийКавычка = Ложь;

					//Если Сред(ТекстJSON, Поз - 1, 1) = """" Тогда

					//	ПредпоследнийКавычка = Истина;

					//КонецЕсли;

					

					Если Поз = 0 Тогда

						Значение = ТекстJSON;

						ТекстJSON = "";

						

					Иначе

						Значение = Лев(ТекстJSON, Поз - 1);

						Значение = СтрЗаменить(Значение, """", "");

						ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз + ?(Сред(ТекстJSON, Поз, 1) = ",", 1, 0)));						

					КонецЕсли;

					

					Значение = СокрЛП(Значение);

					

				КонецЕсли;

				

				Результат.Вставить(ИмяЗначения, Значение);

				

			ИначеЕсли ТипДанных = "Массив" Тогда

				

				// обычное значение

				Поз = 0;

				Для Сч = 1 По СтрДлина(ТекстJSON) Цикл

					Символ = Сред(ТекстJSON, Сч, 1);

					Если Символ = "," ИЛИ Символ = "]" ИЛИ Символ = "}" Тогда

						Поз = Сч;

						Прервать;

					КонецЕсли;

				КонецЦикла;

				

				//ПредпоследнийКавычка = Ложь;

				//Если Сред(ТекстJSON, Поз - 1, 1) = """" Тогда

				//	ПредпоследнийКавычка = Истина;

				//КонецЕсли;

				

				Если Поз = 0 Тогда

					Значение = ТекстJSON;

					ТекстJSON = "";

					

				Иначе

					Значение = Лев(ТекстJSON, Поз - 1);

					Значение = СтрЗаменить(Значение, """", "");

					ТекстJSON = СокрЛП(Сред(ТекстJSON, Поз + ?(Сред(ТекстJSON, Поз, 1) = ",", 1, 0)));

					

				КонецЕсли;

				

				Значение = СокрЛП(Значение);

				

				Результат.Добавить(Значение);

				

			КонецЕсли;

				

			

		КонецЕсли;

		

	КонецЦикла;

	

КонецПроцедуры



Функция ЗаполнитьСтруктуруИзОтветаJSON(Знач ТекстJSON) Экспорт

	

	Результат = Новый Структура;

	

	ТекстJSON = СтрЗаменить(ТекстJSON, "\""", """");	// заменим последовательность \" на "

	//ТекстJSON = СтрЗаменить(ТекстJSON, """", "");		// а теперь удалим все кавычки

	

	Если Лев(ТекстJSON, 1) = "{" Тогда

		// начало структуры

		ЗаполнитьДанныеИзОтветаJSON(Результат, ТекстJSON, "Структура");

		

	ИначеЕсли Лев(ТекстJSON, 1) = "[" Тогда

		// начало массива

		МассивДанных = Новый Массив;

		ЗаполнитьДанныеИзОтветаJSON(МассивДанных, ТекстJSON, "Массив");

		

		Результат.Вставить("Значение", МассивДанных);

		

	КонецЕсли;

		

	Возврат Результат;

	

КонецФункции



Функция КодСимволаASCII(Символ) 

   КодUNICODE = КодСимвола(Символ); 

   Если ((КодUNICODE > 1039) И (КодUNICODE < 1104)) Тогда 

       Возврат (КодUNICODE - 848); 

   ИначеЕсли КодUNICODE = 8470 Тогда 

       Возврат 185; 

   ИначеЕсли КодUNICODE = 1105 Тогда 

       Возврат 184; 

   ИначеЕсли КодUNICODE = 1025 Тогда 

       Возврат 168; 

   Иначе 

       Возврат КодUNICODE; 

   КонецЕсли; 

КонецФункции



Функция URLEncode(value)



    table = "%00%01%02%03%04%05%06%07%08%09%0A%0B%0C%0D%0E%0F%10%11%12%13%14" +

            "%15%16%17%18%19%1A%1B%1C%1D%1E%1F%20%21%22%23%24%25%26%27%28" +

            "%29%2A%2B%2C%2D%2E%2F%30%31%32%33%34%35%36%37%38%39%3A%3B%3C" +

            "%3D%3E%3F%40%41%42%43%44%45%46%47%48%49%4A%4B%4C%4D%4E%4F%50" +

            "%51%52%53%54%55%56%57%58%59%5A%5B%5C%5D%5E%5F%60%61%62%63%64" +

            "%65%66%67%68%69%6A%6B%6C%6D%6E%6F%70%71%72%73%74%75%76%77%78" +

            "%79%7A%7B%7C%7D%7E%7F%80%81%82%83%84%85%86%87%88%89%8A%8B%8C" +

            "%8D%8E%8F%90%91%92%93%94%95%96%97%98%99%9A%9B%9C%9D%9E%9F%A0" +

            "%A1%A2%A3%A4%A5%A6%A7%A8%A9%AA%AB%AC%AD%AE%AF%B0%B1%B2%B3%B4" +

            "%B5%B6%B7%B8%B9%BA%BB%BC%BD%BE%BF%C0%C1%C2%C3%C4%C5%C6%C7%C8" +

            "%C9%CA%CB%CC%CD%CE%CF%D0%D1%D2%D3%D4%D5%D6%D7%D8%D9%DA%DB%DC" +

            "%DD%DE%DF%E0%E1%E2%E3%E4%E5%E6%E7%E8%E9%EA%EB%EC%ED%EE%EF%F0" +

            "%F1%F2%F3%F4%F5%F6%F7%F8%F9%FA%FB%FC%FD%FE%FF";

    

    result = "";        

            

    length = СтрДлина( value );        

    

    Для i = 1 По  length Цикл        

        symbol = Сред( value, i, 1 );        

        //code = КодСимвола( symbol );    

        code = КодСимволаASCII( symbol );

        result = result + Сред( table, code*3 + 1, 3 );        

    КонецЦикла;

    

    

    

    Возврат result;

КонецФункции

/////////////////////////РАБОТА С JSON //////////////////////////////////////////



//Функция декодирует полученный unicod текст - из ответа геокодера Рамблера

// в привычный нам

//Параметры:

// Строка

//Возвращаемое значение:

// Строка

Функция UnicodeEncode(Строка) Экспорт 

	Результат = Истина;

	

	Попытка

		//регулярное выражение

		Рег = Новый COMОбъект("VBScript.RegExp");

		Рег.IgnoreCase = Истина;

		Рег.Global = Истина;

		Рег.Multiline = Ложь;

		Рег.Pattern = "u[0-9a-f]+";

		Колекция = Рег.Execute(Строка);

		Для Каждого Элемент Из Колекция Цикл

			Если СтрДЛина(Элемент.value) = 1 Тогда

				Продолжить;

			КонецЕсли;		

			

			КодСимвола = ПереводЧислаИз16в10(Сред(ВРег(Элемент.value), 2));

			Символ = Символ(КодСимвола);

			Строка = СтрЗаменить(Строка, "\" + Элемент.value, Символ); 

		КонецЦикла;	

	Исключение

		Результат = Ложь;

		Сообщить("Ошибка преобразования из Unicode", СтатусСообщения.Информация);

	КонецПопытки;

	

	Возврат Результат;

КонецФункции



Функция ПереводЧислаИз16в10(Знач Значение)

	Результат = 0;

	

	//перевод значения в строку

	Если ТипЗнч(Значение) <> Тип("Строка") Тогда

		Значение = СокрЛП(Строка(Значение));

	КонецЕсли;

	

	МаксРазрядЦелых = 0;

	МаксРазрядЦелых = СтрДлина(Значение) - 1;

	

	н = МаксРазрядЦелых;

	Ин = 1;

	Пока н >= 0 Цикл

		ТекЗначение = СтруктураЧисел.Получить(Сред(Значение, Ин, 1)) * Pow(16, н);

		Результат = Результат + ТекЗначение;

		н = н - 1;

		Ин = Ин + 1;

	КонецЦикла;

	

	Возврат Результат;

КонецФункции



///////////////////////////

СтруктураПоставщиковКарт = Новый Соответствие;

СтруктураПоставщиковКарт.Вставить(0, "Яндекс");

СтруктураПоставщиковКарт.Вставить(1, "Гугл");

СтруктураПоставщиковКарт.Вставить(2, "2ГИС");

СтруктураПоставщиковКарт.Вставить(3, "Рамблер");





СтруктураЧисел = Новый Соответствие;

СтруктураЧисел.Вставить("0", 0);

СтруктураЧисел.Вставить("1", 1);

СтруктураЧисел.Вставить("2", 2);

СтруктураЧисел.Вставить("3", 3);

СтруктураЧисел.Вставить("4", 4);

СтруктураЧисел.Вставить("5", 5);

СтруктураЧисел.Вставить("6", 6);

СтруктураЧисел.Вставить("7", 7);

СтруктураЧисел.Вставить("8", 8);

СтруктураЧисел.Вставить("9", 9);

СтруктураЧисел.Вставить("A", 10);

СтруктураЧисел.Вставить("B", 11);

СтруктураЧисел.Вставить("C", 12);

СтруктураЧисел.Вставить("D", 13);

СтруктураЧисел.Вставить("E", 14);

СтруктураЧисел.Вставить("F", 15);

Код Формы Управляемой:

Код 1C v 8.2 УП

 



&НаКлиенте

Процедура НайтиАдрес(Команда)

	НайтиАдресНаКарте(ТекАдрес);

КонецПроцедуры



&НаКлиенте

Процедура ИнициализацияКарты(Команда)

	ИнициализироватьКарту();

КонецПроцедуры



&НаКлиенте

Процедура СправочнаяИнформация(Команда)

	Элементы.ГруппаСправка.Видимость = Не Элементы.ГруппаСправка.Видимость;

КонецПроцедуры



&НаКлиенте

Процедура Разработчик(Команда)

	ЗапуститьПриложение("http://smaylukk.com.ua/?lang=Ru");

КонецПроцедуры



&НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

	Объект.ТипКарты = Параметры.ТипКарты;

	ТекОбъект = РеквизитФормыВЗначение("Объект");

	Поставщик = ТекОбъект.СтруктураПоставщиковКарт.Получить(Объект.ТипКарты);

	

	Макет = ТекОбъект.ПолучитьМакет("Справка");

	ТекстСправки = Макет.ПолучитьОбласть("Справка" + Поставщик).Область().Текст;

	Справка = ТекстСправки;

КонецПроцедуры



&НаКлиенте

Процедура ПриОткрытии(Отказ)

	Элементы.ГруппаСправка.Видимость = Ложь;

	Заголовок = "Работа с картами. Поставщик - " + Поставщик;

	ИнициализироватьКарту();

КонецПроцедуры



&НаКлиенте

Процедура ПриЗакрытии()

	//удаление временных файлов

	Для Каждого ТекЭлемент Из МассивВременныхФайлов Цикл

		УдалитьФайлы(ТекЭлемент.Значение);

	КонецЦикла;

КонецПроцедуры



&НаКлиенте

//Процедура составляет  имя процедуры поставщика

// и запускает ее на исполнение

//Параметры:

// НачалоИмени - Строка

Процедура ВыполнитьПроцедуруПоставщика(ИмяПроцедуры)

	Выполнить ИмяПроцедуры;

КонецПроцедуры



&НаКлиенте

//процедура инициализирует карту постащика из макета

Процедура ИнициализироватьКарту()

	Текст = ПолучитьТекстМакета("Макет" + Поставщик);

	

	Эксплорер = Текст;

КонецПроцедуры



&НаСервере

Функция ПолучитьТекстМакета(ИмяМакета)

	Макет = РеквизитФормыВЗначение("Объект").ПолучитьМакет(ИмяМакета);

	Результат = Макет.ПолучитьТекст();

	Возврат Результат;

КонецФункции



&НаКлиенте

Процедура ОчисткаКарты()

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "Reset()";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



///////////////////////////////////////////////////////////////////////

///////////////////ГЕОКОДИРОВАНИЕ И ПОИСК АДРЕСА///////////////////////

///////////////////////////////////////////////////////////////////////



&НаКлиенте

Процедура НайтиАдресНаКарте(Адрес = "")	

	//поиск адреса

	Если Адрес = "" Тогда

		Адрес = "Москва";		

	КонецЕсли;

	

	// дальше пробуем с помощью геокодинга вывести данные поиска в таблицу

	ТаблицаАдресов.Очистить();

	

	ПоискАдреса(Адрес);

	Если Поставщик = "Яндекс" Тогда

		ПроизвестиГеокодинг_Яндекс();

	ИначеЕсли Поставщик = "Гугл" Тогда

		ПроизвестиГеокодинг_Гугл();

	ИначеЕсли Поставщик = "Рамблер" Тогда

		ПроизвестиГеокодинг_Рамблер();

	КонецЕсли;

КонецПроцедуры



&НаКлиенте

Процедура ПоискАдреса(Адрес)

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "FindAdres(""" + Адрес + """);";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаСервере

//Процедура выводит в таблицу данные геокдинга Яндекса

//

//Параметры:

// ТекАдрес - Строка

Процедура ПроизвестиГеокодинг_Яндекс()

	Яндекс = Новый HTTPСоединение("geocode-maps.yandex.ru");

	

	ВременныйФайл = КаталогВременныхФайлов() + "Yandex_geocode_" + СокрЛП(Новый УникальныйИдентификатор);

	Попытка

		Яндекс.Получить("/1.x/?geocode=" + ТекАдрес + "&results=10", ВременныйФайл);

	Исключение

		Сообщить("Ошибка при попытке геокодировать по яндексу адрес: " + ТекАдрес);

		Сообщить(ОписаниеОшибки());

		Возврат;

	КонецПопытки;

	

	ЧтениеXML = Новый ЧтениеXML;

	ЧтениеXML.ОткрытьФайл(ВременныйФайл);

	

	ПостроительDOM 			= Новый ПостроительDOM;

	ДокументДОМ 			= ПостроительDOM.Прочитать(ЧтениеXML);

	

	СписокText 				= ДокументДОМ.ПолучитьЭлементыПоИмени("text");

	СписокPos 				= ДокументДОМ.ПолучитьЭлементыПоИмени("pos");

		

	Если (СписокText.Количество() = 0) ИЛИ (СписокPos.Количество() = 0) Тогда

		Возврат;	

	КонецЕсли;

	

	Для ъ = 0 по СписокText.Количество()-1 Цикл

		Координаты = СписокPos[Ъ].ТекстовоеСодержимое;

		Разделитель = Найти(Координаты," ");

		Широта = Число(Сред(Координаты, Разделитель + 1));

		Долгота = Число(Лев(Координаты, Разделитель - 1));

		

		Если Широта = 0 ИЛИ Долгота = 0 Тогда

			Продолжить;

		КонецЕсли;

		

		стрАдрес = ТаблицаАдресов.Добавить();

		Если СписокText.Количество() > ъ Тогда

			стрАдрес.Адрес = СписокText[Ъ].ТекстовоеСодержимое;

			стрАдрес.Широта = Широта;

			стрАдрес.Долгота = Долгота;

		КонецЕсли;		

	КонецЦикла;	

	МассивВременныхФайлов.Добавить(ВременныйФайл);

КонецПроцедуры



&НаСервере

//Процедура выводит в таблицу данные геокдинга Гугл

//

//Параметры:

// ТекАдрес - Строка

Процедура ПроизвестиГеокодинг_Гугл()

	Гугл = Новый HTTPСоединение("maps.googleapis.com");

	

	ВременныйФайл = КаталогВременныхФайлов() + "Google_geocode_" + СокрЛП(Новый УникальныйИдентификатор);

	Попытка

		Гугл.Получить("/maps/api/geocode/xml?address=" + ТекАдрес + "&language=ru&sensor=false", ВременныйФайл);

	Исключение

		Сообщить("Ошибка при попытке геокодировать по Google адрес: " + ТекАдрес);

		Сообщить(ОписаниеОшибки());

		Возврат;

	КонецПопытки;

	

	ЧтениеXML = Новый ЧтениеXML;

	ЧтениеXML.ОткрытьФайл(ВременныйФайл);

	

	ПостроительDOM 			= Новый ПостроительDOM;

	ДокументДОМ 			= ПостроительDOM.Прочитать(ЧтениеXML);

	ТаблицаРезультатов = ДокументДОМ.ПолучитьЭлементыПоИмени("result");

	

	Если ДокументДОМ.ПолучитьЭлементыПоИмени("status")[0].ТекстовоеСодержимое <> "OK" ИЛИ ТаблицаРезультатов.Количество() = 0 Тогда 

		Возврат;

	КонецЕсли;

		

	Для ТекРезультат = 0 по ТаблицаРезультатов.Количество() -1 Цикл 

		

		СписокText 				= ТаблицаРезультатов[ТекРезультат].ПолучитьЭлементыПоИмени("formatted_address");

		ЭлементыШиротаДолгота = ТаблицаРезультатов[ТекРезультат].ПолучитьЭлементыПоИмени("location");

		Широта = ЭлементыШиротаДолгота[0].ПолучитьЭлементыПоИмени("lat")[0].ТекстовоеСодержимое;

		Долгота = ЭлементыШиротаДолгота[0].ПолучитьЭлементыПоИмени("lng")[0].ТекстовоеСодержимое;

		Если Широта = 0 ИЛИ Долгота = 0 Тогда

			Продолжить;

		КонецЕсли;

			

		стрАдрес = ТаблицаАдресов.Добавить();

		стрАдрес.Широта = Широта;

		стрАдрес.Долгота = Долгота;

		стрАдрес.Адрес = СписокText[0].ТекстовоеСодержимое;  

	КонецЦикла;

	МассивВременныхФайлов.Добавить(ВременныйФайл);

КонецПроцедуры



&НаСервере

//Процедура выводит в таблицу данные геокдинга Рамблер

//

//Параметры:

// ТекАдрес - Строка

Процедура ПроизвестиГеокодинг_Рамблер()

	ТемпАдрес = СтрЗаменить(ТекАдрес, " ", "+");

	

	Рамблер = Новый HTTPСоединение("maps.rambler.ru");	

	ВременныйФайл = КаталогВременныхФайлов() + "Рамблер_geocode_" + СокрЛП(Новый УникальныйИдентификатор);

	Попытка

		Рамблер.Получить("/search/?&a=search&q=" + ТемпАдрес + "&n=10", ВременныйФайл);

	Исключение

		Сообщить("Ошибка при попытке геокодировать по Рамблер адрес: " + ТекАдрес);

		Сообщить(ОписаниеОшибки());

		Возврат;

	КонецПопытки;

	

	а = 1;

	Т = Новый ТекстовыйДокумент;

	Т.Прочитать(ВременныйФайл);

	СтрокаОтвет = Т.ПолучитьТекст();

	Результат = РеквизитФормыВЗначение("Объект").UnicodeEncode(СтрокаОтвет);

	Если Результат Тогда

		СтруктураJSON = РеквизитФормыВЗначение("Объект").ЗаполнитьСтруктуруИзОтветаJSON(СтрокаОтвет);

	КонецЕсли;

	

	МассивРезультатов = СтруктураJSON.res;

	//обрабатываем элементы массива - только адреса. POI можно обработать отдельно пожеланию

	Для Каждого Результат Из МассивРезультатов Цикл

		Для Каждого ТекРезультат Из Результат.matches Цикл				

			стрАдрес = ТаблицаАдресов.Добавить();

			стрАдрес.Долгота = Число(ТекРезультат.x);

			стрАдрес.Широта = Число(ТекРезультат.y);

			Если Результат.type = "addr" Тогда  //Результат.type = "poi" - содержит в себе список точек интереса

				стрАдрес.Адрес = ТекРезультат.addr;

			Иначе

				стрАдрес.Адрес = ТекРезультат.name + " - " + ТекРезультат.addr;

			КонецЕсли;

		КонецЦикла;

	КонецЦикла;

	МассивВременныхФайлов.Добавить(ВременныйФайл);

КонецПроцедуры



&НаКлиенте

Процедура ОбратнПоискАдреса(Широта, Долгота, Адрес)

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "ReverseSearchAdres(" + Широта + "," + Долгота + ", """ + Адрес + """);";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

Процедура ТаблицаАдресовВыбор(Элемент, ВыбраннаяСтрока, Поле, СтандартнаяОбработка)

	Если ЗначениеЗаполнено(ТаблицаАдресов[ВыбраннаяСтрока].Широта) И ЗначениеЗаполнено(ТаблицаАдресов[ВыбраннаяСтрока].Долгота) Тогда

		СтандартнаяОбработка = Ложь;

	КонецЕсли;

	

	Широта = Формат(ТаблицаАдресов[ВыбраннаяСтрока].Широта, "ЧЦ=10; ЧДЦ=7; ЧРД=.; ЧРГ=");

	Долгота = Формат(ТаблицаАдресов[ВыбраннаяСтрока].Долгота, "ЧЦ=10; ЧДЦ=7; ЧРД=.; ЧРГ=");

	

	ОбратнПоискАдреса(Широта, Долгота, ТаблицаАдресов[ВыбраннаяСтрока].Адрес);

КонецПроцедуры



&НаКлиенте

Процедура ТекАдресПриИзменении(Элемент)

	НайтиАдресНаКарте(ТекАдрес);

КонецПроцедуры





///////////////////////////////////////////////////////////////////////

///////////////////МАРШРУТИЗАЦИЯ, КЛАСТЕРА И ПОЛИГОН///////////////////////////////////////

///////////////////////////////////////////////////////////////////////



&НаКлиенте

Процедура ЭксплорерПриНажатии(Элемент, ДанныеСобытия, СтандартнаяОбработка)

	ПолучитьКоординаты();

КонецПроцедуры



&НаКлиенте

Процедура ПостроитьМаршрут(Команда)

	Если ТаблицаТочек.Количество() <= 1 Тогда

		Предупреждение("Недостаточно точек для построение маршрута!");

		Возврат;

	КонецЕсли;

	

	Если Поставщик = "Яндекс" Тогда

		ПостроитьМаршрут_Яндекс();

	ИначеЕсли Поставщик = "Гугл" Тогда

		ПостроитьМаршрут_Гугл();

	ИначеЕсли Поставщик = "Рамблер" Тогда

		ПостроитьМаршрут_Рамблер();

	КонецЕсли;

КонецПроцедуры



&НаКлиенте

//Процедура выстраивает маршрут для Яндекса

//

//Параметры:

//

Процедура ПостроитьМаршрут_Яндекс()

	ПараметрыМаршрута = ПолучитьПараметрыМаршрутаЯндекс();

	

	ОчисткаКарты();

	

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "calcRoute(" + ПараметрыМаршрута + ")";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

//Функция получает массив точек, для передачи параметров в Яндекс

//

//Параметры:

//

//Возвращаемое значение:

// Строка

Функция ПолучитьПараметрыМаршрутаЯндекс()

	Результат = "";

	

	Результат = Результат + "[[" + СтрЗаменить(Строка(ТаблицаТочек[0].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[0].Долгота), ",", ".") + "],";

		

	Для Ин = 1 По ТаблицаТочек.Количество() - 2 Цикл

		Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ин].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ин].Долгота), ",", ".") + "],";

	КонецЦикла;

		

	Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Долгота), ",", ".") + "]]";

		

	Возврат Результат;

КонецФункции



&НаКлиенте

//Процедура выстраивает маршрут для Гугл

//

//Параметры:

//

Процедура ПостроитьМаршрут_Гугл()

	ПараметрыМаршрута = ПолучитьПараметрыМаршрутаГугл();

	

	ОчисткаКарты();

	

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "calcRoute(" + ПараметрыМаршрута + ")";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

//Функция получает массив точек, для передачи параметров в Гугл

//

//Параметры:

//

//Возвращаемое значение:

// Строка

Функция ПолучитьПараметрыМаршрутаГугл()

	Результат = "";

	ВнутрМассив = "";

	

	Результат = Результат + "[[" + СтрЗаменить(Строка(ТаблицаТочек[0].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[0].Долгота), ",", ".") + "],";

	

	Если ТаблицаТочек.Количество() = 2 Тогда

		Результат = Результат + "[],"; 

	Иначе

		Для Ин = 1 По ТаблицаТочек.Количество() - 2 Цикл

			ВнутрМассив = ВнутрМассив + "[" + СтрЗаменить(Строка(ТаблицаТочек[ин].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ин].Долгота), ",", ".") + "],";

		КонецЦикла;

		Результат = Результат + "[" + Сред(ВнутрМассив, 1, СтрДлина(ВнутрМассив) - 1) + "],";

	КонецЕсли;

	

	Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Долгота), ",", ".") + "]]";

		

	Возврат Результат;

КонецФункции



&НаКлиенте

//Процедура выстраивает маршрут для Рамблера

//

//Параметры:

//

Процедура ПостроитьМаршрут_Рамблер()

	ПараметрыМаршрута = ПолучитьПараметрыМаршрутаРамблер();

	

	ОчисткаКарты();

	

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "calcRoute(" + ПараметрыМаршрута + ")";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

//Функция получает массив точек, для передачи параметров в Рамблер

//

//Параметры:

//

//Возвращаемое значение:

// Строка

Функция ПолучитьПараметрыМаршрутаРамблер()

	Результат = "";

	

	Результат = Результат + "[[" + СтрЗаменить(Строка(ТаблицаТочек[0].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[0].Долгота), ",", ".") + "],";

		

	Для Ин = 1 По ТаблицаТочек.Количество() - 2 Цикл

		Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ин].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ин].Долгота), ",", ".") + "],";

	КонецЦикла;

		

	Результат = Результат + "[" + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Широта), ",", ".") + "," + СтрЗаменить(Строка(ТаблицаТочек[ТаблицаТочек.Количество() - 1].Долгота), ",", ".") + "]]";

		

	Возврат Результат;

КонецФункции



&НаКлиенте

Процедура СоздатьКластер(Команда)

	Если ТаблицаТочек.Количество() <= 1 Тогда

		Предупреждение("Недостаточно точек для построение кластера!");

		Возврат;

	КонецЕсли;

	

	ОчисткаКарты();

	

	ПостроитьКластера();

КонецПроцедуры



&НаКлиенте

Процедура ПостроитьКластера()

	Кол = ТаблицаТочек.Количество();

	Индекс = 1;

	Для Каждого ТекСтрока Из ТаблицаТочек Цикл

		Широта = формат(ТекСтрока.Широта, "ЧРД=.");

		Долгота = формат(ТекСтрока.Долгота, "ЧРД=.");

		СодержимоеТочки = "Содерижмое точки";  //опять же можно вставить свое название

		Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "addToPointArray(" + Широта + "," + Долгота + ", '" + ТекСтрока.Точка + "', """ + СодержимоеТочки + """);";

		Элементы.Эксплорер.document.getElementById("WebClient").click();

		

		Состояние("Обработан " + Индекс + " из " + кол);

		Индекс = Индекс + 1;

	КонецЦикла;

	

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "drawCluster();";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаКлиенте

Процедура ОчиститьВсе(Команда)

	ОчисткаКарты();

	ТаблицаТочек.Очистить();

КонецПроцедуры



&НаКлиенте

Процедура ОчиститьКарту(Команда)

	ОчисткаКарты();

КонецПроцедуры



&НаКлиенте

Процедура ОчиститьТаблицу(Команда)

	ТаблицаТочек.Очистить();

КонецПроцедуры



&НаКлиенте

//Процедура получает координаты установленной точки

Процедура ПолучитьКоординаты()

	Попытка

		ЧислоТип = Новый ОписаниеТипов("Число", Новый КвалификаторыЧисла(15, 12));

		

		КоординатаX = Элементы.Эксплорер.document.getElementById("CoordX").value;

		КоординатаX = ЧислоТип.ПривестиЗначение(КоординатаX);

		

		КоординатаY = Элементы.Эксплорер.document.getElementById("CoordY").value;

		КоординатаY = ЧислоТип.ПривестиЗначение(КоординатаY);

		

		Кол = ТаблицаТочек.Количество();

		Если КоординатаX > 0 И КоординатаY > 0 И (Кол = 0 Или КоординатаX <> ТаблицаТочек[Кол - 1].Широта И КоординатаY <> ТаблицаТочек[Кол - 1].Долгота) Тогда

			НоваяСтрока = ТаблицаТочек.Добавить();

			НоваяСтрока.Точка = "Точка" + ТаблицаТочек.Количество();

			НоваяСтрока.Широта = КоординатаX;

			НоваяСтрока.Долгота = КоординатаY;

		КонецЕсли;

	Исключение

	КонецПопытки;

КонецПроцедуры



&НаКлиенте

Процедура ПострениеПолигона(Команда)

	Если ТаблицаТочек.Количество() <= 1 Тогда

		Предупреждение("Недостаточно точек для построение полигона!");

		Возврат;

	КонецЕсли;

	

	ОчисткаКарты();

	

	ПостроитьПолигон();

КонецПроцедуры



&НаКлиенте

//Процедура выстраивает маршрут для Рамблера

//

//Параметры:

//

Процедура ПостроитьПолигон()

	МассивТочек = "[";

	Для Каждого ТекТочка Из ТаблицаТочек Цикл

		Широта = формат(ТекТочка.Широта, "ЧРД=.");

		Долгота = формат(ТекТочка.Долгота, "ЧРД=.");

		МассивТочек = МассивТочек + "[" + Широта + "," + Долгота + "],"; 

	КонецЦикла;

	МассивТочек = Сред(МассивТочек, 1, СтрДлина(МассивТочек) - 1) + "]";

	

	Цвет16 = Получить16Цвет();

	

	Название = "Полигон";//вставить свое 

	Элементы.Эксплорер.document.getElementById("WebClientOperation").value = "createPolygon(" + МассивТочек + ", '" + Название + "', '" + Цвет16 + "');";

	Элементы.Эксплорер.document.getElementById("WebClient").click();

КонецПроцедуры



&НаСервере

//Функция возвращает значение случайного цвета в 16-ричном формате

//

//Параметры:

//  нет

//Возвращаемое значение:

//  Строка

Функция Получить16Цвет()

	Результат = "";

	

	Строка16 = "0123456789ABCDEF";

	ГСЧ = Новый ГенераторСлучайныхЧисел;

	Результат = "#";

	Для н = 1 По 6 Цикл

		м = ГСЧ.СлучайноеЧисло(1, 16);

		Результат = Результат + Сред(Строка16, м, 1);

	КонецЦикла;

	

	Возврат Результат;

КонецФункции

Категория: COM-объекты, WMI, WSH

Как результат СКД в виде Табличного Документа разобрать и вывести в Дерево Значений

Процедура получает из СКД результат в виде Табличного документа, парсит его, создает в Дереве на форме колонки и заполняет дерево данными результата СКД
Смысл в том, что СКД не может вывести результат в объект на форму, если он Таблица - выдает ошибку "Не поддерживается вывод таблиц, диаграмм и вложенных отчетов в универсальную коллекцию значений".

Поэтому я выгружаю СКД в ТабличныйДокумент и вытаскиваю данные уже из него, далее строю и заполняю Дерево на форме

Код 1C v 8.х

 Процедура ЗаполнитьДерево()



    ДеревоЗначений.Строки.Очистить();

    КолРазмеров = 0;



    СхемаКомпоновкиДанных = ПолучитьМакет("Схема");

    Настройки = СхемаКомпоновкиДанных.НастройкиПоУмолчанию;



    Для Каждого ЭлементОтбора Из ПостроительОтчета.Отбор Цикл



        Если Не ЭлементОтбора.Использование Тогда

            Продолжить;

        КонецЕсли;



        ВидСравненияВОтборе = мСоответствиеВидовСравнения.Получить(ЭлементОтбора.ВидСравнения);

        Если ВидСравненияВОтборе = Неопределено Тогда

            Продолжить;

        КонецЕсли;



        Если Лев(ЭлементОтбора.ПутьКДанным, 8) = "Свойство" Тогда

            ИмяПоля = "Номенклатура.["+мСоответствиеНазначений[ЭлементОтбора.Представление]+" (свойство)]";

        ИначеЕсли Лев(ЭлементОтбора.ПутьКДанным, 9) = "Категория" Тогда

            ИмяПоля = "Номенклатура.["+мСоответствиеНазначений[ЭлементОтбора.Представление]+" (категория)]";

        Иначе

            ИмяПоля = ЭлементОтбора.ПутьКДанным;

        КонецЕсли;



        ПолеОтбора = Новый ПолеКомпоновкиДанных(ИмяПоля);



        Отбор = Настройки.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));

        Отбор.ЛевоеЗначение  = ПолеОтбора;

        Отбор.Использование  = Истина;

        Отбор.ВидСравнения   = ВидСравненияВОтборе;

        Отбор.ПравоеЗначение = ЭлементОтбора.Значение;



    КонецЦикла;



    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;

    ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;



    МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки, ДанныеРасшифровки,, Тип("ГенераторМакетаКомпоновкиДанных"));



    ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;

    ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки,, ДанныеРасшифровки);



    ТабличныйДокумент = Новый ТабличныйДокумент;



    ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;

    ПроцессорВывода.УстановитьДокумент(ТабличныйДокумент);



    ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных, Истина);



    //ТабличныйДокумент.Показать();



    КолДанных = 5;  //кол. данных в колонке таблицы СКД



    СоздатьДерево(ТабличныйДокумент, КолДанных);



    СтКол = Новый Структура;

    СтКол.Вставить("Ном",   1);

    СтКол.Вставить("Дат1",  2);

    СтКол.Вставить("Дат2",  3);



    СтКол.Вставить("Прих",  4);

    СтКол.Вставить("Реал",  5);

    СтКол.Вставить("Возв",  6);

    СтКол.Вставить("Остат", 7);

    СтКол.Вставить("ВПути", 8);



    СтрНом = Неопределено;

    СтрДерева = Неопределено;



    Для i=3 По ТабличныйДокумент.ВысотаТаблицы Цикл



        ПерваяКолонка = ПолучитьЗначениеРасшифровки(ТабличныйДокумент, i, СтКол.Ном);



        Если ТипЗнч(ПерваяКолонка) = Тип("СправочникСсылка.Номенклатура") Тогда



            Если СтрНом  Неопределено Тогда

                СтрНом.Строки.Сортировать("Продажи УБЫВ");

                СтрНом.ОстатокМагазин = СтрНом.Строки.Итог("ОстатокМагазин");

                СтрНом.ОстатокСклад = СтрНом.Строки.Итог("ОстатокСклад");

            КонецЕсли;



            СтрНом = ДеревоЗначений.Строки.Добавить();

            СтрДерева = СтрНом;



        ИначеЕсли ТипЗнч(ПерваяКолонка) = Тип("СправочникСсылка.Склады") Тогда



            СтрДерева = СтрНом.Строки.Добавить();



            Дат1 = Формат(ПолучитьЗначениеРасшифровки(ТабличныйДокумент, i, СтКол.Дат1), "ДФ=dd.MM.yy");

            Дат2 = Формат(ПолучитьЗначениеРасшифровки(ТабличныйДокумент, i, СтКол.Дат2), "ДФ=dd.MM.yy");

            СтрДерева.Период = "" + Дат1 + " - " + Дат2;



        Иначе



            Продолжить;



        КонецЕсли;



        СтрДерева.Номенклатура = ПерваяКолонка;

        СтрДерева.Остаток = ПолучитьЗначениеРасшифровки(ТабличныйДокумент, i, СтКол.Остат, Истина);

        СтрДерева.Приход = ПолучитьЗначениеРасшифровки(ТабличныйДокумент, i, СтКол.Прих, Истина);

        СтрДерева.Продажи = ПолучитьЗначениеРасшифровки(ТабличныйДокумент, i, СтКол.Реал, Истина);

        СтрДерева.Возврат = ПолучитьЗначениеРасшифровки(ТабличныйДокумент, i, СтКол.Возв, Истина);



        Если ЗначениеЗаполнено(СтрДерева.Родитель) Тогда

            Если ПерваяКолонка.ТипСклада = Перечисления.ТипыСкладов.ТорговыйЗал Тогда СтрДерева.ОстатокМагазин = СтрДерева.Остаток;

            Иначе                                                                     СтрДерева.ОстатокСклад = СтрДерева.Остаток;

            КонецЕсли;



            Попытка     СтрДерева.ПроцентПродаж = СтрДерева.Продажи * 100 / СтрДерева.Родитель.Продажи;

            Исключение  СтрДерева.ПроцентПродаж = "-";

            КонецПопытки;

        Иначе

            СтрДерева.ПроцентПродаж = "100%";

        КонецЕсли;



        Для j=1 По КолРазмеров Цикл



            СтрДерева["Ост" + j] = ПолучитьЗначениеРасшифровки(ТабличныйДокумент, i, 3 + КолДанных * j + 4, Истина);

            СтрДерева["Пут" + j] = ПолучитьЗначениеРасшифровки(ТабличныйДокумент, i, 3 + КолДанных * j + 5, Истина);



        КонецЦикла;



    КонецЦикла;



КонецПроцедуры



Процедура СоздатьДерево(ТабличныйДокумент, КолДанных)



    КЧ = Новый КвалификаторыЧисла(10, 0);

    Массив = Новый Массив;

    Массив.Добавить(Тип("Число"));

    ОписаниеТиповЧ = Новый ОписаниеТипов(Массив,,,КЧ);



    Ном = 3 + КолДанных + 1;   //колонки в таблич. документе (Ном/Склад, перв. дата, посл. дата)



    КолРазмеров = (ТабличныйДокумент.ШиринаТаблицы - Ном-1) / КолДанных + 1;

    Для i=1 По КолРазмеров Цикл



        Размер = ПолучитьЗначениеРасшифровки(ТабличныйДокумент, 1, Ном, Истина, Ложь);

        Ном = Ном + КолДанных;



        Попытка

            ДеревоЗначений.Колонки.Добавить("Ост" + i, ОписаниеТиповЧ, Размер, 5);

            ДеревоЗначений.Колонки.Добавить("Пут" + i, ОписаниеТиповЧ, "Путь", 5);

            ДеревоЗначений.Колонки.Добавить("Пер" + i, ОписаниеТиповЧ, "Пер", 5);

        Исключение

        КонецПопытки;



    КонецЦикла;

    ЭтаФорма.ЭлементыФормы.ДеревоЗначений.Значение = ДеревоЗначений;

    ЭтаФорма.ЭлементыФормы.ДеревоЗначений.СоздатьКолонки();





    i=1; НомерРазмера=1;

    Для Каждого Кол Из ЭтаФорма.ЭлементыФормы.ДеревоЗначений.Колонки Цикл



        Кол.ТолькоПросмотр = Истина;

        Если      i = (НомерРазмера + 8 + 1) Тогда

            Кол.Положение = ПоложениеКолонки.НоваяКолонка;

        ИначеЕсли i = (НомерРазмера + 8 + 2) Тогда

            Кол.Положение = ПоложениеКолонки.НаСледующейСтроке;

        ИначеЕсли i = (НомерРазмера + 8 + 3) Тогда

            Кол.Положение = ПоложениеКолонки.ВТойЖеКолонке;

            Кол.ТолькоПросмотр = Ложь;

            НомерРазмера = НомерРазмера + 3;

        КонецЕсли;



        Если i=1 Тогда

            Кол.Ширина = 20;

        Иначе

            Если i=2 Тогда          Кол.Ширина = 11;

            ИначеЕсли i9 Тогда    Кол.Ширина = 7;

            Иначе                   Кол.Ширина = 5;

            КонецЕсли;

            Кол.ИзменениеРазмера = ИзменениеРазмераКолонки.НеИзменять;

        КонецЕсли;



        i=i+1;



    КонецЦикла;



КонецПроцедуры

Автор: Абазин Антон

Категория: Схема Компоновки Данных

Внешние источники данных Категория: Встроенные Функции

Форма ~ Программное создание таблицы значений с условным оформлением

Как создать на форме таблицу и сделать для неё подсветку содержимого колонки в строке по условию?

Итак для начала нам надо добавить реквизиты в форму. Для этого у нас есть метод: ИзменитьРеквизиты(). Перед тем как его использовать мы сформируем массив добавляемых реквизитов, который будет называться МассивДобавляемыхРеквизитов.

Код 1C v 8.2 УП

 МассивДобавляемыхРеквизитов = Новый Массив; 

МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("План", Новый ОписаниеТипов("ТаблицаЗначений")));

Обратите внимание, что элементы массива у нас типа РеквизитФормы. Дальше помимо таблицы значений, нам надо добавить колонки таблицы, например будем добавлять три колонки:

Код 1C v 8.2 УП

 МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("Номенклатура", Новый ОписаниеТипов("СправочникСсылка.Номенклатура"),"План" ,"Номенклатура")); 

МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("Регион", Новый ОписаниеТипов("Число",Новый КвалификаторыЧисла(10,2)),"План" , "Регион")); 

МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("Разница", Новый ОписаниеТипов("Число",Новый КвалификаторыЧисла(10,2)),"План" , "Осталось распределить"));

Во время добавления колонок в МассивДобавляемыхРеквизитов обязательно надо указать путь к создаваемому реквизиту, в нашем случае это «План», который был добавлен в массив ранее. Обратите внимание, что путь к создаваемому реквизиту не включает в себя сам реквизит. После того, как массив сформирован, можно вызывать изменение реквизитов:

Код 1C v 8.2 УП

 ИзменитьРеквизиты(МассивДобавляемыхРеквизитов);

После изменения реквизитов у нас уже есть нужный нам реквизит формы «План» типа ТаблицаЗначений с тремя колонками. Если вам надо будет обратиться к значению реквизита, то вы можете это сделать используя ЭтаФорма["План"]. Можно приступать к созданию элементов формы, для отображения данных. Сначала создадим элемент формы типа ТаблицаФормы.

Код 1C v 8.2 УП

 ТаблицаФормы = Элементы.Добавить("План", Тип("ТаблицаФормы"));

ТаблицаФормы.ПутьКДанным = "План"; 

ТаблицаФормы.ПоложениеКоманднойПанели = ПоложениеКоманднойПанелиЭлементаФормы.Нет; 

ТаблицаФормы.ФиксацияСлева = 3; 

ТаблицаФормы.УстановитьДействие("ПередУдалением", "ПланПередУдалением"); 

ТаблицаФормы.УстановитьДействие("ПередНачаломДобавления", "ПланПередНачаломДобавления");

Как вы видите из приведенного когда, во время создания элемента мы тут же определяем действия на события. После создания элемента План типа ТаблицаФормы создадим подчиненные ему элементы типа ПолеФормы, которые будут отвечать у нас за вывод данных в колонки таблицы. Для этого в цикле перебора колонок таблицы необходимо выполнить следующий код (на примере одной из итераций цикла):

Код 1C v 8.2 УП

 НоваяКолонка = Элементы.Добавить("ПланНоменклатура", Тип("ПолеФормы"), Элементы.План); 

НоваяКолонка.Заголовок = "Номенклатура"; 

НоваяКолонка.ПутьКДанным = "План.Номенклатура";

НоваяКолонка.Вид = ВидПоляФормы.ПолеВвода; 

НоваяКолонка.РежимРедактирования = РежимРедактированияКолонки.ВходПриВводе;

Обратите внимание, что во время добавления элемента мы указываем родителя Элементы.План. Так же путь к данным у нас состоит из наименования реквизита типа ТаблицаЗначений и имени колонки, разделенные точкой. После того, как вы в цикле создадите все элементы для колонок форма будет готова к выводу и вводу данных в таблицу.

Теперь можно перейти ко второй части задачи про подсветку цветом колонки Номенклатура. Например условие у нас будет накладываться на колонку Разница и когда она будет равно 100 строку надо будет подсвечивать колонку Номенклатуры серым цветом.

Для реализации этой части задачи мы будем использовать объект УсловноеОформление, который доступен на стороне сервера. Сначала в элементы условного оформления необходимо добавить новый элемент. Затем мы добавляем оформляемые поля. Если надо подсвечивать всю строку, то можно обойти в цикле колонки и добавить все их поля ввода в оформляемые. Так же необходимо потом добавить отбор. В левом значении отбора указываем поле, по которому будет идти сравнение. Поле указывает с точкой, как путь к данным во время добавления колонки.

Код 1C v 8.2 УП

 ЭлементУсловногоОформления = УсловноеОформление.Элементы.Добавить();

ОформляемоеПоле = ЭлементУсловногоОформления.Поля.Элементы.Добавить();

ОформляемоеПоле.Поле = Новый ПолеКомпоновкиДанных("ПланНоменклатура");

ЭлементОтбора = ЭлементУсловногоОформления.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));

ЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("План.Разница");

ЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;

ЭлементОтбора.ПравоеЗначение = 100; 

ЭлементУсловногоОформления.Оформление.УстановитьЗначениеПараметра("ЦветФона", WebЦвета.СеребристоСерый);

Внешняя обработка, демонстрирующая создание таблицы значений программно - Скачивать файлы может только зарегистрированный пользователь!

Андрей Данилюк

Категория: Работа с Формой (Диалог) и её элементами

Экспорт и Импорт данных 1С - Microsoft Excel

Экспорт
Процедура ОсновныеДействияФормыЭкспорт(Кнопка) - выгружает из указанного справочника данные в режиме экспорта в файл в формате Microsoft Excel с указанным именем, используя преобразование данных к типу число и типу строка;

Код 1C v 8.х

 Процедура ОсновныеДействияФормыЭкспорт(Кнопка)

  Попытка

    Попытка



      // Загрузка объекта Microsoft Excel

      Состояние("Выгрузка данных из 1С в Microsoft Excel...");

      ExcelПриложение = Новый COMОбъект("Excel.Application");

    Исключение

      Сообщить("Ошибка при запуске Microsoft Excel."

        + Символы.ПС + ОписаниеОшибки(), СтатусСообщения.Внимание);

      Возврат;

    КонецПопытки;



    // Создадим книгу, по умолчанию в ней уже есть листы

    Книга = ExcelПриложение.WorkBooks.Add();



    // Используем первый лист книги Excel

    Лист = Книга.WorkSheets(1);



    // Сформировать шапку документа в первой строке листа

    Колонка = 1;

    Для каждого стр из ТП цикл

      Если стр.Выгружать Тогда

        Лист.Cells(1, Колонка).Value = стр.НазваниеРеквизита;

        Колонка = Колонка + 1;

      КонецЕсли;

    КонецЦикла;



    // Выгрузить данные справочника

    выборка = Справочники[ИмяСправочника].Выбрать();

    СтрокаЛиста = 2;

    Пока выборка.Следующий() Цикл

      Колонка = 1;

      Для каждого стр из ТП цикл



      Если стр.Выгружать Тогда

      Попытка

        // Установить значение в строке и колонке

        Если ТипЗнч(выборка[стр.НазваниеРеквизита])=Тип("Число") Тогда

        // Установить формат для типа Число

        Лист.Cells(СтрокаЛиста, Колонка).NumberFormat = "0,00";

        Лист.Cells(СтрокаЛиста, Колонка).Value =

          Формат(выборка[стр.НазваниеРеквизита],"ЧГ=0");

        иначе

          // Для всех других типов установим формат "Текстовый"

          Лист.Cells(СтрокаЛиста, Колонка).NumberFormat = "@";

          Лист.Cells(СтрокаЛиста, Колонка).Value =

            Строка(выборка[стр.НазваниеРеквизита]);

        КонецЕсли;

      исключение

        // в случае ошибки вывести номер строки и колонки

        Сообщить("Ошибка установки значения для: " +

          выборка[стр.НазваниеРеквизита]);

        Сообщить("Стр: " +СтрокаЛиста+ " Кол: " +

          Колонка+ " Рек: " + стр.НазваниеРеквизита);

      КонецПопытки;

      Колонка = Колонка + 1;

      КонецЕсли;



    КонецЦикла;

    СтрокаЛиста = СтрокаЛиста + 1;

    Состояние("Экспорт из 1С в Excel " + СтрокаЛиста);

    КонецЦикла;



    // Сохраним созданную книгу в файл xls

    Книга.SaveAs(имяФайла);



    // Обязательно закроем соединение с COM объектом для освобождения памяти

    ExcelПриложение.Quit();



    Сообщить("Файл выгружен успешно: " + имяФайла );



  Исключение

    // Обработка ошибок экспорта данных из 1С в Excel

    Сообщить("Ошибка записи данных файла :" + имяФайла);

    Сообщить(ОписаниеОшибки());

    Попытка

      ExcelПриложение.Quit();

    Исключение

    КонецПопытки;

  КонецПопытки;

КонецПроцедуры

Импорт
Исходный код процедуры 1С для загрузки XLS файла:

Код 1C v 8.х

 Процедура ЧтениеXLSФайла(Элемент)



  Если ПустаяСтрока(ИмяФайла) Тогда

    Предупреждение("Для запуска обработки необходимо предварительно выбрать файл Microsoft Excel.");

    Возврат;

  КонецЕсли;



  Попытка

    // Загрузка Microsoft Excel

    Состояние("Загрузка Microsoft Excel...");

    ExcelПриложение = Новый COMОбъект("Excel.Application");

  Исключение

    Сообщить("Ошибка при загрузке Microsoft Excel." + Символы.ПС + ОписаниеОшибки(), СтатусСообщения.Внимание);

    Возврат;

  КонецПопытки;



  Попытка

    // Открытие файла Microsoft Excel

    Состояние("Открытие файла Microsoft Excel...");

    ExcelФайл = ExcelПриложение.WorkBooks.Open(ИмяФайла);

  Исключение

    Сообщить("Ошибка открытия файла Microsoft Excel." + ИмяФайла + Символы.ПС + ОписаниеОшибки(), СтатусСообщения.Внимание);

  КонецПопытки;



  Попытка

    // Обработка файла Microsoft Excel

    Состояние("Обработка файла Microsoft Excel...");

    // Читаем данные первого листа книги

    ExcelЛист = ExcelФайл.Sheets(1);



    // Определить количество строк и колонок выбранного листа книги Excel

    xlCellTypeLastCell = 11;

    ExcelПоследняяСтрока = ExcelЛист.Cells.SpecialCells(xlCellTypeLastCell).Row;

    ExcelПоследняяКолонка = ExcelЛист.Cells.SpecialCells(xlCellTypeLastCell).Column;

  Исключение

    Сообщить("Ошибка открытия листа №1 Microsoft Excel." + Символы.ПС + ОписаниеОшибки(), СтатусСообщения.Внимание);

    // Закрыть COM соединение для экономии памяти

    ExcelПриложение.Quit();

  КонецПопытки;



  // Создание описателя типов для таблицы значений

  КЧ = Новый КвалификаторыЧисла(15,2);

  КС = Новый КвалификаторыСтроки(50);

  Массив = Новый Массив;

  Массив.Добавить(Тип("Строка"));

  ОписаниеТиповС = Новый ОписаниеТипов(Массив, , КС);

  Массив.Очистить();

  Массив.Добавить(Тип("Число"));

  ОписаниеТиповЧ = Новый ОписаниеТипов(Массив, , ,КЧ);



  // Очистить предыдущие значения

  ТаблицаДокумента.Очистить();

  ТаблицаДокумента.Колонки.Очистить();



  // Создать колонки табличного документа

  ТаблицаДокумента.Колонки.Добавить("Номер",ОписаниеТиповС,"Номер",5);

  ТаблицаДокумента.Колонки.Добавить("Артикул",ОписаниеТиповС,"Артикул",11);

  ТаблицаДокумента.Колонки.Добавить("Описание",ОписаниеТиповС,"Описание",25);

  ТаблицаДокумента.Колонки.Добавить("Цена",ОписаниеТиповЧ,"Цена",6);



  // Последовательное чтение строк с выбранного листа

  Для Строка = 1 По ExcelПоследняяСтрока Цикл



    // Обработка нажатия Ctrl + Break

    ОбработкаПрерыванияПользователя();



    // Добавить данные в табличную часть экранной формы

    Стр=ТаблицаДокумента.Добавить();

    Стр.Номер = Строка;

    Попытка

      Стр.Артикул = ExcelЛист.Cells(Строка, 1).Value;

      Стр.Описание = ExcelЛист.Cells(Строка, 2).Value;

      Стр.Цена = ExcelЛист.Cells(Строка, 3).Value;

    Исключение

      // Не редко происходит ошибка конвертации отдельной ячейки документа

      Сообщить("Ошибка чтения строки файла Microsoft Excel." + Строка + Символы.ПС + ОписаниеОшибки(), СтатусСообщения.Внимание);

    КонецПопытки;

    // Отобразить информацию о ходе выполнения обработки

    Состояние("Обработка файла Microsoft Excel : "

      + "строка " + Строка + " из " + ExcelПоследняяСтрока);



  КонецЦикла;



  // Закрыть COM соединение для экономии памяти

  ExcelПриложение.Quit();



  // Отобразить результаты загрузки в форме элемента

  ЭлементыФормы.ТаблицаДокумента.Значение = ТаблицаДокумента;

  ЭлементыФормы.ТаблицаДокумента.СоздатьКолонки();



КонецПроцедуры // ЧтениеXLSФайла(Элемент)

Категория: Работа с Microsoft Office и OpenOffice

1C и Google Maps Категория: COM-объекты, WMI, WSH

Запрос к Таблице Значений

Код 1C v 8.х

 Таблица = Новый ТаблицаЗначений;

//Опишем тип создаваемой колонки

Массив = Новый Массив;

КЧ = Новый КвалификаторыЧисла(10, 2);

Массив.Добавить(Тип("Число"));

ОписаниеТиповЧ = Новый ОписаниеТипов(Массив, , ,КЧ);

Таблица.Колонки.Добавить("КодУслуги",ОписаниеТиповЧ);



//... выборки из справочника и заполнение ТЗ

Пока ВыборкаСпр.Следующий() Цикл

       НоваяСтрока = Таблица.Добавить();   

       НоваяСтрока.КодУслуги = ВыборкаСпр.Код;   

КонецЦикла;

  

Запрос = Новый Запрос;

МенеджерВТ = Новый МенеджерВременныхТаблиц;

Запрос.МенеджерВременныхТаблиц = МенеджерВТ;

// Текст запроса для построения временной таблицы

Запрос.Текст = "ВЫБРАТЬ

                  |    Таб.КодУслуги КАК Код

                  |ПОМЕСТИТЬ ВТДанные

                  |ИЗ

                  |    &Данные КАК Таб";

Запрос.УстановитьПараметр("Данные",Таблица);

Результат = Запрос.Выполнить();

Пример Заполнения колонки одной таблицы по колонке другой, по типу ЛЕВОЕ СОЕДИНЕНИЕ
Это удобно когда например надо заполнить колонку не одним фиксированным значением, а в зависимости от значений в других колонках

Код 1C v 8.х

 

   ТЗН1 = Новый ТаблицаЗначений;//Колонки Кол1,кол2,кол3,ИД

   ТЗН2 = Новый ТаблицаЗначений;//Колонки Кол4,кол5,кол6,ИД

 

    Запрос.УстановитьПараметр("ТЗН1",Отправления);

    Запрос.УстановитьПараметр("ТЗН2",ЛотыКСписанию);

    МВТ = Новый МенеджерВременныхТаблиц;

    Запрос.МенеджерВременныхТаблиц = МВТ;

    //Запрос 1 Помещаем ТЗН1 в МенеджерВременныхТаблиц в таблицу ТЗН1

 

    Запрос.Текст = 

    "ВЫБРАТЬ

    |    ТЗН1.Кол1 КАК Кол1,

    |    ТЗН1.Кол2 КАК Кол2,

    |    ТЗН1.Кол3 КАК Кол3,

    |    ТЗН1.ИД   КАК ИД

    |ПОМЕСТИТЬ

    |    ТЗН1

    |ИЗ

    |    &ТЗН1 КАК ТЗН1";

    Запрос.Выполнить();

    //Запрос 2 Помещаем ТЗН2 в МенеджерВременныхТаблиц в таблицу ТЗН2

 

    Запрос.Текст =

    "ВЫБРАТЬ

    |    ТЗН2.Кол1 КАК Кол4,

    |    ТЗН2.Кол2 КАК Кол5,

    |    ТЗН2.Кол3 КАК Кол6,

    |    ТЗН2.ИД   КАК ИД

    |ПОМЕСТИТЬ

    |    ТЗН2

    |ИЗ

    |    &ТЗН2 КАК ТЗН2";

    //Получаем результирующую таблицу

 

    Запрос.Выполнить();

    Запрос.Текст = 

        "ВЫБРАТЬ

    |    ТЗН1.Кол1 КАК Кол1,

    |    ТЗН1.Кол2 КАК Кол2,

    |    ТЗН1.Кол3 КАК Кол3,

    |    ТЗН1.ИД   КАК ИД,

    |    ТЗН2.Кол1 КАК Кол4,

    |    ТЗН2.Кол2 КАК Кол5,

    |    ТЗН2.Кол3 КАК Кол6,

    |ИЗ

    |    ТЗН1 КАК ТЗН1

    |   ВНУТРЕННЕЕ СОЕДИНЕНИЕ ТЗН2 КАК ТЗН2

    |   ПО ТЗН1.ИД = ТЗН2.ИД";

    тзн3 = Запрос.Выполнить().Выгрузить();

Запрос к таблице делается в 2 этапа:
Сначала она запросом помещается в МенеджерВременныхТаблиц, а затем вторым запросом к ней делается запрос!

В 8.0 к ТЗ можно работать только построителем запроса!
Примерно так:

Код 1C v 8.х

 ПостроительЗапроса = Новый ПостроительЗапроса;

    ПостроительЗапроса.ИсточникДанных = Новый ОписаниеИсточникаДанных(ТЗ);

    

    СтрокаОтбора = ПостроительЗапроса.Отбор.Добавить("Реквизит");

    СтрокаОтбора.Значение = Истина;

    СтрокаОтбора.ВидСравнения = ВидСравнения.Равно;

    СтрокаОтбора.Использование = Истина;

        

    ПостроительЗапроса.Выполнить();

    ВыбрСтроки = ПостроительЗапроса.Результат.Выгрузить();

Как в запросе, в качестве источника данных, использовать таблицу значений?

Категория: Запросы

Ввести значение, ввод значения Категория: Встроенные Функции