Управление курсором мыши

 // Активизирует один из реквизитов при открытии документа.

//

// Параметры:

//  ДокументОбъект     - объект документа, 

//  ФормаДокумента     - форма документа.

//

Процедура АктивизироватьРеквизитВФорме(ДокументОбъект, ФормаДокумента) Экспорт



	// Структура - порядок актиизации реквизитов.

	// Активизируется первый не заполненный.

	СтруктураРеквизитов = Новый Структура();



	СтруктураРеквизитов.Вставить("Дата");



	// Если поле ввода "Номер" доступен для редактирования

	ЭлементУправления = ФормаДокумента.ЭлементыФормы.Найти("Номер");

	Если ЭлементУправления <> Неопределено И Не ЭлементУправления.ТолькоПросмотр Тогда

		СтруктураРеквизитов.Вставить("Номер");

	КонецЕсли;



	СтруктураРеквизитов.Вставить("Организация");

	СтруктураРеквизитов.Вставить("Склад");

	СтруктураРеквизитов.Вставить("СкладОрдер");

	СтруктураРеквизитов.Вставить("Касса");

	СтруктураРеквизитов.Вставить("СчетОрганизации");

	СтруктураРеквизитов.Вставить("Контрагент");

	СтруктураРеквизитов.Вставить("Получатель");

	СтруктураРеквизитов.Вставить("Плательщик");

	СтруктураРеквизитов.Вставить("ФизЛицо");

	СтруктураРеквизитов.Вставить("Сделка");



	Для каждого Элемент Из СтруктураРеквизитов Цикл



		// Определим, есть ли ЭУ с таким именем.

		ЭлементУправления = ФормаДокумента.ЭлементыФормы.Найти(Элемент.Ключ);

		Если ЭлементУправления <> Неопределено Тогда // есть такой

			Если НЕ ЗначениеЗаполнено(ЭлементУправления.Значение)

			   И ЭлементУправления.Доступность

			   И ЭлементУправления.Видимость

			   И Не ЭлементУправления.ТолькоПросмотр Тогда 



				// Нашли не заполненный ЭУ. Делаем его текущим и прекращаем цикл.

				ФормаДокумента.ТекущийЭлемент = ЭлементУправления;

				Прервать;

			КонецЕсли; 

		КонецЕсли;

	КонецЦикла; 



КонецПроцедуры // АктивизироватьРеквизитВФорме()

   

 // Активизирует один из реквизитов при открытии документа.

//

// Параметры:

//  ДокументОбъект     - объект документа, 

//  ФормаДокумента     - форма документа.

//

Функция АктивизироватьРеквизитВФорме(ДокументОбъект, ФормаДокумента, СтруктураРеквизитов = Неопределено) Экспорт

	

	// Структура - порядок актиизации реквизитов.

	// Активизируется первый не заполненный.

	Если ТипЗнч(СтруктураРеквизитов) <> Тип("Структура") Тогда

		СтруктураРеквизитов = Новый Структура;

		

		СтруктураРеквизитов.Вставить("Дата");

		ЭлементУправления = ФормаДокумента.ЭлементыФормы.Найти("Номер");

		Если ЭлементУправления <> Неопределено И Не ЭлементУправления.ТолькоПросмотр Тогда

			СтруктураРеквизитов.Вставить("Номер");

		КонецЕсли;

		СтруктураРеквизитов.Вставить("Организация");

		СтруктураРеквизитов.Вставить("ПериодРегистрации");

		СтруктураРеквизитов.Вставить("Сотрудник");

		СтруктураРеквизитов.Вставить("ФизЛицо");

		СтруктураРеквизитов.Вставить("Исполнитель");

		СтруктураРеквизитов.Вставить("КурсОбучения");

		СтруктураРеквизитов.Вставить("ДатаЗавершенияКурса");

		СтруктураРеквизитов.Вставить("Мероприятие");

	КонецЕсли;

	

	Для Каждого Элемент Из СтруктураРеквизитов Цикл

		// Определим, есть ли ЭУ с таким именем.

		ЭлементУправления = ФормаДокумента.ЭлементыФормы.Найти(Элемент.Ключ);

		Если ЭлементУправления = Неопределено Тогда

			Продолжить;

		КонецЕсли;

		Если НЕ ЗначениеЗаполнено(ЭлементУправления.Значение) Тогда

			// Нашли не заполненный ЭУ. Делаем его текущим и прекращаем цикл.

			ФормаДокумента.ТекущийЭлемент = ЭлементУправления;

			Возврат Истина;

		КонецЕсли;

	КонецЦикла;

	

	Возврат Ложь;

	

КонецФункции // АктивизироватьРеквизитВФорме()