Процедура ВыполнитьОбработку() Экспорт



    Попытка



        //Объект = ПолучитьCOMОбъект(ПутьКФайлу);

        Объект = ПолучитьCOMОбъект("C:\Users\NKrylov\Desktop\Тест.docx");

        // Покажем документ.

        Объект.Application.Visible = 1;

        Word = Объект.Application;



        ThisDocument = Word.Documents(1);

        ThisDocument.Activate();



        // Отключим проверку грамматики и вывод информации о грамматических ошибках.

        ThisDocument.GrammarChecked=0;

        ThisDocument.ShowGrammaticalErrors=0;



        // Готовим переменную в которой будет содержимое документа (текст).

        S_election = Word.S_election;



        // Очистим документ

        // Ctrl-A

        S_election.WholeStory();

        // Del

        S_election.Delete(1, 1);



        // Уменьшим междустрочный интервал.

        S_election.ParagraphFormat.LineSpacingRule = 0; // 1 по умолчанию

        S_election.ParagraphFormat.SpaceAfter = 0;      // 10 по умолчанию



        // Разметим документ. Это можно сделать и предварительно в макете

        ThisDocument.Bookmarks.Add("Закладка1", S_election.Range());

        S_election.TypeParagraph();

        S_election.TypeText("34r3 ");

        S_election.HomeKey(, 1);

        ThisDocument.Bookmarks.Add("Закладка2", S_election.Range());

        S_election.EndKey();

        S_election.TypeParagraph();

        ThisDocument.Bookmarks.Add("Закладка3", S_election.Range());

        S_election.TypeParagraph();

        ThisDocument.Bookmarks.Add("Закладка4", S_election.Range());

        S_election.EndKey();



        // Так можно работать с текстом только в конкреной области документа - это и будет замена метода Find-Execute.

        ThisDocument.Bookmarks("Закладка3").Range.S_elect();

        S_election = Word.S_election;



        Bookmark = ThisDocument.Bookmarks("Закладка3");

        Table = ThisDocument.Tables.Add(Bookmark.Range(),1,5,1,2);

        Table.Rows(1).Cells(1).Range.Text = 1;

        Table.Rows(1).Cells(2).Range.Text = 2;

        Table.Rows(1).Cells(3).Range.Text = 3;

        Table.Rows(1).Cells(4).Range.Text = 4;

        Table.Rows(1).Cells(5).Range.Text = 5;



        // После вывода таблицы, появится "лишняя строка", удалим ее

        // в результате курсор встанет в область закладки 4

        S_election.MoveDown(, 1);

        S_election.Delete(1, 1);



        // Этот текст будет выведен не с последней позиции курсора, а в активной области.

        // в данном случае - в области закладки 2

        ThisDocument.Bookmarks("Закладка2").Range.S_elect();

        S_election = Word.S_election;

        Text = S_election.Range.Text;

        S_election.TypeText(Text + " sdcsdcs");

        // При выводе текста закладка "сбросилась". Восстановим.

        // "Победить" эту проблему я так и не смог((

        // Хотя на практике, закладка больше и не понадобится.

        // Дважды выводить текст в одну и ту же область - не имеет смысла.

        S_election.HomeKey(, 1);

        ThisDocument.Bookmarks.Add("Закладка2", S_election.Range());

        S_election.EndKey();



        // В области закладки 4 сформируем нумерованный список

        ThisDocument.Bookmarks("Закладка4").Range.S_elect();

        S_election = Word.S_election; // активная (выделенная) область будет начинаться

        // от закладки 4)



        // Добавим текст "для опытов"

        // 1

        S_election.TypeText("sdcsdcsdcsdc");

        S_election.TypeParagraph();

        // 2

        S_election.TypeText("sdcsdcsdcsdc");

        S_election.TypeParagraph();

        // 3

        S_election.TypeText("sdcsdcsdcsdc");

        S_election.TypeParagraph();

        // 4

        S_election.TypeText("sdcsdcsdcsdc");

        S_election.TypeParagraph();

        // Выделяем введенный текст

        S_election.MoveUp(,4,1);



        // Настроим шаблон объекта галереи списков

        // Галереи списков бывают несккольких типов, 2 - нумерованные списки

        ListTemplate = Word.ListGalleries(2).ListTemplates(1).ListLevels(1);

        // Формат нумератора списка - точка после символа нумерации

        ListTemplate.NumberFormat = "%1.";

        // стиль нумератора - арабские цифры

        ListTemplate.NumberStyle = 0; // wdListNumberStyleArabic

        // 4 - маленькие латинские буквы.

        // 2 - маленькие римские цифры.

        // 58- меленькие русские буквы.

        // Font = Template.Font; // можно указать форматирование текста списка



        // Применим шаблон к выделенному тексту

 S_election.Range.ListFormat.ApplyListTemplateWithLevel( Word.ListGalleries(2).ListTemplates(1));



        // Перейдем в конец текста

        S_election.EndKey(6);



        // Добавим картинку

        // Параметры: путь к файлу, создавать ссылку на картинку, сохранять с файлом

        Picture = S_election.InlineShapes.AddPicture("C:\Users\NKrylov\Desktop\Новый.bmp", Ложь, Истина);

        // Зададим размер

        Picture.Height = 100;

        Picture.Width  = 150;



        // Чтобы установить обтекание текста, конвертируем рисунок в фигуру

        Shape = Picture.ConvertToShape();

        Shape.WrapFormat.Type = 0; // по контуру...



        ThisDocument.Save();

        //Объект.Application.Quit();

        Объект = Неопределено;

    Исключение

        ThisDocument.Save();

        Сообщить(ОписаниеОшибки());

        //Объект.Application.Quit();

        Объект = Неопределено;

    КонецПопытки;



КонецПроцедуры   

 Процедура ВыполнитьОбработку() Экспорт



    Попытка

        Объект = ПолучитьCOMОбъект(ПутьКФайлу);

        // Покажем документ. Для красоты.

        Объект.Application.Visible = 1;

        Word = Объект.Application;



        Doc = Объект.Application.Documents(1);

        Doc.Activate();



        // Готовим переменную в которой будет содержимое нашего документа

        // (текст, таблицы и проч).

        Text = Word.S_election;



        // Очистим документ

        // Ctrl-A

        Text.WholeStory();

        // Del

        Text.Delete(1, 1);

        // Двигаемся на 3 строки ниже. Документ пустой, поэтому добавляем

        // строки "Переводами коретки"



        Text.TypeText(Символы.ВК);

        Text.TypeText(Символы.ВК);

        Text.TypeParagraph(); // другой вариант того же действия

        // Выводим текст.

        Text.TypeText("Обычный текст, набранный первую очередь");



        // Курсор в конце строки

        // Эмулируем нажатие Shift+Home - выделяем строку

        Text.HomeKey(, 1);

        // Форматирование выделенной строки

        Text.Font.Bold = 9999998;

        Text.Font.Size = 14;

        Text.Font.Name = "Verdana";



        // Сдвигаем курсор. Сдвинуть курсор по строкам возможно, только,

        // если эти строки уже содержат текст, иначе ничего не произойдет.

        Text.MoveUp(,2);   // вверх на 2 строки

        //Word.S_election.MoveDown(,числострок); // вниз

        //Word.S_election.MoveLeft(,числострок); // влево

        //Word.S_election.MoveRight(,числострок);// вправо



        // Добавление текста. Текст выводится начиная с текщей позиции

        // курсора.

        Text.HomeKey(, 1);

        Text.TypeText("Обычный текст, набранный во вторую очередь");



        Text.MoveDown(,1); // вниз на 2 строки

        Text.EndKey(); // в конец строки

        Text.TypeParagraph(); // и в начало следующей строки



        // Очищаем форматирование

        Text.ClearFormatting();

        // Добавляем таблицу.

        // Получаем текущую позицию курсора

        Position = Text.Range();



        // Параметры: Позиция, число строк, число колонок,

        // последние 2 параметра отвечают за автоподбор высоты и отображение

        // границ таблицы

        Table = Doc.Tables.Add(Position, 1, 6, 1, 2);



        // Устанавливаем ширину колонок

        Table.Columns(1).PreferredWidth=10;

        Table.Columns(2).PreferredWidth=50;

        Table.Columns(3).PreferredWidth=10;

        Table.Columns(4).PreferredWidth=10;

        Table.Columns(5).PreferredWidth=10;

        Table.Columns(6).PreferredWidth=10;



        // Задаем заголовки колонок

        Row1=Table.Rows(1);

        Row1.Cells(1).Range.Text="№ п/п";

        Row1.Cells(2).Range.Text="Наименование";

        Row1.Cells(4).Range.Text="Кол-во";

        Row1.Cells(3).Range.Text="Ед. изм.";

        Row1.Cells(5).Range.Text="Цена,руб.";

        Row1.Cells(6).Range.Text="Сумма,руб.";



        // Построчно выводим содержимое таблицы Товары

        НомерСтроки = 1;

        Для каждого СтрокаТовары Из Ссылка.Товары Цикл

            Row=Table.Rows.Add();

            Row.Cells(1).Range.Text=НомерСтроки;

            // Выравнивание по левому краю

            Row.Cells(1).Range.ParagraphFormat.Alignment = 1;

            // В качестве текста можно передать только значение "простого" формата

            // все агрегатные объекты, переданные как текст, что нормально для платформы 1с

            // вызовут исключение.

            Row.Cells(2).Range.Text=СтрокаТовары.Номенклатура.Наименование

                   +?(ЗначениеЗаполнено(СтрокаТовары.ХарактеристикаНоменклатуры),

                   " ("+СтрокаТовары.ХарактеристикаНоменклатуры+")","");

            Row.Cells(4).Range.Text=Строка(СтрокаТовары.Количество);

            Row.Cells(4).Range.ParagraphFormat.Alignment = 1;

            Row.Cells(3).Range.Text=?(ЗначениеЗаполнено(СтрокаТовары.Номенклатура.БазоваяЕдиницаИзмерения)

                                  ,СтрокаТовары.Номенклатура.БазоваяЕдиницаИзмерения.Наименование,"-");

            Row.Cells(3).Range.ParagraphFormat.Alignment = 1;

            Row.Cells(5).Range.Text=Формат(СтрокаТовары.Цена,"ЧДЦ=2");

            Row.Cells(5).Range.ParagraphFormat.Alignment = 1;

            Row.Cells(6).Range.Text=Формат(СтрокаТовары.Сумма,"ЧДЦ=2");

            Row.Cells(6).Range.ParagraphFormat.Alignment = 1;

            НомерСтроки=НомерСтроки+1;

        КонецЦикла;



        // Задаем форматирование первой строки

        // Если сделать это сразу, то все новые строки таблицы будут

        // формироваться с тем же форматом

        Row1.Range.Font.Bold = 9999998;

        Row1.Range.Font.Size = 14;

        Row1.Range.Font.Name = "Verdana";

        Row1.Range.ParagraphFormat.Alignment = 1;



        // Последняя строка...

        Row = Table.Rows.Add();

        Row.Range.Font.Bold = 9999998;

        Row.Cells(1).Range.Text="Итого:";

    Исключение

        Doc.Save();

        Сообщить(ОписаниеОшибки());

        Объект.Application.Quit();

        Объект = Неопределено;

    КонецПопытки;



    Попытка // эта конструкция выдает исключительную ситуацию, но при этом

        // результат все-равно работает))

        // объединяем ячейки в конце таблицы

        Table.cell(НомерСтроки+1, 1).Merge(Table.cell(НомерСтроки+1, 5));

    Исключение

    КонецПопытки;



    Попытка

        Row.Cells(1).Range.ParagraphFormat.Alignment = 3;

        Row.Cells(2).Range.Text=Формат(Ссылка.Товары.Итог("Сумма"), "ЧДЦ=2");

        Row.Cells(2).Range.ParagraphFormat.Alignment = 1;



        Doc.Save();

        Объект.Application.Quit();

        Объект = Неопределено;

    Исключение

        Doc.Save();

        Сообщить(ОписаниеОшибки());

        Объект.Application.Quit();

        Объект = Неопределено;

    КонецПопытки;



КонецПроцедуры   

 Попытка

    Excel = Новый COMОбъект("Excel.Application");

Исключение

    Сообщить("ВНИМАНИЕ! TOpenOffice не установлен или недостаточно прав доступа!

    | - " + ОписаниеОшибки(), СтатусСообщения.ОченьВажное);

    Возврат;

КонецПопытки;



ТабДокумент = ПечатьЦенника(ВидЦенника);

ИмяФайла = ПутьДляСохранения+"\"+ТабДокумент.ИспользуемоеИмяФайла+".xls";

ТабДокумент.Записать(ИмяФайла, ТипФайлаТабличногоДокумента.XLS97);

   

МакетОформления = Неопределено;

// Откроем табличный документ



Excel.Workbooks.Open(ИмяФайла);

КнигаExcel = Excel.Workbooks.Item(Excel.Workbooks.Count);



ЛистExcel = КнигаExcel.WorkSheets.Item(1);



КнигаExcel.Activate();

ЛистExcel.Activate();



//Установка полей

//Значение - points. Придется делать пересчет (100 points = 3.8 inches)

ЛистExcel.PageSetup.LeftMargin   = 28;

ЛистExcel.PageSetup.RightMargin  = 28;

ЛистExcel.PageSetup.TopMargin    = 25;

ЛистExcel.PageSetup.BottomMargin = 25;



//Установка ориентации

Если ТабДокумент.ОриентацияСтраницы = ОриентацияСтраницы.Ландшафт Тогда

    ЛистExcel.PageSetup.Orientation = 2;

Иначе

    ЛистExcel.PageSetup.Orientation = 1;

КонецЕсли;

   

//Установка масштаба печати

ЛистExcel.PageSetup.Zoom = ТабДокумент.МасштабПечати;



//Сохранение в Мои документы

КнигаExcel.Save();

   

//Покажем книгу на экран

Excel.Visible = 1;

   

//Отключаем COM - соединение

Excel.Quit();    

 Попытка

   СервисМанагер = Новый  COMОбъект("Com.Sun.Star.ServiceManager");

Исключение

   Сообщить("Не могу создать объект Open Office!

   | - " + ОписаниеОшибки(), СтатусСообщения.ОченьВажное);   

   Возврат;

КонецПопытки;

   

ТабДокумент = ПечатьЦенника(ВидЦенника);



ИмяФайла = ПутьДляСохранения+"\"+ТабДокумент.ИспользуемоеИмяФайла+".xls";

ТабДокумент.Записать(ИмяФайла, ТипФайлаТабличногоДокумента.XLS97);

      

МакетОформления = Неопределено;

// Откроем табличный документ

Скрипт = новый COMОбъект("MSScriptControl.ScriptControl");

   Скрипт.language = "javascript";

   Скрипт.eval("Massiv=new Array()");             

   Массив = Скрипт.eval("Massiv");

   Скрипт.AddObject("СервисМанагер",СервисМанагер);

   Скрипт.eval("Massiv[0]=СервисМанагер.Bridge_GetStruct('com.sun.star.beans.PropertyValue')");

   Скрипт.eval("Massiv[0].Name='Hidden'");

   Скрипт.eval("Massiv[0].Value=true");

Стол = СервисМанагер.createInstance("com.sun.star.frame.Desktop");

ВремПуть = СтрЗаменить(ПутьДляСохранения, "\", "/");

ВремПуть = СтрЗаменить(ВремПуть, " ", "%20");

УРЛ = "file:///"+ВремПуть+"/"+ТабДокумент.ИспользуемоеИмяФайла+".xls";



Документ = Стол.LoadComponentFromURL(УРЛ,"_blank",0,Массив);

Документ.lockControllers();

Документ.addActionLock();



Листы=Документ.getSheets();

ЛистДанные=Листы.getByIndex(0);



СтилиСтраницы=Документ.StyleFamilies.getByName("PageStyles");

ПараметрыСтраницы=СтилиСтраницы.getByName(ЛистДанные.PageStyle);



//Установка полей

ПараметрыСтраницы.LeftMargin   = ТабДокумент.ПолеСлева  * 100;

ПараметрыСтраницы.RightMargin  = ТабДокумент.ПолеСправа * 100;

ПараметрыСтраницы.TopMargin    = ТабДокумент.ПолеСверху * 100;

ПараметрыСтраницы.BottomMargin = ТабДокумент.ПолеСнизу  * 100;



//Установка ориентации

Если ТабДокумент.ОриентацияСтраницы = ОриентацияСтраницы.Ландшафт Тогда

   ПараметрыСтраницы.IsLandscape = Истина;

   ПараметрыСтраницы.Width  = 29700;

   ПараметрыСтраницы.Height = 21000;

Иначе

   ПараметрыСтраницы.IsLandscape = Ложь;

   ПараметрыСтраницы.Width  = 21000;

   ПараметрыСтраницы.Height = 29700;

КонецЕсли;



//Установка масштаба печати

ПараметрыСтраницы.PageScale = ТабДокумент.МасштабПечати;



//Сохранение документа

Документ.unlockControllers();

Документ.removeActionLock();

Документ.store();

Документ.Close(Истина);



//Отключаем COM - соединение

Стол.terminate();

   

 // Пример от  Jaap Vduul 

// Пример чтения таблицы из OpenOffice:

// =====================================    

    ServiceManager     = СоздатьОбъект("com.sun.star.ServiceManager");

    Desktop             = ServiceManager.createInstance("com.sun.star.frame.Desktop");

    script             = СоздатьОбъект("ScriptControl");

    script.Language     = "vbs";

    script.AddCode

    (

        "Dim Parameters()

        |   

        |Sub InitParameters(Size)

        |     

        |    Erase Parameters

        |

        |    If Size > 0 Then 

        |        Redim Parameters(Size - 1) 

        |    End If

        |

        |End Sub

        |    

        |Sub SetParameter(ServiceManager, Name, Value, Index)

        |

        |    Set PropertyValue     = ServiceManager.Bridge_GetStruct(""com.sun.star.beans.PropertyValue"")

        |    PropertyValue.Name     = Name

        |    PropertyValue.Value     = Value

        |    

        |    Set Parameters(Index) = PropertyValue

        |

        |End Sub

        |    

        |Sub SetBooleanParameter(ServiceManager, Name, Value, Index)

        |    

        |    SetParameter ServiceManager, Name, Cbool(Value), Index

        |

        |End Sub

        |

        |Function LoadDocument(ComponentLoader, URL, TargetFrameName, SearchFlags)

        |   

        |    Set LoadDocument = ComponentLoader.loadComponentFromURL(URL, TargetFrameName, SearchFlags, Parameters)

        |

        |End Function

        |

        |Sub CloseDocument(Document)

        |

        |    Document.Close True

        |

        |End Sub"

    );

       

    script.Run("InitParameters", 2);

    script.Run("SetBooleanParameter", ServiceManager, "ReadOnly",     1, 0);

    script.Run("SetBooleanParameter", ServiceManager, "Hidden",         1, 1);



    URL = ПреобразоватьВURL(КаталогПриказов + НомерПриказа + ".rtf");

    Документ = script.Run("LoadDocument", Desktop, URL, "_blank", 0);

    Таблица = Документ.TextTables.getByIndex(0); // ссылка на первую таблицу



    ВсегоСтрок         = Таблица.getRows().getCount();

    ВсегоСтолбцов     = Таблица.getColumns().getCount();

     

    Для ИндексСтроки = 1 По (ВсегоСтрок - 1) Цикл // ИндексСтроки = 1, т.к. пропускаем заголовок

        Для ИндексСтолбца = 0 По (ВсегоСтолбцов - 1) Цикл

            Ячейка = Таблица.getCellByPosition(ИндексСтолбца, ИндексСтроки);

            ТекстЯчейки = Ячейка.getString();

        КонецЦикла;

    КонецЦикла;



    script.Run("CloseDocument", Документ);

  Перем СсылкаНаДокумент;



Процедура СформироватбФайл_MS_Word_И_OpenOffice(Кнопка)

	

	ДокументСсылка = СсылкаНаДокумент;

	ИмяФайла = ПолучитьИмяВременногоФайла();



	// Теперь формируем файл из MS Wordа

	Попытка

		

		MSWord = новый COMОбъект("Word.Application");

		//Передаем текущие параметры форм в MSWord

		MSWord.Documents.Open(ИмяФайла);	

		MSWordDoc = MSWord.ActiveDocument();

		

		WordContent =  MSWord.ActiveDocument().ActiveWindow.S_election;

		

		//------------------------------------------------------------

		// Перебираем таблицы в документе, и сопоставляем имена переменных

		// с именами табличных частей.

		Для ТекущаяТаблица = 1 ПО MSWordDoc.Tables.Count Цикл 

			мТабличнаяЧасть = Неопределено;

			Для ТекущаяСтрока  = 1 ПО MSWordDoc.Tables(ТекущаяТаблица).Rows.Count Цикл 

				Для ТекущаяКолонка = 1 ПО MSWordDoc.Tables(ТекущаяТаблица).Columns.Count Цикл 

					

					мТабличнаяЧасть = ИмяТабличнойЧастиВСтроке(

					ПолучитьСтартПеременной( MSWordDoc.Tables(ТекущаяТаблица).Cell(ТекущаяСтрока,ТекущаяКолонка).Range.Text	) 

					,ДокументСсылка);

					

					Если  мТабличнаяЧасть <> Неопределено Тогда

						Прервать;;	

					КонецЕсли;	

					

				КонецЦикла;

				Если  мТабличнаяЧасть <> Неопределено Тогда

					Прервать;;	

				КонецЕсли;	

			КонецЦикла;

			

			//Итак мы имеем номер текущей таблицы  и имя табличной части

			Если  мТабличнаяЧасть <> Неопределено Тогда

				//Производим редактирование нашей таблицы в соответствии с количеством строк

				ВсегоСтрокТЧ = 0;

				Для Каждого строкаТЧ Из  ДокументСсылка[мТабличнаяЧасть.Имя] Цикл

					ВсегоСтрокТЧ = ВсегоСтрокТЧ+1;

				КонецЦикла;

				//ВсегоСтрокТЧ = ДокументСсылка[мТабличнаяЧасть.Имя].Количество;

				// Добавляем строки

				Для ТекущаяСтрокаТЧ  = 1  По ВсегоСтрокТЧ Цикл

					Если ТекущаяСтрокаТЧ <> ВсегоСтрокТЧ  Тогда

						MSWordDoc.Tables(ТекущаяТаблица).Rows.Add(MSWordDoc.Tables(ТекущаяТаблица).Rows(ТекущаяСтрока+ТекущаяСтрокаТЧ-1));

					КонецЕсли;	

					//MSWordDoc.Tables(ТекущаяТаблица).Cell(ТекущаяСтрока+ТекущаяСтрокаТЧ-1,2).Range.Text = Строка(ТекущаяСтрокаТЧ);

					Для ТекКол = 1 ПО MSWordDoc.Tables(ТекущаяТаблица).Columns.Count Цикл 

						Если ТекущаяСтрокаТЧ <> ВсегоСтрокТЧ  Тогда

							ТекстПеременной = ПолучитьПеременнуюИзСтроки(СокрЛП(MSWordDoc.Tables(ТекущаяТаблица).Cell(ТекущаяСтрока+ТекущаяСтрокаТЧ,ТекКол).Range.Text));

							ТекстПеременной = ?(ПустаяСтрока(ТекстПеременной),"", "["+"_"+Строка(ТекущаяСтрокаТЧ)+"_"+ТекстПеременной+"]");

							MSWordDoc.Tables(ТекущаяТаблица).Cell(ТекущаяСтрока+ТекущаяСтрокаТЧ-1,ТекКол).Range.Text = ТекстПеременной;

						Иначе

							ТекстПеременной = ПолучитьПеременнуюИзСтроки(СокрЛП(MSWordDoc.Tables(ТекущаяТаблица).Cell(ТекущаяСтрока+ТекущаяСтрокаТЧ-1,ТекКол).Range.Text));

							ТекстПеременной = ?(ПустаяСтрока(ТекстПеременной),"", "["+"_"+Строка(ТекущаяСтрокаТЧ)+"_"+ТекстПеременной+"]");

							MSWordDoc.Tables(ТекущаяТаблица).Cell(ТекущаяСтрока+ТекущаяСтрокаТЧ-1,ТекКол).Range.Text = ТекстПеременной;

						КонецЕсли;	

					КонецЦикла;	

				КонецЦикла;	

				//MSWordDoc.Tables(ТекущаяТаблица).Rows.Delete();

				//MSWordDoc.Tables(ТекущаяТаблица).Rows(3).Delete();

			КонецЕсли;	

		КонецЦикла;

		

		//------------------------------------------------------------

		// Вытаскивам из шаблона текст 

		ТекстДокумента = MSWordDoc.Range(0, MSWordDoc.Characters.Count).Text;

		

		// Из текста вытаскиваем Имена переменных залюченных а скобки []

		Список = ПолучитьСписокПеременных(ТекстДокумента);

		//Список.ВыбратьЭлемент();

		

		// Заполняем в структуру ревизитовперечень переменных

		СтруктураРеквизитов=СтруктураРеквизитовДокумента(ДокументСсылка);

		ЗначениеРеквизита="";

		Для Каждого ЭлементСписка Из Список Цикл

			

			// Если находится соответствие переменной из документа и шаблона то производим замену

			Если СтруктураРеквизитов.Свойство(ЭлементСписка.Значение, ЗначениеРеквизита ) Тогда

				//Сообщить("["+ЭлементСписка.Значение+"]"+" : "+ЗначениеРеквизита);

				WordContent.Find.Execute("["+ЭлементСписка.Значение+"]",0,0,0,0,0,-1,,,Строка(ЗначениеРеквизита),2);		

			Иначе

				Сообщить("-> " + ЭлементСписка.Значение+" - Не найден в структуре документа");

				// Заменим переменную на пустую строку

				WordContent.Find.Execute("["+ЭлементСписка.Значение+"]",0,0,0,0,0,-1,,," ",2);		

			КонецЕсли;

			

		КонецЦикла;

		

		//автоматически обновляем поля документа

		MSWord.S_election.WholeStory();

		MSWord.S_election.Fields.Update();

		MSWord.S_election.HomeKey();	

		

		//MSWordDoc.SaveAs(ИмяФайла);

		

		//отображаем MSWord

		MSWord.Visible=1;

		MSWord.Activate();

		

	Исключение

		Предупреждение(ОписаниеОшибки());

		MSWord.Quit();

	КонецПопытки;

	

	

	// Теперь формируем файл из OpenOffice

	

	Попытка

		ServiceManager = Новый COMОбъект("com.sun.star.ServiceManager");

		Reflection = ServiceManager.createInstance("com.sun.star.reflection.CoreReflection");

		Desktop = ServiceManager.createInstance("com.sun.star.frame.Desktop");

		

		Args = Новый COMSafeArray("VT_DISPATCH", 1);

		OOДокумент = Desktop.loadComponentFromURL(ПреобразоватьВURL(ИмяФайла), "_blank", 0, Args);

		

		//------------------------------------------------------------

		// Перебираем таблицы в документе, и сопоставляем имена переменных

		// с именами табличных частей.

		Для ТекущаяТаблица = 0 ПО OOДокумент.getTextTables().Count-1 Цикл 

			мТабличнаяЧасть = Неопределено;

			Для ТекущаяСтрока  = 0 ПО OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).Rows.Count-1 Цикл 

				Для ТекущаяКолонка = 0 ПО OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).Columns.Count-1 Цикл 

					

					мТабличнаяЧасть = ИмяТабличнойЧастиВСтроке(

					ПолучитьСтартПеременной( OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).getCellByPosition(ТекущаяКолонка, ТекущаяСтрока).string	) 

					,ДокументСсылка);

					

					Если  мТабличнаяЧасть <> Неопределено Тогда

						Прервать;;	

					КонецЕсли;	

					

				КонецЦикла;

				Если  мТабличнаяЧасть <> Неопределено Тогда

					Прервать;;	

				КонецЕсли;	

			КонецЦикла;

			

			//Итак мы имеем номер текущей таблицы  и имя табличной части

			Если  мТабличнаяЧасть <> Неопределено Тогда

				//Производим редактирование нашей таблицы в соответствии с количеством строк

				ВсегоСтрокТЧ = 0;

				Для Каждого строкаТЧ Из  ДокументСсылка[мТабличнаяЧасть.Имя] Цикл

					ВсегоСтрокТЧ = ВсегоСтрокТЧ+1;

				КонецЦикла;

				//ВсегоСтрокТЧ = ДокументСсылка[мТабличнаяЧасть.Имя].Количество;

				// Добавляем строки

				Для ТекущаяСтрокаТЧ  = 1  По ВсегоСтрокТЧ Цикл

					Если ТекущаяСтрокаТЧ <> ВсегоСтрокТЧ  Тогда

						// Добавляем строку перед нашей

						OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).Rows.I_nsertByIndex(ТекущаяСтрока+ТекущаяСтрокаТЧ-1, 1);

					КонецЕсли;	

					

					Для ТекКол = 0 ПО OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).Columns.Count-1 Цикл 

						

						Если ТекущаяСтрокаТЧ <> ВсегоСтрокТЧ  Тогда             

							ТекстПеременной = ПолучитьПеременнуюИзСтроки(СокрЛП(OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).getCellByPosition(ТекКол, ТекущаяСтрока+ТекущаяСтрокаТЧ).string));

							ТекстПеременной = ?(ПустаяСтрока(ТекстПеременной),"", "["+"_"+Строка(ТекущаяСтрокаТЧ)+"_"+ТекстПеременной+"]");

							OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).getCellByPosition(ТекКол, ТекущаяСтрока+ТекущаяСтрокаТЧ-1).string = ТекстПеременной;

						Иначе                                                   

							ТекстПеременной = ПолучитьПеременнуюИзСтроки(СокрЛП(OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).getCellByPosition(ТекКол, ТекущаяСтрока+ТекущаяСтрокаТЧ-1).string));

							ТекстПеременной = ?(ПустаяСтрока(ТекстПеременной),"", "["+"_"+Строка(ТекущаяСтрокаТЧ)+"_"+ТекстПеременной+"]");

							

							OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).getCellByPosition(ТекКол, ТекущаяСтрока+ТекущаяСтрокаТЧ-1).string = ТекстПеременной;

						КонецЕсли;	

					КонецЦикла;	

				КонецЦикла;	

			КонецЕсли;	

		КонецЦикла;

		

		//------------------------------------------------------------

		// Вытаскивам из шаблона текст 

		//ТекстДокумента = MSWordDoc.Range(0, MSWordDoc.Characters.Count).Text;

		ТекстДокумента = ООПолучитьТекст(OOДокумент);

		

		// Из текста вытаскиваем Имена переменных залюченных а скобки []

		Список = ПолучитьСписокПеременных(ТекстДокумента);

		//Список.ВыбратьЭлемент();

		

		// Заполняем в структуру ревизитовперечень переменных

		СтруктураРеквизитов=СтруктураРеквизитовДокумента(ДокументСсылка);

		ЗначениеРеквизита="";

		

		OOЗамена = OOДокумент.CreateReplaceDescriptor();

		

		Для Каждого ЭлементСписка Из Список Цикл

			

			// Если находится соответствие переменной из документа и шаблона то производим замену

			Если СтруктураРеквизитов.Свойство(ЭлементСписка.Значение, ЗначениеРеквизита ) Тогда

				OOЗамена.SearchString  = "["+ЭлементСписка.Значение+"]";

				OOЗамена.ReplaceString = Строка(ЗначениеРеквизита);

				OOДокумент.ReplaceAll(OOЗамена);

			Иначе

				Сообщить("-> " + ЭлементСписка.Значение+" - Не найден в структуре документа");

				// Заменим переменную на пустую строку

				OOЗамена.SearchString  = "["+ЭлементСписка.Значение+"]";

				OOЗамена.ReplaceString = " ";

				OOДокумент.ReplaceAll(OOЗамена);

				

			КонецЕсли;

			

		КонецЦикла;

		OOДокумент.getCurrentController().getFrame().getContainerWindow().setFocus();

		

	Исключение

		Предупреждение(ОписаниеОшибки());

	КонецПопытки;			

	

КонецПроцедуры    

   //ДОПОЛНИТЕЛЬНО НЕОБХОДИМЫЕ ФУНКЦИИ

// Добавлем форматы представления полей и дополнительную информацию о полях

Процедура ДобавитьФорматы(ПереченьРеквизитов,Значение,пПредставлениеРеквизита, ДокументСсылка = Неопределено)

	Если ТипЗнч(Значение) = Тип("Дата")  Тогда  // расширяем представление даты

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"ДФddMMyyyy",Формат(Значение,"ДФ=dd.MM.yyyy"));

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"ДЛФDD",Формат(Значение,"ДЛФ=DD"));

	ИначеЕсли ТипЗнч(Значение) = Тип("Число") Тогда  // расширяем представление числа

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"ЧДЦ2ЧГ0",Формат(Значение,"ЧДЦ=2; ЧГ=0"));

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"ЧДЦ2",Формат(Значение,"ЧДЦ=2"));

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"ЧПропись",Значение);

	ИначеЕсли  (ТипЗнч(Значение) = Тип("СправочникСсылка.КонтактныеЛица"))  или  (ТипЗнч(Значение) = Тип("СправочникСсылка.ФизическиеЛица")) Тогда

		// Расширяем выводимые поля для типов физ. лица, контакные лица сокращением инициалов	

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"ФИО",Строка(Значение));

	КонецЕсли

КонецПроцедуры



Процедура ЗаполнитьРеквизиты(мГлубинаРекурсии,ПереченьРеквизитов,РеквизитСсылка,Реквизит,пПредставлениеРеквизита)

	

	мГлубинаРекурсии = мГлубинаРекурсии+1;

	ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"Код",РеквизитСсылка["Код"]);

	ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+"Наименование",РеквизитСсылка["Наименование"]);

	

	Для Каждого ЭлементРеквизита Из Реквизит.Реквизиты  Цикл

		ПереченьРеквизитов.Вставить(пПредставлениеРеквизита+"_"+ЭлементРеквизита.Имя,РеквизитСсылка[ЭлементРеквизита.Имя]);

		Если (Найти(ЭлементРеквизита.Тип,"Справочник ссылка")>0) И (мГлубинаРекурсии <=3) И (Найти(ЭлементРеквизита.Тип,",")=0) Тогда

			///+++

			ЗаполнитьРеквизиты(мГлубинаРекурсии, ПереченьРеквизитов,РеквизитСсылка[ЭлементРеквизита.Имя],РеквизитСсылка[ЭлементРеквизита.Имя].Метаданные(),пПредставлениеРеквизита+"_"+ЭлементРеквизита.Имя);

		Иначе

			ДобавитьФорматы(ПереченьРеквизитов,РеквизитСсылка[ЭлементРеквизита.Имя],пПредставлениеРеквизита+"_"+ЭлементРеквизита.Имя);

		КонецЕсли

	КонецЦикла;	

	

КонецПроцедуры



Функция ПолучитьСписокПеременных(ТекстШаблона)

	СписокПеременных = Новый СписокЗначений();

	ЕщеЕсть = Истина;

	Пока ЕщеЕсть Цикл

		ПервыйСимвол = Найти(ТекстШаблона,"[");

		Если ПервыйСимвол > 0 Тогда

			ВторойСимвол = Найти(ТекстШаблона,"]");

			Если (ВторойСимвол > 0 И ВторойСимвол > ПервыйСимвол) Тогда

				СписокПеременных.Добавить(Сред(ТекстШаблона,ПервыйСимвол + 1,ВторойСимвол - ПервыйСимвол - 1));

				ТекстШаблона = Сред(ТекстШаблона,ВторойСимвол + 1);

			Иначе

				ЕщеЕсть = Ложь;

			КонецЕсли;

		Иначе

			ЕщеЕсть = Ложь;

		КонецЕсли;

	КонецЦикла;

	Возврат СписокПеременных;

КонецФункции



Функция СтруктураРеквизитовДокумента(ДокументСсылка)  Экспорт

	ПереченьРеквизитов = Новый Структура;

	ПереченьРеквизитов.Вставить("Дата",ДокументСсылка["Дата"]);

	ДобавитьФорматы(ПереченьРеквизитов,ДокументСсылка["Дата"],"Дата");

	ПереченьРеквизитов.Вставить("Номер",ДокументСсылка["Номер"]);

	Реквизиты = ДокументСсылка.Метаданные().Реквизиты;

	Для Каждого Реквизит Из Реквизиты  Цикл

		мГлубинаРекурсии = 1;

		ПереченьРеквизитов.Вставить(Реквизит.Имя,ДокументСсылка[Реквизит.Имя]);

			ДобавитьФорматы(ПереченьРеквизитов,ДокументСсылка[Реквизит.Имя],Реквизит.Имя,ДокументСсылка);

		Если Найти(Реквизит.Тип,"Справочник ссылка")>0 Тогда

			ЗаполнитьРеквизиты(мГлубинаРекурсии,ПереченьРеквизитов,ДокументСсылка[Реквизит.Имя],ДокументСсылка[Реквизит.Имя].Метаданные(),Реквизит.Имя);

		Иначе

			//ДобавитьФорматы(ПереченьРеквизитов,ДокументСсылка[Реквизит.Имя],Реквизит.Имя);

		КонецЕсли;

	КонецЦикла;	

	ТабличныеЧасти = ДокументСсылка.Метаданные().ТабличныеЧасти;

	Для Каждого ТабличнаяЧасть Из ТабличныеЧасти  Цикл

		// Сообщить(ТабличнаяЧасть); // Для таблицы характеристик отрабатываем свой код // с выводом табличной части как набора реквизитов

		Если ТабличнаяЧасть.Имя = "Характеристики" Тогда

			Для Каждого СтрокаТабличнойЧасти Из ДокументСсылка[ТабличнаяЧасть.Имя]  Цикл

				мПредставлениеРеквизита = "Характеристика"+"_"+СтрЗаменить(СтрокаТабличнойЧасти["ВидХарактеристики"], " ", "_");

				мЗначение = СтрокаТабличнойЧасти["ЗначениеХарактеристики"];

				ПереченьРеквизитов.Вставить(мПредставлениеРеквизита,мЗначение);

				ДобавитьФорматы(ПереченьРеквизитов,мЗначение,мПредставлениеРеквизита,ДокументСсылка);

				Если Найти(ТипЗнч(мЗначение),"Справочник ссылка")>0 Тогда

					ЗаполнитьРеквизиты(мГлубинаРекурсии,ПереченьРеквизитов,мЗначение,мЗначение.Метаданные(),мПредставлениеРеквизита);

				КонецЕсли;

				

			КонецЦикла;	

		КонецЕсли;	

		//Перечень реквизитов табличной части

		Реквизиты = ТабличнаяЧасть.Реквизиты;

		Для Каждого Реквизит Из Реквизиты  Цикл

			Для Каждого СтрокаТабличнойЧасти Из ДокументСсылка[ТабличнаяЧасть.Имя]  Цикл

				мГлубинаРекурсии = 1;

				мПредставлениеРеквизита = "_"+СтрокаТабличнойЧасти.НомерСтроки+"_"+ТабличнаяЧасть.Имя+"_НомерСтроки";

				ПереченьРеквизитов.Вставить(мПредставлениеРеквизита,Строка(СтрокаТабличнойЧасти.НомерСтроки));

				мПредставлениеРеквизита = "_"+СтрокаТабличнойЧасти.НомерСтроки+"_"+ТабличнаяЧасть.Имя+"_"+Реквизит.Имя;

				мЗначение = СтрокаТабличнойЧасти[Реквизит.Имя];

				ПереченьРеквизитов.Вставить(мПредставлениеРеквизита,мЗначение);

				ДобавитьФорматы(ПереченьРеквизитов,мЗначение,мПредставлениеРеквизита,ДокументСсылка);

				Если Найти(ТипЗнч(мЗначение),"Справочник ссылка")>0 Тогда

					ЗаполнитьРеквизиты(мГлубинаРекурсии,ПереченьРеквизитов,мЗначение,мЗначение.Метаданные(),мПредставлениеРеквизита);

				Иначе

					//ДобавитьФорматы(ПереченьРеквизитов,мЗначение,мПредставлениеРеквизита);

				КонецЕсли;

			КонецЦикла;	

			//Если реквизит числовой, то подсчитываем итог  

			Если Реквизит.Тип.СодержитТип(Тип("Число"))  Тогда

				мЗначение = ДокументСсылка[ТабличнаяЧасть.Имя].Итог(Реквизит.Имя);

				мПредставлениеРеквизита = "Итог"+"_"+ТабличнаяЧасть.Имя+"_"+Реквизит.Имя;

				ПереченьРеквизитов.Вставить(мПредставлениеРеквизита,мЗначение);

				ДобавитьФорматы(ПереченьРеквизитов,мЗначение,мПредставлениеРеквизита,ДокументСсылка);

			КонецЕсли;

		КонецЦикла;			

	КонецЦикла;	    	

	Возврат ПереченьРеквизитов;

КонецФункции



Функция ИмяТабличнойЧастиВСтроке(Строка,ДокументСсылка)

	ТабличнаяЧасть=Неопределено;

	Если НЕ ПустаяСтрока(Строка) Тогда

		ТабличнаяЧасть = ДокументСсылка.Метаданные().ТабличныеЧасти.Найти(Строка) 

	КонецЕсли;	

	Возврат ТабличнаяЧасть;

	

КонецФункции



//Получает первый кусок переменной до _

Функция ПолучитьСтартПеременной(ПереданнаяСтрока) Экспорт

	СтартПеременной = "";

	ПервыйСимвол = Найти(ПереданнаяСтрока,"[");

	Если  ПервыйСимвол > 0 Тогда

		ВторойСимвол = Найти(ПереданнаяСтрока,"]");

		Если  (ВторойСимвол > 0) И (ВторойСимвол > ПервыйСимвол) Тогда

			Переменная = (Сред(ПереданнаяСтрока,ПервыйСимвол+1,ВторойСимвол-ПервыйСимвол-1));

			ВторойСимвол = Найти(Переменная,"_");

			Если  (ВторойСимвол > 0) И (ВторойСимвол > 1) Тогда

				СтартПеременной = Сред(Переменная,1,ВторойСимвол-1);

			КонецЕсли;	

		КонецЕсли;	

		

	КонецЕсли;	

	

	Возврат СтартПеременной;	

КонецФункции



// Получает переменную заключенную в скобки

Функция ПолучитьПеременнуюИзСтроки(ПереданнаяСтрока) Экспорт

	Переменная = "";

	ПервыйСимвол = Найти(ПереданнаяСтрока,"[");

	Если  ПервыйСимвол > 0 Тогда

		ВторойСимвол = Найти(ПереданнаяСтрока,"]");

		Если  (ВторойСимвол > 0) И (ВторойСимвол > ПервыйСимвол) Тогда

			Переменная = (Сред(ПереданнаяСтрока,ПервыйСимвол+1,ВторойСимвол-ПервыйСимвол-1));

		КонецЕсли;	

		

	КонецЕсли;	

	Возврат Переменная;	

КонецФункции// Идентифицирует табличную часть в строке



// Функция преобразует Windows имя файла в URL OpenOffice

Функция ПреобразоватьВURL(ИмяФайла)

	Возврат "file:///" + СтрЗаменить(ИмяФайла, "\", "/");

КонецФункции



// Функция извлекает текст из документа

Функция ООПолучитьТекст(OOДокумент)

	Текст = "";

	oParEnum = OOДокумент.getText().createEnumeration();

	Пока  oParEnum.hasMoreElements() Цикл

		oPar = oParEnum.nextElement();

		Если  oPar.supportsService("com.sun.star.text.Paragraph") ТОгда

			Текст = Текст + oPar.getString();

		ИначеЕсли oPar.supportsService("com.sun.star.text.TextTable") Then

			//Сообщить(oPar.getString());

		КонецЕсли;

	КонецЦикла;

	Для ТекущаяТаблица = 0 ПО OOДокумент.getTextTables().Count-1 Цикл 

		Для ТекущаяСтрока  = 0 ПО OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).Rows.Count-1 Цикл 

			Для ТекущаяКолонка = 0 ПО OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).Columns.Count-1 Цикл 

				Текст = Текст + OOДокумент.getTextTables().getByIndex(ТекущаяТаблица).getCellByPosition(ТекущаяКолонка, ТекущаяСтрока).string;

			КонецЦикла;

		КонецЦикла;

	КонецЦикла;

	Возврат Текст;

КонецФункции    

 

Почта = Новый Почта;

Почта.Подключиться(,);   

 

Почта.Подключиться("Outlook");   

 Сообщения = Почта.Выбрать(Ложь,Ложь);   

 Для каждого Сообщение Из Сообщения Цикл

//Добавляем строку в табличную часть

СтрокаТП = ТабличноеПоле1.Добавить();



// Перебираем коллекцию получателей сообщения

Для каждого Получатель Из Письмо.Получатели Цикл

Получатели = Получатели + Получатель.Пользователь + " <" + Получатель.Адрес + "> ";

КонецЦикла; 



СтрокаТП.Кому = Получатели;

Попытка

СтрокаТП.ОтКого= Сообщение.Отправитель.Адрес;

Исключение

СтрокаТП.ОтКого= Сообщение.Отправитель;

КонецПопытки;



СтрокаТП.Тема = Сообщение.Тема;

СтрокаТП.Текст = Сообщение.Текст;

СтрокаТП.Дата = Сообщение.ДатаПолучения;



// Перебираем вложения письма

Для каждого Вложение Из Сообщение.Вложения Цикл

Вложение.Данные.Записать(Вложение.Наименование); 

//Запоминаем имена вложение прикрепленных к данному письму, и сохраним в ТабличноеПоле1

Влож=Влож+Вложение.Наименование+",";

КонецЦикла;



СтрокаТП.ПутьВложения=Влож;

КонецЦикла; 



//отключение 

Почта.Отключиться();   

 Сообщение = Новый ПочтовоеСообщение;

Сообщение.Текст = "текст сообщения";

Сообщение.Отправитель = "petya@pupkin.com";

Сообщение.Тема ="Тема сообщения";

Сообщение.Получатели.Добавить("vasya@pupkin.com");

Сообщение.Вложения.Добавить(Новый ДвоичныеДанные("C:\file.jpg"),"file.jpg");



Почта = Новый Почта;



//подключаемся без параметров, к клиенту установленному по умолчанию в системе

Почта.Подключиться(,);



Попытка

//Пытаемся послать письмо

Почта.Послать(Сообщение,Истина);

Исключение

Сообщить(ОписаниеОшибки()); 

Возврат;

КонецПопытки; 



//отключение

Почта.Отключиться();   

 Функция ПолучитьПрофиль()



Профиль = Новый ИнтернетПочтовыйПрофиль;



// SMTP сервер

Профиль.АдресСервераSMTP = "smtp.pupkin.com";



// Порт SMTP сервера

Профиль.ПортSMTP = 25;



// POP3 сервер

Профиль.АдресСервераPOP3 = "pop.pupkin.com";



// Порт POP3 сервера

Профиль.ПортPOP3 = 110;



// Пароль к почтовому ящику

Профиль.Пароль = "pass";



// Пароль пользователя для SMTP сервера

Профиль.ПарольSMTP = "pass";



// Логин пользователя

Профиль.Пользователь = "vasya";



// Логин пользователя для SMTP сервера

Профиль.ПользовательSMTP = "vasya";



// Время ожидания выполнения операции в секундах



Профиль.ВремяОжидания = 50; 

Возврат Профиль;



КонецФункции





Почта = Новый ИнтернетПочта;



Попытка

Почта.Подключиться(ПолучитьПрофиль());

Исключение

Сообщить(ОписаниеОшибки()); 

Возврат;

КонецПопытки;



Заголовки=Почта.ПолучитьЗаголовки()

Если Заголовки.Количество()=0 Тогда

Предупреждение("В почтовом ящике нет входящих сообщений!", ,"Нет сообщений");

КонецЕсли;



// Загрузка сообщений в массив

Сообщения = Почта.Выбрать(Истина,Заголовки);



Для каждого Сообщение Из Сообщения Цикл

СтрокаТП = ТабличноеПолеИнтернетПочта.Добавить();

СтрокаТП.Дата = Сообщение.ДатаОтправления;

СтрокаТП.ОтКого = Сообщение.Отправитель.Пользователь + " <" + Сообщение.Отправитель.Адрес + "> ";

СтрокаТП.Тема = Сообщение.Тема;



// Перебираем получателей сообщения

Для каждого Получатель Из Сообщение.Получатели Цикл

КомуВходящие = КомуВходящие + Получатель.Пользователь + " <" + Получатель.Адрес + "> ";

КонецЦикла; 

СтрокаТП.Кому = КомуВходящие;



// Перебираем тексты сообщения

Для каждого ТекстСообщения Из Сообщение.Тексты Цикл

ТекстВходящие = ТекстВходящие + ТекстСообщения.Текст;

КонецЦикла; 

СтрокаТП.Текст = ТекстВходящие;



// Перебираем вложения письма

Для каждого Вложение Из Сообщение.Вложения Цикл

Вложение.Данные.Записать(Вложение.Name);

СправочникВложения.РеквизитВложение = новый ХранилищеЗначения(Новый ДвоичныеДанные(Вложение.Name));

СправочникВложения.ИмяВложения=Вложение.Name;

КонецЦикла;

КонецЦикла; 



// отключение

Почта.Отключиться();

   

 

Почта = Новый ИнтернетПочта;

Попытка

Почта.Подключиться(ПолучитьПрофиль());

Исключение

Сообщить(ОписаниеОшибки()); 

Возврат;

КонецПопытки;

Сообщение = Новый ИнтернетПочтовоеСообщение;



Сообщение.Вложения.Добавить(Новый ДвоичныеДанные("C:\file.jpg"),"file.jpg");



Сообщение.Отправитель = "vasya@pupkin.com";

Сообщение.ИмяОтправителя = "Вася";

ПочтовыеАдреса = Сообщение.Получатели;

ПочтовыйАдрес = ПочтовыеАдреса.Добавить();

ПочтовыйАдрес.Адрес = "petya@pupkin.com";

Сообщение.Тема ="Тема сообщения"; 



ИнтернетТекстПочтовогоСообщения = Сообщение.Тексты.Добавить();

ИнтернетТекстПочтовогоСообщения.Текст = "Текст сообщения";

ИнтернетТекстПочтовогоСообщения.ТипТекста = ТипТекстаПочтовогоСообщения.ПростойТекст;



Попытка

// Пытаемся послать письмо

Почта.Послать(Сообщение);

Исключение

Сообщить(ОписаниеОшибки()); 

Возврат;

КонецПопытки;

// отключение

Почта.Отключиться();   

  Договор = ПолучитьМакет("Договор");

// Получить объект из макета.

MSWord = Договор.Получить();



Попытка

	Документ = MSWord.Application.Documents(1);

	Документ.Activate();

	//Определим имена

	Заказчик = "Петр Иванович КакВасТам";

	Исполнитель = "helpf.pro - Помощник по 1С"

	

	// Получить объект, который будем использовать для поиска и замены.

	Замена = Документ.Content.Find;



	// Заменить заранее определенные ключевые конструкции на требуемый текст.

	Замена.Execute("[Заказчик]", Ложь, Истина, Ложь, , , Истина, , Ложь, Заказчик);

	Замена.Execute("[Исполнитель]", Ложь, Истина, Ложь, , , Истина, , Ложь, Исполнитель);

	// Далее аналогично для остальных ключевых конструкций.

	//	...

	// Делаем видимым приложение и активизируем его.

	MSWord.Application.Visible = Истина;

	MSWord.Activate();

Исключение

	// Если произойдет ошибка, выводятся данные об ошибке и объект закрывается.

	Сообщить(ОписаниеОшибки());

	MSWord.Application.Quit();

КонецПопытки;    

 

	Word = создатьОбъект("Word.Application");

    wdDoc = Word.Documents;

	wdDoc.Open(ИмяФайлаШаблона,0,1); //открываем только на чтение

	// Делаем видимым приложение

	Word.Visible = 1;   

	wdFindContinue = 1;                                                                                    

	wdReplaceAll = 2;                    

	True = 1;                                        

	False = 0;

	Word.S_election.Find.Execute("[Заказчик]", True, True, False, False, False, True, wdFindContinue,False,"Петр Иванович КакВасТам", wdReplaceAll);

	Word.S_election.Find.Execute("[Исполнитель]", True, True, False, False, False, True, wdFindContinue,False,"helpf.pro - Помощник по 1C", wdReplaceAll);

  // Пробуем подключиться

		Профиль = Новый ИнтернетПочтовыйПрофиль;

		// Получение почты нам не нужно, коментируем

		//	Профиль.АдресСервераPOP3 = POP3Сервер;

		Профиль.АдресСервераSMTP = СокрЛП(Константы.SMTPSERVER.Получить()); // айпишник екченжа

		//Если ВремяОжиданияСервера > 0 Тогда

		//	Профиль.ВремяОжидания = ВремяОжиданияСервера;

		//КонецЕсли; 

		Профиль.Пароль           = СокрЛП(Константы.SMTPSERVERPASSWORD.Получить());

		Профиль.Пользователь     = СокрЛП(Константы.SMTPSERVERLOGIN.Получить());

		//Профиль.ПортPOP3         = ПортPOP3;

		Профиль.ПортSMTP         = СокрЛП(Константы.SMTPSERVERPORT.Получить());

		

		Профиль.ПарольSMTP       = СокрЛП(Константы.SMTPSERVERPASSWORD.Получить());

		Профиль.ПользовательSMTP = СокрЛП(Константы.SMTPSERVERLOGIN.Получить());

		

		//Профиль.ПарольSMTP       = УчетнаяЗапись.Пароль;

		//Профиль.ПользовательSMTP = УчетнаяЗапись.Логин;

		

		ИнтернетПочта = Новый ИнтернетПочта;

		Попытка

			ИнтернетПочта.Подключиться(Профиль);

		Исключение

			Сообщить(ОписаниеОшибки());

		КонецПопытки;

		

		ПочтовоеСообщение = Новый ИнтернетПочтовоеСообщение;

		ПочтовоеСообщение.ИмяОтправителя  = "1C-ka";

		ПочтовоеСообщение.Отправитель     = СокрЛП(Отправитель.Email);

		ПочтовоеСообщение.Тема            = Тема;

		

		ПочтовоеСообщение.Получатели.Добавить(СокрЛП(Получатель.Email));

		ПочтовоеСообщение.Тексты.Добавить(ТекстПисьма, ТипТекстаПочтовогоСообщения.ПростойТекст);

		

		Если Не пустаястрока(файл) Тогда

			Данные = Новый ДвоичныеДанные(файл); 

			ПочтовоеСообщение.Вложения.Добавить(Данные,файлн); 	

		конецесли;	

		попытка

			ИнтернетПочта.Послать(ПочтовоеСообщение);

		исключение

			Сообщить(ОписаниеОшибки());

		конецпопытки;