v8.2 УП: БольничныЛист ДнейБолезниУходаЗаДетьми

 ВЫБРАТЬ

	СтраховыеВзносыСведенияОДоходахОбороты.РезультатОборот - СтраховыеВзносыСведенияОДоходахОбороты.СкидкаОборот КАК Заработок,

	СтраховыеВзносыСведенияОДоходахОбороты.Период

ПОМЕСТИТЬ ВТДоходыПоМесяцам

ИЗ

	РегистрНакопления.СтраховыеВзносыСведенияОДоходах.Обороты(

			&Начало,

			&Окончание,

			Месяц,

			ВидДохода.ВходитВБазуФСС

				И ФизЛицо = &ФизЛицо

				И Организация = &ГоловнаяОрганизация

				И (ОбособленноеПодразделение = &ОбособленноеПодразделение

					ИЛИ &ПоВсейОрганизации)) КАК СтраховыеВзносыСведенияОДоходахОбороты

ГДЕ

	ГОД(СтраховыеВзносыСведенияОДоходахОбороты.Период) В (&МассивЛет)

;



////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ

	СотрудникиОрганизаций.Ссылка

ПОМЕСТИТЬ ВТСотрудники

ИЗ

	Справочник.СотрудникиОрганизаций КАК СотрудникиОрганизаций

ГДЕ

	СотрудникиОрганизаций.Организация = &ГоловнаяОрганизация

	И СотрудникиОрганизаций.Физлицо = &Физлицо

	И СотрудникиОрганизаций.ВидЗанятости <> ЗНАЧЕНИЕ(Перечисление.ВидыЗанятостиВОрганизации.ВнутреннееСовместительство)

;



////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ

	ОсновныеНачисленияОрганизаций.Ссылка

ПОМЕСТИТЬ ВТНеоблагаемыеВзносамиОтсутствия

ИЗ

	ПланВидовРасчета.ОсновныеНачисленияОрганизаций КАК ОсновныеНачисленияОрганизаций

ГДЕ

	ОсновныеНачисленияОрганизаций.ЗачетНормыВремени

	И НЕ ОсновныеНачисленияОрганизаций.ЗачетОтработанногоВремени

	И НЕ ЕСТЬNULL(ОсновныеНачисленияОрганизаций.КодДоходаСтраховыеВзносы.ВходитВБазуФСС, ЛОЖЬ)

	И ОсновныеНачисленияОрганизаций.СпособРасчета <> ЗНАЧЕНИЕ(Перечисление.СпособыРасчетаОплатыТруда.НулеваяСумма)

	И НЕ ОсновныеНачисленияОрганизаций.ОбозначениеВТабелеУчетаРабочегоВремени В (ЗНАЧЕНИЕ(Справочник.КлассификаторИспользованияРабочегоВремени.Прогулы), ЗНАЧЕНИЕ(Справочник.КлассификаторИспользованияРабочегоВремени.НеоплачиваемыйОтпускПоРазрешениюРаботодателя), ЗНАЧЕНИЕ(Справочник.КлассификаторИспользованияРабочегоВремени.НеоплачиваемыйОтпускПоЗаконодательству), ЗНАЧЕНИЕ(Справочник.КлассификаторИспользованияРабочегоВремени.НеоплачиваемыйДополнительныйОтпуск), ЗНАЧЕНИЕ(Справочник.КлассификаторИспользованияРабочегоВремени.ОтпускНаОбучениеНеоплачиваемый), ЗНАЧЕНИЕ(Справочник.КлассификаторИспользованияРабочегоВремени.ОтстранениеОтРаботыБезОплаты))



ОБЪЕДИНИТЬ



ВЫБРАТЬ

	ЗНАЧЕНИЕ(ПланВидовРасчета.ОсновныеНачисленияОрганизаций.ОтпускПоУходуЗаРебенкомБезОплаты)



ОБЪЕДИНИТЬ



ВЫБРАТЬ

	ЗНАЧЕНИЕ(ПланВидовРасчета.ОсновныеНачисленияОрганизаций.ОтсутствиеПоБолезни)



ОБЪЕДИНИТЬ



ВЫБРАТЬ

	ЗНАЧЕНИЕ(ПланВидовРасчета.ОсновныеНачисленияОрганизаций.ОтсутствиеПоБолезниПоБеременности)

;



////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ

	ОсновныеНачисленияРаботниковОрганизацийФактическийПериодДействия.ПериодДействия,

	СУММА(РАЗНОСТЬДАТ(ОсновныеНачисленияРаботниковОрганизацийФактическийПериодДействия.ПериодДействияНачало, ДОБАВИТЬКДАТЕ(КОНЕЦПЕРИОДА(ОсновныеНачисленияРаботниковОрганизацийФактическийПериодДействия.ПериодДействияКонец, ДЕНЬ), СЕКУНДА, 1), ДЕНЬ) * ВЫБОР

			КОГДА ОсновныеНачисленияРаботниковОрганизацийФактическийПериодДействия.Сторно

				ТОГДА -1

			ИНАЧЕ 1

		КОНЕЦ) КАК ДнейИсключаемыхОтсутствий

ПОМЕСТИТЬ ВТПериодыИсключаемыхОтсутствий

ИЗ

	РегистрРасчета.ОсновныеНачисленияРаботниковОрганизаций.ФактическийПериодДействия(

			Сотрудник В

					(ВЫБРАТЬ

						СотрудникиФизлица.Ссылка

					ИЗ

						ВТСотрудники КАК СотрудникиФизлица)

				И ФизЛицо = &ФизЛицо

				И ВидРасчета В

					(ВЫБРАТЬ

						НеоблагаемыеВзносамиОтсутствия.Ссылка

					ИЗ

						ВТНеоблагаемыеВзносамиОтсутствия КАК НеоблагаемыеВзносамиОтсутствия)

				И Организация = &ГоловнаяОрганизация

				И (ОбособленноеПодразделение = &ОбособленноеПодразделение

					ИЛИ &ПоВсейОрганизации)

				И ГОД(ПериодДействия) В (&МассивЛет)

				И ПериодДействия > &ДатаДоЗакона212

				И ПериодРегистрации <= &ОграничениеПоПериодуРегистрации) КАК ОсновныеНачисленияРаботниковОрганизацийФактическийПериодДействия



СГРУППИРОВАТЬ ПО

	ОсновныеНачисленияРаботниковОрганизацийФактическийПериодДействия.ПериодДействия

;



////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ РАЗЛИЧНЫЕ

	ДоходыПоМесяцам.Период

ПОМЕСТИТЬ ВТПериоды

ИЗ

	ВТДоходыПоМесяцам КАК ДоходыПоМесяцам



ОБЪЕДИНИТЬ



ВЫБРАТЬ

	ПериодыИсключаемыхОтсутствий.ПериодДействия

ИЗ

	ВТПериодыИсключаемыхОтсутствий КАК ПериодыИсключаемыхОтсутствий

;



////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ

	Периоды.Период КАК Месяц,

	НЕ ЕСТЬNULL(ГражданствоФизЛиц.НеИмеетПравоНаПенсию, ЛОЖЬ) КАК ИмеетПравоНаСтрахование

ПОМЕСТИТЬ ВТДанныеОПравеНаСтрахование

ИЗ

	(ВЫБРАТЬ

		Периоды.Период КАК Период,

		МАКСИМУМ(ГражданствоФизЛиц.Период) КАК ПериодРегистра

	ИЗ

		ВТПериоды КАК Периоды

			ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ГражданствоФизЛиц КАК ГражданствоФизЛиц

			ПО Периоды.Период >= ГражданствоФизЛиц.Период

				И (ГражданствоФизЛиц.ФизЛицо = &ФизЛицо)

	

	СГРУППИРОВАТЬ ПО

		Периоды.Период) КАК Периоды

		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ГражданствоФизЛиц КАК ГражданствоФизЛиц

		ПО Периоды.ПериодРегистра = ГражданствоФизЛиц.Период

			И (ГражданствоФизЛиц.ФизЛицо = &Физлицо);

ВЫБРАТЬ

	ГОД(Периоды.Период) КАК РасчетныйГод,

	НАЧАЛОПЕРИОДА(Периоды.Период, ГОД) КАК БазовыйПериодНачало,

	СУММА(ВЫБОР

			КОГДА &УчитыватьВесьЗаработок

				ТОГДА ЕСТЬNULL(ДоходыПоМесяцам.Заработок, 0)

			КОГДА ДанныеОПравеНаСтрахование.ИмеетПравоНаСтрахование

				ТОГДА ЕСТЬNULL(ДоходыПоМесяцам.Заработок, 0)

			ИНАЧЕ 0

		КОНЕЦ) КАК Заработок,

	СУММА(ВЫБОР

			КОГДА &УчитыватьВесьЗаработок

				ТОГДА ЕСТЬNULL(ПериодыИсключаемыхОтсутствий.ДнейИсключаемыхОтсутствий, 0)

			КОГДА ДанныеОПравеНаСтрахование.ИмеетПравоНаСтрахование

				ТОГДА ЕСТЬNULL(ПериодыИсключаемыхОтсутствий.ДнейИсключаемыхОтсутствий, 0)

			ИНАЧЕ 0

		КОНЕЦ) КАК ДнейБолезниУходаЗаДетьми,

	ЗНАЧЕНИЕ(Справочник.Работодатели.ТекущийРаботодатель) КАК Страхователь,

	Периоды.Период КАК Период,

	ЕСТЬNULL(ДанныеОПравеНаСтрахование.ИмеетПравоНаСтрахование, ЛОЖЬ) КАК ИмеетПравоНаСтрахование

ИЗ

	ВТПериоды КАК Периоды

		ЛЕВОЕ СОЕДИНЕНИЕ ВТДоходыПоМесяцам КАК ДоходыПоМесяцам

		ПО Периоды.Период = ДоходыПоМесяцам.Период

		ЛЕВОЕ СОЕДИНЕНИЕ ВТДанныеОПравеНаСтрахование КАК ДанныеОПравеНаСтрахование

		ПО Периоды.Период = ДанныеОПравеНаСтрахование.Месяц

		ЛЕВОЕ СОЕДИНЕНИЕ ВТПериодыИсключаемыхОтсутствий КАК ПериодыИсключаемыхОтсутствий

		ПО Периоды.Период = ПериодыИсключаемыхОтсутствий.ПериодДействия



СГРУППИРОВАТЬ ПО

	НАЧАЛОПЕРИОДА(Периоды.Период, ГОД),

	ГОД(Периоды.Период),

	Периоды.Период,

	ЕСТЬNULL(ДанныеОПравеНаСтрахование.ИмеетПравоНаСтрахование, ЛОЖЬ)





УПОРЯДОЧИТЬ ПО

Период