строкасоединенияинформационнойбазы » Поиск

Результаты по ключевому слову: строкасоединенияинформационнойбазы

Как очистить кэш 1С? Категория: Администрирование

Открытие, перемещение и загрузка файла

Пример обработки загрузки данных на управляемой форме, с определением необходимости передачи файла на сервер:

Код 1C v 8.2 УП

 &НаКлиенте

Процедура ИмяФайлаНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)



    Диалог = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);

    Диалог.Фильтр = "*.xml|*.xml";

    Если Диалог.Выбрать() Тогда

        Объект.ИмяФайла = Диалог.ПолноеИмяФайла;

    КонецЕсли;



КонецПроцедуры



&НаКлиенте

Процедура ИмяФайлаОткрытие(Элемент, СтандартнаяОбработка)



    СтандартнаяОбработка = Ложь;

    ЗапуститьПриложение(Объект.ИмяФайла);



КонецПроцедуры



&НаКлиенте

Процедура Загрузить(Команда)



    СтрокаСоединения = СтрокаСоединенияИнформационнойБазы();



    ws = НСтр(СтрокаСоединения, "ws");

    ИмяСервера = НСтр(СтрокаСоединения, "Srvr");

    Если ИмяСервера = "" Тогда

        Если ws = "" Тогда

            ПередачаФайлаНаСервер = Ложь;

        Иначе

            ПередачаФайлаНаСервер = Истина;

        КонецЕсли;

    Иначе

        ПередачаФайлаНаСервер = (ИмяКомпьютера() <> ИмяСервера);

    КонецЕсли;



    Если ПередачаФайлаНаСервер Тогда

        ПоместитьФайл(АдресХранилища, Объект.ИмяФайла,, Ложь, УникальныйИдентификатор);

    КонецЕсли;



    ЗагрузитьСервер();



КонецПроцедуры



&НаСервере

Процедура ЗагрузитьСервер()



    ЧтениеXML = Новый ЧтениеXML;



    Если ПередачаФайлаНаСервер Тогда

        ИмяВременногоФайла = ПолучитьИмяВременногоФайла("xml");



        ДвоичныеДанные = ПолучитьИзВременногоХранилища(АдресХранилища);

        ДвоичныеДанные.Записать(ИмяВременногоФайла);

        ЧтениеXML.ОткрытьФайл(ИмяВременногоФайла);

    Иначе

        ЧтениеXML.ОткрытьФайл(Объект.ИмяФайла);

    КонецЕсли;



    ОбъектXDTO = ФабрикаXDTO.ПрочитатьXML(ЧтениеXML);

    ЧтениеXML.Закрыть();

    /// Код загрузки

    Сообщить("Загрузка завершена");

КонецПроцедуры

Категория: Работа с Файлами и Каталогами

Сохранение рабочей конфигурации в файл средствами встроенного языка

Как сохранить рабочую конфигурацию из конфигуратора знают все, но это не всегда удобно. Мне понадобилось сохранять рабочую конфигурацию и тут-же этот файл обрабатывать. Предлагаю простую процедуру:

Код 1C v 8.х

 // функция сохраняет рабочую конфигурацию в файл, в случае успеха возвращает Истина

// параметры:

//    Логин - имя пользователя с правами на админисирирование БД

//    Пароль - строка пароля

//    ИмяФайла - полное имя файла для сохранения конфигурации, не обязательно. 

//               по умолчанию использует каталог временных файлов и имя 1Cv8.cf

функция СохранитьТекущуюКонфигурацию (Логин, Пароль, ИмяФайла="") экспорт

    результат = Ложь;

    

    Если ИмяФайла = "" Тогда

        ИмяФайла = КаталогВременныхФайлов() + "1Cv8.cf";        

    КонецЕсли;

    

    СтрокаБазы = СтрокаСоединенияИнформационнойБазы();

    Если Лев(СтрокаБазы, 5) = "File=" Тогда

        // файловый вариант

        СтрокаБазы = Сред(СтрокаБазы, 6, СтрДлина(СтрокаБазы) - 6);

    Иначе

        // серверный вариант пока не готов...

                // может кто допишет?

        возврат Ложь;

    КонецЕсли;

    

    ВыбФайл = Новый Файл(ИмяФайла);

    Если ВыбФайл.Существует() Тогда

        Сигнатура = Строка(ВыбФайл.Размер()) + Строка(ВыбФайл.ПолучитьВремяИзменения()); 

    Иначе

        Сигнатура = "";

    КонецЕсли;

    

    СтрокаЗапуска = """" + КаталогПрограммы() + "1cv8.exe"" CONFIG /F " + СтрокаБазы 

                + ?(Логин = "", "", " /N " + Логин) 

                + ?(Пароль = "", "", " /P " + Пароль) + " /DumpDBCfg """ + ИмяФайла + """";

                

    //            

    // КомандаСистемы (СтрокаЗапуска); не работает!!!!! из-за кавычек в параметрах

    // приходиться  идти кругом...

    // зато можно избежать черного окошка

    //

    WshShell = Новый COMОбъект("WScript.Shell");

    WshShell.Run(СтрокаЗапуска, 0, Истина);

    

    ВыбФайл = Новый Файл(ИмяФайла);

    Если ВыбФайл.Существует() Тогда

        НоваяСигнатура = Строка(ВыбФайл.Размер()) + Строка(ВыбФайл.ПолучитьВремяИзменения());

        Если Сигнатура <> НоваяСигнатура Тогда

            Результат = Истина;

        КонецЕсли;            

    КонецЕсли;

    

    Возврат Результат;

КонецФункции

ну и пример использования (работает если нет пароля):

Код 1C v 8.х

 Функция  ЗаписатьКонфигурациюВФайл(ИмяФайла="")

    Результат = Ложь;

    ВыбФайл = Новый Файл(ИмяФайла);

    Если ВыбФайл.Существует() Тогда

        Если ВыбФайл.ЭтоКаталог() Тогда

            ИмяФайла="";

        КонецЕсли;

    КонецЕсли;

    

    Попытка

        Массив = ПользователиИнформационнойБазы.ПолучитьПользователей();

        Логин = "";

        Пароль = "";

        Если Массив.Количество() > 0 тогда

            Пользователь = ПользователиИнформационнойБазы.ТекущийПользователь();

            Логин = Пользователь.Имя;

            Если Пользователь.ПарольУстановлен Тогда

                // тут нужно получить пароль, лучше интерактивно

                 // но лично мне это совсем не нужно

                Предупреждение("У Вас установлен пароль, этот режим сейчас не доступен");

                Возврат Ложь;

            КонецЕсли 

        КонецЕсли;

        

        Результат = СохранитьТекущуюКонфигурацию(Логин, Пароль, ИмяФайла);

        Если не Результат Тогда

            Предупреждение("Конфигурация не сохранена");

        Иначе

            Сообщить("Конфигурация успешно сохранена в файл: " + ИмяФайла);

        КонецЕсли;

        

    Исключение

        Предупреждение("У Вас не достаточно прав для сохранения конфигурации");

        Возврат Ложь;

    КонецПопытки;

    

    Возврат Результат;

КонецФункции

Автор статьи: vde69

Категория: Полезные, Универсальные Функции

База для Разработки или Рабочая? Как быстро определить? Категория: Полезные, Универсальные Функции

Как определить какая база "Файловая" или "Серверная"? Категория: Полезные, Универсальные Функции

Как определить каталог базы, путь к базе? КаталогИБ()

В 8-ых версий нет встроенной функции получения каталога базы данных, так напишем ее,

Код 1C v 8.2 УП

 //Получить представление информационной базы для отображения пользователю.

// Пример возвращаемого результата:

// - для ИБ в файлом режиме: \\FileServer\1c_ib\

// - для ИБ в серверном режиме: ServerName:1111 / information_base_name

Функция ПолучитьПредставлениеИнформационнойБазы() Экспорт

	Если ПустаяСтрока(СтрокаСоединенияИнформационнойБазы) Тогда

		СтрокаСоединенияИнформационнойБазы =  СтрокаСоединенияИнформационнойБазы();

	КонецЕсли;

	ЭтоФайловаяИБ = Найти(Врег(СтрокаСоединенияИнформационнойБазы), "FILE=") = 1;

	Если ЭтоФайловаяИБ Тогда

		ПутьКБД = Сред(СтрокаСоединенияСБД, 6, СтрДлина(СтрокаСоединенияСБД) - 6);

		ФайловаяБД = Истина;

	Иначе

		// надо к имени сервера прибавить имя пути информационной базы

		ПозицияПоиска = Найти(Врег(СтрокаСоединенияСБД), "SRVR=");

		

		Если ПозицияПоиска <> 1 Тогда

			Возврат Неопределено;

		КонецЕсли;

		

		ПозицияТочкиСЗапятой = Найти(СтрокаСоединенияСБД, ";");

		НачальнаяПозицияКопирования = 6 + 1;

		КонечнаяПозицияКопирования = ПозицияТочкиСЗапятой - 2; 

		

		ИмяСервера = Сред(СтрокаСоединенияСБД, НачальнаяПозицияКопирования, КонечнаяПозицияКопирования - НачальнаяПозицияКопирования + 1);

		

		СтрокаСоединенияСБД = Сред(СтрокаСоединенияСБД, ПозицияТочкиСЗапятой + 1);

		

		// позиция имени сервера

		ПозицияПоиска = Найти(Врег(СтрокаСоединенияСБД), "REF=");

		

		Если ПозицияПоиска <> 1 Тогда

			Возврат Неопределено;

		КонецЕсли;

		

		НачальнаяПозицияКопирования = 6;

		ПозицияТочкиСЗапятой = Найти(СтрокаСоединенияСБД, ";");

		КонечнаяПозицияКопирования = ПозицияТочкиСЗапятой - 2; 

		

		ИмяИБНаСервере = Сред(СтрокаСоединенияСБД, НачальнаяПозицияКопирования, КонечнаяПозицияКопирования - НачальнаяПозицияКопирования + 1);

		

		ПутьКБД = ИмяСервера + "/ " + ИмяИБНаСервере;

		ФайловаяБД = Ложь;

	КонецЕсли;

	Возврат ПутьКБД;

КонецФункции

ТОЛЬКО эта функция работает для файлового варианта базы данных:

Код 1C v 8.х

 

Функция КаталогИБ()

	СтрокаСоединенияСБД = СтрокаСоединенияИнформационнойБазы();

	// в зависимости от того файловый это вариант БД или нет,  по-разному отображается путь в БД 

	ПозицияПоиска = Найти(Врег(СтрокаСоединенияСБД), "FILE=");

	Если ПозицияПоиска = 1 тогда

		// Файловая	

		Возврат Сред(СтрокаСоединенияСБД,7,СтрДлина(СтрокаСоединенияСБД)-8)+"\";

	Иначе 

		// Серверная - Используем КаталогВременныхФайлов() 

		Возврат КаталогВременныхФайлов();

	КонецЕсли;

КонецФункции

Для серверного - используйте другие каталоги, например:

Код 1C v 8.х

 

КаталогВременныхФайлов();	//Возвращает что-то типо: C:\Documents and Settings\E.S.Migachev\Local Settings\Temp\

КаталогПрограммы();	//Возвращает что-то типо: C:\Program Files\1cv81\bin\

Код 1C v 7.x

 

//Встроенная КаталогИБ() - Возвращает имя каталога базы данных.

КаталогИБ(); //Возвращает что-то типо: C:\Basa1C\buh\

Категория: Работа с Файлами и Каталогами

Установить новый заголовок главного окна программы Категория: Встроенные Функции

Как определить Информационная База файловая или SQL? Категория: Полезные, Универсальные Функции