представлена » Поиск

Результаты по ключевому слову: представлена

Вывод результата запроса на форму УП в таблицу значений (аналог СоздатьКолонки() для УП)

при разработке на обычных формах было удобно выводить результат запроса используя метод СоздатьКолоки():

Код 1C v 8.х

 Процедура ПоискНажатие(Элемент)

Запрос = Новый Запрос;

Запрос.Текст = 

"ВЫБРАТЬ

|	ДокументоОборот.Этап,

|	ДокументоОборот.Отдел,

|	ДокументоОборот.ФИО,

|	ДокументоОборот.ДатаВремя КАК Дата_Время,

|	ДокументоОборот.Документы,

|	ДокументоОборот.Примечание,

|	ДокументоОборот.Доставка

|ИЗ

|	РегистрСведений.ДокументоОборот КАК ДокументоОборот

|ГДЕ

|	ДокументоОборот.Документы ПОДОБНОДокументы

|	И ДокументоОборот.Доставка.Дата МЕЖДУДатаН ИДатаК

|

|УПОРЯДОЧИТЬ ПО

|	ДокументоОборот.ДатаВремя";  

Запрос.УстановитьПараметр("Документы", "%"+СокрЛП(Строка(СтрокаПоиска))+"%");

Запрос.УстановитьПараметр("ДатаК", КонПериода);

Запрос.УстановитьПараметр("ДатаН", НачПериода);

Рез=Запрос.Выполнить();

НайденДок = рез.Выгрузить();

ЭлементыФормы.НайденДок.СоздатьКолонки();

В управляемом приложении метод СоздатьКолоки() не доступен, ниже представлена процедура, которая отображает на управляемой форме содержимое таблицы значений переданное ей в качестве параметра:

Пример формы:

Код вывода результата запроса на управляемую форму:

Код 1C v 8.2 УП

 &НаСервере

Процедура СоздатьТаблицуФормы(Знач ИмяПоляТаблицыФормы, Знач ИмяРеквизитаДанныеФормыКоллекция, Знач ТаблицаЗначений)

    

    // Если руками не создали эелемент формы Таблица, то создается программно

    Если Элементы.Найти(ИмяПоляТаблицыФормы) = Неопределено Тогда

        ЭлементРеквизита = Элементы.Добавить(ИмяПоляТаблицыФормы, Тип("ТаблицаФормы"),);

        ЭлементРеквизита.ПутьКДанным = ИмяРеквизитаДанныеФормыКоллекция;

    КонецЕсли;

    

    УдаляемыеРеквизиты = Новый Массив;

    РеквизитыДляУдаления = ПолучитьРеквизиты(ИмяРеквизитаДанныеФормыКоллекция);

    Для Каждого РеквизитУдаления Из РеквизитыДляУдаления Цикл

        УдаляемыеРеквизиты.Добавить(ИмяРеквизитаДанныеФормыКоллекция+"."+РеквизитУдаления.Имя);

        // Удаляем элементы формы

        Элементы.Удалить(Элементы[ИмяПоляТаблицыФормы+РеквизитУдаления.Имя]);

    КонецЦикла;

    

    // Добавление реквизитов в таблицу формы

    ДобавляемыеРеквизиты = Новый Массив;

    Для каждого Колонка Из ТаблицаЗначений.Колонки Цикл

        ДобавляемыеРеквизиты.Добавить(Новый РеквизитФормы(Колонка.Имя, Колонка.ТипЗначения, ИмяРеквизитаДанныеФормыКоллекция, Колонка.Заголовок));

    КонецЦикла;

    ИзменитьРеквизиты(ДобавляемыеРеквизиты,УдаляемыеРеквизиты);

    

    

    // Добавление элементов форму

    Для каждого Колонка Из ТаблицаЗначений.Колонки Цикл

        ЭлементРеквизита = Элементы.Добавить(ИмяПоляТаблицыФормы + Колонка.Имя, Тип("ПолеФормы"), Элементы[ИмяПоляТаблицыФормы]);

        ЭлементРеквизита.ПутьКДанным = ИмяРеквизитаДанныеФормыКоллекция + "." + Колонка.Имя;

        ЭлементРеквизита.Вид = ВидПоляФормы.ПолеВвода;

    КонецЦикла;

    

    ЗначениеВРеквизитФормы(ТаблицаЗначений, ИмяРеквизитаДанныеФормыКоллекция);      

КонецПроцедуры





&НаСервере

Процедура ВПоискНаСервере()

	Запрос = Новый Запрос;

	Запрос.Текст = 

	"ВЫБРАТЬ

	|	РеализацияТоваровУслугСерии.Серия КАК Серия,

	|	РеализацияТоваровУслугСерии.Ссылка КАК Реализация,

	|	РеализацияТоваровУслугСерии.Ссылка.ЗаказКлиента КАК ЗаказКлиента,

	|	РеализацияТоваровУслугСерии.Ссылка.Контрагент КАК Контрагент,

	|	РеализацияТоваровУслугСерии.Ссылка.Договор КАК Договор

	|ИЗ

	|	Документ.РеализацияТоваровУслуг.Серии КАК РеализацияТоваровУслугСерии

	|ГДЕ

	|	РеализацияТоваровУслугСерии.Серия В

	|			(ВЫБРАТЬ

	|				СерииНоменклатуры.Ссылка КАК Ссылка

	|			ИЗ

	|				Справочник.СерииНоменклатуры КАК СерииНоменклатуры

	|			ГДЕ

	|				СерииНоменклатуры.Наименование ПОДОБНОНаименование)

	|

	|УПОРЯДОЧИТЬ ПО

	|	Серия

	|АВТОУПОРЯДОЧИВАНИЕ"; 	

	Запрос.УстановитьПараметр("Наименование", "%"+НомерФН+"%");	

	РезультатЗапроса = Запрос.Выполнить();

	ТаблицаЗапроса = Запрос.Выполнить().Выгрузить();

	СоздатьТаблицуФормы("ТЗ","ТЗ",ТаблицаЗапроса);

КонецПроцедуры



&НаКлиенте

Процедура ВПоиск(Команда)

	ВПоискНаСервере();

КонецПроцедуры

Категория: Управляемое приложение, Тонкий клиент

История развития запросов: Простые запросы, Временные таблицы, Пакетные запросы

Простые запросы

Разберем, как изменялся (скорее дополнялся) синтаксис текстов запросов на простом примере: Проводится документ Расходная содержащая в табличной части Товары список продаваемых товаров и количество. При проведении такого документа необходимо обеспечить контроль отрицательных остатков хранящихся в регистре накопления остатков ОстаткиТоваров.

Структура конфигурации представлена на рисунке справа:

Сформируем запрос к табличной части документа и виртуальной таблице Остатки регистра накопления. Учтем возможные дубли строк в документе, для этого произведем группирование записей.

Код 1C v 8.х

 Процедура ОбработкаПроведения(Отказ, РежимПроведения)



   Запрос = Новый Запрос;

   Запрос.Текст = "

   |ВЫБРАТЬ

   |   Док.Номенклатура,

   |   СУММА(Док.Количество) КАК Док_Количество,

   |   МИНИМУМ(ЕСТЬNULL(Рег.КоличествоОстаток,0)) КАК Рег_Количество

   |

   |ИЗ

   |   Документ.Расходная.Товары КАК Док

   |   ЛЕВОЕ СОЕДИНЕНИЕ

   |     РегистрНакопления.ОстаткиТоваров.Остатки() КАК Рег

   |   ПО

   |     Док.Номенклатура = Рег.Номенклатура

   |

   |ГДЕ

   |   Ссылка =Ссылка

   |СГРУППИРОВАТЬ ПО Док.Номенклатура";



   Запрос.УстановитьПараметр("Ссылка", Ссылка);

   РезультатЗапроса = Запрос.Выполнить();

   Выборка = РезультатЗапроса.Выбрать();



   Пока Выборка.Следующий() Цикл



   //Проверка отрицательных остатков 

   //Проведение по регистру

   КонецЦикла;



КонецПроцедуры

Естественно приведенный запрос абсолютно не оптимален. С помощью вложенных запросов оптимизируем его: Произведем группирование табличной части документа до соединения с таблицей остатков, в параметры виртуальной таблицы передадим список товаров как значение условия для расчета остатков. В итоге наш запрос примет следующий вид:

Код 1C v 8.х

 |ВЫБРАТЬ

| Док.Номенклатура,

| Док.Количество КАК Док_Количество, 

| ЕСТЬNULL(Рег.КоличествоОстаток,0) КАК Рег_Количество

|

|ИЗ

| (ВЫБРАТЬ

|   Номенклатура, СУММА(Количество) КАК Количество

|  ИЗ 

|   Документ.Расходная.Товары

|  ГДЕ 

|   Ссылка =Ссылка

|  СГРУППИРОВАТЬ ПО Номенклатура) КАК Док

|

|  ЛЕВОЕ СОЕДИНЕНИЕ

|   РегистрНакопления.ОстаткиТоваров.Остатки( , Номенклатура В

|                                              (ВЫБРАТЬ РАЗЛИЧНЫЕ 

|                                                Номенклатура

|                                               ИЗ

|                                                Документ.Расходная.Товары

|                                               ГДЕ 

|                                                Ссылка =Ссылка)) КАК Рег

|  ПО

|   Док.Номенклатура = Рег.Номенклатура";

Если бы в запросе необходимо было бы получить данные из остатков разных регистров то значение фильтра, а следовательно и наш второй вложенный запрос, повторялся бы во всех параметрах виртуальных таблиц, естественно что система при каждом вложенном запросе заново обращается к базе данных для получения данных.

Временные таблицы

Не помню уже с какого релиза в запросах стало можно использовать временные таблицы. Для этого используется объект «Менеджер временных таблиц». Фактически менеджер временных таблиц описывает пространство имен временных таблиц и отвечает за их создание и уничтожение в базе данных.

Сами временные таблицы действительно физически создаются в базе, соответственно следует относиться к ним осторожно, так как дисковая подсистема на сегодняшний момент самая медленная часть техники, а скорость создания и уничтожения таблиц напрямую от нее зависит.

Перепишем запрос для использования временных таблиц. Во временные таблицы поместим сгруппированную табличную часть документа и список товаров для фильтра виртуальных таблиц:

Код 1C v 8.х

 Процедура ОбработкаПроведения(Отказ, РежимПроведения)





 МВТ = Новый МенеджерВременныхТаблиц;





 Запрос = Новый Запрос;

 Запрос.МенеджерВременныхТаблиц = МВТ;

 Запрос.Текст = "

 |ВЫБРАТЬ

 | Номенклатура, СУММА(Количество) КАК Количество

 |ПОМЕСТИТЬ ДокТЧ

 |ИЗ 

 | Документ.Расходная.Товары

 |ГДЕ 

 | Ссылка =Ссылка

 |СГРУППИРОВАТЬ ПО Номенклатура";





 Запрос.УстановитьПараметр("Ссылка", Ссылка);

 РезультатЗапроса = Запрос.Выполнить(); //Прим. 1





 Запрос = Новый Запрос;

 Запрос.МенеджерВременныхТаблиц = МВТ;

 Запрос.Текст = "ВЫБРАТЬ РАЗЛИЧНЫЕ

 | Номенклатура

 |ПОМЕСТИТЬ СписокТоваров

 |ИЗ 

 | Документ.Расходная.Товары

 |ГДЕ 

 | Ссылка =Ссылка";





 Запрос.УстановитьПараметр("Ссылка", Ссылка);

 РезультатЗапроса = Запрос.Выполнить(); //Прим. 2





 Запрос = Новый Запрос;

 Запрос.МенеджерВременныхТаблиц = МВТ;

 Запрос.Текст = "

 |ВЫБРАТЬ

 | Док.Номенклатура,

 | Док.Количество КАК Док_Количество,

 | ЕСТЬNULL(Рег.КоличествоОстаток,0) КАК Рег_Количество

 |ИЗ

 | ДокТЧ КАК Док

 | ЛЕВОЕ СОЕДИНЕНИЕ

 |  РегистрНакопления.ОстаткиТоваров.Остатки(,

 |  Номенклатура В(ВЫБРАТЬ РАЗЛИЧНЫЕ

 |                           Номенклатура

 |                          ИЗ

 |                           СписокТоваров КАК СписокТоваров)) КАК Рег

 | ПО

 |  Док.Номенклатура = Рег.Номенклатура";



 РезультатЗапроса = Запрос.Выполнить();

 Выборка = РезультатЗапроса.Выбрать();



 Пока Выборка.Следующий() Цикл



  //Проверка отрицательных остатков



  //Проведение по регистру



 КонецЦикла;



КонецПроцедуры

При использовании временных таблиц в тексте запроса применяют инструкцию Поместить для создания новой временной таблицы, в этом случае в результат запроса система передает не содержимое этой таблицы (см прим 1 и прим 2 в тексте выше), а количество записей помещенных во временную таблицу, по желанию можно не принимать это значение.

Также допускается использование инструкции Уничтожить в этом случае временная таблица уничтожается, в противном случае временные таблицы уничтожаются вместе с объектом менеджер временных таблиц.

В основном нашем запросе я использовал названия временных таблиц как указание на источник получения данных (им обязательно надо назначать синоним, что мы и видим в тексте). Использовать временные таблицы как источник можно не единожды, что при умелом их применении позволит и сократить текст запроса (улучшиться читабельность сложных запросов) и увеличить скорость (при использовании данных временной таблицы в нескольких местах запроса).

Пакетные запросы

Пакетные запросы логично дополняют функционал временных таблиц и дают больше возможностей при работе с запросами.

В пакетном запросе фактически можно описать несколько запросов, как связанных между собой использованием временных таблиц, так и не связанных (можно, но не понятно зачем?). В итоге можно выполнить последовательно все запросы и принять в результате либо массив с результатами исполнения каждого запроса, либо результат последнего. Для получения массива с результатами запроса применяют метод ВыполнитьПакет() объекта запрос, а для получения результата последнего запроса ВыполнитьЗапрос().

В тексте запроса, запросы пакета разделяются символом «;» (точка с запятой). Область имен виртуальных таблиц у одного пакетного запроса одна. Использование менеджера временных таблиц не требуется, но возможно если вы хотите передать временные таблицы из одного пакетного запроса в другой.

Перепишем процедуру для использования пакетных запросов:

Код 1C v 8.х

 Процедура ОбработкаПроведения(Отказ, РежимПроведения)



Запрос = Новый Запрос;

Запрос.Текст = "

|ВЫБРАТЬ

| Номенклатура, СУММА(Количество) КАК Количество

|ПОМЕСТИТЬ ДокТЧ

|ИЗ

| Документ.Расходная.Товары

|ГДЕ 

| Ссылка =Ссылка

|СГРУППИРОВАТЬ ПО Номенклатура

|;

|

|ВЫБРАТЬ РАЗЛИЧНЫЕ

| Номенклатура

|ПОМЕСТИТЬ СписокТоваров

|ИЗ 

| Документ.Расходная.Товары

|ГДЕ 

| Ссылка =Ссылка

|;

|

|ВЫБРАТЬ

| Док.Номенклатура,

| Док.Количество КАК Док_Количество,

| ЕСТЬNULL(Рег.КоличествоОстаток,0) КАК Рег_Количество

|ИЗ

| ДокТЧ КАК Док

| ЛЕВОЕ СОЕДИНЕНИЕ

|  РегистрНакопления.ОстаткиТоваров.Остатки(,

|  Номенклатура В(ВЫБРАТЬ РАЗЛИЧНЫЕ

|                           Номенклатура

|                          ИЗ

|                           СписокТоваров КАК СписокТоваров)) КАК Рег

| ПО

|  Док.Номенклатура = Рег.Номенклатура";





Запрос.УстановитьПараметр("Ссылка", Ссылка);

МассивРезультаттов = Запрос.ВыполнитьПакет(); //Прим. 1

РезультатЗапроса = Запрос.Выполнить(); //Прим. 2

Выборка = РезультатЗапроса.Выбрать();



Пока Выборка.Следующий() Цикл



 //Проверка отрицательных остатков

 //Проведение по регистру



КонецЦикла;



КонецПроцедуры

Фактически я убрал определение объекта запрос и использование менеджера временных таблиц, объединил тексты запросов (обратите внимание на разделитель «;» между текстами). В результате текст запроса стал читабельнее (а при использовании конструктора запросов намного увеличивается удобство чтения запроса).

После выполнения запроса в переменную МассивРезультатов у нас попадет 3 элемента. Первые два будут содержать число характеризующее количество записей помещенных во временные таблицы ДокТЧ и СписокТоваров, а третий будет содержать выборку с полями Номенклатура, Док_Количество и Рег_Количество.

В переменную РезультатЗапроса попадет только выборка.

Ну вот и все что касается пакетных запросов. Очень удобный механизм и с точки зрения написания запросов и с точки зрения чтения сложных запросов.

Автор: Павел Чистов

Категория: Запросы

Механизм оповещений пользователя Категория: Встроенные Функции

Обновление 1С через интернет Категория: 1С Общие вопросы - Обычные формы

Формат, функция форматирования значений

Код 1C v 8.х

 

//Функция формирует удобное для чтения представление значений.



// Примеры форматирования чисел

ЗначФормат = Формат(123456.789, "ЧЦ=10; ЧДЦ=2");      // ЗначФормат = "123 456,79"

ЗначФормат = Формат(123456.789, "ЧГ=0; ЧДЦ=2");      // ЗначФормат = "123456,79"

ЗначФормат = Формат(123456.789, "ЧРД='-'");           // ЗначФормат = "123 456-789"

ЗначФормат = Формат(-123456.789, "ЧО=0");             // ЗначФормат = "(123 456,789)";

ЗначФормат = Формат(13, "ЧЦ=5; ЧВН=; ЧГ=0");      // ЗначФормат = "00013";



//В 8 версии для вывовода чисел прописью используется ЧислоПрописью

ЧислоПрописью(Сумма, "L=ru_RU", Валюта.ПараметрыПрописиНаРусском)  

ЧислоПрописью(1457.25,"L=en_US","dollar, dollars, cent, cents, 2"); // One thousand four hundreds fifty seven dollars 25 cents. 

ЧислоПрописью(Сумма,"Рубль,рубля,рублей,м,копейка,копейки,копеек,ж,2");



//Пример представления Числа в виде Даты

ЗначФормат = Формат(25021949, "ЧЦ=8; ЧРГ=.; ЧВН=; ЧГ=4,2,0");      // ЗначФормат = "25.02.1949"



// Примеры форматирования дат

ЗначФормат = Формат('20020820153309', "ДФ=""дд ММММ гггг 'г.' ЧЧ:мм:сс""");     // ЗначФормат = "20 августа 2002 г. 15:33:09"

ЗначФормат = Формат('20020820153309', "ДФ=""дд/ММ-гггг""");                     // ЗначФормат = "20/08-2002"

ЗначФормат = Формат('20020820153309', "ДФ='q ""кв."" yyyy'"); 		            // ЗначФормат = "3 кв. 2002";

ЗначФормат = Формат('20020820153309', "ДФ='""Итого"" q ""квартал""'") ;	   // ЗначФормат = "Итого 3 квартал";

ЗначФормат = Формат('20020820153309', "ДФ='ММММ гггг'");  		            // ЗначФормат = "Август 2002 г.";

ЗначФормат = Формат('20020820153309', "ДЛФ=ДД");                                // ЗначФормат = "20 августа 2002 г.";

ЗначФормат = Формат('20020820153309', "ДЛФ=Д");                                 // ЗначФормат = "20.08.2002";

ЗначФормат = Формат('20020820153309', "ДЛФ=В");                                 // ЗначФормат = "15:33:09";



ЗначФормат = Формат('20020820153309', "ДФ=HHmmssyyyyMMdd");                                 // ЗначФормат = "15330920020820";

ЗначФормат = Формат('20020820153309', "ДФ=HH:mm:ss yyyy MM dd");                                 // Время 24 часа  - ЗначФормат = "15:33:09 2002 08 20";

ЗначФормат = Формат('20020820153309', "ДФ=hh:mm:ss yyyy MM dd");                                 // Время 12 часов - ЗначФормат = "03:33:09 2002 08 20";



Формат(Дата(2009, 1, 1), "ДЛФ=DD") + ", " + ОпределитьДеньНедели(ДеньНедели(Дата(2009, 1, 1)));   // 1 января 2009 г., Четверг (Смотрите в "Работаем с Датами" Функция Определить день недели)

Формат(Дата(2009, 1, 1), "ДФ=ММММ") + ", " + Формат(Дата(2009, 1, 1), "ДФ=yyyy") + " г.";         // Январь, 2009 г.

Формат(НачалоНедели(Дата(2009, 1, 1)), "ДФ='dd MMMM yyyy'") + " г. - " + Формат(КонецНедели(Дата(2009, 1, 1)), "ДФ='dd MMMM yyyy'") + " г."; // 29 декабря 2008 г. - 04 января 2009 г.



// ДЕКАДУ нельзя вывести через формат, но можно так:

Строка(Цел(День(Дата('20020820153309')) / 10) + 1)+" декада"  = 2 декада



// Примеры форматирования логических выражений

ЗначФормат = Формат(Истина, "БЛ=Отсутствует; БИ=Доступен");                     // ЗначФормат = "Доступен";

ЗначФормат = Формат(Ложь, "БЛ=Нет; БИ=Да");                     				// ЗначФормат = "Нет";

Код 1C v 7.x

 

// Символы, определяющие тип форматируемых данных: 

// Ч — число (Англоязычный синоним: N)  

ЗначФормат = Формат(123.15, "Ч(0)10.2") // 0000123.15

Долг = Строка(Формат(Долг(), "Ч12.2")) + " " + Валюта.Сокр_назв;



// Возможен вывод денежных величин и просто целых чисел прописью. В этом случае форматная строка должна иметь вид "ЧПДС".

// Наличие буквы "П" (в английском варианте для аналогичной цели используется буква "S") определяет сам факт вывода числа прописью. 

// Символ "Д" (в английском варианте — "M") обозначает вывод денежной величины и является необязательным. 

// Символ "С" (в английском варианте — "H") также необязателен и означает вывод с копейками.

ИтогоСуммаПрописью  = Формат(Итог("Сумма"), "ЧПДС");

КоличествоНаименованийПрописью = Формат(КоличествоСтрок(), "ЧП");



// С — строка (Англоязычный синоним: S) 

// "Сn", где n — положительное целое число определяющее ширину поля, в котором будет размещаться строка. 

// В случае, если ширина поля превосходит длину строки сформатированная строка будет дополнена справа пробелами, если же ширина поля меньше длины строки — строка будет усечена справа.





// Д — дата (Англоязычный синоним: D)

ДатаДокумента = Формат(Док.ДатаДок,"Д ДД.ММ.ГГ");  //12.03.08

ДатаДокумента = Формат("01.01.1999", "Д(0)ДДММММГГГГ"); // 01 Января 1999 г.



//Для форматирования даты используется форматная строка вида "Д<ПодстрокаФормата>", где <Подстрока Формата> представляет собой строку, определяющую вид сформатированного представления даты:

//DDMMYY (ДДММГГ)  дата в виде ДД.ММ.ГГ 

//DDMMYYYY (ДДММГГГГ)  дата в виде ДД.ММ.ГГГГ 

//DDMMMMYYYY (ДДММММГГГГ)  дата в виде ДД месяц прописью ГГГГ 

//(0)DDMMMMYYYY ((0)ДДММММГГГГ) этот формат представляет собой вариант предыдущего формата с тем отличием, что число месяца всегда выводится двумя цифрами, т. е. для чисел меньших 10 спереди будет добавлен 0. Например: Формат('01.01.1999', ' 'Д(0)ДДММММГГГГ' ') = 01 Января 1999 г. 

//MMMMYYYY (ММММГГГГ) дата в виде месяц прописью ГГГГ 

//MMMMYY (ММММГГ) дата в виде месяц прописью ГГ 

//ММММ (ММММ) дата в виде месяц прописью 

//QQQQYYYY (ККККГГГГ) дата в виде N квартала ГГГГ 

//QQQQYY (ККККГГ) дата в виде N квартала ГГ 

//QQQQ дата в виде N квартала 

//YYYYMMDD (ГГГГММДД) дата в виде ГГГГММДД, то есть дата '10.11.1998' будет представлена как строка "19981110" 

//WWWW (HHHH) выводит наименование дня недели, соответствующее указанной дате. Наименования дней недели берутся из файла прописи.

Категория: Встроенные Функции