картинкой » Поиск

Результаты по ключевому слову: картинкой

Как уменьшить вес картинок в базе данных или изменить размер, ширину или высоту картинок?

Иногда возникает необходимость обработать фотографии в 1С автоматически, уменьшить вес картинок в килобайтах, за счет удаления из файла не нужной технической информации и сглаживания цветов, или изменить размер, уменьшить картинку пропорционально задав максимальный размер по ширине или высоте.В этом случае можно:1) установить специальные библиотеки в операционной системе для работы с графикой, н-р GFLAx и подключать их как com-объекты2) использовать api сервисов, таких как optipic.io.

Рассмотрим оба варианта:1) Использование GFLAxСкачиваем и устанавливаем библиотеку GFLAx, скачать можно здесь https://www.xnview.com/en/#downloads

Далее её надо зарегистрировать в Windows. Для этого запускаем CMD.exe с правами администратора и набираем: regsrv32 "путь_к_DLL\GFLAx.dll"Далее уже в программе, для пропорционального изменения размера файла до максимального размера в 500 пикселей можно вставить такой код:

Код 1C v 8.х

 GFLAx = Новый COMОбъект("GFLAx.GFLAx");

GFLAx.LoadBitmap(ИмяИсходногоФайла);

// Получаем исходный размер картинки

Ширина = GFLAx.Width;

Высота = GFLAx.Height;

//определяем максимальную сторону по которой будем проводить пропорциональное изменениеДелитель= ?(Ширина>Высота, Делитель=Ширина/500, Делитель=Высота/500);

НоваяШирина = Ширина/Делитель;

НоваяВысота = Высота/Делитель;

GFLAx.Resize(Цел(НоваяШирина),Цел(НоваяВысота));

GFLAx.SaveBitmapИмяВыходногоФайла);

Данный способ требует специальных настроек операционной системы, навыков системного администрирования и данный способ не проводит полноценную оптимизацию картинки.Кроме того, на компьютере или сервере, где производиться оптимизация эта библиотека должна быть установлена.2) Использование сервиса optipic.ioПодобные сервисы обычно платные, но стоимость использования не высокая, а качество и гибкость существенно выше.

Преимущества использования сервиса optipic.io в проектах 1С:

Легко подключить
Не нужно устанавливать дополнительные библиотеки в операционной системе
Можно использовать как для оптимизации изображений, так и для изменения размера изображения в пикселях (ресайз)
Не зависит от операционной системы и типа используемого клиента
Конфигурация будет работать после переезда на другой компьютер или сервер
Качество и эффективность сжатия производятся в самом оптимальном виде

Использование сервиса можно легко встроить в любой свой проект на 1С. Для этого можно добавить себе функцию, в которую передавать имя файла с исходной картинкой и параметры оптимизации. А в качестве ответа получить имя файла уже оптимизированного сервисом.

Пример такой функции для 1C8:

Код 1C v 8.х

 Функция ОптимизироватьКартинку(ФайлКартинкиИсходный, Качество=70, НужноИзменятьРазмер=Ложь, МаксимальнаяШирина=1000, МаксимальнаяВысота=1000) Экспорт

	ssl = Новый ЗащищенноеСоединениеOpenSSL(Неопределено, Неопределено); 

	email  = "ВашEmail";

	Пароль = "ВашПароль";

	Соедиенение = Новый HTTPСоединение("optipic.io", , email, Пароль, , ,ssl);

	СкриптНаСайте = "api/compress?quality="+Качество+"&from=1c";

	Если НужноИзменятьРазмер Тогда

		СкриптНаСайте = СкриптНаСайте + "&maxwidth="+Формат(МаксимальнаяШирина, "ЧГ=")+"&maxheight="+Формат(МаксимальнаяВысота, "ЧГ=");

	КонецЕсли;

	

	НовыйФайлКартинки = ПолучитьИмяВременногоФайла();

	

	Попытка

		Результат  = Соедиенение.ОтправитьДляОбработки(ФайлКартинкиИсходный, СкриптНаСайте, НовыйФайлКартинки);

		Возврат НовыйФайлКартинки;

		

	Исключение

		//Обработка ошибки

		//Не удалось получить файл

		//Или нужно пополнить баланс

		Возврат ФайлКартинкиИсходный;

	КонецПопытки;

		

КонецФункции

И далее в коде обращаться к данной функции, н-р так

Код 1C v 8.х

 НовыйФайл = ОптимизироватьКартинку(ФайлКартинкиИсходный, 70, Истина, 500, 500);

Категория: 1С ERP Управление предприятием 2.0

Как сделать паузу при выполнении кода с информативным сообщением для пользователя Категория: Работа с Формой (Диалог) и её элементами

Как с помощью интернет-почты создать письмо, содержащее HTML-текст с картинками? Категория: Работа с Интернет, Почтой (Mail), FTP

Вывод картинки (изображения) на печать, в макет (табличный документ)

Код 1C v 8.х

 // 1-й вариант

//Как вывести картинку в табличный документ?



ТабДок = Новый ТабличныйДокумент; 

Макет = ОбработкаОбъект.ПолучитьМакет("Макет"); 

ОбластьКартинки = Макет.ПолучитьОбласть("ОбластьСКартинкой"); 

Картинка = Новый Картинка(ПутьККартинке); 



// Элемент управления "Логотип" входит в коллекцию картинок области. 

ОбластьКартинки.Рисунки.Логотип.Картинка = Картинка; 

ТабДок.Вывести(ОбластьКартинки); 



ТабДок.Показать(); 



// 2-й вариант

//Как вывести картинку в табличный документ без изменения макета?



Область = Макет.ПолучитьОбласть("Шапка"); 

Рисунок = Область.Рисунки.Добавить(ТипРисункаТабличногоДокумента.Картинка); 

Рисунок.Верх = 5; 

Рисунок.Высота = 10; 

Рисунок.Ширина = 10; 

Рисунок.Лево = 5; 

Рисунок.Картинка = Новый Картинка(ПутьККартинке); 

Рисунок.РазмерКартинки = РазмерКартинки.РеальныйРазмер; 



ТабДок.Вывести(Область); 



//3-й вариант

//ПечатьОрганизации , добавляем в макет картинку с именем Картинка1 в самую нижнюю

//область с именем ОбластьПечатьОрганизации

ОбластьПечатьОрганизации = Макет.ПолучитьОбласть("ПечатьОрганизации");

Картинка= Новый Картинка("C:\files\img\печатьОрганизации.gif") ;

ОбластьПечатьОрганизации.Рисунки.Картинка1.Картинка = картинка;

ТабДок.Вывести(ОбластьПечатьОрганизации);



// 4-й вариант динамически

ОбластьПечатьОрганизации = Макет.ПолучитьОбласть("ПечатьОрганизации");

КартинкаПечатьОрганизации = ОбластьПечатьОрганизации.Рисунки.Добавить(ТипРисункаТабличногоДокумента.Картинка);

КартинкаПечатьОрганизации.Картинка = БиблиотекаКартинок.ОбщаяКартинка1;

КартинкаПечатьОрганизации.Верх = 0;

КартинкаПечатьОрганизации.Высота = 80;

КартинкаПечатьОрганизации.Ширина = 80;

КартинкаПечатьОрганизации.Лево = 50;

КартинкаПечатьОрганизации.ГраницаСверху = Ложь;

КартинкаПечатьОрганизации.ГраницаСлева = Ложь;

КартинкаПечатьОрганизации.ГраницаСправа = Ложь;

КартинкаПечатьОрганизации.ГраницаСнизу = Ложь;

КартинкаПечатьОрганизации.РазмерКартинки = РазмерКартинки.АвтоРазмер;

ТабДок.Вывести(ОбластьПечатьОрганизации);



//5-й вариант получение картинки из хранилища значений

// Выборка.Изображение - выборка из запроса, Изображение реквизит -хранил. значений  

Попытка

    Путь = КаталогВременныхФайлов()+ "\1С_Картинка_"+Формат(ТекущаяДата(),"ДФ=yyyyMMddЧЧммсс")+".bmp";

    КартинкаВПамяти = Выборка.Изображение.Получить();

    КартинкаВПамяти.Записать(Путь);

    ОбластьСостав.Рисунки.D1.Картинка = Новый Картинка(Путь);

Исключение

    ОбластьСостав.Рисунки.D1.Картинка = Новый Картинка;

КонецПопытки;

Для 7.7 пример обработки, которая выводит все картинки (.jpg) из выбранного каталога (и подкаталогов) в печатную форму Скачивать файлы может только зарегистрированный пользователь!

Вот ее код:

Код 1C v 7.x

 Перем Картинка, ТЗКаталога, ПутьКаталогаРисунков;

//******************************************************************************

Процедура Сформировать1()

    Таб = СоздатьОбъект("Таблица");

    Таб.ИсходнаяТаблица("Сформировать");

    Картинка = СоздатьОбъект("Картинка");

    т=1;

    ТЗКаталога.ВыбратьСтроки();

    Пока ТЗКаталога.ПолучитьСтроку() = 1 Цикл

        Картинка.Загрузить(ТЗКаталога.Путь);

        Сформировать = т; 

        Таб.ВывестиСекцию("Заголовок");

        т = т+1;

    КонецЦикла;

    Таб.Опции(0,0,0,0);

    Таб.Показать("Сформировать","");

    ТЗКаталога = "";

КонецПроцедуры  

//******************************************************************************

Процедура карт(карт)     //Вызывается из объекта картинка на печатной форме

    карт.РежимРисования(3);

    карт.УстановитьКартинку(Картинка);

КонецПроцедуры      //карт(карт)     Вызывается из объекта картинка на печатной форме

//******************************************************************************

Процедура СканироватьКаталог(Каталог)    

    Перем А;

    ФСО=СоздатьОбъект("ФС");

    Ф=ФСО.НайтиПервыйФайл(Каталог+"*");

    Пока Ф<>"" Цикл

        Если (Ф<>".")И(Ф<>"..") Тогда

            ФС.АтрибутыФайла(Каталог+Ф,,А);

            Если Сред(А,4,1)="1" Тогда 

                СканироватьКаталог(Каталог+Ф+"\");

            Иначе 

                Если (Прав(Ф,4)=".jpg") или (Прав(Ф,4)=".wmf") или (Прав(Ф,4)=".emf") или (Прав(Ф,4)=".ico") или (Прав(Ф,4)=".bmp") или (Прав(Ф,4)=".dib") или (Прав(Ф,4)=".rle") Тогда

                    ТЗКаталога.НоваяСтрока();

                    ТЗКаталога.Путь = Каталог+Ф;

                    ТЗКаталога.Файл = Ф;        //Для поиска файла по имени (исп в другой обработке)

                КонецЕсли;

            КонецЕсли;

        КонецЕсли;

        //Сообщить(Каталог+Ф);

        Ф=ФСО.НайтиСледующийФайл();

    КонецЦикла;

КонецПроцедуры  //СканироватьКаталог(Каталог)   

//******************************************************************************

Процедура Сформировать()  

    Если ФС.ВыбратьКаталог(ПутьКаталогаРисунков,"Выберете папку с рисунками .jpg...",60) <> 1 Тогда

        Предупреждение("Рисунки не покажу!"); 

        Возврат;

    Иначе 

        ТЗКаталога = СоздатьОбъект("ТаблицаЗначений");

        ТЗКаталога.НоваяКолонка("Путь",,,,,,,);

        ТЗКаталога.НоваяКолонка("Файл",,,,,,,);

        СканироватьКаталог(ПутьКаталогаРисунков+"\");

    КонецЕсли;

    Сформировать1(); 

КонецПроцедуры

Категория: Табличный документ

Делаем быстрый поиск по списку Справочника, Документов. Категория: Список Справочника, Документов, Регистров

Как сформировать, вывести на печать таблицу, табличный документ

Код 1C v 8.х

  //Получение макета и областей вывода

	Макет = ПолучитьМакет("Отчет"); 

	ОбластьЗаголовок = Макет.ПолучитьОбласть("Заголовок"); 

	ОбластьКартинки = Макет.ПолучитьОбласть("ОбластьСКартинкой")

	ОбластьШапкаТаблицы = Макет.ПолучитьОбласть("ШапкаТаблицы");

	ОбластьДетальныхЗаписей = Макет.ПолучитьОбласть("Детали"); 

	

	ТабДок = Новый ТабличныйДокумент; 

	//Вывод параметров в область

	ОбластьЗаголовок.Параметры.ДатаНач = ДатаНач; 

	ОбластьЗаголовок.Параметры.ДатаКон = ДатаКон; 

	//Вывод области в табличный документ

	ТабДок.Вывести(ОбластьЗаголовок); 

	//Вывод картинки

	Картинка = Новый Картинка(ПутьККартинке); 

   // Элемент управления "Логотип" входит в коллекцию картинок области. 

	ОбластьКартинки.Рисунки.Логотип.Картинка = Картинка; 

	ТабДок.Вывести(ОбластьКартинки); 

    //Выведем шапку таблицы

	ТабДок.Вывести(ОбластьШапкаТаблицы); 

	//Выведм строки из Результата запроса

    ВыборкаДетали = Результат.Выбрать(); 

	Пока ВыборкаДетали.Следующий() Цикл 

		//Заполним параметры значениями свойств переданного объекта. Заполняются только те параметры, имена которых совпадают с именами свойств объекта.

		ОбластьДетальныхЗаписей.Параметры.Заполнить(ВыборкаДетали); 

		//Запишем в и область Описание примечание из запроса

		ОбластьДетальныхЗаписей.Область("Описание").Примечание.Текст = ВыборкаДетали.СодержаниеСобытия; 

		ТабДок.Вывести(ОбластьДетальныхЗаписей); 

	КонецЦикла; 

	//Зададим параметры вывода

	ТабДок.АвтоМасштаб=истина; // уместить на одну страницу

	ТабДок.ТолькоПросмотр=истина;

	ТабДок.ОриентацияСтраницы=ОриентацияСтраницы.Ландшафт;

	ТабДок.ОтображатьСетку=Ложь;

	ТабДок.ОтображатьЗаголовки=Ложь;

	//Выведем полученный документ

	ТабДок.Показать();

Код 1C v 7.x

  

Процедура ПросмотрДокумента()

	Таб = СоздатьОбъект("Таблица");

	Таб.ИсходнаяТаблица("РасходныйДокумент");

	Секция = Таб.ПолучитьСекцию("Шапка");

	Таб.ВывестиСекцию(Секция);

	Секция = Таб.ПолучитьСекцию("ПодписьТаблицы");

	Таб.ВывестиСекцию(Секция);

	ВыбратьСтроки();

	Пока  ПолучитьСтроку()=1 Цикл 

		Секция = Таб.ПолучитьСекцию("ТабличнаяЧасть");

		Таб.ВывестиСекцию(Секция);

	КонецЦикла;                       

	Секция = Таб.ПолучитьСекцию("Подвал");	

	Таб.ВывестиСекцию(Секция);

	Таб.ТолькоПросмотр(0);

	Таб.Показать();

КонецПроцедуры

Категория: Табличный документ