готовую » Поиск

Результаты по ключевому слову: готовую

Получение уникального идентификатора ссылки в СКД

Как известно, с помощью языка запросов 1С получить уникальный идентификатор объекта ссылочного типа на данный момент нельзя. Но используя возможность СКД обращаться к внешним функциям можно получить строковое представление уникального идентификатора ссылки. Для этого необходимо использовать глобальную функцию XMLСтрока в вычисляемых полях в макете схемы компоновки.

Далее проведем эксперимент по быстродействию получения результата через запрос с последующей обработкой выборки и вариантов с использованием СКД.

Рассмотрим два случая - вывод в табличный документ и формирование текстового документа.

Так же в случае с СКД мы можем создать схему компоновки программно или использовать готовую. Результат работы СКД так же можно обойти в цикле, либо вывести в таблицу значений с последующей обработкой. Для экспериментов будет использоваться платформа 8.3, конфигурация УТ11 (файловая), справочник "КлассификаторБанковРФ", более 4000 элементов.

Схему компоновки и макет можно посмотреть, скачав обработку (ссылка в конце).

Код 1C v 8.2 УП

 &НаКлиентеНаСервереБезКонтекста

Функция ПолучитьТекстЗапроса()





 Возврат "ВЫБРАТЬ

         | КлассификаторБанковРФ.Ссылка,

         | КлассификаторБанковРФ.Наименование

         |ИЗ

         | Справочник.КлассификаторБанковРФ КАК КлассификаторБанковРФ";





КонецФункции // ПолучитьТекстЗапроса()





&НаСервере

Функция ПолучитьСхемуОбработки()

 

 Возврат РеквизитФормыВЗначение("Отчет").ПолучитьМакет("Макет");

 

КонецФункции





&НаСервереБезКонтекста

Функция ПолучитьСхемуКомпоновки()

 

 Схема = Новый СхемаКомпоновкиДанных;

 

 ИсточникДанных = Схема.ИсточникиДанных.Добавить();

 ИсточникДанных.Имя = "Источник";

 ИсточникДанных.ТипИсточникаДанных = "Local";

 

 НаборДанных = Схема.НаборыДанных.Добавить(Тип("НаборДанныхЗапросСхемыКомпоновкиДанных"));

 НаборДанных.Имя = "НаборДанных";

 НаборДанных.ИсточникДанных = "Источник";

 НаборДанных.Запрос = ПолучитьТекстЗапроса();

 

 НаборСсылка = НаборДанных.Поля.Добавить(Тип("ПолеНабораДанныхСхемыКомпоновкиДанных"));

 НаборСсылка.Поле = "Ссылка";

 НаборСсылка.ПутьКДанным = "Ссылка";

 НаборНаименование= НаборДанных.Поля.Добавить(Тип("ПолеНабораДанныхСхемыКомпоновкиДанных"));

 НаборНаименование.Поле = "Наименование";

 НаборНаименование.ПутьКДанным = "Наименование";

 

 ПолеИД = Схема.ВычисляемыеПоля.Добавить();

 ПолеИД.Выражение = "XMLСтрока(Ссылка)";

 ПолеИД.Заголовок = "ИД";

 ПолеИД.ПутьКДанным = "ИД";

 

 СтрокаТЗ = Схема.НастройкиПоУмолчанию.Структура.Добавить(Тип("ГруппировкаКомпоновкиДанных"));

 СтрокаТЗ.Выбор.Элементы.Добавить(Тип("АвтоВыбранноеПолеКомпоновкиДанных"));

 

 ЭлементыВыбора = Схема.НастройкиПоУмолчанию.Выбор.Элементы;

 ПолеСсылка = ЭлементыВыбора.Добавить(Тип("ВыбранноеПолеКомпоновкиДанных"));

 ПолеСсылка.Поле = Новый ПолеКомпоновкиДанных("Ссылка");

 ПолеНаименование = ЭлементыВыбора.Добавить(Тип("ВыбранноеПолеКомпоновкиДанных"));

 ПолеНаименование.Поле = Новый ПолеКомпоновкиДанных("Наименование");

 ПолеИД = ЭлементыВыбора.Добавить(Тип("ВыбранноеПолеКомпоновкиДанных"));

 ПолеИД.Поле = Новый ПолеКомпоновкиДанных("ИД");

 

 Возврат Схема;

 

КонецФункции





&НаСервереБезКонтекста

Функция ЗаполнитьПоКомпоновкеПрямойОбход(Схема)





 Док = Новый ТекстовыйДокумент;

 

 КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;

 Макет = КомпоновщикМакета.Выполнить(Схема, Схема.НастройкиПоУмолчанию,,, Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений")); 

 

 ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;

 ПроцессорКомпоновки.Инициализировать(Макет,,, Истина);

 

 ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;

 ПроцессорВывода.УстановитьОбъект(Новый ТаблицаЗначений);

 ПроцессорВывода.НачатьВывод();

 

 Пока Истина Цикл

  

  ЭлементКомпоновки = ПроцессорКомпоновки.Следующий();

  Если ЭлементКомпоновки = Неопределено Тогда

   Прервать;

  КонецЕсли;

  

  ПроцессорВывода.ВывестиЭлемент(ЭлементКомпоновки);

  Если ЭлементКомпоновки.Макет = "Макет2" И ЭлементКомпоновки.ТипЭлемента = ТипЭлементаРезультатаКомпоновкиДанных.НачалоИКонец Тогда

   Док.ДобавитьСтроку(ЭлементКомпоновки.ЗначенияПараметров.П2.Значение + ";" + ЭлементКомпоновки.ЗначенияПараметров.П3.Значение);

  КонецЕсли;

  

 КонецЦикла;

 

 ТЗ = ПроцессорВывода.ЗакончитьВывод();

 

 Возврат Док;





КонецФункции // ЗаполнитьПоКомпоновкеПрямойОбход()





&НаСервере

Функция ЗаполнитьОбходТЗ(ИспользоватьСхемуОбработки)





 Если ИспользоватьСхемуОбработки Тогда

  Схема = ПолучитьСхемуОбработки();

 Иначе

  Схема = ПолучитьСхемуКомпоновки();

 КонецЕсли;

 

 Возврат ЗаполнитьПоКомпоновкеОбходТЗ(Схема);





 //Возврат ЗаполнитьПоКомпоновкеОбходТЗ(?(ИспользоватьСхемуОбработки, ПолучитьСхемуОбработки(), ПолучитьСхемуКомпоновки()));

 

КонецФункции // ЗаполнитьОбходТЗ()





&НаСервере

Функция ЗаполнитьПрямойОбход(ИспользоватьСхемуОбработки)





 Если ИспользоватьСхемуОбработки Тогда

  Схема = ПолучитьСхемуОбработки();

 Иначе

  Схема = ПолучитьСхемуКомпоновки();

 КонецЕсли;

 

 Возврат ЗаполнитьПоКомпоновкеПрямойОбход(Схема);

 //Возврат ЗаполнитьПоКомпоновкеПрямойОбход(?(ИспользоватьСхемуОбработки, ПолучитьСхемуОбработки(), ПолучитьСхемуКомпоновки()));





КонецФункции // ЗаполнитьОбходТЗ()





&НаСервереБезКонтекста

Функция ЗаполнитьПоКомпоновкеОбходТЗ(Схема)





 Док = Новый ТекстовыйДокумент;

 

 КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;

 Макет = КомпоновщикМакета.Выполнить(Схема, Схема.НастройкиПоУмолчанию,,, Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений")); 

 

 ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;

 ПроцессорКомпоновки.Инициализировать(Макет,,, Истина);

 

 ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;

 ПроцессорВывода.УстановитьОбъект(Новый ТаблицаЗначений);

 ТЗ = ПроцессорВывода.Вывести(ПроцессорКомпоновки);

 

 Для Каждого СтрокаТЗ Из ТЗ Цикл

  Док.ДобавитьСтроку(СтрокаТЗ.Наименование + ";" + СтрокаТЗ.ИД);

 КонецЦикла;

 

 Возврат Док;





КонецФункции // ЗаполнитьПоКомпоновкеОбходТЗ()





&НаСервереБезКонтекста

Функция ЗаполнитьПоЗапросу()





 Док = Новый ТекстовыйДокумент;

 

 Запрос = Новый Запрос(ПолучитьТекстЗапроса());

 Результат = Запрос.Выполнить().Выбрать();

 Пока Результат.Следующий() Цикл

  Док.ДобавитьСтроку(Результат.Наименование + ";" + XMLСтрока(Результат.Ссылка));

 КонецЦикла;

 

 Возврат Док;





КонецФункции // ЗаполнитьПоЗапросу()





&НаСервере

Процедура ЗаполнитьТабДокСхема(ИспользоватьСхемуОбработки)





 Если ИспользоватьСхемуОбработки Тогда

  Схема = ПолучитьСхемуОбработки();

  ТабДок = ТабДок1;

 Иначе

  Схема = ПолучитьСхемуКомпоновки();

  ТабДок = ТабДок2;

 КонецЕсли;

 

 КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;

 Макет = КомпоновщикМакета.Выполнить(Схема, Схема.НастройкиПоУмолчанию); 

 

 ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;

 ПроцессорКомпоновки.Инициализировать(Макет,,, Истина);

 

 ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;

 ПроцессорВывода.УстановитьДокумент(ТабДок);

 ПроцессорВывода.Вывести(ПроцессорКомпоновки);





КонецПроцедуры // ЗаполнитьТабДокСхема()





&НаСервере

Процедура ЗаполнитьТабДокЗапрос()

 

 Макет = РеквизитФормыВЗначение("Отчет").ПолучитьМакет("Отчет");

 ОбластьСтрока = Макет.ПолучитьОбласть("Строка");

 

 Запрос = Новый Запрос(ПолучитьТекстЗапроса());

 Результат = Запрос.Выполнить().Выбрать();

 Пока Результат.Следующий() Цикл

  ОбластьСтрока.Параметры.Заполнить(Результат);

  ОбластьСтрока.Параметры.ИД = XMLСтрока(Результат.Ссылка);

  ТабДок3.Вывести(ОбластьСтрока);

 КонецЦикла;

 

КонецПроцедуры





&НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

 

 ЗаполнитьТабДокСхема(Истина);

 ЗаполнитьТабДокСхема(Ложь);

 ЗаполнитьТабДокЗапрос();

 

 Т1 = ЗаполнитьПоЗапросу(); 

 Т2 = ЗаполнитьОбходТЗ(Ложь);

 Т3 = ЗаполнитьОбходТЗ(Истина);

 Т4 = ЗаполнитьПрямойОбход(Ложь);

 Т5 = ЗаполнитьПрямойОбход(Истина);

 

КонецПроцедуры

По результатам замера производительности видно, что вывод результата в табличный документ происходит быстрее при использовании СКД, причем вариант с программным созданием схемы отрабатывает несколько быстрее.

В тоже время вывод результатов в текстовый документ отрабатывает быстрее для запроса.

Программное создание схемы компоновки отработало быстрее, чем получение макета схемы.

Источник

Категория: Схема Компоновки Данных

1С Предприятие что это? Категория: 1С Общие вопросы - Обычные формы

Как получить информацию о изображении (высота, ширина, размер)?

Платформа 1С версии 8.х предоставляет слабые возможности по работе с изображением.
Для работы с изображениями можно использовать библиотеку Windows Image Acquisition Automation Library. Библиотеку с описанием можно скачать здесь (в Windows 7 уже входит в состав дистриботива).

После того, как загрузили архив, распакуйте. Саму библиотеку wiaaut.dll придется зарегистрировать командой regsvr32. После регистрации доступен COM-объект "WIA.ImageFile". Приведем пример работы:

Код 1C v 8.х

 // Выбор файла

СтандартнаяОбработка = Ложь;

РежимДиалога = РежимДиалогаВыбораФайла.Открытие;

ДиалогВыбораФайла = Новый ДиалогВыбораФайла(РежимДиалога);

ДиалогВыбораФайла.МножественныйВыбор = Ложь;

ДиалогВыбораФайла.Заголовок = "Задайте имя файла";

ДиалогВыбораФайла.ПолноеИмяФайла = ПолеИмениФайла;

	

ДиалогВыбораФайла.Фильтр = "Все файлы картинок|*.jpg;*.jpeg;*.gif;*.bmp;*.ico;*.png;*.tif;*.*";

Если НЕ ДиалогВыбораФайла.Выбрать() Тогда

	// Если не выбран файл

	Возврат;

КонецЕсли;

	

ПолеИмениФайла = ДиалогВыбораФайла.ПолноеИмяФайла;

	

// Создаем объект

ФайлКартинка = Новый COMОбъект("WIA.ImageFile");

ФайлКартинка.LoadFile(ПолеИмениФайла);



Сообщить("Расширение файла: " + ФайлКартинка.FileExtension);

Сообщить("Высота: " + ФайлКартинка.Height);

Сообщить("Ширина: " + ФайлКартинка.Width);

Сообщить("Размер: " + Окр(ФайлКартинка.FileData.Count / 1024, 2) + " Кб");

Библиотека была протестирована на самых распространенных форматах файлов-картинок: jpeg, gif, bmp, ico, png, tif.
Здесь можно скачать готовую обработку: Скачивать файлы может только зарегистрированный пользователь!

Помимо данных о картинке, библиотека может многое другое: изменить размер изображения, повернуть, получить изображение со сканера и прочее. Надеюсь, мы еще вернемся к этой библиотеке. Источник

Категория: COM-объекты, WMI, WSH

Временные таблицы, что из себя представляют и как с ними работать?

Временные таблицы - хранятся на сервере и позволяют писать более простые запросы.
Временные таблицы хранятся в объекте типа МенеджерВременныхТаблиц. Когда этот объект уничтожается, уничтожаются и временные таблицы.
Чтобы создать временную таблицу, используется ключевое слово "ПОМЕСТИТЬ В", например:

Код 1C v 8.х

 |ВЫБРАТЬ * ИЗ Справочник.Номенклатура ПОМЕСТИТЬ В ВТТовары

Временная таблица создается при выполнении запроса, если повторно выполнить запрос, то выдастся ошибка, что таблица уже существует.
Описания временных таблиц хранятся в свойстве запроса МенеджерВременныхТаблиц. К сожалению, нельзя получить список временных таблиц, которые хранятся в запросе.

Пример 1: Как можно выгрузить временную таблицу в таблицу значений и как использовать менеджер временных таблиц:

Код 1C v 8.х

 Запрос=Новый Запрос("ВЫБРАТЬ * ИЗ Справочник.Номенклатура ПОМЕСТИТЬ В ВТТовары");

Запрос.Выполнить(); //Создалась таблица ВТТовары

ЗапросТМП=Новый Запрос("ВЫБРАТЬ * ИЗ ВТТовары");

ЗапросТМП.МенеджерВременныхТаблиц=Запрос.МенеджерВременныхТаблиц; //Копируем ссылку на временные таблицы

ТЗ=ЗапросТМП.Выполнить().Выгрузить(); //Получаем временную таблицу в таблице значений

Готовую таблицу значений из памяти можно выгружать в менеджер временных таблиц запроса. Единственное условие - колонки таблицы значений должны быть типизированными, т.е. иметь тип. Вот пример, демонстрирующий это:



ТЗ=Новый ТаблицаЗначений();

//Колонки должны быть типизированы

ТЗ.Колонки.Добавить("А", Новый ОписаниеТипов("Строка"));

ТЗ.Колонки.Добавить("Б", Новый ОписаниеТипов("Строка"));



//Заполняем таблицу данными

Стр=ТЗ.Добавить();

Стр.А="А";

Стр.Б="Б";

Стр=ТЗ.Добавить();

Стр.А="А1";

Стр.Б="Б1";



//Загружаем таблицу значений в менеджер временных таблиц запроса

Запрос=Новый Запрос("Выбрать Т.А, Т.Б ПОМЕСТИТЬ ВТТаб Из &Таб Как Т");

//Вариант: Запрос=Новый Запрос("Выбрать * ПОМЕСТИТЬ ВТТаб Из &Таб Как Т");

Запрос.МенеджерВременныхТаблиц=Новый МенеджерВременныхТаблиц;

Запрос.УстановитьПараметр("Таб",ТЗ);

Запрос.Выполнить();



//Получаем таблицу из менеджера временных таблиц запроса

ЗапросТМП=Новый Запрос("ВЫБРАТЬ * ИЗ ВТТаб");

ЗапросТМП.МенеджерВременныхТаблиц=Запрос.МенеджерВременныхТаблиц;

ТЗ1=ЗапросТМП.Выполнить().Выгрузить();

ТЗ1.ВыбратьСтроку(); //Показываем полученную таблицу

Вместо перечисления списка полей можно использовать "ВЫБРАТЬ * ".
Если есть ТЗ, в каждой колонке которой значения всего одного типа, для типизации колонок, можно воспользоваться функцией:

Код 1C v 8.х

 Процедура ТипизацияТЗ(ТЗ) Экспорт

РезультатТЗ = новый ТаблицаЗначений;

Для Каждого Колонка из ТЗ.Колонки Цикл

Имя = Колонка.Имя;

МассивТипов = новый Массив(1);

МассивТипов[0] = ТипЗнч(ТЗ[0][Имя]);

Описатель = новый ОписаниеТипов(МассивТипов);

РезультатТЗ.Колонки.Добавить(Имя, Описатель);

КонецЦикла;



Для каждого Строка из ТЗ Цикл

СтрокаРез = РезультатТЗ.Добавить();

ЗаполнитьЗначенияСвойств(СтрокаРез, Строка);

КонецЦикла;



ТЗ = РезультатТЗ.Скопировать();

КонецПроцедуры

Пример 2: Нужно в отчете СКД Связать Данные из Регистра Накопления ВзаиморасчетыСРаботниками и Табличной Части Документа ЗарплатаКВыплате по Ссылке на Документ и ФизЛицу! И вывести полученные данные за указанный Период(с ДатаН по ДатаК) - Запрос будет такой:

Код 1C v 8.х

 ВЫБРАТЬ

                ВзаиморасчетыСРаботникамиОрганизаций.Период,

                ВзаиморасчетыСРаботникамиОрганизаций.Физлицо,

                ВзаиморасчетыСРаботникамиОрганизаций.СуммаВзаиморасчетов,

                ВзаиморасчетыСРаботникамиОрганизаций.Организация,

                ВзаиморасчетыСРаботникамиОрганизаций.ПериодВзаиморасчетов,

                ВзаиморасчетыСРаботникамиОрганизаций.Регистратор

ПОМЕСТИТЬ РегВзаимРасч

ИЗ

                РегистрНакопления.ВзаиморасчетыСРаботникамиОрганизаций КАК ВзаиморасчетыСРаботникамиОрганизаций

ГДЕ

                ВзаиморасчетыСРаботникамиОрганизаций.Период МЕЖДУ &ДатаН И &ДатаК

;



////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ

                ЗарплатаКВыплатеОрганизацийЗарплата.Физлицо,

                ЗарплатаКВыплатеОрганизацийЗарплата.Сумма,

                ЗарплатаКВыплатеОрганизацийЗарплата.ВыплаченностьЗарплаты,

                ЗарплатаКВыплатеОрганизацийЗарплата.КомпенсацияЗаЗадержкуЗарплаты,

                ЗарплатаКВыплатеОрганизацийЗарплата.Ссылка

ПОМЕСТИТЬ ДокумЗарплКВыпл

ИЗ

                Документ.ЗарплатаКВыплатеОрганизаций.Зарплата КАК ЗарплатаКВыплатеОрганизацийЗарплата

ГДЕ

                ЗарплатаКВыплатеОрганизацийЗарплата.Ссылка.Дата МЕЖДУ &ДатаН И &ДатаК

;



////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ

                РегВзаимРасч.Период,

                РегВзаимРасч.Физлицо,

                РегВзаимРасч.СуммаВзаиморасчетов,

                ДокумЗарплКВыпл.Сумма,

                ДокумЗарплКВыпл.ВыплаченностьЗарплаты,

                ДокумЗарплКВыпл.КомпенсацияЗаЗадержкуЗарплаты

ИЗ

                РегВзаимРасч КАК РегВзаимРасч

                               ВНУТРЕННЕЕ СОЕДИНЕНИЕ ДокумЗарплКВыпл КАК ДокумЗарплКВыпл

                               ПО РегВзаимРасч.Регистратор = ДокумЗарплКВыпл.Ссылка

                                               И РегВзаимРасч.Физлицо = ДокумЗарплКВыпл.Физлицо

;



////////////////////////////////////////////////////////////////////////////////

УНИЧТОЖИТЬ РегВзаимРасч

;



////////////////////////////////////////////////////////////////////////////////

УНИЧТОЖИТЬ ДокумЗарплКВыпл

Категория: Запросы