игнорировать » Поиск

Результаты по ключевому слову: игнорировать

Обход метаданных (полезные функции)

При написании небольших автоматизированных тестов часто надо обойти всю конфигурацию и проверить, например, для всех форм какое-нибудь свойство. Это всё легко делается через свойство глобального контекста "Метаданные", но чтоб дорбаться до обхода реквизитов надо написать кучу вложенных циклов. При этом код становится слабочитаемым и слабомодифицируемым.

Ниже приведен небольшой модуль, который решает задачу легко и удобно. Создана специальная функция РазвернутьСтрокуОбходаМетаданных, которая может по строке типа "Метаданные.Справочники.*.Реквизиты.*" построить массив строк с перечислением всех реквизитов всех справочников. При помощи этой и нескольких других функций в экспортных функциях модуля реализованы вполне прикладные задачи - получение всех реквизитов, всех макетов, всех форм конфигурации и построение таблицы всех составных типов.

Код 1C v 8.х

  // Автор: Alexander Speshilov

// Рекрсивная функция, которая разворачивает строку вида "Метаданные.Справочники.*[Имя].Реквизиты.*.Тип" 

// в массив строк, заменяя "*" или другой символ, задаваемый параметрами обходом всех элементов 

// коллекции. Допускает выполнение функций встроенного языка (не стоит отдавать ввод параметров 

// пользователям). При этом выражение, используемое для получения по умолчанию может быть задано в 

// квадратных скобках или параметром функции.

//

// Параметры

//  СтрокаОбхода  - Строка - Разворачиваемая строка

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Массив строк

//

Функция РазвернутьСтрокуОбходаМетаданных(СтрокаОбхода, ЗаменяемоеЗначение = "*", ПредставлениеПоУмолчанию = "")

    

    Рез = Новый Массив;

    

    ЧастиСтрокиОбхода = РазобратьСтрокуОбхода(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

    Если ЧастиСтрокиОбхода = Неопределено тогда 

        Рез.Добавить(СтрокаОбхода); //фактически это ограничение рекурсии.

    Иначе

        ОбъектКоллекции = Вычислить(ЧастиСтрокиОбхода.СтрокаКоллекции);

        РазвернутаяКоллекция = РазвернутьКоллекциюВПредставления(ОбъектКоллекции, ЧастиСтрокиОбхода.СтрокаПредставление);

        Для каждого ЭлементРазвернутойКоллекции Из РазвернутаяКоллекция Цикл

            

            // рекурсивный вызов

            ТекущаяСтрокаОбхода = ЧастиСтрокиОбхода.СтрокаНачало + ЭлементРазвернутойКоллекции + ЧастиСтрокиОбхода.СтрокаКонец;

            МассивЭлемента = РазвернутьСтрокуОбходаМетаданных(ТекущаяСтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

            

            Для каждого ПримитивныйЭлементОбхода Из МассивЭлемента Цикл

                Рез.Добавить(ПримитивныйЭлементОбхода);

            КонецЦикла;

            

        КонецЦикла;

    КонецЕсли;

    

    Возврат Рез;

    

КонецФункции // РазвернутьСтрокуОбходаМетаданных()



// Разбирает строку обхода на удобные для работы поля

//

// Параметры

//  СтрокаОбхода  - Строка - Разворачиваемая строка

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Структура с полями ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец

// или Неопределено (если строка не содержит ЗаменяемоеЗначение)

//

Функция РазобратьСтрокуОбхода(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию)

    

    Если ПустаяСтрока(ЗаменяемоеЗначение) Тогда 

        ВызватьИсключение "Некорректное выражение заменяемого значения";

    КонецЕсли;

    

    ПозицияЗамены = Найти(СтрокаОбхода, ЗаменяемоеЗначение);

    

    // Если не найдена строка - возвращаем неопределено, как индикатор

    Если ПозицияЗамены = 0 Тогда 

        Возврат Неопределено; 

    КонецЕсли;

    

    СтрокаНачало = Лев(СтрокаОбхода,ПозицияЗамены - 1);

    

    //Получение строки для выражения-коллекции

    СтрокаКоллекции = СтрокаНачало;

    Если Прав(СтрокаКоллекции, 1) = "." Тогда 

        СтрокаКоллекции = Лев(СтрокаКоллекции,СтрДлина(СтрокаКоллекции) - 1);

    КонецЕсли;

    

    ПозицияОкончанияЗамены = ПозицияЗамены + СтрДлина(ЗаменяемоеЗначение);

    

    ОстатокВыражения = Сред(СтрокаОбхода, ПозицияОкончанияЗамены);

    

    //Обработка явного задания представления

    ОткрывающаяСкобка = "[";

    ЗакрывающаяСкобка = "]";

    Если Найти(ОстатокВыражения, ОткрывающаяСкобка) = 1 Тогда

        ОстатокВыражения = Сред(ОстатокВыражения, СтрДлина(ОткрывающаяСкобка) + 1);

        ПозицияЗакрывающейСкобки = Найти(ОстатокВыражения, ЗакрывающаяСкобка);

        Если ПозицияЗакрывающейСкобки = 0 Тогда 

            ВызватьИсключение "Синтаксическая ошибка разбора выражения";

        КонецЕсли;

        СтрокаПредставление = Лев(ОстатокВыражения, ПозицияЗакрывающейСкобки - 1);

        ОстатокВыражения = Сред(ОстатокВыражения, ПозицияЗакрывающейСкобки + СтрДлина(ЗакрывающаяСкобка));

    Иначе

        СтрокаПредставление = ПредставлениеПоУмолчанию;

    КонецЕсли;

    СтрокаКонец = ОстатокВыражения;

    

    Рез = Новый Структура("ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец",

    ПозицияЗамены, СтрокаНачало, СтрокаКоллекции, СтрокаПредставление, СтрокаКонец);

    

    Возврат Рез;

    

КонецФункции // РазобратьСтрокуОбхода()



// Разворачивает объект коллекции в массив представления элементов

//

// Параметры

//  Коллекция  - Произвольный - Коллекция, которую можно обойти через "Для каждого"

//  ПредставлениеЭлемента  - Строка - необяз., свойство элементов коллекции, которое 

//               используется для получения представления.

//

// Возвращаемое значение:

//   Массив   - Массив представлений коллекции

//

Функция РазвернутьКоллекциюВПредставления(Коллекция, Знач ПредставлениеЭлемента = "")

    

    //Проверка и подгонка параметров

    Если не ПустаяСтрока(ПредставлениеЭлемента) Тогда 

        Если Найти(ПредставлениеЭлемента, ";")>0 Тогда 

            ВызватьИсключение "Некорректное выражение представления";

        КонецЕсли;

        ПредставлениеЭлемента = "." + ПредставлениеЭлемента;

    КонецЕсли;

    

    Рез = Новый Массив;

    Для каждого ЭлементКоллекции Из Коллекция Цикл

        ТекПредставление = Строка(Вычислить("ЭлементКоллекции" + ПредставлениеЭлемента));

        Рез.Добавить(ТекПредставление);

    КонецЦикла; 

    Возврат Рез;

    

КонецФункции // РазвернутьКоллекцию()



// Разворачивает массив строк через РазвернутьСтрокуОбходаМетаданных

//

// Параметры

//  МассивСтрокОбхода  - Массив - Массив разворачиваемых строк

//  ЗаменяемоеЗначение  - Строка - заменяемое значение

//  ПредставлениеПоУмолчанию - Строка - выражение для получения представления

//

// Возвращаемое значение:

//   Массив строк

//

Функция РазвернутьМассивСтрокОбходаМетаданных(МассивСтрокОбхода, ЗаменяемоеЗначение = "*", ПредставлениеПоУмолчанию = "Имя")

    

    Рез = Новый Массив;

    

    Для каждого СтрокаОбхода Из МассивСтрокОбхода Цикл

        

        ДополнениеРезультата = РазвернутьСтрокуОбходаМетаданных(СтрокаОбхода, ЗаменяемоеЗначение, ПредставлениеПоУмолчанию);

        Для каждого ТекСтрока Из ДополнениеРезультата Цикл

            Рез.Добавить(ТекСтрока);

        КонецЦикла; 

        

    КонецЦикла; 

    

    Возврат Рез;

    

КонецФункции // РазвернутьМассивСтрокОбходаМетаданных()



// Преобразует строку в массив одиночных строк по разделителю Символы.ПС

//

// Параметры

//  ПреобразуемаяСтрока - строка для преобразования

//    ИгнорироватьПустые - Булево - Пропускать пустые строки

//  СокращатьПробелы - Использовать СокрЛП

//

// Возвращаемое значение:

//   Массив строк

//

Функция ПолучитьМассивСтрокМногострочнойСтроки(ПреобразуемаяСтрока, ИгнорироватьПустые = Истина, СокращатьПробелы = Истина)

    

    Рез = Новый Массив;

    ЧислоСтрок = СтрЧислоСтрок(ПреобразуемаяСтрока);

    

    Для Сч = 1 По ЧислоСтрок Цикл

        

        ТекСтрока = СтрПолучитьСтроку(ПреобразуемаяСтрока, Сч);

        Если ИгнорироватьПустые и ПустаяСтрока(ТекСтрока) Тогда

            Продолжить;

        КонецЕсли; 

        Если СокращатьПробелы Тогда

            ТекСтрока = СокрЛП(ТекСтрока);

        КонецЕсли; 

        Рез.Добавить(ТекСтрока);

        

    КонецЦикла;

    

    Возврат Рез;

    

КонецФункции // ПолучитьМассивСтрокМногострочнойСтроки()



// Возвращает все реквизиты конфигурации, которые сохраняются в ИБ

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеХранимыеРеквизитыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.Константы.*

    |Метаданные.ПланыОбмена.*.Реквизиты.*

    |Метаданные.ПланыОбмена.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Справочники.*.Реквизиты.*

    |Метаданные.Справочники.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Документы.*.Реквизиты.*

    |Метаданные.Документы.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Последовательности.*.Измерения.*

    |Метаданные.ПланыВидовХарактеристик.*.Реквизиты.*

    |Метаданные.ПланыВидовХарактеристик.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.ПланыСчетов.*.Реквизиты.*

    |Метаданные.ПланыСчетов.*.ПризнакиУчета.*

    |Метаданные.ПланыСчетов.*.ПризнакиУчетаСубконто.*

    |Метаданные.ПланыСчетов.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.ПланыВидовРасчета.*.Реквизиты.*

    |Метаданные.ПланыВидовРасчета.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.РегистрыСведений.*.Измерения.*

    |Метаданные.РегистрыСведений.*.Ресурсы.*

    |Метаданные.РегистрыСведений.*.Реквизиты.*

    |Метаданные.РегистрыНакопления.*.Измерения.*

    |Метаданные.РегистрыНакопления.*.Ресурсы.*

    |Метаданные.РегистрыНакопления.*.Реквизиты.*

    |Метаданные.РегистрыБухгалтерии.*.Измерения.*

    |Метаданные.РегистрыБухгалтерии.*.Ресурсы.*

    |Метаданные.РегистрыБухгалтерии.*.Реквизиты.*

    |Метаданные.РегистрыРасчета.*.Измерения.*

    |Метаданные.РегистрыРасчета.*.Ресурсы.*

    |Метаданные.РегистрыРасчета.*.Реквизиты.*

    |Метаданные.БизнесПроцессы.*.Реквизиты.*

    |Метаданные.БизнесПроцессы.*.ТабличныеЧасти.*.Реквизиты.*

    |Метаданные.Задачи.*.Реквизиты.*

    |Метаданные.Задачи.*.РеквизитыАдресации.*

    |Метаданные.Задачи.*.ТабличныеЧасти.*.Реквизиты.*

    |";

    ВсеХранимыеРеквизитыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеХранимыеРеквизитыКонфигурации;

    

КонецФункции // ПолучитьВсеХранимыеРеквизитыКонфигурации()



// Возвращает все реквизиты конфигурации составного типа, которые сохраняются в ИБ

//

// Параметры - Нет

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция ПолучитьВсеХранимыеРеквизитыКонфигурацииСоставногоТипа() Экспорт

    

    ВсеХранимыеРеквизитыКонфигурации = ПолучитьВсеХранимыеРеквизитыКонфигурации();

    Рез = Новый ТаблицаЗначений;

    Рез.Колонки.Добавить("Имя", Новый ОписаниеТипов("Строка"));

    Рез.Колонки.Добавить("Тип", Новый ОписаниеТипов("ОписаниеТипов"));

    Рез.Колонки.Добавить("КоличествоПростыхТипов", Новый ОписаниеТипов("Число"));

    

    Для каждого ТекРеквизит Из ВсеХранимыеРеквизитыКонфигурации Цикл

        

        Реквизит = Вычислить(ТекРеквизит);

        Тип = Реквизит.Тип;

        КоличествоПростыхТипов = Тип.Типы().Количество();

        Если КоличествоПростыхТипов<>1 Тогда 

    	    ТекСтрока = Рез.Добавить();

            ТекСтрока.Имя = ТекРеквизит;

            ТекСтрока.Тип = Тип;

            ТекСтрока.КоличествоПростыхТипов = КоличествоПростыхТипов;

        КонецЕсли;

    

    КонецЦикла; 

    

    Возврат Рез;

    

КонецФункции // ПолучитьВсеХранимыеРеквизитыКонфигурации()



// Возвращает все формы конфигурации

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеФормыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.ПланыОбмена.*.Формы.*

    |Метаданные.КритерииОтбора.*.Формы.*

    |Метаданные.ОбщиеФормы.*

    |Метаданные.Справочники.*.Формы.*

    |Метаданные.Документы.*.Формы.*

    |Метаданные.ЖурналыДокументов.*.Формы.*

    |Метаданные.Перечисления.*.Формы.*

    |Метаданные.Отчеты.*.Формы.*

    |Метаданные.Обработки.*.Формы.*

    |Метаданные.ПланыВидовХарактеристик.*.Формы.*

    |Метаданные.ПланыСчетов.*.Формы.*

    |Метаданные.ПланыВидовРасчета.*.Формы.*

    |Метаданные.РегистрыСведений.*.Формы.*

    |Метаданные.РегистрыНакопления.*.Формы.*

    |Метаданные.РегистрыБухгалтерии.*.Формы.*

    |Метаданные.РегистрыРасчета.*.Формы.*

    |Метаданные.БизнесПроцессы.*.Формы.*

    |Метаданные.Задачи.*.Формы.*

    |";

    ВсеФормыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеФормыКонфигурации;

    

КонецФункции // ПолучитьВсеФормыКонфигурации()



// Возвращает все макеты конфигурации

//

// Параметры - Нет

//

// Возвращаемое значение:

//   Массив объектов метаданных

//

Функция ПолучитьВсеМакетыКонфигурации() Экспорт

    

    СтрокаВсехРеквизитов = 

    "

    |Метаданные.ПланыОбмена.*.Макеты.*

    |Метаданные.ОбщиеМакеты.*

    |Метаданные.Справочники.*.Макеты.*

    |Метаданные.Документы.*.Макеты.*

    |Метаданные.ЖурналыДокументов.*.Макеты.*

    |Метаданные.Перечисления.*.Макеты.*

    |Метаданные.Отчеты.*.Макеты.*

    |Метаданные.Обработки.*.Макеты.*

    |Метаданные.ПланыВидовХарактеристик.*.Макеты.*

    |Метаданные.ПланыСчетов.*.Макеты.*

    |Метаданные.ПланыВидовРасчета.*.Макеты.*

    |Метаданные.РегистрыСведений.*.Макеты.*

    |Метаданные.РегистрыНакопления.*.Макеты.*

    |Метаданные.РегистрыБухгалтерии.*.Макеты.*

    |Метаданные.РегистрыРасчета.*.Макеты.*

    |Метаданные.БизнесПроцессы.*.Макеты.*

    |Метаданные.Задачи.*.Макеты.*

    |";

    ВсеМакетыКонфигурации = РазвернутьМассивСтрокОбходаМетаданных(ПолучитьМассивСтрокМногострочнойСтроки(СтрокаВсехРеквизитов));

    Возврат ВсеМакетыКонфигурации;

    

КонецФункции // ПолучитьВсеМакетыКонфигурации()

Категория: Метаданные

Поиск строки в текстовом файле по маске

Есть ли возможность поиска строки в текстовом файле по маске? К примеру ХХХХ-ХХХХ-ХХХХ-ХХХХ.

Код 1C v 8.х

 RegExp = Новый COMОбъект("VBScript.RegExp");

        

RegExp.IgnoreCase = Ложь; //Игнорировать регистр

RegExp.Global = Истина; //Поиск всех вхождений шаблона

RegExp.MultiLine = Истина; //Многострочный режим

          

RegExp.Pattern = "Windows[\w\s\d]*([A-Z1-9]{5}-[A-Z1-9]{5}-[A-Z1-9]{5}-[A-Z1-9]{5}-[A-Z1-9]{5})"; //Ищем ключ Windows



Matches=RegExp.Execute("строка поиска");

ЧислоВхождений=Matches.Count();

Если ЧислоВхождений>0 Тогда

  Для к = 0 По ЧислоВхождений-1 Цикл

       Match = Matches.Item(к);

       SubMatches = Match.SubMatches;

               Ключ=SubMatches.Item(0);

  КонецЦикла;

КонецЕсли;

Категория: Регулярные выражения

Удалить в строке все символы кроме цифр

Код 1C v 7.x

 RegExp = CreateObject("VBScript.RegExp"); // здесь под восьмерку переделай

Код 1C v 8.х

 RegExp = Новый COMОбъект("VBScript.RegExp");

    RegExp.IgnoreCase = Истина; //Игнорировать регистр 

    RegExp.Global = Истина; //Поиск всех вхождений шаблона 

    RegExp.MultiLine = Истина; //Многострочный режим 

        

    RegExp.Pattern = "[^0-9]"; // отбор только чисел

    

    стр=RegExp.Replace(стр, ""); 

    Сообщить(стр);

Категория: Регулярные выражения

Удаление html тегов из строки

Код 1C v 8.х

 RegExp = Новый COMОбъект("VBScript.RegExp");

    RegExp.IgnoreCase = Ложь; //Игнорировать регистр   

    RegExp.Global = Истина; //Поиск всех вхождений шаблона   

    RegExp.MultiLine = Ложь; //Многострочный режим   

    

    RegExp.Pattern = "<[^>]*>"; //Ищем теги HTML   

    стр=RegExp.Replace(стр, ""); //Заменяем все теги на пустоту

Категория: Регулярные выражения

Выбор оптимального алгоритма для разбора строки в массив

Столкнулся с проблемой: ПолучитьСтрокуПоНомеру() медленно отрабатывает на входных данных >100 000 строк. Как сделать бытсрее?

Код 1C v 8.х

  // Пример Defender aka LINN

ВремяНачала = ТекущаяДата(); 

Сообщить("Обработка начата: " + ВремяНачала); 



ТЗ = Новый ТаблицаЗначений; 

Текст = ПолучитьМакет("Макет").ПолучитьТекст(); 



RE = New COMObject("VBScript.RegExp"); 

RE.Global        = Истина; 

RE.IgnoreCase    = Истина; 

RE.Multiline    = Истина; 



RE.Pattern = "^.*$"; 



Строки = RE.Execute(Текст); 



RE.Pattern = "([^\|]+?|\|)(?=\|)"; 



ДобавитьКолонки = Истина; 



Для Каждого СтрокаТекста из Строки Цикл 

   СтрокаДляРазбора = СтрокаТекста.Value; 

    

   Результат = RE.Execute(СтрокаДляРазбора); 

    

   Если ДобавитьКолонки Тогда 

       НомерКолонки = 0; 

       Для Каждого Совпадение Из Результат Цикл 

           НомерКолонки = НомерКолонки + 1; 

           ТЗ.Колонки.Добавить("Колонка" + НомерКолонки); 

       КонецЦикла; 

       ДобавитьКолонки = Ложь; 

   КонецЕсли; 

    

   НоваяСтрока = ТЗ.Добавить(); 

    

   НомерКолонки = 0; 

   Для Каждого Совпадение Из Результат Цикл 

        

       Значение = Совпадение.Value; 

        

       НоваяСтрока[НомерКолонки] = ?(Значение = "|", "", Значение); 

       НомерКолонки = НомерКолонки + 1; 

   КонецЦикла; 

КонецЦикла; 



ВремяОкончания = ТекущаяДата(); 



Сообщить("Обработка завершена: " + ВремяОкончания + ", время обработки: " + Формат('00010101' + (ВремяОкончания-ВремяНачала), "ДФ=мм:сс")); 

Сообщить("Количество строк: " + ТЗ.Количество());

Код 1C v 8.х

 // Пример  aleks-id

Функция InitRegExp(Разделитель = "|")

    RegExp = Новый COMОбъект("VBScript.RegExp");

    

    //Параметры: 

    RegExp.MultiLine = Истина;  // истина — текст многострочный, ложь — одна строка 

    RegExp.Global = Истина;   // истина — поиск по всей строке, ложь — до первого совпадения 

    RegExp.IgnoreCase = Ложь; // истина — игнорировать регистр строки при поиске 

    

    RegExp.Pattern = "[^\" + Разделитель + "]+";

    Возврат RegExp;

КонецФункции



Функция РазложитьСтрокуВМассив(RegExp, Строка)

    

    Matches = RegExp.Execute (Строка);

    

    Массив = Новый Массив;

    

    Для Сч = 0 По Matches.Count - 1 Цикл

        Массив.Добавить(Matches.Item(Сч).Value);

    КонецЦикла;

    

    

    Возврат Массив;

КонецФункции



Процедура КнопкаВыполнитьНажатие(Кнопка)

    Текст = Новый ЧтениеТекста("C:\aktivy.txt", КодировкаТекста.ANSI);

    RegExp = InitRegExp();

    Стр = Текст.ПрочитатьСтроку();

    Пока Стр <> Неопределено Цикл

        масс = РазложитьСтрокуВМассив(RegExp, Стр);

        Стр = Текст.ПрочитатьСтроку();

    КонецЦикла;

    RegExp = Неопределено;

КонецПроцедуры

Категория: Регулярные выражения

Разбить строку на подстроки

Разлогает строку типа:
Поле1, "Сложное, с запятыми внутри Поле2", Поле3
на массимв подстрок типа:

Поле1
Сложное, с запятыми внутри Поле2
Поле3

Код 1C v 8.х

 RegExp = Новый COMОбъект("VBScript.RegExp");

    Результат = Новый Массив();

    

    RegExp.IgnoreCase = Ложь; //Игнорировать регистр  

    RegExp.Global = Истина; //Поиск всех вхождений шаблона  

    RegExp.MultiLine = Ложь; //Многострочный режим  

    

    RegExp.Pattern = "(?:^|;)(\""(?:[^\""]+|\""\"")*\""|[^;]*)"; //вот наш супер шаблон  

    //RegExp.Pattern = ";|;|;|;|;;|;|;|;|;|;|;|;|;;|;|;"; //вот наш супер шаблон  

    Matches=RegExp.Execute(Стр);

    ЧислоВхождений=Matches.Count();

    //Сообщить(Стр,СтатусСообщения.Важное); 

    Если ЧислоВхождений>0 Тогда 

        Для к = 0 По ЧислоВхождений-1 Цикл

            Match = Matches.Item(к);

            

            SubMatches = Match.SubMatches;

            ЧислоПодвыражений=SubMatches.Count();

            Для н = 0 По ЧислоПодвыражений-1 Цикл

                SubMatch=SubMatches.Item(н);

                Если SubMatch="" Тогда

                    //Продолжить; 

                КонецЕсли;    

                Результат.Добавить(SubMatch);

                //Сообщить("Подстрока: "+SubMatch); 

            КонецЦикла;    

        КонецЦикла;

    Иначе

        //Сообщить("Вхождений шаблона не найдено"); 

    КонецЕсли;

    Возврат Результат;

Живой Ископаемый

Категория: Регулярные выражения

Использование регулярных выражений (RegExp) в 1С

Регулярные выражения (Regular Expressions) являются известным и мощным средством для поиска, тестирования и замены подстрок. Эта технология доступна и в 1С - через объект VBScript.RegExp. Нужный объект уже встроен в современные версии Windows (начиная с Windows 98), и устанавливать дополнительно ничего не нужно.
Приведенные ниже примеры были протестированы в 1С:Предприятие 7.7; для 1С:Предприятие 8.x изменяется способ создания объекта:

Код 1C v 8.х

 RegExp = Новый COMОбъект("VBScript.RegExp");

Кроме того, там уже есть логические константы Истина и Ложь - объявлять их не нужно.

Более подробное описание самой технологии RegExp (что означают те или иные значки или скобочки, или какие шаблоны поиска или замены можно использовать в типичных ситуациях) можно найти в специальной литературе (например Бен Форта "Освой самостоятельно регулярные выражения (regexp) за 10 минут") или на сайтах в сети Internet.

Код 1C v 7.x

 ///////////////////////////////////////////////////////////////////////

//Поиск вхождений подстроки

Процедура RegExp_Exec()

    

    //Для 1С 7.7:

    Истина=-1;

    Ложь=0;

    RegExp = CreateObject("VBScript.RegExp");

    

    RegExp.IgnoreCase = Ложь; //Игнорировать регистр

    RegExp.Global = Истина; //Поиск всех вхождений шаблона

    RegExp.MultiLine = Ложь; //Многострочный режим

    

    RegExp.Pattern = "<[^>]*>"; //Ищем теги HTML

    Matches=RegExp.Execute("Это <hr> строка <br> с тегами HTML");

    ЧислоВхождений=Matches.Count();

    Если ЧислоВхождений>0 Тогда 

        Для к = 0 По ЧислоВхождений-1 Цикл

            Match = Matches.Item(к);

            Сообщить("Найден тег:"+ Match.Value);

        КонецЦикла;

    Иначе

        Сообщить("Вхождений шаблона не найдено");

    КонецЕсли;

    //Выдаст в окно сообщений:    

    //Найден тег:<hr>

    //Найден тег:<br>    

КонецПроцедуры

Более продвинутый пример разбора HTML использует подвыражения (SubMatches) и позволяет находить как сами теги, так и текст между ними.

Код 1C v 7.x

 ///////////////////////////////////////////////////////////////////////

//Поиск вхождений подстроки с использованием подвыражений

Процедура RegExp_Exec1()

    

    //Для 1С 7.7:

    Истина=-1;

    Ложь=0;

    RegExp = CreateObject("VBScript.RegExp");

    

    RegExp.IgnoreCase = Ложь; //Игнорировать регистр

    RegExp.Global = Истина; //Поиск всех вхождений шаблона

    RegExp.MultiLine = Ложь; //Многострочный режим

    

    RegExp.Pattern = "([^<]*)(<[^>]*>)([^<]*)"; //Ищем теги HTML, а также текст до и после тега

    Matches=RegExp.Execute("  <tr><td id=aaa>Дятел <td> долбит <td> сосну </tr>");

    ЧислоВхождений=Matches.Count();

    Если ЧислоВхождений>0 Тогда 

        Для к = 0 По ЧислоВхождений-1 Цикл

            Match = Matches.Item(к);

            

            SubMatches = Match.SubMatches;

            ЧислоПодвыражений=SubMatches.Count();

            Для н = 0 По ЧислоПодвыражений-1 Цикл

                SubMatch=SubMatches.Item(н);

                Если SubMatch="" Тогда

                    Продолжить;

                КонецЕсли;    

                

                Сообщить("Подстрока: "+SubMatch);

            КонецЦикла;    

        КонецЦикла;

    Иначе

        Сообщить("Вхождений шаблона не найдено");

    КонецЕсли;

КонецПроцедуры



//Выводит в окно сообщений:

//Подстрока:   

//Подстрока: <tr>

//Подстрока: <td id=aaa>

//Подстрока: Дятел 

//Подстрока: <td>

//Подстрока:  долбит 

//Подстрока: <td>

//Подстрока:  сосну 

//Подстрока: </tr>

Часто регулярные выражения используются для тестирования строк, например пользовательского ввода.
Этот пример позволяет узнать, является ли строка целым числом.

Код 1C v 7.x

 ///////////////////////////////////////////////////////////////////////

//Проверка подстроки

Процедура RegExp_Test()

    RegExp = CreateObject("VBScript.RegExp");

    RegExp.Pattern =  "^\d+$"; //Шаблон, который соответствует целому числу

    стр="12345";//Строка, которую тестируем

    Если RegExp.Test(стр)=0 Тогда

        Сообщить("Это не целое число");

    Иначе

        Сообщить("Это целое число");

    КонецЕсли;

    //Выдаст в окно сообщений:    

    //"Это целое число"

КонецПроцедуры

Регулярные выражения поддерживают не только поиск, но и замену текста. При этом найденные подвыражения (в круглых скобках) могут быть представлены в строке замены как $1, $2 и т. д.
(знак доллара используется в VBScript.RegExp; в других средах программирования, например в JavaScript, используемый для этой цели символ может отличаться).

Код 1C v 7.x

 ///////////////////////////////////////////////////////////////////////

//Замена текста в подстроке

Процедура RegExp_Replace()

    

    //Строка, где мы будем производить замены

    стр="Дятел долбил сосну";

    

    Истина=-1;

    Ложь=0;

    RegExp = CreateObject("VBScript.RegExp");

    

    RegExp.IgnoreCase = Истина; //Игнорировать регистр

    RegExp.Global = Истина; //Поиск всех вхождений шаблона

    RegExp.MultiLine = Истина; //Многострочный режим

    

    

    RegExp.Pattern = "(долбил)"; 

    

    стр=RegExp.Replace(стр, "про$1"); 

    Сообщить(стр);

    //Выдаст в окно сообщений:    

    //"Дятел продолбил сосну"

КонецПроцедуры

Источник

Категория: Регулярные выражения

Проверка на корректность адреса Электронной Почты, e-mail

Каким образом можно организовать проверку на корректность адреса электронной почты?

Код 1C v 8.х

 Шаблон = ".+@.+\..+"; // регулярное выражение соответствует произвольному e-mail адресу



СтрокаАдреса = "ivanov@mail.com"; // проверяемый адрес

//CтрокаАдреса = ЭлементыФормы.ПолеВводаАдреса.Значение;  //проверяемый адрес для элемента формы



RegExp = Новый COMОбъект("VBScript.RegExp"); // создаем объект для работы  с регулярными выражениями

RegExp.MultiLine = Ложь;    // истина — текст многострочный, ложь — одна строка

RegExp.Global = Истина;     // истина — поиск по всей строке, ложь — до первого совпадения

RegExp.IgnoreCase = Истина; // истина — игнорировать регистр строки при поиске

RegExp.Pattern = Шаблон;    // шаблон (регулярное выражение) для проверки  корректности e-mail

Если RegExp.Test(СтрокаАдреса) Тогда

     Сообщить("Корректный адрес");

Иначе

     Сообщить("Некорректный адрес");

КонецЕсли;

Для 7.7 в вышеуказанном коде заменить создание объекта на:

Код 1C v 7.x

 RegExp = CreateObject("VBScript.RegExp");

Категория: Регулярные выражения

Как организовать работу удаленных складов?

Код 1C v 8.х

 Процедура ПриОтправкеДанныхПодчиненному(ЭлементДанных, ОтправкаЭлемента) 



	Если ТипЗнч(ЭлементДанных) = Тип("ДокументОбъект.РеализацияТоваров") Тогда 

		Если ЭлементДанных.Склад <> Склад Тогда 

			ОтправкаЭлемента = ОтправкаЭлементаДанных.Удалить; 

		КонецЕсли; 

	КонецЕсли; 



КонецПроцедуры 





Процедура ПриПолученииДанныхОтПодчиненного(ЭлементДанных, ПолучениеЭлемента, ОтправкаНазад) 



	Если ТипЗнч(ЭлементДанных) = Тип("ДокументОбъект.РеализацияТоваров") Тогда 

		ПолучениеЭлемента = ПолучениеЭлементаДанных.Принять; 

	КонецЕсли; 



КонецПроцедуры 





Процедура ПриПолученииДанныхОтГлавного(ЭлементДанных, ПолучениеЭлемента, ОтправкаНазад) 



	Если ТипЗнч(ЭлементДанных) = Тип("ДокументОбъект.РеализацияТоваров") Тогда 

		Если ПланыОбмена.ИзменениеЗарегистрировано(Ссылка, ЭлементДанных) Тогда 

			ПолучениеЭлемента = ПолучениеЭлементаДанных.Игнорировать; 

		КонецЕсли; 

	КонецЕсли; 



КонецПроцедуры

Категория: Конвертация данных, Обмен, Перенос

Конструктор схемы компоновки данных - Закладка Набор данных - Объект

Для набора данных «Объект» используется для передачи в СКД внешних данных, таких как таблица значений, результат запроса. Для этого набора данных доступны описания полей, а также название объекта, которые будет передан в СКД:
title

Описание полей набора данных
После определения, какого вида мы набор данных используем, следует внести описание полей для данных, выводимых в отчет:
title

В таблице «Поля» заполняются свойства:
1. «Поле» - имя поля, в случае запроса заполняется автоматически, в случае набора данных «Объект» определяется вручную.

2. «Путь» - указывается путь к данным из набора. Именно это название, указанное в этом поле будет фигурировать во всех дальнейших настройках СКД.

3. «Заголовок» - строка с заголовком поля, которые выводится в отчет или в настройках

4. «Ограничение доступности поля» - ряд галочек – настроек, служит для указания того, как данное поле не может быть использовано в настройках. Возможно, указать такие ограни-чения
a. «Поле» - поле нельзя использовать в выборках СКД
b. «Условие» - поле нельзя использовать как условие
c. «Группа» - запрет на использование поля в группировках
d. «Упорядочивание» - запрет использовать поле в сортировках

5. «Ограничение доступности полей-реквизитов» - ряд галочек ниже, указывает на ограничения для реквизитов поля, смысл установки данных ограничений такой же что и в для поля

6. «Роль» - обозначает дополнительные свойства поля и его взаимоотношения с другими полями. Для редактирования ролей открывается специальный диалог:
title

a. «Без роли» - никаких особых «нагрузок» на поле не накладывается, режим по умолчанию для большинства полей
b. «Период» - содержит номер периода, если поле имеет тип периода. Самый младший период должен иметь тип 1. Например, в запросе рассчитываем итоги по различным периодам: ПериодСекунда = 1, ПериодДень=2, ПериодНеделя=3 и т.д. Данный номер будет указывать, как в СКД рассчитывается итоги по полям остатка.
c. «Дополнительный» – указывает на то, что поле–период не является обязательным
d. «Счет» - указывает на то, что поля является бухгалтерским счетом, используется для рас-чета бухгалтерских итогов.
e. «Вид» - строка выражение, с помощью которого рассчитывается вид счета. Результатом выражения должно быть значение перечисления ВидСчета (Активный, Пассивный, Активно/Пассивный), либо число. Значение числа 0 соответствует активному счету, 1 – пассивному, 2 – активно-пассивному. Выражение записывается на языке выражений системы компоновки данных. Данная информация используется при расчете по полям бухгалтерских остатков;
f. «Остатки» – признак того, что поле является полем остатка;
g. «Имя» – строка, содержащая имя группы полей остатка. Например: "Сумма", "Количест-во";
h. «Тип» – тип остатка (НачальныйОстаток, КонечныйОстаток, Нет (поле не является остат-ком));
i. «Бух. Тип» – тип бухгалтерского остатка (Дебет, Кредит, Нет (поле не является бухгалтерским остатком));
j. «Поле счета» – имя поля-счета, для которого рассчитываются остатки;
k. Игнорировать значения NULL – если установлено, то в результат не нужно включать групповые записи по данному полю в случае, если поле содержит значение NULL.
l. «Обязательное» - при выполнении запроса поле с указанным флажком будут присутствовать всегда, даже если не были выбраны в выборке.

7. «Выражение представления» - содержит выражение, которое используется при выводе зна-чений поля в отчет.
title

Например нужно преобразовать дату в особый формат для этого указываем такое выражение «Формат(ПериодПолугодие,"ДФ = '""Полугодие с"" дд.ММ.гггг""'")» или ссылку на документ преобразовать к произвольному виду: ««Дата: »+Ссылка.Дата+«Номер: »+Ссылка.Номер».

8. «Выражение упорядочивания» - как упорядочивать это поле. При редактировании открывается диалог:
title

В диалоге можно указать, как данное поле упорядочивать. «Выражение» - как упорядочива-ется это поле, «Тип упорядочивания» - «по возрастанию» или «по убыванию», «Необходи-мость автоупорядочивания» – автоматическое определение полей, по которым необходимо упорядочивать результат компоновки данных.

9. «Проверка иерархии» - используется, в случае если нужно формировать нестандартные отборы.
a. «Набор данных» – набор данных для проверки иерархии;
b. «Параметр» – параметр, в который будет подставляться значение, для которого нужно получить дочерние элементы;

10. «Тип значения» - уточнение типа значения поля набора данных, полезно использховать для уточнения полей составного типа

11. «Оформление» - параметры оформления поля набора данных. При редактировании открывается диалог:
title

Можно задавать следующие параметры:
Цвет фона - Определяет цвет фона в ячеках
Цвет текста - Определяет цвет текст в ячейках
Цвет в диаграмме - Определяет цвет линий в диа-грамме
Цвет границы - Цвет линий границы
Стиль границы - Типы линий границы
Стиль границы слева - слева
Стиль границы сверху - сверху
Стиль границы справа - справа
Стиль границы снизу - снизу
Шрифт - Вид шрифта, толщина, наклон и т.д.
Отступ - Количество знаков отступа
Авто отступ - Количество знаков отступа, применяется в группировках
Горизонтальное положение - Положение текста в ячейке по горизонтали
Вертикальное положение - Положение текста в ячейке по вертикале
Размещение - Размещение текста который не помещается в ячейку
Ориентация текста - Ориентация текст в градусах (90-поворот перпендикулярно)
Формат - Форматная строка значения
Выделять отрицательные - Признак того чтобы выделять отрицательные значения
Минимальная ширина - Минимальная ширина ячейки в пунктах
Минимальная высота - Минимальная высота ячеки
Максимальная высота - Максимальная высота
Текст - Текст который выводится вместо значения

Далее, эти параметры используются для настройки условного оформления при выводе полей в отчет.
Кроме элементов полей в описании могут присутствовать папки, которые служат для организации расположения полей в доступных полях.
title

Для того чтобы поместить поле в папку, нужно создать папку, например «Отбор», далее для полей помещаемых в папку указать путь через точку: «Отбор.Организация», «Отбор.Подразделения». После этого в доступных полях при настройке мы увидим папку, содержащую указанные нами элементы.
title

Категория: Схема Компоновки Данных

Функция РАЗНОСТЬДАТ

РАЗНОСТЬДАТ(<Выражение>, <Выражение>, Секунда | Минута | Час | День | Месяц | Квартал | Год)
В качестве первого параметра передается выражение, значение которого необходимо вычесть из значения второго параметра.
В качестве второго параметра функции передается выражение, из которого необходимо вычесть значение первого параметра.
Третий параметр содержит единицу измерения, в которой необходимо получить результат функции. В качестве третьего параметра можно использовать следующие значения: Секунда, Минута, Час, День, Месяц, Квартал, Год. При расчете результата функция игнорирует единицы измерения, которые меньше, чем указанная в данном параметре единица.

Например, если в качестве третьего параметра указать Час, то при расчете результата будут игнорироваться минуты и секунды, присутствующие в первых двух параметрах. Если же в третьем параметре указать Месяц, то игнорироваться будут дни, часы, минуты и секунды.

Рассмотрим, какие значения будет возвращать функция при различных значениях третьего параметра:

Код 1C v 8.х

 

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 12, 31, 10, 20, 34), ДАТАВРЕМЯ(2003, 01, 01, 9, 18, 06), СЕКУНДА) // 82 652

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 12, 31, 10, 20, 34), ДАТАВРЕМЯ(2003, 01, 01, 9, 18, 06), МИНУТА) // 1 378

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 12, 31, 10, 20, 34), ДАТАВРЕМЯ(2003, 01, 01, 9, 18, 06), ЧАС) // 23

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 12, 31, 10, 20, 34), ДАТАВРЕМЯ(2003, 01, 01, 9, 18, 06), ДЕНЬ) // 1

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 12, 31, 10, 20, 34), ДАТАВРЕМЯ(2003, 01, 01, 9, 18, 06), МЕСЯЦ) // 1

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 12, 31, 10, 20, 34), ДАТАВРЕМЯ(2003, 01, 01, 9, 18, 06), КВАРТАЛ) // 1

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 12, 31, 10, 20, 34), ДАТАВРЕМЯ(2003, 01, 01, 9, 18, 06), ГОД) // 1

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 01, 01, 0, 0, 0), ДАТАВРЕМЯ(2002, 12, 31, 23, 59, 59), СЕКУНДА) // 31 535 999

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 01, 01, 0, 0, 0), ДАТАВРЕМЯ(2002, 12, 31, 23, 59, 59), МИНУТА) // 525 599

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 01, 01, 0, 0, 0), ДАТАВРЕМЯ(2002, 12, 31, 23, 59, 59), ЧАС) // 8 759

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 01, 01, 0, 0, 0), ДАТАВРЕМЯ(2002, 12, 31, 23, 59, 59), ДЕНЬ) // 364

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 01, 01, 0, 0, 0), ДАТАВРЕМЯ(2002, 12, 31, 23, 59, 59), МЕСЯЦ) // 11

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 01, 01, 0, 0, 0), ДАТАВРЕМЯ(2002, 12, 31, 23, 59, 59), КВАРТАЛ) // 3

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 01, 01, 0, 0, 0), ДАТАВРЕМЯ(2002, 12, 31, 23, 59, 59), ГОД) // 0

Категория: Запросы

Функция разбора (разложения) строки в массив

Данные функции позволяют разложить строку в массив, используя заданный разделитель
Например есть строка: абв$dfd$232$-0oj$5
Выполнив код: НашМассив = РазложитьСтрокуВМассив(абв$dfd$232$-0oj$5, "$") ;
Получим: НашМассив = абв
dfd
232
-0oj
5

Код 1C v 8.х

 

// Функция "расщепляет" строку на подстроки, используя заданный 

//		разделитель. Разделитель может иметь любую длину. 

//		Если в качестве разделителя задан пробел, рядом стоящие пробелы 

//		считаются одним разделителем, а ведущие и хвостовые пробелы параметра Стр

//		игнорируются.

//		Например, 

//		РазложитьСтрокуВМассивПодстрок(",ку,,,му", ",") возвратит массив значений из пяти элементов, 

//		три из которых - пустые строки, а 

//		РазложитьСтрокуВМассивПодстрок(" ку   му", " ") возвратит массив значений из двух элементов

//

//	Параметры: 

//		Стр - строка, которую необходимо разложить на подстроки. 

//		Разделитель - 	строка-разделитель, по умолчанию - запятая.

//

//	Возвращаемое значение:

//		массив значений, элементы которого - подстроки

//

Функция РазложитьСтрокуВМассив(Знач Стр, Разделитель = ",") Экспорт

	

	МассивСтрок = Новый Массив();

	Если Разделитель = " " Тогда

		Стр = СокрЛП(Стр);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = СокрЛ(Сред(Стр,Поз));

		КонецЦикла;

	Иначе

		ДлинаРазделителя = СтрДлина(Разделитель);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = Сред(Стр,Поз+ДлинаРазделителя);

		КонецЦикла;

	КонецЕсли;

	

КонецФункции

Пример с использованием предустановленной библиотеки RegExp, т.е. она есть в любом windows.
Плюсы RegExp:
1. Хорошая скорость анализа, т.к. 1С анализ строк (разбор) обычно реализуется циклами и функциями: Лев, Прав, Сред, Найти, а встроенный язык медленный
2. Высокая читаемость и модифицированность (более предсказуем в случае несоответствия строки - разбору)
3. Дополнительный функционал (можно осуществлять анализ, замену и проверку строковых выражений)

Минусы RegExp:
1. Не все задачи можно решить (например рекурсивные разборы тип 1 + (2+3*(2-7)) в случае если нужно разобрать на выражения в скобках) приходится смешивать с кодом.
2. Возможность зависания при использовании сложных шаблонов(редкость, но бывает).
3. RegExp - это дополнительная библиотека и инициализация занимает значительное время.

Код 1C v 8.х

  // Пример с использованием предустановленной библиотеки RegExp, т.е. она есть в любом windows.

Функция РазложитьСтрокуВМассив(Строка, Разделитель = ",") Экспорт

	RegExp = Новый COMОбъект("VBScript.RegExp");    // создаем объект для работы с регулярными выражениями

	

	//Параметры:

	RegExp.MultiLine = Ложь;  // истина — текст многострочный, ложь — одна строка

	RegExp.Global = Истина;   // истина — поиск по всей строке, ложь — до первого совпадения

	RegExp.IgnoreCase = Ложь; // истина — игнорировать регистр строки при поиске

	

	//Разбор строки вида 1,СЛОВО,(1+2); Маска для разделителя ',' [^\,]*"

	RegExp.Pattern = "[^\" + Разделитель + "]+";

	Matches = RegExp.Execute (Строка);

	

	Массив = Новый Массив;

	

	Для Сч = 0 По Matches.Count - 1 Цикл

		Массив.Добавить(Matches.Item(Сч).Value);

	КонецЦикла;

	

	RegExp = Неопределено;

	

	Возврат Массив;

КонецФункции

Посмотрите Функцию разложить строку на подстроки (в список значений), используя заданный разделитель.

Категория: Работа с Текстом (Строкой)