задаваться » Поиск

Результаты по ключевому слову: задаваться

Добавление дополнительных отчетов и обработок в тонком клиенте БП 3.0, ЗУП 3.0, УТ 11

Любой отчет и обработку можно подключить пользователям как дополнительные отчеты или обработки, вот например пункт в БП - Банк:

Добавление происходит через

далее Дополнительные отчеты и обработки, в списке нажмите Создать и Выберите Файл отчета/обработки:

Перед добавлением файл нужно подготовить, дописать в модуль объекта код подключения:

Для обработок код:

Код 1C v 8.3

 Функция СведенияОВнешнейОбработке() Экспорт

	

	ПараметрыРегистрации = Новый Структура;

	

	//Вид

	//Строка, вид обработки, один из возможных: 

	//"ДополнительнаяОбработка", "ДополнительныйОтчет", "ЗаполнениеОбъекта", "Отчет", "ПечатнаяФорма", "СозданиеСвязанныхОбъектов" 

	ПараметрыРегистрации.Вставить("Вид", "ДополнительнаяОбработка");

	

	//Массив строк имен объектов метаданных в формате: 

	//<ИмяКлассаОбъектаМетаданного>.[ * | <ИмяОбъектаМетаданных>]. 

	//Например, "Документ.СчетЗаказ" или "Справочник.*". 

	//Прим. параметр имеет смысл только для назначаемых обработок, для глобальных может не задаваться. 

	ПараметрыРегистрации.Вставить("Назначение", Новый СписокЗначений);

	

	//Наименование обработки, которым будет заполнено наименование элемента справочника по умолчанию - краткая строка для идентификации обработки администратором 

	ПараметрыРегистрации.Вставить("Наименование", "Сравнение документов БУХ и УТ");

	

	//Версия обработки в формате “<старший номер>.<младший номер>” используется при загрузке обработок в информационную базу. Например “. 

	ПараметрыРегистрации.Вставить("Версия", "1.0");

	

	//Принимает значение Истина или Ложь, в зависимости от того, требуется ли устанавливать или отключать безопасный режим исполнения обработок. Если истина, обработка будет запущена в безопасном режиме. Более подбробно о безопасном режиме в справке к платформе 1С:Предприятие. 

	ПараметрыРегистрации.Вставить("БезопасныйРежим", Истина);

	

	//Краткая информация по обработке, описание обработки. 

	ПараметрыРегистрации.Вставить("Информация", "");

	

	//Команды, поставляемые обработкой. Таблица значений с колонками: 

	ПараметрыРегистрации.Вставить("Команды", Новый СписокЗначений);

		

	ТаблицаКоманд = ПолучитьТаблицу_Команд();





  	ДобавитьКоманду(ТаблицаКоманд,

          "Сравнение документов БУХ и УТ", 	//Представление

          "Сравнение документов БУХ и УТ",	//Идентификатор

          "ОткрытиеФормы", 				//Использование

          Ложь,					 		//ПоказыватьОповещение

          "");			 				//Модификатор





  	ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);

	

	Возврат ПараметрыРегистрации;

	

КонецФункции





Функция ПолучитьТаблицу_Команд()





  Команды = Новый ТаблицаЗначений;

  

  //Представление – представление команды в пользовательском интерфейсе;

  Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка"));

  

  //Идентификатор – идентификатор команды; 

  //любая строка, уникальная в пределах данной обработки (отчета). 

  //В случае с обработками печатных форм на основе макета табличного документа передается список макетов, 

  //на основе которых нужно получить печатную форму 

  //(см. описание параметра ИменаМакетов процедуры УправлениеПечатьюКлиент.ВыполнитьКомандуПечати в разделе Печать). 

  Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка"));

  

  //"ОткрытиеФормы" – открыть форму обработки; 

  //"ВызовКлиентскогоМетода" – вызвать клиентскую экспортную процедуру из модуля формы обработки; 

  //"ВызовСерверногоМетода" – вызвать серверную экспортную процедуру из модуля объекта обработки.

  Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка"));

 	

  //ПоказыватьОповещение – если Истина, требуется показать оповещение при начале и при завершении работы обработки. 

  //Имеет смысл только при запуске обработки без открытия формы. 

  Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));

  

  //Модификатор – дополнительный модификатор команды. 

  //Используется для дополнительных обработок печатных форм на основе табличных макетов, 

  //для таких команд должен содержать строку ПечатьMXL (см. пример в демонстрационной конфигурации).

  Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка"));

  

  Возврат Команды;

           

КонецФункции





Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование, ПоказыватьОповещение = Ложь, Модификатор = "")





  НоваяКоманда = ТаблицаКоманд.Добавить();

  НоваяКоманда.Представление = Представление;

  НоваяКоманда.Идентификатор = Идентификатор;

  НоваяКоманда.Использование = Использование;

  НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;

  НоваяКоманда.Модификатор = Модификатор;



КонецПроцедуры

Для отчетов и печатных форм меняйте параметр Вид:

Код 1C v 8.3

 //"ДополнительнаяОбработка", "ДополнительныйОтчет", "ЗаполнениеОбъекта", "Отчет", "ПечатнаяФорма", "СозданиеСвязанныхОбъектов" 

	ПараметрыРегистрации.Вставить("Вид", "ДополнительнаяОбработка");

Возможные значения этого поля приведу в виде таблицы

Значение поля "Вид" Расположение команды

Расширение

файла

ПечатнаяФорма	В меню "Печать" на форме объекта или списка	epf
ЗаполнениеОбъекта	В меню "Заполнить" на форме объекта или списка	epf
СозданиеСвязанныхОбъектов	В меню "Создать на основании" - "Создание связанных объектов.." на форме объекта или списка	epf
Отчет	В меню "Отчеты" на форме объекта или списка	erf
ДополнительнаяОбработка	В списке соответствующих подсистем в меню "Сервис" - "Дополнительные обработки"	epf
ДополнительныйОтчет	В списке соответствующих подсистем в меню "Сервис" - "Дополнительные отчеты"	erf

Это поле может принимать одно из значений, возвращаемых функциями в типовых конфигурациях:

ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработки<Вид>(). Например, для вида "ПечатнаяФорма" есть функция ВидОбработкиПечатнаяФорма().

Категория: Внешние печатные формы, отчеты и обработк�…

Пример создания внешней печатной формы для управляемого приложения

Пример создания внешней печатной формы АКТа для Бухгалтерии 3.0

1. В конфигураторе 1C Предприятия 8 создаем внешнюю обработку (Файл->Новый->Внешняя обработка), задаем имя.

2. В модуле обработки пишем код. Постараюсь его максимально комментировать. Главное должно быть:

функция ПечатьВнешнейПечатнойФормы табличного документа - которая выведет данные в макет
функция Печать - вызывается из конфигурации! в нее передается массив печатаемых объектов
и функция СведенияОВнешнейОбработке(). Она необходима для регистрации печатной формы в справочнике ДополнительныеОтчетыИОбработки, в ней собирается структура с данными для подключения формы. Эта функция, а также ряд сопутствующих ей, практически одинаковы для всех печатных форм, поэтому их можно просто копировать в новую печатную форму ничего не меняя.

Код 1C v 8.3

 // Функция формирует табличный документ с Внешней печатной формой

//

// Возвращаемое значение:

//  Табличный документ - печатная форма акта

Функция ПечатьВнешнейПечатнойФормы(МассивОбъектов, ОбъектыПечати, Подписант) Экспорт

	ТабДок = новый ТабличныйДокумент;

	

	Макет = ПолучитьМакет("Макет");

	

	ОбластьШапки   = Макет.ПолучитьОбласть("Шапка");

	ОбластьДанные  = Макет.ПолучитьОбласть("Данные");

	ОбластьПодвал  = Макет.ПолучитьОбласть("Подвал");

	

	Запрос = новый запрос;

	Запрос.УстановитьПараметр("МассивОбъектов",МассивОбъектов);

	Запрос.Текст = "ВЫБРАТЬ

	|	РеализацияТоваровУслугТовары.Номенклатура,

	|	РеализацияТоваровУслугТовары.Сумма,

	|	РеализацияТоваровУслугТовары.Количество,

	|	РеализацияТоваровУслугТовары.Цена,

	|	РеализацияТоваровУслугТовары.Ссылка КАК Ссылка

	|ИЗ

	|	Документ.РеализацияТоваровУслуг.Товары КАК РеализацияТоваровУслугТовары

	|ГДЕ

	|	РеализацияТоваровУслугТовары.Ссылка В(&МассивОбъектов)

	|

	|ОБЪЕДИНИТЬ ВСЕ

	|

	|ВЫБРАТЬ

	|	РеализацияТоваровУслугУслуги.Номенклатура,

	|	РеализацияТоваровУслугУслуги.Сумма,

	|	РеализацияТоваровУслугУслуги.Количество,

	|	РеализацияТоваровУслугУслуги.Цена,

	|	РеализацияТоваровУслугУслуги.Ссылка

	|ИЗ

	|	Документ.РеализацияТоваровУслуг.Услуги КАК РеализацияТоваровУслугУслуги

	|ГДЕ

	|	РеализацияТоваровУслугУслуги.Ссылка В(&МассивОбъектов)  	

	|

	|УПОРЯДОЧИТЬ ПО

	|	Ссылка";

	

	ОбщаяВыборка = Запрос.Выполнить().Выгрузить();

	

	Для Каждого СсылкаНаОбъект из МассивОбъектов Цикл

		

		ОбластьШапки.Параметры.ТекстЗаголовка = "Акт №  "+СсылкаНаОбъект.Номер;

		ОбластьШапки.Параметры.Организация = СсылкаНаОбъект.Организация;

		

		ТабДок.Вывести(ОбластьШапки);

		

		Отбор = Новый Структура;

		Отбор.Вставить("Ссылка",СсылкаНаОбъект);

		

		Выборка = ОбщаяВыборка.НайтиСтроки(Отбор);

		

		ИтогоСумма      = 0;

		ИтогоКоличество = 0;

		

		Для Каждого Стр из Выборка Цикл

			ЗаполнитьЗначенияСвойств(ОбластьДанные.Параметры,Стр);

			

			ИтогоСумма = ИтогоСумма + Стр.Сумма;

			ИтогоКоличество = ИтогоКоличество + Стр.Количество;

			

			ТабДок.Вывести(ОбластьДанные);

		КонецЦикла;

		

		ОбластьПодвал.Параметры.ИтогоСумма      = ИтогоСумма;

		

		ОбластьПодвал.Параметры.Подписант      = Подписант;





		ТабДок.Вывести(ОбластьПодвал);

		

		ТабДок.ВывестиГоризонтальныйРазделительСтраниц();

	КонецЦикла;

	

	Возврат ТабДок;

КонецФункции



// Экспортная процедура печати, вызываемая из основной программы

//

// Параметры:

// ВХОДЯЩИЕ:

//  МассивОбъектовНазначения - Массив - список объектов ссылочного типа для печати документа

//                 Как правило, содержит один элемент с ссылкой на вызвавший форму объект (документ, справочник)

//

// ИСХОДЯЩИЕ:

//  КоллекцияПечатныхФорм - ТаблицаЗначений - таблица сформированных табличных документов.

//                 Как правило, содержит одну строку с именем текущей печатной формы

//  ОбъектыПечати - СписокЗначений - список объектов печати. 

//  ПараметрыВывода - Структура - Параметры сформированных табличных документов. Содержит поля:

//  						ДоступнаПечатьПоКомплектно - булево - по умолчанию Ложь

//							ПолучательЭлектронногоПисьма

//							ОтправительЭлектронногоПисьма

//

Процедура Печать(МассивОбъектовНазначения, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт

	

	Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "АКТПечатьВнешняя") Тогда 

		ТабличныйДокумент = ПечатьВнешнейПечатнойФормы(МассивОбъектовНазначения, ОбъектыПечати, "");

		УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, "АКТПечатьВнешняя", "АКТ (внешний)", ТабличныйДокумент);

		

	ИначеЕсли УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "АКТПечатьВнешняяИван") Тогда 

		ТабличныйДокумент = ПечатьВнешнейПечатнойФормы(МассивОбъектовНазначения, ОбъектыПечати, "Иванов А.Ю.");

		УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, "АКТПечатьВнешняяИван", "АКТ (внешний) Иванов", ТабличныйДокумент);  		

		

	ИначеЕсли УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "АКТПечатьВнешняяПетр") Тогда 

		ТабличныйДокумент = ПечатьВнешнейПечатнойФормы(МассивОбъектовНазначения, ОбъектыПечати, "Петров В.С.");

		УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, "АКТПечатьВнешняяПетр", "АКТ (внешний) Петров", ТабличныйДокумент);

	КонецЕсли;





КонецПроцедуры





#Область СведенияОВнешнейОбработке

// Сервисная экспортная функция. Вызывается в основной программе при регистрации обработки в информационной базе

// Возвращает структуру с параметрами регистрации

//

// Возвращаемое значение:

//		Структура с полями:

//			Вид - строка, вид обработки, один из возможных: "ДополнительнаяОбработка", "ДополнительныйОтчет", 

//					"ЗаполнениеОбъекта", "Отчет", "ПечатнаяФорма", "СозданиеСвязанныхОбъектов"

//			Назначение - Массив строк имен объектов метаданных в формате: 

//					<ИмяКлассаОбъектаМетаданного>.[ * | <ИмяОбъектаМетаданных>]. 

//					Например, "Документ.СчетЗаказ" или "Справочник.*". Параметр имеет смысл только для назначаемых обработок, для глобальных может не задаваться.

//			Наименование - строка - Наименование обработки, которым будет заполнено наименование элемента справочника по умолчанию.

//			Информация  - строка - Краткая информация или описание по обработке.

//			Версия - строка - Версия обработки в формате “<старший номер>.<младший номер>” используется при загрузке обработок в информационную базу.

//			БезопасныйРежим - булево - Принимает значение Истина или Ложь, в зависимости от того, требуется ли устанавливать или отключать безопасный режим 

//							исполнения обработок. Если истина, обработка будет запущена в безопасном режиме. 

//

Функция СведенияОВнешнейОбработке() Экспорт

	//Инициализируем структуру с параметрами регистрации    	

	ПараметрыРегистрации = Новый Структура;

	// Первый параметр, который мы должны указать - это какой вид обработки системе должна зарегистрировать.

	// Допустимые типы: ДополнительнаяОбработка, ДополнительныйОтчет, ЗаполнениеОбъекта, Отчет, ПечатнаяФорма, СозданиеСвязанныхОбъектов

	ПараметрыРегистрации.Вставить("Вид", "ПечатнаяФорма"); //может быть - ПечатнаяФорма, ЗаполнениеОбъекта, ДополнительныйОтчет, СозданиеСвязанныхОбъектов...

	

	МассивНазначений = Новый Массив;

	// Теперь нам необходимо передать в виде массива имен, к чему будет подключена наша ВПФ

	// Имейте ввиду, что можно задать имя в таком виде: Документ.* - в этом случае обработка будет подключена ко всем документам в системе,

	// которые поддерживают механизм ВПФ

	МассивНазначений.Добавить("Документ.РеализацияТоваровУслуг"); //Указываем документ к которому делаем внешнюю печ. форму   		

	ПараметрыРегистрации.Вставить("Назначение", МассивНазначений);

	

	ПараметрыРегистрации.Вставить("Наименование", "АКТ (Внешний)"); //имя под которым обработка будет зарегестрирована в справочнике внешних обработок

	ПараметрыРегистрации.Вставить("БезопасныйРежим", ЛОЖЬ);  // Зададим право обработке на использование безопасного режима. Более подробно можно узнать в справке к платформе (метод УстановитьБезопасныйРежим)

	ПараметрыРегистрации.Вставить("Версия", "1.0");   // эти два параметра играют больше информационную роль,

	ПараметрыРегистрации.Вставить("Информация", "Дополнительная печатная форма"); // т.е. это то, что будет видеть пользователь в информации к обработке

	

	// Создадим таблицу команд (подробнее смотрим ниже)

	ТаблицаКоманд = ПолучитьТаблицуКоманд();

	ДобавитьКоманду(ТаблицаКоманд, "Внешний: АКТ", "АКТПечатьВнешняя", "ВызовСерверногоМетода", Истина, "ПечатьMXL");

	ДобавитьКоманду(ТаблицаКоманд, "Внешний: АКТ (Иванов)", "АКТПечатьВнешняяИван", "ВызовСерверногоМетода", Истина, "ПечатьMXL");

	ДобавитьКоманду(ТаблицаКоманд, "Внешний: АКТ (Петров)", "АКТПечатьВнешняяПетр", "ВызовСерверногоМетода", Истина, "ПечатьMXL");

	

	ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);

	

	Возврат ПараметрыРегистрации; 	

КонецФункции

#КонецОбласти





#Область Вспомогательное

// ВСПОМОГАТЕЛЬНЫЕ ПРОЦЕДУРЫ И ФУНКЦИИ РЕГИСТРАЦИИ ОБРАБОТКИ





// Формирует структуру с параметрами регистрации регистрации обработки в информационной базе

//

// Параметры:

//	ОбъектыНазначенияФормы - Массив - Массив строк имен объектов метаданных в формате: 

//					<ИмяКлассаОбъектаМетаданного>.[ * | <ИмяОбъектаМетаданных>]. 

//					или строка с именем объекта метаданных 

//	НаименованиеОбработки - строка - Наименование обработки, которым будет заполнено наименование элемента справочника по умолчанию.

//							Необязательно, по умолчанию синоним или представление объекта

//	Информация  - строка - Краткая информация или описание обработки.

//							Необязательно, по умолчанию комментарий объекта

//	Версия - строка - Версия обработки в формате “<старший номер>.<младший номер>” используется при загрузке обработок в информационную базу.

//

//

// Возвращаемое значение:

//		Структура

//

Функция ПолучитьПараметрыРегистрации(ОбъектыНазначенияФормы = Неопределено, НаименованиеОбработки = "", Информация = "", Версия = "1.0")





	Если ТипЗнч(ОбъектыНазначенияФормы) = Тип("Строка") Тогда

		ОбъектНазначенияФормы = ОбъектыНазначенияФормы;

		ОбъектыНазначенияФормы = Новый Массив;

		ОбъектыНазначенияФормы.Добавить(ОбъектНазначенияФормы);

	КонецЕсли; 

	

	ПараметрыРегистрации = Новый Структура;

	ПараметрыРегистрации.Вставить("Вид", "ПечатнаяФорма");

	ПараметрыРегистрации.Вставить("БезопасныйРежим", Истина);

	ПараметрыРегистрации.Вставить("Назначение", ОбъектыНазначенияФормы);

	

	Если Не ЗначениеЗаполнено(НаименованиеОбработки) Тогда

		НаименованиеОбработки = ЭтотОбъект.Метаданные().Представление();

	КонецЕсли; 

	ПараметрыРегистрации.Вставить("Наименование", НаименованиеОбработки);

	

	Если Не ЗначениеЗаполнено(Информация) Тогда

		Информация = ЭтотОбъект.Метаданные().Комментарий;

	КонецЕсли; 

	ПараметрыРегистрации.Вставить("Информация", Информация);

	

	ПараметрыРегистрации.Вставить("Версия", Версия);





	Возврат ПараметрыРегистрации;





КонецФункции





// Формирует таблицу значений с командами печати

//	

// Возвращаемое значение:

//		ТаблицаЗначений

//

Функция ПолучитьТаблицуКоманд()





	Команды = Новый ТаблицаЗначений;

	

	//Представление команды в пользовательском интерфейсе

	Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка"));

	

	//Уникальный идентификатор команды или имя макета печати

	Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка"));

	

	//Способ вызова команды: "ОткрытиеФормы", "ВызовКлиентскогоМетода", "ВызовСерверногоМетода"

	// "ОткрытиеФормы" - применяется только для отчетов и дополнительных отчетов

	// "ВызовКлиентскогоМетода" - вызов процедуры Печать(), определённой в модуле формы обработки

	// "ВызовСерверногоМетода" - вызов процедуры Печать(), определённой в модуле объекта обработки

	Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка"));

	

	//Показывать оповещение.

	//Если Истина, требуется показать оповещение при начале и при завершении работы обработки. 

	//Имеет смысл только при запуске обработки без открытия формы

	Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));

	

	//Дополнительный модификатор команды. 

	//Используется для дополнительных обработок печатных форм на основе табличных макетов.

	//Для таких команд должен содержать строку ПечатьMXL

	Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка"));





	Возврат Команды; 

КонецФункции





// Вспомогательная процедура.

//

Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование = "ВызовСерверногоМетода", ПоказыватьОповещение = Ложь, Модификатор = "ПечатьMXL")

	НоваяКоманда = ТаблицаКоманд.Добавить();

	НоваяКоманда.Представление = Представление;

	НоваяКоманда.Идентификатор = Идентификатор;

	НоваяКоманда.Использование = Использование;

	НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;

	НоваяКоманда.Модификатор = Модификатор;      

КонецПроцедуры



#КонецОбласти

3. Добавляем макет вывода печатной формы:

4. Сохраняем и добавляем в конфигурацию:

Подключается через Администрирование - Печатные формы, отчеты и обработки:

Создаете новую обработку, записывайте и при открытии документа Реализация, нажав на Печать - появляются доступные печатные формы с разными подписывающими.

Скачать Шаблон внешней печатной формы для управляемого приложения

Категория: Внешние печатные формы, отчеты и обработк�…

Как получить текст из html?

Один мой хороший клиент использует встроенный в 1С почтовый клиент.

До этого все работало хорошо, но недавно из-за установки нового банк-клиента на компьютере обновили Internet Explorer до 11 версии - стала появляться ошибка:

Поле объекта не обнаружено innerText

Пришлось немного доработать типовую функцию получения текста из html:

Код 1C v 8.х

 Функция ПреобразоватьТекстИзХТМЛФорматаВПростой(ТекстВФорматеХТМЛ) Экспорт

	Попытка

		НовыйHTMLДокумент = Новый COMОбъект("HtmlFile");

		НовыйHTMLДокумент.open("text/html");

		НовыйHTMLДокумент.write(ТекстВФорматеХТМЛ);

		НовыйHTMLДокумент.close();

		

		Возврат СтрЗаменить(НовыйHTMLДокумент.all.item(0).innerText, Символ(13), "");

	Исключение	

		Построитель = Новый ПостроительDOM;

		ЧтениеHTML = Новый ЧтениеHTML;

		ЧтениеHTML.УстановитьСтроку(ТекстВФорматеХТМЛ);

		ДокументHTML = Построитель.Прочитать(ЧтениеHTML);

		

		Возврат СокрЛП(ДокументHTML.Тело.ТекстовоеСодержимое);

	КонецПопытки;

КонецФункции

еще функции пример получения:

Код 1C v 8.х

 // Процедура изменяет признак формат текста письма (Текст, HТМЛ),

// и при этом конвертирует сам текст.

//

// Параметры:

//  ЭУHTML,ЭУТекст - Элементы управления формы, соответственно поле HTML и поле Текст

//  Кнопка - выбранная кнопка ее текст "Простой текст" или "HTML" новый вид текста письма

//  либо текст кнопки если пометку кнопки менять не требуется, соответственно 

//  вопрос о потере форматирования задаваться не будет

// Возвращаемое значение:

//  Булево, признак выполнения изменения формата

//

Функция удИзменитьФорматТекста(ЭУHTML,ЭУТекст, Кнопка) Экспорт

    Если ТипЗнч(Кнопка) = Тип("Строка") Тогда

        НовыйВидТекстаПисьма = Кнопка;

        ЕстьКнопка = Ложь;

    Иначе

        Если Кнопка.Пометка Тогда 

            Возврат Ложь; 

        КонецЕсли;

        НовыйВидТекстаПисьма = Кнопка.Текст;        

        ЕстьКнопка = Истина;

    КонецЕсли;     

        

    Если Найти(НовыйВидТекстаПисьма,"Простой текст") > 0 Тогда          

        ИсходныйТекст = ЭУHTML.ПолучитьТекст();

        НачалоBODY = Найти(ИсходныйТекст, "<BODY>");

        КонецBODY  = Найти(ИсходныйТекст, "</BODY>");

        Если ЕстьКнопка и (НачалоBODY > 0 И КонецBODY > 0 И (НачалоBODY + 6) < КонецBODY) Тогда

            СтрокаВопроса = "Будет потеряно форматирование текста. Продолжить?";

            ОтветНаВопрос = Вопрос(СтрокаВопроса, РежимДиалогаВопрос.ДаНет, , КодВозвратаДиалога.Нет);

            Если ОтветНаВопрос <> КодВозвратаДиалога.Да Тогда                

                Возврат Ложь;

            КонецЕсли;

        КонецЕсли;

        ФорматТекста = ЭУHTML.Документ.all.item(0).innerText;             

        ЭУТекст.Значение =  СтрЗаменить(ФорматТекста, Символ(13), "");

        ЭУТекст.Видимость = Истина;

        ЭУHTML.Видимость = Ложь;

        ЭУHTML.УстановитьТекст("");                        

    Иначе

        ФорматХТМЛ = СтрЗаменить(ЭУТекст.Значение, Символы.ПС, "<BR>");

    

        ЭУHTML.УстановитьТекст(ФорматХТМЛ);

        ЭУHTML.Видимость = Истина;

        ЭУТекст.Видимость = Ложь;

    КонецЕсли; 

    

    Если ЕстьКнопка Тогда

        Кнопка.Пометка = Истина;         

    КонецЕсли;   

    Возврат Истина;                     





КонецФункции // обИзменитьФорматТекста()

Категория: Работа с Интернет, Почтой (Mail), FTP

Как выбрать записи из регистра сведений?

Код 1C v 8.х

  //ВНИМАНИЕ !!! 

// В качестве полей для отбора могут задаваться измерения или реквизиты, для которых

// в конфигураторе признак индексирования установлен в значение "Индексировать" или 

// установлен признак "Ведущее". Вид сравнения может быть только Равно.



// Пример 1 Периодический регистр сведений

Отбор = Новый Структура("Сотрудник");

Отбор.Сотрудник = Результат.Сотрудник;

ВыборкаОКЛАД = РегистрыСведений.ПлановыеНачисленияРаботниковОрганизаций.Выбрать(Результат.Период,ТекДата, Отбор);

		

// КРАТКИЙ ВАРИАНТ

ВыборкаОКЛАД = РегистрыСведений.ПлановыеНачисленияРаботниковОрганизаций.Выбрать(Результат.Период,ТекДата,Новый Структура("Сотрудник", Результат.Сотрудник));

СумОкл=0;

Пока ВыборкаОКЛАД.Следующий() Цикл

	СумОкл=СумОкл+ВыборкаОКЛАД.Показатель1;

КонецЦикла;



// Пример 2 Непериодический регистр сведений

ВыборкаОРГ = РегистрыСведений.КонтактнаяИнформация.Выбрать(Новый Структура("Объект", Организация));

Пока ВыборкаОРГ.Следующий() Цикл

	Если Строка(ВыборкаОРГ.Вид) = "Юридический адрес организации" Тогда

		ЮрАдрес = ВыборкаОРГ.Представление;

	ИначеЕсли Строка(ВыборкаОРГ.Вид) = "Телефон организации" Тогда

		Телефон = ВыборкаОРГ.Представление;

	КонецЕсли;		

КонецЦикла;

Категория: Регистры сведений

Параметры, ключи запуска 1Сv7 из командной строки

Режим предназначен для выполнения конфигуратором административных функций без участия пользователя. Данный режим применяется в специальных случаях. Например, с его помощью можно организовать специальный ярлык на рабочем столе Windows для создания резервной копии информационной базы 1С:Предприятия. При этом пользователю не нужно будет выполнять никаких действий по выбору необходимой функции в конфигураторе и указанию параметров необходимых для сохранения информационной базы. Данный режим может использоваться для организации автоматического выполнения административных функций в определенный момент времени. Для этого используется любое программное обеспечение, имеющее возможность планирования и запуска задач в определенное время. Например, может быть организовано автоматическое создание резервной копии в ночное время суток

Пакетный режим предназначен для выполнения следующих действий:
-тестирование и исправление информационной базы;
-выгрузка данных;
-сохранение данных;
-автообмен распределенной информационной базы (режим доступен, если установлена компонента «Управление распределенными информационными базами»).

Запуск Конфигуратора в пакетном режиме
Для работы Конфигуратора в пакетном режиме следует в командной строке запуска 1С:Предприятия, кроме параметра CONFIG, указывающего на то, что система 1С:Предприятие запускается в режиме «Конфигуратор», указать параметр /@ФайлПакетногоРежима. ФайлПакетногоРежима - это имя файла, содержащего параметры пакетного запуска. Все необходимые функции, которые должны быть выполнены Конфигуратором в пакетном режиме, описываются в этом файле.
Имя файла может задаваться как абсолютным путем, так и относительным.
В случае задания относительным путем файл ищется программой сначала в рабочем каталоге пользователя, затем в каталоге информационной базы, а затем в том каталоге, из которого запускается 1С:Предприятие.Для того, чтобы при пакетном режиме не выдавался диалог запуска 1С:Предприятия и диалог авторизации, в строке запуска должны быть указаны все необходимые параметры:
-параметр CONFIG;
-каталог информационной базы (параметр /D);
-имя пользователя, если для данной информационной базы ведется список пользователей (параметр /N);
-пароль пользователя, если для пользователя задан пароль (параметр /Р).

Файл пакетного режима имеет по умолчанию расширение .prm, если используется другое расширение, то оно должно явно указываться в имени файла.
Ниже приведен пример строки запуска Конфигуратора в пакетном режиме:
c:\1cv7\bin\1cv7.exe CONFIG /Dc:\1cv7\db /NПопов /PSekret /@C:\lCV7\CMD\Backup

Структура файла пакетного режима.
Файл пакетного режима является текстовым файлом и может создаваться и модифицироваться любым текстовым редактором. Структура файла включает секции и параметры, определенные для каждой секции. Секция задается отдельной строкой с именем секции в прямоугольных скобках. Параметры задаются отдельными строками после строки соответствующей секции с указанием имени параметра и значением, отделенным знаком «=». Основная секция General, описывает общие параметры пакетного режима и необходимость выполнения отдельных функций пакетного режима. Остальные секции содержат параметры, описывающие особенности выполнения конкретных функций.

Секция General [General]

Данная секция предназначена для описания общих параметров пакетного режима и необходимости выполнения отдельных функций.

Output=Имя_файла

Указывает файл, в который будет дополнительно направляться вывод записей о выполняемых действиях в пакетном режиме. Имя файла может указываться как абсолютным путем, так и относительно каталога, в котором расположен файл параметров. Формат файла дополнительного вывода совпадает с форматом вывода в журнал регистрации. Если параметр не указан, то дополнительный вывод производиться не будет. В любом случае вывод производится в журнал регистрации

Quit=Значение

Указывает, нужно ли завершать выполнение Конфигуратора после выполнения действий пакетного режима.

Если задано Y или 1, после выполнения действий пакетного режима, программа будет завершена, а если 0 или N, то нет.

Если параметр не задан, то программа будет завершена.

CheckAndRepair=Значение

Указывает, нужно ли выполнять тестирование и исправление информационной базы.

Если задано Y или 1, тестирование и исправление будет выполняться, а если 0 или N, то нет.

Если параметр не задан, то тестирование и исправление выполняться не будет.

UnloadData =3начение

Указывает, нужно ли выполнять выгрузку информационной базы.

Если задано Y или 1, выгрузка будет выполняться, а если 0 или N, то нет.

Если параметр не задан, то выгрузка выполняться не будет.

SaveData=Значение

Указывает, нужно ли выполнять сохранение информационной базы.

Если задано Y или 1, сохранение будет выполняться, а если 0 или N, то нет.

Если параметр не задан, то сохранение выполняться не будет.

AutoExchange=Значение

Указывает, нужно ли выполнять автообмен в распределенной информационной базе.

Если задано Y или 1, автообмен будет выполняться, а если 0 или N, то нет.

Если параметр не задан, то автообмен выполняться не будет.

Подробное описание работы с распределенными информационными базами приведено в книге «Управление распределенными информационными базами».

Секция CheckAndRepair [CheckAndRepair]

Данная секция предназначена для описания выполнения тестирования и исправления информационной базы.

Repair=Значение

Параметр указывает, должно ли выполняться исправление информационной базы.

Если задано значение Y или 1, то будет выполняться тестирование и исправление обнаруженных ошибок в информационной базе.

Если задано значение N или 0, то будет производиться только тестирование.

Если параметр не задан, то будет производиться тестирование и исправление.

PhysicalIntegrity=Значение

Параметр указывает, следует ли производить проверку физической целостности таблиц информационной базы.

Если задано Y или 1, проверка будет производиться, если N или 0, то нет.

Если параметр не задан, проверка будет производиться.

Reindex=Значение

Параметр указывает, следует ли производить реиндексацию таблиц информационной базы.

Если задано Y или 1, реиндексация будет производиться, если N или 0, то нет.

Если параметр не задан, реиндексация будет производиться.

Если установлен режим исправления, то рекомендуется установить и режим реиндексации.

LogicalIntegrity=Значение

Параметр указывает, следует ли производить проверку логической целостности таблиц информационной базы.

Если задано Y или 1, проверка будет производиться, если N или 0, то нет.

Если параметр не задан, проверка будет производиться.

RecalcSecondaries=Значение

Параметр указывает, следует ли производить обновление (пересчет) вторичных данных информационной базы, то есть служебных данных, которые могут быть рассчитаны на основании другой информации, хранящейся в информационной базе.

Если задано Y или 1, обновление будет производиться, если N или 0 - то нет.

Если параметр не задан, обновление будет производиться.

RecalcTotals=Значение

Параметр указывает, следует ли производить пересчет итогов бухгалтерского и оперативного учета.

Если задано Y или 1, пересчет будет производиться, если N или 0 - то нет.

Если параметр не задан, пересчет будет производиться.

Pack=3начение

Параметр указывает, следует ли производить упаковку таблиц информационной базы, то есть освобождать место занятое удаленными записями.

Если задано Y или 1, упаковка будет производиться, если N или 0, то нет.

Если параметр не задан, упаковка не будет производиться.

Данный параметр имеет смысл, только если данные хранятся в формате DBF/CDX.

SkipUnresolved=Значение

Параметр указывает, следует ли пропускать неразрешенные ссылки, или их следует исправлять.

Если задано Y или 1, неразрешенные ссылки будет только диагностироваться, если N или 0, то ссылки будут разрешаться способом, задаваемым параметром CreateForUnresolved (см. ниже).

Если параметр не задан, ссылки будут исправляться.

Параметр имеет смысл только, если проводится тестирование и исправление информационной базы.

CreateForUnresolved=Значение

Параметр указывает способ разрешения неразрешенных ссылок.

Если задано Y или 1, для неразрешенной ссылки будет создан объект соответствующего типа, если N или 0, то ссылка будет очищена.

Если параметр не задан, будет создан объект.

Параметр имеет смысл только, если проводится тестирование и исправление информационной базы.

Reconstruct=Значение

Параметр указывает способ исправления информационной базы в случае, когда данные объекта частично потеряны. Если задано Y или 1, будет создан объект, заполненный имеющимися данными, если N или 0, то данные объекта будут удалены.

Если параметр не задан, будет создан объект.

Параметр имеет смысл только, если проводится тестирование и исправление информационной базы.

Секция UnloadData [UnloadData]

Данная секция предназначена для описания выполнения выгрузки данных информационной базы.

UnloadToFile=Имя_Файла

Параметр указывает имя файла переноса данных, в который будет производиться выгрузка. Может задаваться как абсолютно, так и относительно того каталога, в котором размещается файл параметров.

Параметр должен быть задан обязательно.

IncludeUserDef=Значение

Параметр указывает должен ли в файл переноса данных включаться список пользователей.

Если задано Y или 1, то список пользователей будет включен в файл переноса, если 0 или N, то нет.

Если параметр не задан, то список будет включен в файл переноса.

Password=Пароль

Параметр задает пароль, которым будет закрыт файл переноса данных.

Если параметр не задан, то файл переноса не будет закрыт паролем.

Секция SaveData [SaveData]

Данная секция предназначена для описания выполнения сохранения данных информационной базы.

SaveToFile=Имя_Файла

Параметр указывает имя файла, в который будет производиться сохранение данных. Может задаваться как абсолютно, так и относительно того каталога, в котором размещается файл параметров.

Параметр должен быть задан обязательно.

FileList=Список сохраняемых файлов

Задается как перечисление имен файлов, разделенных пробелами или запятыми. Длинные имена файлов, содержащие пробелы должны заключаться в кавычки "". В именах файлов могут использоваться символы «*» для обозначения групп файлов.

Если параметр не задан, то список сохраняемых файлов будет взят из файла 1CV7FILE.LST, так же как и в случае выполнения сохранения из пункта меню «Администрирование».

Работа в пакетном режиме
Выполнение указанных действий в пакетном режиме производится всегда в строго определенной последовательности, вне зависимости от порядка следования секций и параметров в файле пакетного режима:
1. тестирование и исправление информационной базы;
2. выгрузка данных;
3. сохранение данных;
4. автообмен распределенной информационной базы.
При работе Конфигуратора в пакетном режиме не выполняется выдача предупреждений и запросов, требующих подтверждения пользователя. При возникновении критических ошибок выполнение пакетного режима прекращается. Результаты выполнения пакетного режима можно просмотреть в журнале регистрации и в файле дополнительного вывода, если он был определен в файле параметров пакетного режима.

Пример пакетного файла:

[General]
Output="D:\Типовые конфигурации\1SBBDemo\log.txt"
Quit=1
SaveData=1
[SaveData]
SaveToFile="D:\Типовые конфигурации\1SBBDemo\arch.zip"

Ярлык для запуска базы и выполнения файла пакетного режима:

\\Server\1cv77\BIN\1cv7s.exe config /D "D:\Типовые конфигурации\1SBBDemo\" /@"D:\Типовые конфигурации\1SBBDemo\paket.txt"

Комментарий к файлу:
Во время работы будет сформирован лог-файл (Output="D:\Типовые конфигурации\1SBBDemo\log.txt"). Он будет здесь D:\Типовые конфигурации\1SBBDemo\log.tx.
Будет выполнено сохранение данных (SaveData=1) в файл arch.zip (SaveToFile="D:\Типовые конфигурации\1SBBDemo\arch.zip"). После выполения работы - конфигуратор будет закрыт (Quit=1). Информационная база хранится в D:\Типовые конфигурации\1SBBDemo\. Файл пакетного режима харанится в папке базы и называется paket.txt.

Пакетный режим является мощным инструментом. Чаще всего используется для создания архивных копий. Проблема только в том, что он архив делается всегда под одним именем. И чтобы не затирать старые архивы, требуется некоторая изворотливость с конфигурационным файлом пакетного режима. Но здесь огромное поле для фантазии, по этому предоставляю Вам возможность фантазировать.

Категория: Администрирование

Сводные Остатки регистра остатков

Метод работает аналогично процедуре Остатки, однако здесь могут быть заданы не все значения измерений, а только несколько,
но обязательно в правильной последовательности, соответствующей структуре измерений данного регистра, как она задана в конфигураторе.
Измерения могут задаваться с пропусками (неуказанное значение — просто запятая), фиксируются только указанные измерения.

Код 1C v 7.x

 // Пример 1

// Для регистра с измерениями «Товар», «Склад», «МОЛ» запись

Рег.СводныеОстатки(Тов1, , );

//означает, что ресурсы будут получены только по одному товару (Тов1), но по всем складам и всем МОЛам.

Процедура ПолучитьСводныеОстатки(Товар, ОстатокТовара, Стоимость);

   Регистр.УчетТовара.СводныеОстатки(Товар, );

   ОстатокТовара = Регистр.УчетТовара.ОстаткиТовара;

   Стоимость = Регистр.УчетТовара.СтоимостьТовара;

КонецПроцедуры



// Пример 2

РегТовары = СоздатьОбъект("Регистр.Товары")

//получить сводные остатки по товару

РегТовары.СводныеОстатки(ТекТовар,); //указано только одно измерение

КолвоТовара = РегТовары.Количество;

СтоимостьТовара = РегТовары.Стоимость;



//получить стоимость всех товаров на данном складе

РегТовары.СводныеИтоги(,ТекСклад); //указано только одно измерение

СтоимостьПоСкладу = РегТовары.Стоимость;

Категория: Регистры

Сводный Остаток регистра остатков

Данный метод работает аналогично методу Остаток, однако здесь могут быть заданы не все значения измерений, а только несколько,
но обязательно в правильной последовательности, соответствующей структуре измерений данного регистра, как она задана в конфигураторе.
Измерения могут задаваться с пропусками (неуказанное значение — просто запятая), фиксируются только указанные измерения.

Код 1C v 7.x

 // Пример 1

// Для регистра с измерениями «Товар», «Склад», «МОЛ» запись

Рег.СводныйОстаток(Тов1, , "ОстатокТовара");

//означает, что ресурс «ОстатокТовара» будет получен только по одному товару (Тов1), но по всем складам и всем МОЛам.

Процедура ПолучитьСводныйОстаток(Товар, Ост);

   Ост = Регистр.УчетТовара.СводныйОстаток(Товар, , "ОстаткиТовара");

КонецПроцедуры



// Пример 2

РегТовары = СоздатьОбъект("Регистр.Товары")

//получить остаток данного товара на всех складах

КолвоТовара = РегТовары.СводныйОстаток (ТекТовар,,"Количество");

СтоимостьТовара = РегТовары.СводныйОстаток (ТекТовар,,"Стоимость");

//получить стоимость всех товаров на данном складе

СтоимостьПоСкладу = РегТовары.СводныйОстаток (,ТекСклад,"Стоимость");

Отзывы об казино 888старс от реальных игроков с опытом игры в данном игровом заведении.

Категория: Регистры

Сводные Итоги оборотного регистра

Метод работает аналогично процедуре Итоги, однако здесь могут быть заданы не все значения измерений, а только несколько, но обязательно в правильной последовательности, соответствующей структуре измерений данного регистра, как она задана в конфигураторе.
Измерения могут задаваться с пропусками (неуказанное значение -просто запятая), фиксируются только указанные измерения.

Код 1C v 7.x

  

// Пример 1

Регистр.ОборотыТоваров.ИспользоватьПериод(Год);

Регистр.ОборотыТоваров.СводниеИтоги(Товар, );

ПолныйОбТов = Регистр.ОборотыТоваров.ОборотТовара;



// Пример 2 

РегДоходы = СоздатьОбъект("Регистр.Доходы");

//установить период выборки "30 января 2009 года"

РегДоходы.ИспользоватьПериод(2009,01,30);

//получить сводные итоги за день по клиенту

РегДоходы.СводныеИтоги(ТекКлиент,); //указано только одно измерение

ДоходПоКлиенту = РегДоходы.Доход;



//получить сводные итоги за день по товару

РегДоходы.СводныеИтоги(,ТекТовар); //указано только одно измерение

ДоходПоТовару = РегДоходы.Доход;

Категория: Регистры

Сводный Итог оборотного регистра

Данный метод работает аналогично методу Итог, однако здесь могут быть заданы не все значения измерений, а только несколько, но обязательно в правильной последовательности, соответствующей структуре измерений данного регистра, как она задана в конфигураторе.
Измерения могут задаваться с пропусками (неуказанное значение — просто запятая), фиксируются только указанные измерения.

Код 1C v 7.x

  

 // Пример 1

 Функция ПолучитьСводныйИтог(Товар, Год);

 	Регистр.ОборотыТоваров.ИспользоватьПериод(Год);

 	Возврат Регистр.ОборотыТоваров.СводныйИтог(Товар, , "ОборотТовара");

 КонецФункции

 

 // Пример 2 

 РегДоходы = СоздатьОбъект("Регистр.Доходы");

 //установить период выборки "30 января 2009 года"

 РегДоходы.ИспользоватьПериод(2009,01,30);

 //получить сводные итоги за день

 ДоходПоКлиенту = РегДоходы.СводныйИтог(ТекКлиент,,"Доход");

 ДоходПоТовару = РегДоходы.СводныйИтог(,ТекТовар,"Доход");

Категория: Регистры

Выборка (перебор) бизнес-процессов

Выбрать(<Дата начала>, <Дата окончания>, <Отбор>, <Порядок>)
<Дата начала> отбора
<Дата окончания> отбора
<Отбор> (необязательный) - Структура. Задает реквизит вида расчета и значение этого реквизита, по которому будет создана выборка. Ключ структуры задает имя реквизита, а значение структуры - значение отбора по этому реквизиту. В качестве реквизитов отбора могут задаваться только "Код", "Наименование" и реквизиты вида расчета, для которых в конфигураторе признак индексирования установлен в значение "Индексировать" или в значение "Индексировать с доп. упорядоч.".
Важно! Структура может содержать только один элемент. Если параметр не указан, то отбор не используется.
<Порядок> (необязательный) - Строка. Строка с именем реквизита вида расчета, определяющая упорядочивание создаваемой выборки.

Код 1C v 8.х

 

Выборка = БизнесПроцессы.Продажа.Выбрать(ДатаНач, ДатаКон);

Пока Выборка.Следующий() Цикл

	//код

КонецЦикла;

Категория: Бизнес-процессы

Выборка запросом, перебор задач

Выбрать(<Отбор>, <Порядок>)
<Отбор> (необязательный) - Структура. Задает реквизит вида расчета и значение этого реквизита, по которому будет создана выборка. Ключ структуры задает имя реквизита, а значение структуры - значение отбора по этому реквизиту. В качестве реквизитов отбора могут задаваться только "Код", "Наименование" и реквизиты вида расчета, для которых в конфигураторе признак индексирования установлен в значение "Индексировать" или в значение "Индексировать с доп. упорядоч.".
Важно! Структура может содержать только один элемент. Если параметр не указан, то отбор не используется.
<Порядок> (необязательный) - Строка. Строка с именем реквизита вида расчета, определяющая упорядочивание создаваемой выборки.

Код 1C v 8.х

 

Выборка = Задачи.Дела.Выбрать();

Пока Выборка.Следующий() Цикл

	//код

КонецЦикла;

Запросом:

Код 1C v 8.х

 Запрос = Новый Запрос;

	Запрос.Текст =

	"ВЫБРАТЬ

	|	CRM_Задача.Ссылка,

	|	CRM_Задача.ТочкаМаршрута КАК Задачи_CRM,

	|	CRM_Задача.БизнесПроцесс.ДокументДоставки.Номер КАК Доставка_Номер,

	|	CRM_Задача.ДатаВыполнения КАК Выполнить_до

	|ИЗ

	|	Задача.CRM_Задача КАК CRM_Задача

	|ГДЕ

	|	CRM_Задача.ТочкаМаршрута В(&ТочкаМаршрута)

	|	И CRM_Задача.Выполнена = ЛОЖЬ

	|	И CRM_Задача.БизнесПроцесс.ДокументДоставки <> ЗНАЧЕНИЕ(Документ.Доставка.ПустаяСсылка)

	|	И (CRM_Задача.Пользователь = &Пользователь

	|			ИЛИ CRM_Задача.Подразделение = &Подразделение)

	|

	|УПОРЯДОЧИТЬ ПО

	|	Выполнить_до

	|АВТОУПОРЯДОЧИВАНИЕ";

	Запрос.УстановитьПараметр("ТочкаМаршрута", СписокТ);

	Запрос.УстановитьПараметр("Пользователь", ПараметрыСеанса.ТекущийПользователь);

	Запрос.УстановитьПараметр("Подразделение", ПараметрыСеанса.ТекущийПользователь.Подразделение);



	Задачи_CRM = Запрос.Выполнить().Выгрузить();

	ЭлементыФормы.Задачи_CRM.СоздатьКолонки();

	ЭлементыФормы.Задачи_CRM.Колонки.Ссылка.Видимость=Ложь;

Категория: Задачи

Выборка (перебор) видов расчета

Код 1C v 8.х

 

Выборка = ПланыВидовРасчета.УдержанияОрганизаций.Выбрать();

Пока Выборка.Следующий() Цикл

	//код обработки выбора	

КонецЦикла;

Категория: Планы видов расчета

Как указать нужную,конкретную дату?

Значения данного типа содержит дату григорианского календаря (с 01 января 0001 года) и время с точностью до секунды.
Литералы:
Строка цифр, заключенная в одинарные кавычки вида: 'ГГГГММДДччммсс', где:
ГГГГ - четыре цифры года (включая тысячелетие и век);
ММ - две цифры месяца:
ДД - две цифры даты;
чч - две цифры часа (в 24-х часовом формате);
мм - две цифры минут;
сс - две цифры секунд;

Код 1C v 8.х

 '20050308' 

Дата(2005, 1, 1) 

Дата(1, 1, 1) 

Дата(2005, 1, 1, 10, 29, 50) 

ДАТАВРЕМЯ(2005, 01, 01)

В литерале типа Дата обязательно должно задаваться значение года, месяца и дня. Для задания даты соответствующей началу отсчета достаточно указать '00010101'.
Допускается при указании литералов типа Дата опускать последние символы (секунды, минуты, часы и т.д.). Это означает, что данные параметры будут равны нулю (для времени) или единице (для даты).
В литерале даты допускается использование различных разделителей:

Код 1C v 8.х

 Сообщить('20040814093941');

Сообщить('2004-08-14 09:39:41');

Код 1C v 8.х

 // Перевод Даты в Строку и Обратно

//ТекущаяДата() - 28.02.2010 23:58:59



//Переведем текущую дату в строку

СтрокаДата = Формат(ТекущаяДата(), "ггггММддЧЧммсс");  // Получаем:  20100228235859



//Переведем строку в дату

ТекДата = Дата(СтрокаДата); // Получаем:  28.02.2010 23:58:59

В языке ЗАПРОСов значения типа Дата задаются с помощью ключевого слова ДАТАВРЕМЯ, после которого в скобках последовательно указываются год, месяц, день, час, минута и секунда. Последние три указывать не обязательно:

Код 1C v 8.х

 ДАТАВРЕМЯ(2003, 10, 12, 10, 15, 34)

ДАТАВРЕМЯ(2003, 10, 12)

Код 1C v 7.x

 ДатаНачала = '01.01.2009';

//В условиях

Если РабочаяДата() > '31.12.2009' Тогда

   //...

КонецЕсли;

Категория: Работа с Датами (Временем)