вызватьисключение » Поиск

Результаты по ключевому слову: вызватьисключение

Как отсканировать штрихкод на мобильном устройстве

//не забываем в свойствах конфигурации установить Требуемые разрешения "Мультимедиа"

Код 1C v 8.3

 
&НаКлиенте
Процедура ЗапуститьСканирование()
	
	#Если МобильноеПриложениеКлиент  Тогда
		 Если НЕ СредстваМультимедиа.ПоддерживаетсяСканированиеШтрихКодов() Тогда
    		ВызватьИсключение НСтр("ru='Сканирование штрихкодов не поддерживается';en='Barcode scanning is not supported'");
			Возврат;
  		КонецЕсли;
		ОбработчикСканирования = Новый ОписаниеОповещения("ОбработкаСканирования", ЭтаФорма);
  		ОбработчикЗакрытия = Новый ОписаниеОповещения("ОбработкаЗакрытияИнтерфейса", ЭтаФорма);
  		СредстваМультимедиа.ПоказатьСканированиеШтрихКодов(НСтр("ru='Наведите камеру на штрихкод';en='Aim the camera at an barcode'"), ОбработчикСканирования, ОбработчикЗакрытия, ТипШтрихКода.Линейный);
	#конецесли

КонецПроцедуры	


&НаКлиенте
Процедура ОбработкаСканирования(Штрихкод, Результат, Сообщение, ДополнительныеПараметры) Экспорт
	
	пТовар    = "";
	
	Если Результат Тогда
		
		Структура = ОбщегоНазначенияСервер.ПоискПоШтрихкодуОбъекта(ШтрихКод);			     			
		Если Структура = Неопределено Тогда
			пТовар = Неопределено;
			//#Если МобильноеПриложениеКлиент  Тогда
			//	СредстваМультимедиа.ЗакрытьСканированиеШтрихКодов();
			//#конецесли
			Сообщение = "Не найден объект по штрихкоду " + Штрихкод;
		Иначе
			пТовар    = Структура.Наименование;
			
			Сообщение = сокрЛП(пТовар) + Символы.ПС + Штрихкод;
						
			ДобавитьТоварВТаблицу(пТовар);
			
		КонецЕсли;
		
	КонецЕсли;
	
КонецПроцедуры

&НаКлиенте
Процедура ОбработкаЗакрытияИнтерфейса(ДополнительныеПараметры) Экспорт
	
	//Если ЗначениеЗаполнено(пТовар) Тогда
	//	можем встроить код открытия формы ввода количества
	//КонецЕсли;	

КонецПроцедуры

Категория: Мобильное приложение

Функции для работы с ZIP-архивами

В работе часто приходится сжимать выгруженные данные в zip архив, отправлять по почте, и потом автоматически разархивировать полученный zip файл:

Код 1C v 8.х

 // Распаковывает файл архива ZIP в указанный каталог; Извлекает все файлы архива
//
// Параметры:
//  ПолноеИмяФайлаАрхива  - Строка - имя файла архива, который необходимо распаковать
//  ПутьРаспаковкиФайлов  - Строка - путь по которому необходимо распаковать файлы
//  ПарольАрхива          - Строка - пароль для распаковки архива. По умолчанию пустая строка
// 
// Возвращаемое значение:
//  Результат - Булево - Истина, если успешно, Ложь, если нет.
//
Функция РаспаковатьZipФайл(Знач ПолноеИмяФайлаАрхива, Знач ПутьРаспаковкиФайлов, Знач ПарольАрхива = "") Экспорт
	
	// возвращаемое значение функции
	Результат = Истина;
	
	Попытка
		
		Архиватор = Новый ЧтениеZipФайла(ПолноеИмяФайлаАрхива, ПарольАрхива);
		
	Исключение
		Архиватор = Неопределено;
		СообщитьОбОшибке(КраткоеПредставлениеОшибки(ИнформацияОбОшибке()));
		Возврат Ложь;
	КонецПопытки;
	
	Попытка
		
		Архиватор.ИзвлечьВсе(ПутьРаспаковкиФайлов, РежимВосстановленияПутейФайловZIP.НеВосстанавливать);
		
	Исключение
		
		СтрокаСообщения = НСтр("ru = 'Ошибка при распаковке файлов архива: %1 в каталог: %2'");
		СтрокаСообщения = ПодставитьПараметрыВСтроку(СтрокаСообщения, ПолноеИмяФайлаАрхива, ПутьРаспаковкиФайлов);
		Сообщить(СтрокаСообщения);
		
		Результат = Ложь;
	КонецПопытки;
	
	Архиватор.Закрыть();
	Архиватор = Неопределено;
	
	Возврат Результат;
	
КонецФункции


// Запаковывает указанный каталог в файл архива ZIP
//
// Параметры:
//  ПолноеИмяФайлаАрхива  - Строка - имя файла архива, в который необходимо запаковать
//  МаскаУпаковкиФайлов    - Строка - имя файла, помещаемого в архив, или маска.
//			Недопустимо использование в именах файлов и папок букв национальных алфавитов, которые при 
//			преобразовании из символов UNICODE в узкие символы могут быть преобразованы с потерей информации. 
//			Рекомендуется использовать в именах файлов и папок символы латинского алфавита. 
//  ПарольАрхива          - Строка - пароль для архива. По умолчанию пустая строка
// 
// Возвращаемое значение:
//  Результат - Булево - Истина, если успешно, Ложь, если нет.
//
Функция ЗапаковатьВZipФайл(Знач ПолноеИмяФайлаАрхива, Знач МаскаУпаковкиФайлов, Знач ПарольАрхива = "") Экспорт
	
	// возвращаемое значение функции
	Результат = Истина;
	
	Попытка
		
		Архиватор = Новый ЗаписьZipФайла(ПолноеИмяФайлаАрхива, ПарольАрхива);
		
	Исключение
		Архиватор = Неопределено;
		СообщитьОбОшибке(КраткоеПредставлениеОшибки(ИнформацияОбОшибке()));
		Возврат Ложь;
	КонецПопытки;
	
	Попытка
		
		Архиватор.Добавить(МаскаУпаковкиФайлов, РежимСохраненияПутейZIP.НеСохранятьПути);
		Архиватор.Записать();
		
	Исключение
		
		СтрокаСообщения = НСтр("ru = 'Ошибка при запаковке файлов архива: %1 из каталог: %2'");
		СтрокаСообщения = ПодставитьПараметрыВСтроку(СтрокаСообщения, ПолноеИмяФайлаАрхива, МаскаУпаковкиФайлов);
		Сообщить(СтрокаСообщения);
		
		Результат = Ложь;
	КонецПопытки;
	
	Архиватор = Неопределено;
	
	Возврат Результат;
	
КонецФункции

В примере используется строковая функция ПодставитьПараметрыВСтроку():

Код 1C v 8.х

 // Подставляет параметры в строку. Максимально возможное число параметров - 9.
// Параметры в строке задаются как %<номер параметра>. Нумерация параметров начинается с единицы.
//
// Параметры:
//  СтрокаПодстановки  – Строка – шаблон строки с параметрами (вхождениями вида "%ИмяПараметра");
//  Параметр<n>        - Строка - подставляемый параметр.
//
// Возвращаемое значение:
//  Строка   – текстовая строка с подставленными параметрами.
//
// Пример:
//  ПодставитьПараметрыВСтроку(НСтр("ru='%1 пошел в %2'"), "Вася", "Зоопарк") = "Вася пошел в Зоопарк".
//
Функция ПодставитьПараметрыВСтроку(Знач СтрокаПодстановки,
	Знач Параметр1,	Знач Параметр2 = Неопределено, Знач Параметр3 = Неопределено,
	Знач Параметр4 = Неопределено, Знач Параметр5 = Неопределено, Знач Параметр6 = Неопределено,
	Знач Параметр7 = Неопределено, Знач Параметр8 = Неопределено, Знач Параметр9 = Неопределено) Экспорт
	
	Если СтрокаПодстановки = Неопределено ИЛИ СтрДлина(СтрокаПодстановки) = 0 Тогда
		Возврат "";
	КонецЕсли;
	
	Результат = "";
	НачПозиция = 1;
	Позиция = 1;
	Пока Позиция <= СтрДлина(СтрокаПодстановки) Цикл
		СимволСтроки = Сред(СтрокаПодстановки, Позиция, 1);
		Если СимволСтроки <> "%" Тогда
			Позиция = Позиция + 1;
			Продолжить;
		КонецЕсли;
		Результат = Результат + Сред(СтрокаПодстановки, НачПозиция, Позиция - НачПозиция);
		Позиция = Позиция + 1;
		СимволСтроки = Сред(СтрокаПодстановки, Позиция, 1);
		
		Если СимволСтроки = "%" Тогда
			Позиция = Позиция + 1;
			НачПозиция = Позиция;
			Результат = Результат + "%";
			Продолжить;
		КонецЕсли;
		
		Попытка
			НомерПараметра = Число(СимволСтроки);
		Исключение
			ВызватьИсключение НСтр("ru='Входная строка СтрокаПодстановки имеет неверный формат: %'" + СимволСтроки);
		КонецПопытки;
		
		Если СимволСтроки = "1" Тогда
			ЗначениеПараметра = Параметр1;
		ИначеЕсли СимволСтроки = "2" Тогда
			ЗначениеПараметра = Параметр2;
		ИначеЕсли СимволСтроки = "3" Тогда
			ЗначениеПараметра = Параметр3;
		ИначеЕсли СимволСтроки = "4" Тогда
			ЗначениеПараметра = Параметр4;
		ИначеЕсли СимволСтроки = "5" Тогда
			ЗначениеПараметра = Параметр5;
		ИначеЕсли СимволСтроки = "6" Тогда
			ЗначениеПараметра = Параметр6;
		ИначеЕсли СимволСтроки = "7" Тогда
			ЗначениеПараметра = Параметр7;
		ИначеЕсли СимволСтроки = "8" Тогда
			ЗначениеПараметра = Параметр8;
		ИначеЕсли СимволСтроки = "9" Тогда
			ЗначениеПараметра = Параметр9;
		Иначе
			ВызватьИсключение НСтр("ru='Входная строка СтрокаПодстановки имеет неверный формат: %'" + ЗначениеПараметра);
		КонецЕсли;
		Если ЗначениеПараметра = Неопределено Тогда
			ЗначениеПараметра = "";
		Иначе
			ЗначениеПараметра = Строка(ЗначениеПараметра);
		КонецЕсли;
		Результат = Результат + ЗначениеПараметра;
		Позиция = Позиция + 1;
		НачПозиция = Позиция;
	
	КонецЦикла;
	
	Если (НачПозиция <= СтрДлина(СтрокаПодстановки)) Тогда
		Результат = Результат + Сред(СтрокаПодстановки, НачПозиция, СтрДлина(СтрокаПодстановки) - НачПозиция + 1);
	КонецЕсли;
	
	Возврат Результат;
	
КонецФункции

Категория: Работа с Файлами и Каталогами

Обход метаданных (полезные функции)

При написании небольших автоматизированных тестов часто надо обойти всю конфигурацию и проверить, например, для всех форм какое-нибудь свойство. Это всё легко делается через свойство глобального контекста "Метаданные", но чтоб дорбаться до обхода реквизитов надо написать кучу вложенных циклов. При этом код становится слабочитаемым и слабомодифицируемым.

Ниже приведен небольшой модуль, который решает задачу легко и удобно. Создана специальная функция РазвернутьСтрокуОбходаМетаданных, которая может по строке типа "Метаданные.Справочники.*.Реквизиты.*" построить массив строк с перечислением всех реквизитов всех справочников. При помощи этой и нескольких других функций в экспортных функциях модуля реализованы вполне прикладные задачи - получение всех реквизитов, всех макетов, всех форм конфигурации и построение таблицы всех составных типов.

Код 1C v 8.х

  // Автор: Alexander Speshilov
// Рекрсивная функция, которая разворачивает строку вида "Метаданные.Справочники.*[Имя].Реквизиты.*.Тип" 
// в массив строк, заменяя "*" или другой символ, задаваемый параметрами обходом всех элементов 
// коллекции. Допускает выполнение функций встроенного языка (не стоит отдавать ввод параметров 
// пользователям). При этом выражение, используемое для получения по умолчанию может быть задано в 
// квадратных скобках или параметром функции.
//
// Параметры
//  СтрокаОбхода  - Строка - Разворачиваемая строка
//  ЗаменяемоеЗначение  - Строка - заменяемое значение
//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления
//
// Возвращаемое значение:
//   Массив строк
//
Функция РазвернутьСтрокуОбходаМетаданных(СтрокаОбхода, ЗаменяемоеЗначение = "*", ПредставлениеПоУмолчанию = "")
    
    Рез = Новый Массив;
    
    ЧастиСтрокиОбхода = РазобратьСтрокуОбхода(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);
    Если ЧастиСтрокиОбхода = Неопределено тогда 
        Рез.Добавить(СтрокаОбхода); //фактически это ограничение рекурсии.
    Иначе
        ОбъектКоллекции = Вычислить(ЧастиСтрокиОбхода.СтрокаКоллекции);
        РазвернутаяКоллекция = РазвернутьКоллекциюВПредставления(ОбъектКоллекции, ЧастиСтрокиОбхода.СтрокаПредставление);
        Для каждого ЭлементРазвернутойКоллекции Из РазвернутаяКоллекция Цикл
            
            // рекурсивный вызов
            ТекущаяСтрокаОбхода = ЧастиСтрокиОбхода.СтрокаНачало + ЭлементРазвернутойКоллекции + ЧастиСтрокиОбхода.СтрокаКонец;
            МассивЭлемента = РазвернутьСтрокуОбходаМетаданных(ТекущаяСтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);
            
            Для каждого ПримитивныйЭлементОбхода Из МассивЭлемента Цикл
                Рез.Добавить(ПримитивныйЭлементОбхода);
            КонецЦикла;
            
        КонецЦикла;
    КонецЕсли;
    
    Возврат Рез;
    
КонецФункции // РазвернутьСтрокуОбходаМетаданных()

// Разбирает строку обхода на удобные для работы поля
//
// Параметры
//  СтрокаОбхода  - Строка - Разворачиваемая строка
//  ЗаменяемоеЗначение  - Строка - заменяемое значение
//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления
//
// Возвращаемое значение:
//   Структура с полями ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец
// или Неопределено (если строка не содержит ЗаменяемоеЗначение)
//
Функция РазобратьСтрокуОбхода(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию)
    
    Если ПустаяСтрока(ЗаменяемоеЗначение) Тогда 
        ВызватьИсключение "Некорректное выражение заменяемого значения";
    КонецЕсли;
    
    ПозицияЗамены = Найти(СтрокаОбхода, ЗаменяемоеЗначение);
    
    // Если не найдена строка - возвращаем неопределено, как индикатор
    Если ПозицияЗамены = 0 Тогда 
        Возврат Неопределено; 
    КонецЕсли;
    
    СтрокаНачало = Лев(СтрокаОбхода,ПозицияЗамены - 1);
    
    //Получение строки для выражения-коллекции
    СтрокаКоллекции = СтрокаНачало;
    Если Прав(СтрокаКоллекции, 1) = "." Тогда 
        СтрокаКоллекции = Лев(СтрокаКоллекции,СтрДлина(СтрокаКоллекции) - 1);
    КонецЕсли;
    
    ПозицияОкончанияЗамены = ПозицияЗамены + СтрДлина(ЗаменяемоеЗначение);
    
    ОстатокВыражения = Сред(СтрокаОбхода, ПозицияОкончанияЗамены);
    
    //Обработка явного задания представления
    ОткрывающаяСкобка = "[";
    ЗакрывающаяСкобка = "]";
    Если Найти(ОстатокВыражения, ОткрывающаяСкобка) = 1 Тогда
        ОстатокВыражения = Сред(ОстатокВыражения, СтрДлина(ОткрывающаяСкобка) + 1);
        ПозицияЗакрывающейСкобки = Найти(ОстатокВыражения, ЗакрывающаяСкобка);
        Если ПозицияЗакрывающейСкобки = 0 Тогда 
            ВызватьИсключение "Синтаксическая ошибка разбора выражения";
        КонецЕсли;
        СтрокаПредставление = Лев(ОстатокВыражения, ПозицияЗакрывающейСкобки - 1);
        ОстатокВыражения = Сред(ОстатокВыражения, ПозицияЗакрывающейСкобки + СтрДлина(ЗакрывающаяСкобка));
    Иначе
        СтрокаПредставление = ПредставлениеПоУмолчанию;
    КонецЕсли;
    СтрокаКонец = ОстатокВыражения;
    
    Рез = Новый Структура("ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец",
    ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец);
    
    Возврат Рез;
    
КонецФункции // РазобратьСтрокуОбхода()

// Разворачивает объект коллекции в массив представления элементов
//
// Параметры
//  Коллекция  - Произвольный - Коллекция, которую можно обойти через "Для каждого"
//  ПредставлениеЭлемента  - Строка - необяз., свойство элементов коллекции, которое 
//               используется для получения представления.
//
// Возвращаемое значение:
//   Массив   - Массив представлений коллекции
//
Функция РазвернутьКоллекциюВПредставления(Коллекция, Знач ПредставлениеЭлемента = "")
    
    //Проверка и подгонка параметров
    Если не ПустаяСтрока(ПредставлениеЭлемента) Тогда 
        Если Найти(ПредставлениеЭлемента, ";")>0 Тогда 
            ВызватьИсключение "Некорректное выражение представления";
        КонецЕсли;
        ПредставлениеЭлемента = "." + ПредставлениеЭлемента;
    КонецЕсли;
    
    Рез = Новый Массив;
    Для каждого ЭлементКоллекции Из Коллекция Цикл
        ТекПредставление = Строка(Вычислить("ЭлементКоллекции" + ПредставлениеЭлемента));
        Рез.Добавить(ТекПредставление);
    КонецЦикла; 
    Возврат Рез;
    
КонецФункции // РазвернутьКоллекцию()

// Разворачивает массив строк через РазвернутьСтрокуОбходаМетаданных
//
// Параметры
//  МассивСтрокОбхода  - Массив - Массив разворачиваемых строк
//  ЗаменяемоеЗначение  - Строка - заменяемое значение
//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления
//
// Возвращаемое значение:
//   Массив строк
//
Функция РазвернутьМассивСтрокОбходаМетаданных(МассивСтрокОбхода, ЗаменяемоеЗначение = "*", ПредставлениеПоУмолчанию = "Имя")
    
    Рез = Новый Массив;
    
    Для каждого СтрокаОбхода Из МассивСтрокОбхода Цикл
        
        ДополнениеРезультата = РазвернутьСтрокуОбходаМетаданных(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);
        Для каждого ТекСтрока Из ДополнениеРезультата Цикл
            Рез.Добавить(ТекСтрока);
        КонецЦикла; 
        
    КонецЦикла; 
    
    Возврат Рез;
    
КонецФункции // РазвернутьМассивСтрокОбходаМетаданных()

// Преобразует строку в массив одиночных строк по разделителю Символы.ПС
//
// Параметры
//  ПреобразуемаяСтрока - строка для преобразования
//    ИгнорироватьПустые - Булево - Пропускать пустые строки
//  СокращатьПробелы - Использовать СокрЛП
//
// Возвращаемое значение:
//   Массив строк
//
Функция ПолучитьМассивСтрокМногострочнойСтроки(ПреобразуемаяСтрока, ИгнорироватьПустые = Истина, СокращатьПробелы = Истина)
    
    Рез = Новый Массив;
    ЧислоСтрок = СтрЧислоСтрок(ПреобразуемаяСтрока);
    
    Для Сч = 1 По ЧислоСтрок Цикл
        
        ТекСтрока = СтрПолучитьСтроку(ПреобразуемаяСтрока, Сч);
        Если ИгнорироватьПустые и ПустаяСтрока(ТекСтрока) Тогда
            Продолжить;
        КонецЕсли; 
        Если СокращатьПробелы Тогда
            ТекСтрока = СокрЛП(ТекСтрока);
        КонецЕсли; 
        Рез.Добавить(ТекСтрока);
        
    КонецЦикла;
    
    Возврат Рез;
    
КонецФункции // ПолучитьМассивСтрокМногострочнойСтроки()

// Возвращает все реквизиты конфигурации, которые сохраняются в ИБ
//
// Параметры - Нет
//
// Возвращаемое значение:
//   Массив объектов метаданных
//
Функция ПолучитьВсеХранимыеРеквизитыКонфигурации() Экспорт
    
    СтрокаВсехРеквизитов = 
    "
    |Метаданные.Константы.*
    |Метаданные.ПланыОбмена.*.Реквизиты.*
    |Метаданные.ПланыОбмена.*.ТабличныеЧасти.*.Реквизиты.*
    |Метаданные.Справочники.*.Реквизиты.*
    |Метаданные.Справочники.*.ТабличныеЧасти.*.Реквизиты.*
    |Метаданные.Документы.*.Реквизиты.*
    |Метаданные.Документы.*.ТабличныеЧасти.*.Реквизиты.*
    |Метаданные.Последовательности.*.Измерения.*
    |Метаданные.ПланыВидовХарактеристик.*.Реквизиты.*
    |Метаданные.ПланыВидовХарактеристик.*.ТабличныеЧасти.*.Реквизиты.*
    |Метаданные.ПланыСчетов.*.Реквизиты.*
    |Метаданные.ПланыСчетов.*.ПризнакиУчета.*
    |Метаданные.ПланыСчетов.*.ПризнакиУчетаСубконто.*
    |Метаданные.ПланыСчетов.*.ТабличныеЧасти.*.Реквизиты.*
    |Метаданные.ПланыВидовРасчета.*.Реквизиты.*
    |Метаданные.ПланыВидовРасчета.*.ТабличныеЧасти.*.Реквизиты.*
    |Метаданные.РегистрыСведений.*.Измерения.*
    |Метаданные.РегистрыСведений.*.Ресурсы.*
    |Метаданные.РегистрыСведений.*.Реквизиты.*
    |Метаданные.РегистрыНакопления.*.Измерения.*
    |Метаданные.РегистрыНакопления.*.Ресурсы.*
    |Метаданные.РегистрыНакопления.*.Реквизиты.*
    |Метаданные.РегистрыБухгалтерии.*.Измерения.*
    |Метаданные.РегистрыБухгалтерии.*.Ресурсы.*
    |Метаданные.РегистрыБухгалтерии.*.Реквизиты.*
    |Метаданные.РегистрыРасчета.*.Измерения.*
    |Метаданные.РегистрыРасчета.*.Ресурсы.*
    |Метаданные.РегистрыРасчета.*.Реквизиты.*
    |Метаданные.БизнесПроцессы.*.Реквизиты.*
    |Метаданные.БизнесПроцессы.*.ТабличныеЧасти.*.Реквизиты.*
    |Метаданные.Задачи.*.Реквизиты.*
    |Метаданные.Задачи.*.РеквизитыАдресации.*
    |Метаданные.Задачи.*.ТабличныеЧасти.*.Реквизиты.*
    |";
    ВсеХранимыеРеквизитыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));
    Возврат ВсеХранимыеРеквизитыКонфигурации;
    
КонецФункции // ПолучитьВсеХранимыеРеквизитыКонфигурации()

// Возвращает все реквизиты конфигурации составного типа, которые сохраняются в ИБ
//
// Параметры - Нет
//
// Возвращаемое значение:
//   ТаблицаЗначений
//
Функция ПолучитьВсеХранимыеРеквизитыКонфигурацииСоставногоТипа() Экспорт
    
    ВсеХранимыеРеквизитыКонфигурации = ПолучитьВсеХранимыеРеквизитыКонфигурации();
    Рез = Новый ТаблицаЗначений;
    Рез.Колонки.Добавить("Имя", Новый ОписаниеТипов("Строка"));
    Рез.Колонки.Добавить("Тип", Новый ОписаниеТипов("ОписаниеТипов"));
    Рез.Колонки.Добавить("КоличествоПростыхТипов", Новый ОписаниеТипов("Число"));
    
    Для каждого ТекРеквизит Из ВсеХранимыеРеквизитыКонфигурации Цикл
        
        Реквизит = Вычислить(ТекРеквизит);
        Тип = Реквизит.Тип;
        КоличествоПростыхТипов = Тип.Типы().Количество();
        Если КоличествоПростыхТипов<>1 Тогда 
    	    ТекСтрока = Рез.Добавить();
            ТекСтрока.Имя = ТекРеквизит;
            ТекСтрока.Тип = Тип;
            ТекСтрока.КоличествоПростыхТипов = КоличествоПростыхТипов;
        КонецЕсли;
    
    КонецЦикла; 
    
    Возврат Рез;
    
КонецФункции // ПолучитьВсеХранимыеРеквизитыКонфигурации()

// Возвращает все формы конфигурации
//
// Параметры - Нет
//
// Возвращаемое значение:
//   Массив объектов метаданных
//
Функция ПолучитьВсеФормыКонфигурации() Экспорт
    
    СтрокаВсехРеквизитов = 
    "
    |Метаданные.ПланыОбмена.*.Формы.*
    |Метаданные.КритерииОтбора.*.Формы.*
    |Метаданные.ОбщиеФормы.*
    |Метаданные.Справочники.*.Формы.*
    |Метаданные.Документы.*.Формы.*
    |Метаданные.ЖурналыДокументов.*.Формы.*
    |Метаданные.Перечисления.*.Формы.*
    |Метаданные.Отчеты.*.Формы.*
    |Метаданные.Обработки.*.Формы.*
    |Метаданные.ПланыВидовХарактеристик.*.Формы.*
    |Метаданные.ПланыСчетов.*.Формы.*
    |Метаданные.ПланыВидовРасчета.*.Формы.*
    |Метаданные.РегистрыСведений.*.Формы.*
    |Метаданные.РегистрыНакопления.*.Формы.*
    |Метаданные.РегистрыБухгалтерии.*.Формы.*
    |Метаданные.РегистрыРасчета.*.Формы.*
    |Метаданные.БизнесПроцессы.*.Формы.*
    |Метаданные.Задачи.*.Формы.*
    |";
    ВсеФормыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));
    Возврат ВсеФормыКонфигурации;
    
КонецФункции // ПолучитьВсеФормыКонфигурации()

// Возвращает все макеты конфигурации
//
// Параметры - Нет
//
// Возвращаемое значение:
//   Массив объектов метаданных
//
Функция ПолучитьВсеМакетыКонфигурации() Экспорт
    
    СтрокаВсехРеквизитов = 
    "
    |Метаданные.ПланыОбмена.*.Макеты.*
    |Метаданные.ОбщиеМакеты.*
    |Метаданные.Справочники.*.Макеты.*
    |Метаданные.Документы.*.Макеты.*
    |Метаданные.ЖурналыДокументов.*.Макеты.*
    |Метаданные.Перечисления.*.Макеты.*
    |Метаданные.Отчеты.*.Макеты.*
    |Метаданные.Обработки.*.Макеты.*
    |Метаданные.ПланыВидовХарактеристик.*.Макеты.*
    |Метаданные.ПланыСчетов.*.Макеты.*
    |Метаданные.ПланыВидовРасчета.*.Макеты.*
    |Метаданные.РегистрыСведений.*.Макеты.*
    |Метаданные.РегистрыНакопления.*.Макеты.*
    |Метаданные.РегистрыБухгалтерии.*.Макеты.*
    |Метаданные.РегистрыРасчета.*.Макеты.*
    |Метаданные.БизнесПроцессы.*.Макеты.*
    |Метаданные.Задачи.*.Макеты.*
    |";
    ВсеМакетыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));
    Возврат ВсеМакетыКонфигурации;
    
КонецФункции // ПолучитьВсеМакетыКонфигурации()

Категория: Метаданные

Определение текущего Пользователя в системе, подстановка пользователя в документы

1. Создаем справочник Пользователи
2. ПараметрыСеанса.ТекущийПользователь - тип справочник Пользователи
3. В модуле Сеанса пишем:

Код 1C v 8.2 УП

 Процедура УстановкаПараметровСеанса(ТребуемыеПараметры)
	ТекущийПользователь = ОбщийМодульСистема.ОпределитьТекущегоПользователя();
	ПараметрыСеанса.ТекущийПользователь = ТекущийПользователь;
КонецПроцедуры

4. Создаем общий модуль ОбщийМодульСистема в нем пишем:

Код 1C v 8.2 УП

 // Функция возвращает ссылку на элемент справочника "Пользователи",
// соответствующий текущему пользователю информационной базы.
Функция ОпределитьТекущегоПользователя() экспорт

	Если ПустаяСтрока(ИмяПользователя()) Тогда
		ИмяПользователя           = "НеАвторизован";
		ПолноеИмяПользователя     = "Не авторизован";        
	Иначе
		ИмяПользователя           = ИмяПользователя();
		
		Если ПустаяСтрока(ПолноеИмяПользователя()) Тогда
			ПолноеИмяПользователя = ИмяПользователя;
		Иначе
			ПолноеИмяПользователя = ПолноеИмяПользователя();
		КонецЕсли;
	КонецЕсли;
	
	ДлинаКодаПользователя = Метаданные.Справочники.Пользователи.ДлинаКода;
	
	Если СтрДлина(ИмяПользователя) > ДлинаКодаПользователя Тогда
		ИмяПользователя = Лев(ИмяПользователя, ДлинаКодаПользователя);
	КонецЕсли; 
	
	Запрос = Новый Запрос;
	Запрос.Текст = "
	|ВЫБРАТЬ ПЕРВЫЕ 1
	|	Пользователи.Ссылка КАК Ссылка,
	|	Пользователи.ЭтоГруппа
	|ИЗ
	|	Справочник.Пользователи КАК Пользователи
	|ГДЕ
	|	Пользователи.Код = &Код";
	
	Запрос.УстановитьПараметр("Код", ИмяПользователя);
	Результат = Запрос.Выполнить();
	
	Если Результат.Пустой() Тогда
		
		ОбъектПользователь = Справочники.Пользователи.СоздатьЭлемент();
		
		ОбъектПользователь.Код          = ИмяПользователя;
		ОбъектПользователь.Наименование = ПолноеИмяПользователя;
    	Попытка
			ОбъектПользователь.Записать();
        Исключение
			ВызватьИсключение "Пользователь : " + ИмяПользователя + " не был найден в справочнике пользователей. Возникла ошибка при добавлении пользователя в справочник.
				|" + ОписаниеОшибки();
        
			Возврат Справочники.Пользователи.ПустаяСсылка();
			
		КонецПопытки;
        
		ТекущийПользователь = ОбъектПользователь.Ссылка;

    Иначе
        Выборка = Результат.Выбрать();
		Выборка.Следующий();
		
		Если Выборка.ЭтоГруппа Тогда
			ВызватьИсключение "Пользователь : " + ИмяПользователя + " не зарегистрирован. В справочнике присутствует группа с тем же именем";
		Иначе
			ТекущийПользователь = Выборка.Ссылка;
		КонецЕсли;	       
		
	КонецЕсли; 
       
    Возврат ТекущийПользователь;

КонецФункции 

Функция ПолучитьТекущегоПользователя() Экспорт 
	Возврат ПараметрыСеанса.ТекущийПользователь;	
КонецФункции

5. В документах пропишем Автоопределение Текущего пользователя

Код 1C v 8.2 УП

 &НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
Объект.Автор = ОбщийМодульСистема.ПолучитьТекущегоПользователя();
Объект.Фирма = Объект.Автор.Фирма;
КонецПроцедуры

Категория: Пользователь, роль доступа, интерфейс

Отмена создания документа в Обработке Заполнения Категория: Документы

Планы обмена и их использование Категория: Конвертация данных, Обмен, Перенос

Функция вычисляет даты начала/конца периодов за интервал в виде таблицы значений

Код 1C v 8.х

  //Начало, Конец - начало и конец периода
//Периодичность - строка "День", "Месяц", "Неделя", "Год", "Квартал"
//Возвращает таблицу значений с колонками:
//	Начало - начало интервала
//	Конец - конец интервала
//	Номер - номер интервала (начиная с единицы)
Функция обПериодыЗаИнтервал(Начало, Конец, Периодичность="День", ВыравниваниеПоПериоду=истина)
	Перем Р, Номер, ТекПериод, СледПериод;
	Р=Новый ТаблицаЗначений();
	Р.Колонки.Добавить("Начало");
	Р.Колонки.Добавить("Конец");
	Р.Колонки.Добавить("Номер");
	
	ТекПериод=Начало;
	Номер=1;
	Пока истина Цикл
		Если Периодичность="День" Тогда
			Если ВыравниваниеПоПериоду Тогда
				ТекПериод=НачалоДня(ТекПериод);
				СледПериод=КонецДня(ТекПериод);
			Иначе
				СледПериод=обДобавитьДни(ТекПериод, 1);
			КонецЕсли;
		ИначеЕсли Периодичность="Месяц" Тогда
			Если ВыравниваниеПоПериоду Тогда
				ТекПериод=НачалоМесяца(ТекПериод);
				СледПериод=КонецМесяца(ТекПериод);
			Иначе
				СледПериод=обДобавитьМесяцы(ТекПериод, 1);
			КонецЕсли;
		ИначеЕсли Периодичность="Год" Тогда
			Если ВыравниваниеПоПериоду Тогда
				ТекПериод=НачалоГода(ТекПериод);
				СледПериод=КонецГода(ТекПериод);
			Иначе
				СледПериод=обДобавитьМесяцы(ТекПериод, 12);
			КонецЕсли;
		ИначеЕсли Периодичность="Квартал" Тогда
			Если ВыравниваниеПоПериоду Тогда
				ТекПериод=НачалоКвартала(ТекПериод);
				СледПериод=КонецКвартала(ТекПериод);
			Иначе
				СледПериод=обДобавитьМесяцы(ТекПериод, 3);
			КонецЕсли;
		ИначеЕсли Периодичность="Неделя" Тогда
			Если ВыравниваниеПоПериоду Тогда
				ТекПериод=НачалоНедели(ТекПериод);
				СледПериод=КонецНедели(ТекПериод);
			Иначе
				СледПериод=обДобавитьДни(ТекПериод, 7);
			КонецЕсли;
		Иначе
			ВызватьИсключение "Неизвестная периодичность времени:"+Периодичность;
		КонецЕсли;
		Если ТекПериод>Конец И НЕ Номер=1 Тогда
			Прервать;
		КонецЕсли;
		
		Стр=Р.Добавить();
		Стр.Начало=ТекПериод;
		Стр.Конец=СледПериод;
		Стр.Номер=Номер;
		ТекПериод=СледПериод+1; //Переходим на следующий период (добавляем одну секунду)
		Номер=Номер+1;
	КонецЦикла;
	Возврат Р;
КонецФункции

Категория: Работа с Датами (Временем)