почте » Поиск

Результаты по ключевому слову: почте

Отправка почты через Mail.ru с использованием технологии шифрования SSL

Часто клиенты просят сделать автоматическую отправку счетов или отчетов на электронную почту, ниже приведены примеры кода для разных версий 1С:

Код 1C v 8.3

 

//Код для обычного приложения, для управляемого приложения отправка почты так же, только с файлами и предупреждение нужно изменить код

Функция ПолучитьПрофильПочты()

	//Создаем профиль либо считываем из справочника 

	Профиль = Новый ИнтернетПочтовыйПрофиль; 

	Профиль.АдресСервераSMTP = "smtp.mail.ru";//Отправитель.АдресСервераSMTP; //"smtp.mail.ru"; 

	Профиль.АдресСервераPOP3 = "pop.mail.ru"; //Отправитель.АдресСервераPOP3; //"pop.mail.ru"; 

	Профиль.ПортPOP3 = 995;//Отправитель.ПортPOP3; //110;

	Профиль.ПортSMTP = 465;//Отправитель.ПортSMTP; //587; 

	Профиль.Пользователь = "s_v@inbox.ru";// Отправитель.Email; //"test@mail.ru"; 

	Профиль.Пароль = "8mFTnDjC4KftTzh"; //Отправитель.Пароль; //"123456789"; 

	Профиль.ПользовательSMTP =  "s_v@inbox.ru";//Отправитель.Email; //"test@mail.ru"; 

	Профиль.ПарольSMTP = "8mFTnDjC4KftTzh";//Отправитель.Пароль; //"123456789"; 

	Профиль.АутентификацияSMTP = СпособSMTPАутентификации.Login;

	Профиль.ИспользоватьSSLPOP3 = Истина;

	Профиль.ИспользоватьSSLSMTP = Истина;  

	//Создаем письмо 

Возврат Профиль;

КонецФункции 





Процедура ОсновныеДействияФормыСчетОтправитьНаПочту(Кнопка)

	Если ЗначениеЗаполнено(Ответственный.ПочтаДляОтправкиСчета) Тогда

		Почта = Новый ИнтернетПочта; 

		Письмо = Новый ИнтернетПочтовоеСообщение; 

		Текст = Письмо.Тексты.Добавить("В приложении счет"); 

		Текст.ТипТекста = ТипТекстаПочтовогоСообщения.ПростойТекст;

		Письмо.Тема = Строка(Ссылка); 

		Письмо.Отправитель = "s_vmeste@inbox.ru"; 

		Письмо.ИмяОтправителя = "1С";

		Письмо.Получатели.Добавить(Ответственный.ПочтаДляОтправкиСчета);



		врфайл=ПолучитьИмяВременногоФайла("pdf");

		текТабдок=СчетФаксимилеТовары(); //Функция возвращает табличный документ печать счета

		текТабдок.Записать(врфайл,ТипФайлаТабличногоДокумента.PDF);



		Письмо.Вложения.Добавить(врфайл);

		//добавляем вложение если нужно, например "C:\Приложение.doc" 

		//Вложений можно добавлять сколько требуется. 

		//Отправляем письмо

		Попытка 

			Почта.Подключиться(ПолучитьПрофильПочты()); Почта.Послать(Письмо); Предупреждение("Письмо отправлено",3);

		Исключение 

			Сообщить(ОписаниеОшибки());

		КонецПопытки;

		//Закрываем письмо

		Почта.Отключиться(); 

		//Закрываем файл вложения

		Письмо.Вложения.Очистить();

	Иначе

		Предупреждение("В настройках ответственного не указана почта для отправки счета");

	КонецЕсли;

КонецПроцедуры

С версиями 8.2 сложнее, так как все почтовые сервисы перешли на SSL, а медоты:

Код 1C v 8.3

 Профиль.ИспользоватьSSLPOP3 = Истина;

	Профиль.ИспользоватьSSLSMTP = Истина;

появились только в 8.3.1 , остается использовать stunnel или CDO:

Код 1C v 8.2 УП

 //Отправка через CDO, Адрессаты через ";"

Функция ПослатьПоПочте(Знач Адрессаты, ТемаСообщения = "",ТекстСообщения = "" ,СписокВложений = "")Экспорт



    Оправитель         = "s_v@inbox.ru";

    Пароль             = "8mFTnDjC4KftTzh";



    loConfig         = Новый COMОбъект("CDO.Configuration");

    loCdoMessage     = Новый COMОбъект("CDO.Message");

    loCdoMessage.Configuration = loConfig;

    loCdoMessage.From    = Строка("1С <"+Оправитель+">");  //loCdoMessage.From    = "Тест 1C"""" <xxxxxxx@yandex.ru>";

    loCdoMessage.To      = Адрессаты; //loCdoMessage.To      = "xxxxxxx@gmail.ru>";

    loCdoMessage.Subject = ?(ТемаСообщения="","1С",ТемаСообщения);

    loCdoMessage.TextBody = "1C";

     HTMLBody = "<html>

    |<head>

    |<meta content=""text/html; charset=Windows-1251"" http-equiv=""content-type"">

    |<title> Тестовое сообщение </title>

    |</head>

    |<body>

    |<h4>" + ТекстСообщения + "</h4>

    |<p></p>

    |</body>

    |</html>";

    //loCdoMessage.BodyPart.Charset = "windows-1251"; 

    loCdoMessage.HTMLBody = HTMLBody;



    Если ТипЗнч(СписокВложений) = Тип("Строка") И Не СписокВложений = "" Тогда

        Попытка

            loCdoMessage.AddAttachment(СписокВложений);

        Исключение

        КонецПопытки;

    ИначеЕсли ТипЗнч(СписокВложений) = Тип("СписокЗначений") Тогда

        Для каждого ПутьКВложению Из СписокВложений Цикл

            Попытка

                loCdoMessage.AddAttachment(ПутьКВложению.Значение);

            Исключение

            КонецПопытки;

        КонецЦикла;

    КонецЕсли;

   loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing").            Value = 2;

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver").           Value = "smtp.mail.ru";

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport").       Value = "465";

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate").     Value = 1;

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername").         Value = Оправитель;

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword").         Value = Пароль;

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl").           Value = 1;

    loConfig.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout").Value = 60;



    loConfig.Fields.Update();   

    Попытка

        loCdoMessage.Send();

    Исключение

        Сообщить(ОписаниеОшибки());

        Возврат Ложь;

    КонецПопытки;



КонецФункции



Процедура ОсновныеДействияФормыСчетТовары(Кнопка)

	Если ЗначениеЗаполнено(Менеджер.ПочтаДляОтправкиСчета) Тогда

		

		врфайл=ПолучитьИмяВременногоФайла("xls");

		текТабдок=СчетФаксимилеТовары();

		текТабдок.Записать(врфайл,ТипФайлаТабличногоДокумента.XLS);

		ПослатьПоПочте(Менеджер.ПочтаДляОтправкиСчета,Строка(Ссылка),"Счет в приложении",врфайл);

		

		Предупреждение("Письмо отправлено",3);		

	Иначе

		Предупреждение("В настройках ответственного не указана почта для отправки счета");

	КонецЕсли;

КонецПроцедуры

Через stunnel в 1С код, менять не нужно, только установить программу и изменить настройки подключения к почтовому ящику

Скачиваем stunnel c официального сайта (stunnel.org) и запускаем инсталятор, жмем yes при установке спросит страну и ваши данные, это нужно для создания сертификата на вашем компьютере.

После запуска в трее появится его иконка, правой клавишей и редактировать edit configuration

В блокноте откроется файл настроек, там будет пример для gmail дополняем или заменяем его следующим:

Код Batch File (DOS, CMD, BAT)

 [gmail-pop3]

client = yes

accept = 127.0.0.1:10110

connect = pop.gmail.com:995

[gmail-imap]

client = yes

accept = 127.0.0.1:10143

connect = imap.gmail.com:993

[gmail-smtp]

client = yes

accept = 127.0.0.1:10025

connect = smtp.gmail.com:465

[yandex-pop3]

client = yes

accept = 127.0.0.1:20110

connect = pop.yandex.ru:995

[yandex-imap]

client = yes

accept = 127.0.0.1:20143

connect = imap.yandex.ru:993

[yandex-smtp]

client = yes

accept = 127.0.0.1:20025

connect = smtp.yandex.ru:465

[mail-pop3]

client = yes

accept = 127.0.0.1:30110

connect = pop.mail.ru:995

[mail-imap]

client = yes

accept = 127.0.0.1:30143

connect = imap.mail.ru:993

[mail-smtp]

client = yes

accept = 127.0.0.1:30025

connect = smtp.mail.ru:465

Сохраняем файл и делаем Reload configuration

В настройка 1С меняем порты для работы

gmail

pop3 10110

imap 10143

smtp 10025

yandex

pop3 20110

imap 20143

smtp 20025

mail

pop3 30110

imap 30143

smtp 30025

Если в коде прописано, то:

Код 1C v 8.х

 Функция ПолучитьПрофильПочты()

	//Создаем профиль либо считываем из справочника 

	Профиль = Новый ИнтернетПочтовыйПрофиль; 

	Профиль.АдресСервераSMTP = "localhost";//"smtp.mail.ru";//Отправитель.АдресСервераSMTP; //"smtp.mail.ru"; 

	Профиль.АдресСервераPOP3 = "localhost";//"pop.mail.ru"; //Отправитель.АдресСервераPOP3; //"pop.mail.ru"; 

	Профиль.ПортPOP3 = 30110;//Отправитель.ПортPOP3; //110;  995

	Профиль.ПортSMTP = 30025;//Отправитель.ПортSMTP; //587; 465

	Профиль.Пользователь = "s_v@inbox.ru";// Отправитель.Email; //"test@mail.ru"; 

	Профиль.Пароль = "8mFTnDjC4KftTzh"; //Отправитель.Пароль; //"123456789"; 

	Профиль.ПользовательSMTP =  "s_v@inbox.ru";//Отправитель.Email; //"test@mail.ru"; 

	Профиль.ПарольSMTP = "8mFTnDjC4KftTzh";//Отправитель.Пароль; //"123456789"; 

	Профиль.АутентификацияSMTP = СпособSMTPАутентификации.Login;

	//Профиль.ИспользоватьSSLPOP3 = Истина;

	//Профиль.ИспользоватьSSLSMTP = Истина;  

	//Создаем письмо 

Возврат Профиль;

КонецФункции

Все, можно отправлять и проверять работу через консоль Show log window в меню

P.S. Почтовый ящик в примерах не рабочий, как пример

Категория: Работа с Интернет, Почтой (Mail), FTP

SMTP greeting failure: 421 SMTP connection broken (reply)

Описание ошибки:С сентября 2014 Яндекс.Почта, Mail.ru перешли на протокол SSL, что сделало их ещё более безопасными. Чтобы и дальше работать с письмами через 1С, Вам нужно изменить их настройки и внести доработки в код конфигураций.

Найденные решения:

Ошибка наблюдается, в частности, в случае, когда меняются настройки почты. Например мне довелось столкнуться в случае, когда ввели для почты SSL-шифрование. Если это Ваш случай, то из быстрых и простых остается только обновление до версии платформы 8.3, где поддержка этого шифрования для "ИнтернетПочтовыйПрофиль" реализована. И доработка кода типовых конфигураций для учета настроек SSL-шифрования и включения у почтового профиля.

Код 1C v 8.х

 ИнтернетПочтовыйПрофиль.ИспользоватьSSLPOP3 = Истина;ИнтернетПочтовыйПрофиль.ИспользоватьSSLSMTP = Истина;

Сопровождающие проблему ошибки:

Яндекс.Почта

адрес_почты@yandex.ru. {ОбщийМодуль.УправлениеЭлектроннойПочтой.Модуль(1065)}: Ошибка при вызове метода контекста (Подключиться): Почтовый ящик пользователя "адрес_почты@yandex.ru" на сервере "pop.yandex.ru" не найден. Ответ сервера: "[AUTH] Working without SSL/TLS encryption is not allowed. Please visit https://help.yandex.ru/mail/mail-clients/ssl.xml. sc=NXhLmqHbM4YK"

Если установлены не правильные порты, то получим ошибку:Ошибка при вызове метода контекста (Подключиться): TLS/SSL failure for smtp.mail.ru: Invalid token, probably not an SSL serverУстановите порты 465 для smtp, 995 для pop3.

При соединении с Яндексом: в логинах оставить только содержимое логина до @yandex.ru, т.е. из примера "адрес_почты" (без кавычек). Устанавливаем для pop3 и smtp SSL-шифрование. Если почта корпоративная на Яндексе, и в наименовании не используется @yandex.ru, то оставляем логин, равный наименованию почты, как есть.

Mail.ru

Не включено SSL-шифрование для учетной записи электронной почты. Ошибка при вызове метода контекста (Подключиться): Can not authenticate to POP3 server: POP3 is available only with SSL or TLS connection enabled

Если установлены не правильные порты, то получим ошибку:Ошибка при вызове метода контекста (Подключиться): TLS/SSL failure for smtp.mail.ru: Invalid token, probably not an SSL serverУстанавливаем порты 465 для smtp, 995 для pop3.

Если возникает ошибка:Ошибка при вызове метода контекста (Подключиться): Can't connect to smtp.mail.ru,495: Timed out - значит неправильно указан порт.

Если возникает ошибка:Ошибка при вызове метода контекста (Подключиться): SMTP greeting failure: 421 SMTP connection broken (reply)Порты настроены правильно, не установлено SSL-шифрование для smtp.

В паролях для почты не использовать спецсимволы, пример из опыта: в пароле к почте был символ "+", пока из пароля не убрали, соединение не происходило! Система выдавала ошибку: Ошибка при вызове метода контекста (Подключиться): Can not authenticate to SMTP server: 535 5.7.8 Error: authentication failed: Invalid user or password!

Разработчики 1С вносят фунционал в рабочие конфигурации, например: УТ 10.3.30.1 от 26.09.2014, описание обновления: В справочник "Учетные записи электронной почты" добавлены реквизиты "Использовать защищенную версию протокола SMTP" и "Использовать защищенную версию протокола POP3". При установке этих реквизитов предоставляется возможность подключаться к почтовым серверам через безопасное соединение (SSL). Реквизиты доступны при использовании версии платформы не ниже 8.3.1.

P.S.: Возможно еще использование дополнительной программы stunnel. Но мне этот вариант меньше понравился. Т.к. клиенту не хотелось зависеть от программиста каждый раз, когда появляется новая почта или рабочее место, а чтобы сразу можно было из 1С настроить, как и раньше.

Журавлев А.С. (Сайт www.azhur-c.ru)

Категория: Системные Ошибки

Не работает настройка панелей в 1С Такси Категория: 1С Общие вопросы - Управляемые формы и Такс…

Функции для работы с ZIP-архивами

В работе часто приходится сжимать выгруженные данные в zip архив, отправлять по почте, и потом автоматически разархивировать полученный zip файл:

Код 1C v 8.х

 // Распаковывает файл архива ZIP в указанный каталог; Извлекает все файлы архива

//

// Параметры:

//  ПолноеИмяФайлаАрхива  - Строка - имя файла архива, который необходимо распаковать

//  ПутьРаспаковкиФайлов  - Строка - путь по которому необходимо распаковать файлы

//  ПарольАрхива          - Строка - пароль для распаковки архива. По умолчанию пустая строка

// 

// Возвращаемое значение:

//  Результат - Булево - Истина, если успешно, Ложь, если нет.

//

Функция РаспаковатьZipФайл(Знач ПолноеИмяФайлаАрхива, Знач ПутьРаспаковкиФайлов, Знач ПарольАрхива = "") Экспорт

	

	// возвращаемое значение функции

	Результат = Истина;

	

	Попытка

		

		Архиватор = Новый ЧтениеZipФайла(ПолноеИмяФайлаАрхива, ПарольАрхива);

		

	Исключение

		Архиватор = Неопределено;

		СообщитьОбОшибке(КраткоеПредставлениеОшибки(ИнформацияОбОшибке()));

		Возврат Ложь;

	КонецПопытки;

	

	Попытка

		

		Архиватор.ИзвлечьВсе(ПутьРаспаковкиФайлов, РежимВосстановленияПутейФайловZIP.НеВосстанавливать);

		

	Исключение

		

		СтрокаСообщения = НСтр("ru = 'Ошибка при распаковке файлов архива: %1 в каталог: %2'");

		СтрокаСообщения = ПодставитьПараметрыВСтроку(СтрокаСообщения, ПолноеИмяФайлаАрхива, ПутьРаспаковкиФайлов);

		Сообщить(СтрокаСообщения);

		

		Результат = Ложь;

	КонецПопытки;

	

	Архиватор.Закрыть();

	Архиватор = Неопределено;

	

	Возврат Результат;

	

КонецФункции





// Запаковывает указанный каталог в файл архива ZIP

//

// Параметры:

//  ПолноеИмяФайлаАрхива  - Строка - имя файла архива, в который необходимо запаковать

//  МаскаУпаковкиФайлов    - Строка - имя файла, помещаемого в архив, или маска.

//			Недопустимо использование в именах файлов и папок букв национальных алфавитов, которые при 

//			преобразовании из символов UNICODE в узкие символы могут быть преобразованы с потерей информации. 

//			Рекомендуется использовать в именах файлов и папок символы латинского алфавита. 

//  ПарольАрхива          - Строка - пароль для архива. По умолчанию пустая строка

// 

// Возвращаемое значение:

//  Результат - Булево - Истина, если успешно, Ложь, если нет.

//

Функция ЗапаковатьВZipФайл(Знач ПолноеИмяФайлаАрхива, Знач МаскаУпаковкиФайлов, Знач ПарольАрхива = "") Экспорт

	

	// возвращаемое значение функции

	Результат = Истина;

	

	Попытка

		

		Архиватор = Новый ЗаписьZipФайла(ПолноеИмяФайлаАрхива, ПарольАрхива);

		

	Исключение

		Архиватор = Неопределено;

		СообщитьОбОшибке(КраткоеПредставлениеОшибки(ИнформацияОбОшибке()));

		Возврат Ложь;

	КонецПопытки;

	

	Попытка

		

		Архиватор.Добавить(МаскаУпаковкиФайлов, РежимСохраненияПутейZIP.НеСохранятьПути);

		Архиватор.Записать();

		

	Исключение

		

		СтрокаСообщения = НСтр("ru = 'Ошибка при запаковке файлов архива: %1 из каталог: %2'");

		СтрокаСообщения = ПодставитьПараметрыВСтроку(СтрокаСообщения, ПолноеИмяФайлаАрхива, МаскаУпаковкиФайлов);

		Сообщить(СтрокаСообщения);

		

		Результат = Ложь;

	КонецПопытки;

	

	Архиватор = Неопределено;

	

	Возврат Результат;

	

КонецФункции

В примере используется строковая функция ПодставитьПараметрыВСтроку():

Код 1C v 8.х

 // Подставляет параметры в строку. Максимально возможное число параметров - 9.

// Параметры в строке задаются как %<номер параметра>. Нумерация параметров начинается с единицы.

//

// Параметры:

//  СтрокаПодстановки  – Строка – шаблон строки с параметрами (вхождениями вида "%ИмяПараметра");

//  Параметр<n>        - Строка - подставляемый параметр.

//

// Возвращаемое значение:

//  Строка   – текстовая строка с подставленными параметрами.

//

// Пример:

//  ПодставитьПараметрыВСтроку(НСтр("ru='%1 пошел в %2'"), "Вася", "Зоопарк") = "Вася пошел в Зоопарк".

//

Функция ПодставитьПараметрыВСтроку(Знач СтрокаПодстановки,

	Знач Параметр1,	Знач Параметр2 = Неопределено, Знач Параметр3 = Неопределено,

	Знач Параметр4 = Неопределено, Знач Параметр5 = Неопределено, Знач Параметр6 = Неопределено,

	Знач Параметр7 = Неопределено, Знач Параметр8 = Неопределено, Знач Параметр9 = Неопределено) Экспорт

	

	Если СтрокаПодстановки = Неопределено ИЛИ СтрДлина(СтрокаПодстановки) = 0 Тогда

		Возврат "";

	КонецЕсли;

	

	Результат = "";

	НачПозиция = 1;

	Позиция = 1;

	Пока Позиция <= СтрДлина(СтрокаПодстановки) Цикл

		СимволСтроки = Сред(СтрокаПодстановки, Позиция, 1);

		Если СимволСтроки <> "%" Тогда

			Позиция = Позиция + 1;

			Продолжить;

		КонецЕсли;

		Результат = Результат + Сред(СтрокаПодстановки, НачПозиция, Позиция - НачПозиция);

		Позиция = Позиция + 1;

		СимволСтроки = Сред(СтрокаПодстановки, Позиция, 1);

		

		Если СимволСтроки = "%" Тогда

			Позиция = Позиция + 1;

			НачПозиция = Позиция;

			Результат = Результат + "%";

			Продолжить;

		КонецЕсли;

		

		Попытка

			НомерПараметра = Число(СимволСтроки);

		Исключение

			ВызватьИсключение НСтр("ru='Входная строка СтрокаПодстановки имеет неверный формат: %'" + СимволСтроки);

		КонецПопытки;

		

		Если СимволСтроки = "1" Тогда

			ЗначениеПараметра = Параметр1;

		ИначеЕсли СимволСтроки = "2" Тогда

			ЗначениеПараметра = Параметр2;

		ИначеЕсли СимволСтроки = "3" Тогда

			ЗначениеПараметра = Параметр3;

		ИначеЕсли СимволСтроки = "4" Тогда

			ЗначениеПараметра = Параметр4;

		ИначеЕсли СимволСтроки = "5" Тогда

			ЗначениеПараметра = Параметр5;

		ИначеЕсли СимволСтроки = "6" Тогда

			ЗначениеПараметра = Параметр6;

		ИначеЕсли СимволСтроки = "7" Тогда

			ЗначениеПараметра = Параметр7;

		ИначеЕсли СимволСтроки = "8" Тогда

			ЗначениеПараметра = Параметр8;

		ИначеЕсли СимволСтроки = "9" Тогда

			ЗначениеПараметра = Параметр9;

		Иначе

			ВызватьИсключение НСтр("ru='Входная строка СтрокаПодстановки имеет неверный формат: %'" + ЗначениеПараметра);

		КонецЕсли;

		Если ЗначениеПараметра = Неопределено Тогда

			ЗначениеПараметра = "";

		Иначе

			ЗначениеПараметра = Строка(ЗначениеПараметра);

		КонецЕсли;

		Результат = Результат + ЗначениеПараметра;

		Позиция = Позиция + 1;

		НачПозиция = Позиция;

	

	КонецЦикла;

	

	Если (НачПозиция <= СтрДлина(СтрокаПодстановки)) Тогда

		Результат = Результат + Сред(СтрокаПодстановки, НачПозиция, СтрДлина(СтрокаПодстановки) - НачПозиция + 1);

	КонецЕсли;

	

	Возврат Результат;

	

КонецФункции

Категория: Работа с Файлами и Каталогами

Отправка отчетов из 1С по электронной почте (E-Mail) Категория: Работа с Интернет, Почтой (Mail), FTP

Работа с Почтой в 1С: Предприятие v 8 Категория: Работа с Интернет, Почтой (Mail), FTP

Руководство компании, хочет получать оперативную сводку продаж по фирме

Руководство компании, хочет получать оперативную сводку продаж по фирме на свой почтовый ящик с обратной связью. То есть, посылая письмо на определенный ящик, программа составляет отчет о продажах на текущий день и отсылает на ящик отправителя.

Технический аспект реализации. на почтовом сервере компании заводим ящик autoreport.xxx.ru , в глобальный модуль в предопределенную процедуру ПриНачалеРаботыСистемы вставляем проверку строки запуска 1С для того, что бы определить момент старта проверки поступления новых писем в ящик.

Код 1C v 8.х

 

Процедура ПриНачалеРаботыСистемы() 

Если Найти(ПараметрЗапуска,"changemail")>0 Тогда 

Форма = Обработки.SaletoMail.ПолучитьФорму(); 

Форма.ОтсылкаПоЗаказу(); 

ЗавершитьРаботуСистемы(Ложь); 

конецЕсли; 

КонецПроцедуры

В планировщик задач вписываем запуск 1С Предприятия в “C:\Program Files\1cv8\bin\1cv8.exe” enterprise /DisableStartupMessages /smain\demo /cchangemail и ставим запуск каждые 5 минут. После запуска 1С проверяет переданный параметр если он подходит то происходит вызов внешней обработки в которой формируется отчет и происходит передача отчета обратно на ящик отправителя. Во внешнюю обработку писем процедуру ОтсылкаПоЗаказу() которая проверяет ящик на наличие писем, делает минимальную проверку , но то, что письмо пришло из нашего почтового сервера и отсылает продажи на адрес отправителя.

Код 1C v 8.х

 

Процедура ОтсылкаПоЗаказу() 

Профиль = Новый ИнтернетПочтовыйПрофиль; 

Профиль.АдресСервераSMTP = "mail.xxx.ru"; 

Профиль.АдресСервераPOP3 = "mail.xxx.ru"; 

Профиль.ПортSMTP = 25; 

Профиль.ПортPOP3 = 110; 

Профиль.Пользователь = "sale"; 

Профиль.Пароль = "Report"; 

Почта = Новый ИнтернетПочта; 

Почта.Подключиться(Профиль); 

Массив = Новый Массив; Сообщения = Почта.Выбрать(true ,Массив); 

// true для того, что бы очистить обработанные сообщения 

Для КолПисем= 1 По Сообщения.Количество() Цикл 

ТекПисьмо = Сообщения.Получить(КолПисем-1); 

Если (Найти(ТекПисьмо.Отправитель.Адрес,"xxx.ru")>0) and (НРег(ТекПисьмо.Тема)="magicsale") тогда Письмо = Новый ИнтернетПочтовоеСообщение; Письмо.ИмяОтправителя = "sale"; 

Сообщение = Новый ИнтернетПочтовоеСообщение; 

Письмо.Тексты.Добавить("Продажи дня" + ТекущаяДата()); 

Письмо.Получатели.Добавить(""+Сообщения.Получить(КолПисем-1).Отправитель.Адрес); 

// ….. Поскипано 

// ….. Формируем отчет о продажах и сохраняем его во внешний файл , или текст. 

// ….. вкладываем отчет как приатаченный файл или тело сообщения. 

Почта.Послать(Письмо); 

КонецЕсли; 

КонецЦикла; 

Почта.Отключиться(); 

КонецПроцедуры

Отправка отчетов из 1С по электронной почте (E-Mail)

Категория: Полезные, Универсальные Функции

Практическая работа с почтой (E-mail,The Bat, Outlook, Mozilla Thunderbird)

Код 1C v 8.х

 Попытка

    ОтправитьПоПочте2(ТекСтрока); // работает с Батом

Исключение

    Попытка

    ОтправитьПоПочте1(ТекСтрока); // работает с Аутлуком, но переспрашивает при отправке

    Исключение

        Сообщить_и_записать("Ошибка при отправке почты - "+ОписаниеОшибки(),СтатусСообщения.Важное);

    КонецПопытки;

КонецПопытки;



Процедура ОтправитьПоПочте1(ТекСтрока)

    Почта = Новый Почта;

    Сообщение = Новый ПочтовоеСообщение;

    //Работает с Аутглуком, но переспрашивает при отправке

    //не работает с Батом 3.60

    Почта.Подключиться("name@mysite.dp.ua","password");

   

    Сообщение.Вложения.Добавить(ПолучитьИмяФайлаПодразделения(ТекСтрока.филиал.наименование));

    Сообщение.Получатели.Добавить(ТекСтрока.филиал.email);

    Сообщение.Тема ="Проигнорированные документы в офисе. Письмо сгенерированно роботом";

    Сообщение.Текст="Проверьте, будь ласка эти документы ПОСЛЕ получения обновления из офиса. Ваши изменения в этих документах не попали в базу. Откройте прикрепленный файл";

    Почта.Послать(Сообщение);

    Почта.Отключиться();

    УдалитьФайлы(ПолучитьИмяФайлаПодразделения(ТекСтрока.филиал.наименование));

КонецПроцедуры           



Процедура ОтправитьПоПочте2(ТекСтрока)

    ПочтовыйПрофиль = Новый ИнтернетПочтовыйПрофиль;

    ПочтовыйПрофиль.АдресСервераPOP3   = "pop3.mysite.dp.ua";

    ПочтовыйПрофиль.АдресСервераSMTP   = "smtp.mysite.dp.ua";

    ПочтовыйПрофиль.ПортSMTP           = 25;

    ПочтовыйПрофиль.ПортPOP3           = 110;

    ПочтовыйПрофиль.Пользователь       = "name";

    ПочтовыйПрофиль.Пароль             = "password";

    ПочтовыйПрофиль.ВремяОжидания      = 60;

       

    Сообщение = Новый ИнтернетПочтовоеСообщение ;

    Сообщение.Вложения.Добавить(ПолучитьИмяФайлаПодразделения(ТекСтрока.филиал.наименование));

    Сообщение.Получатели.Добавить(ТекСтрока.филиал.email);

    Сообщение.Тема ="Проигнорированные документы в офисе. Письмо сгенерированно роботом";

    Сообщение.ИмяОтправителя="Обмен";

    Сообщение.Отправитель="name@mysite.dp.ua";

       

    Текст = Сообщение.Тексты.Добавить("Проверьте, будь ласка эти документы ПОСЛЕ получения обновления из офиса. Ваши изменения в этих документах не попали в базу. Откройте прикрепленный файл");

    Текст.ТипТекста = ТипТекстаПочтовогоСообщения.ПростойТекст;

   

    Почта = Новый ИнтернетПочта();

    Почта.Подключиться(ПочтовыйПрофиль);

    Почта.Послать(Сообщение);

    Почта.Отключиться();

    УдалитьФайлы(ПолучитьИмяФайлаПодразделения(ТекСтрока.филиал.наименование));

КонецПроцедуры

А вот так 1с работает с Мозилой Сундербердом (который хорошо поддерживает IMAP):

Код 1C v 8.х

  ПутьМозиллы = """C:/Program Files/Mozilla Thunderbird/thunderbird.exe""";

    Текст = Новый ЗаписьТекста(КаталогОбмена + "sendfiletofilial"+Строка(ТекСтрока.филиал.наименование)+".bat", КодировкаТекста.OEM);

    Текст.ЗаписатьСтроку("@echo off");

    Текст.ЗаписатьСтроку("@echo Отправка проигнорированных писем на филиал"+Строка(ТекСтрока.филиал.наименование));

    СтрокаЗапуска = " -compose to='"+ТекСтрока.филиал.email+"',cc='name@mysite.dp.ua',subject=""Проигнорированные документы в офисе. Письмо сгенерированно роботом"",body=""Проигнорированные документы в офисе. Письмо сгенерированно роботом"",attachment=""file://";

    Файл = """"+ПолучитьИмяФайлаПодразделения(ТекСтрока.филиал.наименование)+"""";

    Текст.ЗаписатьСтроку(ПутьМозиллы+СтрокаЗапуска +Файл);

    Текст.ЗаписатьСтроку("del "+Файл);

    Текст.Закрыть();

    ЗапуститьПриложение(КаталогОбмена + "sendfiletofilial"+Строка(ТекСтрока.филиал.наименование)+".bat",КаталогОбмена)

Получение почты

Код 1C v 8.х

 

Процедура КнопкаВыполнитьНажатие(Кнопка)

  Почта = Новый ИнтернетПочта;



    Профиль = Новый ИнтернетПочтовыйПрофиль;

    Профиль.АдресСервераPOP3 = "192.168.0.2";



    Профиль.Пользователь = "romix";

    Профиль.Пароль = "ТутНапишитеПароль";



    Почта.Подключиться(Профиль);



    МассивПисем = Почта.Выбрать(Ложь);



    Для Каждого Письмо из МассивПисем Цикл

        Сообщить("Получено письмо с заголовоком: "+Письмо.Тема);

        Для Каждого Вложение из Письмо.Вложения Цикл

            Сообщить("Вложение: "+Вложение.ИмяФайла);

            Вложение.Данные.Записать("c:\tempdata\"+Вложение.ИмяФайла);

        КонецЦикла;    

        Для Каждого Текст из Письмо.Тексты Цикл

            Сообщить("Текст: "+Текст.Текст);

            Текст.Данные.Записать("c:\tempdata\ТекстСообщения.txt");

        КонецЦикла;    

    КонецЦикла;



КонецПроцедуры

Автор: 1CLama

Категория: Работа с Интернет, Почтой (Mail), FTP

Некоторые полезные настройки при работе с УРИБ. Категория: Администрирование

Ян­декс.Почта

Mail.ru

Яндекс.Почта