тхт » Поиск

Результаты по ключевому слову: тхт

Как получить текст из html?

Один мой хороший клиент использует встроенный в 1С почтовый клиент.

До этого все работало хорошо, но недавно из-за установки нового банк-клиента на компьютере обновили Internet Explorer до 11 версии - стала появляться ошибка:

Поле объекта не обнаружено innerText

Пришлось немного доработать типовую функцию получения текста из html:

Код 1C v 8.х

 Функция ПреобразоватьТекстИзХТМЛФорматаВПростой(ТекстВФорматеХТМЛ) Экспорт

	Попытка

		НовыйHTMLДокумент = Новый COMОбъект("HtmlFile");

		НовыйHTMLДокумент.open("text/html");

		НовыйHTMLДокумент.write(ТекстВФорматеХТМЛ);

		НовыйHTMLДокумент.close();

		

		Возврат СтрЗаменить(НовыйHTMLДокумент.all.item(0).innerText, Символ(13), "");

	Исключение	

		Построитель = Новый ПостроительDOM;

		ЧтениеHTML = Новый ЧтениеHTML;

		ЧтениеHTML.УстановитьСтроку(ТекстВФорматеХТМЛ);

		ДокументHTML = Построитель.Прочитать(ЧтениеHTML);

		

		Возврат СокрЛП(ДокументHTML.Тело.ТекстовоеСодержимое);

	КонецПопытки;

КонецФункции

еще функции пример получения:

Код 1C v 8.х

 // Процедура изменяет признак формат текста письма (Текст, HТМЛ),

// и при этом конвертирует сам текст.

//

// Параметры:

//  ЭУHTML,ЭУТекст - Элементы управления формы, соответственно поле HTML и поле Текст

//  Кнопка - выбранная кнопка ее текст "Простой текст" или "HTML" новый вид текста письма

//  либо текст кнопки если пометку кнопки менять не требуется, соответственно 

//  вопрос о потере форматирования задаваться не будет

// Возвращаемое значение:

//  Булево, признак выполнения изменения формата

//

Функция удИзменитьФорматТекста(ЭУHTML,ЭУТекст, Кнопка) Экспорт

    Если ТипЗнч(Кнопка) = Тип("Строка") Тогда

        НовыйВидТекстаПисьма = Кнопка;

        ЕстьКнопка = Ложь;

    Иначе

        Если Кнопка.Пометка Тогда 

            Возврат Ложь; 

        КонецЕсли;

        НовыйВидТекстаПисьма = Кнопка.Текст;        

        ЕстьКнопка = Истина;

    КонецЕсли;     

        

    Если Найти(НовыйВидТекстаПисьма,"Простой текст") > 0 Тогда          

        ИсходныйТекст = ЭУHTML.ПолучитьТекст();

        НачалоBODY = Найти(ИсходныйТекст, "<BODY>");

        КонецBODY  = Найти(ИсходныйТекст, "</BODY>");

        Если ЕстьКнопка и (НачалоBODY > 0 И КонецBODY > 0 И (НачалоBODY + 6) < КонецBODY) Тогда

            СтрокаВопроса = "Будет потеряно форматирование текста. Продолжить?";

            ОтветНаВопрос = Вопрос(СтрокаВопроса, РежимДиалогаВопрос.ДаНет, , КодВозвратаДиалога.Нет);

            Если ОтветНаВопрос <> КодВозвратаДиалога.Да Тогда                

                Возврат Ложь;

            КонецЕсли;

        КонецЕсли;

        ФорматТекста = ЭУHTML.Документ.all.item(0).innerText;             

        ЭУТекст.Значение =  СтрЗаменить(ФорматТекста, Символ(13), "");

        ЭУТекст.Видимость = Истина;

        ЭУHTML.Видимость = Ложь;

        ЭУHTML.УстановитьТекст("");                        

    Иначе

        ФорматХТМЛ = СтрЗаменить(ЭУТекст.Значение, Символы.ПС, "<BR>");

    

        ЭУHTML.УстановитьТекст(ФорматХТМЛ);

        ЭУHTML.Видимость = Истина;

        ЭУТекст.Видимость = Ложь;

    КонецЕсли; 

    

    Если ЕстьКнопка Тогда

        Кнопка.Пометка = Истина;         

    КонецЕсли;   

    Возврат Истина;                     





КонецФункции // обИзменитьФорматТекста()

Категория: Работа с Интернет, Почтой (Mail), FTP

Импорт в 1С из текстовых файлов (TXT, CSV)

Не редко возникает необходимость загрузить в справочники или документы 1С данные из текстового файла. Приведенный пример внешней обработки позволит преобразовать текстовый файл с известным разделителем данных в поле табличного документа для последующей обработки уже внутри 1С:Предприятия. Обработка содержит функцию разбора строки на массив данных, настраиваемый разделитель строки текста на "столбцы", процедуру чтения данных из текстового файла.

Разбор строки в массив с использованием функций из конфигурации 1С
Для разложения строки в массив в конфигурация 1С:Бухгалтерия, 1С:Торговля и 1С:УПП имеется замечательная функция - Функция РазложитьСтрокуВМассивПодстрок(Знач Стр, Разделитель = ",") Экспорт. Функция "расщепляет" строку на подстроки, используя заданный разделитель. Разделитель может иметь любую длину. Если в качестве разделителя задан пробел, рядом стоящие пробелы считаются одним разделителем, а ведущие и хвостовые пробелы параметра "Стр" игнорируются. Подробнее можно прочесть внутри конфигурации - "Общие модули" -> "Общего назначения". Функция возвращает массив значений, элементы которого - подстроки.

Чтение текстового файла (txt) в 1С
Операцию импорта - экспорта текстовых файлов (формат тхт или csv, а также htm, html) очень удобно реализовать при помощи конструкции следующего вида:

1. Функция ПолучитьПотокЧтенияСтрок(Файл) - Назначение: Проверить наличие файла (функция Файл()), Создать текстовый документ (Новый ТекстовыйДокумент()), вызвать метод "Прочитать" для открытия потока чтения файла. Возвращает поток, готовый для чтения.
2. Процедура ЧтениеТХТФайла(Элемент) - Назначение: В цикле произвести последовательное чтение строк файла текстового документа, разбирая на массив колонок данных и добавляя значения массива в табличное поле;

Исходный код 1С функции создания текстового потока чтения файла ТХТ:

Код 1C v 8.х

 Функция ПолучитьПотокЧтенияСтрок(Файл)

  Попытка

    // Используется для доступа к параметрам файлов или каталогов. 

    ТекстовыйФайл = Новый Файл(Файл);

    Если ТекстовыйФайл.Существует() = Ложь Тогда

      Сообщить("Файла "+Файл+" не существует!");

      Возврат Неопределено;

    КонецЕсли;



    // Текстовый документ предназначен для работы с текстами. 

    // Объект позволяет получать и сохранять текст в файле, 

    // работать со строками

    ПотокЧтенияСтрок = Новый ТекстовыйДокумент();

    ПотокЧтенияСтрок.Прочитать(ТекстовыйФайл);

  Исключение

    Сообщить("Файл не прочитан.", СтатусСообщения.Внимание);

    Сообщить(ОписаниеОшибки());

    Возврат Неопределено;

  КонецПопытки;



  // Возвращает текст, извлеченный из файла

  Возврат ПотокЧтенияСтрок;



КонецФункции // ПолучитьПотокЧтенияСтрок





// Исходный код функции загрузки строк в табличное поле:



Процедура ЧтениеТХТФайла(Элемент)



  // Проверка на наличие имени файла

  Если ПустаяСтрока(ИмяФайла) Тогда

    Предупреждение("Для запуска обработки необходимо предварительно выбрать файл данных.");

    Возврат;

  КонецЕсли;



  // Открыть файл, создать текстовый документ, прочитать

  ПотокСтрок = ПолучитьПотокЧтенияСтрок(ИмяФайла);



  // Очистить предыдущие значения

  ТаблицаДокумента.Очистить();

  ТаблицаДокумента.Колонки.Очистить();



  // Создать колонки табличного документа

  ТаблицаДокумента.Колонки.Добавить("Номер",,"Номер",5);

  ТаблицаДокумента.Колонки.Добавить("Артикул",,"Артикул",11);

  ТаблицаДокумента.Колонки.Добавить("Номенклатура",,"Номенклатура",25);

  ТаблицаДокумента.Колонки.Добавить("Цена",,"Цена",6);



  // Последовательное чтение строк текстового файла

  КоличествоСтрок = ПотокСтрок.КоличествоСтрок();

  Для Строка = 1 По КоличествоСтрок Цикл



    // Обработка нажатия Ctrl + Break

    ОбработкаПрерыванияПользователя();



    // Чтение строки из файла тхт / csv

    СтрокаИзФайла = ПотокСтрок.ПолучитьСтроку(Строка);



    // Разбор строки в массив, используя в качествен символа-разделителя "|"

    МассивСтрок = ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(СтрокаИзФайла,"|");



    // Добавить данные в табличную часть экранной формы

    Стр=ТаблицаДокумента.Добавить();

    Стр.Номер	 = Строка;

    Стр.Артикул = МассивСтрок[0];

    Стр.Номенклатура = МассивСтрок[1];

    Стр.Цена = МассивСтрок[2];

    // Отобразить информацию о ходе выполнения обработки

    Состояние("Обработка строки файла : "

      + "строка " + Строка + " из " + КоличествоСтрок);



  КонецЦикла;



  // Отобразить результаты загрузки в форме элемента

  ЭлементыФормы.ТаблицаДокумента.Значение = ТаблицаДокумента;

  ЭлементыФормы.ТаблицаДокумента.СоздатьКолонки();



КонецПроцедуры // ЧтениеTXTФайла(Элемент)

В данном примере была произведена загрузка из текстового файла в следующем формате:

Код

7754|Процессор Atom 1.7|10,00
5054|Процессор AMD x64|8,99
7546|Мышь Microsoft|45,88

Категория: XML, DBF, TXT, CSV

Загрузка данных из текстовых файлов, выбирая SQL запросом данные из этих файлов Категория: Конвертация данных, Обмен, Перенос

Выгрузка форматированного документа 1С на свой сайт

Пользователи в 1с ведут описание объектов, которые редактируются в объекте ФорматированныйДокумент. Необходимо обеспечить выгрузку форматированного документа на фтп.

Для решения этой задачи воспользуемся методом форматированного документа ПолучитьHTML(). Этот метод вернет нам сам текст html документа и структуру картинок. После выполнения данного метода нам следует выгрузить картинки на наш сайт. Во время выгрузки картинок определяем тип картинки и на основании этого определяем расширение файла. Поэтому нам надо и подкорректировать сам текст html, так как источник картинки в нем по умолчанию прописывается в виде «image001″ (без расширения). Эта корректировка не критична для нас, страница будет отображаться нормально, но отдельно по ссылке открыть рисунок будет проблематично.
Код функции:

Код 1C v 8.2 УП

 &НаСервере

Функция ВыгрузитьОбъект(ТекОбъект)  Экспорт

    РезультатВыгрузки = "";



    //проверим есть ли описание объекта в базе

    ФорматированныйДокумент = ТекОбъект.Описание.Получить();

    Если ФорматированныйДокумент = Неопределено Тогда

        РезультатВыгрузки = "   У данного объекта не определено описание. Выгрузка объекта остановлена";

        Возврат РезультатВыгрузки;

    КонецЕсли;



    //Определяем настройки подключения к фтп

    Сервер = ХранилищеНастроек.ФТПСервер;

    Порт = ХранилищеНастроек.ФТПпорт;

    ИмяПользователяФТП = ХранилищеНастроек.ФТПИмяПользователя;

    ПарольПользователяФТП = ХранилищеНастроек.ФТППароль;

    ТекущийКаталогFTP = ХранилищеНастроек.ФТПТекущийКаталог;



    ФТП = Новый FTPСоединение(Сервер,,ИмяПользователяФТП,ПарольПользователяФТП);



    Попытка

        ФТП.УстановитьТекущийКаталог(ТекущийКаталогFTP);

    Исключение

        РезультатВыгрузки = "Невозможно подключиться к фтп";

        Возврат РезультатВыгрузки;

    КонецПопытки;



    ИмяКаталогаОбъекта = Формат(ТекОбъект.Ссылка.Код, "ЧЦ=5; ЧВН=; ЧГ=");



    //Каталог для элемента

    Попытка

        ФТП.УстановитьТекущийКаталог(ТекущийКаталогFTP + "/" + ИмяКаталогаОбъекта);

    Исключение

        ФТП.СоздатьКаталог(ИмяКаталогаОбъекта);

        ФТП.УстановитьТекущийКаталог(ТекущийКаталогFTP + "/" + ИмяКаталогаОбъекта);

        РезультатВыгрузки = РезультатВыгрузки + Символы.ПС + "   Создан каталог " + ТекущийКаталогFTP + "/" + ИмяКаталогаОбъекта;

    КонецПопытки;



    //Чистка имеющихся элементов в каталоге элемента

    ФТП.Удалить(ТекущийКаталогFTP + "/" + ИмяКаталогаОбъекта,"*.*");



    ТекстХТМЛ = "";

    СтруктураКартинок = Новый Структура;

    ФорматированныйДокумент.ПолучитьHTML(ТекстХТМЛ, СтруктураКартинок);



    //Выгрузка картинок и корректировка ХТМЛ

    Для Каждого ТекКартинка Из СтруктураКартинок Цикл

        ИмяТемпФайла = ПолучитьИмяВременногоФайла();

        ТекКартинка.Значение.Записать(ИмяТемпФайла);

        ФорматТекущейКартинки = Строка(ТекКартинка.Значение.Формат());

        Если Не ФорматТекущейКартинки = ФорматКартинки.НеизвестныйФормат Тогда

            ФорматТекущейКартинкиСтрока = Строка(ФорматТекущейКартинки);

            ТекстХТМЛ = СтрЗаменить(ТекстХТМЛ,ТекКартинка.Ключ,ТекКартинка.Ключ+ "." + ФорматТекущейКартинкиСтрока);

            ФТП.Записать(ИмяТемпФайла, ТекКартинка.Ключ+ "." + ФорматТекущейКартинкиСтрока);

            РезультатВыгрузки = РезультатВыгрузки + Символы.ПС + "   Записан файл " + ТекКартинка.Ключ+ "." + ФорматТекущейКартинкиСтрока;

        Иначе

            ФТП.Записать(ИмяТемпФайла, ТекКартинка.Ключ);

            РезультатВыгрузки = РезультатВыгрузки + Символы.ПС + "   Записан файл " + ТекКартинка.Ключ;

        КонецЕсли;

    КонецЦикла;



    //ВыгрузкаХТМЛ

    ИмяТемпФайла = ПолучитьИмяВременногоФайла("html");

    ФайлHТМЛ = Новый ТекстовыйДокумент;

    ФайлHТМЛ.ДобавитьСтроку(ТекстХТМЛ);

    ФайлHТМЛ.Записать(ИмяТемпФайла);



    //Собственно запись хтмл

    ФТП.Записать(ИмяТемпФайла, ИмяКаталогаОбъекта + ".html");

    РезультатВыгрузки = РезультатВыгрузки + Символы.ПС + "   Записан файл " + ИмяКаталогаОбъекта + ".html";



    Возврат РезультатВыгрузки;

КонецФункции

Андрей Данилюк

Категория: Форматированный документ

Загрузка данных из текстовых файлов с выборкой через ADO. Категория: XML, DBF, TXT, CSV

Получить статус сетевой карты(устройства), Работает или уже нет

Код 1C v 7.x

 // Глобальная переменная в которой будем хранить

// известные нам типы статусов сетевой карты

перем сзТипСтатуса;

// Глобальная переменая

перем обШелл;



//*******************************************

// стрСтатусАдаптера(стрИмя = "")

//

// Параметры:

//  стрИмя - Строка. Имя сетевой статус которой надо определить.

//           В том виде как показа в сетвых подключениях.

//

// Возвращаемое значение:

//  Строка. Статус заданой сетевой.

//

// Описание:

//  Функция определяет статус сетевой.

//

функция стрСтатусАдаптера(стрИмя = "")

    Ответ = "";

    // Попытаемся получить статус через контрол скриптов

    попытка

        сзСтевые = создатьобъект("списокзначений");

        // Выполняем скрипт. Из полученного значения пытаемся

        // сформировать список значений

        сзСтевые = значениеизстроки(обШелл.Run("strGetAdapterInfo"));

    исключение

        // По каким-то причинам выполнить скрипт не удалось

        Ответ = "Статус установить не удалось";

    конецпопытки;

    // Если в возращаемом значение пустая строка, то скрипт

    // выполнился. Можно смотреть дальше.

    если Ответ = "" тогда

        // Получаем индекс статуса сетевой.

        стрСтатус = строка(сзСтевые.Получить(стрИмя));

        // Проверяем на пустое значение индекса.

        если пустоезначение(стрСтатус) = 1 тогда

            // Если индекс пуст, то сетевая суказанным именем отсуствует

            Ответ = "Сетевая с таким именем отсуствует";

        иначе

            // Ищем индекс статуса в известных нам типов статуса.

            чисПозиция = сзТипСтатуса.НайтиЗначение(стрСтатус);

            если чисПозиция = 0 тогда

                // Не нашли. Смотрим MSDN

                Ответ = "Не известный тип статуса сетевой";

            иначе

                // Получаем строковое представление статуса.

                сзТипСтатуса.ПолучитьЗначение(чисПозиция, Ответ);

            конецесли;

        конецесли;

    конецесли;

    // Возвращаем полученный статус

    возврат Ответ;

конецфункции;



//*******************************************

// Этот блок обязателен.

// Необходимо что бы он отработал до первого вызова

// функции стрСтатусАдаптера

//*******************************************

// Создаем объект для управления скриптами

обШелл = создатьобъект("MSScriptControl.ScriptControl");

// Устанавливаем рабочий язык для выполнения скриптов

обШелл.Language = "VBScript";

// Сам срипт который соберет статусы всех сетевых устройств

тхтКод = "

|function strGetAdapterInfo()

|  dim objNetworkAdapter

|  Answer = ""{""""СписокЗначений"""",{""

|  set objWMI = getobject(""WinMgmts:\\.\Root\CIMV2"")

|  set objNetworkAdapters = objWMI.ExecQuery(""S_elect * FROM Win32_NetworkAdapter"", , 48)

|  for each objNetworkAdapter in objNetworkAdapters

|    Answer = Answer & ""{{""""Строка"""","""""" & objNetworkAdapter.NetConnectionStatus &_

|             """"""}, """""" & objNetworkAdapter.NetConnectionID & """""",""""0""""}""

|            

|  next

|  Answer = Answer & ""}}""

|  strGetAdapterInfo = Answer

|  end function";

// Добавим наш скрипт в котрол скриптов

обШелл.AddCode(тхтКод);

// Создадим список значений в который поместим все известные нам

// виды статуса сетевых устройств.

сзТипСтатуса = создатьобъект("списокзначений");

// Поместим в список значений виды статусов их строковое представление

сзТипСтатуса.ДобавитьЗначение("0", "Отключенно");

сзТипСтатуса.ДобавитьЗначение("1", "Подключение");

сзТипСтатуса.ДобавитьЗначение("2", "Подключено");

сзТипСтатуса.ДобавитьЗначение("3", "Отключение");

сзТипСтатуса.ДобавитьЗначение("4", "Устройство не представленно");

сзТипСтатуса.ДобавитьЗначение("5", "Устройство отключено");

сзТипСтатуса.ДобавитьЗначение("6", "Устройство не исправно");

сзТипСтатуса.ДобавитьЗначение("7", "Соединение разорвано");

сзТипСтатуса.ДобавитьЗначение("8", "Аутентификация");

сзТипСтатуса.ДобавитьЗначение("9", "Аутентификация прошла успешно");

сзТипСтатуса.ДобавитьЗначение("10", "Аутентификация не прошла");

сзТипСтатуса.ДобавитьЗначение("11", "Неправильный адресс");

сзТипСтатуса.ДобавитьЗначение("12", "Требуется полномочия");

IUnknown

Категория: COM-объекты, WMI, WSH

Как получить список зарегистрированных пользователей базы 1С

Код 1C v 8.х

  Выборка = ПользователиИнформационнойБазы.ПолучитьПользователей(); 

Для Каждого ЭлементМассива Из Выборка Цикл 

	ИмяПользователя = ЭлементМассива.Имя; 

	ПолноеИмяПользователя = ЭлементМассива.ПолноеИмя; 

	ЕстьПароль = ЭлементМассива.ПарольУстановлен; 

	Роли = ЭлементМассива.Роли; 

	

	Для Каждого Роль Из Роли Цикл 

		ИмяРоли = Роль.Имя; 

	КонецЦикла; 

КонецЦикла;

Код 1C v 7.x

 //  Функция возвращает список зарегистрированных для выбранной

//  базы пользователей. Если пользователи не определены, список

//  будет пуст.

//

функция сзПолучитьПользователей(стрПутьКБазе)

    // Создаем список значений для возврата

    Ответ = создатьобъект("СписокЗначений");

    // Формируем полное имя файла, в котором 1С

    // хранит информацию о пользователях базы.

    стрИмяФайла = стрПутьКБазе + "\UsrDEF\Users.USR";

    // Проверим его наличие.

    если фс.СуществуетФайл(стрИмяФайла) > 0 тогда

        // Создаем объект FSO для работы с файлами.

        обФСО = создатьобъект("Scripting.FileSystemObject");

        // Открываем файл пользователей как текстовый.

        тхтФайл = обФСО.OpenTextFile(стрИмяФайла);

        // Инициализация первоначальных переменных

        // Загружаем в буфер(тестовую строку) информацию из файла.

        стрБуфер = "";

        чисПозиция = 0;

        // Перебеирать файл придеться посимвольно, так как 1С не совсеми

        // символами может работать коректно если они находяться в строке.

        пока тхтФайл.AtEndOfStream = 0 цикл

            // Получаем очередную позицию в файле.

            чисПозиция = чисПозиция + 1;

            // Получаем символ из данной позиции.

            стрСимв = тхтФайл.Read(1);

            // Если код символа больше 31

            если кодсимв(стрСимв) > 31 тогда

                // Тогда добавляем его к буферу.

                стрБуфер = стрБуфер + стрСимв;

            конецесли;

        конеццикла;

        // После формирования буфера начнем искать пользователей в нем.

        // Признаком для пользователя будет строка '{"UserItemType","Page.'

        стрПоиска = "{""UserItemType"",""Page.";

        // Получаем позицию первого пользователя.

        чисПозиция = найти(стрБуфер, стрПоиска);

        // Проверяем если в буфере нужная нам строка

        если чисПозиция > 0 тогда

            // Если есть, вырезаем из строки ненужную информацию.

            стрБуфер = сред(стрБуфер, чисПозиция);

            // Позиция после отрезания становиться в единицу

            чисПозиция = 1;

        конецесли;

        // В цикле получаем информацию о пользователях БД

        пока чисПозиция > 0 цикл

            // Удаляем из буфера 'мусор'

            стрБуфер = сред(стрБуфер, чисПозиция + 22);

            // Находим признак начала информации об имени пользователя.

            чисСмещение = найти(стрБуфер, """,""") + 3;

            // Перемещаем начало буфера на начало информации об имени пользователя

            стрБуфер = сред(стрБуфер, чисСмещение);

            // Получаем имя пользователя

            стрИмяПользователя = лев(стрБуфер, найти(стрБуфер, """,""") - 1);

            // Добовляем имя к нашему списку.

            Ответ.ДобавитьЗначение(стрИмяПользователя);

            // Получаем очередную позицию информации о пользователе

            чисПозиция = найти(стрБуфер, стрПоиска);

        конеццикла;

    конецесли;

    // Возращаем полученный список значений содержащий в себе список пользователей базы

    возврат Ответ;

конецфункции

еще Пример получения списка пользователей из файла users.usr

Категория: Полезные, Универсальные Функции