Циклы применяются для выполнения каких либо повторяющихся действий, возможные варианты перебора в цикле:

Перебираем строки с помощью цикла Для каждого

Код 1C v 8.3

 Для каждого ТекСтрока Из КоллекцияСтрок Цикл

// код обработки

КонецЦикла;   

Перебираем строки с помощью цикла Пока

Код 1C v 8.3

 Пока л < КолСтрок Цикл

	// код обработки, например л=л+1;

КонецЦикла;   

Перебираем строки с помощью цикла Для

Код 1C v 8.3

 Для л=0 по КолСтрок Цикл

// код обработки, например л=л+1;

КонецЦикла   

Еще вариант, но советую его использовать только в без выходных ситуациях, Если

Код 1C v 8.3

 ~НачалоЦикла:

Если л <> КоличествоИтераций Тогда 

// код обработки, например л=л+1;

	Перейти ~НачалоЦикла;

КонецЕсли;   

Примеры циклов

Код 1C v 8.2 УП

 &НаКлиенте

Процедура ВыполнитьКод(Команда)

 

    /// Как организовать цикл в 1с 8.3, 8.2

 

    // Для Цикл

    Для Счетчик = 1 По 5 Цикл

        Сообщить(Счетчик); // 1 2 3 4 5

    КонецЦикла;

 

    // Для Каждого Цикл

 

    Дни = Новый Массив();

    Дни.Добавить("Понедельник");

    Дни.Добавить("Вторник");

    Дни.Добавить("Среда");

 

    Для Каждого Элемент Из Дни Цикл

        Сообщить(Элемент); // Понедельник Вторник Среда

    КонецЦикла;

 

    // Пока Цикл

    Счетчик = 0;

    Пока Счетчик < Дни.Количество() Цикл        

        Сообщить(Дни[Счетчик]); // Понедельник Вторник Среда

        Счетчик = Счетчик + 1;     

    КонецЦикла;     

 

    /// Как организовать обратный цикл в 1с 8.3, 8.2     

 

    Счетчик = Дни.Количество() - 1;     

    Пока Счетчик >= 0 Цикл

        Сообщить(Дни[Счетчик]); // Среда Вторник Понедельник

        Счетчик = Счетчик - 1;

    КонецЦикла;

 

    /// Как прервать цикл в 1с 8.3, 8.2

 

    Для Счетчик = 1 По 5 Цикл

        Если Счетчик > 2 Тогда

            Прервать;

        КонецЕсли;

        Сообщить(Счетчик); // 1 2

    КонецЦикла;

 

    /// Как принудительно продолжить цикл в 1с 8.3, 8.2

 

    Для Счетчик = 1 По 5 Цикл

        Если Счетчик <> 3 Тогда

            Продолжить;

        КонецЕсли;

 

        Сообщить(Счетчик); // 3

    КонецЦикла;   

 

КонецПроцедуры

   

А какой цикл работает быстрее?

Итак, я нашел пять способов, как можно организовать цикл средствами 1С.

Первый вид цикла, назовем его условно «Для По» выглядит так:

Код 1C v 8.х

 Для н = 0 по КоличествоИтераций Цикл

КакиеТоДействия();

КонецЦикла;   

Второй вид «Для Каждого»:

Код 1C v 8.х

 Для Каждого ЭлементКоллекции из Коллекция Цикл

КакиеТоДействия();

КонецЦикла;   

Третий «Пока»:

Код 1C v 8.х

 Пока н <> КоличествоИтераций Цикл

КакиеТоДействия();

н = н + 1;

КонецЦикла;   

Далее вспомнил ассемблерную молодость & цикл «Если»:

Код 1C v 8.х

 ~НачалоЦикла:

Если н <> КоличествоИтераций Тогда

КакиеТоДействия();

н = н + 1;

Перейти ~НачалоЦикла;

КонецЕсли;   

Ну и напоследок «Рекурсия»

Код 1C v 8.х

 Процедура РекурсивныйЦикл(н, КоличествоИтераций)

КакиеТоДействия();

Если н <> КоличествоИтераций Тогда

РекурсивныйЦикл(н+1, КоличествоИтераций);

КонецЕсли;

КонецПроцедуры   

Естественно, что относить рекурсию к циклам не совсем корректно, но тем ни менее с её помощью можно добиться похожих результатов. Сразу оговорюсь, что в дальнейшем тестировании рекурсия не участвовала. Во первых все тесты проводились при 1 000 000 итераций, а рекурсия выпадает уже при 2 000. Во вторых скорость рекурсии в десятки раз меньше, чем скорость остальных циклов.

Последнее отступление. Одним из условий было выполнение в цикле каких-либо действий. Во первых пустой цикл используется очень редко. Во вторых цикл «ДляКаждого» используется для какой-либо коллекции, а значит и остальные циклы должны работать с коллекцией, чтобы тестирование проходило в одинаковых условиях.

Ну что ж, поехали. В качестве тела цикла использовалось чтение из заранее заполненного массива.

Код 1C v 8.х

 ПриемникТестовогоЗначения = ТестовыйМассив.Получить(н);   

или, при использовании цикла «Для Каждого»

Код 1C v 8.х

 ПриемникТестовогоЗначения = Элем;   

Тестирование проводилось на платформе 8.3.5.1231 для трех видов интерфейса (Обычное приложение, Управляемое приложение и Такси).

Результаты для 8.3.5.1231

Интерфейс	ДляПо	ДляКаждого	Пока	Если
Обычное приложение	5734,2	4680,4	7235,4	7263,0
Управляемое приложение	5962,4	4882,6	7497,4	7553,6
Такси	5937,2	4854,6	7500,8	7513,0

Числа это время в миллисекундах полученное с помощью функции ТекущаяУниверсальнаяДатаВМиллисекундах(), которую я вызывал до цикла и после его завершения. Числа дробные, потому что я использовал среднее арифметическое пяти замеров. Почему я не использовал Замер производительности? У меня не было цели замерить скорость каждой строчки кода, только скорость циклов с одинаковым результатом работы.

Казалось бы и все, но & тестировать так тестировать!

Результаты для 8.2.19.106

Интерфейс	ДляПо	ДляКаждого	Пока	Если
Обычное приложение	4411,8	3497,2	5432,0	5454,0
Управляемое приложение	4470,8	3584,8	5522,6	5541,0

В среднем платформа 8.2 на 25% быстрее, чем 8.3. Я немножко не ожидал такой разницы и решил провести тест на другой машине. Скажу только, что там 8.2 была быстрее процентов на 20.

Почему? Не знаю, дезасемблировать ядро в мои планы не входило, но в замер производительности я все же заглянул. Оказалось, что сами циклические операции в 8.3 проходят несколько быстрее, чем в 8.2. Но на строке

Код 1C v 8.х

 ПриемникТестовогоЗначения = ТестовыйМассив.Получить(н);   

то есть при считывании элемента коллекции в переменную происходит значительное снижение производительность.

Для себя я сделал несколько выводов:

1. Если есть возможность использовать специализированный цикл & «Для Каждого», то лучше использовать его. Кстати, сам по себе он отрабатывает дольше чем другие циклы, но скорость доступа к элементу коллекции у него на много выше.

2. Если заранее знаешь количество итераций & используй «Для По». «Пока» отработает медленнее.

3. Если использовать цикл «Если» & другие программисты тебя явно не поймут.

---

В статье использованы материалы с хабра и хелпме

Для реализации расшифровки отчетов, выполненных при помощи системы компоновки данных, в платформе реализован объект ОбработкаРасшифровкиКомпоновкиДанных, который позволяет сформировать настройки компоновки данных, которые можно использовать для формирования отчета - расшифровки.

В некоторых ситуациях использовать возможности объекта ОбработкаРасшифровкиКомпоновкиДанных не представляется возможным, и возникает необходимость программного получения значений полей, которые присутствовали в некоторой ячейке табличного документа, для которой можно получать расшифровку.
В данной статье описывается, каким образом устроен объект ДанныеРасшифровки и как его можно использовать для получения значений полей и полей группировок.

ВАЖНО!
Для того, чтобы при выводе отчета объект ДанныеРасшифровки был заполнен, следует его создать при компоновке макета и передать в процессор компоновки данных.
Для создания объекта ДанныеРасшифровки, при вызове метода Выполнить компоновщика макета, следует передать переменную, в которую требуется поместить созданный объект.
Пример:

Код 1C v 8.х

     МакетКомпоновкиДанных = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки, ДанныеРасшифровки);   

Для того, чтобы данные расшифровки заполнились при формировании результата, необходимо передать объект ДанныеРасшифровки в метод Инициализировать процессора компоновки данных.
Пример:

Код 1C v 8.х

     ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновкиДанных, , ДанныеРасшифровки);   

Если используется метод объекта Отчет СкомпоноватьРезультат, то для заполнения данных расшифровки следует передать в метод переменную, в которую необходимо поместить данные расшифровки.
Пример:

Код 1C v 8.х

 СкомпоноватьРезультат(ЭлементыФормы.Результат, ДанныеРасшифровки);   

Если отчет формируется при помощи стандартной команды отчета Сформировать, то данные расшифровки помещаются в свойство расширения формы отчета ДанныеРасшифровки.

Объект ДанныеРасшифровки содержит настройки, для которых этот объект был сформирован (заполняются при генерации макета компоновки данных) и коллекции элементов расшифровки (заполняются при формировании результата).

Каждый элемент расшифровки имеет идентификатор (который и помещается в ячейку табличного документа - результата) и массив идентификаторов родительских элементов расшифровки. Имея идентификатор расшифровки из объекта ДанныеРасшифровки можно получить элемент расшифровки при помощи метода Получить или при помощи операции [].
Пример:

Код 1C v 8.х

 Элемент = ДанныеРасшифровки.Элементы[ИдентификаторРасшифровки];   

Существуют два типа элементов расшифровки: ЭлементРасшифровкиКомпоновкиДанныхПоля и ЭлементРасшифровкиКомпоновкиДанныхГруппировка.

ЭлементРасшифровкиКомпоновкиДанныхПоля содержит список значений полей, которые присутствуют в элементе расшфровки. В каждом значении имеется указание того, для какого поля содержится значение (соответствует пути к данным поля в терминах настроек компоновки данных, например: Номенклатура.ОсновнойПоставщик), само значение поля, и указание того, что значение было получено для иерархической записи (имеет значение Истина, если значение было получено от иерархической записи).

ЭлементРасшифровкиКомпоновкиДанныхГруппировка содержит имя группировки, для которой был создан элемент (соответствует идентификатору группировки в настройках из данных расшифровки).

При компоновке результата процессор компоновки данных заполняет данные расшифровки следующим образом:
1. При выводе группировки помещает в данные расшифровки элемент типа ЭлементРасшифровкиКомпоновкиДанныхГруппировка, с указанием того, какая группировка выводится. Если выводится вложенная группировка, то в качестве идентификатора родительского элемента группировки будет использован идентификатор расшифровки от родительской группировки.

2. В качестве дочернего к элементу группировки выдает в данные расшифровки элемент типа ЭлементРасшифровкиКомпоновкиДанныхПоля, в который выдает значения полей, по которым осуществлялась группировка. Например, если группировка осуществлялась по полю Номенклатура.ОсновнойПоставщик, то в значениях полей будет находиться значение для этого поля. При этом, если группировка выполнялась по иерархии и в настоящий момент выдавалась иерархическая запись, то в значении поля группировки об этом будет сказано в свойстве Иерархия.

3. При выводе ячеек процессор компоновки получит из каждой ячейки список полей, которые нужно помещать в ее расшфровку и создаст в данных расшифровки для ячейки элемент типа ЭлементРасшифровкиКомпоновкиДанныхПоля, в который поместит значения полей. При этом родительским для нового элемента будет являться элемент, содержащий значения полей группировки, т.е. элемент, заполненный на втором шаге. Если выводился элемент для ресурсов на пересечении группировок кросс-таблицы, то у элемента будет установлено два родительских элемента - один от группировки - строки и один от группировки - колонки. Идентификатор вновь созданного элемента будет помещен в качестве значения расшифровки в ячейку результирующего табличного документа. Именно этот идентификатор придет в обработчик расшифровки, если пользователь потребует расшифровать в отчет в данной ячейке.

Обработка расшифровки.

При обработке расшифровки, в обработчик поля табличного документа будет передаваться идентификатор расшифровки. По этому идентификатору из объекта данных расшифровки можно получить элемент расшифровки. В этом элементе будут находиться значения полей, которые предполагалось выдавать в качестве расшифровки в данной ячейке.

Если необходимо получать значения полей - группировок для текущего элемента, то следует рекурсивно получить все родительские элементы расшифровки и получить из них значения полей.

Регулярные выражения (Regular Expressions) являются известным и мощным средством для поиска, тестирования и замены подстрок. Эта технология доступна и в 1С - через объект VBScript.RegExp. Нужный объект уже встроен в современные версии Windows (начиная с Windows 98), и устанавливать дополнительно ничего не нужно.
Приведенные ниже примеры были протестированы в 1С:Предприятие 7.7; для 1С:Предприятие 8.x изменяется способ создания объекта:

Код 1C v 8.х

 RegExp = Новый COMОбъект("VBScript.RegExp");   

Кроме того, там уже есть логические константы Истина и Ложь - объявлять их не нужно.

Более подробное описание самой технологии RegExp (что означают те или иные значки или скобочки, или какие шаблоны поиска или замены можно использовать в типичных ситуациях) можно найти в специальной литературе (например Бен Форта "Освой самостоятельно регулярные выражения (regexp) за 10 минут") или на сайтах в сети Internet.

Код 1C v 7.x

 ///////////////////////////////////////////////////////////////////////

//Поиск вхождений подстроки

Процедура RegExp_Exec()

    

    //Для 1С 7.7:

    Истина=-1;

    Ложь=0;

    RegExp = CreateObject("VBScript.RegExp");

    

    RegExp.IgnoreCase = Ложь; //Игнорировать регистр

    RegExp.Global = Истина; //Поиск всех вхождений шаблона

    RegExp.MultiLine = Ложь; //Многострочный режим

    

    RegExp.Pattern = "<[^>]*>"; //Ищем теги HTML

    Matches=RegExp.Execute("Это <hr> строка <br> с тегами HTML");

    ЧислоВхождений=Matches.Count();

    Если ЧислоВхождений>0 Тогда 

        Для к = 0 По ЧислоВхождений-1 Цикл

            Match = Matches.Item(к);

            Сообщить("Найден тег:"+ Match.Value);

        КонецЦикла;

    Иначе

        Сообщить("Вхождений шаблона не найдено");

    КонецЕсли;

    //Выдаст в окно сообщений:    

    //Найден тег:<hr>

    //Найден тег:<br>    

КонецПроцедуры

Более продвинутый пример разбора HTML использует подвыражения (SubMatches) и позволяет находить как сами теги, так и текст между ними.

Код 1C v 7.x

 ///////////////////////////////////////////////////////////////////////

//Поиск вхождений подстроки с использованием подвыражений

Процедура RegExp_Exec1()

    

    //Для 1С 7.7:

    Истина=-1;

    Ложь=0;

    RegExp = CreateObject("VBScript.RegExp");

    

    RegExp.IgnoreCase = Ложь; //Игнорировать регистр

    RegExp.Global = Истина; //Поиск всех вхождений шаблона

    RegExp.MultiLine = Ложь; //Многострочный режим

    

    RegExp.Pattern = "([^<]*)(<[^>]*>)([^<]*)"; //Ищем теги HTML, а также текст до и после тега

    Matches=RegExp.Execute("  <tr><td id=aaa>Дятел <td> долбит <td> сосну </tr>");

    ЧислоВхождений=Matches.Count();

    Если ЧислоВхождений>0 Тогда 

        Для к = 0 По ЧислоВхождений-1 Цикл

            Match = Matches.Item(к);

            

            SubMatches = Match.SubMatches;

            ЧислоПодвыражений=SubMatches.Count();

            Для н = 0 По ЧислоПодвыражений-1 Цикл

                SubMatch=SubMatches.Item(н);

                Если SubMatch="" Тогда

                    Продолжить;

                КонецЕсли;    

                

                Сообщить("Подстрока: "+SubMatch);

            КонецЦикла;    

        КонецЦикла;

    Иначе

        Сообщить("Вхождений шаблона не найдено");

    КонецЕсли;

КонецПроцедуры



//Выводит в окно сообщений:

//Подстрока:   

//Подстрока: <tr>

//Подстрока: <td id=aaa>

//Подстрока: Дятел 

//Подстрока: <td>

//Подстрока:  долбит 

//Подстрока: <td>

//Подстрока:  сосну 

//Подстрока: </tr>

Часто регулярные выражения используются для тестирования строк, например пользовательского ввода.
Этот пример позволяет узнать, является ли строка целым числом.

Код 1C v 7.x

 ///////////////////////////////////////////////////////////////////////

//Проверка подстроки

Процедура RegExp_Test()

    RegExp = CreateObject("VBScript.RegExp");

    RegExp.Pattern =  "^\d+$"; //Шаблон, который соответствует целому числу

    стр="12345";//Строка, которую тестируем

    Если RegExp.Test(стр)=0 Тогда

        Сообщить("Это не целое число");

    Иначе

        Сообщить("Это целое число");

    КонецЕсли;

    //Выдаст в окно сообщений:    

    //"Это целое число"

КонецПроцедуры

Регулярные выражения поддерживают не только поиск, но и замену текста. При этом найденные подвыражения (в круглых скобках) могут быть представлены в строке замены как $1, $2 и т. д.
(знак доллара используется в VBScript.RegExp; в других средах программирования, например в JavaScript, используемый для этой цели символ может отличаться).

Код 1C v 7.x

 ///////////////////////////////////////////////////////////////////////

//Замена текста в подстроке

Процедура RegExp_Replace()

    

    //Строка, где мы будем производить замены

    стр="Дятел долбил сосну";

    

    Истина=-1;

    Ложь=0;

    RegExp = CreateObject("VBScript.RegExp");

    

    RegExp.IgnoreCase = Истина; //Игнорировать регистр

    RegExp.Global = Истина; //Поиск всех вхождений шаблона

    RegExp.MultiLine = Истина; //Многострочный режим

    

    

    RegExp.Pattern = "(долбил)"; 

    

    стр=RegExp.Replace(стр, "про$1"); 

    Сообщить(стр);

    //Выдаст в окно сообщений:    

    //"Дятел продолбил сосну"

КонецПроцедуры

Источник

В большинстве случаев для установки 1C:Предприятия 8.х в варианте “клиент-сервер” достаточно запуска программы установки 1С:Предприятия 8.х. При этом сервер 1С:Предприятия получает стандартные значения параметров, необходимые для его нормального функционирования.

Рассмотрим установку сервера 1С:Предприятия более детально. В процессе установки сервера 1С:Предприятия 8.х программа установки 1С:Предприятия 8.х выполняет следующие действия:

* Копирует загрузочные модули сервера 1С:Предприятия в каталог, указанный программе установки 1С:Предприятия в качестве конечной папки.
* Если в процессе установки выбрано "Создать пользователя USR1CV81", то создает пользователя USR1CV81. От имени этого пользователя работает сервер 1С:Предприятия 8.1, если он запускается как сервис. Ему доступны только те ресурсы, которые необходимы серверу 1С:Предприятия. Важно, что серверу 1С:Предприятия для работы необходимы два каталога: общий каталог с данными сервера (обычно "C:\Program Files\1cv81\server") и каталог временных файлов (обычно "C:\Documents and Settings\usr1cv81\Local Settings\Temp" или "C:\WINNT\Temp"). Пользователь USR1CV81 получает права на общий каталог с данными сервера. Каталог временных файлов обычно доступен всем пользователям.
* Если в процессе установки включено "Установить сервер 1С:Предприятия 8.1 как сервис Windows", то регистрирует в Windows сервис агента сервера 1С:Предприятия и запускает его. При первом запуске создается кластер серверов 1С:Предприятия с настройками по умолчанию. В нем один рабочий сервер и один рабочий процесс. Адрес рабочего сервера совпадает с именем компьютера, на котором выполнена установка.

Пользователь USR1CV81 или USR1CV82 и его права

Сервер 1С:Предприятия является серверным приложением работа которого не должна зависеть от того, какой пользователь вошел в серверный компьютер в интерактивном режиме, если вообще кто-нибудь вошел. Поэтому при установке сервера 1С:Предприятия желательно создать специального пользователя USR1CV81, наделенного правами, минимально необходимыми для сервера 1С:Предприятия, и не предназначенного для интерактивного входа. Сервер 1С:Предприятия представляется системе Windows пользователем USR1CV81.

Рассмотрим подробнее права, устанавливаемые пользователю USR1CV81. Сервер 1С:Предприятия использует следующие каталоги:

* Каталог загрузочных модулей находится в каталоге, заданном программе установки 1С:Предприятия в качестве конечной папки. В нем расположены загрузочные модули сервера 1С:Предприятия. Пользователь USR1CV81 необходимы права на чтение данных и запуск программ из этого каталога и его подкаталогов. Он получает эти права неявно, благодаря включению в группу Users.
* Каталог данных сервера обычно имеет имя "C:\Program Files\1cv81\server". Пользователю USR1CV81 необходимы полные права на этот каталог. Программа установки 1С:Предприятия при создании пользователя USR1CV81 наделяет его правами на этот каталог.
* Каталог временных файлов обычно имеет имя "C:\Documents and Settings\usr1cv81\Local Settings\Temp" или "C:\WINNT\Temp", которое определяется значением переменной TEMP окружения пользователя или переменной TEMP системного окружения. Посмотреть значение этой переменной можно в диалоге System Properties (Start -> Settings -> Control Panel -> System -> Advanced -> Environment Variables). Программа установки 1С:Предприятия задает пользователю USR1CV81 полные права на этот каталог. Обычно при установки Windows каталог временных файлов доступен всем пользователям посредством включения в его список доступа группы CREATOR OWNER. Однако, это доступ не полный. В частности, всем пользователям не доступна операция поиска файлов в этом каталоге. Установка пользователю USR1CV81 полных прав на каталог временных файлов позволяет серверу 1С:Предприятия выполнять все необходимые ему операции. Посмотреть список доступа можно в диалоге свойств каталога на закладке Security. Наличие группы CREATOR OWNER позволяет обращаться к каталогу любому пользователю, создающему какие-нибудь файлы в этом каталоге или владеющему какими-нибудь файлами в этом каталоге. При этом в списке доступа созданного файла вместо группы CREATOR OWNER будет записан пользователь, создавший файл. Среди пользователей, которым разрешен доступ в этот каталог, должен быть и пользователь USR1CV81, наделенный полными правами на этот каталог.
Важно иметь в виду, что каталог временных файлов определенного пользователя (в том числе и пользователя USR1CV81) определяется комбинацией переменных окружения этого пользователя и системных переменных окружения. Чтобы узнать этот каталог, программа установки 1С:Предприятия запрашивает контекст пользователя USR1CV81. В для этого в Windows 2000 пользователю, от имени которого запускается программа установки 1С:Предприятия, могут потребоваться привилегии: Act as part of the operating system и Bypass traverse checking. Проверить привилегии пользователя можно утилитой Local Sequrity Settings в ветке Local Policies -> User Rights Assignment. В процессе установки нового программного обеспечения программа установки обычно получает эти привилегии автоматически.

Регистрация сервера 1С:Предприятия как сервиса Windows

Сервер 1С:Предприятия является простым консольным Windows приложением и может быть запущен интерактивно. Однако для постоянного использования это неудобно, поскольку ставит запуск сервера 1С:Предприятия от входа итнерактивного пользователя в серверный компьютер. Чтобы исключить эту зависимость, сервер 1С:Предприятия может запускаться как сервис Windows. Для этого он должен быть зарегистрирован в менеджере сервисов Windows.

Для просмотра списка сервисов Windows и их параметров предназначена утилита Component Services (Start -> Settings -> Control Panel -> Administrative Tools -> Services). Сервер 1С:Предприятия представлен в списке сервисов сервисом "Агент сервера 1С:Предприятия 8.1". Параметры сервиса определяют запуск процесса "Агент сервера 1С:Предприятия" (ragent), пользователя, от имени которого он запускается, а также способ перезапуска в аварийных ситуациях.

В диалоге свойств сервиса "Агент сервера 1С:Предприятия 8.1" на закладке General показана строка запуска процесса ragent, который является Агентом сервера 1С:Предприятия. Обычно эта строка имеет вид:
"C:\Program Files\1cv81\bin\ragent.exe" -srvc -agent -regport 1541 -port 1540 -range 1560:1591 -d "C:\Program Files\1cv81\server"

В ней указано, что:

* процессом Агента сервера является загрузочный модуль "C:\Program Files\1cv81\bin\ragent.exe";
* процесс ragent запускается как сервис Windows и должен управляться менеджером сервисов (-srvc);
* используется как Агент сервера 1С:Предприятия (-agent);
* при первом запуске сервиса должен быть создан кластер с параметрами по умолчанию и главным IP-портом номер 1541 (-regport 1541). По этому порту клиентские приложения должны соединяться с информационными базами, зарегистрированными в кластере;
* IP-порт агента сервера должен иметь номер 1540 (-port 1540). По этому порту Консоль кластера должна соединяться с центральным сервером для выполнения административных функций;
* при запуске процессов кластера на данном сервере им будут динамически назначаться IP-порты из диапазона 1560-1591 (-range 1560:1591).
* общие данные кластера будут размещены в каталоге "C:\Program Files\1cv81\server" (-d "C:\Program Files\1cv81\server").

Сервис "Агент сервера 1С:Предприятия 8.1" может быть добавлен или удален не только при установке или удалении 1С:Предприятия программой установки 1С:Предприятия 8.1, но и вручную. Для этого можно исполнить из командной строки утилиту ragent, указав ей соответствующие параметры.

Для создания сервиса нужно указать параметр -instsrvc и параметры: -usr - имя пользователя, от имени которого должен быть запущен сервис, -pwd - пароль этого пользователя. При этом остальные параметры станут параметрами строки запуска Агента сервера 1С:Предприятия как сервиса. Например, для стандартной регистрации сервиса Агента сервера 1С:Предприятия в отладочном режиме набор параметров должен быть таким:

"C:\Program Files\1cv81\bin\ragent.exe" -instsrvc -usr .\USR1CV81 -pwd Password -regport 1541 -port 1540 -range 1560:1591 -d "C:\Program Files\1cv81\server" -debug

Для удаления сервиса нужно указать параметр -rmsrvc. Например:
"C:\Program Files\1cv81\bin\ragent.exe" -rmsrvc

Иногда бывает полено изменить строку запуска Агента сервера или другие параметры сервиса Агента, например, включить режим отладки, или создать несколько сервисов разных версий. Диалог свойств сервиса не позволяет редактировать строку запуска сервисного приложения и некоторые другие параметры, например, идентификатор сервиса. Для редактирования потребуется утилита regedit, предназначенная для просмотра и редактирования системного реестра Windows.

Внимание!
Редактирование системного реестра Windows требует крайней осторожности, поскольку ошибочные изменения в нем могут привести операционную систему в неработоспособное состояние.

Запустите утилиту regedit (откройте Start -> Run и наберите regedit) и выберите ветку:
HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\1C:Enterprise 8.1 Server Agent

Среди ее параметров есть параметр ImagePath, значением которой является строка запуска Агента сервера 1С:Предприятия. Здесь можно добавить новые параметры строки запуска или поменять значения существующих. Полный список возможных параметров приведен в книге "1С:Предприятие 8.1 Клиент-сервер" документации.

При необходимости регистрации нескольких независимых сервисов Агента сервера 1С:Предприятия нужно указать им разные загрузочные модули, разные порты и разные каталоги данных кластера. Еще требуется зарегистрировать их с разными идентификаторами сервисов. Это можно сделать так:

* Создать первый сервис:
"C:\Program Files\1cv81\bin\ragent.exe" -srvc -agent -regport 1541 -port 1540 -range 1560:1591 -d "C:\Program Files\1cv81\server"

* При помощи утилиты regedit изменить идентификатор зарегистрированного сервиса. Для этого: выбрать ветку
HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\1C:Enterprise 8.1 Server Agent
и изменить ее имя, например на:
HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\1C:Enterprise 8.1 Server Agent First
* Создать второй сервис:
"C:\Program Files\1cv81_10\bin\ragent.exe" -srvc -agent -regport 1641 -port 1640 -range 1660:1691 -d "C:\Program Files\1cv81_10\server"

* Быть может, его идентификатор тоже изменить. Для этого: выбрать ветку
HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\1C:Enterprise 8.1 Server Agent
и изменить ее имя, например на:
HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\1C:Enterprise 8.1 Server Agent Second

Что не может сделать программа установки 1С:Предприятия?

Как уже говорилось, программа установки 1С:Предприятия копирует загрузочные модули 1С:Предприятия и выполняет необходимую регистрацию в COM и в менеджере сервисов Windows. Выше приведена информация, необходимая для понимания внутренних механизмов этой регистрации. Если на серверном компьютере установлен не только сервер, но и клиентская часть 1С:Предприятия, то она готова к работе сразу после установки (и подключения ключей защиты).

Чтобы сервер 1С:Предприятия был доступен с других компьютеров в локальной сети, необходимо проверить сетевые настройки на серверном и клиентском компьютере, а также для сети в целом. Для передачи данных между клиентскими приложениями и сервером 1С:Предприятия, а также между процессами кластера серверов используется TCP/IP. От правильности его настройки зависит работа 1С:Предприятия в варианте клиент-сервер.

Процессы кластера серверов 1С:Предприятия соединяются друг с другом по адресам, определенным в качестве значений свойства "Компьютер" диалога свойств рабочих серверов. Для кластера необходимо, чтобы значением свойства "Компьютер" был либо IP-адрес в точечной нотации, либо такой символический адрес, по которому может быть определен IP адрес при помощи функции gethostbyname, определенной в программном интерфейсе протокола TCP. Определение IP-адреса выполняется либо на основании локальной таблицы символических адресов (C:\WINNT\system32\drivers\etc\hosts), либо по таблицам адресов в доступных DNS серверах. Если по символическому адресу рабочего сервера его IP-адрес не определяется или определяется неправильно (например, IP-адрес не совпадает с фактическим IP-адресом данного компьютера), то кластер работать не будет. Важно, чтобы имена компьютеров и их адреса, определенные в Windows на каждом из рабочих серверов кластера, не противоречили их именам в DNS.

На каждом рабочем сервере процессы кластера используют следующие порты: IP порт рабочего сервера (обычно 1540); IP порты из диапазонов IP портов рабочего процесса (обычно 1560-1591). Кроме того, на центральном сервере кластера используется порт кластера (обычно 1541). Если в системе используются сетевые экраны, то передача данных по этим портам должна быть разрешена. Вместо разрешения портов из приведенного списка можно разрешить передачу данных процессам кластера (ragent, rmngr, rphost).

Соединение клиентского приложения 1С:Предприятия с сервером выполняется в 2 этапа. Сначала оно устанавливает соединение с менеджером кластера. При этом используется адрес центрального сервера (символический или числовой) и порт кластера (обычно 1541). Далее клиентское приложение устанавливает соединение с одним из рабочих процессов. В качестве его адреса используется значение свойства "Компьютер" соответствующего рабочего сервера и порт рабочего процесса, который выбирается из диапазона IP портов рабочего сервера. Передача данных на эти порты должна быть разрешена во всех сетевых экранах на маршруте от компьютера клиентского приложения до компьютеров кластера серверов 1С:Предприятия. Определение IP адреса серверных процессов выполняется при помощи функции gethostbyname на компьютере клиента. Важно, чтобы имена центрального и рабочих серверов и их адреса, определенные в Windows на каждом из серверов кластера, не противоречили их именам в DNS, доступном компьютеру клиента.

И последнее. Очевидно, что для успешного доступа к серверу 1С:Предприятия с других компьютеров он должен быть в сети и должны быть выполнены необходимые для этого настройки. Подключение к сети и методика настройки относятся к администрированию сетей на базе Microsoft Windows и описаны в соответствующих инструкциях.

Особенности настройки SQL-сервера

1С:Предприятие в варианте «клиент-сервер» использует для хранения данных SQL-сервер. При этом к SQL-серверу обращается только Сервер 1С:Предприятия. Клиенты 1С:Предприятия непосредственного доступа к SQL-серверу не имеют. Установка и настройка SQL-сервера подробно описана в документации по Microsoft SQL Server. Для успешной работы Сервера 1С:Предприятия с SQL-сервером необходимо обратить особое внимание на следующие настройки.

* Необходимые компоненты SQL-сервера. Для доступа к SQL-серверу со стороны Сервера 1С:Предприятия на компьютере Сервера 1С:Предприятия должны быть установлены компоненты Microsoft Data Access 2.6 или более поздний.
* Аутентификация пользователя SQL-сервером. Права доступа к базам данных SQL-сервера определяются пользователем, от имени которого происходит обращение к базам данных. С компьютера, на котором установлен SQL-сервер, запустим утилиту SQL Server Enterprise Manager, найдем узел Local (Console Root -> Microsoft SQL Servers -> SQL Server Group -> (Local)) и откроем его свойства. На закладке Sequrity можно видеть, что SQL-сервер поддерживает два способа аутентификации пользователей: SQL Server and Windows и Windows only. Аутентификация Windows позволит Серверу 1С:Предприятия обращаться к SQL-серверу только от имени пользователя USR1CV81, что не позволяет различать права доступа до различных информационных баз, обслуживаемых одним сервером 1С:Предприятия. Рекомендуется выбирать режим SQL Server and Windows. В этом случае обращение к конкретной информационной базе будет выполняться от имени пользователя, который задан в качестве пользователя SQL-сервера при создании данной информационной базы. Важно, что этот пользователь должен иметь не только полные права на базу данных информационной базы, но и права на создание баз данных в SQL-сервере и на чтение таблиц базы данных Master.
* Сетевые протоколы для доступа к SQL-серверу. Если Сервер 1С:Предприятия и SQL-сервер размещены на разных компьютерах, то необходимо выполнить настройки сетевых протоколов доступа к SQL-серверу. Это можно сделать при помощи утилиты SQL Server Client Network Utility. На закладке General можно выбрать список сетевых протоколов, используемых для доступа к SQL-серверу. Наиболее быстрым и универсальным является использование протокола TCP/IP. При использовании других протоколов необходимо иметь в виду, что некоторые из них, например Named Pipes, выполняют дополнительную аутентификацию средствами Windows при обмене данными с SQL-сервером. В этом случае для успешной работы с SQL-сервером на компьютере с SQL-сервером должен быть зарегистрирован пользователь USR1CV81, наделенный соответствующими правами. Протокол доступа к данному SQL-серверу может быть изменен на закладке Alias.

Недавно делал перенос справочников и документов из 1С 7.7 "Зарплата и кадры" в 1С 8.1 "Управление торговым предприятием" через Com соединение. Во время переноса столкнулся с некоторыми проблемами. Одна из них - это при выполнении запроса очень важно правильно указать синтаксис передаваемых значений, особенно даты, иначе запрос не будет выполняться. Как правильно написать запрос? Смотрим:

Код 1C v 8.х

 //Создадим Com объект для подключения к 1С 77

  База77  = Новый COMObject("V77.Application");

  

  //Устанавливаем соединение  

  Открыта = База77.Initialize(База77.RMTrade,"/d" + ПутьКБазе77,"NO_SPLASH_SHOW");

 

  Если Открыта Тогда

    Предупреждение("Ошибка открытия информационной базы!");

  Иначе

    Сообщить("БАЗА ОТКРЫТА УСПЕШНО!");

  Конецесли;

 

  //Определим дату из периода за который 

  //необходимо выбрать данные

  ДатаПериода = ТекущаяДата();

  

  //Подключимся к журналу расчетов

  Зрп = База77.CreateObject("ЖурналРасчетов.Зарплата");

  

  //Получим период журнала расчета по нашей дате

  //переведем в формат без времени

  НТП = Формат(Зрп.НачалоПериодаПоДате(ДатаПериода),"ДЛФ=Д");

  КТП = Формат(Зрп.КонецПериодаПоДате(ДатаПериода),"ДЛФ=Д");

  

  //Напишем текст запроса

  //обратите внимание на установку периода в запросе

  //Если неправильно написать, будет вылазить ошибка

  ТекстЗапр =  "//{{ЗАПРОС(ВидыРасч)

  |Период с '" + НТП + "' по '" + КТП + "';

  |Вир = ЖурналРасчетов.Зарплата.ВидРасч;

  |Рез = ЖурналРасчетов.Зарплата.Результат;

  |Дни = ЖурналРасчетов.Зарплата.Дни;   

  |ДатаНачала   = ЖурналРасчетов.Зарплата.ДатаНачала;

  |ДатаОкончания   = ЖурналРасчетов.Зарплата.ДатаОкончания;  

  |Часы = ЖурналРасчетов.Зарплата.Часы;   

  |Субконто = ЖурналРасчетов.Зарплата.Субконто;  

  |Сот = ЖурналРасчетов.Зарплата.Объект;

  |КодОбъекта = ЖурналРасчетов.Зарплата.Объект.Код;

  |Функция РезСумма = Сумма(Рез);

  |Группировка Сот;

  |Группировка Вир;

  |"//}}ЗАПРОС

  ;

  

  //Создаем объект типа запрос

  Запр = База77.CreateObject("Запрос");

  

  //Выполним запрос, если успешно делаем выборку

  Если Запр.Выполнить(ТекстЗапр) <> 0 Тогда

    Пока Запр.Группировка("Сот") = 1 Цикл

      Пока Запр.Группировка("Вир") = 1 Цикл                

        //...................

        //Здесь пишем код выборки и обработки полученных данных

      Конеццикла;  

    Конеццикла;  

  Конецесли;     

Если нам необходимо установить отбор в журнале, например по сотруднику, то сделать это можно следующим образом:

Код 1C v 8.х

  //в перечне полей добавляем поле код объекта (можно наименование)

"|КодОбъекта = ЖурналРасчетов.Зарплата.Объект.Код;"

//строка условия будет следующей

"|Условие(КодОбъекта = " + Сотр.код + ");"   

Из журнала расчетов можно выбрать записи без запроса, методом прямой выборки. В некоторых ситуациях этот способ может быть даже удобней чем через запрос. В данном случае синтаксис будет довольно простым:

Код 1C v 7.x

  Запр = База77.CreateObject("ЖурналРасчетов.Зарплата");

Запр.ВыбратьЗаписиПоОбъекту(Сотр,НТП,КТП);

Пока Запр.ПолучитьЗапись() = 1 Цикл

//Делаем обработку выборки

Конеццикла;

Написал Валецкий Станислав

Примеры настройки технологического журнала

Технологический журнал выключен
Если файл logcfg.xml отсутствует в каталоге C:\Program Files\1cv81\bin, то технологический журнал не создается. Если файл logcfg.xml необходим для правильной настойки дампов, то он не должен содержать ни одного элемента log. Следующий пример определяет необходимость построения полного дампа приложения при его аварийном завершении. Дампы помещаются в каталог: C:\Program Files\1cv81\bin\dumps.

Код

< config xmlns="http://v8.1c.ru/v8/tech—log">
< dump location="C:\Program Files\1cv81\bin\dumps" create="l" type="3"/>
< /config>

Полный технологический журнал
Приведенный ниже конфигурационный файл определяет вывод в технологический журнал всех событий вместе со всеми свойствами. Журнал будет сохраняться в течение недели (168 часов). Объем выводимой информации при этом будет очень большим, однако, она может быть полезна при анализе сложных нештатных ситуаций. Данную конфигурацию рекомендуется использовать на этапе тестирования и при расследовании ошибок.

Код

< config xmlns="http://v8.1c.ru/v8/tech—log">
< log location="C:\Program Files\1cv81\bin\logs" history="168"> < event>
< ne property="Name" value="" /> < /event>
< property name="al1"> < /property>
< /log>
< /config>

Обращения к СУБД
Следующий конфигурационный файл определяет, что технологический журнал будет содержать только обращения 1С:Предприятия к СУБД, а так же информацию об ошибочных ситуациях. Объем выводимой информации меньше, чем при полном технологическом журнале, но тоже может быть очень большим.

Код

< config xmlns="http://v8.1c.ru/v8/tech—log">
< log location="C:\Program Files\1cv81\bin\logs" history="168"> < event>
< eq propertу ="Name" va1ue="DBV8DBEng" /> < /event>
< event>
< eq propertу ="Name" va1ue="DBMSSQL"/> < /event>
< event>
< eq property="Name" value="DBPOSTGRS"/> < /event> < event>
< eq property="Name" value="DB2"/> < /event> < event>
< eq proper t у ="Name" va1ue="EXCP"/> < /event>
< property name="al1"> < /property>
< /log>
< /config>

Действия администратора и ошибки
Этот конфигурационный файл создает технологический журнал небольшого объема, в котором содержится информация о запуске и завершении приложений, установке и разрыве соединений с кластером серверов 1С:Предприятия, действиях администратора кластера и об ошибочных ситуациях в работе 1С:Пред приятия. Такой журнал в большинстве случаев достаточен, для расследования ошибочных ситуаций как в конфигурации, так и в технологической платформе 1С:Предприятия.

Код

< config xmlns="http://v8.1c.ru/v8/tech—log">
< log location="C:\Program Files\1cv81\bin\logs" history="168"> < event>
< event> < eq property= Name' value= PR0C"/> < /event>
< event> < eq property= Name' value= SC0M"/> < /event>
< event> < eq property= Name' value= C0NN"/> < /event>
< event> < eq property= Name' value= EXCP"/> < /event>
< event> < eq property= Name' value= ADMIN"/> < /event>
< event> < eq property= Name' value= QERR"/> < /event>
< property name="all"> < /property>
< /log>
< /config>

Ошибки и долгие операции
По сравнению с предыдущим, данный конфигурационный файл добавляет все операции, длительность которых превышает 10 секунд. Это может оказаться полезным для обнаружения действий пользователей, которые выполнялись длительное время, с целью, например, их последующей оптимизации. Длительность событий выражается в сотнях микросекунд.

Код

< config xmlns="http://v8.1c.ru/v8/tech—log">
< log location="C:\Program Files\1cv81\bin\logs" history="168"> < event>
< event> < eq property= Name' value= PR0C"/> < /event>
< event> < eq property= Name' value= SC0M"/> < /event>
< event> < eq property= Name' value= C0NN"/> < /event>
< event> < eq property= Name' value= EXCP"/> < /event>
< event> < eq property= Name' value= ADMIN"/> < /event>
< event> < eq property= Name' value= QERR"/> < /event>
< event> < gt property= Duration" value="100000"/> < /event>
< property name="al1"> < /property>
< /log>
< /config>

NULL – отсутствующие значения.
Не путать с нулевым значением! NULL – это не число, не равно пробелу, пустой ссылке, Неопределено.

NULL – типообразующее значение, т.е. есть тип NULL и единственное значение этого типа.

NULL значения появляются в запросе в следующих ситуациях:
а) Внешнее соединение, при котором не было найдено соответствующей записи в другой таблице (при левом – во второй, при правом – в первой, при полном – в обоих)
б) Обращение к реквизитам элементов для группы и наоборот.
в) NULL в списке полей выборки (ВЫБРАТЬ)
г) Обращение к реквизитам для битой ссылки

ЕСТЬ NULL используется в операторе ВЫБРАТЬ (как бы проверя, что значение это есть пустое ( Значение ЕСТЬ NULL )):

Код 1C v 8.х

 	

ВЫБОР 

 КОГДА Значение ЕСТЬ NULL ТОГДА РезультатЕслиNULL 

 ИНАЧЕ Значение 

КОНЕЦ 	

   

еще пример:

Код 1C v 8.х

  ВЫБРАТЬ

    СправочникНоменклатуры.Наименование,

    ВЫБОР КОГДА УчетНоменклатурыОстатки.КоличествоОстаток ЕСТЬ NULL ТОГДА 0 

    ИНАЧЕ УчетНоменклатурыОстатки.КоличествоОстаток КАК КоличествоОстаток

ИЗ

    Справочник.Номенклатура КАК СправочникНоменклатуры

        ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.УчетНоменклатуры.Остатки КАК УчетНоменклатурыОстатки

        ПО УчетНоменклатурыОстатки.Номенклатура = СправочникНоменклатуры.Ссылка

ГДЕ

    СправочникНоменклатуры.ЭтоГруппа = ЛОЖЬ    

Функция ЕСТЬNULL (значение, РезультатЕслиNULL) возвращает значение своего первого параметра, в случае если он не равен NULL, и значение второго параметра в противном случае
Является свернутым ВЫБОР…КОНЕЦ, но ЕСТЬNULL предпочтительнее.

Код 1C v 8.х

 

ВЫБРАТЬ

	ЕСТЬNULL(Справочник.Номенклатура.Артикул, "---") КАК Артикул,

	Справочник.Номенклатура.Представление КАК Номенклатура

   

еще пример:

Код 1C v 8.х

 

ВЫБРАТЬ

    СправочникНоменклатуры.Наименование,

    ЕСТЬNULL(УчетНоменклатурыОстатки.КоличествоОстаток, 0) КАК КоличествоОстаток

ИЗ

    Справочник.Номенклатура КАК СправочникНоменклатуры

        ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.УчетНоменклатуры.Остатки КАК УчетНоменклатурыОстатки

        ПО УчетНоменклатурыОстатки.Номенклатура = СправочникНоменклатуры.Ссылка

ГДЕ

    СправочникНоменклатуры.ЭтоГруппа = ЛОЖЬ    

В данном примере получаются все элементы справочника номенклатуры, после чего, для каждой номенклатуры из регистра накопления получаются текущие остатки. Т.к. для номенклатуры, по которой отсутствуют остатки, виртуальная таблица остатков не запись вернет, то в результате соединения в поле "УчетНоменклатурыОстатки.КоличествоОстаток" будут значения NULL для номенклатуры, по которой не было остатков. Для того чтобы вместо значения NULL в результате запроса присутствовало значение 0, мы использовали функцию ЕСТЬNULL(), которая осуществит желаемую замену.

ЕСТЬNULL отличается от ВЫБОР по следующим причинам:
а) При ЕСТЬNULL лучше читается запрос (проще)
б) При ЕСТЬNULL, если проверяется сложное выражение, то работает быстрее, поскольку вычисляется один раз
в) При ЕСТЬNULL выражение замены приводится к типу проверяемого выражения, если оно имеет тип Строка (длина) или Число (разрядность).

Нельзя проверять значения на NULL обычным равенством, потому что в SQL действует трехзначная логика – Истина, Ложь, NULL, и результатом такого сравнения будет UNKNOWN, что в 1С 8.0 аналогично ЛОЖЬ.
NULL <> 0, поэтому при левых внешних соединениях спр. Номенклатура с таблицами остатков, цен, Контрагентов со взаиморасчетами при отсутствии таких записей там будет NULL, который не равен 0. Лучшее решение – ЕСТЬNULL