контрольный » Поиск

Результаты по ключевому слову: контрольный

Печать штрихкода в управляемом приложении

Программируя под 8.2, работающем в режиме управляемого приложения, я столкнулся с проблемой печати штрихкода. Для платформы 8.1 и платформы 8.2 в режиме обычного приложения такой проблемы не было: устанавливаем элемент «1С:Печать штрихкодов» в макет и наслаждаемся вертикальными черточками. В режиме управляемого приложения вываливается ошибка:

Код 1C v 8.2 УП

 ОбластьВывода.Рисунки.ШтрихКод.Объект – неопределено

Что же случилось?
Дело в том, что для управляемого приложения внешние компоненты разрабатываются по другой технологии. Пример внешней компоненты для печати штрих-кода в 8.2 есть в демонстрационной конфигурации "Управляемое приложение" в макетах справочника Товары либо в конфигурации «1С:Управление торговлей» версии 11, макеты обработки «Печать этикеток и ценников».
Данная компонента, получив в качестве параметра строку штрихкода, возвращает картинку – штрихкод, которую программисту предлагается поместить в любое удобное место печатной формы.

Теперь как это сделать.
Всего обработок аж четыре штуки:
КомпонентаПечатиШтрихкодовWindows32
КомпонентаПечатиШтрихкодовWindows64
КомпонентаПечатиШтрихкодовLinux32
КомпонентаПечатиШтрихкодовLinux64

Все они загружены в одноименные макеты. Функция, подключающая внешнюю компоненту в зависимости от платформы может выглядеть так:

Код 1C v 8.х

 Функция ПодключитьВнешнююКомпонентуПечатиШтрихкода() Экспорт

	

	// В зависимости от типа платформы подключим соответствующую внешнюю компоненту

	СистемнаяИнформация = Новый СистемнаяИнформация;



	Если СистемнаяИнформация.ТипПлатформы = ТипПлатформы.Windows_x86 Тогда

		ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("Обработка.ПечатьЭтикетокИЦенников.Макет.КомпонентаПечатиШтрихкодовWindows32", "КартинкаШтрихкода", ТипВнешнейКомпоненты.Native);

	

	ИначеЕсли СистемнаяИнформация.ТипПлатформы = ТипПлатформы.Windows_x86_64 Тогда

		ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("Обработка.ПечатьЭтикетокИЦенников.Макет.КомпонентаПечатиШтрихкодовWindows64", "КартинкаШтрихкода", ТипВнешнейКомпоненты.Native);

	

	ИначеЕсли СистемнаяИнформация.ТипПлатформы = ТипПлатформы.Linux_x86 Тогда

		ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("Обработка.ПечатьЭтикетокИЦенников.Макет.КомпонентаПечатиШтрихкодовLinux32", "КартинкаШтрихкода", ТипВнешнейКомпоненты.Native);

	

	Иначе

		ПодключениеВыполнено = ПодключитьВнешнююКомпоненту("Обработка.ПечатьЭтикетокИЦенников.Макет.КомпонентаПечатиШтрихкодовLinux64", "КартинкаШтрихкода", ТипВнешнейКомпоненты.Native);

	

	КонецЕсли;



	// Создадим объект внешней компоненты

	Если ПодключениеВыполнено Тогда

		ВнешняяКомпонента = Новый("AddIn.КартинкаШтрихкода.Barcode");

	Иначе

		Возврат Неопределено;

	КонецЕсли;

	

	// Если нет возможности рисовать

	Если НЕ ВнешняяКомпонента.ГрафикаУстановлена Тогда

		// То картинку сформировать не сможем

		Возврат Неопределено;

	Иначе

		

		// Установим основные параметры компоненты

		

		// Если в системе установлен шрифт Tahoma

		Если ВнешняяКомпонента.НайтиШрифт("Tahoma") = Истина Тогда

			// Выбираем его как шрифт для формирования картинки

			ВнешняяКомпонента.Шрифт = "Tahoma";

		Иначе

			

			// Шрифт Tahoma в системе отсутствует

			// Обойдем все доступные компоненте шрифты

			Для Сч = 0 По ВнешняяКомпонента.КоличествоШрифтов -1 Цикл

				// Получим очередной шрифт, доступный компоненте

				ТекущийШрифт = ВнешняяКомпонента.ШрифтПоИндексу(Сч);

				// Если шрифт доступен

				Если ТекущийШрифт <> Неопределено Тогда

					// Они и будет шрифтом для формирования штри-кода

					ВнешняяКомпонента.Шрифт = ТекущийШрифт;

					Прервать;

				КонецЕсли;

			КонецЦикла;

		КонецЕсли;

		

		// Утановим размер шрифта

		ВнешняяКомпонента.РазмерШрифта = 10;

		

		Возврат ВнешняяКомпонента;

		

	КонецЕсли;

	

КонецФункции

В коде выше все компоненты загружены в макеты обработки «ПечатьЭтикетокИЦенников». В принципе ничто не мешает поместить их в любое иное место. Вызов функции осуществляется командой:

Код 1C v 8.х

 ВнешняяКомпонента = ПодключитьВнешнююКомпонентуПечатиШтрихкода();

Если что-то не получилось – возвращает НЕОПРЕДЕЛЕНО.

Далее опишем функцию, которая, получив данные, сформирует нужную нам картинку с штрихкодом:

Код 1C v 8.х

 Функция ПолучитьКартинкуШтрихкода(ВнешняяКомпонента, Штрихкод, Ширина, Высота) Экспорт

	

	// Зададим размер картинки

	ВнешняяКомпонента.Ширина =Ширина;

	ВнешняяКомпонента.Высота =Высота;

	

	// Разрешим компоненте самой определять тип кода

	ВнешняяКомпонента.АвтоТип = истина;

	

	// Если код содержит контрольный символ, обязательно указываем

	ВнешняяКомпонента.СодержитКС = СтрДлина(Штрихкод) = 13;

	

	// Если отображать контрольный символ не нужно

	// ВнешняяКомпонента.ВидимостьКС = Ложь;

	

	// Формируем картинку штрихкода

	ВнешняяКомпонента.ЗначениеКода = Штрихкод;

	

	// Если установленная нами ширина меньше минимально допустимой для этого штрихкода

	Если ВнешняяКомпонента.Ширина < ВнешняяКомпонента.МинимальнаяШиринаКода Тогда

		// Скорректируем ширину

		ВнешняяКомпонента.Ширина = ВнешняяКомпонента.МинимальнаяШиринаКода + 10;

	КонецЕсли;

	

	// Сформируем картинку

	ДвоичныеДанныеКартинки = ВнешняяКомпонента.ПолучитьШтрихкод();

	

	// Если картинка сформировалась

	Если ДвоичныеДанныеКартинки <> Неопределено Тогда

		// Формируем из двоичных данных

		Возврат Новый Картинка(ДвоичныеДанныеКартинки);

	КонецЕсли;

	

	Возврат Неопределено;

	

КонецФункции

В данной функции используется автоопределение типа штрихкода командой

Код 1C v 8.х

 ВнешняяКомпонента.АвтоТип = истина;

Можно тип штрихкода указать вручную:

Код 1C v 8.х

 ВнешняяКомпонента.АвтоТип = Ложь;

ВнешняяКомпонента.ТипКода = 1; // указан тип EAN13

ТипКода - число от 0 до 15: 0 - EAN8, 1 - EAN13, 2 - EAN128. Вот полный список типов по порядку:
EAN8, EAN13, EAN128, Code39, Code128, Code16k, PDF417, Standart (Industrial) 2 of 5, Interleaved 2 of 5, Расширение Code39, Code93, ITF14, RSS14, CodaBar, EAN13 AddOn 2, EAN13 AddOn 5.

Кроме типа штрихкода, компонента имеет ряд других свойств, например ВнешняяКомпонента.ОтображатьТекст, ВнешняяКомпонента.РазмерШрифта и прочие, можно посмотреть в свойствах.

Наконец последнее - вывод штрихкода. Для этого в макет поместим картинку с именем «Штрихкод». Получаем и выводим штрихкод в область командой:

Код 1C v 8.х

 ОбластьЗначение.Рисунки.Штрихкод.Картинка = ПолучитьКартинкуШтрихкода(ВнешняяКомпонента, Штрихкод, 50, 30);

Где Штрихкод – переменная, содержащая строку штрихкода номенклатуры, 50 – требуемая ширина, 30 – высота картинки. В макете размер картинки лучше всего поставить «Реальный размер».

Замечание. Сразу бросается в глаза то, что я вручную указываю размер требуемой картинки – 50 на 30. Возникает вопрос, а нельзя ли размеры требуемой картинки получить из картинки на макете? Конечно можно:

Код 1C v 8.х

 ОбластьЗначение.Рисунки.Штрихкод.Ширина

ОбластьЗначение.Рисунки.Штрихкод.Высота

К сожалению, цифры получаемые этими командами почему-то слишком малы. Как получить реальный видимый размер картинки я пока не знаю, может кто подскажет?
Источник

Категория: Штрих-код (barcode)

Простое штрихкодирование документов

Была поставлена задача на предприятии, где ежедневно выписывается по 300-500 накладных организовать штрихкодирование документов, для более удобной работы с бумажным носителем в дальнейшем. И вот результат…

Конфигурация “Торговля и склад”. Хотелось сделать как можно проще и быстрее, и в тоже время надежно. На решение задачи ушло 1,5 часа. И так приступим….

У нас будет использоваться штрихкод EAN13. Создаем общий реквизит документов:
title

Общий реквизит документов "EAN13"
Тип – “Строка”, длина – 13, отбор по реквизиту

Добавляем в глобальный модуль процедуру

Код 1C v 7.x

 //******************************************************************************

// глСформироватьШтрихкодДокумента(Конт)

//

// Параметры:

//  Конт - контекст документа для которого необходимо сформировать штрихкод

//    EAN13- реквизит документа содержащий штрихкод

// Возвращаемое значение:

//  Нет                

//

// Описание:

//  На основании номера документа и вида документа формирует штрихкод в формате

//  EAN

//

Процедура глСформироватьШтрихкодДокумента(Конт, EAN13) Экспорт

   

    Если ПустаяСтрока(EAN13) = 1 Тогда

   

        ПрефиксыДокументов = СоздатьОбъект("СписокЗначений");



        ПрефиксыДокументов.ДобавитьЗначение("001", "Реализация");



        ПрефиксыДокументов.ДобавитьЗначение("002", "СчетФактураВыданный");               

        // и т.д



        КодДокумента        = СокрЛП(Прав(Конт.НомерДок,7));

        КодВидаДокумента    = ПрефиксыДокументов.Получить(Конт.Вид());

   

       

        Префикс = Прав(ДатаГод(Конт.ДатаДок), 2);

   

        ИспКолво = 10;

       

        Штрихкод = СимволыВЦифры(Прав(СокрЛП(КодДокумента+КодВидаДокумента),

                   ИспКолво));

        Штрихкод = Префикс + глДополнитьСтрокуЛ(Штрихкод, "0", ИспКолво);

                 

        EAN13 = Штрихкод + глКонтрольныйСимволEAN(Штрихкод, 13);

    КонецЕсли;

                   

КонецПроцедуры // глСформироватьШтрихкодДокумента()

После этого в документы, которым будут присваиваться штрихкоды добавляем вызов
вышеописанного в процедуру "ПриЗаписи()"

Код 1C v 7.x

 Процедура ПриЗаписи()

   //..............................

   глСформироватьШтрихкодДокумента(Контекст, EAN13);

КонецПроцедуры

В результате при первой записи документа ему будет присвоен штрихкод состоящий
из следующих блоков:
1. год документа (2 символа);
2. семь цифр справа от номера документа;
3. код вида документа (3 символа);
4. контрольный символ;

Осталось только вставить в печатную форму объект ActiveBarcode и настроить
необходимые свойства у него.

А вот и результат

Автор: Александр Шкураев

Категория: Штрих-код (barcode)

Функция проверки соответствия введенного ИНН контрагента требованиям

Идентификационный номер налогоплательщика
Идентификационный номер налогоплательщика (ИНН) - в Российской Федерации уникальный код используемый при учете в налоговом органе юридических и физических лиц. ИНН юридических лиц (организаций) состоит из 10 цифр. ИНН физических лиц, в т.ч. индивидуальных предпринимателей состоит из 12 цифр.

ИНН указывается налогоплательщиками в документах, предусмотренных законодательством, подаваемых в налоговые органы. Для идентификации отдельного подразделения организации, в связи с постановкой на учет в разных налоговых органах применяется код причины постановки (КПП).

Структура ИНН юридического лица

ИНН юридического лица состоит из 10 последовательных цифр.

1-2: код субъекта Российской Федерации.

3-4: номер налоговой инспеции в субъекте РФ.

1-4: код налоговой инспекции по СОУН (Справочник кодов обозначения налоговых органов для целей учёта налогоплательщиков) осуществивщей регистрацию.

5-9: номер записи в территориальном разделе ЕГРН (Единый государственный реестр налогоплательщиков).

10: контрольная цифра.

Структура ИНН физического лица

ИНН юридического лица состоит из 10 последовательных цифр.

1-2: код субъекта Российской Федерации.

3-4: номер налоговой инспеции в субъекте РФ.

1-4: код налоговой инспекции по СОУН осуществивщей регистрацию.

5-10: номер записи в территориальном разделе ЕГРН.

11-12: контрольные цифры.

Для проверки ИНН можно обратиться в налоговый орган за выпиской из ЕГРН или провести проверку контрольных цифр в соответствии со следующим алгоритмом:

1. Для расчета десятого контрольного разряда в 10-ти значном ИНН каждая цифра ИНН (кроме десятой) умножается на соответствующий множитель в соответствии с таб.1 , ззатем все значения суммируются , сумма берется по модулю 11, затем полученное число берется по модулю 10 это и есть десятый разряд.

2. Для расчета 11-ого контрольного разряда (1-ой контрольной цифры) в 12-ти значном ИНН каждая цифра ИНН (кроме 11-ой и 12-ой) умножается на соответствующий множитель в соответствии с таб.1 , затем все значения суммируются , сумма берется по модулю 11, затем полученное число берется по модулю 10 это и есть 11-ый разряд.

3. Для расчета 12-ого контрольного разряда (2-ой контрольной цифры) в 12-ти значном ИНН каждая цифра ИНН (кроме12-ой) ,11-ая вычисляется в соотв. с пред. пунктом, умножается на соответствующий множитель в соответствии с таб.1 , затем все значения суммируются , сумма берется по модулю 11, затем полученное число берется по модулю 10 это и есть 12-ый разряд.
title

Конкретные примеры

ИНН 500100732259 — 12 цифр (первый попавшийся в Интернете ИНН).

Шаг 1: 5* 7+ 0* 2+ 0* 4+ 1* 10+ 0* 3+ 0* 5+ 7* 9+ 3* 4+ 2* 6+ 2* 8= 148
148= 11* 13 + 5(остаток); совпадает
Шаг 2: 5* 3+ 0* 7+ 0* 2+ 1* 4+ 0* 10+ 0* 3+ 7* 5+ 3* 9+ 2* 4+ 2* 6+ 5* 8= 141141= 11* 12 +9(остаток); совпадает
Оба контрольных числа совпадают, номер правильный.

ИНН 7830002293 — 10 цифр (Санкт-Петербургская бумажная фабрика Гознака).

Шаг 1: 7* 2+ 8* 4+ 3* 10+ 0* 3+ 0* 5+ 0* 9+ 2* 4+ 2* 6+ 9* 8= 168168= 11* 15 +3(остаток)
Контрольное число совпадает, номер правильный.

Функция проверки соответствия ИНН требованиям:

Код 1C v 8.х

 // Параметры:

//		ИНН - строка - проверяемый индивидуальный номер налогоплательщика,

//		ВладелецИНН - ПеречислениеСсылка.ЮрФизЛицо - тип владельца ИНН: физлицо или юрлицо

Функция ИННСоответствуетТребованиям(Знач ИНН, ВладелецИНН) Экспорт



	ИНН = СокрЛП(ИНН);

	ДлинаИНН =  СтрДлина(ИНН);



	Если НЕ ТолькоЦифрыВСтроке(ИНН) Тогда

		Возврат Ложь;

	КонецЕсли;



	Если ДлинаИНН = 10  и ВладелецИНН = Перечисления.ЮрФизЛицо.ЮрЛицо Тогда



		КонтрольнаяСумма = 0;



		Для Н = 1 По 9 Цикл



			Если 	  Н = 1 Тогда

				Множитель = 2;

			ИначеЕсли Н = 2 Тогда

				Множитель = 4;

			ИначеЕсли Н = 3 Тогда

				Множитель = 10;

			ИначеЕсли Н = 4 Тогда

				Множитель = 3;

			ИначеЕсли Н = 5 Тогда

				Множитель = 5;

			ИначеЕсли Н = 6 Тогда

				Множитель = 9;

			ИначеЕсли Н = 7 Тогда

				Множитель = 4;

			ИначеЕсли Н = 8 Тогда

				Множитель = 6;

			ИначеЕсли Н = 9 Тогда

				Множитель = 8;

			КонецЕсли; 

			

			Цифра = Число(Сред(ИНН,Н,1));

			КонтрольнаяСумма = КонтрольнаяСумма + Цифра * Множитель;

			

		КонецЦикла; 

		

		КонтрольныйРазряд = (КонтрольнаяСумма %11) %10;

		

		Если КонтрольныйРазряд <> Число(Сред(ИНН,10,1)) Тогда

			Возврат Ложь;

		КонецЕсли; 

		

	ИначеЕсли ДлинаИНН =12 и ВладелецИНН = Перечисления.ЮрФизЛицо.ФизЛицо Тогда

		

		КонтрольнаяСумма11 = 0;

		КонтрольнаяСумма12 = 0;

		

		Для Н=1 По 11 Цикл

			

			// Расчет множителя для 11-го и 12-го разрядов

			Если Н = 1 Тогда

				Множитель11 = 7;

				Множитель12 = 3;

			ИначеЕсли Н = 2 Тогда

				Множитель11 = 2;

				Множитель12 = 7;

			ИначеЕсли Н = 3 Тогда

				Множитель11 = 4;

				Множитель12 = 2;

			ИначеЕсли Н = 4 Тогда

				Множитель11 = 10;

				Множитель12 = 4;

			ИначеЕсли Н = 5 Тогда

				Множитель11 = 3;

				Множитель12 = 10;

			ИначеЕсли Н = 6 Тогда

				Множитель11 = 5;

				Множитель12 = 3;

			ИначеЕсли Н = 7 Тогда

				Множитель11 = 9;

				Множитель12 = 5;

			ИначеЕсли Н = 8 Тогда

				Множитель11 = 4;

				Множитель12 = 9;

			ИначеЕсли Н = 9 Тогда

				Множитель11 = 6;

				Множитель12 = 4;

			ИначеЕсли Н = 10 Тогда

				Множитель11 = 8;

				Множитель12 = 6;

			ИначеЕсли Н = 11 Тогда

				Множитель11 = 0;

				Множитель12 = 8;

			КонецЕсли; 

			

			Цифра = Число(Сред(ИНН,Н,1));

			КонтрольнаяСумма11 = КонтрольнаяСумма11 + Цифра * Множитель11;

			КонтрольнаяСумма12 = КонтрольнаяСумма12 + Цифра * Множитель12;

			

		КонецЦикла; 

		

		КонтрольныйРазряд11 = (КонтрольнаяСумма11 %11) %10;

		КонтрольныйРазряд12 = (КонтрольнаяСумма12 %11) %10;

		

		Если КонтрольныйРазряд11 <> Число(Сред(ИНН,11,1))

			ИЛИ КонтрольныйРазряд12 <> Число(Сред(ИНН,12,1)) Тогда

			Возврат Ложь;

		КонецЕсли; 

		

	Иначе		

		Возврат Ложь;		

	КонецЕсли; 	

	Возврат Истина;	

КонецФункции

Категория: Полезные, Универсальные Функции