содержиттип » Поиск

Результаты по ключевому слову: содержиттип

ДеревоЗначений в ТекстовыйДокумент

Код 1C v 8.2 УП

 // Выводит данные ДереваЗначений в ТекстовыйДокумент, пригодный к рассмотрению в отладчике, окне сообщений и показу.

//

// Параметры:

//    рВетка - дерево значений, подлежащее выводу. Может иметь почти любую глубину иерархии, количество и тип колонок. Если хватит

//        объявленных позиционных строк-заполнителей, всё поместится. Если иерархия слишком глубока, строки просто надо нарастить;

//    рТекст - на входе должен быть равен Неопределено; на выходе по окончании работы содержит результатный текстовый документ;

//    рПараметры - структура дополнительных настроек, допустимые ключи:

//        Колонки - структура колонок, которые подлежат выводу. Если пуста или имеет тип, отличный от структуры, выводятся все колонки;

//           если в ключах структуры указаны имена колонок, будут выведены только они. В значениях структуры можно передать строковое

//           представление формата, согласно которому должны будут форматироваться выводимые значения. По умолчанию формата нет;

//        ПоказыватьУровни - булево, управляет выводом №№ уровней (метод Уровень()), по умолчанию выключено;

//        ШагОтступа - число, определяющее шаг в символах, используемый для показа псевдографики иерархии веток в дереве.

//

&НаСервереБезКонтекста

Процедура ВывестиДеревоЗначенийВТекст(Знач рВетка,рТекст,Знач рПараметры=Неопределено)

Попытка

    Если рТекст=Неопределено Тогда // первая итерация, шапочный вызов исходной части

        //---------------------------------------------------------------------------------------------------------------------------

        // Разбираем входные данные

        Если ТипЗнч(рВетка)<>Тип("ДеревоЗначений") Тогда Возврат КонецЕсли;

        Если ТипЗнч(рПараметры)<>Тип("Структура") Тогда рПараметры=Новый Структура КонецЕсли;

        стрКолонок=?(рПараметры.Свойство("Колонки"),рПараметры.Колонки,Неопределено);

        Если ТипЗнч(стрКолонок)<>Тип("Структура") Тогда стрКолонок=Новый Структура КонецЕсли;

        рПоказыватьУровни=?(рПараметры.Свойство("ПоказыватьУровни"),рПараметры.ПоказыватьУровни,Ложь); // затратное дело, кстати

        рШагОтступа=?(рПараметры.Свойство("ШагОтступа"),рПараметры.ШагОтступа,2); // для отображения отступа в колонке иерархии





        //---------------------------------------------------------------------------------------------------------------------------

        // Определяем максимальное количество уровней

        // Также можно получить максимальный уровень, "плоско" перебрав все строки (например, получив их через НайтиСтроки)

        // и в цикле для каждой вызывая Уровень() и определяя максимум.

        // Вариант через СКД и служебное поле "Уровень" ни на одной известной мне платформе не работоспособен (нехватка памяти).

        //

        //

        //рДеревоДляТеста=КакНибудьСкопироватьДерево(рВетка);

        //рДеревоДляТеста.Колонки.Вставить(0,"_Level",Новый ОписаниеТипов("Булево")); // самый экономный вариант, с сохранением иерархии

        //мНенужных=Новый Массив;

        //Для й=1 По рДеревоДляТеста.Колонки.Количество()-1 Цикл

        //  мНенужных.Добавить(рДеревоДляТеста.Колонки[й]);

        //КонецЦикла;

        //Для каждого кол Из мНенужных Цикл

        //  рДеревоДляТеста.Колонки.Удалить(кол);

        //КонецЦикла;

        //

        рДеревоДляТеста=рВетка; // пока сериализуем прямо всё дерево (неоптимально, но...)

        рЗапись=Новый ЗаписьXML;

        рЗапись.УстановитьСтроку();

        СериализаторXDTO.ЗаписатьXML(рЗапись,рДеревоДляТеста);

        стро=рЗапись.Закрыть();

        //

        стро=СтрЗаменить(стро,"xmlns=","xmlns:myns1C="); // иначе не будет работать XPath

        //

        рЧтение=Новый ЧтениеXML;

        рЧтение.УстановитьСтроку(стро);

        постр=Новый ПостроительDOM;

        рДокументДОМ=постр.Прочитать(рЧтение);





        рВыражение="/ValueTree/row"; максКолвоУровней=1;

        рРазыменователь=Новый РазыменовательПространствИменDOM(рДокументДОМ);

        Пока Истина Цикл

            #Если Клиент Тогда

                ОбработкаПрерыванияПользователя();

            #КонецЕсли

            рРезультат=рДокументДОМ.ВычислитьВыражениеXPath(рВыражение,рДокументДОМ,рРазыменователь,ТипРезультатаDOMXPath.Любой);

            Если рРезультат.ПолучитьСледующий()=Неопределено Тогда Прервать КонецЕсли;

            рВыражение=рВыражение+"/row";

            максКолвоУровней=максКолвоУровней+1;

        КонецЦикла;

        максКолвоУровней=максКолвоУровней-1; // можно и так: СтрЧислоВхождений(рВыражение,"/row")-1;





        //---------------------------------------------------------------------------------------------------------------------------

        // готовим исходный макет вывода

        строПробелы="                                                                                                                                                                                                                 ";

        строРазделители="===============================================================================================";

        строОтступы="___________________________________________________________________________________________"; // тут нужны чуть для другого

        //

        секШапка1="|[_HCS"+Лев(строПробелы,максКолвоУровней*рШагОтступа)+"]|"; // HierarchyColumnShow

        секГорРазделитель1="|"+Лев(строОтступы,максКолвоУровней*рШагОтступа+6)+"|"; // здесь именно Отступы!

        рШиринаКолонкиИерархии=СтрДлина(секШапка1)-2;

        строПолейШапки="#Поле _HCS

        |   #Выравнивание Центр";

        строПолейЗаписи="";

        //

        Если рПоказыватьУровни Тогда

            секШапка1=секШапка1+"[_Level]|";

            секГорРазделитель1=секГорРазделитель1+Лев(строРазделители,8)+"|";

            строПолейШапки=строПолейШапки+"

            |#Поле _Level

            |   #Выравнивание Центр";

            строПолейЗаписи="#Поле _Level

            |   #Выравнивание Центр

            |   #Забивать Истина";

        КонецЕсли;

        //

        мИменКолонок=Новый Массив;

        Для каждого кол Из рВетка.Колонки Цикл

            Если стрКолонок.Количество()<>0 и не стрКолонок.Свойство(кол.Имя) Тогда Продолжить КонецЕсли; // чётко указаны конкретные колонки

            рДлинаИмениКолонки=СтрДлина(кол.Имя);

            рНужнаяШирина=Макс(?(кол.Ширина<3,10,кол.Ширина),рДлинаИмениКолонки);

            // к сожалению, ключевое слово "#Поля" неприменимо - платформа падает - поэтому делаем всё сами

            секШапка1=секШапка1+"["+кол.Имя+Лев(строПробелы,рНужнаяШирина-рДлинаИмениКолонки)+"]|";

            секГорРазделитель1=секГорРазделитель1+Лев(строРазделители,рНужнаяШирина+1)+"=|";

            строПолейШапки=строПолейШапки+"

            |#Поле "+кол.Имя+"

            |   #Выравнивание Центр";

            рОписТипов=кол.ТипЗначения;

            Если рОписТипов.Типы().Количество()=1 и рОписТипов.СодержитТип(Тип("Булево")) Тогда

                рВыравнивание="Центр";

            ИначеЕсли рОписТипов.СодержитТип(Тип("Число")) Тогда

                рВыравнивание="Право";

            ИначеЕсли рОписТипов.СодержитТип(Тип("Строка")) и рОписТипов.КвалификаторыСтроки.Длина=0 Тогда

                рВыравнивание="ПоШирине";

            Иначе

                рВыравнивание="Лево";

            КонецЕсли;

            строПолейЗаписи=строПолейЗаписи+?(ПустаяСтрока(строПолейЗаписи),"",Символы.ПС)+"#Поле "+кол.Имя+"

            |   #Выравнивание "+рВыравнивание;

            Попытка

                Если ЗначениеЗаполнено(стрКолонок[кол.Имя]) Тогда // указан формат, уточняющий показ колонки

                    строПолейЗаписи=строПолейЗаписи+"

                    |   #Формат """+СокрЛП(стрКолонок[кол.Имя])+"""";

                КонецЕсли;

            Исключение

            КонецПопытки;

            мИменКолонок.Добавить(кол.Имя);

        КонецЦикла;

        секШапка2=СтрЗаменить(СтрЗаменить(секШапка1,"[","<"),"]",">");

        секЗапись1=секШапка1; секЗапись2=секШапка2; // пусть они по дизайну пока не отличаются

        секГорРазделитель2=СтрЗаменить(СтрЗаменить(секГорРазделитель1,"=","-"),"|","+");

        // обработаем нормальное обрамление шапки колонки иерархии

        секГорРазделитель1=СтрЗаменить(секГорРазделитель1,"_","=");

        секГорРазделитель2=СтрЗаменить(секГорРазделитель2,"_"," ");

        //

        тМакет=Новый ТекстовыйДокумент;

        тМакет.ДобавитьСтроку("#Область Шапка");

        тМакет.ДобавитьСтроку(строПолейШапки);

        тМакет.ДобавитьСтроку(секГорРазделитель1);

        тМакет.ДобавитьСтроку(секШапка1);

        тМакет.ДобавитьСтроку(секШапка2);

        тМакет.ДобавитьСтроку(секГорРазделитель1);

        тМакет.ДобавитьСтроку("#КонецОбласти");

        тМакет.ДобавитьСтроку("");

        тМакет.ДобавитьСтроку("#Область Запись");

        тМакет.ДобавитьСтроку(строПолейЗаписи);

        тМакет.ДобавитьСтроку(секЗапись1);

        тМакет.ДобавитьСтроку(секЗапись2);

        тМакет.ДобавитьСтроку(секГорРазделитель2);

        тМакет.ДобавитьСтроку("#КонецОбласти");

        рПараметры.Вставить("ИсходныйМакет",тМакет); // пусть будет





        //---------------------------------------------------------------------------------------------------------------------------

        // Запускаем вывод в итоговый документ

        рТекст=Новый ТекстовыйДокумент;

        сек=тМакет.ПолучитьОбласть("Шапка");

        сек.Параметры._HCS="Иерархия";

        Для каждого имякол Из мИменКолонок Цикл

            кол=рВетка.Колонки[имякол];

            сек.Параметры[кол.Имя]=?(ПустаяСтрока(кол.Заголовок),кол.Имя,кол.Заголовок);

        КонецЦикла;

        рТекст.Вывести(сек);

        //

        пар=Новый Структура;

        пар.Вставить("МассивИмёнКолонок",мИменКолонок);

        пар.Вставить("ТекущаяСекция",тМакет.ПолучитьОбласть("Запись"));

        пар.Вставить("ШиринаКолонкиИерархии",рШиринаКолонкиИерархии);

        пар.Вставить("ПоказыватьУровни",рПоказыватьУровни);

        пар.Вставить("Отступ",0);

        пар.Вставить("ШагОтступа",рШагОтступа);

        ВывестиДеревоЗначенийВТекст(рВетка,рТекст,пар);





    Иначе

        // очередная итерация, вывод в текстовый документ

        мИменКолонок=рПараметры.МассивИмёнКолонок;

        рСекция=рПараметры.ТекущаяСекция;

        рОтступ=рПараметры.Отступ;

        рШиринаКолонкиИерархии=рПараметры.ШиринаКолонкиИерархии;

        рПоказыватьУровни=рПараметры.ПоказыватьУровни;

        //

        строОтступы="_________________________________________________________________________________________________________";

        строПробелы="                                                                                                                                                                                                                 ";

        //

        пар=Новый Структура;

        пар.Вставить("МассивИмёнКолонок",мИменКолонок);

        пар.Вставить("ТекущаяСекция",рПараметры.ТекущаяСекция);

        пар.Вставить("ШиринаКолонкиИерархии",рШиринаКолонкиИерархии);

        пар.Вставить("ПоказыватьУровни",рПоказыватьУровни);

        пар.Вставить("ШагОтступа",рПараметры.ШагОтступа);

        пар.Вставить("Отступ",рОтступ+рПараметры.ШагОтступа);

        //

        Для каждого рПодветка Из рВетка.Строки Цикл

            рСекция.Параметры._HCS=Лев(строПробелы,рОтступ)+"\"+Лев(строОтступы,рШиринаКолонкиИерархии-рОтступ-1);

            Если рПоказыватьУровни Тогда

                рСекция.Параметры._Level=рПодветка.Уровень();

            КонецЕсли;

            Для каждого имякол Из мИменКолонок Цикл

                рСекция.Параметры[имякол]=рПодветка[имякол];

            КонецЦикла;

            рТекст.Вывести(рСекция);

            ВывестиДеревоЗначенийВТекст(рПодветка,рТекст,пар)

        КонецЦикла;

        //

    КонецЕсли;

Исключение

    Сообщить("ВывестиДеревоЗначенийВТекст, ошибка: "+ОписаниеОшибки(),СтатусСообщения.ОченьВажное);

КонецПопытки;

КонецПроцедуры

Источник

Категория: Работа с Деревом Значений

Форма ~ Программное добавление элементов на форму

ЭлементыФормы (Controls) . Добавить (Add) - Добавляет элемент управления на форму.
Синтаксис:

Код 1C v 8.х

 Добавить(<Тип>, <Имя>, <Видимость>, <ПоместитьНа>)

Параметры:
<Тип> (обязательный)
Тип: Тип. Тип добавляемого элемента управления:
Индикатор; ПолеКалендаря; Кнопка; КоманднаяПанель; Надпись; Панель; Переключатель; ПолеТабличногоДокумента; ПолеHTMLДокумента; ПолеТекстовогоДокумента; ПолеВвода; ПолеВыбора; ПолеСписка; ПолеКартинки; ПолосаРегулирования; Разделитель; РамкаГруппы; ТабличноеПоле; Флажок; ПолеГрафическойСхемы; ПолеГеографическойСхемы.
<Имя> (обязательный)
Тип: Строка. Имя создаваемого элемента управления. Имя должно быть указано в соответсвии с правилами написания имен системы 1С:Предприятие 8. В противном случае выполнение метода вызовет исключение.
<Видимость> (необязательный)
Тип: Булево. Определяет, создавать новый элемент управления формы видимым или нет. Истина - элемент создается видимым.
Значение по умолчанию: Истина
<ПоместитьНа> (необязательный)
Тип: Панель; ПолеТабличногоДокумента. Определяет, какой панели формы или какому табличному документу принадлежит создаваемый элемент. Если указана панель, то добавляемый элемент размещается на текущей странице панели. Если не указан, создаваемый элемент будет принадлежать непосредственно форме.

Код 1C v 8.х

 

// Расположим на странице табличное поле

ПолеРегистра = ЭлементыФормы.Добавить(Тип("ТабличноеПоле"), 

    СтрокаТаблицы.Имя, 

    Истина, 

    ЭлементыФормы.ОсновнаяПанель);

ПолеРегистра.Данные = "ДокументОбъект.Движения." + СтрокаТаблицы.Имя;



Если НЕ ЭтоНовый() Тогда

  ПолеРегистра.Значение.Прочитать();

КонецЕсли; 



ПолеРегистра.Верх = 30;

ПолеРегистра.Лево = 6;

ПолеРегистра.Ширина = ЭлементыФормы.ОсновнаяПанель.Ширина - 14;

ПолеРегистра.Высота = ЭлементыФормы.ОсновнаяПанель.Высота - 56;

ПолеРегистра.ТолькоПросмотр = Ложь;

ПолеРегистра.ИзменятьПорядокСтрок = Истина;

ПолеРегистра.ИзменятьСоставСтрок = Истина;



ПолеРегистра.УстановитьПривязку(ГраницаЭлементаУправления.Верх,

    КоманднаяПанельРегистра,

    ГраницаЭлементаУправления.Низ);

ПолеРегистра.УстановитьПривязку(ГраницаЭлементаУправления.Низ,

    ЭлементыФормы.ОсновнаяПанель,

    ГраницаЭлементаУправления.Низ);

ПолеРегистра.УстановитьПривязку(ГраницаЭлементаУправления.Право,

    ЭлементыФормы.ОсновнаяПанель,

    ГраницаЭлементаУправления.Право);



ПолеРегистра.СоздатьКолонки();



Если Метаданные.РегистрыНакопления[СтрокаТаблицы.Имя].ВидРегистра =   Метаданные.СвойстваОбъектов.ВидРегистраНакопления.Остатки Тогда



  КолонкаВидДвижения = ПолеРегистра.Колонки.Вставить(1, "Вид движения");

  КолонкаВидДвижения.Имя = "ВидДвиженияРегистраНакопления";

  КолонкаВидДвижения.УстановитьЭлементУправления(Тип("ПолеВвода"));

  КолонкаВидДвижения.Данные = "ВидДвижения";

  КолонкаВидДвижения.ЭлементУправления.КнопкаВыбора = Истина;

  КолонкаВидДвижения.ЭлементУправления.ВыбиратьТип = Ложь;



КонецЕсли;



ПолеРегистра.Колонки.Регистратор.Видимость = Ложь;

ПолеРегистра.Колонки.Период.Видимость   = Ложь;

ПолеРегистра.Колонки.НомерСтроки.Видимость = Ложь;



// Поле ввода

ПолеВвода = ЭлементыФормы.Добавить(Тип("ПолеВвода"), "ПолеВвода", Истина);

  

ПолеВвода.Верх  = Надпись.Верх + Надпись.Высота + 5;

ПолеВвода.Лево  = ЭлементыФормы.Переключатель1.Лево;

ПолеВвода.Ширина = ЭлементыФормы.Переключатель1.Ширина;

ПолеВвода.Высота = ЭлементыФормы.Переключатель1.Высота;

  

ПолеВвода.Доступность = Ложь;

  

// установка привязок

ПолеВвода.УстановитьПривязку(ГраницаЭлементаУправления.Низ,  ПолеВвода,  ГраницаЭлементаУправления.Верх);

ПолеВвода.УстановитьПривязку(ГраницаЭлементаУправления.Лево,     ЭтаФорма.Панель,  ГраницаЭлементаУправления.Лево);

ПолеВвода.УстановитьПривязку(ГраницаЭлементаУправления.Право,    ЭтаФорма.Панель,  ГраницаЭлементаУправления.Право);



//Надпись и поле ввода

ЭлементНадпись = ЭлементыФормы.Добавить(Тип("Надпись"), "Надпись"+ИмяЭлемента, Истина, ЭлементыФормы.ПанельПодбор);

ЭлементНадпись.Заголовок = Синоним + ":";

ЭлементНадпись.Лево = 6;

ЭлементНадпись.Верх = ВерхЭлемента + 6;

ЭлементНадпись.Высота = 19;

ЭлементНадпись.Ширина = 160;

ЭлементНадпись.ЦветФона = ЦветаСтиля.ФонЭпицентра;



ЭлементПолеВвода = ЭлементыФормы.Добавить(Тип("ПолеВвода"), ИмяЭлемента, Истина, ЭлементыФормы.ПанельПодбор);

ЭлементПолеВвода.ТипЗначения = Параметр.Тип;

ЭлементПолеВвода.Верх = ЭлементНадпись.Верх;

ЭлементПолеВвода.Лево = ЭлементНадпись.Лево + ЭлементНадпись.Ширина + 6;

ЭлементПолеВвода.Высота = ЭлементНадпись.Высота;

Если ЭлементПолеВвода.ТипЗначения.СодержитТип(Тип("Дата")) Тогда

  ЭлементПолеВвода.Ширина = 80;

Иначе

  ЭлементПолеВвода.Ширина = 200;

КонецЕсли;

 





//Надпись и Поле Выбора

ИмяЭлемента = " Подписывающий";

ЭлементНадпись = ЭлементыФормы.Добавить(Тип("Надпись"), "Надпись"+ИмяЭлемента, Истина,);

ЭлементНадпись.Заголовок = ИмяЭлемента + ":";

ЭлементНадпись.Лево = 250;

ЭлементНадпись.Верх = 33;

ЭлементНадпись.Высота = 19;

ЭлементНадпись.Ширина = 160;

ЭлементНадпись.ЦветФона = ЦветаСтиля.ЦветФонаФормы;



ЭлементПолеВвода = ЭлементыФормы.Добавить(Тип("ПолеВыбора""), ИмяЭлемента, Истина,);

ЭлементПолеВвода.Данные = Подписывающий;

//ЭлементПолеВвода.ТипЗначения  = Новый ОписаниеТипов("СправочникСсылка.СотрудникиОрганизаций");

ЭлементПолеВвода.Верх = ЭлементНадпись.Верх;

ЭлементПолеВвода.Лево = ЭлементНадпись.Лево + ЭлементНадпись.Ширина + 6;

ЭлементПолеВвода.Высота = ЭлементНадпись.Высота;

ЭлементПолеВвода.Ширина = 200;

Категория: Работа с Формой (Диалог) и её элементами

Как установить значение Субконто

Код 1C v 8.х

 Процедура УстановитьСубконто(Счет, Субконто, ИмяСубконто, ЗначениеСубконто) Экспорт



    Если Счет = Неопределено ИЛИ Счет.Пустая() Тогда

        Возврат;

    КонецЕсли;



    Если ТипЗнч(ИмяСубконто) = Тип("Число") Тогда

        Если ИмяСубконто > Счет.ВидыСубконто.Количество() Тогда

            Возврат;

        КонецЕсли;

        ВидСубк = Счет.ВидыСубконто[ИмяСубконто - 1].ВидСубконто;

    Иначе

        ВидСубк = ПланыВидовХарактеристик[Метаданные.НайтиПоТипу(ТипЗнч(Счет)).ВидыСубконто.Имя][ИмяСубконто];            

        Если Счет.ВидыСубконто.Найти( ВидСубк) = Неопределено Тогда

            Возврат;

        КонецЕсли;

    КонецЕсли;



    Если ВидСубк.ТипЗначения.СодержитТип(ТипЗнч(ЗначениеСубконто)) Тогда

        Субконто.Вставить(ВидСубк, ЗначениеСубконто);

    Иначе

        Сообщить("Неверное значение """ + ЗначениеСубконто + """ для вида субконто <" + ВидСубк + ">");

    КонецЕсли;



КонецПроцедуры

Пример использования:

Код 1C v 8.х

  // где Выборка - Выборка из результата запроса

Проводка = Движения.Международный.Добавить();

Проводка.Период = ДатаЗакрытияПериода;

Проводка.СчетДт = Выборка.Счет;

Проводка.СчетКт = ПланыСчетов.Международный.СуммарныеДоходыИРасходы;

Проводка.Организация = Организация;

Проводка.Сумма = Выборка.СуммаОстатокКт;

Проводка.Содержание = "Закрытие счетов в конце финансового года";

Проводка.НомерЖурнала = "Рег";

                

НомерСубконто = 0;

Для каждого ВидСубконто Из Проводка.СчетДт.ВидыСубконто Цикл

    НомерСубконто = НомерСубконто + 1;

    ЗначениеСубконто = Выборка["Субконто"+НомерСубконто];

           Если ЗначениеЗаполнено(ЗначениеСубконто) Тогда

              УстановитьСубконто(Проводка.СчетДт, Проводка.СубконтоДт, НомерСубконто, ЗначениеСубконто);

           КонецЕсли;

КонецЦикла;

Категория: Регистры бухгалтерии

Как получить менеджер объекта по переданной ссылке?

Код 1C v 8.х

 // Возвращает менеджер объекта по переданной ссылке.

// Не обрабатываются точки маршрутов бизнес-процессов.

Функция МенеджерОбъектаПоСсылке(Ссылка) Экспорт

	

	ИмяОбъекта = Ссылка.Метаданные().Имя;

	ТипСсылки = ТипЗнч(Ссылка);

	

	Если Справочники.ТипВсеСсылки().СодержитТип(ТипСсылки) Тогда

		Возврат Справочники[ИмяОбъекта];

	ИначеЕсли Документы.ТипВсеСсылки().СодержитТип(ТипСсылки) Тогда

		Возврат Документы[ИмяОбъекта];

	ИначеЕсли БизнесПроцессы.ТипВсеСсылки().СодержитТип(ТипСсылки) Тогда

		Возврат БизнесПроцессы[ИмяОбъекта];

	ИначеЕсли ПланыВидовХарактеристик.ТипВсеСсылки().СодержитТип(ТипСсылки) Тогда

		Возврат ПланыВидовХарактеристик[ИмяОбъекта];

	ИначеЕсли ПланыСчетов.ТипВсеСсылки().СодержитТип(ТипСсылки) Тогда

		Возврат ПланыСчетов[ИмяОбъекта];

	ИначеЕсли ПланыВидовРасчета.ТипВсеСсылки().СодержитТип(ТипСсылки) Тогда

		Возврат ПланыВидовРасчета[ИмяОбъекта];

	ИначеЕсли Задачи.ТипВсеСсылки().СодержитТип(ТипСсылки) Тогда

		Возврат Задачи[ИмяОбъекта];

	ИначеЕсли ПланыОбмена.ТипВсеСсылки().СодержитТип(ТипСсылки) Тогда

		Возврат ПланыОбмена[ИмяОбъекта];

	ИначеЕсли Перечисления.ТипВсеСсылки().СодержитТип(ТипСсылки) Тогда

		Возврат Перечисления[ИмяОбъекта];

	Иначе

		Возврат НеОпределено;

	КонецЕсли;

	

КонецФункции

Категория: Полезные, Универсальные Функции

Как получить вид объекта по переданной ссылке?

Код 1C v 8.х

 

// Возвращает вид объекта по переданной ссылке - строку "Справочник", "Документ" и т.д.

// Не обрабатываются точки маршрутов бизнес-процессов.

Функция ВидОбъектаПоСсылке(Ссылка) Экспорт

	ТипСсылки = ТипЗнч(Ссылка);

	Если Справочники.ТипВсеСсылки().СодержитТип(ТипСсылки) Тогда

		Возврат "Справочник";



	ИначеЕсли Документы.ТипВсеСсылки().СодержитТип(ТипСсылки) Тогда

		Возврат "Документ";



	ИначеЕсли БизнесПроцессы.ТипВсеСсылки().СодержитТип(ТипСсылки) Тогда

		Возврат "БизнесПроцесс";



	ИначеЕсли ПланыВидовХарактеристик.ТипВсеСсылки().СодержитТип(ТипСсылки) Тогда

		Возврат "ПланВидовХарактеристик";



	ИначеЕсли ПланыСчетов.ТипВсеСсылки().СодержитТип(ТипСсылки) Тогда

		Возврат "ПланСчетов";



	ИначеЕсли ПланыВидовРасчета.ТипВсеСсылки().СодержитТип(ТипСсылки) Тогда

		Возврат "ПланВидовРасчета";



	ИначеЕсли Задачи.ТипВсеСсылки().СодержитТип(ТипСсылки) Тогда

		Возврат "Задача";



	ИначеЕсли ПланыОбмена.ТипВсеСсылки().СодержитТип(ТипСсылки) Тогда

		Возврат "ПланОбмена";



	ИначеЕсли Перечисления.ТипВсеСсылки().СодержитТип(ТипСсылки) Тогда

		Возврат "Перечисление";



	Иначе

		Возврат "";



	КонецЕсли;

	

КонецФункции

Категория: Полезные, Универсальные Функции

Как сформировать новый документ на основании файла, шаблона Microsoft Office Word и OpenOffice?

Код 1C v 8.х

  Перем СсылкаНаДокумент;



Процедура СформироватбФайл_MS_Word_И_OpenOffice(Кнопка)

	

	ДокументСсылка = СсылкаНаДокумент;

	ИмяФайла = ПолучитьИмяВременногоФайла();



	// Теперь формируем файл из MS Wordа

	Попытка

		

		MSWord = новый COMОбъект("Word.Application");

		//Передаем текущие параметры форм в MSWord

		MSWord.Documents.Open(ИмяФайла);	

		MSWordDoc = MSWord.ActiveDocument();

		

		WordContent =  MSWord.ActiveDocument().ActiveWindow.S_election;

		

		//------------------------------------------------------------

		// Перебираем таблицы в документе, и сопоставляем имена переменных

		// с именами табличных частей.

		Для ТекущаяТаблица = 1 ПО MSWordDoc.Tables.Count Цикл 

			мТабличнаяЧасть = Неопределено;

			Для ТекущаяСтрока  = 1 ПО MSWordDoc.Tables(ТекущаяТаблица).Rows.Count Цикл 

				Для ТекущаяКолонка = 1 ПО MSWordDoc.Tables(ТекущаяТаблица).Columns.Count Цикл 

					

					мТабличнаяЧасть = ИмяТабличнойЧастиВСтроке(

					ПолучитьСтартПеременной( MSWordDoc.Tables(ТекущаяТаблица).Cell(ТекущаяСтрока,ТекущаяКолонка).Range.Text	) 

					,ДокументСсылка);

					

					Если  мТабличнаяЧасть <> Неопределено Тогда

						Прервать;;	

					КонецЕсли;	

					

				КонецЦикла;

				Если  мТабличнаяЧасть <> Неопределено Тогда

					Прервать;;	

				КонецЕсли;	

			КонецЦикла;

			

			//Итак мы имеем номер текущей таблицы  и имя табличной части

			Если  мТабличнаяЧасть <> Неопределено Тогда

				//Производим редактирование нашей таблицы в соответствии с количеством строк

				ВсегоСтрокТЧ = 0;

				Для Каждого строкаТЧ Из  ДокументСсылка[мТабличнаяЧасть.Имя] Цикл

					ВсегоСтрокТЧ = ВсегоСтрокТЧ+1;

				КонецЦикла;

				//ВсегоСтрокТЧ = ДокументСсылка[мТабличнаяЧасть.Имя].Количество;

				// Добавляем строки

				Для ТекущаяСтрокаТЧ  = 1  По ВсегоСтрокТЧ Цикл

					Если ТекущаяСтрокаТЧ <> ВсегоСтрокТЧ  Тогда

						MSWordDoc.Tables(ТекущаяТаблица).Rows.Add(MSWordDoc.Tables(ТекущаяТаблица).Rows(ТекущаяСтрока+ТекущаяСтрокаТЧ-1));

					КонецЕсли;	

					//MSWordDoc.Tables(ТекущаяТаблица).Cell(ТекущаяСтрока+ТекущаяСтрокаТЧ-1,2).Range.Text = Строка(ТекущаяСтрокаТЧ);

					Для ТекКол = 1 ПО MSWordDoc.Tables(ТекущаяТаблица).Columns.Count Цикл 

						Если ТекущаяСтрокаТЧ <> ВсегоСтрокТЧ  Тогда

							ТекстПеременной = ПолучитьПеременнуюИзСтроки(СокрЛП(MSWordDoc.Tables(ТекущаяТаблица).Cell(ТекущаяСтрока+ТекущаяСтрокаТЧ,ТекКол).Range.Text));

							ТекстПеременной = ?(ПустаяСтрока(ТекстПеременной),"", "["+"_"+Строка(ТекущаяСтрокаТЧ)+"_"+ТекстПеременной+"]");

							MSWordDoc.Tables(ТекущаяТаблица).Cell(ТекущаяСтрока+ТекущаяСтрокаТЧ-1,ТекКол).Range.Text = ТекстПеременной;

						Иначе

							ТекстПеременной = ПолучитьПеременнуюИзСтроки(СокрЛП(MSWordDoc.Tables(ТекущаяТаблица).Cell(ТекущаяСтрока+ТекущаяСтрокаТЧ-1,ТекКол).Range.Text));

							ТекстПеременной = ?(ПустаяСтрока(ТекстПеременной),"", "["+"_"+Строка(ТекущаяСтрокаТЧ)+"_"+ТекстПеременной+"]");

							MSWordDoc.Tables(ТекущаяТаблица).Cell(ТекущаяСтрока+ТекущаяСтрокаТЧ-1,ТекКол).Range.Text = ТекстПеременной;

						КонецЕсли;	

					КонецЦикла;	

				КонецЦикла;	

				//MSWordDoc.Tables(ТекущаяТаблица).Rows.Delete();

				//MSWordDoc.Tables(ТекущаяТаблица).Rows(3).Delete();

			КонецЕсли;	

		КонецЦикла;

		

		//------------------------------------------------------------

		// Вытаскивам из шаблона текст 

		ТекстДокумента = MSWordDoc.Range(0, MSWordDoc.Characters.Count).Text;

		

		// Из текста вытаскиваем Имена переменных залюченных а скобки []

		Список = ПолучитьСписокПеременных(ТекстДокумента);

		//Список.ВыбратьЭлемент();

		

		// Заполняем в структуру ревизитовперечень переменных

		СтруктураРеквизитов=СтруктураРеквизитовДокумента(ДокументСсылка);

		ЗначениеРеквизита="";

		Для Каждого ЭлементСписка Из Список Цикл

			

			// Если находится соответствие переменной из документа и шаблона то производим замену

			Если СтруктураРеквизитов.Свойство(ЭлементСписка.Значение, ЗначениеРеквизита ) Тогда

				//Сообщить("["+ЭлементСписка.Значение+"]"+" : "+ЗначениеРеквизита);

				WordContent.Find.Execute("["+ЭлементСписка.Значение+"]",0,0,0,0,0,-1,,,Строка(ЗначениеРеквизита),2);		

			Иначе

				Сообщить("-> " + ЭлементСписка.Значение+" - Не найден в структуре документа");

				// Заменим переменную на пустую строку

				WordContent.Find.Execute("["+ЭлементСписка.Значение+"]",0,0,0,0,0,-1,,," ",2);		

			КонецЕсли;

			

		КонецЦикла;

		

		//автоматически обновляем поля документа

		MSWord.S_election.WholeStory();

		MSWord.S_election.Fields.Update();

		MSWord.S_election.HomeKey();	

		

		//MSWordDoc.SaveAs(ИмяФайла);

		

		//отображаем MSWord

		MSWord.Visible=1;

		MSWord.Activate();

		

	Исключение

		Предупреждение(ОписаниеОшибки());

		MSWord.Quit();

	КонецПопытки;

	

	

	// Теперь формируем файл из OpenOffice

	

	Попытка

		ServiceManager = Новый COMОбъект("com.sun.star.ServiceManager");

		Reflection = ServiceManager.createInstance("com.sun.star.reflection.CoreReflection");

		Desktop = ServiceManager.createInstance("com.sun.star.frame.Desktop");

		

		Args = Новый COMSafeArray("VT_DISPATCH", 1);

		OOДокумент = Desktop.loadComponentFromURL(ПреобразоватьВURL(ИмяФайла), "_blank", 0, Args);

		

		//------------------------------------------------------------

		// Перебираем таблицы в документе, и сопоставляем имена переменных

		// с именами табличных частей.

		Для ТекущаяТаблица = 0 ПО OOДокумент.getTextTables().Count-1 Цикл 

			мТабличнаяЧасть = Неопределено;

			Для ТекущаяСтрока  = 0 ПО OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).Rows.Count-1 Цикл 

				Для ТекущаяКолонка = 0 ПО OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).Columns.Count-1 Цикл 

					

					мТабличнаяЧасть = ИмяТабличнойЧастиВСтроке(

					ПолучитьСтартПеременной( OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).getCellByPosition(ТекущаяКолонка, ТекущаяСтрока).string	) 

					,ДокументСсылка);

					

					Если  мТабличнаяЧасть <> Неопределено Тогда

						Прервать;;	

					КонецЕсли;	

					

				КонецЦикла;

				Если  мТабличнаяЧасть <> Неопределено Тогда

					Прервать;;	

				КонецЕсли;	

			КонецЦикла;

			

			//Итак мы имеем номер текущей таблицы  и имя табличной части

			Если  мТабличнаяЧасть <> Неопределено Тогда

				//Производим редактирование нашей таблицы в соответствии с количеством строк

				ВсегоСтрокТЧ = 0;

				Для Каждого строкаТЧ Из  ДокументСсылка[мТабличнаяЧасть.Имя] Цикл

					ВсегоСтрокТЧ = ВсегоСтрокТЧ+1;

				КонецЦикла;

				//ВсегоСтрокТЧ = ДокументСсылка[мТабличнаяЧасть.Имя].Количество;

				// Добавляем строки

				Для ТекущаяСтрокаТЧ  = 1  По ВсегоСтрокТЧ Цикл

					Если ТекущаяСтрокаТЧ <> ВсегоСтрокТЧ  Тогда

						// Добавляем строку перед нашей

						OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).Rows.I_nsertByIndex(ТекущаяСтрока+ТекущаяСтрокаТЧ-1, 1);

					КонецЕсли;	

					

					Для ТекКол = 0 ПО OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).Columns.Count-1 Цикл 

						

						Если ТекущаяСтрокаТЧ <> ВсегоСтрокТЧ  Тогда             

							ТекстПеременной = ПолучитьПеременнуюИзСтроки(СокрЛП(OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).getCellByPosition(ТекКол, ТекущаяСтрока+ТекущаяСтрокаТЧ).string));

							ТекстПеременной = ?(ПустаяСтрока(ТекстПеременной),"", "["+"_"+Строка(ТекущаяСтрокаТЧ)+"_"+ТекстПеременной+"]");

							OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).getCellByPosition(ТекКол, ТекущаяСтрока+ТекущаяСтрокаТЧ-1).string = ТекстПеременной;

						Иначе                                                   

							ТекстПеременной = ПолучитьПеременнуюИзСтроки(СокрЛП(OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).getCellByPosition(ТекКол, ТекущаяСтрока+ТекущаяСтрокаТЧ-1).string));

							ТекстПеременной = ?(ПустаяСтрока(ТекстПеременной),"", "["+"_"+Строка(ТекущаяСтрокаТЧ)+"_"+ТекстПеременной+"]");

							

							OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).getCellByPosition(ТекКол, ТекущаяСтрока+ТекущаяСтрокаТЧ-1).string = ТекстПеременной;

						КонецЕсли;	

					КонецЦикла;	

				КонецЦикла;	

			КонецЕсли;	

		КонецЦикла;

		

		//------------------------------------------------------------

		// Вытаскивам из шаблона текст 

		//ТекстДокумента = MSWordDoc.Range(0, MSWordDoc.Characters.Count).Text;

		ТекстДокумента = ООПолучитьТекст(OOДокумент);

		

		// Из текста вытаскиваем Имена переменных залюченных а скобки []

		Список = ПолучитьСписокПеременных(ТекстДокумента);

		//Список.ВыбратьЭлемент();

		

		// Заполняем в структуру ревизитовперечень переменных

		СтруктураРеквизитов=СтруктураРеквизитовДокумента(ДокументСсылка);

		ЗначениеРеквизита="";

		

		OOЗамена = OOДокумент.CreateReplaceDescriptor();

		

		Для Каждого ЭлементСписка Из Список Цикл

			

			// Если находится соответствие переменной из документа и шаблона то производим замену

			Если СтруктураРеквизитов.Свойство(ЭлементСписка.Значение, ЗначениеРеквизита ) Тогда

				OOЗамена.SearchString  = "["+ЭлементСписка.Значение+"]";

				OOЗамена.ReplaceString = Строка(ЗначениеРеквизита);

				OOДокумент.ReplaceAll(OOЗамена);

			Иначе

				Сообщить("-> " + ЭлементСписка.Значение+" - Не найден в структуре документа");

				// Заменим переменную на пустую строку

				OOЗамена.SearchString  = "["+ЭлементСписка.Значение+"]";

				OOЗамена.ReplaceString = " ";

				OOДокумент.ReplaceAll(OOЗамена);

				

			КонецЕсли;

			

		КонецЦикла;

		OOДокумент.getCurrentController().getFrame().getContainerWindow().setFocus();

		

	Исключение

		Предупреждение(ОписаниеОшибки());

	КонецПопытки;			

	

КонецПроцедуры

Код 1C v 8.х

   //ДОПОЛНИТЕЛЬНО НЕОБХОДИМЫЕ ФУНКЦИИ

// Добавлем форматы представления полей и дополнительную информацию о полях

Процедура ДобавитьФорматы(ПереченьРеквизитов,Значение,пПредставлениеРеквизита, ДокументСсылка = Неопределено)

	Если ТипЗнч(Значение) = Тип("Дата")  Тогда  // расширяем представление даты

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"ДФddMMyyyy",Формат(Значение,"ДФ=dd.MM.yyyy"));

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"ДЛФDD",Формат(Значение,"ДЛФ=DD"));

	ИначеЕсли ТипЗнч(Значение) = Тип("Число") Тогда  // расширяем представление числа

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"ЧДЦ2ЧГ0",Формат(Значение,"ЧДЦ=2; ЧГ=0"));

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"ЧДЦ2",Формат(Значение,"ЧДЦ=2"));

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"ЧПропись",Значение);

	ИначеЕсли  (ТипЗнч(Значение) = Тип("СправочникСсылка.КонтактныеЛица"))  или  (ТипЗнч(Значение) = Тип("СправочникСсылка.ФизическиеЛица")) Тогда

		// Расширяем выводимые поля для типов физ. лица, контакные лица сокращением инициалов	

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"ФИО",Строка(Значение));

	КонецЕсли

КонецПроцедуры



Процедура ЗаполнитьРеквизиты(мГлубинаРекурсии,ПереченьРеквизитов,РеквизитСсылка,Реквизит,пПредставлениеРеквизита)

	

	мГлубинаРекурсии = мГлубинаРекурсии+1;

	ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"Код",РеквизитСсылка["Код"]);

	ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"Наименование",РеквизитСсылка["Наименование"]);

	

	Для Каждого ЭлементРеквизита Из Реквизит.Реквизиты  Цикл

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+ЭлементРеквизита.Имя,РеквизитСсылка[ЭлементРеквизита.Имя]);

		Если (Найти(ЭлементРеквизита.Тип,"Справочник ссылка")>0) И (мГлубинаРекурсии <=3) И (Найти(ЭлементРеквизита.Тип,",")=0) Тогда

			///+++

			ЗаполнитьРеквизиты(мГлубинаРекурсии, ПереченьРеквизитов,РеквизитСсылка[ЭлементРеквизита.Имя],РеквизитСсылка[ЭлементРеквизита.Имя].Метаданные(),пПредставлениеРеквизита+"_"+ЭлементРеквизита.Имя);

		Иначе

			ДобавитьФорматы(ПереченьРеквизитов,РеквизитСсылка[ЭлементРеквизита.Имя],пПредставлениеРеквизита+"_"+ЭлементРеквизита.Имя);

		КонецЕсли

	КонецЦикла;	

	

КонецПроцедуры



Функция ПолучитьСписокПеременных(ТекстШаблона)

	СписокПеременных = Новый СписокЗначений();

	ЕщеЕсть = Истина;

	Пока ЕщеЕсть Цикл

		ПервыйСимвол = Найти(ТекстШаблона,"[");

		Если ПервыйСимвол > 0 Тогда

			ВторойСимвол = Найти(ТекстШаблона,"]");

			Если (ВторойСимвол > 0 И ВторойСимвол > ПервыйСимвол) Тогда

				СписокПеременных.Добавить(Сред(ТекстШаблона,ПервыйСимвол + 1,ВторойСимвол - ПервыйСимвол - 1));

				ТекстШаблона = Сред(ТекстШаблона,ВторойСимвол + 1);

			Иначе

				ЕщеЕсть = Ложь;

			КонецЕсли;

		Иначе

			ЕщеЕсть = Ложь;

		КонецЕсли;

	КонецЦикла;

	Возврат СписокПеременных;

КонецФункции



Функция СтруктураРеквизитовДокумента(ДокументСсылка)  Экспорт

	ПереченьРеквизитов = Новый Структура;

	ПереченьРеквизитов.Вставить("Дата",ДокументСсылка["Дата"]);

	ДобавитьФорматы(ПереченьРеквизитов,ДокументСсылка["Дата"],"Дата");

	ПереченьРеквизитов.Вставить("Номер",ДокументСсылка["Номер"]);

	Реквизиты = ДокументСсылка.Метаданные().Реквизиты;

	Для Каждого Реквизит Из Реквизиты  Цикл

		мГлубинаРекурсии = 1;

		ПереченьРеквизитов.Вставить(Реквизит.Имя,ДокументСсылка[Реквизит.Имя]);

			ДобавитьФорматы(ПереченьРеквизитов,ДокументСсылка[Реквизит.Имя],Реквизит.Имя,ДокументСсылка);

		Если Найти(Реквизит.Тип,"Справочник ссылка")>0 Тогда

			ЗаполнитьРеквизиты(мГлубинаРекурсии,ПереченьРеквизитов,ДокументСсылка[Реквизит.Имя],ДокументСсылка[Реквизит.Имя].Метаданные(),Реквизит.Имя);

		Иначе

			//ДобавитьФорматы(ПереченьРеквизитов,ДокументСсылка[Реквизит.Имя],Реквизит.Имя);

		КонецЕсли;

	КонецЦикла;	

	ТабличныеЧасти = ДокументСсылка.Метаданные().ТабличныеЧасти;

	Для Каждого ТабличнаяЧасть Из ТабличныеЧасти  Цикл

		// Сообщить(ТабличнаяЧасть); // Для таблицы характеристик отрабатываем свой код // с выводом табличной части как набора реквизитов

		Если ТабличнаяЧасть.Имя = "Характеристики" Тогда

			Для Каждого СтрокаТабличнойЧасти Из ДокументСсылка[ТабличнаяЧасть.Имя]  Цикл

				мПредставлениеРеквизита = "Характеристика"+"_"+СтрЗаменить(СтрокаТабличнойЧасти["ВидХарактеристики"], " ", "_");

				мЗначение = СтрокаТабличнойЧасти["ЗначениеХарактеристики"];

				ПереченьРеквизитов.Вставить(мПредставлениеРеквизита,мЗначение);

				ДобавитьФорматы(ПереченьРеквизитов,мЗначение,мПредставлениеРеквизита,ДокументСсылка);

				Если Найти(ТипЗнч(мЗначение),"Справочник ссылка")>0 Тогда

					ЗаполнитьРеквизиты(мГлубинаРекурсии,ПереченьРеквизитов,мЗначение,мЗначение.Метаданные(),мПредставлениеРеквизита);

				КонецЕсли;

				

			КонецЦикла;	

		КонецЕсли;	

		//Перечень реквизитов табличной части

		Реквизиты = ТабличнаяЧасть.Реквизиты;

		Для Каждого Реквизит Из Реквизиты  Цикл

			Для Каждого СтрокаТабличнойЧасти Из ДокументСсылка[ТабличнаяЧасть.Имя]  Цикл

				мГлубинаРекурсии = 1;

				мПредставлениеРеквизита = "_"+СтрокаТабличнойЧасти.НомерСтроки+"_"+ТабличнаяЧасть.Имя+"_НомерСтроки";

				ПереченьРеквизитов.Вставить(мПредставлениеРеквизита,Строка(СтрокаТабличнойЧасти.НомерСтроки));

				мПредставлениеРеквизита = "_"+СтрокаТабличнойЧасти.НомерСтроки+"_"+ТабличнаяЧасть.Имя+"_"+Реквизит.Имя;

				мЗначение = СтрокаТабличнойЧасти[Реквизит.Имя];

				ПереченьРеквизитов.Вставить(мПредставлениеРеквизита,мЗначение);

				ДобавитьФорматы(ПереченьРеквизитов,мЗначение,мПредставлениеРеквизита,ДокументСсылка);

				Если Найти(ТипЗнч(мЗначение),"Справочник ссылка")>0 Тогда

					ЗаполнитьРеквизиты(мГлубинаРекурсии,ПереченьРеквизитов,мЗначение,мЗначение.Метаданные(),мПредставлениеРеквизита);

				Иначе

					//ДобавитьФорматы(ПереченьРеквизитов,мЗначение,мПредставлениеРеквизита);

				КонецЕсли;

			КонецЦикла;	

			//Если реквизит числовой, то подсчитываем итог  

			Если Реквизит.Тип.СодержитТип(Тип("Число"))  Тогда

				мЗначение = ДокументСсылка[ТабличнаяЧасть.Имя].Итог(Реквизит.Имя);

				мПредставлениеРеквизита = "Итог"+"_"+ТабличнаяЧасть.Имя+"_"+Реквизит.Имя;

				ПереченьРеквизитов.Вставить(мПредставлениеРеквизита,мЗначение);

				ДобавитьФорматы(ПереченьРеквизитов,мЗначение,мПредставлениеРеквизита,ДокументСсылка);

			КонецЕсли;

		КонецЦикла;			

	КонецЦикла;	    	

	Возврат ПереченьРеквизитов;

КонецФункции



Функция ИмяТабличнойЧастиВСтроке(Строка,ДокументСсылка)

	ТабличнаяЧасть=Неопределено;

	Если НЕ ПустаяСтрока(Строка) Тогда

		ТабличнаяЧасть = ДокументСсылка.Метаданные().ТабличныеЧасти.Найти(Строка) 

	КонецЕсли;	

	Возврат ТабличнаяЧасть;

	

КонецФункции



//Получает первый кусок переменной до _

Функция ПолучитьСтартПеременной(ПереданнаяСтрока) Экспорт

	СтартПеременной = "";

	ПервыйСимвол = Найти(ПереданнаяСтрока,"[");

	Если  ПервыйСимвол > 0 Тогда

		ВторойСимвол = Найти(ПереданнаяСтрока,"]");

		Если  (ВторойСимвол > 0) И (ВторойСимвол > ПервыйСимвол) Тогда

			Переменная = (Сред(ПереданнаяСтрока,ПервыйСимвол+1,ВторойСимвол-ПервыйСимвол-1));

			ВторойСимвол = Найти(Переменная,"_");

			Если  (ВторойСимвол > 0) И (ВторойСимвол > 1) Тогда

				СтартПеременной = Сред(Переменная,1,ВторойСимвол-1);

			КонецЕсли;	

		КонецЕсли;	

		

	КонецЕсли;	

	

	Возврат СтартПеременной;	

КонецФункции



// Получает переменную заключенную в скобки

Функция ПолучитьПеременнуюИзСтроки(ПереданнаяСтрока) Экспорт

	Переменная = "";

	ПервыйСимвол = Найти(ПереданнаяСтрока,"[");

	Если  ПервыйСимвол > 0 Тогда

		ВторойСимвол = Найти(ПереданнаяСтрока,"]");

		Если  (ВторойСимвол > 0) И (ВторойСимвол > ПервыйСимвол) Тогда

			Переменная = (Сред(ПереданнаяСтрока,ПервыйСимвол+1,ВторойСимвол-ПервыйСимвол-1));

		КонецЕсли;	

		

	КонецЕсли;	

	Возврат Переменная;	

КонецФункции// Идентифицирует табличную часть в строке



// Функция преобразует Windows имя файла в URL OpenOffice

Функция ПреобразоватьВURL(ИмяФайла)

	Возврат "file:///" + СтрЗаменить(ИмяФайла, "\", "/");

КонецФункции



// Функция извлекает текст из документа

Функция ООПолучитьТекст(OOДокумент)

	Текст = "";

	oParEnum = OOДокумент.getText().createEnumeration();

	Пока  oParEnum.hasMoreElements() Цикл

		oPar = oParEnum.nextElement();

		Если  oPar.supportsService("com.sun.star.text.Paragraph") ТОгда

			Текст = Текст + oPar.getString();

		ИначеЕсли oPar.supportsService("com.sun.star.text.TextTable") Then

			//Сообщить(oPar.getString());

		КонецЕсли;

	КонецЦикла;

	Для ТекущаяТаблица = 0 ПО OOДокумент.getTextTables().Count-1 Цикл 

		Для ТекущаяСтрока  = 0 ПО OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).Rows.Count-1 Цикл 

			Для ТекущаяКолонка = 0 ПО OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).Columns.Count-1 Цикл 

				Текст = Текст + OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).getCellByPosition(ТекущаяКолонка, ТекущаяСтрока).string;

			КонецЦикла;

		КонецЦикла;

	КонецЦикла;

	Возврат Текст;

КонецФункции

Категория: Работа с Microsoft Office и OpenOffice