признаки » Поиск

Результаты по ключевому слову: признаки

Регламентные операции на уровне субд для MS SQL Server, Оптимизация работы

Одной из часто встречающихся причин не оптимальной работы системы является неправильное или несвоевременное выполнение регламентных операций на уровне СУБД. Особенно важно выполнять эти регламентные процедуры в крупных информационных системах, которые работают под значительной нагрузкой и обслуживают одновременно большое количество пользователей. Специфика таких систем в том, что обычных действий, выполняемых СУБД автоматически (на основании настроек) оказывает недостаточно для эффективной работы.

Если в работающей системе наблюдаются какие-либо симптомы проблем с производительностью, следует проверить, что в системе правильно настроены и регулярно выполняются все рекомендуемые регламентные операции на уровне СУБД.

Выполнение регламентных процедур должно быть автоматизировано. Для автоматизации этих операций рекомендуется использовать встроенное средства MS SQL Server: Maintenance Plan. Существуют так же другие способы автоматизации выполнения этих процедур. В настоящей статье для каждой регламентной процедуры дан пример ее настройки при помощи Maintenance Plan для MS SQL Server 2005.

Для MS SQL Server рекомендуется выполнять следующие регламентные операции:

Обновление статистикОчистка процедурного КЭШаДефрагментация индексовРеиндексация таблиц базы данных

Рекомендуется регулярно контролировать своевременность и правильность выполнения данных регламентных процедур.

Обновление статистик

MS SQL Server строит план запроса на основании статистической информации о распределении значений в индексах и таблицах. Статистическая информация собирается на основании части (образца) данных и автоматически обновляется при изменении этих данных. Иногда этого оказывается недостаточно для того, что MS SQL Server стабильно строил наиболее оптимальный план выполнения всех запросов.

В этом случае возможно проявление проблем с производительностью запросов. При этом в планах запросов наблюдаются характерные признаки неоптимальной работы (неоптимальные операции).

Для того, чтобы гарантировать максимально правильную работу оптимизатора MS SQL Server рекомендуется регулярно обновлять статистики базы данных MS SQL.

Для обновления статистик по всем таблицам базы данных необходимо выполнить следующий SQL запрос:

Код SQL

 exec sp_msforeachtable N'UPDATE STATISTICS ? WITH FULLSCAN'

Обновление статистик не приводит к блокировке таблиц, и не будет мешать работе других пользователей. Статистика может обновляться настолько часто, насколько это необходимо. Следует учитывать, что нагрузка на сервер СУБД во время обновления статистик возрастет, что может негативно сказаться на общей производительности системы.

Оптимальная частота обновления статистик зависит от величины и характера нагрузки на систему и определяется экспериментальным путем. Рекомендуется обновлять статистики не реже одного раза в день.

Приведенный выше запрос обновляет статистики для всех таблиц базы данных. В реально работающей системе разные таблицы требуют различной частоты обновления статистик. Путем анализа планов запроса можно установить, какие таблицы больше других нуждаются в частом обновлении статистик, и настроить две (или более) различных регламентных процедуры: для часто обновляемых таблиц и для всех остальных таблиц. Такой подход позволит существенно снизить время обновления статистик и влияние процесса обновления статистики на работу системы в целом.

Настройка автоматического обновления статистик (MS SQL 2005)

Запустите MS SQL Server Management Studio и подключитесь к серверу СУБД. Откройте папку Management и создайте новый план обслуживания:

Создайте субплан (Add Sublan) и назовите его «Обновление статистик». Добавьте в него задачу Update Statistics Task из панели задач:

Настройте расписание обновления статистик. Рекомендуется обновлять статистики не реже одного раза в день. При необходимости частота обновления статистик может быть увеличена.

Настройте параметры задачи. Для этого следует два раза кликнуть на задачу в правом нижнем углу окна. В появившейся форме укажите имя базу данных (или несколько баз данных) для которых будет выполняться обновление статистик. Кроме этого вы можете указать для каких таблиц обновлять статистики (если точно неизвестно, какие таблицы требуется указать, то устанавливайте значение All).

Обновление статистик необходимо проводить с включенной опцией Full Scan.

Сохраните созданный план. При наступлении указанного в расписании срока обновление статистик будет запущено автоматически.

Очистка процедурного КЭШа

Оптимизатор MS SQL Server кэширует планы запросов для их повторного выполнения. Это делается для того, чтобы экономить время, затрачиваемое на компиляцию запроса в том случае, если такой же запрос уже выполнялся и его план известен.

Возможна ситуация, при которой MS SQL Server, ориентируясь на устаревшую статистическую информацию, построит неоптимальный план запроса. Этот план будет сохранен в процедурном КЭШе и использован при повторном вызове такого же запроса. Если Вы обновили статистику, но не очистили процедурный кэш, то SQL Server может выбрать старый (неоптимальный) план запроса из КЭШа вместо того, чтобы построить новый (более оптимальный) план.

Таким образом, рекомендуется всегда после обновления статистик очищать содержимое процедурного КЭШа.

Для очистки процедурного КЭШа MS SQL Server необходимо выполнить следующий SQL запрос:

Код SQL

 DBCC FREEPROCCACHE

Этот запрос следует выполнять непосредственно после обновления статистики. Соответственно, частота его выполнения должна совпадать с частотой обновления статистики.

Настройка очистки процедурного КЭШа

для (MS SQL 2005)

Поскольку процедурный КЭШ необходимо очищать при каждом обновлении статистики, данную операцию рекомендуется добавить в уже созданный субплан «Обновление статистик». Для этого следует открыть субплан и добавить в его схему задачу Execute T-SQL Statement Task. Затем следует соединить задачу Update Statistics Task стрелочкой с новой задачей.

В тексте созданной задачи Execute T-SQL Statement Task следует указать запрос «DBCC FREEPROCCACHE»:

Дефрагментация индексов

При интенсивной работе с таблицами базы данных возникает эффект фрагментации индексов, который может привести к снижению эффективности работы запросов.

Рекомендуется регулярное выполнение дефрагментации индексов. Для дефрагментации всех индексов всех таблиц базы данных необходимо использовать следующий SQL запрос (предварительно подставив имя базы):

Код SQL

 sp_msforeachtable N'DBCC INDEXDEFRAG (<имя базы данных>, ''?'')'

Дефрагментация индексов не блокирует таблицы, и не будет мешать работе других пользователей, однако создает дополнительную нагрузку на SQL Server. Оптимальная частота выполнения данной регламентной процедуры должна подбираться в соответствии с нагрузкой на систему и эффектом, получаемым от дефрагментации. Рекомендуется выполнять дефрагментацию индексов не реже одного раза в день.

Возможно выполнение дефрагментации для одной или нескольких таблиц, а не для всех таблиц базы данных.

Настройка дефрагментации индексов (MS SQL 2005)

В ранее созданном плане обслуживания создайте новый субплан с именем «Дефрагментация индексов». Добавьте в него задачу Reorganize Index Task:

Задайте расписание выполнения для задачи дефрагментации индексов. Рекомендуется выполнять задачу не реже одного раза в неделю, а при высокой изменчивости данных в базе еще чаще – до одного раза в день.

Настройте задачу, указав базу данных (или несколько баз данных) и выбрав необходимые таблицы. Если точно неизвестно, какие таблицы следует указать, то устанавливайте значение All.

Реиндексация таблиц включает полное перестроение индексов таблиц базы данных, что приводит к существенной оптимизации их работы. Рекомендуется выполнять регулярную переиндексацию таблиц базы данных. Для реиндексации всех таблиц базы данных необходимо выполнить следующий SQL запрос:

Код SQL

 sp_msforeachtable N'DBCC DBREINDEX (''?'')'

Реиндексация таблиц блокирует их на все время своей работы, что может существенно сказаться на работе пользователей. В связи с этим реиндексацию рекомендуется выполнять во время минимальной загрузки системы.

После выполнения реиндексации нет необходимости делать дефрагментацию индексов.

В ранее созданном плане обслуживания создайте новый субплан с именем «Дефрагментация индексов». Добавьте в него задачу Rebuild Index Task:

Задайте расписание выполнения для задачи реиндексирования таблиц. Рекомендуется выполнять задачу во время минимальной нагрузки на систему, не реже одного раза в неделю.

Реиндексация таблиц базы данных

Необходимо осуществлять регулярный контроль выполнения регламентных процедур на уровне СУБД. Ниже приведен пример контроля выполнения плана обслуживания для MS SQL Server 2005.

Откройте созданный вами план обслуживания и выберите из контекстного меню пункт «View History»:

Откроется окно с протоколом выполнения всех заданных регламентных процедур.

Успешно выполненные задачи и задачи, выполненные с ошибками, будут помечены соответствующими иконками. Для задач, выполненных с ошибками, доступна подробная информация об ошибке.

Источник: Регламентные операции MS SQL Server. Оптимизация работы

Категория: Администрирование

Обход метаданных (полезные функции)

При написании небольших автоматизированных тестов часто надо обойти всю конфигурацию и проверить, например, для всех форм какое-нибудь свойство. Это всё легко делается через свойство глобального контекста "Метаданные", но чтоб дорбаться до обхода реквизитов надо написать кучу вложенных циклов. При этом код становится слабочитаемым и слабомодифицируемым.

Ниже приведен небольшой модуль, который решает задачу легко и удобно. Создана специальная функция РазвернутьСтрокуОбходаМетаданных, которая может по строке типа "Метаданные.Справочники.*.Реквизиты.*" построить массив строк с перечислением всех реквизитов всех справочников. При помощи этой и нескольких других функций в экспортных функциях модуля реализованы вполне прикладные задачи - получение всех реквизитов, всех макетов, всех форм конфигурации и построение таблицы всех составных типов.

Код 1C v 8.х

  // Автор: Alexander Speshilov

// Рекрсивная функция, которая разворачивает строку вида "Метаданные.Справочники.*[Имя].Реквизиты.*.Тип" 

// в массив строк, заменяя "*" или другой символ, задаваемый параметрами обходом всех элементов 

// коллекции. Допускает выполнение функций встроенного языка (не стоит отдавать ввод параметров 

// пользователям). При этом выражение, используемое для получения по умолчанию может быть задано в 

// квадратных скобках или параметром функции.

//

// Параметры

//  СтрокаОбхода  - Строка - Разворачиваемая строка

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Массив строк

//

Функция РазвернутьСтрокуОбходаМетаданных(СтрокаОбхода, ЗаменяемоеЗначение = "*", ПредставлениеПоУмолчанию = "")

    

    Рез = Новый Массив;

    

    ЧастиСтрокиОбхода = РазобратьСтрокуОбхода(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

    Если ЧастиСтрокиОбхода = Неопределено тогда 

        Рез.Добавить(СтрокаОбхода); //фактически это ограничение рекурсии.

    Иначе

        ОбъектКоллекции = Вычислить(ЧастиСтрокиОбхода.СтрокаКоллекции);

        РазвернутаяКоллекция = РазвернутьКоллекциюВПредставления(ОбъектКоллекции, ЧастиСтрокиОбхода.СтрокаПредставление);

        Для каждого ЭлементРазвернутойКоллекции Из РазвернутаяКоллекция Цикл

            

            // рекурсивный вызов

            ТекущаяСтрокаОбхода = ЧастиСтрокиОбхода.СтрокаНачало + ЭлементРазвернутойКоллекции + ЧастиСтрокиОбхода.СтрокаКонец;

            МассивЭлемента = РазвернутьСтрокуОбходаМетаданных(ТекущаяСтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

            

            Для каждого ПримитивныйЭлементОбхода Из МассивЭлемента Цикл

                Рез.Добавить(ПримитивныйЭлементОбхода);

            КонецЦикла;

            

        КонецЦикла;

    КонецЕсли;

    

    Возврат Рез;

    

КонецФункции // РазвернутьСтрокуОбходаМетаданных()



// Разбирает строку обхода на удобные для работы поля

//

// Параметры

//  СтрокаОбхода  - Строка - Разворачиваемая строка

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Структура с полями ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец

// или Неопределено (если строка не содержит ЗаменяемоеЗначение)

//

Функция РазобратьСтрокуОбхода(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию)

    

    Если ПустаяСтрока(ЗаменяемоеЗначение) Тогда 

        ВызватьИсключение "Некорректное выражение заменяемого значения";

    КонецЕсли;

    

    ПозицияЗамены = Найти(СтрокаОбхода, ЗаменяемоеЗначение);

    

    // Если не найдена строка - возвращаем неопределено, как индикатор

    Если ПозицияЗамены = 0 Тогда 

        Возврат Неопределено; 

    КонецЕсли;

    

    СтрокаНачало = Лев(СтрокаОбхода,ПозицияЗамены - 1);

    

    //Получение строки для выражения-коллекции

    СтрокаКоллекции = СтрокаНачало;

    Если Прав(СтрокаКоллекции, 1) = "." Тогда 

        СтрокаКоллекции = Лев(СтрокаКоллекции,СтрДлина(СтрокаКоллекции) - 1);

    КонецЕсли;

    

    ПозицияОкончанияЗамены = ПозицияЗамены + СтрДлина(ЗаменяемоеЗначение);

    

    ОстатокВыражения = Сред(СтрокаОбхода, ПозицияОкончанияЗамены);

    

    //Обработка явного задания представления

    ОткрывающаяСкобка = "[";

    ЗакрывающаяСкобка = "]";

    Если Найти(ОстатокВыражения, ОткрывающаяСкобка) = 1 Тогда

        ОстатокВыражения = Сред(ОстатокВыражения, СтрДлина(ОткрывающаяСкобка) + 1);

        ПозицияЗакрывающейСкобки = Найти(ОстатокВыражения, ЗакрывающаяСкобка);

        Если ПозицияЗакрывающейСкобки = 0 Тогда 

            ВызватьИсключение "Синтаксическая ошибка разбора выражения";

        КонецЕсли;

        СтрокаПредставление = Лев(ОстатокВыражения, ПозицияЗакрывающейСкобки - 1);

        ОстатокВыражения = Сред(ОстатокВыражения, ПозицияЗакрывающейСкобки + СтрДлина(ЗакрывающаяСкобка));

    Иначе

        СтрокаПредставление = ПредставлениеПоУмолчанию;

    КонецЕсли;

    СтрокаКонец = ОстатокВыражения;

    

    Рез = Новый Структура("ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец",

    ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец);

    

    Возврат Рез;

    

КонецФункции // РазобратьСтрокуОбхода()



// Разворачивает объект коллекции в массив представления элементов

//

// Параметры

//  Коллекция  - Произвольный - Коллекция, которую можно обойти через "Для каждого"

//  ПредставлениеЭлемента  - Строка - необяз., свойство элементов коллекции, которое 

//               используется для получения представления.

//

// Возвращаемое значение:

//   Массив   - Массив представлений коллекции

//

Функция РазвернутьКоллекциюВПредставления(Коллекция, Знач ПредставлениеЭлемента = "")

    

    //Проверка и подгонка параметров

    Если не ПустаяСтрока(ПредставлениеЭлемента) Тогда 

        Если Найти(ПредставлениеЭлемента, ";")>0 Тогда 

            ВызватьИсключение "Некорректное выражение представления";

        КонецЕсли;

        ПредставлениеЭлемента = "." + ПредставлениеЭлемента;

    КонецЕсли;

    

    Рез = Новый Массив;

    Для каждого ЭлементКоллекции Из Коллекция Цикл

        ТекПредставление = Строка(Вычислить("ЭлементКоллекции" + ПредставлениеЭлемента));

        Рез.Добавить(ТекПредставление);

    КонецЦикла; 

    Возврат Рез;

    

КонецФункции // РазвернутьКоллекцию()



// Разворачивает массив строк через РазвернутьСтрокуОбходаМетаданных

//

// Параметры

//  МассивСтрокОбхода  - Массив - Массив разворачиваемых строк

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Массив строк

//

Функция РазвернутьМассивСтрокОбходаМетаданных(МассивСтрокОбхода, ЗаменяемоеЗначение = "*", ПредставлениеПоУмолчанию = "Имя")

    

    Рез = Новый Массив;

    

    Для каждого СтрокаОбхода Из МассивСтрокОбхода Цикл

        

        ДополнениеРезультата = РазвернутьСтрокуОбходаМетаданных(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

        Для каждого ТекСтрока Из ДополнениеРезультата Цикл

            Рез.Добавить(ТекСтрока);

        КонецЦикла; 

        

    КонецЦикла; 

    

    Возврат Рез;

    

КонецФункции // РазвернутьМассивСтрокОбходаМетаданных()



// Преобразует строку в массив одиночных строк по разделителю Символы.ПС

//

// Параметры

//  ПреобразуемаяСтрока - строка для преобразования

//    ИгнорироватьПустые - Булево - Пропускать пустые строки

//  СокращатьПробелы - Использовать СокрЛП

//

// Возвращаемое значение:

//   Массив строк

//

Функция ПолучитьМассивСтрокМногострочнойСтроки(ПреобразуемаяСтрока, ИгнорироватьПустые = Истина, СокращатьПробелы = Истина)

    

    Рез = Новый Массив;

    ЧислоСтрок = СтрЧислоСтрок(ПреобразуемаяСтрока);

    

    Для Сч = 1 По ЧислоСтрок Цикл

        

        ТекСтрока = СтрПолучитьСтроку(ПреобразуемаяСтрока, Сч);

        Если ИгнорироватьПустые и ПустаяСтрока(ТекСтрока) Тогда

            Продолжить;

        КонецЕсли; 

        Если СокращатьПробелы Тогда

            ТекСтрока = СокрЛП(ТекСтрока);

        КонецЕсли; 

        Рез.Добавить(ТекСтрока);

        

    КонецЦикла;

    

    Возврат Рез;

    

КонецФункции // ПолучитьМассивСтрокМногострочнойСтроки()



// Возвращает все реквизиты конфигурации, которые сохраняются в ИБ

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеХранимыеРеквизитыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.Константы.*

    |Метаданные.ПланыОбмена.*.Реквизиты.*

    |Метаданные.ПланыОбмена.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Справочники.*.Реквизиты.*

    |Метаданные.Справочники.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Документы.*.Реквизиты.*

    |Метаданные.Документы.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Последовательности.*.Измерения.*

    |Метаданные.ПланыВидовХарактеристик.*.Реквизиты.*

    |Метаданные.ПланыВидовХарактеристик.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.ПланыСчетов.*.Реквизиты.*

    |Метаданные.ПланыСчетов.*.ПризнакиУчета.*

    |Метаданные.ПланыСчетов.*.ПризнакиУчетаСубконто.*

    |Метаданные.ПланыСчетов.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.ПланыВидовРасчета.*.Реквизиты.*

    |Метаданные.ПланыВидовРасчета.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.РегистрыСведений.*.Измерения.*

    |Метаданные.РегистрыСведений.*.Ресурсы.*

    |Метаданные.РегистрыСведений.*.Реквизиты.*

    |Метаданные.РегистрыНакопления.*.Измерения.*

    |Метаданные.РегистрыНакопления.*.Ресурсы.*

    |Метаданные.РегистрыНакопления.*.Реквизиты.*

    |Метаданные.РегистрыБухгалтерии.*.Измерения.*

    |Метаданные.РегистрыБухгалтерии.*.Ресурсы.*

    |Метаданные.РегистрыБухгалтерии.*.Реквизиты.*

    |Метаданные.РегистрыРасчета.*.Измерения.*

    |Метаданные.РегистрыРасчета.*.Ресурсы.*

    |Метаданные.РегистрыРасчета.*.Реквизиты.*

    |Метаданные.БизнесПроцессы.*.Реквизиты.*

    |Метаданные.БизнесПроцессы.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Задачи.*.Реквизиты.*

    |Метаданные.Задачи.*.РеквизитыАдресации.*

    |Метаданные.Задачи.*.ТабличныеЧасти.*.Реквизиты.*

    |";

    ВсеХранимыеРеквизитыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеХранимыеРеквизитыКонфигурации;

    

КонецФункции // ПолучитьВсеХранимыеРеквизитыКонфигурации()



// Возвращает все реквизиты конфигурации составного типа, которые сохраняются в ИБ

//

// Параметры - Нет

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция ПолучитьВсеХранимыеРеквизитыКонфигурацииСоставногоТипа() Экспорт

    

    ВсеХранимыеРеквизитыКонфигурации = ПолучитьВсеХранимыеРеквизитыКонфигурации();

    Рез = Новый ТаблицаЗначений;

    Рез.Колонки.Добавить("Имя", Новый ОписаниеТипов("Строка"));

    Рез.Колонки.Добавить("Тип", Новый ОписаниеТипов("ОписаниеТипов"));

    Рез.Колонки.Добавить("КоличествоПростыхТипов", Новый ОписаниеТипов("Число"));

    

    Для каждого ТекРеквизит Из ВсеХранимыеРеквизитыКонфигурации Цикл

        

        Реквизит = Вычислить(ТекРеквизит);

        Тип = Реквизит.Тип;

        КоличествоПростыхТипов = Тип.Типы().Количество();

        Если КоличествоПростыхТипов<>1 Тогда 

    	    ТекСтрока = Рез.Добавить();

            ТекСтрока.Имя = ТекРеквизит;

            ТекСтрока.Тип = Тип;

            ТекСтрока.КоличествоПростыхТипов = КоличествоПростыхТипов;

        КонецЕсли;

    

    КонецЦикла; 

    

    Возврат Рез;

    

КонецФункции // ПолучитьВсеХранимыеРеквизитыКонфигурации()



// Возвращает все формы конфигурации

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеФормыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.ПланыОбмена.*.Формы.*

    |Метаданные.КритерииОтбора.*.Формы.*

    |Метаданные.ОбщиеФормы.*

    |Метаданные.Справочники.*.Формы.*

    |Метаданные.Документы.*.Формы.*

    |Метаданные.ЖурналыДокументов.*.Формы.*

    |Метаданные.Перечисления.*.Формы.*

    |Метаданные.Отчеты.*.Формы.*

    |Метаданные.Обработки.*.Формы.*

    |Метаданные.ПланыВидовХарактеристик.*.Формы.*

    |Метаданные.ПланыСчетов.*.Формы.*

    |Метаданные.ПланыВидовРасчета.*.Формы.*

    |Метаданные.РегистрыСведений.*.Формы.*

    |Метаданные.РегистрыНакопления.*.Формы.*

    |Метаданные.РегистрыБухгалтерии.*.Формы.*

    |Метаданные.РегистрыРасчета.*.Формы.*

    |Метаданные.БизнесПроцессы.*.Формы.*

    |Метаданные.Задачи.*.Формы.*

    |";

    ВсеФормыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеФормыКонфигурации;

    

КонецФункции // ПолучитьВсеФормыКонфигурации()



// Возвращает все макеты конфигурации

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеМакетыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.ПланыОбмена.*.Макеты.*

    |Метаданные.ОбщиеМакеты.*

    |Метаданные.Справочники.*.Макеты.*

    |Метаданные.Документы.*.Макеты.*

    |Метаданные.ЖурналыДокументов.*.Макеты.*

    |Метаданные.Перечисления.*.Макеты.*

    |Метаданные.Отчеты.*.Макеты.*

    |Метаданные.Обработки.*.Макеты.*

    |Метаданные.ПланыВидовХарактеристик.*.Макеты.*

    |Метаданные.ПланыСчетов.*.Макеты.*

    |Метаданные.ПланыВидовРасчета.*.Макеты.*

    |Метаданные.РегистрыСведений.*.Макеты.*

    |Метаданные.РегистрыНакопления.*.Макеты.*

    |Метаданные.РегистрыБухгалтерии.*.Макеты.*

    |Метаданные.РегистрыРасчета.*.Макеты.*

    |Метаданные.БизнесПроцессы.*.Макеты.*

    |Метаданные.Задачи.*.Макеты.*

    |";

    ВсеМакетыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеМакетыКонфигурации;

    

КонецФункции // ПолучитьВсеМакетыКонфигурации()

Категория: Метаданные

Выгрузка / Загрузка данных посредством XML файлов?

В основе работы с XML-файлами лежит технология доступа SAX, которая осуществляет считывание по одному тегу. Для этого существует два типа данных – ЗаписьXML и ЧтениеXML.
Запись данных справочника в XML-файл:

Код 1C v 8.х

 Запись = Новый ЗаписьXML;

Запись.ОткрытьФайл(ПутьКФайлу);

Запись.ЗаписатьОбъявлениеXML();

// формируем корневой элемент

Запись.ЗаписатьНачалоЭлемента("Клиенты");

Выборка = Справочники.Клиенты.Выбрать();

Пока Выборка.Следующий() Цикл

	// для каждого клиента формируем свой элемент

	Запись.ЗаписатьНачалоЭлемента("Клиент");

	// запишем код клиента в атрибут тега

	Запись.ЗаписатьАтрибут("Код", Строка(Выборка.Код));

	// Наименование клиента запишем в текст элемента

	Запись.ЗаписатьТекст(Выборка.Наименование);

	// закрываем элемент клиента

	Запись.ЗаписатьКонецЭлемента();	

КонецЦикла;

// закрываем корневой элемент xml-документа

Запись.ЗаписатьКонецЭлемента();	

// закрыть файл

Запись.Закрыть();

Чтение данных из XML-файла в справочник:

Код 1C v 8.х

 Чтение = Новый ЧтениеXML;

Чтение.ОткрытьФайл(ПутьКФайлу);

Спр="";

// чтение осуществляется по одному тегу

Пока Чтение.Прочитать() Цикл

	// анализируем тип элемента и его имя

	Если Чтение.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда

		Если Чтение.Имя="Клиент" Тогда

			// создаем новый элемент справочника

			Спр = Справочники.Клиенты.СоздатьЭлемент();

// читаем атрибуты

			Пока Чтение.ПрочитатьАтрибут() Цикл

				Если Чтение.Имя="Код" Тогда

					Спр.Код = Число(Чтение.Значение);

				КонецЕсли;

КонецЦикла;

		КонецЕсли;

	ИначеЕсли Чтение.ТипУзла = ТипУзлаXML.Текст Тогда

		// заполняем наименование созданного ранее элемента

		Спр.Наименование = Чтение.Значение;

	ИначеЕсли Чтение.ТипУзла = ТипУзлаXML.КонецЭлемента Тогда

		// требуется записать информацию про клиента

		Спр.Записать();

	КонецЕсли;

КонецЦикла;

Создадим обработку в типовой конфигурации для экспорта плана счетов. Структура xml-файла должна быть такой. Корневой элемент xml-документа соответствует плану счетов в целом. В нем располагаются подчиненные элементы с именем Счет, содержащие информацию о счетах. В качестве содержимого элементов указывается наименование счета. Остальные данные записываются в качестве атрибутов (код, признаки валютного, количественного учета и пр.). В качестве подчиненных элементов для элемента Счет задаются элементы, обозначающие его субсчета с теми же атрибутами. Приведем код процедуры экспорта плана счетов.

Код 1C v 7.x

 Процедура Выполнить()

  Если ЗагрузитьВнешнююКомпоненту(КаталогПрограммы()+"v7plus.dll")<>1 Тогда

    Предупреждение("Компонента не обнаружена");

    Возврат;

  КонецЕсли;

  Анализатор=СоздатьОбъект("AddIn.XMLParser");

  Корень=Анализатор.СоздатьДокумент();

  План=Корень.СоздатьПодчиненныйЭлемент("ПланСчетов");

  Счет=СоздатьОбъект("Счет.Основной");

  Родитель=СоздатьОбъект("Счет.Основной");

  Счет.ВыбратьСчета();

  Пока Счет.ПолучитьСчет()=1 Цикл

    // если это счет, а не субсчет

    Если Счет.Уровень()=1 Тогда

      Родитель.НайтиПоКоду(Счет.Код);

      СчетXML=План.СоздатьПодчиненныйЭлемент("Счет");

      СчетXML.УстановитьАтрибут("Код", Счет.Код);

      СчетXML.УстановитьАтрибут("Валютный", Счет.Валютный);

      СчетXML.УстановитьАтрибут("Количественный", Счет.Количественный);

      СчетXML.УстановитьАтрибут("Забалансовый", Счет.Забалансовый);

      Если Счет.Активный=1 Тогда

        СчетXML.УстановитьАтрибут("вид","активный");

      ИначеЕсли Счет.Активный=2 Тогда

        СчетXML.УстановитьАтрибут("вид","пассивный");

      Иначе

        СчетXML.УстановитьАтрибут("вид","активно-пассивный");

      КонецЕсли;

      СчетXML.Значение=Счет.Наименование;

    Иначе

      Если Счет.ПринадлежитГруппе(Родитель)=1 Тогда

        СубсчетXML=СчетXML.СоздатьПодчиненныйЭлемент("Субсчет");

        СубсчетXML.УстановитьАтрибут("Код", Счет.Код);

        // аналогично устанавливаем все атрибуты на элемент СубсчетXML

        СубсчетXML.Значение=Счет.Наименование;

      КонецЕсли;

    КонецЕсли;

  КонецЦикла;

  Корень.Записать(КаталогПрограммы()+"plan.xml");

КонецПроцедуры

В результате будет получен файл, вот его фрагмент:

Код

<?xml version="1.0" encoding="windows-12Sl" ?> - <ПланСчетов>
<Счет Код="00" Валютный="0" Количественный="0" Забалансовый="0" вид="активно-пассивный">Вспомогательный</Счет>
- <Счет Код="01" Валютный="0" Количественный="0" Забалансовый="0" вид="активный">
Основные средства
<Субсчет Код="01.1" Валютный="0" Количественный="0" Забалансовый="0"
вид="активный">ОС в организации</Субсчет> <Субсчет Код="01.2" Валютный="0" Количественный="0" Забалансовый="0"
вид="активный">Выбытие ОС</Субсчет> </Счет>
- <Счет Код="02" Валютный="0" Количественный="0" Забалансовый="0" вид="пассивный">
Амортизация ОС

А теперь приведем код для импорта плана счетов из xml-файла в новую конфигурацию. Код модуля соответствующей обработки должен содержать процедуру Выполнить(), которая имеет такой вид.

Код 1C v 7.x

 Процедура Выполнить()

  Если ЗагрузитьВнешнююКомпоненту(КаталогПрограммы()+"v7plus.dll")<>1 Тогда

    Предупреждение("Внешняя компонента не найдена");

    Возврат;

  КонецЕсли;

  Анализатор=СоздатьОбъект("AddIn.XMLParser");

  Файл=Анализатор.СоздатьДокумент();

  Файл.Загрузить(КаталогПрограммы()+"plan.xml");

  План=Файл.ВыбратьУзел("ПланСчетов");

  кол=План.КоличествоПодчиненных();

  Счет=СоздатьОбъект("Счет.Основной");

  Для инд=1 по кол Цикл

    СчетXML=План.ПолучитьПодчиненныйПоНомеру(инд);

    КолСубсчетов=СчетXML.КоличествоПодчиненных();

    // подчиненным элементом является и содержимое элемента

    Если КолСубсчетов>1 Тогда

      Счет.Новый(1);

    Иначе

      Счет.Новый(0);

    КонецЕсли;

    Счет.Код=СчетXML.ПолучитьАтрибут("Код");

    Счет.Наименование=СчетXML.Значение;

    Счет.Валютный=СчетXML.ПолучитьАтрибут("Валютный");

    Счет.Количественный=СчетXML.ПолучитьАтрибут("Количественный");

    Счет.Забалансовый=СчетXML.ПолучитьАтрибут("Забалансовый");

    Если СчетXML.ПолучитьАтрибут("вид")="активный" Тогда

      Счет.Активный=1;

    ИначеЕсли СчетXML.ПолучитьАтрибут("вид")="пассивный" Тогда

      Счет.Активный=2;

    Иначе

      Счет.Активный=3;

    КонецЕсли;

    Счет.Записать();

    Если КолСубсчетов>1 Тогда

      Счет1=СоздатьОбъект("Счет.Основной");

      Для инд1=2 По кол_субсчетов Цикл

        Субсчет=СчетXML.ПолучитьПодчиненныйПоНомеру(инд1);

        Счет1.Новый(0);

        Счет1.Код=Субсчет.ПолучитьАтрибут("Код");

        // аналогично устанавливаются все атрибуты создаваемого субсчета

        Счет1.Записать();

      КонецЦикла;

    КонецЕсли;

  КонецЦикла;

Категория: XML, DBF, TXT, CSV