Отправка отчетов из 1С по электронной почте (E-Mail)

Автоматическая генерация отчета "Анализ заказов поставщикам"
Отчет анализ заказов является штатным отчетом конфигурации 1С Управление производственным предприятием. Обработка для генерации отчета, рассматриваемая в данной статье, позволяет программно создать и настроить форму отчета, запустить его выполнение. Полученный результат сохраняется в файл Microsoft Excel (XLS, XLSX) и может быть отправлен по электронной почте.
Предлагаемое решение состоит из трех файлов: Скачивать файлы может только зарегистрированный пользователь!

service.vbs служит для запуска 1С предприятия и генерации отчета;
emailer.vbs - VBS скрипт предназначен для отправки результатов выполнения запроса отчета на указанный при настройке адрес электронной почты;
rep_email.epf - сама внешняя обработка для генерации отчета, выполняющая настройки отображаемых показателей, группировок строк и столбцов, установки требуемых отборов отчета, обеспечивает выполнение запроса и формирования табличного документа по макету отчета и сохранение сформированного отчета в XLS файл.

Запуск отчета выполняется посредством VBS файла (vbscript) при помощи "Назначенных заданий". VBS программа обеспечивает запуск приложения 1С, устанавливает соединение с сервером 1С и передает управление внешней обработке через экспортную функцию ReportNow(), размещенную в общем модуле обработки по генерации отчета. Пример VBS Script для выполнения внешней обработки 1С из командной строки:

Код VBS

 ' Установить соединение с сервером 1С

Set v81 = CreateObject("V81.Application")

res = v81.Connect("Srvr=Server1C;Ref = db1C;Usr=User1C;Pwd=Password1C")

' Передать управление внешней обработке по генерации Отчета Анализ Заказов

res = v81.ExternalDataProcessors.Create("C:\1C\Service\rep_email.epf").ThisObject.Report()

v81.Exit(false)



' Дать возможность 1С закрыть все открытые файлы и выгрузиться из памяти

WScript.Sleep(5000)



' Вызвать VBS скрипт отправки почты по E-Mail

Dim WshShell

Set WshShell = WScript.CreateObject("WScript.Shell")

WshShell.Run "C:\1C\ Service\emailer.vbs"

VBS E-Mail скрипт для отправки готового отчета в формате Excel создает новое электронное письмо на заданный адрес, в теле письма указывает пояснение к отчету, а в качестве вложения прикрепляет файл, создание и наполнение информацией которого была произведена при запуске service.vbs

Код VBS

 'Отправить сообщение с помощью локальной службы SMTP

Const cdoSendUsingPickup = 1

'Отправить сообщение с помощью сети (SMTP через сеть)

Const cdoSendUsingPort = 2

Const cdoAnonymous = 0

Const cdoBasic = 1

Const cdoNTLM = 2



Set objMessage = CreateObject("CDO.Message")

' Тема сообщения и адрес отправителя

objMessage.Subject = "Ежедневный отчет Анализ заказов поставщикам"

objMessage.From = """Генератор отчетов"" "

' Получатели письма указываются через " ; "

objMessage.To = "email@domain.org; recv@domain.net; last@domain.ru"

' Содержимое тела письма.

objMessage.TextBody = "JSC AUTO SERVICE. Please find Orders reporting in attachment." & vbCRLF & _

"------------------------------------------" & vbCRLF & _

"Best regards, Auto report service" & vbCRLF & _

"Support line: it@domian.ru" & vbCRLF



' Добавляем файл - вложение для отправки отчета по EMail

objMessage.AddAttachment "C:\1C\Service\ЗаказыПоставщику.xls"



' Секция настроек SMTP сервера для отправки почты.

objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2



' Имя или IP адрес SMTP Server

objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "mail.domain.ru"



' Тип используемой авторизации, NONE, Basic (Base64 encoded), NTLM

objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasic



' Авторизация на SMTP server

objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = "report@domain.ru"

' Пароль SMTP server

objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "youpassword"



' Порт SMTP Server port (обычно 25, но может быть и другим)

objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25

' Использование SSL для соединения (False или True)

objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = False

' Время ожидания соединения с почтовым сервером

objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60

' Сохранить настройки CDO для отправки сообщения

objMessage.Configuration.Fields.Update



' Отправить созданное почтовое сообщение с вложением отчета в формате XLS по указанному адресу

objMessage.Send

Внешняя обработка по запуску отчета "Анализ заказов поставщику" состоит из двух процедур. Первая - "ReportNow() Экспорт" служит для определения входной точки передачи управления от VBS к 1С. Вторая - "ОткрытьОтчетПоИмени()" - выполняет действия по настройке критериев отбора отчета, группировке строк и столбцов, определению состава количественных показателей. Данный способ вызова отчетов стандартной конфигурации широко применяется в различных формах 1С, и по мере развития конфигурации может быть позаимствован как минимум из нескольких форм списка справочников (Контрагенты, Номенклатура и т.д.). Исходный код первой функции: >

Код 1C v 8.х

 Процедура ReportNow() Экспорт

 // Вызывается из vbscript, выполняет работы с отчетом.

 ОткрытьОтчетПоИмени("АнализЗаказовПоставщикам");

КонецПроцедуры

Сохранение отчета из 1С в Excel
Процедура формирования формы отчета принимает в качестве параметра название объекта метаданных конфигурации, в данном случае - "АнализЗаказовПоставщикам". Очевидно, что в зависимости от типа отчета процедура будет меняться пропорционально используемым реквизитам. В рассматриваемом примере добавляется отбор по контрагенту. Для своего ключевого поставщика заменить значение искомого наименования на нужное.

Код 1C v 8.х

 Процедура ОткрытьОтчетПоИмени(НазваниеОтчета) Экспорт



// получаем отчет и открываем форму

// для построения отчета по названию отчета

Отчет = Отчеты[НазваниеОтчета].Создать();

Форма = Отчет.ПолучитьФорму(, , );

Форма.Открыть();



// Выполнить настройку отчета по умолчанию

Отчет.УстановитьНачальныеНастройки();



// Добавить требуемый отбор по поставщику

ТекОтбор = Отчет.УниверсальныйОтчет.ПостроительОтчета.Отбор.ДоговорКонтрагентаВладелец;

ТекОтбор.Использование = Истина;

ТекОтбор.Значение = Справочники.Контрагенты.НайтиПоНаименованию("Поставщик");

ТекОтбор.ВидСравнения = ВидСравнения.Равно;



// Добавляем специфичное для нас измерение в отборе - например, "осталось отгрузить"

// в данном случае из отчета уйдут позиции, по которым все получено.

Отчет.УниверсальныйОтчет.ПостроительОтчета.Отбор.Добавить("ОсталосьОтгрузитьЕдиницОтчетов");

ТекОтбор1 = ОтчетОстатки.УниверсальныйОтчет.ПостроительОтчета.Отбор.ОсталосьОтгрузитьЕдиницОтчетов;

ТекОтбор1.Использование = Истина;

ТекОтбор1.Значение = 0;

ТекОтбор1.ВидСравнения = ВидСравнения.Больше;



// Состав отдельных ключевых показателей

// для каждого отчета можно посмотреть в конфигураторе

Отчет.СостояниеОтгрузкиПоЗаказу = истина;

Отчет.НеОтгружено = Истина;

Отчет.ОтгруженоЧастично = Истина;



// После завершения настроек нажмем программно кнопку "Сформировать"

Отчет.СформироватьОтчет(ФормаОтчета.ЭлементыФормы.ПолеТабличногоДокументаРезультат);



// Сформировать путь и имя файла для сохранения отчета

мПутьШаблон="C:\1C\Service";

мФайлШаблон="ЗаказыПоставщику.xls";

ИмяФайла = мПутьШаблон + "\" + мФайлШаблон;



// Полученные в отчете цифры и данные сохраним в файл Excel

Если Не ИмяФайла = Неопределено Тогда

Форма.ЭлементыФормы.ПолеТабличногоДокументаРезультат.СохранятьСвойстваОтображения = Истина;

Форма.ЭлементыФормы.ПолеТабличногоДокументаРезультат.Записать(ИмяФайла, ТипФайлаТабличногоДокумента.XLS97);

КонецЕсли;



// Закрыть форму отчета после завершения работы

ФормаОтчета.Закрыть();

КонецПроцедуры

Для того, чтобы отладить обработку в режиме 1С:Предприятие, запущенного из конфигуратора можно создать экранную форму обработки и разместить в ней следующую процедур автоматического запуска отлаживаемого отчета:

Код 1C v 8.х

 Процедура ПередОткрытием(Отказ, СтандартнаяОбработка)

Отказ = истина;

ОткрытьОтчетПоИмени("АнализЗаказовПоставщикам");

КонецПроцедуры

Надеемся, что успешная комбинация внешней обработки для запуска отчета по расписанию и vbscript поможет в автоматизации бизнеса вашего предприятия. Данная редакция настроек больше ориентирована на менеджера поставщика для вашей компании, что отслеживать взаимное движение товаров и документов.
Источник

Руководство компании, хочет получать оперативную сводку продаж по фирме

Опубликовано на сайте: https://HelpF.pro
Прямая ссылка: https://HelpF.pro/faq/view/1053.html