вывестирезультат » Поиск

Результаты по ключевому слову: вывестирезультат

Полнотекстовый поиск в 1С (что это и пример использования)

Полнотекстовый поиск - позволит найти текстовую информацию, размещенную практически в любом месте используемой конфигурации. При этом искать нужные данные можно либо по всей конфигурации в целом, либо сузив область поиска до нескольких объектов (например, определенных видов документов или справочников). Сами критерии поиска могут варьироваться в довольно широком диапазоне. То есть найти нужные данные можно, даже не помня точно, где они хранятся в конфигурации и как именно записаны.

Полнотекстовый поиск предоставляет следующие возможности:

Есть поддержка транслитерации (написание русских слов символами латиницы в соответствии с ГОСТ 7.79-2000). Пример: "русская фраза" = "russkaya fraza".
Есть поддержка замещения (написание части символов в русских словах одноклавишными латинскими символами). Пример: "руссrfz фраpf" (окончания каждого слова набраны латиницей, допустим, в результате ошибки оператора).
Есть возможность нечеткого поиска (буквы в найденных словах могут отличаться) с указанием порога нечеткости. Пример: указав в строке поиска слово "привет" и нечеткость 17 %, найдем все аналогичные слова с ошибками и без: "привет", "превет", "привед".
Есть возможность указать область выполнения поиска по выбранным объектам метаданных.
Полнотекстовое индексирование названий стандартных полей ("Код", "Наименование" и т. д.) производится на всех языках конфигурации.
Поиск выполняется с учетом синонимов русского, английского и украинского языков.
Морфологический словарь русского языка содержит ряд специфических слов, относящихся к областям деятельности, автоматизируемым с помощью системы программ "1С:Предприятие".
Стандартно в состав поставляемых словарей включены словарные базы и словари тезауруса и синонимов русского, украинского и английского языков, которые предоставлены компанией "Информатик".
Поиск можно осуществлять с использованием подстановочных символов ("*"), а также с указанием поисковых операторов ("И", "ИЛИ", "НЕ", "РЯДОМ") и спецсимволов.

Полнотекстовый поиск можно осуществлять в любой конфигурации на платформе 1С:Предприятие 8

Для того чтобы открыть окно управления полнотекстовым поиском необходимо выполнить следующее:

Обычное приложение - пункт меню Операции - Управление полнотекстовым поиском.

Управляемое приложение - пункт меню Главное меню - Все функции - Стандартные - Управление полнотекстовым поиском.

Обновить индекс – Создание индекса/Обновление индекса;
Очистить индекс – обнуление индекса(рекомендуется после обновления всех данных);
пункт Разрешить слияние индексов – отвечает за слияние основного и дополнительного индекса.

Полнотекстовый поиск осуществляется при помощи полнотекстового индекса. При отсутствии индекса полнотекстовый поиск как таковой не возможен. Для того чтобы поиск имел результат, все необходимые данные должны быть включены в полнотекстовый индекс. Если пользователем введены в базу новые данные, их следует включить в рассматриваемый индекс, иначе они не будут участвовать в поиске. Чтобы этого избежать, необходимо обновлять полнотекстовый индекс. При обновлении система анализирует только определенные типы данных: Строка, Данные ссылочного типа (ссылки на документы, справочники),Число, Дата, ХранилищеЗначения. Если пользователь не имеет прав доступа к определенной информации, то он не сможет увидеть ее в результатах поиска. Следует также помнить и о том, что в свойствах объектов, по которым будет происходить поиск должно быть установлено значение Полнотекстовый Поиск – Использовать, которое задано по умолчанию.

Как вы можете заметить свойство Использовать установлено для всего справочника Контрагенты, но сделать это можно и для каждого его реквизита соответствующего типа.

Рассмотрим более подробно полнотекстовый индекс, который состоит из двух частей (индексов): основного индекса и дополнительного. Высокая скорость поиска данных обеспечивается за счет основного индекса, но обновление его происходит относительно медленно, в зависимости от объема данных. Дополнительный индекс ему противоположен. Данные добавляются в него намного быстрее, но поиск осуществляется медленнее. Система осуществляет поиск одновременно в обоих индексах. Большая часть данных находится в основном индексе, а данные добавляемые в систему попадают в дополнительный индекс. Пока объем данных в дополнительном индексе небольшой, поиск по нему происходит относительно быстро. В тот момент, когда нагрузка на систему невелика, происходит операция слияния индексов, в результате чего дополнительный индекс очищается, а все данные помещаются в основной индекс. Слияние индексов предпочтительнее выполнять в тот момент времени, когда нагрузка на систему минимальна. С этой целью можно создавать регламентированные задания и задания по расписанию.

Специальные операторы, допустимые при задании поискового выражения

Механизм полнотекстового поиска допускает написание части символов русского слова одноклавишными латинскими символами. Результат поиска при этом не измениться.

Два оператора РЯДОМ

упрощенный. На расстоянии 8 слов друг от друга
РЯДОМ/[+/-]n – поиск данных в одном реквизите на расстоянии n-1 слов между ними.

Знак указывает в каком направлении от первого слова будет поиск второго. (+ - после, - до)

Групповой символ «*» может использоваться только в качестве замены конца слова

Оператор нечеткости «#». Если неизвестно точное написание названия, имени.

Программными средствами и средствами 1с: программирование.

Оператор синонимов «!». Позволяет найти слово и его синонимы

Как программно обновить индекс полнотекстового поиска?

Код 1C v 8.х

 Процедура ОбновлениеИндексы() Экспорт

ПолнотекстовыйПоиск.ОбновитьИндекс();

КонецПроцедуры

Пример полнотекстового поиска данных

Определение переменной СписокПоиска

Код 1C v 8.х

 Перем СписокПоиска;

Кроме этого в процедуре обработки события ПриОткрыии формы определим, что эта переменная будет содержать список полнотекстового поиска, с помощью которого мы и будем осуществлять поиск в данных

Код 1C v 8.х

 Процедура ПриОткрытии()

СписокПоиска = ПолнотекстовыйПоиск.СоздатьСписок();

КонецПроцедуры

Теперь для события нажатия на кнопку Найти напишем код, который позволит нам выполнять поиск в соответствии с тем выражением, которое задано в поле ПоисковоеВыражение

Код 1C v 8.х

 Процедура НайтиНажатие(Элемент)

СписокПоиска.СтрокаПоиска = ПоисковоеВыражение;

Попытка

СписокПоиска.ПерваяЧасть();

Исключение

Предупреждение(ОписаниеОшибки());

КонецПопытки;

Если СписокПоиска.ПолноеКоличество() = 0 Тогда

ЭлементыФормы.СообщениеОРезультате.Значение = "Не найдено";

ЭлементыФормы.РезультатПоиска.УстановитьТекст("");

Иначе

ВывестиРезультатПоиска();

КонецЕсли;

КонецПроцедуры

Сначала в этой процедуре мы устанавливаем поисковое выражение, введенное пользователем, в качестве строки поиска для полнотекстового поиска. Затем выполняем метод ПерваяЧасть(), который собственно запускает полнотекстовый поиск и возвращает первую порцию результатов. По умолчанию порция содержит 20 элементов. После этого мы анализируем количество элементов в списке поиска. Если он не содержит ни одного элемента, то мы выводим в форму соответствующее сообщение. В противном случае вызывается процедура ВывестиРезультатПоиска(), которая отображает полученные результаты пользователю.

Создадим в модуле формы процедуру с таким именем и напишем в ней код,

Код 1C v 8.х

 Процедура ВывестиРезультатПоиска()

ЭлементыФормы.СообщениеОРезультате.Значение = "Показаны " + Строка(СписокПоиска.НачальнаяПозиция() + 1) + " - " + Строка(СписокПоиска.НачальнаяПозиция() +СписокПоиска.Количество()) + " из " + СписокПоиска.ПолноеКоличество();

Результат = СписокПоиска.ПолучитьОтображение(ВидОтображенияПолнотекстовогоПоиска.HTMLТекст);

ЭлементыФормы.РезультатПоиска.УстановитьТекст(Результат);

ДоступностьКнопок();

КонецПроцедуры

Действия, выполняемые в этой процедуре, просты. Сначала мы формируем сообщение о том, какие элементы отображены и сколько всего элементов найдено. Затем получаем результат полнотекстового поиска в виде HTML-текста и выводим этот текст в поле HTML-документа, расположенное в форме.

В заключение передаем управление в процедуру ДоступностьКнопок() для того, чтобы сделать доступными или, наоборот, запретить доступ к кнопкам Предыдущая порция и Следующая порция (в зависимости от того, какая порция полученных результатов отображена). Текст этой процедуры представлен в Коде

Код 1C v 8.х

 Процедура ДоступностьКнопок()

ЭлементыФормы.СледующаяПорция.Доступность = (СписокПоиска.ПолноеКоличество() - СписокПоиска.НачальнаяПозиция()) > СписокПоиска.Количество();

ЭлементыФормы.ПредыдущаяПорция.Доступность = (СписокПоиска.НачальнаяПозиция() > 0);

КонецПроцедуры

Теперь необходимо создать обработчики событий нажатия на кнопки ПредыдущаяПорция() и СледующаяПорция().

Код 1C v 8.х

 Процедура ПредыдущаяПорцияНажатие(Элемент)

СписокПоиска.ПредыдущаяЧасть();

ВывестиРезультатПоиска();

КонецПроцедуры

Процедура СледующаяПорцияНажатие(Элемент)

СписокПоиска.СледующаяЧасть();

ВывестиРезультатПоиска();

КонецПроцедуры

Заключительным «штрихом» будет создание обработчика события onclick поля HTML-документа, расположенного в форме. Дело в том, что результат полнотекстового поиска, представленный в виде HTML-текста, содержит гиперссылки на номера элементов списка поиска. И нам хотелось бы, чтобы при переходе пользователя на эту ссылку система открывала бы форму того объекта, который содержится в этом элементе списка. Для этого мы будем перехватывать событие onclick HTML-документа, содержащегося в поле HTML-документа, получать номер элемента списка из гиперссылки и открывать форму соответствующего объекта. Текст обработчика события onclick поля HTML-документа представлен в коде

Код 1C v 8.х

 Процедура РезультатПоискаonclick(Элемент, pEvtObj)

htmlElement = pEvtObj.srcElement;

// Проверить идентификатор элемента

Если (htmlElement.id = "FullTextSearchListItem") Тогда

// Получить имя файла (номер строки списка поиска),

// содержащегося в гиперссылке

НомерВСписке = Число(htmlElement.nameProp);

// Получить строку списка поиска по номеру

ВыбраннаяСтрока = СписокПоиска[НомерВСписке];

// Открыть форму найденного объекта

ОткрытьЗначение(ВыбраннаяСтрока.Значение);

pEvtObj.returnValue = Ложь;

КонецЕсли;

КонецПроцедуры

Категория: Встроенные Функции

Как сформировать отчет СКД без проверки прав (в привилегированном режиме)?

Что при разработке отчетов требуется чтобы у пользователя с ограниченными правами, отчет формировался полностью без проверки прав!

Особенно если настроен RLS

Есть несколько способов как это сделать:

1. Установить привилегированный режим в модуле отчета

Форма отчета должна быть Управляемой, далее в модуле отчета процедура обработчика «При компоновке результата»:

Код 1C v 8.3

 //Перехватываем событие вывода компоновки данных в табличный документ и выводим со своим заголовком

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)

	СтандартнаяОбработка = Ложь; 

	УстановитьПривилегированныйРежим(Истина);	

	

	//Сформируем отчет

	СформироватьОтчет(ДокументРезультат, ДанныеРасшифровки);

	

	УстановитьПривилегированныйРежим(Ложь);

КонецПроцедуры

2. Формирование в привилегированном режиме через Общий модуль с галкой Привелигерованный

Создаем общий модуль

так же как в пункте 1 в обработчике «При компоновке результата» пишем:

Код 1C v 8.3

 //Перехватываем событие вывода компоновки данных в табличный документ и выводим со своим заголовком

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)

	СтандартнаяОбработка = Ложь;  

	

	МЕ_ДляОтчетаСКД_ПривелРежим.СформироватьОтчетПривРеж(ДокументРезультат, СхемаКомпоновкиДанных, ДанныеРасшифровки, КомпоновщикНастроек);



КонецПроцедуры

В общем модуле МЕ_ДляОтчетаСКД_ПривелРежим код:

Код 1C v 8.3

 Процедура СформироватьОтчетПривРеж(ТабличныйДокумент, СхемаКомпоновкиДанных, ДанныеРасшифровки, КомпоновщикНастроек) Экспорт 



	ТабличныйДокумент.Очистить();  

	

	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных; 	

	МакетКомпоновкиДанных = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки, ДанныеРасшифровки,,,Ложь);

	

	ВнешниеНаборыДанных  = Новый Структура;

	/// можно передать внешние данные ВнешниеНаборыДанных.Вставить("тзПродаж", СформироватьТЗПродаж());

	

	ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;

	ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновкиДанных,ВнешниеНаборыДанных,ДанныеРасшифровки);

	

	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;

	ПроцессорВывода.УстановитьДокумент(ТабличныйДокумент);

	ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);

	

КонецПроцедуры

3. Если включен режим Использовать ограничение на уровне прав доступа - RLS

Часто используется в типовых. Тут в модуле для текущего пользователя можно на время формирования отчету установить параметр сеанса ИспользоватьОграниченияПравДоступаНаУровнеЗаписей в Ложь и RLS не сработает.

Код 1C v 8.3

 ПараметрыСеанса.ИспользоватьОграниченияПравДоступаНаУровнеЗаписей=Ложь;

После завершения формирования, не забудьте включить rls обратно установив = Истина

4. Если в запросе используется конструкция вида регистратор.дата и это поле не отображается в полях отчета СКД

Допустим Вы сделали запрос по регистру накоплений и через регистратор обратились к дате или сумме документа и при формировании отчета СКД, эти поля недоступны !? как же быть?

Проблема в том - что у регистратором может выступать несколько документов и видимо права чтение/просмотр есть не на все - поэтому через скд эта таблица целиком недоступна, решение:

1. открыть доступ на все регистраторы регистра

2. в запросе четко обозначить тип

Код 1C v 8.3

 //примеры

ВЫРАЗИТЬ(ДокументыОплаты.Регистратор КАК Документ.ПлатежноеПоручениеВходящее).СуммаДокумента

//или так

ВЫБОР

 КОГДА РАЗНОСТЬДАТ(ВЫРАЗИТЬ(ВзаиморасчетыПоДокументам.ДокументРасчетовСКонтрагентом КАК Документ.ПоступлениеТоваровУслуг).Дата,КонецПериода, ДЕНЬ) > ВзаиморасчетыПоДокументам.ДоговорКонтрагента.ДопустимоеЧислоДнейЗадолженности

   ТОГДА ДОБАВИТЬКДАТЕ(ВЫРАЗИТЬ(ВзаиморасчетыПоДокументам.ДокументРасчетовСКонтрагентом КАК Документ.ПоступлениеТоваровУслуг).Дата, ДЕНЬ, ВзаиморасчетыПоДокументам.ДоговорКонтрагента.ДопустимоеЧислоДнейЗадолженности)

 ИНАЧЕ ДАТАВРЕМЯ(1, 1, 1)

КОНЕЦ КАК ДеньВозникновенияЗадолженности

В дополнении у пункту 1, код процедуры сформировать отчет(). Для вывода отчета я использую шаблон All4CF.ru_Template_SKD_v4.1 в нем уже реализованы почти все необходимые функции и работает в Обычных и УП формах:

Код 1C v 8.3

 // Процедура выполняет формирование табличного документа по настройкам СКД

Процедура СформироватьОтчет(ТабличныйДокумент, ДанныеРасшифровки) 

	УстановитьПривилегированныйРежим(Истина);	

	// если отчет открывается по расшифровке, отбору, упорядочиванию, 

	// группировке или условному оформлению - восстановим настройки вывода заголовка,

	// т.к., в переданных настройках при этом, вывод заголовка отключен

	// для того, чтобы не выводился встроенный заголовок компоновки.                                                                         

	ВосстановитьНастройкиВыводаЗаголовка();

	

	ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;

	

	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;

	

	ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;

	

	ТабличныйДокумент.Очистить();

	

	// установим обязательные настройки отчета

	УстановитьПараметрыОтчета();

	

	// Сделаем копию настроек вывода заголовка

	СохранитьНастройкиВыводаЗаголовка();

	

	ВыводитьЗаголовок = ВыводитьЗаголовокОтчета();

	Если ВыводитьЗаголовок Тогда

		ПрисоединитьЗаголовокОтчетаКТабличномуДокументу(ТабличныйДокумент, ПолучитьТекстЗаголовкаОтчета());

		

		// Отключим в настройках вывод встроенного заголовка

		НайденнаяНастройкаВыводаЗаголовка = КомпоновщикНастроек.Настройки.ПараметрыВывода.Элементы.Найти("ВыводитьЗаголовок");

		НайденнаяНастройкаВыводаЗаголовка.Значение		= ТипВыводаТекстаКомпоновкиДанных.НеВыводить;

		НайденнаяНастройкаВыводаЗаголовка.Использование	= Истина;

	КонецЕсли;

	

	КопияДополнительныхНастроек = УстановитьДополнительныеНастройкиДляРасшифровки();

	

	МакетКомпоновкиДанных = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки, ДанныеРасшифровки);

	

	// при необходимости вставим внешние наборы данных в СКД

	ВнешниеНаборыДанных = Новый Структура;

	

	ТаблицаВнешнегоНабораДанных = ПолучитьТаблицуВнешнегоНабораДанных();

	ВнешниеНаборыДанных.Вставить("ТаблицаВнешнегоНабораДанных",ТаблицаВнешнегоНабораДанных);

	

	ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновкиДанных,ВнешниеНаборыДанных,ДанныеРасшифровки);

	

	ВывестиРезультатКомпоновкиСАвтофиксациейСтрок(ТабличныйДокумент, ПроцессорКомпоновкиДанных, ДанныеРасшифровки.Элементы,,,КоличествоФиксируемыхСтолбцов);

	

	ДополнительнаяОбработкаРезультатаОтчета(ТабличныйДокумент);

	

	Если ВыводитьЗаголовок Тогда

		// вернем настройки вывода заголовка на место		

		ВосстановитьНастройкиВыводаЗаголовка();

	КонецЕсли;

	

	// восстановим дополнительные настройки

	Для Каждого ЭлементСтруктуры Из КопияДополнительныхНастроек Цикл

		КомпоновщикНастроек.Настройки.ДополнительныеСвойства.Вставить(ЭлементСтруктуры.Ключ, ЭлементСтруктуры.Значение);

	КонецЦикла;

	

	// сохраненные настройки нужны только при расшифровке и т.п.

	// и не будуть давать изменить вывоз заголовка при обычном формировании.

	ОчиститьСохраненныеНастройкиВыводаЗаголовка();





	УстановитьВидимостьЗаголовкаОтчета(ТабличныйДокумент);

	УстановитьВидимостьПараметровОтчета(ТабличныйДокумент);    

    УстановитьПривилегированныйРежим(Ложь);

КонецПроцедуры // СформироватьОтчет()

Категория: Схема Компоновки Данных

СКД Внешний источник данных, грузим из ТЗ и далее получаем остатки на каждый документ

Очень часто бывают ситуации, когда необходимо сделать отчет СКД на сложном запросе, который используюет в себе вложенные запросы и объединения внутренние и полные и т.д. - в результате в консоли этот запрос формируется верно, а в скд половина полей пустые! Связано это с особенностью СКД в объединении внутренних данных, а так же не стоит забывать что в СКД наборы данных связываются как левое соединение...

Решения возможны следующие:

Изменить запрос в СКД
Сформировать запрос обычным способом и подставить эти данные в СКД как внешние

Рассмотрим последний вариант:

Внешний источник данных, грузим из ТЗ

Для вывода отчета я использую шаблон All4CF.ru_Template_SKD_v4.1 в нем уже реализованы почти все необходимые функции и работает в Обычных и УП формах.

В модуле объекта уже есть функция

Код 1C v 8.2 УП

 Функция ПолучитьТаблицуВнешнегоНабораДанных()

	Возврат Новый ТаблицаЗначений;

КонецФункции // ПолучитьТаблицуВнешнегоНабораДанных()

установим в ней наш запрос, получается примерно так:

Код 1C v 8.2 УП

 // В данной функции можно сформировать таблицу внешнего набора данных для СКД

//

// Функция должна возвращать таблицу данных (например таблицу значений)

//

Функция ПолучитьТаблицуВнешнегоНабораДанных()

	

	Запрос = Новый Запрос;

	Запрос.Текст =

	"ВЫБРАТЬ РАЗРЕШЕННЫЕ РАЗЛИЧНЫЕ

	|	ВложенныйЗапрос.Регистратор КАК ДокРеал,

	|	ВложенныйЗапрос.Регистратор.Доставка КАК ДокДоставка

	|ПОМЕСТИТЬ ОплаченнаяРеализация

	|ИЗ

	|	(ВЫБРАТЬ

	|		ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОбороты.Регистратор КАК Регистратор

	/////// Огромный запрос .......

	|		СГРУППИРОВАТЬ ПО

	|			ДоставкаПромежуточнаяНакладная.Ссылка,

	|			ДоставкаПромежуточнаяНакладная.Ссылка.Счет,

	|			ДоставкаПромежуточнаяНакладная.Ссылка.ВыставленоКлиенту,

	|			ИздержкиРаспределенныеНеНаОП.РаспределеннаяИздержка,

	|			ДоставкаПромежуточнаяНакладная.Ссылка.СтоимостьПрайс + ДоставкаПромежуточнаяНакладная.Ссылка.ЗатратыПриДоставке) КАК ДанныеПоДоставкам

	|		ПО ДанныеПоРеализации.ДокументПродажи.Доставка = ДанныеПоДоставкам.ДокДоставка";

	Запрос.УстановитьПараметр("КонецПериода", НастройкаПериода.ДатаОкончания);

	Запрос.УстановитьПараметр("НачалоПериода", НастройкаПериода.ДатаНачала);

	Запрос.УстановитьПараметр("НачалоПериодаМинусГод", НастройкаПериода.ДатаНачала-(86400*365)); 	

	Результат = Запрос.Выполнить();

	Выборка = Результат.Выгрузить();

	Возврат Выборка;	

КонецФункции // ПолучитьТаблицуВнешнегоНабораДанных()

Ниже в коде происходит установка внешних данных из нашей ТЗ с именем ТаблицаВнешнегоНабораДанных

Код 1C v 8.2 УП

 // при необходимости вставим внешние наборы данных в СКД

	ВнешниеНаборыДанных = Новый Структура;

	

	ТаблицаВнешнегоНабораДанных = ПолучитьТаблицуВнешнегоНабораДанных();

	ВнешниеНаборыДанных.Вставить("ТаблицаВнешнегоНабораДанных",ТаблицаВнешнегоНабораДанных);

	

	ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновкиДанных,ВнешниеНаборыДанных,ДанныеРасшифровки);

	

	ВывестиРезультатКомпоновкиСАвтофиксациейСтрок(ТабличныйДокумент, ПроцессорКомпоновкиДанных, ДанныеРасшифровки.Элементы,,,КоличествоФиксируемыхСтолбцов);

В самой компоновке добавляем набор Объект с именем ТаблицаВнешнегоНабораДанных и перечисляем поля, которые будут использоваться в отчете:

Как я уже говорил выше, далее нам необходимо получить остатки взаиморасчетов на дату документа:

Получение остатков на документ в СКД

Набор данных Запрос - назвали его Остатки:

Теперь установим связи Запроса и Объекта

Остатки нужно получать на дату документа и по контрагенту

Далее, если нужно, задайте вычисляемые поля, ресурсы, параметры и Настройте Список вывода...

Пример результата отчета:

Категория: Схема Компоновки Данных

Вертикальная автофиксация для СКД

В СКД очень не хватает возможности автофиксации строк. Обусловлено это невозможностью однозначно определить их количество в общем случае. Однако в большинстве случаев это можно сделать
Обращаю ваше внимание, что приведенная процедура работает не всегда корректно. Но в большинстве случаев она сделает свое дело.

Код 1C v 8.х

 // Выводит результат СКД с установкой вертикальной автофиксации.

// Параметры:

// Таб - ТабличныеДокумент, ПолеТабличногоДокумента - куда выводим отчет;

// ПроцессорКомпоновкиДанных - ПроцессорКомпоновкиДанных;

// ЭлементыРасшировки - ЭлементыРасшифровкиКомпоновкиДанных;

// МассивИгнорируемыхПолей - Массив, *Неопределено - массив имен игнорируемых полей;

// РазрешитьПрерывание - Булево, *Истина.

//

Процедура ЛксВывестиРезультатКомпоновкиСАвтофиксациейСтрок(Таб, ПроцессорКомпоновкиДанных, ЭлементыРасшировки,

 Знач МассивИгнорируемыхПолей = Неопределено, РазрешитьПрерывание = Истина) Экспорт 

 

 ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;

 ПроцессорВывода.УстановитьДокумент(Таб);

 ПроцессорВывода.НачатьВывод();

 ФиксацияВыполнена = Ложь;

 Если МассивИгнорируемыхПолей = Неопределено Тогда

 	МассивИгнорируемыхПолей = Новый Массив;

 КонецЕсли; 

 Пока Истина Цикл

 	ЭлементРезультатаКомпоновкиДанных = ПроцессорКомпоновкиДанных.Следующий();

 	Если ЭлементРезультатаКомпоновкиДанных = Неопределено Тогда

 	 Прервать;

 	КонецЕсли;

  

 	// Автофиксация

 	Если Не ФиксацияВыполнена Тогда

 	 Для Каждого ЗначениеПараметра Из ЭлементРезультатаКомпоновкиДанных.ЗначенияПараметров Цикл

 	 Если ТипЗнч(ЗначениеПараметра.Значение) = Тип("ИдентификаторРасшифровкиКомпоновкиДанных") Тогда

 	 ЗначенияПолейРасшифровки = ЭлементыРасшировки[ЗначениеПараметра.Значение].ПолучитьПоля();

 	 Для Каждого ЗначениеПоляРасшифровки Из ЗначенияПолейРасшифровки Цикл

 	 Если МассивИгнорируемыхПолей.Найти(ЗначениеПоляРасшифровки.Поле) = Неопределено Тогда

 	 Таб.ФиксацияСверху = Таб.ВысотаТаблицы;

 	 ФиксацияВыполнена = Истина;

 	 Прервать;

 	 КонецЕсли;

 	 КонецЦикла;

 	 Если ФиксацияВыполнена Тогда

 	 Прервать;

 	 КонецЕсли;

 	 КонецЕсли;

 	 КонецЦикла;

 	КонецЕсли;

  

 	ПроцессорВывода.ВывестиЭлемент(ЭлементРезультатаКомпоновкиДанных);

 	Если РазрешитьПрерывание Тогда

 	 ОбработкаПрерыванияПользователя();

 	КонецЕсли; 

 КонецЦикла;

 ПроцессорВывода.ЗакончитьВывод();

 

КонецПроцедуры // ЛксВывестиРезультатКомпоновкиСАвтофиксациейСтрок

tormozit

Категория: Схема Компоновки Данных

МоментВремени, получение остатков до и после проведения

"Момент времени" - виртуальное поле, не хранится в базе данных. Содержит объект МоментВремени (который включает в себя дату и ССЫЛКУ НА ДОКУМЕНТ)
В 7.7 было понятие ПозицияДокумента, а в 8.x Момент времени

Для получения Остатков, Движений:
МоментВремени - это момент непосредственно перед позицией документа!
Если Вам необходимо получить момент непосредственно после позиции документа, то через объект Граница:

Код 1C v 8.х

  МоментСразуПослеДокумента = Новый Граница(ДокументСсылка,ВидГраницы.Включая);

Пример получения остатков на дату документа, но до его движений

Код 1C v 8.х

  Запрос = Новый Запрос;

Запрос.Текст = 

"ВЫБРАТЬ

|	ВзаиморасчетыСРаботникамиОрганизацийОстатки.Физлицо,

|	ВзаиморасчетыСРаботникамиОрганизацийОстатки.СуммаВзаиморасчетовОстаток

|ИЗ

|	РегистрНакопления.ВзаиморасчетыСРаботникамиОрганизаций.Остатки(&МомВрем, Физлицо = &Физик) КАК ВзаиморасчетыСРаботникамиОрганизацийОстатки";

МомВрем = Документы.НачислениеЗарплатыРаботникамОрганизаций.НайтиПоНомеру("00012","31.12.2009 23:59:59");

Запрос.УстановитьПараметр("МомВрем", Новый Граница(МомВрем.МоментВремени(), ВидГраницы.Включая));

Запрос.УстановитьПараметр("Физик", Справочники.ФизическиеЛица.НайтиПоКоду("365"));	

ВывестиРезультат(Запрос.Выполнить());

Пример получения остатков на дату документа, включая его движения

Код 1C v 8.х

  Запрос = Новый Запрос;

Запрос.Текст = 

"ВЫБРАТЬ

|	ВзаиморасчетыСРаботникамиОрганизацийОстатки.Физлицо,

|	ВзаиморасчетыСРаботникамиОрганизацийОстатки.СуммаВзаиморасчетовОстаток

|ИЗ

|	РегистрНакопления.ВзаиморасчетыСРаботникамиОрганизаций.Остатки(&МомВрем, Физлицо = &Физик) КАК ВзаиморасчетыСРаботникамиОрганизацийОстатки";

МомВрем = Документы.НачислениеЗарплатыРаботникамОрганизаций.НайтиПоНомеру("00012","31.12.2009 23:59:59");

Запрос.УстановитьПараметр("МомВрем", Новый Граница(МомВрем.МоментВремени(), ВидГраницы.Исключая));

// или так: Запрос.УстановитьПараметр("МомВрем", МомВрем.МоментВремени());

Запрос.УстановитьПараметр("Физик", Справочники.ФизическиеЛица.НайтиПоКоду("365"));	

ВывестиРезультат(Запрос.Выполнить());

Категория: Встроенные Функции

Как закрепить шапку таблицы отчета?

Код 1C v 8.х

 // Пример от  sergeante   Фиксирует шапку при любых отборах.

Процедура скдФиксироватьШапкуОтчета(ТабДок, Фиксировать, Строка = "Номенклатура", Поправка = 0) Экспорт

    Если Фиксировать Тогда

        Область = ТабДок.НайтиТекст(Строка,,,,Истина);

        ТабДок.ФиксацияСверху = ?(ЗначениеЗаполнено(Область), Область.Верх + Поправка, 0);    

    Иначе

        ТабДок.ФиксацияСверху = 0;

    КонецЕсли; 

КонецПроцедуры

Код 1C v 8.х

  // Пример от i-rek

   ПроцессорВывода.НачатьВывод(); 



    ТаблицаЗафиксирована = Ложь;

    Пока Истина Цикл

        ЭлементРезультата = ПроцессорКомпоновкиДанных.Следующий();

         Если ЭлементРезультата= Неопределено Тогда

            Прервать;     

         Иначе     

            ПроцессорВывода.ВывестиЭлемент(ЭлементРезультата);

            Если Не ТаблицаЗафиксирована И ЭлементРезультата.ЗначенияПараметров.Количество() >  0 Тогда

                ТаблицаЗафиксирована = Истина;

                Таб.ФиксацияСверху = Таб.ВысотаТаблицы;

              КонецЕсли;

         КонецЕсли;

    КонецЦикла;

    ПроцессорВывода.ЗакончитьВывод();

Код 1C v 8.х

 // Пример от Kashemir

Процедура глВывестиРезультатКомпоновкиСАвтофиксациейСтрок( Таб, 

                                                            ПроцессорКомпоновкиДанных, 

                                                            ЭлементыРасшировки,

                                                             Знач МассивИгнорируемыхПолей = Неопределено, 

                                                            РазрешитьПрерывание = Истина) Экспорт 

 

 ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;

 ПроцессорВывода.УстановитьДокумент(Таб);

 ПроцессорВывода.НачатьВывод();

 ФиксацияВыполнена = Ложь;

 Если МассивИгнорируемыхПолей = Неопределено Тогда

     МассивИгнорируемыхПолей = Новый Массив;

 КонецЕсли; 

 Пока Истина Цикл

     ЭлементРезультатаКомпоновкиДанных = ПроцессорКомпоновкиДанных.Следующий();

     Если ЭлементРезультатаКомпоновкиДанных = Неопределено Тогда

         Прервать;

     КонецЕсли;

     

     // Автофиксация 

     Если Не ФиксацияВыполнена Тогда

         Для Каждого ЗначениеПараметра Из ЭлементРезультатаКомпоновкиДанных.ЗначенияПараметров Цикл

             Если ТипЗнч(ЗначениеПараметра.Значение) = Тип("ИдентификаторРасшифровкиКомпоновкиДанных") Тогда

                 ЗначенияПолейРасшифровки = ЭлементыРасшировки[ЗначениеПараметра.Значение].ПолучитьПоля();

                 Для Каждого ЗначениеПоляРасшифровки Из ЗначенияПолейРасшифровки Цикл

                     Если МассивИгнорируемыхПолей.Найти(ЗначениеПоляРасшифровки.Поле) = Неопределено Тогда

                         Таб.ФиксацияСверху = Таб.ВысотаТаблицы;

                         ФиксацияВыполнена = Истина;

                         Прервать;

                     КонецЕсли;

                 КонецЦикла;

                 Если ФиксацияВыполнена Тогда

                     Прервать;

                 КонецЕсли;

             КонецЕсли;

         КонецЦикла;

     КонецЕсли;

     

     ПроцессорВывода.ВывестиЭлемент(ЭлементРезультатаКомпоновкиДанных);

     Если РазрешитьПрерывание Тогда

         #Если Клиент тогда 

         ОбработкаПрерыванияПользователя();

         #КонецЕсли 

     КонецЕсли; 

 КонецЦикла;

 ПроцессорВывода.ЗакончитьВывод();

 

КонецПроцедуры

Категория: Схема Компоновки Данных

Почему при получении остатков или оборотов на дату, попадают не все движения(документы)?

При указании конечной даты, указывайте на просто Дату, а Границу!

Например, если нужно получить на конец дня, то указывайте так:

Код 1C v 8.х

  ГраницаКНД = Новый Граница(КонецДня(Дата), ВидГраницы.Включая);

Запрос.УстановитьПараметр("КонГраница", ГраницаКНД );

Если вы хотите получить остатки до определенного документа или после, то используйте:

Пример получения остатков на дату документа, но до его движений

Код 1C v 8.х

  Запрос = Новый Запрос;

Запрос.Текст = 

"ВЫБРАТЬ

|	ВзаиморасчетыСРаботникамиОрганизацийОстатки.Физлицо,

|	ВзаиморасчетыСРаботникамиОрганизацийОстатки.СуммаВзаиморасчетовОстаток

|ИЗ

|	РегистрНакопления.ВзаиморасчетыСРаботникамиОрганизаций.Остатки(&МомВрем, Физлицо = &Физик) КАК ВзаиморасчетыСРаботникамиОрганизацийОстатки";

МомВрем = Документы.НачислениеЗарплатыРаботникамОрганизаций.НайтиПоНомеру("00012","31.12.2009 23:59:59");

Запрос.УстановитьПараметр("МомВрем", Новый Граница(МомВрем.МоментВремени(), ВидГраницы.Включая));

Запрос.УстановитьПараметр("Физик", Справочники.ФизическиеЛица.НайтиПоКоду("365"));	

ВывестиРезультат(Запрос.Выполнить());

Пример получения остатков на дату документа, включая его движения

Код 1C v 8.х

  Запрос = Новый Запрос;

Запрос.Текст = 

"ВЫБРАТЬ

|	ВзаиморасчетыСРаботникамиОрганизацийОстатки.Физлицо,

|	ВзаиморасчетыСРаботникамиОрганизацийОстатки.СуммаВзаиморасчетовОстаток

|ИЗ

|	РегистрНакопления.ВзаиморасчетыСРаботникамиОрганизаций.Остатки(&МомВрем, Физлицо = &Физик) КАК ВзаиморасчетыСРаботникамиОрганизацийОстатки";

МомВрем = Документы.НачислениеЗарплатыРаботникамОрганизаций.НайтиПоНомеру("00012","31.12.2009 23:59:59");

Запрос.УстановитьПараметр("МомВрем", Новый Граница(МомВрем.МоментВремени(), ВидГраницы.Исключая));

// или так: Запрос.УстановитьПараметр("МомВрем", МомВрем.МоментВремени());

Запрос.УстановитьПараметр("Физик", Справочники.ФизическиеЛица.НайтиПоКоду("365"));	

ВывестиРезультат(Запрос.Выполнить());

Категория: Регистры накопления

Момент Времени и Граница, назначение, примеры использования Категория: Работа с Датами (Временем)