v8: V8 Управляемые формы. произвольное ДеревоЗначений на форме обработки

01.11.2011 09:48

Прочитано: 4334

Здравствуйте!
Прошу помощи в решении данного вопроса.
Задача: необходимо вывести на форме обработке деревозначений, где в строках номенклатура , а в колонках склады, значение в колонках число.Склады и номенклатуру необходимо заполнить выбором или запросом.
P.S. в обычном приложении заполнял таблицуЗначений и выводил, в управляемом не получается.
Пользователи вдохновлены документом УТ "Установка Цен Номенклатуры" и захотели аналог в обработку, где сначала можно было выбрать склады а затем создалось ДеревоЗначений на форме.

Изменено 01.11.11 09:01:38

Yandex

Возможно, вас также заинтересует

E_Migachev

01.11.2011 11:51

Ответ № 1

(0) snfr1c, ДеревоЗначений доступно только на сервере, в толстом клиенте и внешнем соединение. В данных самой управляемой формы для моделирования дерева используется тип ДанныеФормыДерево. Для преобразования ДеревоЗначений <-> ДанныеФормыДерево используются методы управляемой формы ЗначениеВРеквизитФормы() и РеквизитФормыВЗначение(). Для непосредственного отображения дерева используется элемент формы типа ТаблицаФормы связанный через реквизит ПутьКДанным с реквизитом формы типа ДанныеФормыДерево. Если Вам не очень понятна вышеописанная связь объектов, не огорчайтесь, ниже рассмотрим практический пример и все встанет на свои места.
Задача: Имеется дерево значений, необходимо отобразить его на управляемой форме.
Создаем новую внешнюю обработку ( Скачивать файлы может только зарегистрированный пользователь!

), добавляем управляемую форму и создаем обработчик ПриСозданииНаСервере(). Никаких реквизитов и элементов “вручную” не добавляем, будем делать это программно.

Код 1C v 8.2 УП

 &НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)



    // Создание и заполнение "обычного" объекта прикладного типа ДеревоЗначений,

    // который будет отображен на управляемой форме

    ДеревоОбъект = Новый ДеревоЗначений;

    ДеревоОбъект.Колонки.Добавить("Узел", Новый ОписаниеТипов("Строка"));

    Для к1 = 1 По 3 Цикл

        СтрокаУ1 = ДеревоОбъект.Строки.Добавить();

        СтрокаУ1.Узел = "Узел"+к1;

        Для к2 = 1 По 3 Цикл

            СтрокаУ2 = СтрокаУ1.Строки.Добавить();

            СтрокаУ2.Узел = СтрокаУ1.Узел+к2;

            Для к3 = 1 По 3 Цикл

                СтрокаУ3 = СтрокаУ2.Строки.Добавить();

                СтрокаУ3.Узел = СтрокаУ2.Узел+к3;

            КонецЦикла;

        КонецЦикла;

    КонецЦикла;



    // Создание Реквизита формы типа ДанныеФормыДерево

    МассивДобавляемыхРеквизитов = Новый Массив;

    МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("Дерево",

        Новый ОписаниеТипов("ДеревоЗначений")));

    Для Каждого Колонка Из ДеревоОбъект.Колонки Цикл

        МассивДобавляемыхРеквизитов.Добавить(

           Новый РеквизитФормы(Колонка.Имя, Колонка.ТипЗначения, "Дерево"));

    КонецЦикла;

    ИзменитьРеквизиты(МассивДобавляемыхРеквизитов);



    // Преобразование объекта прикладного типа ДеревоЗначений

    // в реквизит управляемой формы (данные формы)

    ЗначениеВРеквизитФормы(ДеревоОбъект, "Дерево");



    // Создание элемента формы типа ТаблицаФормы для отображения дерева

    ЭлементДерево = Элементы.Добавить("Дерево", Тип("ТаблицаФормы"));

    ЭлементДерево.ПутьКДанным = "Дерево";

    ЭлементДерево.Отображение = ОтображениеТаблицы.Дерево;



    Для Каждого Колонка Из ДеревоОбъект.Колонки Цикл

        НовыйЭлемент = Элементы.Добавить(Колонка.Имя, Тип("ПолеФормы"),

            ЭлементДерево);

        НовыйЭлемент.Вид = ВидПоляФормы.ПолеВвода;

        НовыйЭлемент.ПутьКДанным = "Дерево." + Колонка.Имя;

    КонецЦикла;



КонецПроцедуры

snfr1c

02.11.2011 08:54

Ответ № 2

спасибо

snfr1c

02.11.2011 08:55

Ответ № 3

Вопрос закрыт!

Подсказка: Для быстрого поиска ответов - используйте 'Поиск'