найденная » Поиск

Результаты по ключевому слову: найденная

Программное создание, заполнение документа и открытие формы (УП, тонкий клиент)

Чтобы программно заполнить документ по кнопке, делаем примерно следующее:

1. на форму, в нашем случае документа, добавляем кнопку (Команда и у нее процедура СоздатьПеремещение(Команда))

2. в ее обработчике пишем код создания документа перемещение товаров и заполняем его

Код 1C v 8.3

 &НаСервере

Функция СоздатьПеремещениеНаСервере(ДанныеФормы)

	ДанныеФормы.Дата=ТекущаяДата();

	// ДанныеФормы.Номер="1";

	ДанныеФормы.СкладОтправитель =  Справочники.Склады.НайтиПоНаименованию("Склад гарантийного обслуживания");

	ДанныеФормы.СкладПолучатель = Справочники.Склады.НайтиПоНаименованию("Склад гарантийных");

	

	новСП=Новый СписокЗначений;	н=0;

	Для Каждого стр из Объект.ДанныеПоГН Цикл 

		Если стр.ДанныеПроверки=Перечисления.СтатусПроверкиГарантии.зн0 тогда //!В документ перемещение только записи статус=зн0

		новСП.Добавить(Строка(стр.НомерЗаводской));  н=н+1;

		КонецЕсли;

	КонецЦикла;

	

	Если н>0 Тогда

	Запрос = Новый Запрос;

	Запрос.Текст = 

	"ВЫБРАТЬ

	|	РеализацияТоваровУслугСерии.Серия КАК Серия,

	|	РеализацияТоваровУслугСерии.Ссылка.Дата КАК ДатаОтгрузки,

	|	РеализацияТоваровУслугСерии.Ссылка.Контрагент КАК Контрагент,

	|	РеализацияТоваровУслугСерии.Ссылка КАК Возврат,

	|	РеализацияТоваровУслугСерии.Номенклатура,

	|	ПРЕДСТАВЛЕНИЕ(РеализацияТоваровУслугСерии.Серия) КАК СерияСТР

	|ИЗ

	|	Документ.ВозвратТоваровОтКлиента.Серии КАК РеализацияТоваровУслугСерии

	|ГДЕ

	|	РеализацияТоваровУслугСерии.Серия В

	|			(ВЫБРАТЬ

	|				СерииНоменклатуры.Ссылка КАК Ссылка

	|			ИЗ

	|				Справочник.СерииНоменклатуры КАК СерииНоменклатуры

	|			ГДЕ

	|				СерииНоменклатуры.Наименование В (&Наименование))

	|

	|УПОРЯДОЧИТЬ ПО

	|	Серия

	|АВТОУПОРЯДОЧИВАНИЕ"; 	

	Запрос.УстановитьПараметр("Наименование", новСП);	

	ТаблицаЗапроса = Запрос.Выполнить().Выгрузить();	

	Для каждого стр из новСП Цикл

		

			НайденнаяСтрока=ТаблицаЗапроса.Найти(стр.Значение,"СерияСТР");

			Если НайденнаяСтрока = Неопределено Тогда

				//нет такого

			Иначе

				нстр=ДанныеФормы.Товары.Добавить();

				нстр.Номенклатура = НайденнаяСтрока.Номенклатура;

				нстр.Серия=НайденнаяСтрока.Серия; 

				нстр.КоличествоУпаковок=1;

				нстр.Количество=1;

				нстр.СтатусУказанияСерий=2;

				нстр.СтатусУказанияСерийОтправитель=2;

				нстр.СтатусУказанияСерийПолучатель=2;

				

				нстр=ДанныеФормы.Серии.Добавить();

				нстр.Номенклатура = НайденнаяСтрока.Номенклатура;

				нстр.Серия=НайденнаяСтрока.Серия; 

				нстр.Количество=1;    

			КонецЕсли;	

	КонецЦикла;

	КонецЕсли;

	Возврат ДанныеФормы;

КонецФункции





&НаКлиенте

Процедура СоздатьПеремещение(Команда)

	Форма=ПолучитьФорму("Документ.ПеремещениеТоваров.ФормаОбъекта"); 

	ДанныеФормы=Форма.Объект;

	ДанныеФормы=СоздатьПеремещениеНаСервере(ДанныеФормы);

	КопироватьДанныеФормы(ДанныеФормы,Форма.Объект);

	Форма.Открыть();

КонецПроцедуры

Категория: Документы

Как программно создать нового пользователя или скопировать настройки существующего?

Часто встречаю вопросы касаемые программного создания и настройки прав пользователей.

В этот статье я приведу примеры для Обычного и Управляемого приложений, которые программно создают пользователя в конфигураторе и в режиме Предприятие (справочник пользователи) и установку Групп пользователей.

В приложении к статье обработки, код которых приведен ниже: Скачать обработки

Обработки были написаны под УТ, но, при необходимости, вы можете их легко доработать под другие конфигурации.

Управляемое приложение:

В конфигурациях на управляемом интерфейсе (Такси) изменили подход к ведению пользователей. Если вы добавляете не программно, то добавлять нужно из режима Предприятия - тогда пользователь ИБ у вас сам создатся. И если раньше, в обычном приложении, достаточно будет добавить польз в конфигураторе - и при заходе в Предприятие, этот польз сам создавался в спр Пользователи, то с управляемым приложением такой фокус не прокатит - система не даст зайти под пользователем ИБ, которого нет в справочнике Пользователи.

! В типовых конфигурациях для работы с пользователями активно используется БСП !

В общем модуле Пользователи используется программный интерфейс процедур и функций НовоеОписаниеПользователяИБ, ПрочитатьПользователяИБ, ЗаписатьПользователяИБ иУдалитьПользователяИБ.

Код создания нового пользователя с использованием БСП:

Код 1C v 8.3

 &НаСервере

Функция КопированиеВсехНастроек(ПользовательСсылка,ПользовательПриемник)

	

	Пользователь = Обработки.НастройкиПользователей.ИмяПользователяИБ(ПользовательСсылка);

	

	Приемники = Новый Массив;

	ТаблицаПользователей = Новый ТаблицаЗначений;

	ТаблицаПользователей.Колонки.Добавить("Пользователь");

	ТаблицаПользователей = Обработки.НастройкиПользователей.ПользователиДляКопирования(ПользовательСсылка, ТаблицаПользователей, 

	ТипЗнч(ПользовательСсылка) = Тип("СправочникСсылка.ВнешниеПользователи"));

	

	Для Каждого СтрокаТаблицы Из ТаблицаПользователей Цикл

		Приемники.Добавить(ПользовательПриемник);

	КонецЦикла;

	

	КопируемыеНастройки = Новый Массив;

	КопируемыеНастройки.Добавить("НастройкиОтчетов");

	КопируемыеНастройки.Добавить("НастройкиВнешнегоВида");

	КопируемыеНастройки.Добавить("ПерсональныеНастройки");

	КопируемыеНастройки.Добавить("Избранное");

	КопируемыеНастройки.Добавить("НастройкиПечати");

	КопируемыеНастройки.Добавить("ПрочиеПользовательскиеНастройки");

	

	НастройкиСкопированы = Обработки.НастройкиПользователей.

	КопированиеНастроекПользователей(ПользовательСсылка, Приемники, КопируемыеНастройки);

		

	Возврат НастройкиСкопированы;

	

КонецФункции





Функция СоздатьНовыйУровеньДоступа(ФИО)

	

	 Рез = Справочники.CRM_УровниДоступа.НайтиПоНаименованию(ФИО);

	 Если Рез = Неопределено ИЛИ Рез = Справочники.CRM_УровниДоступа.ПустаяСсылка() Тогда

		 НовыйОбъект = Справочники.CRM_УровниДоступа.СоздатьЭлемент();

		 НовыйОбъект.Наименование = ФИО;

		 НовыйОбъект.Записать();

		 возврат НовыйОбъект.Ссылка;

	 КонецЕсли;	 

		 

КонецФункции	





Процедура ОбновитьДанныеПользователяИБ(ПользовательНастроек, Знач ОтображатьИмя = Истина)

	

	Если ПользовательНастроек = Неопределено Тогда

		Возврат;

	КонецЕсли;

	

	ПроверкаНаСуществующегоПользователя = ПользователиИнформационнойБазы.НайтиПоИмени(Объект.ФИОСоздаваемогоПользователя);

	Если ПроверкаНаСуществующегоПользователя = Неопределено Тогда

		

	Пользователь_Шаблон = ПользователиИнформационнойБазы.НайтиПоИмени(сокрлп(ПользовательНастроек.Наименование));





	ОписаниеПользователяИБ            = Пользователи.НовоеОписаниеПользователяИБ();

	ПользовательИБСуществует          = Ложь;

	ДоступКИнформационнойБазеРазрешен = Ложь;

	

	// Заполнение начальных значений свойств пользователяИБ.

	Если ОбщегоНазначенияПовтИсп.РазделениеВключено() Тогда

		ОписаниеПользователяИБ.ПоказыватьВСпискеВыбора = Ложь;

	Иначе

		ОписаниеПользователяИБ.ПоказыватьВСпискеВыбора =

			НЕ Константы.ИспользоватьВнешнихПользователей.Получить();

	КонецЕсли;

	ОписаниеПользователяИБ.АутентификацияСтандартная = Истина;

	ОписаниеПользователяИБ.Роли = Новый Массив;

	ПрочитанныеСвойства               = Неопределено;

	Если Пользователи.ПрочитатьПользователяИБ(

		         ПользовательНастроек.ИдентификаторПользователяИБ,ПрочитанныеСвойства

		         ) Тогда

			

			// Установка связи пользователем ИБ.

			//ДоступКИнформационнойБазеРазрешен = Истина;

			

			// Копирование свойств и ролей пользователяИБ.

			ЗаполнитьЗначенияСвойств(

				ОписаниеПользователяИБ,

				ПрочитанныеСвойства,

				"АутентификацияOpenID,

				|АутентификацияСтандартная,

				|ЗапрещеноИзменятьПароль,

				|ПоказыватьВСпискеВыбора,

				|АутентификацияОС,

				|РежимЗапуска,

				|Язык,

				|Роли");

	КонецЕсли;

	

	ОписаниеПользователяИБ.Вставить("Действие", "Записать");

	ОписаниеПользователяИБ.Вставить("Имя", Объект.ФИОСоздаваемогоПользователя);

	





		НовыйПользователь = Справочники.Пользователи.СоздатьЭлемент();

		НовыйПользователь.Наименование 					= Объект.ФИОСоздаваемогоПользователя;

		НовыйПользователь.ТекущееПодразделение			= ПользовательНастроек.ТекущееПодразделение;

		НовыйПользователь.CRM_УровеньДоступа			= СоздатьНовыйУровеньДоступа(Объект.ФИОСоздаваемогоПользователя);

		НовыйПользователь.Недействителен				= ложь;





		НовыйПользователь.ДополнительныеСвойства.Вставить(

			"ОписаниеПользователяИБ", ОписаниеПользователяИБ);

			

		НовыйПользователь.Записать();

				

		Запрос = Новый Запрос;

		Запрос.Текст = 

		"ВЫБРАТЬ

		|	ГруппыПользователейПользователиГруппы.Ссылка

		|ИЗ

		|	Справочник.ГруппыПользователей.Состав КАК ГруппыПользователейПользователиГруппы

		|ГДЕ

		|	ГруппыПользователейПользователиГруппы.Пользователь =Пользователь

		|

		|СГРУППИРОВАТЬ ПО

		|	ГруппыПользователейПользователиГруппы.Ссылка";

		

		Запрос.УстановитьПараметр("Пользователь", ПользовательНастроек);

		

		РезультатЗапроса = Запрос.Выполнить();

		

		ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

		

		Пока ВыборкаДетальныеЗаписи.Следующий() Цикл

			объ = ВыборкаДетальныеЗаписи.Ссылка.ПолучитьОбъект();

			НоваяСтрока = объ.Состав.Добавить();

			НоваяСтрока.Пользователь = НовыйПользователь.Ссылка;

			объ.Записать();

		КонецЦикла;

		

		Запрос.Текст = 

		"ВЫБРАТЬ

		|	ГруппыДоступаПользователи.Ссылка

		|ИЗ

		|	Справочник.ГруппыДоступа.Пользователи КАК ГруппыДоступаПользователи

		|ГДЕ

		|	ГруппыДоступаПользователи.Пользователь =Пользователь

		|

		|СГРУППИРОВАТЬ ПО

		|	ГруппыДоступаПользователи.Ссылка";

		

		Запрос.УстановитьПараметр("Пользователь", ПользовательНастроек);

		

		РезультатЗапроса = Запрос.Выполнить();

		

		ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

		

		Пока ВыборкаДетальныеЗаписи.Следующий() Цикл

			объ = ВыборкаДетальныеЗаписи.Ссылка.ПолучитьОбъект();

			НоваяСтрока = объ.Пользователи.Добавить();

			НоваяСтрока.Пользователь = НовыйПользователь.Ссылка;

			объ.Записать();

		КонецЦикла;





		КопированиеВсехНастроек(ПользовательНастроек,НовыйПользователь.Ссылка);

		

	Иначе

		сообщить("Указанное ФИО Пользователя уже используется !!! ");

	КонецЕсли;

		

КонецПроцедуры





&НаКлиенте

Процедура СоздатьПользователя(Команда)

	СоздатьПользователяНаСервере();

КонецПроцедуры





&НаСервере

Процедура СоздатьПользователяНаСервере()

	

	Если НЕ ЗначениеЗаполнено(Объект.ШаблонПользователяДляСозданияНового) Тогда

		Возврат;

	КонецЕсли;





	// настройки устанавливаются на форму

	ОбновитьДанныеПользователяИБ(Объект.ШаблонПользователяДляСозданияНового, Ложь);

	

КонецПроцедуры





&НаСервере

Процедура СкопироватьНастройкиНаСервере(ИзменяемыйПользователь,ШаблонПользователяДляКопирования)

	//Копируем роли пользователя

	тИзменяемыйПользователь = ПользователиИнформационнойБазы.НайтиПоИмени(сокрлп(ИзменяемыйПользователь.Наименование));

	тШаблонПользователяДляКопирования = ПользователиИнформационнойБазы.НайтиПоИмени(сокрлп(ШаблонПользователяДляКопирования.Наименование));

	

	//Очищаем роли

	тИзменяемыйПользователь.Роли.Очистить();

	// Копируем

	СписокДоступныхРолейПользователяИБ = Новый СписокЗначений;  	

	Для Каждого мРоль Из Метаданные.Роли Цикл

		СтрокаСписокаДоступныхРолей = СписокДоступныхРолейПользователяИБ.Добавить();

		СтрокаСписокаДоступныхРолей.Представление = мРоль.Представление();

		СтрокаСписокаДоступныхРолей.Значение = мРоль;

	КонецЦикла; 

	

	Для Каждого СтрокаСпискаДоступныхРолей Из СписокДоступныхРолейПользователяИБ Цикл

		Если тШаблонПользователяДляКопирования.Роли.Содержит(СтрокаСпискаДоступныхРолей.Значение) Тогда

			тИзменяемыйПользователь.Роли.Добавить(СтрокаСпискаДоступныхРолей.Значение);		

		КонецЕсли;	

	КонецЦикла; 

	тИзменяемыйПользователь.Записать();





	//Копируем настройки БСП

	КопированиеВсехНастроек(ШаблонПользователяДляКопирования,ИзменяемыйПользователь);  

КонецПроцедуры





&НаКлиенте

Процедура СкопироватьНастройки(Команда)

	СкопироватьНастройкиНаСервере(Объект.ИзменяемыйПользователь, Объект.ШаблонПользователяДляКопирования);

КонецПроцедуры

Обычное приложение:

В обычном все проще:

Код 1C v 8.х

 Процедура КнопкаВыполнитьНажатие(Кнопка)



	Если НЕ ЗначениеЗаполнено(ШаблонПользователяДляСозданияНового) Тогда

		Возврат;

	КонецЕсли;



	// настройки устанавливаются на форму

	ОбновитьДанныеПользователяИБ(ШаблонПользователяДляСозданияНового, Ложь);

	

КонецПроцедуры



Процедура ОбновитьДанныеПользователяИБ(ПользовательНастроек, Знач ОтображатьИмя = Истина)

	

	Если ПользовательНастроек = Неопределено Тогда

		Возврат;

	КонецЕсли;

	

	ПроверкаНаСуществующегоПользователя = ПользователиИнформационнойБазы.НайтиПоИмени(ФИОСоздаваемогоПользователя);

	Если ПроверкаНаСуществующегоПользователя = Неопределено Тогда

		

		Пользователь_Шаблон = ПользователиИнформационнойБазы.НайтиПоИмени(сокрлп(ПользовательНастроек.Код));

		

		ПользовательИБ = ПользователиИнформационнойБазы.СоздатьПользователя();

		ПользовательИБ.Имя = ФИОСоздаваемогоПользователя;

		ПользовательИБ.АутентификацияСтандартная = Истина;

		ПользовательИБ.Пароль = ПарольСоздаваемогоПользователя;

		ПользовательИБ.ПолноеИмя =  ФИОСоздаваемогоПользователя;

		ПользовательИБ.ПоказыватьВСпискеВыбора = Истина;

		ПользовательИБ.ОсновнойИнтерфейс = Пользователь_Шаблон.ОсновнойИнтерфейс;

		ПользовательИБ.Язык = Пользователь_Шаблон.Язык;

		

		

		СписокДоступныхРолейПользователяИБ = Новый СписокЗначений;

		

		Для Каждого мРоль Из Метаданные.Роли Цикл

			СтрокаСписокаДоступныхРолей = СписокДоступныхРолейПользователяИБ.Добавить();

			СтрокаСписокаДоступныхРолей.Представление = мРоль.Представление();

			СтрокаСписокаДоступныхРолей.Значение = мРоль;

		КонецЦикла; 

		

		Для Каждого СтрокаСпискаДоступныхРолей Из СписокДоступныхРолейПользователяИБ Цикл

			Если Пользователь_Шаблон.Роли.Содержит(СтрокаСпискаДоступныхРолей.Значение) Тогда

				ПользовательИБ.Роли.Добавить(СтрокаСпискаДоступныхРолей.Значение);		

			КонецЕсли;	

		КонецЦикла; 

		

		ПользовательИБ.Записать();

		

		НовыйПользователь = Справочники.Пользователи.СоздатьЭлемент();

		//НовыйПользователь.ИдентификаторПользователяИБ 	= ПользовательИБ.УникальныйИдентификатор;

		НовыйПользователь.Код 							= ФИОСоздаваемогоПользователя;

		НовыйПользователь.Наименование 					= ФИОСоздаваемогоПользователя;

		НовыйПользователь.Родитель						= ПользовательНастроек.Родитель;

		

		НовыйПользователь.Подразделение					= ПользовательНастроек.Подразделение;

		НовыйПользователь.Категория						= ПользовательНастроек.Категория;

		НовыйПользователь.Руководитель					= ПользовательНастроек.Руководитель;

		НовыйПользователь.Действует						= ПользовательНастроек.Действует;

		НовыйПользователь.Записать();

		

		

		НаборПользователя = РегистрыСведений.НастройкиПользователей.СоздатьНаборЗаписей();

		НаборПользователя.Отбор.Пользователь.Установить(ПользовательНастроек);

		НаборПользователя.Прочитать();

		

		НаборНовогоПользователя = РегистрыСведений.НастройкиПользователей.СоздатьНаборЗаписей();

		НаборНовогоПользователя.Отбор.Пользователь.Установить(НовыйПользователь.Ссылка);

		

		

		Для Каждого СтрокаНастроек из НаборПользователя Цикл

			НоваяСтрокаНастроек = НаборНовогоПользователя.Добавить();

			ЗаполнитьЗначенияСвойств(НоваяСтрокаНастроек,СтрокаНастроек);

			НоваяСтрокаНастроек.Пользователь = НовыйПользователь.Ссылка;

			Если Найти(СтрокаНастроек.Настройка.Наименование,"Основной ответственный") Тогда

				НоваяСтрокаНастроек.Значение = НовыйПользователь.Ссылка;

			КонецЕсли;	

		КонецЦикла;	

		

		Если НаборНовогоПользователя.Количество()>0 Тогда

			НаборНовогоПользователя.Записать();

		КонецЕсли;	

		сообщить("Создан пользователь "+ФИОСоздаваемогоПользователя);

		

		Запрос = Новый Запрос;

		Запрос.Текст = 

		"ВЫБРАТЬ

		|	ГруппыПользователейПользователиГруппы.Ссылка

		|ИЗ

		|	Справочник.ГруппыПользователей.ПользователиГруппы КАК ГруппыПользователейПользователиГруппы

		|ГДЕ

		|	ГруппыПользователейПользователиГруппы.Пользователь =Пользователь

		|

		|СГРУППИРОВАТЬ ПО

		|	ГруппыПользователейПользователиГруппы.Ссылка";

		

		Запрос.УстановитьПараметр("Пользователь", ПользовательНастроек);

		

		РезультатЗапроса = Запрос.Выполнить();

		

		ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

		

		Пока ВыборкаДетальныеЗаписи.Следующий() Цикл

			объ = ВыборкаДетальныеЗаписи.Ссылка.ПолучитьОбъект();

			НоваяСтрока = объ.ПользователиГруппы.Добавить();

			НоваяСтрока.Пользователь = НовыйПользователь.Ссылка;

			объ.Записать();

		КонецЦикла;

		

	Иначе

		сообщить("Указанное ФИО Пользователя уже используется !!! ");

	КонецЕсли;

	

	

КонецПроцедуры

еще пример:

Код 1C v 8.х

 Функция ДобавитьПользователя(ИмяПользователя, ДоменноеИмя, ПользовательАктивен, АутентификацияОС, Авторизация1СПредприятия, МассивРолей) Экспорт

    // Попробуем найти сотрудника

    Пользователь = ПользователиИнформационнойБазы.НайтиПоИмени(ИмяПользователя);





    // Теперь попробум найти сотрудника по пользователю ос

   Если Пользователь = Неопределено Тогда

        Для Каждого ТекущийПользователь Из ПользователиИнформационнойБазы.ПолучитьПользователей() Цикл

            Если ТекущийПользователь.ПользовательОС = ДоменноеИмя Тогда

                Пользователь = ТекущийПользователь;

                Прервать;

            Конецесли;

        КонецЦикла;

    КонецЕсли;

    //                            





    // Если мы не нашли сотрудника, то создадим его

    Если Пользователь = Неопределено Тогда

        Пользователь = ПользователиИнформационнойБазы.СоздатьПользователя();

    КонецЕсли;

    //





    // Записываем свойства

    Пользователь.АутентификацияОС = АутентификацияОС;

    Пользователь.АутентификацияСтандартная = Авторизация1СПредприятия;

    Пользователь.ЗапрещеноИзменятьПароль = Истина;

    Пользователь.Имя = ИмяПользователя;

    Пользователь.ПолноеИмя = ИмяПользователя;

    Пользователь.ПоказыватьВСпискеВыбора = Ложь;

    Пользователь.ПользовательОС = ДоменноеИмя;

    

    // Сначала очистим все текущие роли

    Пользователь.Роли.Очистить();

    

    //  Теперь найдем переданный массив ролей в справочнике профилей 

    // и добавим все роли указанные в профиле. Все очень сложно, да

    МассивИменРолей = Новый Массив();

    Для Каждого Роль Из МассивРолей.Role Цикл

        МассивИменРолей.Добавить(Роль);    

    КонецЦикла;

    ТекстЗапроса = "ВЫБРАТЬ

                   |    ПрофилиГруппДоступаРоли.Роль.Имя КАК Имя

                   |ИЗ

                   |    Справочник.ПрофилиГруппДоступа.Роли КАК ПрофилиГруппДоступаРоли

                   |ГДЕ

                   |    ПрофилиГруппДоступаРоли.Ссылка.Наименование В(&МассивИменРолей)";

    Запрос = Новый Запрос(ТекстЗапроса);

    Запрос.УстановитьПараметр("МассивИменРолей", МассивИменРолей);

    Результат = Запрос.Выполнить().Выгрузить();    

    Для Каждого Роль Из Результат Цикл

        НайденнаяРоль = Метаданные.Роли.Найти(Роль.Имя);

        Если НайденнаяРоль <> Неопределено Тогда

            Пользователь.Роли.Добавить(НайденнаяРоль);

        КонецЕсли;

    КонецЦикла;



    // Записываем!

    Пользователь.Записать();



    // Теперь посмотрим нужно ли деактивировать пользователя

    Если Не ПользовательАктивен Тогда

        ДективироватьПользователя(Пользователь);    

    КонецЕсли;



    // Запишем еще и справочник пользователя

    ЗаполнитьСправочникПользователя(Пользователь);

  

    Возврат Истина;

КонецФункции





// Процедура заполняет помимо прочего справочник пользователя

Процедура ЗаполнитьСправочникПользователя(ПользовательИБ) Экспорт

    ТекстЗапроса = "ВЫБРАТЬ

                   |    ИСТИНА КАК ЕстьПользователь,

                   |    Пользователи.Ссылка КАК Пользователь

                   |ИЗ

                   |    Справочник.Пользователи КАК Пользователи

                   |ГДЕ

                   |    Пользователи.ИдентификаторПользователяИБ =ИдентификаторПользователяИБ

                   |

                   |ОБЪЕДИНИТЬ ВСЕ

                   |

                   |ВЫБРАТЬ

                   |    ЛОЖЬ,

                   |    NULL";

    Запрос = Новый Запрос(ТекстЗапроса);

    Запрос.УстановитьПараметр("ИдентификаторПользователяИБ", ПользовательИБ.УникальныйИдентификатор);

    Результат = Запрос.Выполнить().Выгрузить()[0];

    ОписаниеПользователя = Пользователи.НовоеОписаниеПользователяИБ();

    Если Результат.ЕстьПользователь Тогда

        ПользовательОбъект = Результат.Пользователь.ПолучитьОбъект();

    Иначе            

        ПользовательОбъект = Справочники.Пользователи.СоздатьЭлемент(); 

        ПользовательОбъект.ИдентификаторПользователяИБ = ПользовательИБ.УникальныйИдентификатор;

        ПользовательОбъект.Наименование = ПользовательИБ.Имя;

        ОписаниеПользователя.Вставить("Действие", "Записать");

        ПользовательОбъект.ДополнительныеСвойства.Вставить("ОписаниеПользователяИБ", ОписаниеПользователя);

    КонецЕсли;

    ЗаполнитьЗначенияСвойств(ОписаниеПользователя, ПользовательИБ);

    Для Каждого Элемент Из ОписаниеПользователя Цикл

        ПользовательОбъект.ДополнительныеСвойства.Вставить(Элемент.Ключ, Элемент.Значение);        

    КонецЦикла;        

    ПользовательОбъект.ДополнительныеСвойства.Удалить("Роли");

    ПользовательОбъект.Записать();

КонецПроцедуры

Категория: Пользователь, роль доступа, интерфейс

Как сформировать отчет СКД без проверки прав (в привилегированном режиме)?

Что при разработке отчетов требуется чтобы у пользователя с ограниченными правами, отчет формировался полностью без проверки прав!

Особенно если настроен RLS

Есть несколько способов как это сделать:

1. Установить привилегированный режим в модуле отчета

Форма отчета должна быть Управляемой, далее в модуле отчета процедура обработчика «При компоновке результата»:

Код 1C v 8.3

 //Перехватываем событие вывода компоновки данных в табличный документ и выводим со своим заголовком

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)

	СтандартнаяОбработка = Ложь; 

	УстановитьПривилегированныйРежим(Истина);	

	

	//Сформируем отчет

	СформироватьОтчет(ДокументРезультат, ДанныеРасшифровки);

	

	УстановитьПривилегированныйРежим(Ложь);

КонецПроцедуры

2. Формирование в привилегированном режиме через Общий модуль с галкой Привелигерованный

Создаем общий модуль

так же как в пункте 1 в обработчике «При компоновке результата» пишем:

Код 1C v 8.3

 //Перехватываем событие вывода компоновки данных в табличный документ и выводим со своим заголовком

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)

	СтандартнаяОбработка = Ложь;  

	

	МЕ_ДляОтчетаСКД_ПривелРежим.СформироватьОтчетПривРеж(ДокументРезультат, СхемаКомпоновкиДанных, ДанныеРасшифровки, КомпоновщикНастроек);



КонецПроцедуры

В общем модуле МЕ_ДляОтчетаСКД_ПривелРежим код:

Код 1C v 8.3

 Процедура СформироватьОтчетПривРеж(ТабличныйДокумент, СхемаКомпоновкиДанных, ДанныеРасшифровки, КомпоновщикНастроек) Экспорт 



	ТабличныйДокумент.Очистить();  

	

	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных; 	

	МакетКомпоновкиДанных = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки, ДанныеРасшифровки,,,Ложь);

	

	ВнешниеНаборыДанных  = Новый Структура;

	/// можно передать внешние данные ВнешниеНаборыДанных.Вставить("тзПродаж", СформироватьТЗПродаж());

	

	ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;

	ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновкиДанных,ВнешниеНаборыДанных,ДанныеРасшифровки);

	

	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;

	ПроцессорВывода.УстановитьДокумент(ТабличныйДокумент);

	ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);

	

КонецПроцедуры

3. Если включен режим Использовать ограничение на уровне прав доступа - RLS

Часто используется в типовых. Тут в модуле для текущего пользователя можно на время формирования отчету установить параметр сеанса ИспользоватьОграниченияПравДоступаНаУровнеЗаписей в Ложь и RLS не сработает.

Код 1C v 8.3

 ПараметрыСеанса.ИспользоватьОграниченияПравДоступаНаУровнеЗаписей=Ложь;

После завершения формирования, не забудьте включить rls обратно установив = Истина

4. Если в запросе используется конструкция вида регистратор.дата и это поле не отображается в полях отчета СКД

Допустим Вы сделали запрос по регистру накоплений и через регистратор обратились к дате или сумме документа и при формировании отчета СКД, эти поля недоступны !? как же быть?

Проблема в том - что у регистратором может выступать несколько документов и видимо права чтение/просмотр есть не на все - поэтому через скд эта таблица целиком недоступна, решение:

1. открыть доступ на все регистраторы регистра

2. в запросе четко обозначить тип

Код 1C v 8.3

 //примеры

ВЫРАЗИТЬ(ДокументыОплаты.Регистратор КАК Документ.ПлатежноеПоручениеВходящее).СуммаДокумента

//или так

ВЫБОР

 КОГДА РАЗНОСТЬДАТ(ВЫРАЗИТЬ(ВзаиморасчетыПоДокументам.ДокументРасчетовСКонтрагентом КАК Документ.ПоступлениеТоваровУслуг).Дата,КонецПериода, ДЕНЬ) > ВзаиморасчетыПоДокументам.ДоговорКонтрагента.ДопустимоеЧислоДнейЗадолженности

   ТОГДА ДОБАВИТЬКДАТЕ(ВЫРАЗИТЬ(ВзаиморасчетыПоДокументам.ДокументРасчетовСКонтрагентом КАК Документ.ПоступлениеТоваровУслуг).Дата, ДЕНЬ, ВзаиморасчетыПоДокументам.ДоговорКонтрагента.ДопустимоеЧислоДнейЗадолженности)

 ИНАЧЕ ДАТАВРЕМЯ(1, 1, 1)

КОНЕЦ КАК ДеньВозникновенияЗадолженности

В дополнении у пункту 1, код процедуры сформировать отчет(). Для вывода отчета я использую шаблон All4CF.ru_Template_SKD_v4.1 в нем уже реализованы почти все необходимые функции и работает в Обычных и УП формах:

Код 1C v 8.3

 // Процедура выполняет формирование табличного документа по настройкам СКД

Процедура СформироватьОтчет(ТабличныйДокумент, ДанныеРасшифровки) 

	УстановитьПривилегированныйРежим(Истина);	

	// если отчет открывается по расшифровке, отбору, упорядочиванию, 

	// группировке или условному оформлению - восстановим настройки вывода заголовка,

	// т.к., в переданных настройках при этом, вывод заголовка отключен

	// для того, чтобы не выводился встроенный заголовок компоновки.                                                                         

	ВосстановитьНастройкиВыводаЗаголовка();

	

	ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;

	

	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;

	

	ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;

	

	ТабличныйДокумент.Очистить();

	

	// установим обязательные настройки отчета

	УстановитьПараметрыОтчета();

	

	// Сделаем копию настроек вывода заголовка

	СохранитьНастройкиВыводаЗаголовка();

	

	ВыводитьЗаголовок = ВыводитьЗаголовокОтчета();

	Если ВыводитьЗаголовок Тогда

		ПрисоединитьЗаголовокОтчетаКТабличномуДокументу(ТабличныйДокумент, ПолучитьТекстЗаголовкаОтчета());

		

		// Отключим в настройках вывод встроенного заголовка

		НайденнаяНастройкаВыводаЗаголовка = КомпоновщикНастроек.Настройки.ПараметрыВывода.Элементы.Найти("ВыводитьЗаголовок");

		НайденнаяНастройкаВыводаЗаголовка.Значение		= ТипВыводаТекстаКомпоновкиДанных.НеВыводить;

		НайденнаяНастройкаВыводаЗаголовка.Использование	= Истина;

	КонецЕсли;

	

	КопияДополнительныхНастроек = УстановитьДополнительныеНастройкиДляРасшифровки();

	

	МакетКомпоновкиДанных = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки, ДанныеРасшифровки);

	

	// при необходимости вставим внешние наборы данных в СКД

	ВнешниеНаборыДанных = Новый Структура;

	

	ТаблицаВнешнегоНабораДанных = ПолучитьТаблицуВнешнегоНабораДанных();

	ВнешниеНаборыДанных.Вставить("ТаблицаВнешнегоНабораДанных",ТаблицаВнешнегоНабораДанных);

	

	ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновкиДанных,ВнешниеНаборыДанных,ДанныеРасшифровки);

	

	ВывестиРезультатКомпоновкиСАвтофиксациейСтрок(ТабличныйДокумент, ПроцессорКомпоновкиДанных, ДанныеРасшифровки.Элементы,,,КоличествоФиксируемыхСтолбцов);

	

	ДополнительнаяОбработкаРезультатаОтчета(ТабличныйДокумент);

	

	Если ВыводитьЗаголовок Тогда

		// вернем настройки вывода заголовка на место		

		ВосстановитьНастройкиВыводаЗаголовка();

	КонецЕсли;

	

	// восстановим дополнительные настройки

	Для Каждого ЭлементСтруктуры Из КопияДополнительныхНастроек Цикл

		КомпоновщикНастроек.Настройки.ДополнительныеСвойства.Вставить(ЭлементСтруктуры.Ключ, ЭлементСтруктуры.Значение);

	КонецЦикла;

	

	// сохраненные настройки нужны только при расшифровке и т.п.

	// и не будуть давать изменить вывоз заголовка при обычном формировании.

	ОчиститьСохраненныеНастройкиВыводаЗаголовка();





	УстановитьВидимостьЗаголовкаОтчета(ТабличныйДокумент);

	УстановитьВидимостьПараметровОтчета(ТабличныйДокумент);    

    УстановитьПривилегированныйРежим(Ложь);

КонецПроцедуры // СформироватьОтчет()

Категория: Схема Компоновки Данных

Объединение 2 таблиц значений

Код 1C v 8.х

 // Объединить 2 таблицы значения

// тзОсновная - таблица к которой будут изменяться данные

// тзПрисоединяемая - таблица из которой будут браться данные

// стОтборОдинаковых - стурктура со списком полей по которым определяеться одинаковость записи

// ДобавлятьНеНайденное  - ИСТИНА => не сущесвующие записи в тзОсновная будут браться из тзПрисоединяемая

Процедура ОбъединитьТаблицыЗначений(тзОсновная,тзПрисоединяемая, стОтборОдинаковых, ДобавлятьНеНайденное = Ложь) Экспорт

    Для каждого текПрисоединяемаяЗапись из тзПрисоединяемая цикл

        ЗаполнитьЗначенияСвойств(стОтборОдинаковых,текПрисоединяемаяЗапись);

        НайденыеСтроки = тзОсновная.НайтиСтроки(стОтборОдинаковых);

        Если НайденыеСтроки.Количество() > 0 тогда

            Для каждого текНайденная из НайденыеСтроки цикл

                ЗаполнитьЗначенияСвойств(текНайденная,текПрисоединяемаяЗапись);

            КонецЦикла;

        ИначеЕсли ДобавлятьНеНайденное тогда

            НовСтрокаОсновном = тзОсновная.Добавить();

            ЗаполнитьЗначенияСвойств(НовСтрокаОсновном,текПрисоединяемаяЗапись);

        КонецЕсли;

    КонецЦикла;

КонецПроцедуры

Категория: Работа с Таблицей Значений

Набор функций для работы с разделителями в строке

Код 1C v 8.х

 // Функция разбивает строку разделителем.

// 

// Параметры:

//  пСтрока      - Строка - которую разбиваем;

//  *пРазделитель - Строка, "." - символ-разделитель;

//  *ОбрезатьНепечатныеСимволы - Булево, *Ложь.

//

// Возвращаемое значение:

//  Массив - фрагментов.

//

Функция ПолучитьМассивИзСтрокиСРазделителем(Знач Стр, Разделитель = ".", ОбрезатьНепечатныеСимволы = Ложь) Экспорт

	

	МассивСтрок = Новый Массив;

	

	Если Разделитель = " " Тогда

		Стр = СокрЛП(Стр);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = СокрЛ(Сред(Стр,Поз));

		КонецЦикла;

	Иначе

		ДлинаРазделителя = СтрДлина(Разделитель);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				Фрагмент = Стр;

				Если ОбрезатьНепечатныеСимволы Тогда

					Фрагмент = СокрЛП(Фрагмент);

				КонецЕсли;

				МассивСтрок.Добавить(Фрагмент);

				Возврат МассивСтрок;

			КонецЕсли;

			Фрагмент = Лев(Стр,Поз-1);

			Если ОбрезатьНепечатныеСимволы Тогда

				Фрагмент = СокрЛП(Фрагмент);

			КонецЕсли;

			МассивСтрок.Добавить(Фрагмент);

			Стр = Сред(Стр,Поз+ДлинаРазделителя);

		КонецЦикла;

	КонецЕсли;



	Возврат МассивСтрок;

		

КонецФункции // ПолучитьМассивИзСтрокиСРазделителем()



// Функция собирает строку из элементов массива с разделителем.

// 

// Параметры:

//  пМассив      - Массив - из которого формируем строку;

//  *пРазделитель - Строка - символ-разделитель.

//

// Возвращаемое значение:

//  Строка.

//

Функция ПолучитьСтрокуСРазделителемИзМассива(пМассив, пРазделитель = ", ") Экспорт

	

	Результат = "";

	Для Каждого Элемент Из пМассив Цикл

		Результат = Результат + пРазделитель + Строка(Элемент);

	КонецЦикла;

	Возврат Сред(Результат, СтрДлина(пРазделитель) + 1);

		

КонецФункции // ПолучитьСтрокуСРазделителемИзМассива()



// Получает первый фрагмент, отделяемый разделителем от строки.

// Написана для оптимизации по скорости.

// 

// Параметры:

//  пСтрока      - Строка - которую разбиваем;

//  *пРазделитель - Строка, "." - символ-разделитель;

//  *пЛиИспользоватьГраницуЕслиМаркерНеНайден - Булево, *Истина.

//

// Возвращаемое значение:

//               - Строка - первый фрагмент строки;

//  Неопределено - в строке не обнаружен разделитель.

//

Функция ПолучитьПервыйФрагмент(пСтрока, пРазделитель = ".",

	пЛиИспользоватьГраницуЕслиМаркерНеНайден = Истина) Экспорт



	Позиция = Найти(пСтрока, пРазделитель);

	Если Позиция > 0 Тогда

		Возврат Лев(пСтрока, Позиция - 1);

	Иначе

		Если пЛиИспользоватьГраницуЕслиМаркерНеНайден Тогда 

			Возврат пСтрока;

		Иначе

			Возврат пСтрока;

		КонецЕсли;

	КонецЕсли;



КонецФункции // ПолучитьПервыйФрагмент()

                                                           

// Получает последний фрагмент, отделяемый разделителем от строки.

//

// Параметры:

//  пСтрока      - Строка - в которой ищем;

//  *пМаркер     – Строка, "." – отсекающий маркер;

//  *пЛиИспользоватьГраницуЕслиМаркерНеНайден - Булево, *Истина - разрешение использования границ строки

//               в случае, если маркер не найден.

//

// Возвращаемое значение:

//  Неопределено - маркер не найден;

//               – Число – позиция маркера.

//

Функция ПолучитьПоследнийФрагмент(пСтрока, пМаркер = ".",

	пЛиИспользоватьГраницуЕслиМаркерНеНайден = Истина) Экспорт



	Подстрока = пСтрока;

	МаркерНайден = Ложь;

	Пока пМаркер <> "" Цикл

		Позиция = Найти(Подстрока, пМаркер);

		Если Позиция = 0 Тогда 

			Прервать;

		КонецЕсли;

		МаркерНайден = Истина;

		Подстрока = Сред(Подстрока, Позиция + СтрДлина(пМаркер));

	КонецЦикла;

	Если Истина

		И Не МаркерНайден

		И пЛиИспользоватьГраницуЕслиМаркерНеНайден

	Тогда

		Возврат пСтрока;

	ИначеЕсли МаркерНайден Тогда 

		Возврат Подстрока;

	Иначе

		Возврат "";

	КонецЕсли;

	

КонецФункции // ПолучитьПоследнийФрагмент()



// Получает подстроку заключенную между первым вхождением начального маркера и первым вхождением 

// в правой части конечного маркера. Сами маркеры не включаются в результат. Опционально - если

// маркер не найден, то границей считается граница строки.

//

// Параметры:

//  пСтрока      - Строка - в которой ищем;

//  *пНачальныйМаркер - Строка, *Неопределено - начальный маркер подстроки;

//  *пКонечныйМаркер - Строка, *Неопределено - конечный маркер подстроки;

//  *пЛиИспользоватьГраницуЕслиМаркерНеНайден - Булево, *Истина - разрешение использования границ строки

//               в случае, если маркер не найден;

//  *пЛиВключатьМаркеры - Булево, *Ложь - включение маркеров в результат.

//

// Возвращаемое значение:

//  Неопределено - обязательные условия не выполнены;

//  Строка – найденная подстрока.

//

Функция ПолучитьСтрокуМеждуМаркерами(пСтрока, пНачальныйМаркер = Неопределено, пКонечныйМаркер = Неопределено,

	пЛиИспользоватьГраницуЕслиМаркерНеНайден = Истина, пЛиВключатьМаркеры = Ложь) Экспорт



	ПозицияНачальногоМаркера = Найти(пСтрока, пНачальныйМаркер);

	Если Истина

		И ПозицияНачальногоМаркера = 0

		И пЛиИспользоватьГраницуЕслиМаркерНеНайден = Ложь

	Тогда

		Возврат Неопределено;

	КонецЕсли;

	Если Ложь

		ИЛИ пНачальныйМаркер = Неопределено

		ИЛИ ПозицияНачальногоМаркера = 0 

	Тогда

		ПозицияНачальногоМаркера = - СтрДлина(пНачальныйМаркер);

	КонецЕсли;

	Стр = Сред(пСтрока, ПозицияНачальногоМаркера + СтрДлина(пНачальныйМаркер));

	ПозицияКонечногоМаркера  = Найти(Стр, пКонечныйМаркер);

	Если Истина

		И ПозицияКонечногоМаркера = 0

		И пЛиИспользоватьГраницуЕслиМаркерНеНайден = Ложь

	Тогда

		Возврат Неопределено;

	КонецЕсли;

	Если Ложь

		ИЛИ пКонечныйМаркер = Неопределено

		ИЛИ ПозицияКонечногоМаркера = 0 

	Тогда

		ПозицияКонечногоМаркера = СтрДлина(Стр) + 1;

	КонецЕсли;

	Результат = Лев(Стр, ПозицияКонечногоМаркера - 1);

	Если пЛиВключатьМаркеры Тогда

		Если пНачальныйМаркер <> Неопределено Тогда

			Результат = пНачальныйМаркер + Результат;

		КонецЕсли; 

		Если пКонечныйМаркер <> Неопределено Тогда

			Результат = Результат + пКонечныйМаркер;

		КонецЕсли; 

	КонецЕсли;

	Возврат Результат;

	

КонецФункции // ПолучитьСтрокуМеждуМаркерами()

Категория: Работа с Текстом (Строкой)

Ускорение поиска в таблице значений - Индексы Категория: Работа с Таблицей Значений

Как вывести все зарегистрированные в текущем периоде расчеты (объект, ВР и результат) Сотрудников Категория: Журналы расчетов

Загрузка данных в 1С из FoxPro

Deggy пишет:
Так сейчас так веду импорт из FoxPro-шных таблиц в восьмерку. Вот например заполнение справочника стран:

Код 1C v 8.х

 НачатьТранзакцию();

	стрПодключения = "Driver={Microsoft Visual FoxPro Driver};

	|SourceType=DBF;SourceDB=\\192.168.***.***\server\baza\;

	|Exclusive=No; Collate=Machine;NULL=NO;DELETED=YES;BACKGROUNDFETCH=NO;";

	Connect = Новый COMОбъект("ADODB.Connection");

	попытка

		Connect.Open(стрПодключения);

	исключение

		сообщить(ОписаниеОшибки());

		Отказ=Истина;

		Возврат;

	КонецПопытки;

	RS = Новый COMОбъект("ADODB.RecordSet");

	RS.Open("Select * from country where !deleted()",Connect);

	пока RS.EOF()=0  цикл

		Если Число(RS.Fields("cntry_code").Value)>0 тогда

			РезультатПоиска = Справочники.КлассификаторСтранМира.НайтиПоКоду(Число(RS.Fields("cntry_code").Value));	 

			Если РезультатПоиска.Пустая() Тогда

				НоваяСтрана = Справочники.КлассификаторСтранМира.СоздатьЭлемент();	

				НоваяСтрана.Код =Число(RS.Fields("cntry_code").Value);

				НоваяСтрана.Наименование = СокрЛП(RS.Fields("cntry_name").Value);

				НоваяСтрана.Записать();

			Иначе

				НайденнаяСтрана=РезультатПоиска.ПолучитьОбъект();

				НайденнаяСтрана.Наименование=СокрЛП(RS.Fields("cntry_name").Value);

				НайденнаяСтрана.Записать();

				Сообщить("Страна с кодом "+ СокрЛП(RS.Fields("cntry_code").Value)+ "уже существует");

			конецесли;

		КонецЕсли;

		сообщить("-------------------");

		Сообщить(СокрЛП(RS.Fields("cntry_code").Value)+"  " + СокрЛП(RS.Fields("cntry_name").Value));	

		RS.MoveNext();

	КонецЦикла;

	RS.Close();

	Connect.Close();

	ЗафиксироватьТранзакцию();

Категория: Конвертация данных, Обмен, Перенос

Найти значение в Таблице Значений Категория: Работа с Таблицей Значений