sms » Поиск » HelpF.pro

Результаты по ключевому слову: sms

Отправка SMS через SMS.ru

Один из самый простых сервисов для работы с смс.

Регистрируемся на сайта sms.ru
Добавляем отправителя, проходим все проверки и разрешения (очень просто и быстро)
Получаем API ключ и начинаем кодить в 1С.

Сама отправка смс, через http, выглядит вот так

https://sms.ru/sms/send?api_id=ВАШ_АПИ_КЛЮЧ&to=Номер1,Номер2&msg=hello+world&json=1 [/pre]

Для примера , у меня будет цикл по запросу, который отправляет заранее заданный текст из справочника, клиентам.

В нем у нас есть 2 объекта.

1) HTTP соединения

2) HTTP Запрос

В запрос кидаем сформированную строку, в которой есть

1) API ключ - записан в константы

2) Текст, из справочника (с заменой)

3) номер телефона из заказа (у кого откуда )

4) конец строки JSON= 1 , означает получение ответа от сайта , о успешной или не успешной отправке смс с кодами авторизации/отправки в формате JSON (Разбор JSON отдельная тема)

В запросе, указываем адрес который идет после sms.ru, начиная со слэша!

В соединении, если httpS , не указываем изначально , какой это протокол, указать порт и создать объект защищенного соединения.

В остальном, все как в коде, в любом виде =)

Код 1C v 8.х

 



Соединение = Новый HTTPСоединение("sms.ru",443,,,,,Новый ЗащищенноеСоединениеOpenSSL);

Запрос 	   = Новый HTTPЗапрос;

			 

Пока ВыборкаДляСмс.Следующий() Цикл

			

	ВремФайл 			 = ПолучитьИмяВременногоФайла("txt");

	текст				 = СтрЗаменить(Справочники.МДО_ТекстыСМС.НайтиПоКоду("000000001").Текст,"*номер*",ВыборкаДляСмс.НомерЗаказа);

	запрос.АдресРесурса = "/sms/send?api_id="+Константы.SMSru_ApiКлюч.Получить()+"&to="+СтрЗаменить(ВыборкаДляСмс.ТелефонИзЗаказа," ","")+"&from="+Константы.SMSru_Отправитель.Получить()+"&msg="+текст+"&json=1";

			 

	Соединение.ВызватьHTTPМетод("GET",Запрос,ВремФайл);

	ИзменитьСтатусСМС(ВремФайл,ВыборкаДляСмс.Заказ);

			 

КонецЦикла;

Категория: COM-объекты, WMI, WSH

Оформление строки в ПриПолученииДанных или ПриВыводеСтроки

Событие ПриПолученииДанных использется для оформления ячеек строк данных, отображаемых табличным полем. Обработчик данного события вызывается табличным полем в тех же случаях, что и обработчик ПриВыводеСтроки, т.е. при обновлении данных, отображаемых табличным полем или при поиске по подстроке. Важно отметить, что обработчик данного события вызывается табличным полем перед вызовом обработчиков события ПриВыводеСтроки для всех видимых строк табличного поля. Основным отличием данного события от события ПриВыводеСтроки является то, что в обработчике события ПриПолученииДанных можно изменять настройки ячеек группы строк, а не одной строки как в обработчике события ПриВыводеСтроки.

Обрабатывая данное событие можно изменять шрифт, цвет фона или текста, как определенной ячейки, так и всей строки табличного поля, устанавливать высоту или видимость ячеек строки табличного поля, а также устанавливать картинку, флажок или новый текст в ячейке. Параметром данного события является объект типа ОформлениеСтрок - коллекция объектов типа ОформлениеСтроки, являющихся оформлениями строк табличного поля.

Пример кода:

Код 1C v 8.х

 Процедура ТППриВыводеСтроки(Элемент, ОформлениеСтроки, ДанныеСтроки)

	

	Попытка

		ОформлениеСтроки.Ячейки.ПредоплатаОтсрочка.УстановитьТекст(?(ОформлениеСтроки.ДанныеСтроки.Ссылка.Счет.ДоговорКонтрагента.КонтролироватьЧислоДнейЗадолженности, "ОТСРОЧКА","ПРЕДОПЛАТА"));

	Исключение

	КонецПопытки;

	

	Если ОформлениеСтроки.Ячейки.Доставка.Значение = Неопределено Тогда

		возврат;

	КонецЕсли;	

	

	Если ДанныеСтроки.Доставка.Проведен Тогда

		ОформлениеСтроки.Ячейки.Картинка.ИндексКартинки = 0;

	ИначеЕсли ДанныеСтроки.Доставка.ПометкаУдаления Тогда

		ОформлениеСтроки.Ячейки.Картинка.ИндексКартинки = 1;

	Иначе

		ОформлениеСтроки.Ячейки.Картинка.ИндексКартинки = 2;

	КонецЕсли;	

	ОформлениеСтроки.Ячейки.Картинка.ОтображатьКартинку = истина;

	

	Если ДанныеСтроки.СтатусНов = "Нет машины" Тогда 

		ОформлениеСтроки.Ячейки.СтатусНов.ЦветФона = Новый Цвет(255, 196, 196);

	ИначеЕсли ДанныеСтроки.СтатусНов = "Нет разрешения" Тогда

		текцвет = Новый Цвет(255, 196, 196);

		Если ДанныеСтроки.Доставка.ДатаДоставки = НачалоДня(РабочаяДата) Тогда

			ТекВремя = Дата(1,1,1)+(ТекущаяДата()-НачалоДня(ТекущаяДата()));

			Попытка ПодачаМашины=?(ДанныеСтроки.Доставка.ВремяЗагрузкиФакт[0].ПодачаМашины>ДанныеСтроки.Доставка.ВремяПриездаЭкспедитораФакт,ДанныеСтроки.Доставка.ВремяЗагрузкиФакт[0].ПодачаМашины,ДанныеСтроки.Доставка.ВремяПриездаЭкспедитораФакт); Исключение ПодачаМашины = ДанныеСтроки.Доставка.ВремяПриездаЭкспедитораФакт; КонецПопытки;

			Если ПодачаМашины+(15*60)> ТекВремя Тогда ОформлениеСтроки.Ячейки.СтатусНов.УстановитьТекст("Получение разрешения"); текцвет = Новый Цвет(255, 225, 225); КонецЕсли;

		КонецЕсли; 				

		ОформлениеСтроки.Ячейки.СтатусНов.ЦветФона = текцвет;

	ИначеЕсли ДанныеСтроки.СтатусНов = "Загрузка" Тогда 

		ОформлениеСтроки.Ячейки.СтатусНов.ЦветФона = Новый Цвет(255, 153, 0);

	ИначеЕсли ДанныеСтроки.СтатусНов = "В пути" Тогда 

		ОформлениеСтроки.Ячейки.СтатусНов.ЦветФона = Новый Цвет(255, 255, 0);	

	ИначеЕсли ДанныеСтроки.СтатусНов = "На объекте" Тогда 

		ОформлениеСтроки.Ячейки.СтатусНов.ЦветФона = Новый Цвет(51, 204, 204);	

	ИначеЕсли ДанныеСтроки.СтатусНов = "Завершено" Тогда 

		ОформлениеСтроки.Ячейки.СтатусНов.ЦветФона = Новый Цвет(137, 255, 113);

	КонецЕсли;

	

	Если ЗначениеЗаполнено(ДанныеСтроки.СтатусSMS) Тогда

		

		Если ДанныеСтроки.СтатусSMS = "Доставлено" Тогда 

			ОформлениеСтроки.Ячейки.СтатусSMS.ЦветФона = Новый Цвет(137, 255, 113);

		ИначеЕсли ДанныеСтроки.СтатусSMS = "Поставлено в очередь" ИЛИ

			ДанныеСтроки.СтатусSMS = "Отправляется" ИЛИ

			ДанныеСтроки.СтатусSMS = "Отправлено" Тогда 

			ОформлениеСтроки.Ячейки.СтатусSMS.ЦветФона = Новый Цвет(255, 255, 0);

		Иначе 

			ОформлениеСтроки.Ячейки.СтатусSMS.ЦветФона = Новый Цвет(255, 0, 0);

		КонецЕсли;

				

	КонецЕсли; 

		

	ОформлениеСтроки.Ячейки.колКОтгрузке.УстановитьТекст(ДанныеСтроки.колКОтгрузке);

	Если ДанныеСтроки.колКОтгрузке = "ОК" Тогда

		ОформлениеСтроки.Ячейки.колКОтгрузке.ЦветФона = Новый Цвет(200, 255, 200);

	Иначе

		ОформлениеСтроки.Ячейки.колКОтгрузке.ЦветФона = Новый Цвет(255, 0, 0);

	КонецЕсли;

	

	ОформлениеСтроки.Ячейки.колСДоставки.УстановитьТекст(ДанныеСтроки.колСДоставки);

	Если ДанныеСтроки.колСДоставки = "ОК" Тогда

		ОформлениеСтроки.Ячейки.колСДоставки.ЦветФона = Новый Цвет(200, 255, 200);

	Иначе

		ОформлениеСтроки.Ячейки.колСДоставки.ЦветФона = Новый Цвет(255, 0,0);

	КонецЕсли;

	

	//Доставка до 14.00 раскраска цветом

	Если НЕ (ДанныеСтроки.Доставка.ВидДоставки = Перечисления.ВидыДоставки.Самовывоз или ДанныеСтроки.Доставка.ВидДоставки = Перечисления.ВидыДоставки.Централизация) Тогда

		Если ДанныеСтроки.Доставка.Дата < НачалоДня(ДанныеСтроки.Доставка.Дата)+60*60*14 Тогда ОформлениеСтроки.Ячейки.Менеджер.ЦветФона = Новый Цвет(166, 255, 166); Иначе ОформлениеСтроки.Ячейки.Менеджер.ЦветФона = Новый Цвет(255, 166,166); КонецЕсли;

	КонецЕсли;

	

КонецПроцедуры

А вот так это выглядит в реальности:

Категория: Список Справочника, Документов, Регистров

Отправка sms из 1C через МТС Коммуникатор

Есть сервис МТС Коммуникатор - удобный обмен SMS-сообщениями с Вашими сотрудниками, клиентами и партнерами. Так вот через него мы настроили отправку СМС клиентам компании из 1С:

Код 1C v 8.2 УП

 Если ПустаяСтрока(ТелефонКлиента) Тогда

		Сообщить("Не определен телефон экспедитора загрузки");

		Предупреждение("СМС не может быть отправлено");

	Иначе

		

		Адресат = ТелефонКлиента;

		Адресат = СтрЗаменить(СтрЗаменить(Адресат, "(", ""), ")", "");

		Адресат = СтрЗаменить(СтрЗаменить(СтрЗаменить(Адресат, ".", ""), "-", ""), " ", "");

		Адресат = СтрЗаменить(Адресат, "+", "");

		

		WinHttp = Новый COMОбъект("WinHttp.WinHttpRequest.5.1");

		WinHttp.Option(2, "Windows-1251");

		WinHttp.Open("POST", "http://mtscommunicator.ru/m2m/m2m_api.asmx/SendMessage", 0);



		WinHttp.SetRequestHeader("Accept-Language", "ru");

		WinHttp.SetRequestHeader("Accept-Charset","Windows-1251");

		WinHttp.setRequestHeader("Content-Language", "ru");

		WinHttp.setRequestHeader("Content-Charset", "Windows-1251");

		WinHttp.setRequestHeader("Content-Type","application/x-www-form-urlencoded");



		ПараметрыPOST = "msid=" + Адресат + "&message=" + ПодготовитьСообщение(ТекстСМС) + "&naming=USER&login=NUMERLOGIN&password=PASSWORD";



		Ошибка = Ложь;

		ИДСообщения = "";

		

		Попытка

			

			WinHttp.Send(ПараметрыPOST);



			ИмяФайлаЗапроса = ПолучитьИмяВременногоФайла();



			Текст = Новый ЗаписьТекста(ИмяФайлаЗапроса, КодировкаТекста.UTF8);

			Текст.ЗаписатьСтроку(WinHttp.ResponseText());

			Текст.Закрыть();

		

			Ошибка = (WinHttp.Status <> 200);

			

		Исключение

			Ошибка = Истина;

		КонецПопытки;

		

		Если НЕ Ошибка Тогда 

			

			Попытка

				

				XMLОтвет = Новый ЧтениеXML;

				XMLОтвет.ОткрытьФайл(ИмяФайлаЗапроса);	

				

				Пока XMLОтвет.Прочитать() Цикл

					Если XMLОтвет.ТипУзла = ТипУзлаXML.НачалоЭлемента И (XMLОтвет.Имя = "long")  Тогда

						XMLОтвет.Прочитать();

						ИДСообщения = XMLОтвет.Значение;

						Прервать;

					КонецЕсли;

				КонецЦикла;		

				

			Исключение

				Ошибка = Истина;

			КонецПопытки;

			

		КонецЕсли;

		

		Если Ошибка Тогда 

			Сообщить("Не удалось отправить СМС. Проверьте настройки подключения");

			Предупреждение("СМС не было отправлено");

		Иначе

	

			ПоказатьОповещениеПользователя("Отправка СМС",, "СМС-сообщение отправлено ", БиблиотекаКартинок.СМС);

			

		КонецЕсли;

КонецЕсли;



//Преобразование текста сообщения

Функция ПодготовитьСообщение(Сообщение)

	

	ВрСообщение = "";

	

	Для ТекСимвол = 1 По СтрДлина(Сообщение) Цикл

		Если КодСимвола(Сред(Сообщение, ТекСимвол, 1)) = 10 Тогда

			ВрСообщение = ВрСообщение + " ";

		Иначе

			ВрСообщение = ВрСообщение + Сред(Сообщение, ТекСимвол, 1);

		КонецЕсли;

	КонецЦикла;

	

	Сообщение = ВрСообщение;

	Сообщение = СтрЗаменить(Сообщение, "%", "%25");

	Сообщение = СтрЗаменить(Сообщение, " ", "%20");

	Сообщение = СтрЗаменить(Сообщение, "&", "%26");

	Сообщение = СтрЗаменить(Сообщение, "#", "%23");

	Сообщение = СтрЗаменить(Сообщение, "*", "%2A");

	Сообщение = СтрЗаменить(Сообщение, "|", "%7C");

	Сообщение = СтрЗаменить(Сообщение, "\", "%5C");

	Сообщение = СтрЗаменить(Сообщение, "/", "%2F");

	Сообщение = СтрЗаменить(Сообщение, "?", "%3F");

	Сообщение = СтрЗаменить(Сообщение, "^", "%5E");

	

	Возврат Сообщение;

	

КонецФункции

Категория: COM-объекты, WMI, WSH

Отправка sms из 1C через avisosms.ru. Категория: COM-объекты, WMI, WSH

Обновление 1С через интернет Категория: 1С Общие вопросы - Обычные формы