keys » Поиск » HelpF.pro

Результаты по ключевому слову: keys

Синтаксический анализ JSON - выражения средствами 1С 7.7

Код 1C v 7.x

 



Перем Л_Лев_Фиг_Скобка, Л_Прав_Фиг_Скобка, Л_Лев_Кв_Скобка, Л_Прав_Кв_Скобка, Л_Кавычка, Л_Экран, Л_Двоеточие, Л_Запятая, Л_Число, Л_Строка, Л_Константа, Л_Финиш;

Перем Цифры1_9, Цифры0_9, ПервыеСимволыКонстант, ОдносимвольныеЛексемы;

Перем НомЛексемы, ТекЛексема;

Перем JSON_Error;

Перем В_Массив, В_Объект, В_Значение;

//*****

Перем НомерСимвола;

Перем ФлагОшибки;

Перем СписокСтроковыхКонстант;

Перем СтекЛексем;

Перем АнализируемаяСтрока;

//*****

Перем ТекКаталог, ТекФайл;

//*****

Функция ПолучитьОбъект_ТЗ() Далее

Функция ПолучитьМассив_ТЗ() Далее

//*****

Функция ТекущиеСимволы(Сколько)

	Возврат Сред(АнализируемаяСтрока, НомерСимвола, Сколько);

КонецФункции

//*****

Функция ПрошлыйСимвол(Сдвиг)

	Возврат Сред(АнализируемаяСтрока, НомерСимвола - Сдвиг, 1);

КонецФункции

//*****

Процедура ДобавитьЛексему(Лексема, Значение, Сдвиг)

	СтекЛексем.НоваяСтрока();

	СтекЛексем.Лексема	= Лексема;

	СтекЛексем.Значение	= Значение;	

	НомерСимвола		= НомерСимвола + Сдвиг;

КонецПроцедуры

//*****

Процедура ОбвестиОбласть(Обл)

	Обл.РамкаСнизу(1);

	Обл.РамкаСверху(1);

	Обл.РамкаСлева(1);

	Обл.РамкаСправа(1);

КонецПроцедуры

//*****

Процедура НапечататьТЗ(Таб, ТЗ, НомС, НомК)

Перем Тип, Обл1, НС, КС, Ключ, Зн, Обл2;

	Тип = ТЗ.ПолучитьЗначение(1, 1);

	НомС = НомС + 1;

	Обл1 = Таб.Область(НомС, НомК);

	ОбвестиОбласть(Обл1);

	Если Тип = В_Значение Тогда

		ТипЗн = ТЗ.ПолучитьЗначение(2, 1);

		Обл1.Текст = ТЗ.ПолучитьЗначение(2, 2);

		Обл1.ГоризонтальноеПоложение(1);

		Если ТипЗн = Л_Число Тогда

			Обл1.ГоризонтальноеПоложение(2);

		ИначеЕсли ТипЗн = Л_Константа Тогда

			Обл1.Полужирный(1);

		ИначеЕсли ТипЗн = Л_Строка Тогда

			Обл1.Контроль(4);

		КонецЕсли;

		Возврат;

	ИначеЕсли (Тип = В_Объект) Или (Тип = В_Массив) Тогда

		Обл1.Текст = Тип;

		Обл1.Полужирный(1);

		Обл1.ЦветФона(12648447);

		Обл1.РамкаСнизу(5);

		КС = ТЗ.КоличествоСтрок();

		Для НС = 2 По КС Цикл

			НомС = НомС + 1;

			Обл2 = Таб.Область(НомС, НомК);

			Обл2.Текст = ТЗ.ПолучитьЗначение(НС, 1);

			Если Тип = В_Массив Тогда

				Обл2.ГоризонтальноеПоложение(2);

			КонецЕсли;

			ОбвестиОбласть(Обл2);

			НомС = НомС - 1;

			НапечататьТЗ(Таб, ТЗ.ПолучитьЗначение(НС, 2), НомС, НомК + 1);

		КонецЦикла;

	Иначе

		Сообщить("Фигня " + Тип, "!");

	КонецЕсли;

КонецПроцедуры

//*****

Процедура ВыравнятьТЗ(Таб, ОграничениеШирины)

Перем НомерКол, НомерСтр, МаксШирина, Обл, ТекШирина, ТекДлина;

	Для НомерКол = 1 По Таб.ШиринаТаблицы() Цикл

		МаксШирина = 0;

		Для НомерСтр = 1 По Таб.ВысотаТаблицы() Цикл

			Обл = Таб.Область(НомерСтр, НомерКол);

			ТекШирина = Обл.ШиринаСтолбца();

			ТекДлина = СтрДлина(СокрЛП(Обл.Текст));

			МаксШирина = Макс(МаксШирина, ТекШирина, ТекДлина);

		КонецЦикла;

		Таб.Область(, НомерКол).ШиринаСтолбца(Мин(МаксШирина, ОграничениеШирины));

	КонецЦикла;

КонецПроцедуры

//*****

Процедура Напечатать_ТЗ(ТЗ)

Перем Таб, НС, НК, МаксШирина, ТекДлина, Обл;	

	Таб = СоздатьОбъект("Таблица");

	МаксНК = 1;

	НС = 0;

	НК = 1;

	НапечататьТЗ(Таб, ТЗ, НС, НК);

	ВыравнятьТЗ(Таб, 30);

	Таб.Область(1, 1, Таб.ВысотаТаблицы(), Таб.ШиринаТаблицы()).ВертикальноеПоложение(2);

	Таб.Опции(0, 0);

	Таб.Показать("JSON");

КонецПроцедуры

//*****

Функция Ошибка()

	ФлагОшибки = 1;

	Возврат 0;

КонецФункции

//*****

Функция ЧитатьКонстанту(ПервСимвол)

Перем КонстантаСтр, ДлинаКонстанты;	

	КонстантаСтр = СписокСтроковыхКонстант.Получить(ПервСимвол);

	ДлинаКонстанты = СтрДлина(КонстантаСтр);

	Если ТекущиеСимволы(ДлинаКонстанты) = КонстантаСтр Тогда

		ДобавитьЛексему(Л_Константа, КонстантаСтр, ДлинаКонстанты);

		Возврат 1;

	Иначе

		Возврат Ошибка();

	КонецЕсли;

КонецФункции

//*****

Процедура ДописатьСимвол(Стр)

	Стр = Стр + ТекущиеСимволы(1);

	НомерСимвола = НомерСимвола + 1;

КонецПроцедуры

//*****

Функция ЧитатьЧисло() 

Перем ЧислоСтр;

	ЧислоСтр = "";

	Если ТекущиеСимволы(1) = "-" Тогда

		ДописатьСимвол(ЧислоСтр);

	КонецЕсли;

	Если Найти(Цифры1_9, ТекущиеСимволы(1)) > 0 Тогда // не с нуля

		ДописатьСимвол(ЧислоСтр);

		Пока Найти(Цифры0_9, ТекущиеСимволы(1)) > 0 Цикл  // любые цыфры 

			ДописатьСимвол(ЧислоСтр);

		КонецЦикла;		

	ИначеЕсли ТекущиеСимволы(1) = "0" Тогда //с нуля - ничего дальше 

		ДописатьСимвол(ЧислоСтр);

	Иначе

		Возврат Ошибка();

	КонецЕсли;

	Если ТекущиеСимволы(1) = "." Тогда // десятичная точка

		ДописатьСимвол(ЧислоСтр);

		Пока Найти(Цифры0_9, ТекущиеСимволы(1)) > 0 Цикл  // любые цыфры

			ДописатьСимвол(ЧислоСтр);

		КонецЦикла;		

	КонецЕсли;

	Если ВРег(ТекущиеСимволы(1)) = "E" Тогда // значок e больное или маленькое

		ДописатьСимвол(ЧислоСтр);

		Если Найти("+-", ТекущиеСимволы(1)) > 0 Тогда  // унарный знак для порядка

			ДописатьСимвол(ЧислоСтр);

		КонецЕсли;

		Пока Найти(Цифры0_9, ТекущиеСимволы(1)) > 0 Цикл  // любые цыфры

			ДописатьСимвол(ЧислоСтр);

		КонецЦикла;		

	КонецЕсли;

	ДобавитьЛексему(Л_Число, ЧислоСтр, 0);

	Возврат 1;

КонецФункции

//*****

Функция ЧитатьСтроку()

Перем СтрокаСтр;

	СтрокаСтр = "";

	НомерСимвола = НомерСимвола + 1;

	Пока (ТекущиеСимволы(1) <> Л_Кавычка) Или ((ТекущиеСимволы(1) = Л_Кавычка) И (ПрошлыйСимвол(1) = Л_Экран) И (ПрошлыйСимвол(2) <> Л_Экран)) Цикл

		ДописатьСимвол(СтрокаСтр);

	КонецЦикла;

	ДобавитьЛексему(Л_Строка, СтрокаСтр, 1); 

	Возврат 1;

КонецФункции 

//*****

Функция ПрочитатьФайл(ИмяФайла)

Перем Т, НомерСтрокиФайла, СтрокаРез;

	Т = СоздатьОбъект("Текст");

	Т.Открыть(ИмяФайла);

	СтрокаРез = "";

	Для НомерСтрокиФайла = 1 По Т.КоличествоСтрок() Цикл

		СтрокаРез = СтрокаРез + Т.ПолучитьСтроку(НомерСтрокиФайла);

	КонецЦикла;

	Возврат СтрокаРез;

КонецФункции

//*****

Функция СледующаяЛексема()

	НомЛексемы = НомЛексемы + 1;

	СтекЛексем.ПолучитьСтрокуПоНомеру(НомЛексемы);

	ТекЛексема = СтекЛексем.Лексема;

	Возврат 1;

КонецФункции

//*****

Функция ОшибкаЛексемы()

Перем РезСтр, НомСтр, ТЛ, ТС;

	Сообщить("Ошибочная лексема № " + НомЛексемы + " : <" + ТекЛексема + ">", "!");

	РезСтр = "";

	Для НомСтр = НомЛексемы + 1 По СтекЛексем.КоличествоСтрок() Цикл

		СтекЛексем.ПолучитьСтрокуПоНомеру(НомСтр);

		ТЛ = СтекЛексем.Лексема;

		Если ТЛ = Л_Строка Тогда 

			ТС = "<" + ТЛ + "(" + СтекЛексем.Значение + ")>";

		ИначеЕсли ТЛ = Л_Константа Тогда

			ТС = "<" + ТЛ + "(" + СтекЛексем.Значение + ")>";

		Иначе

			ТС = "<" + ТЛ + ">";

		КонецЕсли;

		РезСтр = РезСтр + ТС + ",";

	КонецЦикла;

	Сообщить(Лев(РезСтр, 400), "!");

	Возврат 0;

КонецФункции

//*****

Процедура ДобавитьПару(ТЗ, Ключ, Значение)

	ТЗ.НоваяСтрока();

	ТЗ.Ключ		= Ключ;

	ТЗ.Значение	= Значение;

КонецПроцедуры

//*****

Функция НоваяТЗ(Тип)

Перем _ТЗ;

	_ТЗ = СоздатьОбъект("ТаблицаЗначений");

	_ТЗ.НоваяКолонка("Ключ");

	_ТЗ.НоваяКолонка("Значение");

	ДобавитьПару(_ТЗ, Тип, "");

	Возврат _ТЗ;

КонецФункции

//*****

Функция ПолучитьПроизвольноеЗначение_ТЗ()

Перем ТЗ;	

	Если (ТекЛексема = Л_Строка) Или (ТекЛексема = Л_Число) Или (ТекЛексема = Л_Константа) Тогда

		ТЗ = НоваяТЗ(В_Значение);

		ДобавитьПару(ТЗ, ТекЛексема, СтекЛексем.Значение);

		СледующаяЛексема();

		Возврат ТЗ;

	ИначеЕсли ТекЛексема = Л_Лев_Фиг_Скобка Тогда

		Возврат ПолучитьОбъект_ТЗ();

	ИначеЕсли ТекЛексема = Л_Лев_Кв_Скобка 	Тогда

		Возврат ПолучитьМассив_ТЗ();					

	КонецЕсли;

	Возврат ОшибкаЛексемы();

КонецФункции

//*****

Функция ДобавитьКлючЗначение(ТЗ)

Перем НовКлюч, НовЗначение;

	Если ТекЛексема <> Л_Строка Тогда

		Возврат 0;

	КонецЕсли;

	НовКлюч = СтекЛексем.Значение;

	СледующаяЛексема();

	Если ТекЛексема <> Л_Двоеточие Тогда

		Возврат ОшибкаЛексемы();

	КонецЕсли;

	СледующаяЛексема();

	НовЗначение = ПолучитьПроизвольноеЗначение_ТЗ();

	Если НовЗначение = 0 Тогда

		Возврат 0;

	КонецЕсли;

	ДобавитьПару(ТЗ, НовКлюч, НовЗначение);

	Возврат 1;

КонецФункции

//*****

Функция ПолучитьОбъект_ТЗ()

Перем ТЗ;

	ТЗ = НоваяТЗ(В_Объект);

	СледующаяЛексема();

	Если ТекЛексема = Л_Прав_Фиг_Скобка Тогда // пустой объект

		СледующаяЛексема();

		Возврат ТЗ;

	КонецЕсли;

	Если ДобавитьКлючЗначение(ТЗ) = 0 Тогда   // первая пара ключ-значение

		Возврат 0;

	КонецЕсли;	

	Пока ТекЛексема = Л_Запятая Цикл			// пока запятые

		СледующаяЛексема();

		Если ДобавитьКлючЗначение(ТЗ) = 0 Тогда	// пара ключ-значение

			Возврат 0;

		КонецЕсли;

	КонецЦикла;

	Если ТекЛексема = Л_Прав_Фиг_Скобка Тогда

		СледующаяЛексема();

		Возврат ТЗ;

	КонецЕсли;

	Возврат 0;

КонецФункции

//*****

Функция ПолучитьМассив_ТЗ()

Перем ТЗ, _Ключ, _Значение;

	ТЗ = НоваяТЗ(В_Массив);

	СледующаяЛексема();

	Если ТекЛексема = Л_Прав_Кв_Скобка Тогда

		СледующаяЛексема();

		Возврат ТЗ;

	КонецЕсли;

	_Значение = ПолучитьПроизвольноеЗначение_ТЗ();

	Если _Значение = 0 Тогда

		Возврат 0;

	КонецЕсли;

	_Ключ = 0; // JS - индексы массиворв с нуля

	ДобавитьПару(ТЗ, _Ключ, _Значение);	

	Пока ТекЛексема = Л_Запятая Цикл

		СледующаяЛексема();

		_Значение = ПолучитьПроизвольноеЗначение_ТЗ();

		Если _Значение = 0 Тогда

			Возврат 0;

		КонецЕсли;

		_Ключ = _Ключ + 1;

		ДобавитьПару(ТЗ, _Ключ, _Значение);

	КонецЦикла;

	Если ТекЛексема = Л_Прав_Кв_Скобка Тогда

		СледующаяЛексема();

		Возврат ТЗ;

	КонецЕсли;

	Возврат 0;

КонецФункции

//*****

Функция ПрочитатьОбъект_ТЗ()

Перем Рез;	

	НомЛексемы = 0;

	СледующаяЛексема();

	Если ТекЛексема = Л_Лев_Фиг_Скобка Тогда

		Рез = ПолучитьОбъект_ТЗ();

	ИначеЕсли ТекЛексема = Л_Лев_Кв_Скобка Тогда

		Рез = ПолучитьМассив_ТЗ();

	Иначе

		Рез = ПолучитьПроизвольноеЗначение_ТЗ();

	КонецЕсли;

	Если (Рез = 0) Или (ТекЛексема <> Л_Финиш) Тогда

		ОшибкаЛексемы();

		Возврат 0;

	КонецЕсли;

	Возврат Рез;	

КонецФункции

//*****

Функция СгенерироватьТЗ(НачАнализируемаяСтрока)

Перем НачальныйСимвол, Рез;

	АнализируемаяСтрока = НачАнализируемаяСтрока;

	СтекЛексем = СоздатьОбъект("ТаблицаЗначений");

	СтекЛексем.НоваяКолонка("Лексема" , "Строка");

	СтекЛексем.НоваяКолонка("Значение", "Строка");

	ФлагОшибки = 0;

	НомерСимвола = 1;

	Пока НомерСимвола <= СтрДлина(АнализируемаяСтрока) Цикл

		НачальныйСимвол = ТекущиеСимволы(1);

		Если Найти(" " + Симв(9), НачальныйСимвол) > 0 Тогда  // пробелы и разделители строк пропускаем

			НомерСимвола = НомерСимвола + 1;

		ИначеЕсли НачальныйСимвол = Л_Кавычка	Тогда // кавычка - читаем строку

			ЧитатьСтроку();

		ИначеЕсли Найти(ОдносимвольныеЛексемы, НачальныйСимвол) > 0 Тогда

			ДобавитьЛексему(НачальныйСимвол, "", 1);

		ИначеЕсли Найти(ПервыеСимволыКонстант, НачальныйСимвол) > 0 Тогда // первая буква из начала константы - константа null, true, false

			Если ЧитатьКонстанту(НачальныйСимвол) = 0 Тогда

				Прервать;

			КонецЕсли;

		ИначеЕсли Найти("-" + Цифры0_9, НачальныйСимвол) > 0 Тогда // число

			Если ЧитатьЧисло() = 0 Тогда

				Прервать;

			КонецЕсли;

		Иначе		// иных вариантов нет

			Сообщить("========= " + НомерСимвола, "!");

			Сообщить(НачальныйСимвол, "!");

			Сообщить("<" + НачальныйСимвол + "> " + КодСимв(НачальныйСимвол), "!");

			Сообщить(ТекущиеСимволы(100), "!");

			Возврат 0;

		КонецЕсли;

	КонецЦикла;

	Если ФлагОшибки <> 0 Тогда

		Сообщить("Ошибка парсинга JSON - выражения", "!");

		Возврат 0;

	ИначеЕсли СтекЛексем.КоличествоСтрок() = 0 Тогда

		Сообщить("Пустой стек", "!");

		Возврат 0;

	КонецЕсли;

	ДобавитьЛексему(Л_Финиш, "", 0);

	Возврат ПрочитатьОбъект_ТЗ();

КонецФункции

//*****

Функция JSON_Error(Стр = "")

	Если Стр <> "" Тогда

		Сообщить("JSON-ОШИБКА: " + Стр, "!");

	КонецЕсли;

	Возврат JSON_Error;

КонецФункции

//*****

Функция JSON_Type(Парам)

	Если ТипЗначенияСтр(Парам) <> "ТаблицаЗначений" Тогда

		Возврат JSON_Error();

	ИначеЕсли Парам.КоличествоКолонок() <> 2 Тогда

		Возврат JSON_Error();

	ИначеЕсли Парам.КоличествоСтрок() < 2 Тогда

		Возврат JSON_Error();

	КонецЕсли;

	Возврат Парам.ПолучитьЗначение(1, 1);

КонецФункции

//*****

Функция JSON_GetValue(Парам, Keys)

Перем Тип, До, После, ПозЗакр, Л1, П2, Инд, ИндСтр, НС, КвоСтрок;

	Тип = JSON_Type(Парам);

	ПозЗакр = Найти(Keys, "]");

	Если ПозЗакр = 0 Тогда

		ПозЗакр = СтрДлина(Keys) + 1;

	КонецЕсли;	

	До = Лев(Keys, ПозЗакр);

	После = Сред(Keys, ПозЗакр + 1);

	Л1 = Лев(До, 1);

	П2 = Найти(До, "]");

	Если Тип = JSON_Error Тогда

		Возврат JSON_Error("Параметра");

	КонецЕсли;

	КвоСтрок = Парам.КоличествоСтрок();

	Если До = "" Тогда // сам объект

		Если (Тип = В_Массив) Или (Тип = В_Объект) Тогда

			Возврат JSON_Error();

		ИначеЕсли Тип = В_Значение Тогда

			Возврат Парам.ПолучитьЗначение(2, 2);

		Иначе

			Возврат JSON_Error("№ 1");

		КонецЕсли;		

	ИначеЕсли До = ".length" Тогда // размер массива или объекта. Для значения - ошибка

		Если (Тип = В_Массив) Или (Тип = В_Объект) Тогда

			Возврат Парам.КоличествоСтрок() - 1;

		Иначе

			Возврат JSON_Error("Длина скаляра");

		КонецЕсли;

	ИначеЕсли Л1 = "[" Тогда // размер массива или объекта. Для значения - ошибка

		Если П2 = 0 Тогда

			Возврат JSON_Error("Индексация: <" + До + ">");

		КонецЕсли;

		Инд = Сред(До, 2, П2 - 2);

		Если (Найти("'""", Лев(Инд, 1)) > 0) И (Найти("'""", Прав(Инд, 1)) > 0) Тогда // строковый только объект

			ИндСтр = Сред(Инд, 2, СтрДлина(Инд) - 2);

			Если Тип <> В_Объект Тогда

				Возврат JSON_Error("Строковый индекс <" + ИндСтр + "> только для Объекта");

			КонецЕсли;

			НС = 0;

			Если Парам.НайтиЗначение(ИндСтр, НС, 1) = 1 Тогда

				Возврат JSON_GetValue(Парам.ПолучитьЗначение(НС, 2), После);

			КонецЕсли;

			Возврат JSON_Error("Нет индекса <" + ИндСтр + ">");

		КонецЕсли;

		ИндЧис = 0 + Инд;

		Если "" + ИндЧис <> Инд Тогда // защита от <5D>

			Возврат JSON_Error("Ошибка 1 числового индекса <" + Инд + ">");

		ИначеЕсли Цел(ИндЧис) <> ИндЧис Тогда // защита от неЦелого индекса

			Возврат JSON_Error("Ошибка 2 числового индекса <" + Инд + "> (нецелый)");

		ИначеЕсли ИндЧис < 0 Тогда

			Возврат JSON_Error("Ошибка 3 числового индекса <" + Инд + "> (отрицательный)");

		ИначеЕсли ИндЧис > (КвоСтрок - 2) Тогда

			Возврат JSON_Error("Ошибка 4 числового индекса <" + Инд + "> (" + ИндЧис + ">" + (КвоСтрок - 2) + ")");

		КонецЕсли;

		Возврат JSON_GetValue(Парам.ПолучитьЗначение(ИндЧис + 1, 2), После);

	Иначе

		Возврат JSON_Error("Ошибка 5 <" + До + ">");

	КонецЕсли;

КонецФункции

//*****

Процедура ПриОткрытии()

Перем Рез1, ТипУзла1, Зн1, Значение;	

	ОчиститьОкноСообщений();

	СтатусВозврата(0);

	Рез1 = СгенерироватьТЗ(ПрочитатьФайл(ТекКаталог + "j1.json"));

	Напечатать_ТЗ(Рез1);

	ТипУзла1 = JSON_Type(Рез1);

	Сообщить("Тип узла: " + ТипУзла1);

	Зн1 = JSON_GetValue(Рез1, ".length");									Сообщить("1) Размер: " 		+ Зн1);

	Зн3 = JSON_GetValue(Рез1, "['1']");										Сообщить("3) ['1']: <" 		+ Зн3 + ">");

	Зн4 = JSON_GetValue(Рез1, "[1]");										Сообщить("4) [1]: <" 		+ Зн4 + ">");

	Зн5 = JSON_GetValue(Рез1, "['Массив'][6]");								Сообщить("5) [*]: <" + Зн5 + ">");

	Зн6 = JSON_GetValue(Рез1, "['Соответствие']['ДопустимоеИмяСвойства']");	Сообщить("6) [*]: <" + Зн6 + ">");

КонецПроцедуры

//*****

Процедура ДобавитьСтроковуюКонстанту(КонстантаСтр)

Перем ПервыйСимвол;	

	ПервыйСимвол = Лев(КонстантаСтр, 1);

	ПервыеСимволыКонстант = ПервыеСимволыКонстант + ПервыйСимвол;

	СписокСтроковыхКонстант.Установить(ПервыйСимвол, КонстантаСтр);

КонецПроцедуры

//*****

РасположениеФайла(ТекКаталог, ТекФайл);

//*****

Л_Лев_Фиг_Скобка	= "{";

Л_Прав_Фиг_Скобка	= "}";

Л_Лев_Кв_Скобка		= "["; 

Л_Прав_Кв_Скобка	= "]";

Л_Двоеточие			= ":";

Л_Запятая			= ",";

Л_Экран				= "\";

Л_Кавычка			= """";

Л_Финиш				= "";

Л_Число				= "number";

Л_Строка			= "string";

Л_Константа			= "const";

ОдносимвольныеЛексемы = Л_Лев_Фиг_Скобка + Л_Прав_Фиг_Скобка + Л_Лев_Кв_Скобка + Л_Прав_Кв_Скобка + Л_Двоеточие + Л_Запятая;

//*****

Цифры1_9 = "123456789";

Цифры0_9 = "0" + Цифры1_9;

//*****

В_Массив   = "###array";

В_Объект   = "###object";

В_Значение = "###value";

//*****

СписокСтроковыхКонстант	= СоздатьОбъект("СписокЗначений");

ПервыеСимволыКонстант	= "";

ДобавитьСтроковуюКонстанту("null");

ДобавитьСтроковуюКонстанту("false");

ДобавитьСтроковуюКонстанту("true");

JSON_Error = "ERROR";

В качестве примера взят файл j1.json :

{

"999": 88,

"Null": null,

"Сэкраном": "\"",

"Ложь": false,

"ОдинСимв": "1",

"1": "11111",

"Пустышка": "",

"Истина": true,

"Число (плавающая точка)": 1.001e-2,

"Число (плавающая)": -1.001e-2,

"Число (фиксированная точка)": -1000.001,

"Дата": "2011-01-01T12:00:00Z",

"Строка (двойная кавычка)": "Двойная кавычка",

"Строка (одинарная кавычка)": "Одинарная кавычка",

"Маскируемые символы": " \\ \/ \b \t \n \f \r \" ",

"Заковыристая строка": "\\n\\",

"Проблемные символы": "Спец. символы: \u0000, \u0001, \u0002, ... , \u001e, \u001f; Юникод символы: \u0421\u0430\u0448\u0430\u0020\u003a\u0029",

"Кириллические символы": "’АБВГҐДЂЃЕ?ЁЄЖЗЅИ?ІЇЙЈКЛЉМНЊОПРСТЋЌУЎФХЦЧЏШЩЪЫЬЭЮЯ",

"Идентификатор": "a763cfbb-f94f-4c67-8e13-0e96a3a7f353",

"Пустой массив": [],

"Пустой объект": {},

"Массив": [

null,

false,

true,

1.001e-2,

-1000.001,

"2011-01-01T12:00:00Z",

"Двойная кавычка",

"Одинарная кавычка",

"a763cfbb-f94f-4c67-8e13-0e96a3a7f353",

[

"Первый элемент",

"Второй элемент"

{

"Имя": "Александр",

"Отчество": "Владимирович",

"Фамилия": "Переверзев"

{

"ДопустимоеИмяСвойства": true,

"Недопустимое Имя Свойства": false

}

"Структура":

{

"Имя": "Александр",

"Отчество": "Владимирович",

"Фамилия": "Переверзев"

"Соответствие":

{

"ДопустимоеИмяСвойства": true,

"Недопустимое Имя Свойства": false

"Ссылка":

{

"Ссылка": "00000000-0000-0000-0000-000000000000",

"Представление": "Неизвестная ссылка"

"COMSafeArray": [

]

}

Категория: HTML, JS, VML

Программно открыть Предварительный просмотр. Программно открыть Параметры страницы

Код 1C v 8.х

 	

Shell = Новый COMОбъект("WScript.Shell");

Shell.SendKeys("%+A+H)"); //имитируем нажатие Alt+Ф+Р Предварительный просмотр

Shell.SendKeys("%фр");      //имитируем нажатие Alt+Ф+Р   Предварительный просмотр

Shell.SendKeys("%фм");    //Параметры страницы

////· "Shift" - +;

////· "Ctrl" - ^;

////· "Alt" - %.

Категория: Прочие вопросы

Динамический список ~ Как программно выделить все строки динамического списка?

В платформе “1с предприятие 8.2″ появился такой замечательный объект как “динамический список“. Данный объект я часто использую в подборах, если не нужно делать сложные расчеты, а просто показать данные и выбрать.

Бывают такие ситуации, что список большой, более 10 позиций, и пользователю необходимо выбрать все строки. Стандартного способа как это сделать я не нашел.

Для решения это задачи я использовал объект “WSCript.Shell“.

В процессе реализации у меня получилось 2 варианта:
Вариант №1
Определим кнопку “Выделить все строки” и в модуль обработчика добавим код:

Код 1C v 8.2 УП

 wsh = Новый COMОбъект(“WSCript.Shell”);

ЭтаФорма.ТекущийЭлемент = Элементы.ДинамическийСписок;

wsh.sendkeys(“^{A}”);

С помощью данного кода выполняется нажатие клавиш “Ctrl + A“, т.е. “выделить все”.

Вариант №2
Вариант №1 не всегда срабатывал. Тогда данный код я переписал следующим образом:

Добавим реквизит формы “ПоследняяСтрокаСписка”
Для списка укажем свойство “Начальное отображение списка” = В конце списка
В процедуру “ПриОткрытии” добавим заполнение реквизита, определенного в пункте 1.

Код 1C v 8.2 УП

 ПоследняяСтрокаСписка = Элементы.ДинамическийСписок.ВыделенныеСтроки[0];

Определим кнопку “Выделить все строки” и в модуль обработчика добавим код:

Код 1C v 8.2 УП

 wsh = Новый COMОбъект(“WSCript.Shell”);

ЭтаФорма.ТекущийЭлемент = Элементы.ДинамическийСписок;

wsh.sendkeys(“{END}”);

ТекДанные = Элементы.ДинамическийСписок.ТекущиеДанные;

Если ТекДанные <> Неопределено Тогда

  wsh.sendkeys(“+{UP ” + ПоследняяСтрокаСписка + “}”);

КонецЕсли;

С помощью данного кода выполняется нажатие клавиш “Shift + кнопка вверх“.

Хочу обратить внимание. Данное решение не будет работать на клиентах, которые запускаются на Линукс.

Автор Сергей Сопелев

Категория: Работа с Формой (Диалог) и её элементами

Имитация (программное) нажатия Клавиш

В системе "1С:Предприятие" часто возникает ситуация, когда нужно закрыть окно сообщений, появляющееся при вызове метода Сообщить. Стандартно это окно закрывается при нажатии комбинации клавиш <Ctrl>+<Shift>+<Z>, но можно сделать это и программно.

Код 1C v 8.х

 //В ходе выполнения некоторого кода открывается окно сообщений 

Сообщить("Сегодня: " +ТекущаяДата());



//Выполнение другой части кода



//Теперь нам необходимо закрыть окно сообщений

Wsh = Новый СОМОбъект("Wscript.shell");

//Wsh - переменная. Можно было дать любое другое имя, например Окно

Wsh.SendKeys("^+z");   //имитируем нажатие Ctrl+Z

Wsh.SendKeys("^+я");   //для случая, если текущей является русская раскладка клавиатуры

В результате выполнения данного кода окно сообщений будет закрыто. Теперь поясним работу этого небольшого куска программы. SendKeys(String) - имитируется нажатие клавиши или последовательности клавиш, указанных в параметре String. В качестве параметра можно указывать как алфавитно-цифровые символы, так и символы специальных клавиш, например "Enter", "Tab", "F1", "Alt", "Shift", "Ctrl" и т.д. Для указания клавиш "Alt", "Shift", "Ctrl" существуют специальные коды:
· "Shift" - +;
· "Ctrl" - ^;
· "Alt" - %.
Если возникнет необходимость передать специальные символы именно как символы, а не команды, нужно заключать их в фигурные скобки, например {+}.

Категория: COM-объекты, WMI, WSH

Работа с буфером обмена средствами 1С

Копировать из 1С в буфер обмена( без ВК):

Код 1C v 8.х

 ЭлементыФормы.Добавить(Тип("ПолеHTMLДокумента"), "Поле_HTML_Документа_acb123", Ложь);

Окно = ЭлементыФормы.Поле_HTML_Документа_acb123.Документ.ParentWindow;

Окно.ClipboardData.SetData("Text", ТекстПисьма);

ЭлементыФормы.Удалить(ЭлементыФормы.Индекс(ЭлементыФормы.Найти("Поле_HTML_Документа_acb123")));

Вставить в 1С из буфера обмена:

Код 1C v 8.х

 ЭлементыФормы.Добавить(Тип("ПолеHTMLДокумента"), "Поле_HTML_Документа_acb123", Ложь);

Окно = ЭлементыФормы.Поле_HTML_Документа_acb123.Документ.ParentWindow;

СодержимоеБуфера = Окно.ClipboardData.GetData("Text");

ЭлементыФормы.Удалить(ЭлементыФормы.Индекс(ЭлементыФормы.Найти("Поле_HTML_Документа_acb123")));

ТекстПисьма = ТекстПисьма + СодержимоеБуфера;

При определенных настройках политики безопасности, способ с ПолеHTMLДокумента НЕ работает, используйте:

Код 1C v 8.х

 

Функция ПолучитьТекстБуфераОбмена() Экспорт

#Если Клиент Тогда

    Объект = Новый COMОбъект("htmlfile");

    Возврат Объект.ParentWindow.ClipboardData.Getdata("Text");

#КонецЕсли

КонецФункции

 

Функция УстановитьТекстВБуферОбмена(Текст) Экспорт

#Если Клиент Тогда 

    Объект = Новый COMОбъект("htmlfile");

    Объект.ParentWindow.ClipboardData.Setdata("Text", Текст);

    Возврат Текст;

#КонецЕсли 

КонецФункции

Для 7.7:

Код 1C v 7.x

 Set objHTM = CreateObject("htmlfile");

Текст = "Помощь в 1С";

objHTM.ParentWindow.ClipboardData.Setdata("Text", Текст);

Текст = objHTM.ParentWindow.ClipboardData.GetData("text");

Используя WSH:

Код 1C v 8.х

  // через SendKeys передаем Ctrl-C и Ctrl-V    

wsh=Новый COMОбъект("WScript.Shell");    

// Скопировать текст     

wsh.SendKeys("^c");      

// Вставить текст  

wsh.SendKeys("^v");

Код 1C v 7.x

  // через SendKeys передаем Ctrl-C и Ctrl-V    

wsh=СоздатьОбъект("WScript.Shell"); 

// Скопировать текст     

wsh.SendKeys("^c");  // или так:  wsh.SendKeys("^(C)");          

// Вставить текст  

wsh.SendKeys("^v");  // или так:  wsh.SendKeys("^(V)");  



//Объект Clipboard

WshExtra = СоздатьОбъект("WshExtra.Clipboard");  

// Скопировать текст   

WshExtra.Copy("Запись в буфер обмена")

// Вставить текст 

Текст = WshExtra.Paste();

Категория: Полезные, Универсальные Функции

Как в 1С автоматически переключать раскладку клавиатуры?

Для этого можно использовать функционал следующих внешних компонент:
1. FormEx смотрите тут.

Код 1C v 7.x

 Сервис=СоздатьОбъект("Сервис");

Сервис.РаскладкаКлавиатуры("Russian");

2. Miracle смотрите тут.

3. NetaTable смотрите тут.

Код 1C v 7.x

   Если (ЗагрузитьВнешнююКомпоненту("NetaTable.dll")=1) Тогда

    РовнаяТаблица=СоздатьОбъект("AddIn.NTable");

  Иначе

    Предупреждение("Внешняя компонента AddIn.NetaTable НЕ подключена!!!"+РазделительСтрок+"Работа программы невозможна!!!");

    СтатусВозврата(0);

    Возврат

  КонецЕсли;

Процедура ПриНачалеВыбораЗначения(ИдентЭлемента,ФлагОтбора)

  Если ИдентЭлемента = "Диагноз" Тогда

    РовнаяТаблица.УстановитьРаскладку(67699721);

  ИначеЕсли ИдентЭлемента = "ИсточникФинансирования" Тогда

    РовнаяТаблица.УстановитьРаскладку(68748313);

  КонецЕсли;

КонецПроцедуры

А можно и без внешних компонент:

Код 1C v 7.x

  //примеры Sserj

Процедура СменитьРаскладку(Реж)

    //Можно и просто через wrapper.dll

    //Wrapper = CreateObject("DynamicWrapper"); 

    //Wrapper.Register("USER32.DLL", "ActivateKeyboardLayout", "i=ll", "f=s", "r=l"); 

    //Wrapper.Register("USER32.DLL", "LoadKeyboardLayout", "i=sl", "f=s", "r=l"); 

    //rus = Wrapper.LoadKeyboardLayout("00000419", 0); 

    //eng = Wrapper.LoadKeyboardLayout("00000409", 0); 

    //Если Реж = "RUS" Тогда 

    //    Wrapper.ActivateKeyboardLayout(rus, 0); 

    //ИначеЕсли Реж = "EN" Тогда 

    //    Wrapper.ActivateKeyboardLayout(eng , 0); 

    //КонецЕсли; 

    Если Не (Константа.ВключатьНамЛоокВТелефонах = Истина) Тогда

        Возврат;

    КонецЕсли;

    wshShell=createObject("wScript.shell");

    Если Реж = "RUS" Тогда

        wshShell.SendKeys("^(8)",0);

    ИначеЕсли Реж = "EN" Тогда

        wshShell.SendKeys("^(9)",0);

    КонецЕсли;

КонецПроцедуры // СменитьРаскладку(Реж)



//ЕЩЕ



  //Обновляем хоткеи смены языков, для подмены в полях где нужна английская раскладка 

        текст = СоздатьОбъект("текст");

        текст.ДобавитьСтроку("Windows Registry Editor Version 5.00");

        текст.ДобавитьСтроку("");

        текст.ДобавитьСтроку("[HKEY_CURRENT_USER\Control Panel\Input Method\Hot Keys\00000100]");

        текст.ДобавитьСтроку("""Virtual Key""=hex:39,00,00,00");

        текст.ДобавитьСтроку("""Key Modifiers""=hex:02,c0,00,00");

        текст.ДобавитьСтроку("""Target IME""=hex:09,04,09,04");

        текст.ДобавитьСтроку("");

        текст.ДобавитьСтроку("[HKEY_CURRENT_USER\Control Panel\Input Method\Hot Keys\00000101]");

        текст.ДобавитьСтроку("""Virtual Key""=hex:38,00,00,00");

        текст.ДобавитьСтроку("""Key Modifiers""=hex:02,c0,00,00");

        текст.ДобавитьСтроку("""Target IME""=hex:19,04,19,04");

        ИмяФайла = КаталогИБ() + "LangHotKey.reg";

        Попытка

            текст.Записать(ИмяФайла);

            wshShell=createObject("wScript.shell");

            StrComand = "regedit /S " + СокрЛП(ИмяФайла);

            wshShell.Run(StrComand,1);

            //Задерживаемся, иначе скрипт не успевает прочитать файл 

            Для Сч=1 По 50000 Цикл

            КонецЦикла;

            ФС.УдалитьФайл(ИмяФайла);

        Исключение

        КонецПопытки;

Категория: Полезные, Универсальные Функции

Кнопка ~ Как программно нажать кнопку на форме ?

Вопрос:
На готовой форме есть кнопки : <OK> <ЗАПИСАТЬ> <ОТМЕНА>
Как программно нажать например кнопку <OK> ?

Ответ:
Нужно программно вызвать процедуру этой кнопки.
Например: Записать(); , Закрыть(); или ЗаписатьВФОРМЕ();
Смотрите синтаксис-помощник 1С

Если эта кнопка по умолчанию, то

Код 1C v 8.х

 Shell = Новый COMОбъект("WScript.Shell");

Shell.SendKeys("{ENTER}");

Категория: Работа с Формой (Диалог) и её элементами

Использование программы rundll32.exe в 1С

Программа rundll32.exe входит в стандартную поставку всех операционных систем семейства Windows и позволяет выполнять различные функции, описанные в библиотеках, драйверах или ActiveX-объектах, как будто они выполняются из программы. Также эта программа входит в состав новой операционной системы Windows Vista, поэтому обзор новой операционной системы, предназначенный для опытных пользователей, никак нельзя назвать законченным, если он не будет содержать описание команд rundll32.exe, доступных в Windows Vista.

Синтаксис использования программы rundll32.exe следующий: rundll32.exe «библиотека», «функция» «параметры». При этом очень важно понимать, что название функции, хранящейся в библиотеке, зависит от регистра, которым вы ее написали. То есть, например, функции MessageBox и messageBox, в понимании программы rundll32.exe, являются различными функциями, поэтому если в названии функции вы напишете вместо прописной буквы строчную, программа rundll32.exe выдаст ошибку. Название же самой программы rundll32.exe и название библиотеки можно указывать как строчными, так и прописными символами.

Пример:

Код 1C v 8.х

 //Emigachev Проверим дату на компе

	Если ТекущаяДата()<Дата(2009,1,1) Тогда 

		Предупреждение("Установите правильную дату!");

		//Открыть диалог установки Даты и Времени

		ЗапуститьПриложение("rundll32 shell32,Control_RunDLL timedate.cpl");

	КонецЕсли;

Приведу список наиболее значимых команд (в котором найдете ОЧЕНЬ интересные команды, ну а как их использовать, думайте сами!):
* rundll32 shell32.dll,Control_RunDLL hotplug.dll - диалоговое окно Отключение или извлечение аппаратного устройства
* rundll32 diskcopy,DiskCopyRunDll - вызов диалога "Копирование диска".
* rundll32 keyboard,disable - отключение клавиатуры, действует до следующей перезагрузки.
* rundll32 mouse,disable - отключение мыши вплоть до перезагрузки.
* rundll32 krnl386.exe,exitkernel - выгрузить ядро системы, выход из Windows.
* rundll32 mshtml.dll,PrintHTML "HtmlFileNameAndPath" - распечатать документ HTML, где "HtmlFileNameAndPath" - путь к файлу и его имя.
* rundll32 мсprint2.dll,RUNDLL_PrintTestPage - распечатать тестовую страницу на принтере.
* rundll32 netplwiz.dll,AddNetPlaceRunDll - вызов мастера подключения нового сетевого ресурса "Добавление в сетевое окружение".
* rundll32 rnaui.dll,RnaWizard - вызов мастера "Удаленный доступ к сети".
* rundll32 rnaui.dll,RnaWizard /1 - вызов мастера "Удаленный доступ к сети" без отображения начального окна.
* rundll32 shell,ShellExecute - открыть Проводник (папка "Рабочий стол").
* rundll32 shell32,Control_RunDLL - открыть в Проводнике папку "Панель управления".
* rundll32 shell32,Control_RunDLL appwiz.cpl,,n - вызов диалогового окна "Установка и удаление программ", в котором будет открыта вкладка с номером "n" (от 1 до 3).
* rundll32 shell32,Control_RunDLL main.cpl @0 - открыть диалог "Свойства мыши".
* rundll32 shell32,Control_RunDLL main.cpl @1 - открыть диалог "Свойства клавиатуры".
* rundll32 shell32,Control_RunDLL main.cpl @2 - открыть папку "Принтеры".
* rundll32 SHELL32,SHHelpShortcuts_RunDLL PrintersFolder - открыть папку "Принтеры" (другой способ).
* rundll32 shell32,Control_RunDLL main.cpl @3 - открыть папку "Шрифты".
* rundll32 SHELL32,SHHelpShortcuts_RunDLL FontsFolder - открыть папку "Шрифты" (другой способ).
* rundll32 SHELL32,Control_RunDLL modem.cpl, add - открыть диалог "Свойства модема".
* rundll32 shell32,Control_RunDLL timedate.cpl - открыть диалог "Дата и время".
* rundll32 shell32,OpenAs_RunDLL - вызвать диалог "Открыть с помощью...".
* rundll32 shell32,ShellAboutA WINHOWTO.RU - информация о версии Windows.
* rundll32 shell32,SHExitWindowsEx 0 - закрыть все программы, перегрузить оболочку.
* rundll32 shell32, SHExitWindowsEx 1 - выключить ПК.
* rundll32 SHELL32, SHExitWindowsEx -1 - перегрузить оболочку Windows.
* rundll32 shell32, SHExitWindowsEx 2 - перегрузить ПК.
* rundll32 shell32,SHExitWindowsEx 4 - принудительно закрыть все программы.
* rundll32 shell32,SHExitWindowsEx 8 - выход из Windows и выключение ATX-совместимого ПК.
* rundll32 shell32,SHFormatDrive - вызов диалога форматирования диска А:.
* rundll32 SHELL32,SHHelpShortcuts_RunDLL AddPrinter - запуск "Мастера установки принтера".
* rundll32 shell32,SHHelpShortcuts_RunDLL Connect - запуск мастера подключения сетевого диска.
* rundll32 SHELL32,SHHelpShortcuts_RunDLL PrintTestPage - распечатать тестовую страницу.
* rundll32 sysdm.cpl,InstallDevice_Rundll - вызов мастера установки оборудования.
* rundll32 url.dll,FileProtocolHandler %1 - открыть веб-страницу, где %1 - URL сайта (включая http://).
* rundll32 url.dll,MailToProtocolHandler %1 - создать новое письмо, где %1 - e-mail адресата.
* rundll32 user,CASCADECHILDWINDOWS - расположить все окна каскадом.
* rundll32 user,TILECHILDWINDOWS - расположить все окна по экрану.
* rundll32 user,disableoemlayer - сбой системы (!) - выключить все функции ввода-вывода
(клавиатура, дисплей, мышь). В результате будет черный экран с курсором и ни на что не реагирующая система, однако Windows продолжает работать.
* rundll32 user,ExitWindowsExec - быстрая перезагрузка Windows.
* rundll32 user,RepaintScreen - выполнить команду "Обновить".
* rundll32 user,SetCaretBlinkTime n - задать частоту мигания курсора, соответствующую значению параметра n.
* rundll32 user,SetCursorPos - переместить курсор мыши в верхний левый угол экрана.
* rundll32 user,SetDoubleClickTime n - задать скорость двойного нажатия левой кнопки мыши (Double Click), соответствующую параметру n.
* rundll32 user,SwapMouseButton - поменять местами клавиши мыши (обратная смена невозможна).
* rundll32 user,WNetConnectDialog - вызов диалога "Подключение сетевого диска".
* rundll32 user,WNetDisconnectDialog - вызов диалога "Отключение сетевого диска".
* rundll32 AppWiz.Cpl,NewLinkHere %1 - запуск мастера создания нового ярлыка, где %1 - путь к исходному файлу.
* rundll32.exe shell32.dll, SHHelpShortcuts_RunDLL Connect. Вызвать мастер подключения сетевых дисков.
* rundll32.exe shell32.dll, ShellAboutA. Вызвать диалог, отображающий версию операционной системы Windows. Также данный диалог можно отобразить, выполнив команду winver.exe.
* rundll32.exe IEAKENG.dll, BrowseForFileA. Отображает дерево файловой системы жесткого диска компьютера.
* rundll32.exe ndfapi.dll, NdfRunDllHelpTopic «html-страница». Вызвать диалог HELP AND SUPPORT на указанной странице. Например, в качестве html-страницы можно использовать вызов mshelp://Windows/?id=33307acf-0698-41ba-b014-ea0a2eb8d0a8.
* rundll32.exe shell32.dll, OpenAs_RunDLL "путь и имя файла". Вызвать диалог OPEN AS… для открытия данного файла.
* rundll32.exe shell32.dll, Control_RunDLL Cliconfg.dll. Отображает диалог SQL Server Client Network Utility.
* rundll32.exe shell32.dll, Control_RunDLL Hotplug.dll. Отображает диалог удаления съемного устройства.
* rundll32.exe admparse.dll, CheckDuplicateKeysA "путь и имя файла". Переписывает содержимое данного файла.
* rundll32.exe IEAKENG.dll, BToolbar_SaveA "путь к папке". Создает папку. Если данная папка уже существует, тогда все ее содержимое будет удалено.
* rundll32.exe appwiz.cpl, GetProgramsOnline. Запускает браузер Internet Explorer и загружает страницу http://g.msn.com/WMHFUSEN/101724.
* rundll32.exe shell32.dll, ShellExec_RunDLL "команда". Выполняет команду.
* rundll32.exe url.dll, FileProtocolHandler "каталог". Открыть папку. Если вы не укажете папки, тогда будет открыта папка вашего профиля.
* rundll32.exe WININET.dll, RunOnceUrlCache "путь к папке". Удаляет все файлы указанной папки, имеющие атрибут FILEATTRIBUTETAGINFORMATION.
* rundll32.exe xwizards.dll, ProcessXMLFile "путь и имя xml-файла". Выполнить xml-файл.
* rundll32.exe user32.dll, mouse_event. Выполнить нажатие правой клавиши мыши.
* rundll32.exe user32.dll, SetCursorPos. Установить курсор в правый нижний угол экрана.
* rundll32.exe dfshim.dll, KillService. Остановить работу службы фонового обновления dfsvc.exe
* rundll32.exe IERNONCE.dll, RunOnceExProcess. Выполняет команды, описанные в ветви реестра HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx (или в ветви корневого раздела HKCU).

Категория: COM-объекты, WMI, WSH

Запись СД из 1С(без ВК и других программ, проверено на ХР/2003)

Код 1C v 7.x

 

Процедура Сформировать(ДискДляЗаписи="E:\",АвтоИзвлечениеСД=0,АвтоЗакрытиеМастера=1)

    Перем Имя,Каталог;

    scr=СоздатьОбъект("MSScriptControl.ScriptControl");

    scr.language="javascript";

    shell=СоздатьОбъект("Shell.Application");

    scr.AddObject("Shell",shell);

    ИмяСлужбы="ImapiService";

    Если Shell.CanStartStopService(ИмяСлужбы)=0 Тогда

        Предупреждение("Вам недозволено записывать диски СД!",5);

        Возврат;

    КонецЕсли;

    scr.Eval("Shell.ServiceStart('"+ИмяСлужбы+"',true)");

    РасположениеФайла(Каталог,Имя);

    Если ФС.ВыбратьФайл(0,Имя,Каталог,"Выбирите файл для записи","Все файлы|*.*","*")=0 Тогда

        Возврат;

    КонецЕсли;

    fso=СоздатьОбъект("Scripting.FileSystemObject");

    wshshell=СоздатьОбъект("WScript.Shell");

    КаталогДляЗаписи=wshshell.regread("HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders\CD Burning");

    fso.CopyFile(Каталог+Имя,КаталогДляЗаписи+"\"+Имя,-1);

    ДискДляЗаписиNS=shell.NameSpace(ДискДляЗаписи);

    wshshell.regwrite("HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\CD Burning\Auto Eject",АвтоИзвлечениеСД,"REG_DWORD");

    wshshell.regwrite("HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\CD Burning\Auto Close",АвтоЗакрытиеМастера,"REG_DWORD");

    scr.AddObject("Verbs",ДискДляЗаписиNS.items().item().verbs());

    e=scr.Eval("new Enumerator(Verbs)");

    Пока e.atEnd(0)=0 Цикл

        Если Найти(Нрег(e.item(0).name),"записать файлы на компакт-диск")>0 Тогда

            e.item(0).doit();

            Пока wshshell.appactivate("Мастер записи компакт-дисков")=0 Цикл

            КонецЦикла;

            wshshell.sendkeys("{ENTER}")

        КонецЕсли;

        e.moveNext(0);

    КонецЦикла;

    Пока wshshell.appactivate("Мастер записи компакт-дисков")=-1 Цикл

        ВвестиСтроку("","Пауза",1,0,1);

    КонецЦикла;

КонецПроцедуры

Конечно метод дубовенький, расчитан тока на русскую версию, но можно и допеределать.
Не стал писать код определения пишущего сидирома и возможности записи (хотя на отсутствие диска или невозможность записать ОС сама укажет)...
Автор: smaharbA

А через Nero можно записать так:

Код DOS Batch File

 

"C:\Program Files\Ahead\Nero\NeroCmd.exe" --no_user_interaction --write --real --iso Archive_1C --drivename M --force_erase_cdrw --dvd --dvd_high_compatibility --close_session --verify E:\Full_Archive_1C\*.* >H:\BackUp\Log\write.log

Категория: Полезные, Универсальные Функции

Скрипт запуска 1С:Предприятия от имени Администратора или Пользователя

Данные пример для 7.7, для 8-ых версий указать путь к 1Сv8.exe

Код VBS

 

Dim WshShell, ObjFSO 

Set WshShell = CreateObject("WScript.Shell")  

set objFSO = CreateObject("Scripting.FileSystemObject")  

 

appl="C:\1Cv7\BINOP\1CV7s.exe"  

users="DomenKompanii\emigachev"  

Set objWMIService = GetObject _  

      ("winmgmts:\\.\root\cimv2:Win32_Process")  

      errReturn = objWMIService.Create _  

("cmd.exe /K ""title RUNAS_AUTO & runas.exe /user:" & users & " """ & appl  & """""", Null, Null, intProcessID)  

wscript.Sleep(1000)  

wshShell.AppActivate "RUNAS_AUTO"

function WriteWord() 

WshShell.SendKeys "P@ssw0rd"

end function

wscript.Sleep(1000)  

wshShell.SendKeys "{ENTER}"

или так:

Код VBS

 

Set WshShell = CreateObject("Wscript.Shell")

Set WshEnv = WshShell.Environment("PRocess")

WshShell.Run "runas.exe /user:DomenKompanii\emigachev C:\WD\1Cv7\BINOP\1CV7s.exe" 

Wscript.Sleep 800

WshShell.AppActivate WshEnv("SystemRoot") & "\system32\runas.exe"

Wscript.Sleep 200

WshShell.SendKeys "P@ssw0rd"

Wscript.Sleep 500

Категория: Администрирование