Процедура ДействияФормыВыгрузка(Кнопка)

//Выберем файл для сохранения выгрузки

Диалог = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Сохранение);

Диалог.Заголовок = "Выберите файл для сохранения данных";

Диалог.ПолноеИмяФайла = "NDFL_"+Формат(НачПериода,"ДФ=MM_yyyy");

Диалог.Фильтр = "TXT (*.txt)|*.txt";

Диалог.МножественныйВыбор = Ложь; Диалог.Каталог = "D:\";

Если Диалог.Выбрать() Тогда 

	ФайлСохранения = Диалог.ПолноеИмяФайла; 

	//Выгрузим результат отчета СКД в Таблицу Значений	

	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;

	МакетКомпоновкиДанных = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки, , , Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));

	ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных; 

	ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновкиДанных);

	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;

	ДанныеТЗ = Новый ТаблицаЗначений;

	ПроцессорВывода.УстановитьОбъект(ДанныеТЗ);

	ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);

	

	//Выгрузим данные из Таблицы значений в Файл, запись данных в файл построчно

	Текст = Новый ЗаписьТекста(ФайлСохранения, КодировкаТекста.ANSI);

	Текст.ЗаписатьСтроку("Организация~КПП~Начислено13~Начислено30");

	Для Каждого стр из ДанныеТЗ Цикл

		Текст.ЗаписатьСтроку(СокрЛП(Строка(стр.Организация))+"~"+СокрЛП(стр.ПодразделениеОрганизацииКПП)+"~"+Формат(стр.Начислено13,"ЧГ=0")+"~"+Формат(стр.Начислено30,"ЧГ=0"));

	КонецЦикла;

	Текст.Закрыть();

КонецЕсли;

КонецПроцедуры



Процедура ВыбПериодНажатие(Элемент)

	НастройкаПериода = Новый НастройкаПериода;

	НастройкаПериода.УстановитьПериод(НачПериода, ?(КонПериода='0001-01-01', КонПериода, КонецДня(КонПериода)));

	НастройкаПериода.РедактироватьКакИнтервал = Истина;

	НастройкаПериода.РедактироватьКакПериод = Истина;

	НастройкаПериода.ВариантНастройки = ВариантНастройкиПериода.Период;

	Если НастройкаПериода.Редактировать() Тогда

		НачПериода = НастройкаПериода.ПолучитьДатуНачала();

		КонПериода = НастройкаПериода.ПолучитьДатуОкончания();

	КонецЕсли;

	// установить парметры периода для отчета СКД

	КомпоновщикНастроек.Настройки.ПараметрыДанных.Элементы[4].Значение = НачПериода;

	КомпоновщикНастроек.Настройки.ПараметрыДанных.Элементы[5].Значение = КонПериода;

КонецПроцедуры   

 //  Получим суммы начисленные по ФизЛицу документом НачислениеЗарплатыРаботникамОрганизаций

// (отбор по Документ.НачислениеЗарплатыРаботникамОрганизаций)

Запрос=новый Запрос;

Запрос.Текст="

|ВЫБРАТЬ

|	ВзаиморасчетыСРаботникамиОрганизаций.Период,

|	ВзаиморасчетыСРаботникамиОрганизаций.Регистратор,

|	ВзаиморасчетыСРаботникамиОрганизаций.НомерСтроки,

|	ВзаиморасчетыСРаботникамиОрганизаций.Активность,

|	ВзаиморасчетыСРаботникамиОрганизаций.ВидДвижения,

|	ВзаиморасчетыСРаботникамиОрганизаций.Физлицо,

|	ВзаиморасчетыСРаботникамиОрганизаций.Организация,

|	ВзаиморасчетыСРаботникамиОрганизаций.ПериодВзаиморасчетов,

|	ВзаиморасчетыСРаботникамиОрганизаций.СуммаВзаиморасчетов, 

|	ВзаиморасчетыСРаботникамиОрганизаций.ВидРасчета,

|	ВзаиморасчетыСРаботникамиОрганизаций.СуммаВUSD

|ИЗ

|	РегистрНакопления.ВзаиморасчетыСРаботникамиОрганизаций КАК ВзаиморасчетыСРаботникамиОрганизаций

|ГДЕ

|	ВзаиморасчетыСРаботникамиОрганизаций.Физлицо = &Физлицо

|	И ВзаиморасчетыСРаботникамиОрганизаций.ПериодВзаиморасчетов = &ПериодВзаиморасчетов

|	И ВзаиморасчетыСРаботникамиОрганизаций.Регистратор ССЫЛКА Документ.НачислениеЗарплатыРаботникамОрганизаций

|

|";

Запрос.УстановитьПараметр("ПериодВзаиморасчетов",Дата("01.09.2009 0:00:00"));

Запрос.УстановитьПараметр("Физлицо",Справочники.ФизическиеЛица.НайтиПоКоду("00000054"));

Результат = Запрос.Выполнить();

Результат = Результат.Выбрать();

Пока Результат.Следующий() Цикл

 // обработка результата

КонецЦикла;



//Пример 2

Запрос=новый Запрос;

Запрос.Текст="

|ВЫБРАТЬ

|	ВзаиморасчетыСРаботникамиОрганизаций.Физлицо КАК Физлицо,

|	ВзаиморасчетыСРаботникамиОрганизаций.ПериодВзаиморасчетов КАК ПериодВзаиморасчетов,

|	СУММА(ВЫБОР

|			КОГДА ВзаиморасчетыСРаботникамиОрганизаций.ВидРасчета В (&VidUSD)

|				ТОГДА ВзаиморасчетыСРаботникамиОрганизаций.СуммаВUSD

|			ИНАЧЕ 0

|		КОНЕЦ) КАК USD,

|	СУММА(ВЫБОР

|			КОГДА (НЕ ВзаиморасчетыСРаботникамиОрганизаций.ВидРасчета В (&VidUSD))

|				ТОГДА ВЫБОР

|						КОГДА (НЕ ВзаиморасчетыСРаботникамиОрганизаций.ВидРасчета = НЕОПРЕДЕЛЕНО)

|								ИЛИ ВзаиморасчетыСРаботникамиОрганизаций.Регистратор ССЫЛКА Документ.НачислениеОтпускаРаботникамОрганизаций

|							ТОГДА ВзаиморасчетыСРаботникамиОрганизаций.СуммаВзаиморасчетов

|						ИНАЧЕ 0

|					КОНЕЦ

|			ИНАЧЕ 0

|		КОНЕЦ) КАК RUB,

|	СУММА(ВЫБОР

|			КОГДА ВзаиморасчетыСРаботникамиОрганизаций.ВидРасчета = НЕОПРЕДЕЛЕНО

|					И ВзаиморасчетыСРаботникамиОрганизаций.Регистратор ССЫЛКА Документ.НачислениеЗарплатыРаботникамОрганизаций

|				ТОГДА ВзаиморасчетыСРаботникамиОрганизаций.СуммаВзаиморасчетов * -1

|			ИНАЧЕ 0

|		КОНЕЦ) КАК NDFL

|ИЗ

|	РегистрНакопления.ВзаиморасчетыСРаботникамиОрганизаций КАК ВзаиморасчетыСРаботникамиОрганизаций

|ГДЕ

|	ВзаиморасчетыСРаботникамиОрганизаций.Физлицо = &Физлицо

|	И ВзаиморасчетыСРаботникамиОрганизаций.ПериодВзаиморасчетов = &ПериодВзаиморасчетов

|	И (ВзаиморасчетыСРаботникамиОрганизаций.Регистратор ССЫЛКА Документ.НачислениеЗарплатыРаботникамОрганизаций

|			ИЛИ ВзаиморасчетыСРаботникамиОрганизаций.Регистратор ССЫЛКА Документ.НачислениеОтпускаРаботникамОрганизаций)

|

|СГРУППИРОВАТЬ ПО

|	ВзаиморасчетыСРаботникамиОрганизаций.Физлицо,

|	ВзаиморасчетыСРаботникамиОрганизаций.ПериодВзаиморасчетов

|";