валютадокумента » Поиск

Результаты по ключевому слову: валютадокумента

Загрузка данных в 1С из PDF

В данной статье описан пример реализации загрузки данных накладных из PDF файлов для одного крупного Ритейла...

И так у Нас есть несколько файлов в формате pdf, которые нам необходимо загрузить в 1С.

Чтение PDF файлов из 1С

Первым дело я стал искать, как напрямую можно прочитать данные из 1С в PDF файлах - было найдено много информации и вариантов решений, но к сожалению большинство из них не правильно работали с кодировкой В результате банальный текст вида Красный стул превращался в страшную кракозябру.

Далее после долгих поисков был найден конвертер PDF в TXT - pdf2txt

Поддержка командной строки:

PDF2TXT <input PDF file> [output TXT file] [-logfile] [-open] [-space] [-html] [-format] [-silent] [-blankline] [-summary] [-zoom <num>] [-?] [-h]

<input PDF file> : Open an existing PDF file to convert.

[output TXT file] : Write to TEXT file, the default is same filename of input PDF file.

[-first <page number>]: Specify the first page number.

[-last <page number>]: Specify the last page number.

[-logfile] : Write log to "C:\pdf2txt.log" file.

[-open] : Auto open the text file after it be created.

[-space] : Auto insert spaces into text file.

[-html] : Output to a HTML file, not a text file.

[-format] : Keep the page layout in the generated TXT file.

[-silent] : Disable error and warning messages.

[-blankline] : Auto delete blank line in the generated TXT file.

[-summary] : Get PDF document summary.

[-zoom <num>] : Set zoom ratio, the range is from 50 to 200.

[-unicode] : Create UTF-8 encoding text file.

Примеры:

Код Batch File (DOS, CMD, BAT)

 C:\>PDF2TXT C:\input.pdf

C:\>PDF2TXT C:\input.pdf -unicode

C:\>PDF2TXT C:\input.pdf -first 10 -last 12

C:\>PDF2TXT C:\input.pdf C:\output.txt

C:\>PDF2TXT C:\input.pdf -open -silent -logfile -zoom 150

C:\>PDF2TXT C:\input.pdf C:\output.txt -open -silent

C:\>PDF2TXT C:\*.pdf

C:\>PDF2TXT C:\*.pdf C:\*.txt

C:\>PDF2TXT C:\test\*.pdf C:\test\*.txt

В архиве (Скачать Вы можете из статьи по ссылке) заготовка 1С обработки для частного случая, если она Вам подойдет - Хорошо

Если же нет, то Мы можем для Вас быстро доработать загрузку PDF в 1С!

Код на 1С для конфигурации УТ 10.3:

Код 1C v 8.х

 Функция РазложитьСтрокуВМассивПодстрок(Знач Стр, Разделитель = ",") Экспорт

	МассивСтрок = Новый Массив();

	Если Разделитель = " " Тогда

		Стр = СокрЛП(Стр);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = СокрЛ(Сред(Стр,Поз));

		КонецЦикла;

	Иначе

		ДлинаРазделителя = СтрДлина(Разделитель);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			ТекЗнч = СокрЛП(Лев(Стр,Поз-1));

			Если ЗначениеЗаполнено(ТекЗнч) Тогда

				МассивСтрок.Добавить(ТекЗнч);

			КонецЕсли;

			Стр = Сред(Стр,Поз+ДлинаРазделителя);

		КонецЦикла;

	КонецЕсли;	

КонецФункции 









Процедура КнопкаВыполнитьНажатие(Кнопка)

	//Ищем Файлы

	тч.Очистить();

	НайденныеФайлы = НайтиФайлы(ПутьКPDF,"*.pdf",ложь);

	Для каждого стр Из НайденныеФайлы Цикл

		Нстр = ТЧ.Добавить();

		Нстр.ФайлPDF = стр.Имя;

	КонецЦикла;

	ЭтаФорма.Обновить();

	//Преобразуем PDF в TXT

	Для каждого стр Из ТЧ Цикл

		Попытка

			pdf = СокрЛП(ПутьКPDF+"\"+стр.ФайлPDF);

			txt = СтрЗаменить(pdf,"pdf","txt");

			Команд = ПутьКPDF2TXT+"\pdf2txt.exe "+pdf+" "+txt; 

			ЗапуститьПриложение(Команд,ПутьКPDF,Истина);	         

			стр.ФайлTXT = txt;

		Исключение

			стр.ФайлTXT = "!!!_ОШИБКА";

		КонецПопытки;

		ЭлементыФормы.ТЧ.ТекущаяСтрока = стр;

		ЭлементыФормы.ТЧ.ОбновитьСтроки(стр);

	КонецЦикла;	

	

	мТекущийПользователь = глЗначениеПеременной("глТекущийПользователь");

	мСкладПоУмолчанию = УправлениеПользователями.ПолучитьЗначениеПоУмолчанию(мТекущийПользователь, "ОсновнойСклад");

	мОсновноеПодразделение = УправлениеПользователями.ПолучитьЗначениеПоУмолчанию(мТекущийПользователь, "ОсновноеПодразделение");

	мОсновнаяВалютаВзаиморасчетов = УправлениеПользователями.ПолучитьЗначениеПоУмолчанию(мТекущийПользователь, "ОсновнаяВалютаВзаиморасчетов");

	мОсновноеВедениеВзаиморасчетовПоДоговорам = УправлениеПользователями.ПолучитьЗначениеПоУмолчанию(мТекущийПользователь, "ОсновноеВедениеВзаиморасчетовПоДоговорам");

	мВидНоменклатурыПоУмолчанию = УправлениеПользователями.ПолучитьЗначениеПоУмолчанию(мТекущийПользователь, "ОсновнойВидНоменклатуры");

	

	мОтражатьВРеглУчете = УправлениеПользователями.ПолучитьЗначениеПоУмолчанию(мТекущийПользователь, "ОтражатьДокументыВУправленческомУчете");

	мОтражатьВБухУчета = УправлениеПользователями.ПолучитьЗначениеПоУмолчанию(мТекущийПользователь, "ОтражатьДокументыВБухгалтерскомУчете");

	мОтражатьВНалУчете = УправлениеПользователями.ПолучитьЗначениеПоУмолчанию(мТекущийПользователь, "ОтражатьДокументыВНалоговомУчете");



	//Создаем Документ

	Для каждого стр Из ТЧ Цикл

		Состояние("Загружаю: "+стр.ФайлTXT);

		текдок=Новый ТекстовыйДокумент;

		текдок.Прочитать(стр.ФайлTXT,"UTF-8");

		ЗагрузкаТЧ=Ложь;

		

		ДокВозвратТоваровОтПокупателя = Документы.ВозвратТоваровОтПокупателя.СоздатьДокумент();	

		ДокВозвратТоваровОтПокупателя.Ответственный = мТекущийПользователь;   	

		ДокВозвратТоваровОтПокупателя.Дата  = ОбщегоНазначения.ПолучитьРабочуюДату();

		ДокВозвратТоваровОтПокупателя.УстановитьНовыйНомер();

		

		ДокВозвратТоваровОтПокупателя.ВидПоступления = Перечисления.ВидыПоступленияТоваров.НаСклад;

		ДокВозвратТоваровОтПокупателя.СкладОрдер = Склад;

		ДокВозвратТоваровОтПокупателя.Подразделение = мОсновноеПодразделение;

		ДокВозвратТоваровОтПокупателя.ВалютаДокумента  = Справочники.Валюты.НайтиПоКоду("643");

		ДокВозвратТоваровОтПокупателя.УчитыватьНДС     = ИСТИНА;

		ДокВозвратТоваровОтПокупателя.СуммаВключаетНДС = ИСТИНА;



		Для Ном=1 по текдок.КоличествоСтрок() цикл

			ТСтр = текдок.ПолучитьСтроку(Ном);

			ТекСтр = СокрЛП(ТСтр);

			

			Если Найти(ТекСтр, "Всего по накладной")>0 Тогда

				ЗагрузкаТЧ=Ложь;

				

				//делаем пересчеты сумм, количества мест и НДС по строкам

				Для Каждого СтрокаТабличнойЧасти Из ДокВозвратТоваровОтПокупателя.Товары Цикл

					ОбработкаТабличныхЧастей.РассчитатьКоличествоМестТабЧасти(СтрокаТабличнойЧасти, ДокВозвратТоваровОтПокупателя);

					ОбработкаТабличныхЧастей.РассчитатьСуммуТабЧасти(СтрокаТабличнойЧасти, ДокВозвратТоваровОтПокупателя);

					ОбработкаТабличныхЧастей.РассчитатьСуммуНДСТабЧасти(СтрокаТабличнойЧасти, ДокВозвратТоваровОтПокупателя);

				КонецЦикла;

				Попытка  

					ДокВозвратТоваровОтПокупателя.Записать(РежимЗаписиДокумента.Проведение); 

				Исключение

					ДокВозвратТоваровОтПокупателя.Записать(РежимЗаписиДокумента.Запись);  

				КонецПопытки;

				стр.Документ = ДокВозвратТоваровОтПокупателя.Ссылка;

				стр.Инфо = "Все ОК";

				ЭлементыФормы.ТЧ.ТекущаяСтрока = стр;

				ЭлементыФормы.ТЧ.ОбновитьСтроки(стр);

				

				//ВСЕ

				Прервать;

			КонецЕсли;	

				

			Если ЗагрузкаТЧ  Тогда

				ТекСтр = СтрЗаменить(ТекСтр, "подложке  ","подложке");

				ТекСтр = СтрЗаменить(ТекСтр, "   ","|");

				

				СтрМ=РазложитьСтрокуВМассивПодстрок(ТекСтр,"|");

				Если СтрМ.Количество()>2 Тогда

					//Сообщить(СтрМ);

					Попытка

						НоваяСтрока                            = ДокВозвратТоваровОтПокупателя.Товары.Добавить();

						НоваяСтрока.Номенклатура               = Справочники.Номенклатура.НайтиПоКоду(СтрМ[2]);

						//НоваяСтрока.ХарактеристикаНоменклатуры = СтрокаТаблицы.ХарактеристикаНоменклатуры;		

						//УстановитьСтавкуНДСВТабЧасти(НоваяСтрока, СтрокаТаблицы);

						//ПроверитьНаличиеСерииНоменклатуры(НоваяСтрока, СтрокаТаблицы);

						//УстановитьПризнакВеденияПоСериямНоменклатуры(НоваяСтрока); 		

						НоваяСтрока.ЕдиницаИзмерения           = НоваяСтрока.Номенклатура.БазоваяЕдиницаИзмерения;

						НоваяСтрока.Коэффициент                = 1;

						НоваяСтрока.Количество                 = Число(СтрМ[6]);

						НоваяСтрока.Цена                       = Число(СтрМ[7]);

						НоваяСтрока.Сумма         = Число(СтрМ[8]);

						НоваяСтрока.СуммаНДС     = Число(СтрМ[11]);

						НоваяСтрока.Качество = Справочники.Качество.Новый;

						Попытка

							НоваяСтрока.СтавкаНДС = Перечисления.СтавкиНДС["НДС"+Лев(СокрЛП(СтрМ[9]),2)];

						Исключение

							НоваяСтрока.СтавкаНДС = НоваяСтрока.Номенклатура.СтавкаНДС;

						КонецПопытки;

					Исключение

						Сообщить("Не загружено: "+ТекСтр);

					КонецПопытки;

				Иначе

					Продолжить;

				КонецЕсли;				

			Иначе

				// Возможно что-то будет			

			КонецЕсли;

			//Сообщить(ТекСтр);

			Если Найти(ТекСтр, "Товарная накладная")>0 Тогда

				ТекСтр = СтрЗаменить(ТекСтр, "   ","|");

				СтрМ=РазложитьСтрокуВМассивПодстрок(ТекСтр,"|");

				Если СтрМ.Количество()>1 Тогда

					//Сообщить(СтрМ);

					ДокВозвратТоваровОтПокупателя.НомерВходящегоДокументаЭлектронногоОбмена = СтрМ[1];

					ТекДата = СтрМ[2];

					ДокВозвратТоваровОтПокупателя.ДатаВходящегоДокументаЭлектронногоОбмена = Дата(Прав(ТекДата,4)+Сред(ТекДата,4,2)+Лев(ТекДата,2));

				КонецЕсли;			

			КонецЕсли;

			

			Если Найти(ТекСтр, "Грузополучатель:")>0 Тогда

				//Сообщить(ТекСтр);

				//Получим ИНН

				ГдеИНН = Найти(ТекСтр, "ИНН");

				Если ГдеИНН>0 Тогда

					ГдеИННвр= лев(ТекСтр,ГдеИНН+15);

					текИНН = Прав(гдеИННвр, СтрДлина(ГдеИННвр)-(ГдеИНН+3));

					текИНН = СокрЛП(СтрЗаменить(текИНН,".","")); текИНН = СокрЛП(СтрЗаменить(текИНН,",",""));  

					ТекОрганизация = Справочники.Организации.НайтиПоРеквизиту("ИНН",текИНН);

					Если ТекОрганизация=Справочники.Организации.ПустаяСсылка() Тогда

						ДокВозвратТоваровОтПокупателя.Организация = Организация;	

					Иначе

						ДокВозвратТоваровОтПокупателя.Организация = ТекОрганизация;			

					КонецЕсли;

					

				КонецЕсли;	

			КонецЕсли;

			

			Если Найти(ТекСтр, "Поставщик:")>0 Тогда

				//Сообщить(ТекСтр);

				//Получим ИНН

				ГдеИНН = Найти(ТекСтр, "ИНН");

				Если ГдеИНН>0 Тогда

					ГдеИННвр= лев(ТекСтр,ГдеИНН+15);

					текИНН = Прав(гдеИННвр, СтрДлина(ГдеИННвр)-(ГдеИНН+3));

					текИНН = СокрЛП(СтрЗаменить(текИНН,".","")); текИНН = СокрЛП(СтрЗаменить(текИНН,",",""));  

					ТекПоставщик = Справочники.Контрагенты.НайтиПоРеквизиту("ИНН",текИНН);

					ДокВозвратТоваровОтПокупателя.Контрагент = ТекПоставщик;

					ДокВозвратТоваровОтПокупателя.ДоговорКонтрагента = ТекПоставщик.ОсновнойДоговорКонтрагента;

				КонецЕсли;

			КонецЕсли;

			

			Если Найти(ТекСтр, "Плательщик:")>0 Тогда

				//Сообщить(ТекСтр);

				//Получим ИНН

				ГдеИНН = Найти(ТекСтр, "ИНН");

				Если ГдеИНН>0 Тогда

					ГдеИННвр= лев(ТекСтр,ГдеИНН+15);

					текИНН = Прав(гдеИННвр, СтрДлина(ГдеИННвр)-(ГдеИНН+3));

					текИНН = СокрЛП(СтрЗаменить(текИНН,".","")); текИНН = СокрЛП(СтрЗаменить(текИНН,",",""));  

					ТекПлательщик = Справочники.Контрагенты.НайтиПоРеквизиту("ИНН",текИНН);

				КонецЕсли;

			КонецЕсли;

			

			Если текстр="1                                   2                                       3            4        5      6       7            8             9      10               11                      12                  13               14                            15" Тогда

				ЗагрузкаТЧ=Истина;				

			КонецЕсли;

		КонецЦикла;	

		

	КонецЦикла;

	

КонецПроцедуры



Процедура ПутьКPDF2TXTОткрытие(Элемент, СтандартнаяОбработка)

	СтандартнаяОбработка = Ложь;

	Режим = РежимДиалогаВыбораФайла.ВыборКаталога; 

	ДиалогОткрытия = Новый ДиалогВыбораФайла(Режим); 

	ДиалогОткрытия.Каталог = ""; 

	ДиалогОткрытия.МножественныйВыбор = Ложь; 

	ДиалогОткрытия.Заголовок = "Выберите каталог с PDF2TXT"; 

	Если ДиалогОткрытия.Выбрать() Тогда 

		ПутьКPDF2TXT = ДиалогОткрытия.Каталог; 

		ПутьКPDF = ДиалогОткрытия.Каталог; 

	КонецЕсли; 

КонецПроцедуры



Процедура ПутьКPDFОткрытие(Элемент, СтандартнаяОбработка)

	СтандартнаяОбработка = Ложь;

	Режим = РежимДиалогаВыбораФайла.ВыборКаталога; 

	ДиалогОткрытия = Новый ДиалогВыбораФайла(Режим); 

	ДиалогОткрытия.Каталог = ""; 

	ДиалогОткрытия.МножественныйВыбор = Ложь; 

	ДиалогОткрытия.Заголовок = "Выберите каталог с PDF2TXT"; 

	Если ДиалогОткрытия.Выбрать() Тогда 

		ПутьКPDF = ДиалогОткрытия.Каталог; 

	КонецЕсли; 

КонецПроцедуры

Категория: Загрузка данных в 1С

Срез последних (остатки) на каждую дату Категория: Регистры накопления

Подключение к ИБ через Com, Получение списка документов и их Загрузка

Код 1C v 8.х

  //Пример кода

Перем Подключились;

Перем COMОбъект;



Функция ПолучитьНом(Выборка)

	

	Ном = Справочники.Номенклатура.НайтиПоНаименованию(СокрЛП(Выборка.Номенклатура));

	

	Если Ном.Пустая() Тогда

		ВвестиЗначение(Ном, "Выберите номенклатуру " + СокрЛП(Выборка.Номенклатура), Тип("СправочникСсылка.Номенклатура"));

	КонецЕсли;

	

	Возврат Ном;

	

КонецФункции





Функция ПодключитьсяКCRM()

	

	Подключились = Истина;

	

	Попытка

		Подкл = Новый COMОбъект("V82.COMConnector");

		COMОбъект = Подкл.Connect("Srvr=""Server1"";Ref=""TradeUT"";Usr=""ObmenBot"";Pwd=""12345""");

	Исключение

		Сообщить(ОписаниеОшибки());

		Подключились = Ложь;

	КонецПопытки;

	

	Возврат Подключились;

	

КонецФункции



Процедура Реализации_Анализ(Элемент)

	

	Если не Подключились Тогда

		Если не ПодключитьсяКCRM() Тогда

			Возврат;

		КонецЕсли;

	КонецЕсли;

	

	Запрос = COMОбъект.NewObject("Запрос");

	

	Запрос.Текст = ПолучитьМакет("ЗапросПродажи").ПолучитьТекст();

	

	Запрос.УстановитьПараметр("Дата1", НачалоДня(ДатаНач));

	Запрос.УстановитьПараметр("Дата2", КонецДня(ДатаКон));

	

	глРезультатЗапросаПродажи = Запрос.Выполнить();

	

	Выборка = глРезультатЗапросаПродажи.Выбрать(COMОбъект.ОбходРезультатаЗапроса.ПоГруппировкам);

	

	ДокРеал = Документы.РеализацияТоваровУслуг;

	СпрКонтр = Справочники.Контрагенты;

	

	ТаблицаДокументов.Очистить();

	

	Пока Выборка.Следующий() Цикл

		ОбработкаПрерыванияПользователя();

		Стр = ТаблицаДокументов.Добавить();

		ЗаполнитьЗначенияСвойств(Стр, Выборка);

		Стр.Документ = ДокРеал.НайтиПоНомеру(Стр.Номер, Стр.Дата);

		Стр.ТекстКонтрагент = Выборка.КонтрагентНаименование + ", ИНН " + Выборка.ИННКонтрагента;

		Если не ПустаяСтрока(Выборка.ИННКонтрагента) Тогда

			ВыборкаКонтр = СпрКонтр.Выбрать(,, Новый Структура("ИНН", Выборка.ИННКонтрагента));

			Пока ВыборкаКонтр.Следующий() Цикл

				Если не ЗначениеЗаполнено(Стр.Контрагент) или ВыборкаКонтр.КПП = Выборка.КППКонтрагента Тогда

					Стр.Контрагент = ВыборкаКонтр.Ссылка;

				КонецЕсли;

			КонецЦикла;

		КонецЕсли;

		

	КонецЦикла;

	

	ЭлементыФормы.кнЗагрузитьШаг1.Доступность = Истина;

	ЭлементыФормы.ИндикаторРеал.МаксимальноеЗначение = ТаблицаДокументов.Количество(); 

	

КонецПроцедуры



Процедура Реализации_Загрузить(Элемент)

	

	ЭлементыФормы.ИндикаторРеал.МаксимальноеЗначение = ТаблицаДокументов.Количество(); 

	ЗначениеИндикатораРеал = 0;

	

	ДокРеал = Документы.РеализацияТоваровУслуг;

	

	ВыборкаДок = глРезультатЗапросаПродажи.Выбрать(COMОбъект.ОбходРезультатаЗапроса.ПоГруппировкам);

	

	мСписокВидовДоговоров = Новый СписокЗначений;

	мСписокВидовДоговоров.Добавить(Перечисления.ВидыДоговоровКонтрагентов.СПокупателем);

	

	СпособЗаполненияЦен = Перечисления.СпособыЗаполненияЦен.ПоЦенамНоменклатуры;

	

	Пока ВыборкаДок.Следующий() Цикл

		ЗначениеИндикатораРеал = ЗначениеИндикатораРеал + 1;

		

		СтрокаТаб = ТаблицаДокументов.Найти(ВыборкаДок.Номер, "Номер");

		

		Если СтрокаТаб <> Неопределено Тогда

			Если ЗначениеЗаполнено(СтрокаТаб.Документ) Тогда

				Док = СтрокаТаб.Документ.ПолучитьОбъект();

				Док.Товары.Очистить();

				Док.Услуги.Очистить();

			Иначе

				Док = ДокРеал.СоздатьДокумент();

			КонецЕсли;

			

			

			Док.Дата = ВыборкаДок.Дата;

			Док.Номер = ВыборкаДок.Номер;

			Док.Контрагент = СтрокаТаб.Контрагент;

			

			ЗаполнениеДокументов.ЗаполнитьШапкуДокумента(Док, глЗначениеПеременной("глТекущийПользователь"), Док.мВалютаРегламентированногоУчета, "Продажа");

			ЗаполнениеДокументов.ПриИзмененииЗначенияКонтрагента(Док, мСписокВидовДоговоров);

			ЗаполнениеДокументов.ПриИзмененииЗначенияДоговора(Док, Док.ВалютаДокумента, Док.мВалютаРегламентированногоУчета, СпособЗаполненияЦен, Ценообразование.ПолучитьСтруктуруРеквизитовДокументаДляЦенообразования(Док), "Продажа", "Товары", Неопределено);

			

			Док.ЗаполнитьСчетаУчетаРасчетов();

			

			Док.УчитыватьНДС = Ложь;

			

			ВыборкаНом = ВыборкаДок.Выбрать(COMОбъект.ОбходРезультатаЗапроса.ПоГруппировкам);

			Пока ВыборкаНом.Следующий() Цикл

				

				ОбработкаПрерыванияПользователя();

				

				Ном = ПолучитьНом(ВыборкаНом);

				

				Если ВыборкаНом.Идентификатор = 1 Тогда

					СтрокаТЧ = Док.Товары.Добавить();

					СтрокаТЧ.Номенклатура = Ном;

					Док.ЗаполнитьСчетаУчетаВСтрокеТабЧасти(СтрокаТЧ, "Товары", Истина);

				Иначе

					СтрокаТЧ = Док.Услуги.Добавить();

					СтрокаТЧ.Номенклатура = Ном;

					Док.ЗаполнитьСчетаУчетаВСтрокеТабЧастиУслуги(СтрокаТЧ, ИСТИНА);

					ОбработкаТабличныхЧастей.ЗаполнитьСодержаниеТабЧасти(СтрокаТЧ, Док);

				КонецЕсли;

				

					

				ОбработкаТабличныхЧастей.ЗаполнитьСтавкуНДСТабЧасти(СтрокаТЧ, Док);

				ОбработкаТабличныхЧастей.ЗаполнитьЕдиницуЦенуПродажиТабЧасти(СтрокаТЧ, Док, Док.мВалютаРегламентированногоУчета);

				

				СтрокаТЧ.Количество = ВыборкаНом.Количество;

				СтрокаТЧ.Сумма = ВыборкаНом.Сумма;

				СтрокаТЧ.Цена = СтрокаТЧ.Сумма / ?(ВыборкаНом.Количество = 0, 1, ВыборкаНом.Количество);

				

			КонецЦикла;

			

			Если не ВыборкаДок.ДоставкаОтдельно и ВыборкаДок.СтоимостьДоставкиПлан <> 0 Тогда

				СтрокаТЧ = Док.Товары.Добавить();

				СтрокаТЧ.Номенклатура = Док.Товары[0].Номенклатура;

				Док.ЗаполнитьСчетаУчетаВСтрокеТабЧасти(СтрокаТЧ, "Товары", Истина);

				ОбработкаТабличныхЧастей.ЗаполнитьСтавкуНДСТабЧасти(СтрокаТЧ, Док);

				ОбработкаТабличныхЧастей.ЗаполнитьЕдиницуЦенуПродажиТабЧасти(СтрокаТЧ, Док, Док.мВалютаРегламентированногоУчета);

				СтрокаТЧ.Сумма = - ВыборкаДок.СтоимостьДоставкиПлан;

				

				СтрокаТЧ = Док.Услуги.Добавить();

				СтрокаТЧ.Номенклатура = Справочники.Номенклатура.ТранспортныеУслуги;

				Док.ЗаполнитьСчетаУчетаВСтрокеТабЧастиУслуги(СтрокаТЧ, ИСТИНА);

				ОбработкаТабличныхЧастей.ЗаполнитьСодержаниеТабЧасти(СтрокаТЧ, Док);

				ОбработкаТабличныхЧастей.ЗаполнитьСтавкуНДСТабЧасти(СтрокаТЧ, Док);

				ОбработкаТабличныхЧастей.ЗаполнитьЕдиницуЦенуПродажиТабЧасти(СтрокаТЧ, Док, Док.мВалютаРегламентированногоУчета);

				СтрокаТЧ.Количество = 1;

				СтрокаТЧ.Цена = ВыборкаДок.СтоимостьДоставкиПлан;

				СтрокаТЧ.Сумма = ВыборкаДок.СтоимостьДоставкиПлан;

				

			КонецЕсли;

			

			Ош = Ложь;

			Попытка

				Док.Записать(?(Проводить, РежимЗаписиДокумента.Проведение, РежимЗаписиДокумента.Запись));

				Ош = Истина;

			Исключение

			КонецПопытки;

			

			Если Ош и Проводить Тогда

				Док.Записать(РежимЗаписиДокумента.Запись);

			КонецЕсли;

			

			СтрокаТаб.Документ = Док.Ссылка;

			

		КонецЕсли;

			

	КонецЦикла;

	

КонецПроцедуры



Подключились = Ложь;

Категория: COM-объекты, WMI, WSH

Как получить Срез Последних значений на Каждую Дату Категория: Схема Компоновки Данных

Как для Подбора Элемента Справочника Открыть Форму Подбора с нужной Открытой Группой? Категория: Справочники

Как организовать обмен данными между произвольными конфигурациями?

Код 1C v 8.х

 Процедура Выгрузка(Элемент) 



	Путь = "c:\"; //реальный путь к каталогу, в котором создаются файлы 



	ЗаписьXML = Новый ЗаписьXML(); 

	ЗаписьXML.ОткрытьФайл(Путь + "выгрузка.xml"); 

	Узел = ПланыОбмена.Поставка.НайтиПоКоду("Маг1"); 



	ЗапСообщения = ПланыОбмена.СоздатьЗаписьСообщения(); 

	ЗапСообщения.НачатьЗапись(ЗаписьXML, Узел); 



	Выборка = ПланыОбмена.ВыбратьИзменения(Узел, ЗапСообщения.НомерСообщения); 



	Пока Выборка.Следующий() Цикл 

		Данные = Выборка.Получить(); 



		Если ТипЗнч(Данные) = Тип("ДокументОбъект.РеализацияТоваров") Тогда 

			ВыгрузкаРеализации(ЗаписьXML, Данные); 

	

		Иначе // все остальные объекты 

			ЗаписатьXML(ЗаписьXML, Данные); 

		КонецЕсли; 

	КонецЦикла; 



	ЗапСообщения.ЗакончитьЗапись(); 

	ЗаписьXML.Закрыть(); 



КонецПроцедуры 





Процедура ВыгрузкаРеализации(ЗаписьXML, Документ) 



	ЗаписьXML.ЗаписатьНачалоЭлемента("DocumentObject.ПередачаТовара"); 



	ЗаписатьXML(ЗаписьXML, Документ.Ссылка.УникальныйИдентификатор(), "Ref", НазначениеТипаXML.Явное); 

	ЗаписатьXML(ЗаписьXML, Документ.ПометкаУдаления, "DeletionMark", НазначениеТипаXML.Явное); 

	ЗаписатьXML(ЗаписьXML, Документ.ВалютаДокумента, "ВалютаДокумента", НазначениеТипаXML.Явное); 



	// Остальные свойства документа. 



	// Табличная часть. 

	ЗаписьXML.ЗаписатьНачалоЭлемента("Товары"); 



	Для Каждого ТекСтрока Из Документ.Товары Цикл

		ЗаписьXML.ЗаписатьНачалоЭлемента("Row"); 



		ЗаписатьXML(ЗаписьXML, ТекСтрока.Номенклатура, "Номенклатура", НазначениеТипаXML.Явное); 

		ЗаписатьXML(ЗаписьXML, ТекСтрока.Количество, "Количество", НазначениеТипаXML.Явное); 



		// Остальные реквизиты табличной части. 



		ЗаписьXML.ЗаписатьКонецЭлемента(); 

	КонецЦикла; 



	ЗаписьXML.ЗаписатьКонецЭлемента(); 

	ЗаписьXML.ЗаписатьКонецЭлемента(); 



КонецПроцедуры 





Процедура Загрузка(Элемент) 



	Путь = "c:\"; //реальный путь к каталогу, в котором создаются файлы 



	ЧтениеXML = Новый ЧтениеXML(); 

	ЧтениеXML.ОткрытьФайл(Путь + "выгрузка.xml"); 

	

	ЧтСообщения = ПланыОбмена.СоздатьЧтениеСообщения(); 

	ЧтСообщения.НачатьЧтение(ЧтениеXML); 



	ПланыОбмена.УдалитьРегистрациюИзменений(ЧтСообщения.Отправитель, ЧтСообщения.НомерСообщения); 



	Пока ВозможностьЧтенияДанных(ЧтениеXML) Цикл 

		Данные = ПрочитатьДанные(ЧтениеXML); 

		

		Если РазрешениеКоллизий(Данные) Тогда 

			Данные.ОбменДанными.Отправитель = ЧтСообщения.Отправитель; 

			Данные.ОбменДанными.Загрузка = Истина; 

			Данные.Записать(); 

		КонецЕсли; 

	КонецЦикла; 



	ЧтСообщения.ЗакончитьЧтение(); 

	ЧтениеXML.Закрыть(); 



КонецПроцедуры 





Функция ВозможностьЧтенияДанных(ЧтениеXML) 



	ТипXML = ПолучитьXMLТип(ЧтениеXML); 



	Если ТипXML = Неопределено Тогда 

		Возврат Ложь; 

	КонецЕсли; 



	Если ТипXML.ИмяТипа = "DocumentObject.ПередачаТовара" И ТипXML.URIПространстваИмен = "" Тогда 

		Возврат Истина; 

	КонецЕсли; 



	Возврат ВозможностьЧтенияXML(ЧтениеXML); 



КонецФункции 





Функция ПрочитатьДанные(ЧтениеXML) 



	ТипXML = ПолучитьXMLТип(ЧтениеXML); 

	

	Если ТипXML.ИмяТипа = "DocumentObject.ПередачаТовара" И ТипXML.URIПространстваИмен = "" Тогда 

		Возврат ЧтениеРеализации(ЧтениеXML); 

	КонецЕсли; 



	Возврат ПрочитатьXML(ЧтениеXML); 



КонецФункции 





Функция ЧтениеРеализации(ЧтениеXML) 



	ЧтениеXML.Прочитать(); 



	// Работа со ссылкой документа. 

	ПолученнаяСсылка = ПрочитатьXML(ЧтениеXML); 

	Док = Документы.ПоступлениеТоваров.ПолучитьСсылку(Новый УникальныйИдентификатор(ПолученнаяСсылка)); 



	Документ = Док.ПолучитьОбъект(); 



	Если Документ = Неопределено Тогда 

		Документ = Документы.ПоступлениеТоваров.СоздатьДокумент(); 

		Документ.УстановитьСсылкуНового(Док);

		Документ.Дата = ТекущаяДата; 

		Документ.УстановитьНовыйНомер(); 

	КонецЕсли; 



	Документ.ПометкаУдаления = ПрочитатьXML(ЧтениеXML); 

	Документ.ВалютаДокумента = ПрочитатьXML(ЧтениеXML); 



	// Табличная часть "Товары. 

	// Построчное чтение. 

	ЧтениеXML.Прочитать(); 

	Документ.Товары.Очистить(); 



	Пока ЧтениеXML.Имя = "Row" Цикл 



		// Позиционируемся на узле с номенклатурой. 

		ЧтениеXML.Прочитать(); 

		НоваяСтрока = Документ.Товары.Добавить(); 

		НоваяСтрока.Номенклатура = ПрочитатьXML(ЧтениеXML); 

		НоваяСтрока.Количество = ПрочитатьXML(ЧтениеXML); 



		// Читаем конец узла Row. 

		ЧтениеXML.Прочитать(); 

	КонецЦикла; 



	// Читаем конец табличной части. 

	ЧтениеXML.Прочитать(); 



	// Читаем конец документа. 

	ЧтениеXML.Прочитать(); 



	Возврат(Документ); 



КонецФункции 





Функция РазрешениеКоллизий(Данные) 



	Если ТипЗнч(Данные) = Тип("ДокументОбъект.ПоступлениеТоваров") Тогда 



		Если Не Данные.ЭтоНовый() Тогда 

			СсылкаНаУзел = ПланыОбмена.Поставка.НайтиПоКоду("Опт"); 



			Если ПланыОбмена.ИзменениеЗарегистрировано(СсылкаНаУзел, Данные) Тогда 

				Возврат(Ложь); 

			КонецЕсли; 

		КонецЕсли; 

	КонецЕсли; 



	Возврат(Истина); 



КонецФункции

Категория: Конвертация данных, Обмен, Перенос

Использование предложения ДЛЯ ИЗМЕНЕНИЯ

Предложение ДЛЯ ИЗМЕНЕНИЯ позволяет заблаговременно заблокировать некоторые данные (которые могут читаться транзакцией другого соединения) уже при считывании, чтобы исключить взаимные блокировки при записи. ДЛЯ ИЗМЕНЕНИЯ дает возможность указать в запросе таблицы, считываемые данные которых предполагается изменять. В этом случае другое соединение будет ожидать освобождения этих данных уже в момент считывания внутри транзакции, т.е. не сможет прочесть заблокированные данные до тех пор, пока не будет завершена транзакция, наложившая блокировку. Блокировка от изменения данных считываемых в транзакции выполняется независимо от предложения ДЛЯ ИЗМЕНЕНИЯ. Это значит, что если внутри какой-либо транзакции считаны некоторые данные, то из другого соединения эти данные не могут быть изменены до тех пор, пока блокировка не будет снята. Если запрос выполняется вне транзакции, то в нем могут быть считаны и заблокированные данные.

Блокировки устанавливаются в момент выполнения запроса, сбрасываются же при окончании транзакции. В случае если запрос выполняется вне транзакции предложение ДЛЯ ИЗМЕНЕНИЯ игнорируется.

В случае если после предложения ДЛЯ ИЗМЕНЕНИЯ отсутствуют имена таблиц, блокироваться будут считанные данные из всех таблиц, задействованных в запросе. В случае указания конкретных таблиц будут блокироваться только данные из перечисленных таблиц. Для блокировки можно указывать только таблицы верхнего уровня (т.е. не табличные части), участвующие в запросе. Должны приводиться именно имена таблиц, а не их псевдонимы, определенные в запросе. В случае указания виртуальной таблицы будут блокированы данные из всех таблиц, задействованных в виртуальной таблице. При указании виртуальной таблицы следует записывать ее имя без параметров.

Пример использования предложения ДЛЯ ИЗМЕНЕНИЯ можно посмотреть в типовой конфигурации "Управление торговлей" в модуле документа РеализацияТоваров, в функции СформироватьЗапросПоШапке(Режим), которая вызывается из обработчика проведения документа. В этой функции, в случае оперативного проведения выполняется запрос, в котором накладывается блокировка на регистр остатков:

Код 1C v 8.х

 ВЫБРАТЬ 

   Док.Дата, 

   Док.Ссылка, 

   Док.ВидОперации, 

   Док.Организация, 

   Док.ОтражатьВРегламентированномУчете, 

   Док.ОтражатьВУправленческомУчете, 

   Док.ПодразделениеКомпании, 

   Док.Контрагент, 

   Док.ДоговорВзаиморасчетов,

   Док.СкладКомпании, 

   Док.Сделка,

   Док.Сделка.ВидОперации КАК ВидЗаказаПокупателя,

   Док.КурсДокумента, 

   Док.КратностьДокумента, 

   Док.ВалютаДокумента, 

   Док.СуммаДокумента, 

   Док.КурсВзаиморасчетов,

   Док.КратностьВзаиморасчетов,

   Док.СкладКомпании.Розничный КАК СкладКомпанииРозничный,

   Док.ДоговорВзаиморасчетов.ВалютаВзаиморасчетов КАК ВалютаВзаиморасчетов,

   Док.ДоговорВзаиморасчетов.ВедениеВзаиморасчетов КАК ВедениеВзаиморасчетов,

   Док.ДоговорВзаиморасчетов.КонтролироватьЧислоДнейЗадолженности 

       КАК КонтролироватьЧислоДнейЗадолженности,

   Док.ДоговорВзаиморасчетов.ДопустимоеЧислоДнейЗадолженности 

       КАК ДопустимоеЧислоДнейЗадолженности,

   Док.ДоговорВзаиморасчетов.КонтролироватьСуммуЗадолженности 

       КАК КонтролироватьСуммуЗадолженности,

   Док.ДоговорВзаиморасчетов.ДопустимаяСуммаЗадолженности 

       КАК ДопустимаяСуммаЗадолженности,

   Док.ДоговорВзаиморасчетов.ПроцентПредоплаты КАК ПроцентПредоплаты,

   Док.УчитыватьНДС,

   Док.УчитыватьНП,

   Док.СуммаВключаетНДС,

   Док.СуммаВключаетНП,

   Константы.ВалютаУправленческогоУчетаКомпании КАК ВалютаУправленческогоУчета,

   КурсыВалютСрезПоследних.Курс КАК КурсВалютыУпрУчета,

   КурсыВалютСрезПоследних.Кратность КАК КратностьВалютыУпрУчета,

   ВзаиморасчетыПоДоговору.СуммаВалОстаток КАК СуммаВалОстатокПоДоговору,

   ВзаиморасчетыПоСделке.СуммаВалОстаток КАК СуммаВалОстатокПоСделке,

   ПерваяСделка.ДатаПервойСделки,

   СуммыЗаказов.СуммаЗаказаОборот,

   СуммыЗаказов.СуммаОплатыОборот

ИЗ 

   Документ.РеализацияТоваров Док,

   Константы 

      ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.КурсыВалют.СрезПоследних(&ДатаДокумента,) 

            КАК КурсыВалютСрезПоследних

      ПО Константы.ВалютаУправленческогоУчетаКомпании = КурсыВалютСрезПоследних.Валюта

 

ЛЕВОЕ СОЕДИНЕНИЕ // Для контроля суммы задолженности по договору 

                 // (ведение взаиморасчетов - любое) и числа дней задолженности по договору 

                 // (ведение взаиморасчетов - по расчетным документам)

   РегистрНакопления.КонтрагентыВзаиморасчетыКомпании.Остатки(, 

             ДоговорВзаиморасчетов = &ДоговорВзаиморасчетов) 

      КАК ВзаиморасчетыПоДоговору

   ПО Истина

 

ЛЕВОЕ СОЕДИНЕНИЕ 

   (ВЫБРАТЬ // Выбирает даты самых ранних сделок по договорам, указанным в т.ч. 

        МИНИМУМ(Сделка.Дата) КАК ДатаПервойСделки,

        ДоговорВзаиморасчетов

    ИЗ РегистрНакопления.КонтрагентыВзаиморасчетыКомпании.Остатки(, 

         ДоговорВзаиморасчетов = &ДоговорВзаиморасчетов)

    ГДЕ СуммаВалОстаток > 0 // Дебиторская задолженность больше 0

        И ДоговорВзаиморасчетов.ВедениеВзаиморасчетов = &ПоРасчетнымДокументам

        И ДоговорВзаиморасчетов.КонтролироватьЧислоДнейЗадолженности

    СГРУППИРОВАТЬ ПО ДоговорВзаиморасчетов) КАК ПерваяСделка

   ПО Истина

 

ЛЕВОЕ СОЕДИНЕНИЕ // Для контроля суммы задолженности по расчетному документу 

                 //(ведение взаиморасчетов - по расчетным документам)

   РегистрНакопления.КонтрагентыВзаиморасчетыКомпании.Остатки(,

   ДоговорВзаиморасчетов = &ДоговорВзаиморасчетов

   И Сделка = &Сделка

   ) КАК ВзаиморасчетыПоСделке

   ПО Истина

 

ЛЕВОЕ СОЕДИНЕНИЕ 

   РегистрНакопления.СуммыЗаказов.Обороты(,,, Заказ = &Сделка) КАК СуммыЗаказов

   ПО Истина

ГДЕ 

   Док.Ссылка = &ДокументСсылка

ДЛЯ ИЗМЕНЕНИЯ РегистрНакопления.КонтрагентыВзаиморасчетыКомпании.Остатки 

                           // Блокирующие чтение таблицы остатков регистра для разрешения 

                           // коллизий многопользовательской работы

Категория: Запросы

Пример загрузки остатков в документ 1С из DBF файла

Код 1C v 8.х

 ФайлОстатков = Новый XBase;

ФайлОстатков.Кодировка = КодировкаXBase.OEM;

ФайлОстатков.ОткрытьФайл(ПутьКТаблицеОстатков);

ФайлОстатков.Первая();        

Пока Не ФайлОстатков.ВКонце() Цикл

	КодКонтрагента = СокрЛП(ФайлОстатков.ПолучитьЗначениеПоля("ZKPO"));

	Если КодКонтрагента = "" Тогда

		КодКонтрагента = СокрЛП(ФайлОстатков.ПолучитьЗначениеПоля("IDENKOD"));

	КонецЕсли;

	НаименованиеКонтрагента = СокрЛП(СтрЗаменить(ФайлОстатков.ПолучитьЗначениеПоля("NAME"),"?","і"));

	Контрагент = ПолучитьКонтрагента(КодКонтрагента,НаименованиеКонтрагента);

	СимволСчета = СокрЛП(ФайлОстатков.ПолучитьЗначениеПоля("SYMBOL"));

	ОстатокДебет = ФайлОстатков.ПолучитьЗначениеПоля("DB_PP");

	ОстатокКредит = ФайлОстатков.ПолучитьЗначениеПоля("KR_PP");

	

	Документ = Документы.КорректировкаДолга.СоздатьДокумент(); 	

	Документ.Организация = Организация;

	Документ.Дата = "20090630235959";

	Документ.ВидОперации = Перечисления.ВидыОперацийКорректировкаДолга.ВводНачальныхОстатков;

	Если ОстатокДебет > 0 Тогда

		Документ.КонтрагентДебитор = Контрагент;

		Документ.СуммыДолга.Очистить();

		СтрокаСуммыДолга = Документ.СуммыДолга.Добавить();

		СтрокаСуммыДолга.ВидЗадолженности = Перечисления.ВидыЗадолженности.Дебиторская;

		СтрокаСуммыДолга.ДоговорКонтрагента = ПолучитьДоговор(Документ.КонтрагентДебитор);

		Если Лев(СимволСчета,3) = "361" Тогда

			СтрокаСуммыДолга.ТипКонтрагента = Перечисления.СтатусыКонтрагентов.Покупатель;

		Иначе

			СтрокаСуммыДолга.ТипКонтрагента = Перечисления.СтатусыКонтрагентов.Поставщик;

		КонецЕсли;

		СтрокаСуммыДолга.КратностьВзаиморасчетов = 1.00;

		СтрокаСуммыДолга.КурсВзаиморасчетов = 1.00;

		СтрокаСуммыДолга.Сумма = ОстатокДебет;

		СтрокаСуммыДолга.СуммаВзаиморасчетов = ОстатокДебет;

		СтрокаСуммыДолга.СтавкаНДС = Перечисления.СтавкиНДС.НДС20;

		СтрокаСуммыДолга.СчетУчетаРасчетов = ПланыСчетов.Хозрасчетный.НайтиПоКоду(СимволСчета);

	Иначе

		Документ.КонтрагентДебитор = Контрагент;

		Документ.СуммыДолга.Очистить();

		СтрокаСуммыДолга = Документ.СуммыДолга.Добавить();

		СтрокаСуммыДолга.ВидЗадолженности = Перечисления.ВидыЗадолженности.Кредиторская;

		СтрокаСуммыДолга.ДоговорКонтрагента = ПолучитьДоговор(Документ.КонтрагентДебитор);

		Если Лев(СимволСчета,3) = "361" Тогда

			СтрокаСуммыДолга.ТипКонтрагента = Перечисления.СтатусыКонтрагентов.Покупатель;

		Иначе

			СтрокаСуммыДолга.ТипКонтрагента = Перечисления.СтатусыКонтрагентов.Поставщик;

		КонецЕсли;

		СтрокаСуммыДолга.КратностьВзаиморасчетов = 1.00;

		СтрокаСуммыДолга.КурсВзаиморасчетов = 1.00;

		СтрокаСуммыДолга.Сумма = ОстатокКредит;

		СтрокаСуммыДолга.СуммаВзаиморасчетов = ОстатокКредит;

		СтрокаСуммыДолга.СтавкаНДС = Перечисления.СтавкиНДС.НДС20;

		СтрокаСуммыДолга.СчетУчетаРасчетов = ПланыСчетов.Хозрасчетный.НайтиПоКоду(СимволСчета);

	КонецЕсли;

	Документ.ВалютаДокумента = Валюта;

	Документ.СчетДт = ПланыСчетов.Хозрасчетный.Вспомогательный;

	Документ.СчетКт = ПланыСчетов.Хозрасчетный.Вспомогательный;

	Документ.Записать(РежимЗаписиДокумента.Проведение);

	ФайлОстатков.Следующая();

КонецЦикла;

ФайлОстатков.ЗакрытьФайл();

Категория: XML, DBF, TXT, CSV