ФормДок = Новый ФорматированныйДокумент;

	Вложения = Новый Структура;

	ФормДок.УстановитьHTML(ТестСтраницы, Вложения);

	Вложения = Неопределено;

	ТекстСайта = ФормДок.ПолучитьТекст();

	ФормДок = Неопределено;

   

В процессе разработки прикладных решений возникает необходимость предоставить пользователю возможность выполнять редактирование текстов с оформлением (далее форматированный документ). В качестве примера такой необходимости можно привести написание писем электронной почты, различных служебных записок или сопроводительных документов.

Для работы с форматированным документом предназначен объект ФорматированныйДокумент, с помощью которого можно выполнять программную обработку документа и поле ввода вида Поле форматированного документа, который предназначен для интерактивного изменения форматированного документа.

В информационной базе форматированный документ рекомендуется хранить в реквизите типа ХранилищеЗначения, в который помещается объект типа ФорматированныйДокумент.

Для того чтобы предоставить пользователю возможность интерактивного изменения документа, следует выполнить следующие шаги:
* создать реквизит формы типа ФорматированныйДокумент и установить для него свойство Сохраняемые данные;
* создать элемент формы типа Поле ввода вида Поле форматированного документа и связать его с ранее созданным реквизитом;
* при чтении данных формы (обработчик ПриЧтенииНаСервере()) загрузить в реквизит формы документ, который необходимо редактировать, предварительно получив его из информационной базы;
* перед записью данных формы (обработчик ПередЗаписьюНаСервере()) получить результат редактирования документа и поместить его в реквизит, сохраняемый в информационной базе.
* В процессе работы с документом можно использовать закладки. Закладкой называет позиция в документе. При определении позиции следует учитывать следующие особенности:
o содержимое документа считается одной последовательностью символов.
o перенос строки считается одним символом.
o картинка считается одним символом.

С помощью закладок можно получать и устанавливать выделение или позицию курсора в редакторе, добавлять и удалять элементы текста в документе (собственно текст, картинка, перевод строки).

Если при получении выделения позиции начала и окончания выделения совпадают, это значит, что выделение отсутствует и получено положение курсора. Также и при установке выделения: если начальная и конечная позиция выделения совпадают – происходит изменение позиции курсора, без выделения. Также следует помнить, что при программном изменении выделенного текста не происходит отмены выделения. Выделение остается в тех же позициях, в которых оно было до программного изменения текста.
Приведем пример получения и установки выделения в редакторе форматированного документа:

Код 1C v 8.2 УП

 // Содержимое – реквизит формы типа ФорматированныйДокумент

// Редактор – элемент формы типа Поле форматированного документа

// Начало – реквизит формы типа Число. Указывает позицию начала выделения.

// Окончание – реквизит формы типа Число. Указывает позицию окончания выделения.



&;НаКлиенте

Процедура ПолучитьВыделение()

    ПозицияНачала = 0;

    ПозицияОкончания = 0;

    Элементы.Редактор.ПолучитьГраницыВыделения(ПозицияНачала,ПозицияОкончания);

    Начало = Содержимое.ПолучитьПозициюПоЗакладке(ПозицияНачала);

    Окончание = Содержимое.ПолучитьПозициюПоЗакладке(ПозицияОкончания);

КонецПроцедуры



&;НаКлиенте

Процедура УстановитьВыделение()

    ПозицияНачала = Содержимое.ПолучитьЗакладкуПоПозиции(Начало);

    ПозицияОкончания = Содержимое.ПолучитьЗакладкуПоПозиции(Окончание);

    Элементы.Редактор.УстановитьГраницыВыделения(ПозицияНачала,ПозицияОкончания);

КонецПроцедуры   

Форматированный документ предназначен для оформление текста. Его можно выделить жирным, подчеркнуть, увеличить/уменьшить шрифт, центрировать и т.д. Также можно добавить картинку. Т.е. в 1С теперь можно отформатировать текст, примерно, как в MS Word и др. подобным программам. Это может быть удобно при оформлении различных договоров или, например, при редактировании электронного письма. Таким образом, у нас есть возможность привести текстовый документ в тот вид, который мы пожелаем.



В синтакс-помощнике есть описание.
Объект ФорматированныйДокумент (FormattedDocument) имеет одноименный тип данных, который поддерживает функционирование данного объекта и имеет следующие методы:
Вставить (I_nsert)
Добавить (Add)
Записать (Write)
ПолучитьHTML (GetHTML)
ПолучитьЗакладкуКонца (GetEndBookmark)
ПолучитьЗакладкуНачала (GetBeginBookmark)
ПолучитьЗакладкуПоПозиции (GetPositionBookmark)
ПолучитьПозициюПоЗакладке (GetBookmarkPosition)
ПолучитьТекст (GetText)
Удалить (Delete)
УстановитьHTML (SetHTML)

Доступен во всех типах приложения: Тонкий клиент, веб-клиент, сервер, толстый клиент, внешнее соединение. Нельзя указать новый тип данных в качестве типа реквизита.

Есть одна важная особенность этого типа. Нельзя задавать тип «Форматированный документ» для реквизита объекта (справочника, документа и др.). Но есть возможность указывать его для реквизитов формы.



Возникает вопрос, как же нам сохранить те изменения при форматировании текста, которые сделал пользователь? Для этого применяется специальный объект «ХранилищеЗначения», который может содержать в себе любой тип данных, в том числе и «форматированный документ». Таким образом, в базе данных сам объект будет храниться как «Хранилище значения», далее при открытии формы необходимо будет извлечь объект из хранилища, отобразить его на форме используя тип «ФорматированныйДокумент». Если пользователь решит сохранить изменения, то при записи объекта нужно снова взять объект «форматированный документ» и записать его в хранилище.

Пример работы
Возьмем за основу каркасную конфигурацию, создадим в ней справочники «Контрагенты» и «Договоры». Установим справочник «Договоры» подчиненным справочнику «Контрагенты» и создадим реквизит «Текст» с типом ХранилищеЗначения.

Создадим форму элемента справочника «Договоры» и добавим на нее новый реквизит, который назовем «ТекстДоговора», укажем тип данных «ФорматированныйДокумент». Обратите внимание, что реквизит «Текст» с типом «ХранилищеЗначения» на форму поместить нельзя.
Создадим также командную панель (меню) содержащую необходимые кнопки для управления форматированным документом. Для этого надо добавить в форму «Группа – Командная панель» и указать в свойстве «Источник команд» реквизит формы «ТекстДоговора» с типом ФорматированныйДокумент.

Запускаем отладчик, проверяем, что у нас получилось…

Все бы хорошо, но есть некоторые проблемы:
Во-первых, если ввести текст и отформатировать его должным образом, то признак модифицированности для формы не возникает. Таким образом, случайно нажав на кнопку закрытия формы, система не задавая вопросов закрывает ее без всякого сохранения.
Для того чтобы подобные неприятности не случались, необходимо установить флаг у свойства «Сохраняемые данные» реквизита формы «ТекстДоговора». В результате, при любом изменении данных в реквизите «ТекстДоговора», будет устанавливаться признак модифицированности формы, а при ее закрытии система спросит: «Сохранить изменения?».

Во-вторых. Попытаемся закрыть форму и сохранить введенные данные. Заново открыв сохраненный договор, видим что текст введенный в форму договора отсутствует. Почему так происходит?

Все дело в том, что мы делаем изменения в реквизите формы, который у нас никак не связан с реквизитом объекта. Давайте настроим связь между реквизитом формы «Текст договора» с типом данных «ФорматированныйДокумент» и реквизитом объекта «Текст» с типом «ХранилищеЗначения».

Пропишем эту связь программно в модуле формы. Опишем алгоритм.

1. При открытии формы, необходимо будет обратиться к реквизиту объекта «Текст», чтобы прочитать из него данные и записать их в форматированный документ «Текст договора».
2. При записи объекта, берем содержимое форматированного документа и помещаем его в реквизит объекта «Текст» с типом «ХранилищеЗначения».

Таким образом у нас будет возникать эффект, что все изменения производимые пользователем, будут сохраняться в базе данных.
Нам понадобятся следующие обработчики событий:
- событие ПриЧтенииНаСервере(ТекущийОбъект)
оно удобно тем, что при ошибочном внесении изменений в данные формы, можно нажать кнопку «Перечитать» и вернутся к исходным данным.

Код 1C v 8.2 УП

 &НаСервере

Процедура ПриЧтенииНаСервере(ТекущийОбъект)

 ТекстДоговора = ТекущийОбъект.Текст.Получить();

КонецПроцедуры   

- событие ПередЗаписьюНаСервере(Отказ, ТекущийОбъект, ПараметрыЗаписи)

Код 1C v 8.2 УП

 &НаСервере

Процедура ПередЗаписьюНаСервере(Отказ, ТекущийОбъект, ПараметрыЗаписи)

 ТекущийОбъект.Текст = Новый ХранилищеЗначения(ТекстДоговора);

КонецПроцедуры   

Т.к. реквизит Текст у нас имеет тип «ХранилищеЗначений», надо учесть нюансы работы с ним… В случае чтения объекта используем метод Получить(), а в случае записи используем конструктор объекта Новый ХранилищеЗначения(<Значение>, <АлгоритмСжатияДанных>).

На этом пока всё. В следующий раз попробую рассказать про использование шаблонов для вставки параметров в текст форматированного документа, например, вместо %Контрагент% вставлять наименование контрагента.
Сергей (SirYozha)

Пользователи в 1с ведут описание объектов, которые редактируются в объекте ФорматированныйДокумент. Необходимо обеспечить выгрузку форматированного документа на фтп.

Для решения этой задачи воспользуемся методом форматированного документа ПолучитьHTML(). Этот метод вернет нам сам текст html документа и структуру картинок. После выполнения данного метода нам следует выгрузить картинки на наш сайт. Во время выгрузки картинок определяем тип картинки и на основании этого определяем расширение файла. Поэтому нам надо и подкорректировать сам текст html, так как источник картинки в нем по умолчанию прописывается в виде «image001&#8243; (без расширения). Эта корректировка не критична для нас, страница будет отображаться нормально, но отдельно по ссылке открыть рисунок будет проблематично.
Код функции:

Код 1C v 8.2 УП

 &НаСервере

Функция ВыгрузитьОбъект(ТекОбъект)  Экспорт

    РезультатВыгрузки = "";



    //проверим есть ли описание объекта в базе

    ФорматированныйДокумент = ТекОбъект.Описание.Получить();

    Если ФорматированныйДокумент = Неопределено Тогда

        РезультатВыгрузки = "   У данного объекта не определено описание. Выгрузка объекта остановлена";

        Возврат РезультатВыгрузки;

    КонецЕсли;



    //Определяем настройки подключения к фтп

    Сервер = ХранилищеНастроек.ФТПСервер;

    Порт = ХранилищеНастроек.ФТПпорт;

    ИмяПользователяФТП = ХранилищеНастроек.ФТПИмяПользователя;

    ПарольПользователяФТП = ХранилищеНастроек.ФТППароль;

    ТекущийКаталогFTP = ХранилищеНастроек.ФТПТекущийКаталог;



    ФТП = Новый FTPСоединение(Сервер,,ИмяПользователяФТП,ПарольПользователяФТП);



    Попытка

        ФТП.УстановитьТекущийКаталог(ТекущийКаталогFTP);

    Исключение

        РезультатВыгрузки = "Невозможно подключиться к фтп";

        Возврат РезультатВыгрузки;

    КонецПопытки;



    ИмяКаталогаОбъекта = Формат(ТекОбъект.Ссылка.Код, "ЧЦ=5; ЧВН=; ЧГ=");



    //Каталог для элемента

    Попытка

        ФТП.УстановитьТекущийКаталог(ТекущийКаталогFTP + "/" + ИмяКаталогаОбъекта);

    Исключение

        ФТП.СоздатьКаталог(ИмяКаталогаОбъекта);

        ФТП.УстановитьТекущийКаталог(ТекущийКаталогFTP + "/" + ИмяКаталогаОбъекта);

        РезультатВыгрузки = РезультатВыгрузки + Символы.ПС + "   Создан каталог " + ТекущийКаталогFTP + "/" + ИмяКаталогаОбъекта;

    КонецПопытки;



    //Чистка имеющихся элементов в каталоге элемента

    ФТП.Удалить(ТекущийКаталогFTP + "/" + ИмяКаталогаОбъекта,"*.*");



    ТекстХТМЛ = "";

    СтруктураКартинок = Новый Структура;

    ФорматированныйДокумент.ПолучитьHTML(ТекстХТМЛ, СтруктураКартинок);



    //Выгрузка картинок и корректировка ХТМЛ

    Для Каждого ТекКартинка Из СтруктураКартинок Цикл

        ИмяТемпФайла = ПолучитьИмяВременногоФайла();

        ТекКартинка.Значение.Записать(ИмяТемпФайла);

        ФорматТекущейКартинки = Строка(ТекКартинка.Значение.Формат());

        Если Не ФорматТекущейКартинки = ФорматКартинки.НеизвестныйФормат Тогда

            ФорматТекущейКартинкиСтрока = Строка(ФорматТекущейКартинки);

            ТекстХТМЛ = СтрЗаменить(ТекстХТМЛ,ТекКартинка.Ключ,ТекКартинка.Ключ+ "." + ФорматТекущейКартинкиСтрока);

            ФТП.Записать(ИмяТемпФайла, ТекКартинка.Ключ+ "." + ФорматТекущейКартинкиСтрока);

            РезультатВыгрузки = РезультатВыгрузки + Символы.ПС + "   Записан файл " + ТекКартинка.Ключ+ "." + ФорматТекущейКартинкиСтрока;

        Иначе

            ФТП.Записать(ИмяТемпФайла, ТекКартинка.Ключ);

            РезультатВыгрузки = РезультатВыгрузки + Символы.ПС + "   Записан файл " + ТекКартинка.Ключ;

        КонецЕсли;

    КонецЦикла;



    //ВыгрузкаХТМЛ

    ИмяТемпФайла = ПолучитьИмяВременногоФайла("html");

    ФайлHТМЛ = Новый ТекстовыйДокумент;

    ФайлHТМЛ.ДобавитьСтроку(ТекстХТМЛ);

    ФайлHТМЛ.Записать(ИмяТемпФайла);



    //Собственно запись хтмл

    ФТП.Записать(ИмяТемпФайла, ИмяКаталогаОбъекта + ".html");

    РезультатВыгрузки = РезультатВыгрузки + Символы.ПС + "   Записан файл " + ИмяКаталогаОбъекта + ".html";



    Возврат РезультатВыгрузки;

КонецФункции   

Андрей Данилюк