HelpF.pro

Функция "расщепляет" строку на подстроки, используя заданный разделитель

глРазложить(Стр,Разделитель)
Параметры:
Стр - строка, которую необходимо разложить на подстроки.
Параметр передается по значению.
Разделитель - строка-разделитель, по умолчанию - запятая.

Возвращаемое значение:
список значений, элементы которого - подстроки

Описание:
Функция "расщепляет" строку на подстроки, используя заданный разделитель.
Разделитель может иметь любую длину.
Если в качестве разделителя задан пробел, рядом стоящие пробелы
считаются одним разделителем, а ведущие и хвостовые пробелы параметра Стр
игнорируются.

Пример:
глРазложить(",ку,,,му", ",") возвратит список значений из пяти элементов,
три из которых - пустые строки, а
глРазложить(" ку му", " ") возвратит список значений из двух элементов

Код 1C v 7.x
 

Функция глРазложить(Знач Стр, Разделитель = ",") Экспорт

	СЗ = СоздатьОбъект("СписокЗначений");

	Если Разделитель = " " Тогда

		Стр = СокрЛП(Стр);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				СЗ.ДобавитьЗначение(Стр);

				Возврат СЗ;

			КонецЕсли;

			СЗ.ДобавитьЗначение(Лев(Стр,Поз-1));

			Стр = СокрЛ(Сред(Стр,Поз));

		КонецЦикла;

	Иначе

		ДлинаРазделителя = СтрДлина(Разделитель);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				СЗ.ДобавитьЗначение(Стр);

				Возврат СЗ;

			КонецЕсли;

			СЗ.ДобавитьЗначение(Лев(Стр,Поз-1));

			Стр = Сред(Стр,Поз+ДлинаРазделителя);

		КонецЦикла;

	КонецЕсли;

КонецФункции



Код 1C v 8.х
 

Функция глРазложить(Знач Стр, Разделитель = ",") Экспорт

	СЗ = Новый СписокЗначений;

	Если Разделитель = " " Тогда

		Стр = СокрЛП(Стр);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				СЗ.Добавить(Стр);

				Возврат СЗ;

			КонецЕсли;

			СЗ.Добавить(Лев(Стр,Поз-1));

			Стр = СокрЛ(Сред(Стр,Поз));

		КонецЦикла;

	Иначе

		ДлинаРазделителя = СтрДлина(Разделитель);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				СЗ.Добавить(Стр);

				Возврат СЗ;

			КонецЕсли;

			СЗ.Добавить(Лев(Стр,Поз-1));

			Стр = Сред(Стр,Поз+ДлинаРазделителя);

		КонецЦикла;

	КонецЕсли;

КонецФункции

Пример использования функции глРазложить
Опубликовано на сайте: https://HelpF.pro
Прямая ссылка: https://HelpF.pro/faq8/view/171.html