quit » Поиск » HelpF.pro

Результаты по ключевому слову: quit

Функция проверяет орфографию переданного текста с помощью средств MS Word

Код 1C v 8.х

 // Проверка орфоргафии переданного текста с помощью средств MS Word

// Параметры

//  <Текст> – <Строка> – проверяемый текст

//  <ДеревоЗначений> – <ДеревоЗначений> – возвращает дерево замен

// Возвращаемое значение:

//   <Булево> – Истина, если текст не содержит ошибок

Функция ПроверитьОрфографию(Текст, ДеревоЗначений = Null) Экспорт

    Попытка

		Ворд = Новый COMОбъект("Word.Application"); //Создаем объект MS Word

	Исключение

		Предупреждение("Microsoft Word не установлен!",,"Ошибка!");

		Возврат Ложь;

	КонецПопытки;



	ТекстБезОшибок = Ворд.CheckSpelling(Текст); //проверяем нашу строку на ошибки



	Если ТекстБезОшибок Тогда // Нет ошибок

		Возврат Истина;



	Иначе // Обнаружены ошибки, будем проверять по словам

        Если ДеревоЗначений <> Null Тогда

			Ворд_Активен = Ворд.Visible; //Запомним, был ли Word активен

			

			ВремДок = Ворд.Documents.Add(); //Добавляем к открытым документам

			МояОбласть = ВремДок.Range(0, 0); //Получаем пустую область в начале документа

			МояОбласть.I_nsertBefore(Текст); //Добавляем в эту область нашу строку

			ЧислоСлов = МояОбласть.Words.Count; //Подсчитываем число слов в области



			ДеревоЗначений = Новый ДеревоЗначений; //сюда будем записывать слова и варианты их замен

            МассивТипов = Новый Массив;

			МассивТипов.Добавить(Тип("Строка"));

			ОписаниеТипов = Новый ОписаниеТипов(МассивТипов);

			ДеревоЗначений.Колонки.Добавить("Слово", ОписаниеТипов, "Слово/Замена",);

			

			wdSpellword=0; //константа Word, указывающая на то, что при при вызове проверки орфографии возвращается множество замен

			wdDoNotSaveChanges=0; //константа Word, указывающая на то, что при закрытии не надо сохранять изменения в закрываемом документе

			

			Для НомерСлова = 1 По ЧислоСлов Цикл

	            ОбработкаПрерыванияПользователя();

				ПровОбласть = МояОбласть.Words(НомерСлова); //выбираем очередное слово

				ПровСлово = СокрЛП(ПровОбласть.Text);

				СловоБезОшибок = Ворд.CheckSpelling(ПровСлово); //проверяем наше слово на ошибки

				Если НЕ СловоБезОшибок Тогда //получаем варианты замен (их может и не быть!)

					Если ДеревоЗначений.Строки.Найти(ПровСлово, "Слово") = Неопределено Тогда

						НоваяСтрока = ДеревоЗначений.Строки.Добавить();

						НоваяСтрока.Слово = ПровСлово;

						

						Замены = ПровОбласть.GetSpellingSuggestions( ,1, ,wdSpellword); //проверяем орфографию, укзав, что возвращать надо множество замен

						ЧислоЗамен = Замены.Count; //получаем число возможных замен

						Если ЧислоЗамен > 0 Тогда //заносим варианты замен в таблицу значений

							Для НомерЗамены = 1 По ЧислоЗамен Цикл

								СловоЗамены = СокрЛП(Замены.Item(НомерЗамены).Name);

								НоваяПодСтрока = НоваяСтрока.Строки.Добавить();

								НоваяПодСтрока.Слово = СловоЗамены;

							КонецЦикла;

						КонецЕсли;	

					КонецЕсли; 

				КонецЕсли;	

			КонецЦикла;



			ВремДок.Close(wdDoNotSaveChanges,,);

			Если Не Ворд_Активен Тогда

				Ворд.Quit();

			КонецЕсли;

		КонецЕсли; 



		Возврат Ложь;

	КонецЕсли; 

КонецФункции

Пример использования:

Код 1C v 8.х

 

  Перем ДеревоЗначений;

    Состояние("Идет проверка орфографии. Пожалуйста ждите...");

	Текст = ЭлементыФормы.ПолеТекстовогоДокумента.ПолучитьТекст(); // Получаем текст

    Если ПроверитьОрфографию(Текст, ДеревоЗначений) Тогда  // Проверяем орфографию

		Предупреждение("Текст ошибок не содержит!!!", 5, "OK");

	Иначе

		Если ДеревоЗначений.Строки.Количество() > 0 Тогда

			// Создаем и открываем форму автозамен...

			ФормаВыбора = ЭтотОбъект.ПолучитьФорму("ФормаВыбора");



			Для каждого СтрокаДЗ Из ДеревоЗначений.Строки Цикл

				Строка = ФормаВыбора.ДеревоЗначений.Строки.Добавить();

				Строка.Слово = СтрокаДЗ.Слово;



				Для каждого ПодСтрокаДЗ Из СтрокаДЗ.Строки Цикл

					ПодСтрока = Строка.Строки.Добавить();

					ПодСтрока.Слово = ПодСтрокаДЗ.Слово;

				КонецЦикла; 

			КонецЦикла; 



			Если ФормаВыбора.ОткрытьМодально() = "OK" Тогда

		        // Производим автозамены в тексте

				Для каждого СтрокаДЗ Из ФормаВыбора.ДеревоЗначений.Строки Цикл

					Для каждого ПодСтрокаДЗ Из СтрокаДЗ.Строки Цикл

						Если ПодСтрокаДЗ.Пометка Тогда

							Текст = СтрЗаменить(Текст, ПодСтрокаДЗ.Родитель.Слово, ПодСтрокаДЗ.Слово);

						КонецЕсли; 

					КонецЦикла; 

				КонецЦикла; 

             	ЭлементыФормы.ПолеТекстовогоДокумента.УстановитьТекст(Текст); //Вставим в поле исправленный текст

			КонецЕсли; 

		Иначе

			Предупреждение("В тексте найдены ошибки, но вариантов автозамены не нашлось!!!", 5, "Ошибка");

		КонецЕсли; 

	КонецЕсли;

Категория: Работа с Microsoft Office и OpenOffice

Запуск макроса в MS Word из 1С

Код 1C v 8.х

 //Пример показывает как из 1С вызывается MS Word, вставляется макрос и запускается!

//Макрос пишет на листе Добрый день!, https://helpf.pro и сохраняет файл в D:/primer.doc 



ПримерМакроса = "Sub VBAprimer()

|S_election.TypeText Text:=""Добрый день!""

|Application.Keyboard (1033)

|S_election.TypeText Text:="": https://helpf.pro""

|S_election.TypeParagraph

|S_election.MoveUp Unit:=wdLine, Count:=2

|S_election.EndKey Unit:=wdLine, Extend:=wdExtend

|S_election.Style = ActiveDocument.Styles(""Заголовок 1"")

|S_election.MoveDown Unit:=wdLine, Count:=1

|S_election.HomeKey Unit:=wdLine

|S_election.EndKey Unit:=wdLine, Extend:=wdExtend

|S_election.Style = ActiveDocument.Styles(""Заголовок 2"")

|ActiveDocument.SaveAs FileName:=""D:/primer.doc"", FileFormat:= _

|    wdFormatDocument, LockComments:=False, Password:="""", AddToRecentFiles:= _

|    True, WritePassword:="""", ReadOnlyRecommended:=False, EmbedTrueTypeFonts:= _

|    False, SaveNativePictureFormat:=False, SaveFormsData:=False, _

|    SaveAsAOCELetter:=False

|End Sub";



// Создание объекта

Word = Новый COMОбъект("Word.Application");

Word.Documents.Add();

//VBComponents = Word.VBE.ActiveVBProject.VBComponents;

VBComponents = Word.ActiveDocument.VBProject.VBComponents;

Count = VBComponents.Count();

VBComponents.Add(1);

VBComponents.Item(Count + 1).CodeModule.I_nsertLines(1, ПримерМакроса);

Word.Application.Run(VBAprimer");

Word.Quit();

Word = Неопределено;

Код 1C v 7.x

  // Если не будет работать - возможно установлен высокий уровень безопасности. Понизьте до среднего ...

Процедура Сформировать()

     Попытка     

          W=СоздатьОбъект("Word.Application"); 

     Исключение

          Возврат;

     КонецПопытки;

     W.Documents.Add();

     i = W.VBE.ActiveVBProject.VBComponents.Count();

     W.VBE.ActiveVBProject.VBComponents.Add (1);

     W.VBE.ActiveVBProject.VBComponents.Item(i + 1).CodeModule.I_nsertLines (1, "Sub Golif()");

     W.VBE.ActiveVBProject.VBComponents.Item(i + 1).CodeModule.I_nsertLines (2, "MsgBox " + """" + "Работает" + """");

     W.VBE.ActiveVBProject.VBComponents.Item(i + 1).CodeModule.I_nsertLines (3, "End Sub");

     W.Application.Run ("Golif");

     W="";

КонецПроцедуры

Категория: Работа с Microsoft Office и OpenOffice

Загрузка списка номенклатуры в ТЗ из Excel

Код 1C v 8.х

   

  Попытка

	  XLSОбъектОсновной = Новый COMОбъект("Excel.Application");

  Исключение

	  Предупреждение("Невозможно загрузить MS EXCEL !!!" + Символы.ПС + ОписаниеОшибки(), 10, "Ошибка");

	  Возврат;

  КонецПопытки;

										  

  XLSОбъектКниги = XLSОбъектОсновной.WorkBooks;

										  

  Попытка

	  XLSОбъект = XLSОбъектКниги.Open(элементыформы.пвИмяФайла.Значение);

  Исключение

	  Предупреждение("Невозможно открыть файл " + элементыформы.пвИмяФайла.Значение + " !!!" + Символы.ПС + ОписаниеОшибки(), 10, "Ошибка");

	  Возврат;

  КонецПопытки;

										  

  XLSОбъект.Application.Caption = "Открыто из 1С";

  //определим диапозоны

  Если НомерСтрокиСДанными = 0 Тогда

	  // То с первой строки

	  НомерСтрокиСДанными = 1;

  КонецЕсли; 

										  

  Если НомерСтраницы = 0 Тогда

	  // То с первой страницы

	  НомерСтраницы = 1;

  КонецЕсли; 

										  

  Лист = XLSОбъект.Sheets(НомерСтраницы);

  

  Если КолВоКолонок = 0 Тогда

  	//КолВоКолонок не установлено, будем автоматически заполнять

  	КолВоКолонок = Лист.Cells(1,1).SpecialCells(11).Column;

  КонецЕсли;

										  

  Если КолВоСтрок = 0 Тогда

	  // КолВоСтрок не уставновлено, Будем автоматически заполнять количество строк.

	  КолВоСтрок = Лист.Cells(1,1).SpecialCells(11).Row;

  КонецЕсли;

  // ТЗДанных - Таблица значений на форме

  ТЗДанных.Очистить();

  Лист = XLSОбъект.Sheets(НомерСтраницы);

  Для чС = (НомерСтрокиСДанными + 1) По КолВоСтрок Цикл

	  Состояние("Загружаем строки:" + чС);

	  ностр=ТЗДанных.Добавить();

	  попытка

		  //грузим  номенклатуру

		  Ячейка = Лист.Cells(чС,1);

		  ностр.НоменклатураЕксел = Ячейка.Value;

	  исключение

		  сообщить("Номенклатура - строка - "+чс + Символы.ПС + ОписаниеОшибки());

	  конецпопытки;

	  попытка

		  //грузим  количество

		  Ячейка = Лист.Cells(чС, 2);

		  ностр.Количество = Ячейка.Value;

	  исключение

		  сообщить("Количество - строка - "+чс + Символы.ПС + ОписаниеОшибки());

	  конецпопытки;

	  попытка

		  //грузим  сумму

		  Ячейка = Лист.Cells(чС, 3);

		  ностр.Сумма = Ячейка.Value;

	  исключение

		  сообщить("Сумма - строка - "+чс + Символы.ПС + ОписаниеОшибки());

	  конецпопытки;

	  попытка

		  //грузим  единица измерения

		  Ячейка = Лист.Cells(чС, 4);

		  ностр.ЕдИзмеренияЕксел = Ячейка.Value;

	  исключение

		  сообщить("Ед. измерения - строка - "+чс + Символы.ПС + ОписаниеОшибки());

	  конецпопытки;

	  //КонецЦикла;

  КонецЦикла;



  XLSОбъект.Application.Quit();

Категория: Работа с Microsoft Office и OpenOffice

Подключение к EXCEL и чтение данных из листа Excel

Код 1C v 8.х

 Ex = Новый COMObject("Excel.Application");

   Ex.Workbooks.Open(Путь);

   Ex.Visible = 1;    

   ТекЛист=Ex.WorkSheets(1);        

   Для Ячейка = 1 по 400 цикл

       Если НЕ  ТекЛист.Cells(Ячейка,1).Value  = Неопределено тогда

           Сообщить(Строка(ТекЛист.Cells(Ячейка,1).Value));    

           Карта = Справочники.Номенклатура.НайтиПоКоду(ИзЧислаВСтроку(ТекЛист.Cells(Ячейка,1).Value));    

           Если Карта.Пустая() тогда        

               Сообщить(" Пустой элемент "  + ТекЛист.Cells(Ячейка,1));

           иначе

               Объект = Карта.ПолучитьОбъект();

               Объект.ОсновнойПоставщик = ОсновнойКлиент;

               Объект.Записать();

               конецесли;    

       конецесли;

   конеццикла;

Примеры процедур для чтения данных из EXCEL

Код 1C v 8.х

 

// Функция получает данные из файла Excel

//

// Параметры:

//   пФайл - Имя файла

//   пЛист - Имя листа с данными

//   СтруктураКолонок - Структура вида "ИмяКолонки" - "НомерКолонки"

//                      если не задано, созадуться колонки вида "К1", "К2"

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция Excel_ПолучитьДанные_ADO(пФайл, пЛист, СтруктураКолонок = Неопределено, Знач НачСтрока = 0, Знач КонСтрока = 0) Экспорт



    #Если Клиент Тогда

    Состояние("Установка соединения с Excel");

    #КонецЕсли



    //ЗаголовкиВСтроке1 = "HDR=YES;"

    ЗаголовкиВСтроке1 = "HDR=NO;";



    СтрокаСоединения ="Provider=Microsoft.Jet.OLEDB.4.0;Data Source= " + СокрЛП(пФайл) +" ;Extended Properties=""Excel 8.0;" + ЗаголовкиВСтроке1 + "IMEX=1;""";



    Connection = Новый COMОбъект("ADODB.Connection");

    Connection.ConnectionString =  СтрокаСоединения;



    Попытка

        Connection.Open();

    Исключение

        Сообщить ("Проблемы с подключением к Excel" );

        Возврат Неопределено;

    КонецПопытки;



    RS = Новый COMОбъект("ADODB.Recordset");



    ТекстЗапроса =

    "S_elect

    |    Лист.*

    |FROM

    |    [" + пЛист + "$] as Лист";



    Попытка

        RS.Open(ТекстЗапроса, Connection);

    Исключение

        Сообщить ("Проблемы с выполнением запроса");

        Возврат Неопределено;

    КонецПопытки;



    Таблица = Новый ТаблицаЗначений;



    Если СтруктураКолонок = Неопределено Тогда



        Для Счетчик = 1 По RS.Fields.Count Цикл

            Поле = RS.Fields.Item(Счетчик - 1);

            Колонка = Таблица.Колонки.Добавить("К" + Счетчик, , Поле.Name);

        КонецЦикла;



    Иначе



        Для каждого КлючИЗначение Из СтруктураКолонок Цикл

            Колонка = Таблица.Колонки.Добавить(КлючИЗначение.Ключ);

        КонецЦикла;



    КонецЕсли;



    НомерСтроки = 0;

    КолвоСтрок  = RS.RecordCount;



    Пока RS.EOF() = 0 Цикл



        НомерСтроки = НомерСтроки + 1;



        #Если Клиент Тогда

        Состояние("Чтение файла: " + Формат(НомерСтроки) + " из " + Формат(КолвоСтрок));

        ОбработкаПрерыванияПользователя();

        #КонецЕсли



        Если НомерСтроки < НачСтрока Тогда

            RS.MoveNext();

            Продолжить;

        КонецЕсли;



        Если КонСтрока > 0 И НомерСтроки > КонСтрока Тогда

            Прервать;

        КонецЕсли;



        НоваяСтрока = Таблица.Добавить();



        Если СтруктураКолонок = Неопределено Тогда



            Для Счетчик = 1 По RS.Fields.Count Цикл



                Поле = RS.Fields.Item(Счетчик - 1);

                НоваяСтрока["К" + Счетчик] = Поле.Value;



            КонецЦикла;



        Иначе



            Для каждого КлючИЗначение Из СтруктураКолонок Цикл



                Поле = RS.Fields.Item(КлючИЗначение.Значение - 1);

                НоваяСтрока[КлючИЗначение.Ключ] = Поле.Value;



            КонецЦикла;



        КонецЕсли;



        // Обработка других полей

        RS.MoveNext();



    КонецЦикла;



    // Завершение работы



    RS.Close();

    Connection.Close();



    Возврат Таблица;



КонецФункции



// Функция получает данные из файла Excel

//

// Параметры:

//   пФайл     - Имя файла

//   пЛист     - Имя листа с данными

//   СтруктураКолонок - Структура вида "ИмяКолонки" - "НомерКолонки"

//                      если не задано, созадуться колонки вида "К1", "К2"

//   XLSОбъект - COM объект типа "Excel.Application"

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция Excel_ПолучитьДанные_COM(пФайл, пЛист, СтруктураКолонок = Неопределено, Знач НачСтрока = 0, Знач КонСтрока = 0, XLSОбъект = Неопределено) Экспорт



    #Если Клиент Тогда

    Состояние("Открытие Excel");

    #КонецЕсли



    Если XLSОбъект = Неопределено Тогда

        XLSОбъект = Новый COMОбъект("Excel.Application");

        XLSОбъект.Visible       = Ложь;

        XLSОбъект.DisplayAlerts = Ложь;

    КонецЕсли;



    Попытка

        Book = XLSОбъект.Workbooks.Open(пФайл, , Истина);

    Исключение

        Сообщить ("Проблемы с подключением к Excel" );

        Возврат Неопределено;

    КонецПопытки;



    Лист = Book.Sheets(1);

    КолвоКолонок = Лист.Cells(1,1).SpecialCells(11).Column;

    КолвоСтрок   = Лист.Cells(1,1).SpecialCells(11).Row;



    Таблица = Новый ТаблицаЗначений;



    Если СтруктураКолонок = Неопределено Тогда



        Для Счетчик = 1 По КолвоКолонок Цикл

            Колонка = Таблица.Колонки.Добавить("К" + Счетчик);

        КонецЦикла;



    Иначе



        Для каждого КлючИЗначение Из СтруктураКолонок Цикл

            Колонка = Таблица.Колонки.Добавить(КлючИЗначение.Ключ);

        КонецЦикла;



    КонецЕсли;



    НачСтрока = ?(НачСтрока = 0, 1, НачСтрока);

    КонСтрока = ?(КонСтрока = 0, КолвоСтрок, КонСтрока);

    КонСтрока = Мин(КонСтрока, КолвоСтрок);



    Для НомерСтроки = НачСтрока По КонСтрока Цикл



        #Если Клиент Тогда

        Состояние("Чтение файла: " + Формат(НомерСтроки) + " из " + Формат(КонСтрока));

        ОбработкаПрерыванияПользователя();

        #КонецЕсли



        НоваяСтрока = Таблица.Добавить();



        Если СтруктураКолонок = Неопределено Тогда



            Для НомерКолонки = 1 По КолвоКолонок Цикл



                Поле = Лист.Cells(НомерСтроки, НомерКолонки);

                НоваяСтрока["К" + Формат(НомерКолонки, "ЧГ=0")] = Поле.Value;



            КонецЦикла;



        Иначе



            Для каждого КлючИЗначение Из СтруктураКолонок Цикл



                Поле = Лист.Cells(НомерСтроки, КлючИЗначение.Значение);

                НоваяСтрока[КлючИЗначение.Ключ] = Поле.Value;



            КонецЦикла;



        КонецЕсли;



    КонецЦикла;



    XLSОбъект.Application.Quit();

    Возврат Таблица;



КонецФункции



// Функция получает данные из файла Excel

//

// Параметры:

//   пФайл     - Имя файла

//   пЛист     - Имя листа с данными

//   СтруктураКолонок - Структура вида "ИмяКолонки" - "НомерКолонки"

//                      если не задано, созадуться колонки вида "К1", "К2"

//   XLSОбъект - COM объект типа "Excel.Application"

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция Excel_ПолучитьДанные_COMArray(пФайл, пЛист, СтруктураКолонок = Неопределено, Знач НачСтрока = 0, Знач КонСтрока = 0, XLSОбъект = Неопределено) Экспорт



    #Если Клиент Тогда

    Состояние("Открытие Excel");

    #КонецЕсли



    Если XLSОбъект = Неопределено Тогда

        XLSОбъект = Новый COMОбъект("Excel.Application");

        XLSОбъект.Visible       = Ложь;

        XLSОбъект.DisplayAlerts = Ложь;

    КонецЕсли;



    Попытка

        Book = XLSОбъект.Workbooks.Open(пФайл, , Истина);

    Исключение

        Сообщить ("Проблемы с подключением к Excel" );

        Возврат Неопределено;

    КонецПопытки;



    Лист = Book.Sheets(1);

    КолвоКолонок = Лист.Cells(1,1).SpecialCells(11).Column;

    КолвоСтрок   = Лист.Cells(1,1).SpecialCells(11).Row;



    Таблица = Новый ТаблицаЗначений;



    Если СтруктураКолонок = Неопределено Тогда



        Для Счетчик = 1 По КолвоКолонок Цикл

            Колонка = Таблица.Колонки.Добавить("К" + Счетчик);

        КонецЦикла;



    Иначе



        МаксимальныйНомерКолонки = 0;

        Для каждого КлючИЗначение Из СтруктураКолонок Цикл

            Колонка = Таблица.Колонки.Добавить(КлючИЗначение.Ключ);

            МаксимальныйНомерКолонки = Макс(МаксимальныйНомерКолонки, КлючИЗначение.Значение);

        КонецЦикла;



        КолвоКолонок = Мин(КолвоКолонок, МаксимальныйНомерКолонки);



    КонецЕсли;



    НачСтрока = ?(НачСтрока = 0, 1, НачСтрока);

    КонСтрока = ?(КонСтрока = 0, КолвоСтрок, КонСтрока);

    КонСтрока = Мин(КонСтрока, КолвоСтрок);



    // Массив типа COMSafeArray

    Массив = Лист.Range(Лист.Cells(НачСтрока, 1), Лист.Cells(КонСтрока, КолвоКолонок)).Value;

    КолвоСтрок   = Массив.GetUpperBound(1);



    Для НомерСтроки = 1 По КолвоСтрок Цикл



        #Если Клиент Тогда

        Состояние("Чтение файла: " + Формат(НомерСтроки) + " из " + Формат(КолвоСтрок));

        ОбработкаПрерыванияПользователя();

        #КонецЕсли



        НоваяСтрока = Таблица.Добавить();



        Если СтруктураКолонок = Неопределено Тогда



            Для НомерКолонки = 1 По КолвоКолонок Цикл



                НоваяСтрока["К" + Формат(НомерКолонки, "ЧГ=0")] = Массив.GetValue(НомерКолонки, НомерСтроки);



            КонецЦикла;



        Иначе



            Для каждого КлючИЗначение Из СтруктураКолонок Цикл



                НоваяСтрока[КлючИЗначение.Ключ] = Массив.GetValue(КлючИЗначение.Значение, НомерСтроки);



            КонецЦикла;



        КонецЕсли;



    КонецЦикла;



    XLSОбъект.Application.Quit();

    Возврат Таблица;



КонецФункции



// Функция получает список листов Excel

//

// Параметры:

//   пФайл - Имя файла

//   XLSОбъект - COM объект типа "Excel.Application"

//

// Возвращаемое значение:

//   СписокЗначений

//

Функция Excel_ПолучитьСписокЛистов(пФайл, XLSОбъект = Неопределено) Экспорт



    Если XLSОбъект = Неопределено Тогда

        XLSОбъект = Новый COMОбъект("Excel.Application");

        XLSОбъект.Visible       = Ложь;

        XLSОбъект.DisplayAlerts = Ложь;

    КонецЕсли;



    Попытка

        Book = XLSОбъект.Workbooks.Open(пФайл, , Истина);

    Исключение

        Возврат Новый СписокЗначений;

    КонецПопытки;



    СписокЛистов = Новый СписокЗначений;

    Для каждого Лист Из XLSОбъект.Sheets Цикл

        СписокЛистов.Добавить(Лист.Name);

    КонецЦикла;



    XLSОбъект.Application.Quit();

    Возврат СписокЛистов;



КонецФункции

Код 1C v 7.x

 Попытка

  Excel = СоздатьОбъект("Excel.Application");

 Исключение

  Сообщить(ОписаниеОшибки()+"; программа Excel не установлена на данном компьютере!");

     Возврат;

 КонецПопытки;

РабочиеКниги=Excel.WorkBooks;  // создаем рабочую книгу



 Попытка // открываем файл

  Отчет=РабочиеКниги.Open(Каталог+ИмяФайла); 

 Исключение 

  Сообщить(ОписаниеОшибки()+"; фаил с макросом не найден!");

  Возврат;

 КонецПопытки;



// заносим в таблицу какие-либо данные



 Лист = Отчет.Worksheets(1);



 Для Ном=1 По 20 Цикл

      Ячейка = Лист .Cells(ном,1); Ячейка.Value;

      Сообщить(Ячейка );

 КонецЦикла; 



Excel.Visible=1;



Попытка

      Отчет.Save();

Исключение

     Сообщить(ОписаниеОшибки()+"; не могу сохранить отчет!");

  Возврат;

 КонецПопытки;

Категория: Работа с Microsoft Office и OpenOffice

Пакетный режим Конфигуратора 7.7

Пример пакетного файла:

[General]
Output="D:\Типовые конфигурации\1SBBDemo\log.txt"
Quit=1
SaveData=1
[SaveData]
SaveToFile="D:\Типовые конфигурации\1SBBDemo\arch.zip"

Ярлык для запуска базы и выполнения файла пакетного режима:

\\Server\1cv77\BIN\1cv7s.exe config /D "D:\Типовые конфигурации\1SBBDemo\" /@"D:\Типовые конфигурации\1SBBDemo\paket.txt"

Комментарий к файлу:
Во время работы будет сформирован лог-файл (Output="D:\Типовые конфигурации\1SBBDemo\log.txt"). Он будет здесь D:\Типовые конфигурации\1SBBDemo\log.tx.
Будет выполнено сохранение данных (SaveData=1) в файл arch.zip (SaveToFile="D:\Типовые конфигурации\1SBBDemo\arch.zip"). После выполения работы - конфигуратор будет закрыт (Quit=1). Информационная база хранится в D:\Типовые конфигурации\1SBBDemo\. Файл пакетного режима харанится в папке базы и называется paket.txt.

Пакетный режим является мощным инструментом. Чаще всего используется для создания архивных копий. Проблема только в том, что он архив делается всегда под одним именем. И чтобы не затирать старые архивы, требуется некоторая изворотливость с конфигурационным файлом пакетного режима. Но здесь огромное поле для фантазии, по этому предоставляю Вам возможность фантазировать.

Более подробно читайте в статье Параметры, ключи запуска 1Сv7 из командной строки

Категория: Администрирование