{"ok":"true","description":"\u0421\u0442\u0430\u0442\u0443\u0441 \u0437\u0430\u043a\u0430\u0437\u0430 \u0438\u0437\u043c\u0435\u043d\u0435\u043d"}   

 Чтение = Новый ЧтениеJSON;

	Чтение.УстановитьСтроку(стрВходящая);

	ДанныеЛога = ПрочитатьJSON(Чтение);

	Чтение.Закрыть();   

 //Функция читает полученный JSON декадируя текст юникод

Функция ДекодироватьUniCodeВJSON(стрВходящая) 

	// стрВходящая содержит {"ok":"true","description":"\u0421\u0442\u0430\u0442\u0443\u0441 \u0437\u0430\u043a\u0430\u0437\u0430 \u0438\u0437\u043c\u0435\u043d\u0435\u043d"}

	

	Чтение = Новый ЧтениеJSON;

	Чтение.УстановитьСтроку(стрВходящая);

	ДанныеЛога = ПрочитатьJSON(Чтение);

	Чтение.Закрыть();

	

	// Вариант 1 используя перебор структуры и вывод в текстовую переменную

	Текст = "";

	Для каждого Элемент Из ДанныеЛога Цикл

		//добавим разделитель после предыдущего значения

		Текст = Текст + ?(НЕ ПустаяСтрока(Текст), Символы.ПС, "");

		//добавим представление ключа и значения:

		Текст = Текст + Элемент.Ключ + " = " + Элемент.Значение;

	КонецЦикла;

	Возврат Текст; //Вернет   ok = true   description = Статус заказа изменен

	

	// Вариант 2 мспользуя ЗаписьJSON

	Запись = Новый ЗаписьJSON;    

	Запись.УстановитьСтроку(Новый ПараметрыЗаписиJSON(ПереносСтрокJSON.Нет));

	ЗаписатьJSON(Запись, ДанныеЛога,);

	Возврат Запись.Закрыть();  // Вернет JSON  {"ok":"true","description":"Статус заказа изменен"}

КонецФункции   

 //Параметры: Строка в Юникод (обязательный) Тип: Строка. Исходная строка.

//Возвращаемое значение: Тип: Строка. Строка обработанных символов.

//Описание: Возвращает преобразованную строку из формата Unicod.

//Автор: Александр Кияница (treedo)

Функция ПереобразоватьЮникод(Строка)

   

    ГотововаяСтрока = "" ;

    

    МасУкр = Новый Массив(66) ;

    

    МасУкр[0]="А";   МасУкр[1]="Б";  МасУкр[2]="В";  МасУкр[3]="Г";  МасУкр[4]="Ґ";  МасУкр[5]="Д";

    МасУкр[6]="Е";   МасУкр[7]="Є";  МасУкр[8]="Ж";  МасУкр[9]="З";  МасУкр[10]="И"; МасУкр[11]="І";

    МасУкр[12]="Ї";  МасУкр[13]="Й"; МасУкр[14]="К"; МасУкр[15]="Л"; МасУкр[16]="М"; МасУкр[17]="Н";

    МасУкр[18]="О";  МасУкр[19]="П"; МасУкр[20]="Р"; МасУкр[21]="С"; МасУкр[22]="Т"; МасУкр[23]="У";

    МасУкр[24]="Ф";  МасУкр[25]="Х"; МасУкр[26]="Ц"; МасУкр[27]="Ч"; МасУкр[28]="Ш"; МасУкр[29]="Щ";

    МасУкр[30]="Ь";  МасУкр[31]="Ю"; МасУкр[32]="Я";  





    МасУкр[33]="а";  МасУкр[34]="б"; МасУкр[35]="в"; МасУкр[36]="г"; МасУкр[37]="ґ"; МасУкр[38]="д";

    МасУкр[39]="е";  МасУкр[40]="є"; МасУкр[41]="ж"; МасУкр[42]="з"; МасУкр[43]="и"; МасУкр[44]="і";

    МасУкр[45]="ї";  МасУкр[46]="й"; МасУкр[47]="к"; МасУкр[48]="л"; МасУкр[49]="м"; МасУкр[50]="н";

    МасУкр[51]="о";  МасУкр[52]="п"; МасУкр[53]="р"; МасУкр[54]="с"; МасУкр[55]="т"; МасУкр[56]="у";

    МасУкр[57]="ф";  МасУкр[58]="х"; МасУкр[59]="ц"; МасУкр[60]="ч"; МасУкр[61]="ш"; МасУкр[62]="щ";

    МасУкр[63]="ь";  МасУкр[31]="ю"; МасУкр[65]="я";  

        

    

    МасКод = Новый Массив(66) ;

    

    МасКод[0]="0410";   МасКод[1]="0411";  МасКод[2]="0412";  МасКод[3]="0413";  МасКод[4]="0490";  МасКод[5]="0414";

    МасКод[6]="0415";   МасКод[7]="0404";  МасКод[8]="0416";  МасКод[9]="0417";  МасКод[10]="0418"; МасКод[11]="0406";

    МасКод[12]="0407";  МасКод[13]="0419"; МасКод[14]="041A"; МасКод[15]="041B"; МасКод[16]="041C"; МасКод[17]="041D";

    МасКод[18]="041E";  МасКод[19]="041F"; МасКод[20]="0420"; МасКод[21]="0421"; МасКод[22]="0422"; МасКод[23]="0423";

    МасКод[24]="0424";  МасКод[25]="0425"; МасКод[26]="0426"; МасКод[27]="0427"; МасКод[28]="0428"; МасКод[29]="0429";

    МасКод[30]="042C";  МасКод[31]="042E"; МасКод[32]="042F";  





    МасКод[33]="0430";  МасКод[34]="0431"; МасКод[35]="0432"; МасКод[36]="0413"; МасКод[37]="0491"; МасКод[38]="0434";

    МасКод[39]="0435";  МасКод[40]="0454"; МасКод[41]="0436"; МасКод[42]="0437"; МасКод[43]="0438"; МасКод[44]="0456";

    МасКод[45]="0457";  МасКод[46]="0439"; МасКод[47]="043A"; МасКод[48]="043B"; МасКод[49]="043C"; МасКод[50]="043D";

    МасКод[51]="043E";  МасКод[52]="043F"; МасКод[53]="0440"; МасКод[54]="0441"; МасКод[55]="0442"; МасКод[56]="0443";

    МасКод[57]="0444";  МасКод[58]="0445"; МасКод[59]="0446"; МасКод[60]="0447"; МасКод[61]="0448"; МасКод[62]="0449";

    МасКод[63]="044C";  МасКод[31]="044E"; МасКод[65]="044F";  

    

    

    тмпСтрока = "" ;

    Для Счетчик = 1 По СтрДлина(Строка) Цикл      

        Если Лев(Строка, 1) = "\" Тогда

            Если Лев(Строка, 2) = "\u" Тогда

                

                тмпСтрока = Прав(Лев(Строка, 6),4) ;

                Если МасКод.Найти(тмпСтрока) = Неопределено Тогда

                    СтрокаЗамены = Прав(тмпСтрока, 1) ;

                    тмпСтрока = СтрЗаменить(тмпСтрока,СтрокаЗамены,ТРег(СтрокаЗамены)); 

                    Если МасКод.Найти(тмпСтрока) = Неопределено Тогда

                        Сообщить("Код символа не найден: " + тмпСтрока) ;

                    Иначе                      

                        ГотововаяСтрока = ГотововаяСтрока + МасУкр[МасКод.Найти(тмпСтрока)] ;                                   

                    КонецЕсли;

                Иначе

                    ГотововаяСтрока = ГотововаяСтрока + МасУкр[МасКод.Найти(тмпСтрока)] ;               

                КонецЕсли;

                

                Строка = Прав(Строка, (СтрДлина(Строка)-6)) ; 

            Иначе  

                Строка = Прав(Строка, (СтрДлина(Строка)-2)) ;

            КонецЕсли;

        Иначе

            ГотововаяСтрока = ГотововаяСтрока + Лев(Строка, 1) ;

            Строка = Прав(Строка, (СтрДлина(Строка)-1)) ;     

        КонецЕсли;         

    КонецЦикла;   





    Возврат ГотововаяСтрока ;

        

КонецФункции   

 



Перем Л_Лев_Фиг_Скобка, Л_Прав_Фиг_Скобка, Л_Лев_Кв_Скобка, Л_Прав_Кв_Скобка, Л_Кавычка, Л_Экран, Л_Двоеточие, Л_Запятая, Л_Число, Л_Строка, Л_Константа, Л_Финиш;

Перем Цифры1_9, Цифры0_9, ПервыеСимволыКонстант, ОдносимвольныеЛексемы;

Перем НомЛексемы, ТекЛексема;

Перем JSON_Error;

Перем В_Массив, В_Объект, В_Значение;

//*****

Перем НомерСимвола;

Перем ФлагОшибки;

Перем СписокСтроковыхКонстант;

Перем СтекЛексем;

Перем АнализируемаяСтрока;

//*****

Перем ТекКаталог, ТекФайл;

//*****

Функция ПолучитьОбъект_ТЗ() Далее

Функция ПолучитьМассив_ТЗ() Далее

//*****

Функция ТекущиеСимволы(Сколько)

	Возврат Сред(АнализируемаяСтрока, НомерСимвола, Сколько);

КонецФункции

//*****

Функция ПрошлыйСимвол(Сдвиг)

	Возврат Сред(АнализируемаяСтрока, НомерСимвола - Сдвиг, 1);

КонецФункции

//*****

Процедура ДобавитьЛексему(Лексема, Значение, Сдвиг)

	СтекЛексем.НоваяСтрока();

	СтекЛексем.Лексема	= Лексема;

	СтекЛексем.Значение	= Значение;	

	НомерСимвола		= НомерСимвола + Сдвиг;

КонецПроцедуры

//*****

Процедура ОбвестиОбласть(Обл)

	Обл.РамкаСнизу(1);

	Обл.РамкаСверху(1);

	Обл.РамкаСлева(1);

	Обл.РамкаСправа(1);

КонецПроцедуры

//*****

Процедура НапечататьТЗ(Таб, ТЗ, НомС, НомК)

Перем Тип, Обл1, НС, КС, Ключ, Зн, Обл2;

	Тип = ТЗ.ПолучитьЗначение(1, 1);

	НомС = НомС + 1;

	Обл1 = Таб.Область(НомС, НомК);

	ОбвестиОбласть(Обл1);

	Если Тип = В_Значение Тогда

		ТипЗн = ТЗ.ПолучитьЗначение(2, 1);

		Обл1.Текст = ТЗ.ПолучитьЗначение(2, 2);

		Обл1.ГоризонтальноеПоложение(1);

		Если ТипЗн = Л_Число Тогда

			Обл1.ГоризонтальноеПоложение(2);

		ИначеЕсли ТипЗн = Л_Константа Тогда

			Обл1.Полужирный(1);

		ИначеЕсли ТипЗн = Л_Строка Тогда

			Обл1.Контроль(4);

		КонецЕсли;

		Возврат;

	ИначеЕсли (Тип = В_Объект) Или (Тип = В_Массив) Тогда

		Обл1.Текст = Тип;

		Обл1.Полужирный(1);

		Обл1.ЦветФона(12648447);

		Обл1.РамкаСнизу(5);

		КС = ТЗ.КоличествоСтрок();

		Для НС = 2 По КС Цикл

			НомС = НомС + 1;

			Обл2 = Таб.Область(НомС, НомК);

			Обл2.Текст = ТЗ.ПолучитьЗначение(НС, 1);

			Если Тип = В_Массив Тогда

				Обл2.ГоризонтальноеПоложение(2);

			КонецЕсли;

			ОбвестиОбласть(Обл2);

			НомС = НомС - 1;

			НапечататьТЗ(Таб, ТЗ.ПолучитьЗначение(НС, 2), НомС, НомК + 1);

		КонецЦикла;

	Иначе

		Сообщить("Фигня " + Тип, "!");

	КонецЕсли;

КонецПроцедуры

//*****

Процедура ВыравнятьТЗ(Таб, ОграничениеШирины)

Перем НомерКол, НомерСтр, МаксШирина, Обл, ТекШирина, ТекДлина;

	Для НомерКол = 1 По Таб.ШиринаТаблицы() Цикл

		МаксШирина = 0;

		Для НомерСтр = 1 По Таб.ВысотаТаблицы() Цикл

			Обл = Таб.Область(НомерСтр, НомерКол);

			ТекШирина = Обл.ШиринаСтолбца();

			ТекДлина = СтрДлина(СокрЛП(Обл.Текст));

			МаксШирина = Макс(МаксШирина, ТекШирина, ТекДлина);

		КонецЦикла;

		Таб.Область(, НомерКол).ШиринаСтолбца(Мин(МаксШирина, ОграничениеШирины));

	КонецЦикла;

КонецПроцедуры

//*****

Процедура Напечатать_ТЗ(ТЗ)

Перем Таб, НС, НК, МаксШирина, ТекДлина, Обл;	

	Таб = СоздатьОбъект("Таблица");

	МаксНК = 1;

	НС = 0;

	НК = 1;

	НапечататьТЗ(Таб, ТЗ, НС, НК);

	ВыравнятьТЗ(Таб, 30);

	Таб.Область(1, 1, Таб.ВысотаТаблицы(), Таб.ШиринаТаблицы()).ВертикальноеПоложение(2);

	Таб.Опции(0, 0);

	Таб.Показать("JSON");

КонецПроцедуры

//*****

Функция Ошибка()

	ФлагОшибки = 1;

	Возврат 0;

КонецФункции

//*****

Функция ЧитатьКонстанту(ПервСимвол)

Перем КонстантаСтр, ДлинаКонстанты;	

	КонстантаСтр = СписокСтроковыхКонстант.Получить(ПервСимвол);

	ДлинаКонстанты = СтрДлина(КонстантаСтр);

	Если ТекущиеСимволы(ДлинаКонстанты) = КонстантаСтр Тогда

		ДобавитьЛексему(Л_Константа, КонстантаСтр, ДлинаКонстанты);

		Возврат 1;

	Иначе

		Возврат Ошибка();

	КонецЕсли;

КонецФункции

//*****

Процедура ДописатьСимвол(Стр)

	Стр = Стр + ТекущиеСимволы(1);

	НомерСимвола = НомерСимвола + 1;

КонецПроцедуры

//*****

Функция ЧитатьЧисло() 

Перем ЧислоСтр;

	ЧислоСтр = "";

	Если ТекущиеСимволы(1) = "-" Тогда

		ДописатьСимвол(ЧислоСтр);

	КонецЕсли;

	Если Найти(Цифры1_9, ТекущиеСимволы(1)) > 0 Тогда // не с нуля

		ДописатьСимвол(ЧислоСтр);

		Пока Найти(Цифры0_9, ТекущиеСимволы(1)) > 0 Цикл  // любые цыфры 

			ДописатьСимвол(ЧислоСтр);

		КонецЦикла;		

	ИначеЕсли ТекущиеСимволы(1) = "0" Тогда //с нуля - ничего дальше 

		ДописатьСимвол(ЧислоСтр);

	Иначе

		Возврат Ошибка();

	КонецЕсли;

	Если ТекущиеСимволы(1) = "." Тогда // десятичная точка

		ДописатьСимвол(ЧислоСтр);

		Пока Найти(Цифры0_9, ТекущиеСимволы(1)) > 0 Цикл  // любые цыфры

			ДописатьСимвол(ЧислоСтр);

		КонецЦикла;		

	КонецЕсли;

	Если ВРег(ТекущиеСимволы(1)) = "E" Тогда // значок e больное или маленькое

		ДописатьСимвол(ЧислоСтр);

		Если Найти("+-", ТекущиеСимволы(1)) > 0 Тогда  // унарный знак для порядка

			ДописатьСимвол(ЧислоСтр);

		КонецЕсли;

		Пока Найти(Цифры0_9, ТекущиеСимволы(1)) > 0 Цикл  // любые цыфры

			ДописатьСимвол(ЧислоСтр);

		КонецЦикла;		

	КонецЕсли;

	ДобавитьЛексему(Л_Число, ЧислоСтр, 0);

	Возврат 1;

КонецФункции

//*****

Функция ЧитатьСтроку()

Перем СтрокаСтр;

	СтрокаСтр = "";

	НомерСимвола = НомерСимвола + 1;

	Пока (ТекущиеСимволы(1) <> Л_Кавычка) Или ((ТекущиеСимволы(1) = Л_Кавычка) И (ПрошлыйСимвол(1) = Л_Экран) И (ПрошлыйСимвол(2) <> Л_Экран)) Цикл

		ДописатьСимвол(СтрокаСтр);

	КонецЦикла;

	ДобавитьЛексему(Л_Строка, СтрокаСтр, 1); 

	Возврат 1;

КонецФункции 

//*****

Функция ПрочитатьФайл(ИмяФайла)

Перем Т, НомерСтрокиФайла, СтрокаРез;

	Т = СоздатьОбъект("Текст");

	Т.Открыть(ИмяФайла);

	СтрокаРез = "";

	Для НомерСтрокиФайла = 1 По Т.КоличествоСтрок() Цикл

		СтрокаРез = СтрокаРез + Т.ПолучитьСтроку(НомерСтрокиФайла);

	КонецЦикла;

	Возврат СтрокаРез;

КонецФункции

//*****

Функция СледующаяЛексема()

	НомЛексемы = НомЛексемы + 1;

	СтекЛексем.ПолучитьСтрокуПоНомеру(НомЛексемы);

	ТекЛексема = СтекЛексем.Лексема;

	Возврат 1;

КонецФункции

//*****

Функция ОшибкаЛексемы()

Перем РезСтр, НомСтр, ТЛ, ТС;

	Сообщить("Ошибочная лексема № " + НомЛексемы + " : <" + ТекЛексема + ">", "!");

	РезСтр = "";

	Для НомСтр = НомЛексемы + 1 По СтекЛексем.КоличествоСтрок() Цикл

		СтекЛексем.ПолучитьСтрокуПоНомеру(НомСтр);

		ТЛ = СтекЛексем.Лексема;

		Если ТЛ = Л_Строка Тогда 

			ТС = "<" + ТЛ + "(" + СтекЛексем.Значение + ")>";

		ИначеЕсли ТЛ = Л_Константа Тогда

			ТС = "<" + ТЛ + "(" + СтекЛексем.Значение + ")>";

		Иначе

			ТС = "<" + ТЛ + ">";

		КонецЕсли;

		РезСтр = РезСтр + ТС + ",";

	КонецЦикла;

	Сообщить(Лев(РезСтр, 400), "!");

	Возврат 0;

КонецФункции

//*****

Процедура ДобавитьПару(ТЗ, Ключ, Значение)

	ТЗ.НоваяСтрока();

	ТЗ.Ключ		= Ключ;

	ТЗ.Значение	= Значение;

КонецПроцедуры

//*****

Функция НоваяТЗ(Тип)

Перем _ТЗ;

	_ТЗ = СоздатьОбъект("ТаблицаЗначений");

	_ТЗ.НоваяКолонка("Ключ");

	_ТЗ.НоваяКолонка("Значение");

	ДобавитьПару(_ТЗ, Тип, "");

	Возврат _ТЗ;

КонецФункции

//*****

Функция ПолучитьПроизвольноеЗначение_ТЗ()

Перем ТЗ;	

	Если (ТекЛексема = Л_Строка) Или (ТекЛексема = Л_Число) Или (ТекЛексема = Л_Константа) Тогда

		ТЗ = НоваяТЗ(В_Значение);

		ДобавитьПару(ТЗ, ТекЛексема, СтекЛексем.Значение);

		СледующаяЛексема();

		Возврат ТЗ;

	ИначеЕсли ТекЛексема = Л_Лев_Фиг_Скобка Тогда

		Возврат ПолучитьОбъект_ТЗ();

	ИначеЕсли ТекЛексема = Л_Лев_Кв_Скобка 	Тогда

		Возврат ПолучитьМассив_ТЗ();					

	КонецЕсли;

	Возврат ОшибкаЛексемы();

КонецФункции

//*****

Функция ДобавитьКлючЗначение(ТЗ)

Перем НовКлюч, НовЗначение;

	Если ТекЛексема <> Л_Строка Тогда

		Возврат 0;

	КонецЕсли;

	НовКлюч = СтекЛексем.Значение;

	СледующаяЛексема();

	Если ТекЛексема <> Л_Двоеточие Тогда

		Возврат ОшибкаЛексемы();

	КонецЕсли;

	СледующаяЛексема();

	НовЗначение = ПолучитьПроизвольноеЗначение_ТЗ();

	Если НовЗначение = 0 Тогда

		Возврат 0;

	КонецЕсли;

	ДобавитьПару(ТЗ, НовКлюч, НовЗначение);

	Возврат 1;

КонецФункции

//*****

Функция ПолучитьОбъект_ТЗ()

Перем ТЗ;

	ТЗ = НоваяТЗ(В_Объект);

	СледующаяЛексема();

	Если ТекЛексема = Л_Прав_Фиг_Скобка Тогда // пустой объект

		СледующаяЛексема();

		Возврат ТЗ;

	КонецЕсли;

	Если ДобавитьКлючЗначение(ТЗ) = 0 Тогда   // первая пара ключ-значение

		Возврат 0;

	КонецЕсли;	

	Пока ТекЛексема = Л_Запятая Цикл			// пока запятые

		СледующаяЛексема();

		Если ДобавитьКлючЗначение(ТЗ) = 0 Тогда	// пара ключ-значение

			Возврат 0;

		КонецЕсли;

	КонецЦикла;

	Если ТекЛексема = Л_Прав_Фиг_Скобка Тогда

		СледующаяЛексема();

		Возврат ТЗ;

	КонецЕсли;

	Возврат 0;

КонецФункции

//*****

Функция ПолучитьМассив_ТЗ()

Перем ТЗ, _Ключ, _Значение;

	ТЗ = НоваяТЗ(В_Массив);

	СледующаяЛексема();

	Если ТекЛексема = Л_Прав_Кв_Скобка Тогда

		СледующаяЛексема();

		Возврат ТЗ;

	КонецЕсли;

	_Значение = ПолучитьПроизвольноеЗначение_ТЗ();

	Если _Значение = 0 Тогда

		Возврат 0;

	КонецЕсли;

	_Ключ = 0; // JS - индексы массиворв с нуля

	ДобавитьПару(ТЗ, _Ключ, _Значение);	

	Пока ТекЛексема = Л_Запятая Цикл

		СледующаяЛексема();

		_Значение = ПолучитьПроизвольноеЗначение_ТЗ();

		Если _Значение = 0 Тогда

			Возврат 0;

		КонецЕсли;

		_Ключ = _Ключ + 1;

		ДобавитьПару(ТЗ, _Ключ, _Значение);

	КонецЦикла;

	Если ТекЛексема = Л_Прав_Кв_Скобка Тогда

		СледующаяЛексема();

		Возврат ТЗ;

	КонецЕсли;

	Возврат 0;

КонецФункции

//*****

Функция ПрочитатьОбъект_ТЗ()

Перем Рез;	

	НомЛексемы = 0;

	СледующаяЛексема();

	Если ТекЛексема = Л_Лев_Фиг_Скобка Тогда

		Рез = ПолучитьОбъект_ТЗ();

	ИначеЕсли ТекЛексема = Л_Лев_Кв_Скобка Тогда

		Рез = ПолучитьМассив_ТЗ();

	Иначе

		Рез = ПолучитьПроизвольноеЗначение_ТЗ();

	КонецЕсли;

	Если (Рез = 0) Или (ТекЛексема <> Л_Финиш) Тогда

		ОшибкаЛексемы();

		Возврат 0;

	КонецЕсли;

	Возврат Рез;	

КонецФункции

//*****

Функция СгенерироватьТЗ(НачАнализируемаяСтрока)

Перем НачальныйСимвол, Рез;

	АнализируемаяСтрока = НачАнализируемаяСтрока;

	СтекЛексем = СоздатьОбъект("ТаблицаЗначений");

	СтекЛексем.НоваяКолонка("Лексема" , "Строка");

	СтекЛексем.НоваяКолонка("Значение", "Строка");

	ФлагОшибки = 0;

	НомерСимвола = 1;

	Пока НомерСимвола <= СтрДлина(АнализируемаяСтрока) Цикл

		НачальныйСимвол = ТекущиеСимволы(1);

		Если Найти(" " + Симв(9), НачальныйСимвол) > 0 Тогда  // пробелы и разделители строк пропускаем

			НомерСимвола = НомерСимвола + 1;

		ИначеЕсли НачальныйСимвол = Л_Кавычка	Тогда // кавычка - читаем строку

			ЧитатьСтроку();

		ИначеЕсли Найти(ОдносимвольныеЛексемы, НачальныйСимвол) > 0 Тогда

			ДобавитьЛексему(НачальныйСимвол, "", 1);

		ИначеЕсли Найти(ПервыеСимволыКонстант, НачальныйСимвол) > 0 Тогда // первая буква из начала константы - константа null, true, false

			Если ЧитатьКонстанту(НачальныйСимвол) = 0 Тогда

				Прервать;

			КонецЕсли;

		ИначеЕсли Найти("-" + Цифры0_9, НачальныйСимвол) > 0 Тогда // число

			Если ЧитатьЧисло() = 0 Тогда

				Прервать;

			КонецЕсли;

		Иначе		// иных вариантов нет

			Сообщить("========= " + НомерСимвола, "!");

			Сообщить(НачальныйСимвол, "!");

			Сообщить("<" + НачальныйСимвол + "> " + КодСимв(НачальныйСимвол), "!");

			Сообщить(ТекущиеСимволы(100), "!");

			Возврат 0;

		КонецЕсли;

	КонецЦикла;

	Если ФлагОшибки <> 0 Тогда

		Сообщить("Ошибка парсинга JSON - выражения", "!");

		Возврат 0;

	ИначеЕсли СтекЛексем.КоличествоСтрок() = 0 Тогда

		Сообщить("Пустой стек", "!");

		Возврат 0;

	КонецЕсли;

	ДобавитьЛексему(Л_Финиш, "", 0);

	Возврат ПрочитатьОбъект_ТЗ();

КонецФункции

//*****

Функция JSON_Error(Стр = "")

	Если Стр <> "" Тогда

		Сообщить("JSON-ОШИБКА: " + Стр, "!");

	КонецЕсли;

	Возврат JSON_Error;

КонецФункции

//*****

Функция JSON_Type(Парам)

	Если ТипЗначенияСтр(Парам) <> "ТаблицаЗначений" Тогда

		Возврат JSON_Error();

	ИначеЕсли Парам.КоличествоКолонок() <> 2 Тогда

		Возврат JSON_Error();

	ИначеЕсли Парам.КоличествоСтрок() < 2 Тогда

		Возврат JSON_Error();

	КонецЕсли;

	Возврат Парам.ПолучитьЗначение(1, 1);

КонецФункции

//*****

Функция JSON_GetValue(Парам, Keys)

Перем Тип, До, После, ПозЗакр, Л1, П2, Инд, ИндСтр, НС, КвоСтрок;

	Тип = JSON_Type(Парам);

	ПозЗакр = Найти(Keys, "]");

	Если ПозЗакр = 0 Тогда

		ПозЗакр = СтрДлина(Keys) + 1;

	КонецЕсли;	

	До = Лев(Keys, ПозЗакр);

	После = Сред(Keys, ПозЗакр + 1);

	Л1 = Лев(До, 1);

	П2 = Найти(До, "]");

	Если Тип = JSON_Error Тогда

		Возврат JSON_Error("Параметра");

	КонецЕсли;

	КвоСтрок = Парам.КоличествоСтрок();

	Если До = "" Тогда // сам объект

		Если (Тип = В_Массив) Или (Тип = В_Объект) Тогда

			Возврат JSON_Error();

		ИначеЕсли Тип = В_Значение Тогда

			Возврат Парам.ПолучитьЗначение(2, 2);

		Иначе

			Возврат JSON_Error("№ 1");

		КонецЕсли;		

	ИначеЕсли До = ".length" Тогда // размер массива или объекта. Для значения - ошибка

		Если (Тип = В_Массив) Или (Тип = В_Объект) Тогда

			Возврат Парам.КоличествоСтрок() - 1;

		Иначе

			Возврат JSON_Error("Длина скаляра");

		КонецЕсли;

	ИначеЕсли Л1 = "[" Тогда // размер массива или объекта. Для значения - ошибка

		Если П2 = 0 Тогда

			Возврат JSON_Error("Индексация: <" + До + ">");

		КонецЕсли;

		Инд = Сред(До, 2, П2 - 2);

		Если (Найти("'""", Лев(Инд, 1)) > 0) И (Найти("'""", Прав(Инд, 1)) > 0) Тогда // строковый только объект

			ИндСтр = Сред(Инд, 2, СтрДлина(Инд) - 2);

			Если Тип <> В_Объект Тогда

				Возврат JSON_Error("Строковый индекс <" + ИндСтр + "> только для Объекта");

			КонецЕсли;

			НС = 0;

			Если Парам.НайтиЗначение(ИндСтр, НС, 1) = 1 Тогда

				Возврат JSON_GetValue(Парам.ПолучитьЗначение(НС, 2), После);

			КонецЕсли;

			Возврат JSON_Error("Нет индекса <" + ИндСтр + ">");

		КонецЕсли;

		ИндЧис = 0 + Инд;

		Если "" + ИндЧис <> Инд Тогда // защита от <5D>

			Возврат JSON_Error("Ошибка 1 числового индекса <" + Инд + ">");

		ИначеЕсли Цел(ИндЧис) <> ИндЧис Тогда // защита от неЦелого индекса

			Возврат JSON_Error("Ошибка 2 числового индекса <" + Инд + "> (нецелый)");

		ИначеЕсли ИндЧис < 0 Тогда

			Возврат JSON_Error("Ошибка 3 числового индекса <" + Инд + "> (отрицательный)");

		ИначеЕсли ИндЧис > (КвоСтрок - 2) Тогда

			Возврат JSON_Error("Ошибка 4 числового индекса <" + Инд + "> (" + ИндЧис + ">" + (КвоСтрок - 2) + ")");

		КонецЕсли;

		Возврат JSON_GetValue(Парам.ПолучитьЗначение(ИндЧис + 1, 2), После);

	Иначе

		Возврат JSON_Error("Ошибка 5 <" + До + ">");

	КонецЕсли;

КонецФункции

//*****

Процедура ПриОткрытии()

Перем Рез1, ТипУзла1, Зн1, Значение;	

	ОчиститьОкноСообщений();

	СтатусВозврата(0);

	Рез1 = СгенерироватьТЗ(ПрочитатьФайл(ТекКаталог + "j1.json"));

	Напечатать_ТЗ(Рез1);

	ТипУзла1 = JSON_Type(Рез1);

	Сообщить("Тип узла: " + ТипУзла1);

	Зн1 = JSON_GetValue(Рез1, ".length");									Сообщить("1) Размер: " 		+ Зн1);

	Зн3 = JSON_GetValue(Рез1, "['1']");										Сообщить("3) ['1']: <" 		+ Зн3 + ">");

	Зн4 = JSON_GetValue(Рез1, "[1]");										Сообщить("4) [1]: <" 		+ Зн4 + ">");

	Зн5 = JSON_GetValue(Рез1, "['Массив'][6]");								Сообщить("5) [*]: <" + Зн5 + ">");

	Зн6 = JSON_GetValue(Рез1, "['Соответствие']['ДопустимоеИмяСвойства']");	Сообщить("6) [*]: <" + Зн6 + ">");

КонецПроцедуры

//*****

Процедура ДобавитьСтроковуюКонстанту(КонстантаСтр)

Перем ПервыйСимвол;	

	ПервыйСимвол = Лев(КонстантаСтр, 1);

	ПервыеСимволыКонстант = ПервыеСимволыКонстант + ПервыйСимвол;

	СписокСтроковыхКонстант.Установить(ПервыйСимвол, КонстантаСтр);

КонецПроцедуры

//*****

РасположениеФайла(ТекКаталог, ТекФайл);

//*****

Л_Лев_Фиг_Скобка	= "{";

Л_Прав_Фиг_Скобка	= "}";

Л_Лев_Кв_Скобка		= "["; 

Л_Прав_Кв_Скобка	= "]";

Л_Двоеточие			= ":";

Л_Запятая			= ",";

Л_Экран				= "\";

Л_Кавычка			= """";

Л_Финиш				= "";

Л_Число				= "number";

Л_Строка			= "string";

Л_Константа			= "const";

ОдносимвольныеЛексемы = Л_Лев_Фиг_Скобка + Л_Прав_Фиг_Скобка + Л_Лев_Кв_Скобка + Л_Прав_Кв_Скобка + Л_Двоеточие + Л_Запятая;

//*****

Цифры1_9 = "123456789";

Цифры0_9 = "0" + Цифры1_9;

//*****

В_Массив   = "###array";

В_Объект   = "###object";

В_Значение = "###value";

//*****

СписокСтроковыхКонстант	= СоздатьОбъект("СписокЗначений");

ПервыеСимволыКонстант	= "";

ДобавитьСтроковуюКонстанту("null");

ДобавитьСтроковуюКонстанту("false");

ДобавитьСтроковуюКонстанту("true");

JSON_Error = "ERROR";

 //PAV 17/05/2010 (Andrew_flyer)

Функция ПреобразоватьвСистему(Число10,система)

	

	Если система > 36 или система < 2 тогда

		Сообщить("Выбранная система исчисления не поддерживается");

		Возврат -1;

	КонецЕсли;

	

	СтрокаЗначений = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ";

	СтрокаСистема = "";

	Пока Число10 > 0 цикл

		РезДеления = Число10/система;

		ЧислоСистема = цел(РезДеления);

		остатокОтДеления = Число10 - система*(ЧислоСистема);

		СтрокаСистема = сред(СтрокаЗначений,остатокОтДеления+1,1)+ СтрокаСистема;

		Число10 = ?(ЧислоСистема=0,0,РезДеления); 

	КонецЦикла;

	

	//!!!!!!!!

	//[

	Нечётное = стрДлина(СтрокаСистема) - цел(стрДлина(СтрокаСистема)/2)*2;

	Если Нечётное тогда

		СтрокаСистема = "0"+СтрокаСистема;

	КонецЕсли;

	//]

	Возврат СтрокаСистема;

КонецФункции



Функция ПреобразоватьКURL(Стр)

	

	Длина=СтрДлина(Стр);

	Итог="";

	Для Н=1 По Длина Цикл

		Знак=Сред(Стр,Н,1);

		Код=КодСимвола(Знак);

		

		если ((Знак>="a")и(Знак<="z")) или

			 ((Знак>="A")и(Знак<="Z")) или

			 ((Знак>="0")и(Знак<="9")) тогда

			Итог=Итог+Знак;

		Иначе

			Если (Код>=КодСимвола("А"))И(Код<=КодСимвола("п")) Тогда

				Итог=Итог+"%"+ПреобразоватьвСистему(208,16)+"%"+ПреобразоватьвСистему(144+Код-КодСимвола("А"),16);

			ИначеЕсли (Код>=КодСимвола("р"))И(Код<=КодСимвола("я")) Тогда

				Итог=Итог+"%"+ПреобразоватьвСистему(209,16)+"%"+ПреобразоватьвСистему(128+Код-КодСимвола("р"),16);

			ИначеЕсли (Знак="ё") Тогда

				Итог=Итог+"%"+ПреобразоватьвСистему(209,16)+"%"+ПреобразоватьвСистему(145,16);

			ИначеЕсли (Знак="Ё") Тогда

				Итог=Итог+"%"+ПреобразоватьвСистему(208,16)+"%"+ПреобразоватьвСистему(129,16);

			Иначе

				Итог=Итог+"%"+ПреобразоватьвСистему(Код,16);

			КонецЕсли;

		КонецЕсли;

	КонецЦикла;

	Возврат Итог;

КонецФункции