банки » Поиск

Результаты по ключевому слову: банки

Обработка на сервере с индикатором

Обработка на сервере с отображением процесса загрузки (индикатор) и возможностью прерывания

Код 1C v 8.2 УП

 // Автор acsent

&НаСервере

Функция ИнициализацияОбработкиСервер()



    Запрос = Новый Запрос;

    Запрос.Текст =

    "ВЫБРАТЬ

    |   Спр.Ссылка

    |ИЗ

    |   Справочник.Банки КАК Спр";



    Данные      = Запрос.Выполнить().Выгрузить();

    АдресДанных = ПоместитьВоВременноеХранилище(Данные, УникальныйИдентификатор);



    // Обработка

    // В справочнике ~ 4000 элементов

    Возврат Данные.Количество();



КонецФункции



&НаСервереБезКонтекста

Функция ОбработатьЭлемент(ДанныеЭлемента)



    СпрОбъект = ДанныеЭлемента.Ссылка.ПолучитьОбъект();



    // Обработка



    СпрОбъект.ОбменДанными.Загрузка = Истина;

    СпрОбъект.Записать();



КонецФункции



&НаСервереБезКонтекста

Функция ОбработатьПорциюНаСервере(Начало, Конец, АдресДанных)



    Данные = ПолучитьИзВременногоХранилища(АдресДанных);



    Для Счетчик = Начало - 1 По Конец - 1 Цикл



        ОбработатьЭлемент(Данные[Счетчик]);



    КонецЦикла;



КонецФункции



&НаКлиенте

Процедура ВыполнитьОбработку(Команда)



    Количество      = ИнициализацияОбработкиСервер();

    РазмерШага      = 10;

    КоличествоШагов = Цел(Количество / РазмерШага);

    КоличествоЦел   = КоличествоШагов * РазмерШага;



    Если КоличествоЦел < Количество Тогда

        Элементы.Индикатор.МаксимальноеЗначение = КоличествоШагов + 1;

    Иначе

        Элементы.Индикатор.МаксимальноеЗначение = КоличествоШагов;

    КонецЕсли;



    Для Счетчик = 1 По КоличествоШагов Цикл



        ОбработатьПорциюНаСервере(РазмерШага * (Счетчик - 1) + 1, РазмерШага * Счетчик, АдресДанных);

        Индикатор = Счетчик;

        ОбработкаПрерыванияПользователя();

        ОбновитьОтображениеДанных();



    КонецЦикла;



    Если КоличествоЦел < Количество Тогда



        ОбработатьПорциюНаСервере(КоличествоШагов * РазмерШага + 1, Количество, АдресДанных);

        Индикатор = Индикатор + 1;



    КонецЕсли;



КонецПроцедуры

Категория: Управляемое приложение, Тонкий клиент

Вывод картинки в строках отчета на СКД Категория: Схема Компоновки Данных

Оператор ПОДОБНО

ПОДОБНО - Оператор проверки строки на подобие шаблону. Аналог LIKE в SQL.
Оператор ПОДОБНО позволяет сравнить значение выражения, указанного слева от него, со строкой шаблона, указанной справа. Значение выражения должно иметь тип строка. Если значение выражения удовлетворяет шаблону – результатом оператора будет ИСТИНА, иначе – ЛОЖЬ.
Следующие символы в строке шаблона являются служебными и имеют смысл, отличный от символа строки:
• % (процент): последовательность, содержащая любое количество произвольных символов
• _ (подчеркивание): один произвольный символ
• […] (в квадратных скобках один или несколько символов): любой одиночный символ из перечисленных внутри квадратных скобок
В перечислении могут встречаться диапазоны, например a-z, означающие произвольный символ, входящий в диапазон, включая концы диапазона.
• [^…] (в квадратных скобках значок отрицания, за которым следует один или несколько символов): любой одиночный символ, кроме тех, которые перечислены следом за значком отрицания
Любой другой символ означает сам себя и не несет никакой дополнительной нагрузки.
Если в качестве самого себя необходимо записать один из перечисленных символов, то ему должен предшествовать <Спецсимвол>. Сам <Спецсимвол> (любой подходящий символ) определяется в этом же операторе после ключевого слова СПЕЦСИМВОЛ.
Например, шаблон “%АБВ[0-9][абвг]\_абв%” СПЕЦСИМВОЛ “\” означает подстроку, состоящую из последовательности символов:
буквы А; буквы Б; буквы В; одной цифры; одной из букв а, б, в или г; символа подчеркивания; буквы а; буквы б; буквы в.
Причем перед этой последовательностью может располагаться произвольный набор символов.

Примеры использования:

Код 1C v 8.х

 Процедура БанкОкончаниеВводаТекста(Элемент, Текст, Значение, СтандартнаяОбработка)

   СтандартнаяОбработка = Ложь;

   //Делаем запрос с поиском по шаблону вида "%" + <Текст введенный пользователм в поле ввода> + "%"

   Запрос = Новый Запрос;

   Запрос.УстановитьПараметр("Наименование", "%" + Текст + "%");

   Запрос.Текст = "ВЫБРАТЬ

   |    Банки.Ссылка

   |ИЗ

   |    Справочник.Банки КАК Банки

   |

   |ГДЕ

   |    Банки.Наименование ПОДОБНО &Наименование";

   

   Результат = Запрос.Выполнить();

   Выборка = Результат.Выбрать();

   Если Результат.Пустой() Тогда

       //Ничего не нашли. Здесь можно вывести сообщение, или еще чего сделать 

   Иначе

       //Получаем результаты

       тзРезультаты = Результат.Выгрузить();

       //Подготовим список значений который будет содержать найденные элементы.

       Значение = Новый СписокЗначений();

       Значение.ЗагрузитьЗначения(тзРезультаты.ВыгрузитьКолонку("Ссылка"));

   КонецЕсли;

КонецПроцедуры

Нужно, что бы в "Договора по умолчанию" попадали только Наименования Основной договор и т.д:

Код 1C v 8.х

 Выбор

  Когда Наименование ПОДОБНО "Договор №%" тогда "Договора с номером" //Подходит любая строка, начинающаяся с "Договор №"

 Когда Наименование ПОДОБНО "Основной договор%[^А-яЁё"+Символ(33)+"-"+Символ(126)+"№»«"+Символы.ПС+Символы.Таб+Символы.ПФ+Символы.НПП+Символы.ВТаб+"]%" тогда "Договора по умолчанию" //Подходит любая строка, начинающаяся с "Основной договор"

  Иначе "Прочие"

Конец Как ВидДоговора

Категория: Запросы

Создание и запись нового элемента справочника

Код 1C v 8.2 УП

 &НаКлиенте

Процедура ПоКнопкеНовыйКонтрагент(Команда)

       // Вставить содержимое обработчика.

        Перем НовыйКонтрагент;



        НовыйКонтрагент = Новый Структура("Наименование, ПолноеНаименование, ИНН");

        НовыйКонтрагент.Наименование = "РиК ООО";

        НовыйКонтрагент.ПолноеНаименование = "ООО Рога и копыта"; 

        НовыйКонтрагент.ИНН =  "123456789012";



 

        Если СоздатьНовогоКонтрагента(НовыйКонтрагент) = 0 Тогда

                Сообщить("Не удалось создать нового контрагента");

        КонецЕсли;



КонецПроцедуры

 



&НаСервере

Функция СоздатьНовогоКонтрагента(СтруктураСправочника)



        Перем НовыйКонтрагент,СпрПользователи;



        СпрКонтрагенты = Справочники.Контрагенты;

        НовыйКонтрагент = СпрКонтрагенты.СоздатьЭлемент();

        НовыйКонтрагент.Наименование = СтруктураСправочника.Наименование;

        НовыйКонтрагент.ПолноеНаименование = СтруктураСправочника.ПолноеНаименование; 

        НовыйКонтрагент.ИНН = СтруктураСправочника.ИНН;

        Попытка

                НовыйКонтрагент.Записать();

                Возврат 1;

        Исключение

                Возврат 0;

        КонецПопытки;



КонецФункции

Код 1C v 8.х

 //Пример 1

НовыйЭлемент = Справочники.Контрагенты.СоздатьЭлемент(); 

НовыйЭлемент.Наименование = "ООО Березка"; 

// Установить другие реквизиты.  

НовыйЭлемент.Записать(); 



НовыйЭлемент = Справочники.Банки.СоздатьЭлемент(); 

// Получить ссылку на группу, в которой будет находиться новый элемент. 

Родитель = Справочники.Банки.НайтиПоКоду("000000001"); 

НовыйЭлемент.Наименование = "ВТБ"; 

НовыйЭлемент.Код = "000000011"; 

НовыйЭлемент.Родитель = Родитель; 



// Установить другие реквизиты.  

НовыйЭлемент.Записать(); 



//Пример 2

СпрСотр = Справочники.Сотрудники;

//или так:

//СпрСотр = Справочники["Сотрудники"]

НовЭл = СпрСотр.СоздатьЭлемент();

НовЭл.Наименование = "Иванов Иван Иванович";

НовЭл.Оклад = 100;

НовЭл.Записать();

Код 1C v 7.x

  //Пример 1

//создаваться будет прямо в корне справочника

спр = создатьОбъект("Справочник.Контрагенты");

спр.Новый();

спр.Наименование = "ООО Березка";

спр.УстановитьНовыйКод();

// итак далее

//спр.Реквизит1="......"

//спр.Реквизит2="......"

спр.Записать(); 



//Пример 2

СпрСотр = СоздатьОбъект("Справочник.Сотрудники"); 	

СпрСотр.Новый();

СпрСотр.Наименование = "Иванов Иван Иванович";

СпрСотр.Оклад = 100;

СпрСотр.Записать();

Категория: Справочники