договорыконтрагентов » Поиск

Результаты по ключевому слову: договорыконтрагентов

Как очистить справочник удалив все не используемые элементы?

Очень часто менеджеры дублируют информацию в справочниках и время от времени их приходится чистить.

Но как удалить только те элементы справочника, которые не используются в документах?

Следующий пример кода поможет это сделать(в примере обрабатывается 4 справочника: Сотрудники, ФизЛица, Договора и Контрагенты) Скачать: Обработка для УТ 10:

Код 1C v 8.х

 сп=Новый СписокЗначений;

	сп.Добавить("СотрудникиОрганизаций");

	сп.Добавить("ФизическиеЛица");

	сп.Добавить("ДоговорыКонтрагентов");

	сп.Добавить("Контрагенты");

	

	Для Каждого стр из сп Цикл

		текСпр=стр.Значение;

		Запрос = Новый Запрос;

		Текст = 

		"ВЫБРАТЬ

		|	СотрудникиОрганизаций.Ссылка

		|ИЗ

		|	Справочник.%текСпр% КАК СотрудникиОрганизаций

		|ГДЕ

		|	НЕ СотрудникиОрганизаций.ПометкаУдаления И НЕ СотрудникиОрганизаций.ЭтоГруппа";

		Запрос.Текст = СтрЗаменить(Текст,"%текСпр%",текСпр);

		РезультатЗапроса = Запрос.Выполнить();

		ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

		итЗаписей = Строка(ВыборкаДетальныеЗаписи.Количество());

		ном=0;

		Пока ВыборкаДетальныеЗаписи.Следующий() Цикл

			ном=ном+1; Состояние(текСпр+": "+Строка(ном)+" из "+итЗаписей);

			СсылкаНаУдаляемыйЭлемент = ВыборкаДетальныеЗаписи.Ссылка;

			// Найти ссылки на удаляемый элемент - СсылкаНаУдаляемыйЭлемент. 

			МассивСсылок = Новый Массив; 

			МассивСсылок.Добавить(СсылкаНаУдаляемыйЭлемент); 

			НайденныеСсылки = НайтиПоСсылкам(МассивСсылок); 

			

			Если НайденныеСсылки.Количество() > 0 Тогда 

				Сообщить("Нельзя удалять элемент:"+Строка(СсылкаНаУдаляемыйЭлемент)+", на него имеются ссылки",СтатусСообщения.Внимание); 

			Иначе

				Сообщить("Удаляем элемент:"+Строка(СсылкаНаУдаляемыйЭлемент),СтатусСообщения.Информация); 

				// Получаем объект

				УдаляемыйЭлемент = СсылкаНаУдаляемыйЭлемент.ПолучитьОбъект(); 

				// Установить пометку

				//УдаляемыйЭлемент.УстановитьПометкуУдаления(Истина); 

				// Удалить сразу

				УдаляемыйЭлемент.Удалить();

			КонецЕсли; 		  

			

		КонецЦикла; 

	КонецЦикла;

Категория: Справочники

Как программно установить отбор в открываемой форме(При открытии)?

Для установки отбора используется свойство "Отбор" у менеджеров списков объектов, например, для открытия списка договоров определенного контрагента можно написать следующий код:

Код 1C v 8.х

 ФормаВыбора = Справочники.ДоговорыКонтрагентов.ПолучитьФормуВыбора("ФормаВыбора", ЭтаФорма, "ФормаВыбораДоговора");

ФормаВыбора.Отбор.Владелец.Значение = КонтрагентСсылка;

ФормаВыбора.Отбор.Владелец.Использование = ИСТИНА;

ФормаВыбора.ОткрытьМодально();

В данном случае мы применили вид сравнения "Равно", но не указывали его т.к. оно стоит по умолчанию. Используя разные значения вида сравнения мы значительно расширяем возможности.

Например, у нас в базе контрагент является и продавцом и покупателем, при этом договоры находятся в соответствующей группе внутри справочника. Поэтому мы сделаем отбор не только на самого контрагента, но и на группу "Группа Покупатели" в которой находится договор:

Код 1C v 8.х

 ФормаВыбора = Справочники.ДоговорыКонтрагентов.ПолучитьФормуВыбора("ФормаВыбора", ЭтаФорма, "ФормаВыбораДоговора");

ФормаВыбора.Отбор.Владелец.Значение = КонтрагентСсылка;

ФормаВыбора.Отбор.Владелец.Использование = ИСТИНА;

ГруппаПокупатели = Справочники.ДоговорыКонтрагентов.НайтиПоНаименованию("Группа Покупатели");

ФормаВыбора.Отбор.Родитель.ВидСравнения = ВидСравнения.ВИерархии;

ФормаВыбора.Отбор.Родитель.Значение = ГруппаПокупатели;

ФормаВыбора.Отбор.Родитель.Использование = ИСТИНА;

ФормаВыбора.ОткрытьМодально();

Категория: Работа с Формой (Диалог) и её элементами

Как в запросе задать условие на параметр? Параметр может быть задан или нет, а запрос выполняется!

Код 1C v 8.х

 Запрос = Новый Запрос(" 

|ВЫБРАТЬ

|	ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОстатки.ДоговорКонтрагента,

|	ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОстатки.ДокументРасчетовСКонтрагентом,

|	ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОстатки.СуммаВзаиморасчетовОстаток КАК СуммаВзаиморасчетовОстаток,

|	ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОстатки.Сделка

|ИЗ

|	РегистрНакопления.ВзаиморасчетыСКонтрагентамиПоДокументамРасчетов.Остатки(

|			&Кон,

|			ВЫБОР

|					КОГДА &Организация = ЗНАЧЕНИЕ(Справочник.Организации.ПустаяСсылка)

|						ТОГДА ИСТИНА

|					ИНАЧЕ Организация = &Организация

|				КОНЕЦ

|				И ВЫБОР

|					КОГДА &Контрагент = ЗНАЧЕНИЕ(Справочник.Контрагенты.ПустаяСсылка)

|						ТОГДА ИСТИНА

|					ИНАЧЕ Контрагент = &Контрагент

|				КОНЕЦ

|				И Учет = ЗНАЧЕНИЕ(Перечисление.ВидыУчета.Общий)) КАК ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОстатки

|ГДЕ

|	ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОстатки.СуммаВзаиморасчетовОстаток > 0

|

|УПОРЯДОЧИТЬ ПО

|	ВзаиморасчетыСКонтрагентамиПоДокументамРасчетовОстатки.ДокументРасчетовСКонтрагентом.Дата"); 

Запрос.УстановитьПараметр("Организация", Организация); 

Запрос.УстановитьПараметр("Контрагент", ПолеВводаКонтрагент); 



Результат = Запрос.Выполнить().Выбрать(); 



Пока Результат.Следующий() Цикл 

	Наименование = Результат.Наименование;  

КонецЦикла;

Более грамотный вариант:

Код 1C v 8.х

 (Организация В ИЕРАРХИИ (&Организация) ИЛИ &Организация = ЗНАЧЕНИЕ(Справочник.Организации.ПустаяСсылка))

еще пример:

Код 1C v 8.х

     Запрос = Новый Запрос;

    Запрос.Текст =

        "ВЫБРАТЬ ПЕРВЫЕ 1

        |   ДоговорыКонтрагентов.Ссылка

        |ИЗ

        |   Справочник.ДоговорыКонтрагентов КАК ДоговорыКонтрагентов

        |ГДЕ

        |   ВЫБОР

        |           КОГДА &Владелец ССЫЛКА Справочник.Контрагенты

        |               ТОГДА ДоговорыКонтрагентов.Владелец = &Владелец

        |           ИНАЧЕ ИСТИНА

        |       КОНЕЦ

        |   И ВЫБОР

        |           КОГДА &Владелец ССЫЛКА Справочник.Контрагенты

        |               ТОГДА ДоговорыКонтрагентов.ВидДоговора = &ВидДоговора

        |           ИНАЧЕ ИСТИНА

        |       КОНЕЦ

        |   И ДоговорыКонтрагентов.Наименование = &Наименование

        |   И ДоговорыКонтрагентов.Организация = &Организация";



    Запрос.УстановитьПараметр("Владелец", Контрагент);

    Запрос.УстановитьПараметр("Наименование", Наименование);

    Запрос.УстановитьПараметр("ВидДоговора", ВидДоговора);

    Запрос.УстановитьПараметр("Организация", Организация);



    Результат = Запрос.Выполнить();

Категория: Запросы

Как открыть форму подчиненного Реквизиту Контрагент справочника "ДоговорыКонтрагентов"? Категория: Справочники

Формирование проводок в регистре бухгалтерии

Код 1C v 8.х

 

// Задать выбираемые значения. 

ВыбранныйОтветственный = Справочники.Пользователи.НайтиПоНаименованию("Иванцова"); 

ВыбранныйКонтрагент = Справочники.Контрагенты.НайтиПоКоду("00027"); 

ВыбранныйДоговор = Справочники.ДоговорыКонтрагентов.НайтиПоКоду("00013"); 

ВыбранныйДокумент = Документы.ДокументРасчетовСКонтрагентом.НайтиПоНомеру(2, '20050101'); 

ВыбранныйСчет = Справочники.БанковскиеСчета.НайтиПоКоду("00001"); 

ВыбраннаяСтатья = Справочники.СтатьиДвиженияДенежныхСредств.НайтиПоКоду("00002"); 

ВыбраннаяОрганизация = Справочники.Организации.НайтиПоКоду("00001"); 

ВыбраннаяВалюта = Справочники.Валюты.НайтиПоКоду(810); 



// Создать будущий регистратор. 

ДатаЗаписи = ТекущаяДата(); 

Документ = Документы.ОперацияБух.СоздатьДокумент(); 

Документ.Дата = ДатаЗаписи; 

Документ.Организация = ВыбраннаяОрганизация; 

Документ.Ответственный = ВыбранныйОтветственный; 

Документ.Содержание = "Оплата поставщику"; 

Документ.Записать(); 



// Создать набор записей. 

НаборЗаписей = РегистрыБухгалтерии.Хозрасчетный.СоздатьНаборЗаписей();



НаборЗаписей.Отбор.Регистратор.Установить(Документ.Ссылка); 



Движение = НаборЗаписей.Добавить(); 

Движение.Регистратор = Документ.Ссылка; 

Движение.Период = ДатаЗаписи; 



// Заполнить счет дебета. 

Движение.СчетДт = ПланыСчетов.Хозрасчетный.НайтиПоКоду("60.01"); 



// Заполнить аналитику счета дебета. 

Движение.СубконтоДт.Контрагенты = ВыбранныйКонтрагент; 

Движение.СубконтоДт.Договоры = ВыбранныйДоговор; 

Движение.СубконтоДт.ДокументыРасчетовСКонтрагентами = ВыбранныйДокумент; 



// Заполнить счет кредита. 

Движение.СчетКт = ПланыСчетов.Хозрасчетный.НайтиПоКоду("51"); 



// Заполнить аналитику счета кредита. 

Движение.СубконтоКт.БанковскиеСчета = ВыбранныйСчет; 

Движение.СубконтоКт.СтатьиДвиженияДенежныхСредств = ВыбраннаяСтатья; 



// Балансовое измерение. 

Движение.Организация = ВыбраннаяОрганизация; 



// Балансовый ресурс. 

Движение.Сумма = 300000; 



// Реквизиты.Движение.НомерЖурнала = "БК"; 

Движение.Содержание = "Оплата поставщику"; 



// Записать набор записей. 

НаборЗаписей.Записать();

Категория: Регистры бухгалтерии