лстр » Поиск

Результаты по ключевому слову: лстр

Циклы в языке 1С, примеры и тест - какой цикл быстрее?

Циклы применяются для выполнения каких либо повторяющихся действий, возможные варианты перебора в цикле:

Перебираем строки с помощью цикла Для каждого

Код 1C v 8.3

 Для каждого ТекСтрока Из КоллекцияСтрок Цикл

// код обработки

КонецЦикла;

Перебираем строки с помощью цикла Пока

Код 1C v 8.3

 Пока л < КолСтрок Цикл

	// код обработки, например л=л+1;

КонецЦикла;

Перебираем строки с помощью цикла Для

Код 1C v 8.3

 Для л=0 по КолСтрок Цикл

// код обработки, например л=л+1;

КонецЦикла

Еще вариант, но советую его использовать только в без выходных ситуациях, Если

Код 1C v 8.3

 ~НачалоЦикла:

Если л <> КоличествоИтераций Тогда 

// код обработки, например л=л+1;

	Перейти ~НачалоЦикла;

КонецЕсли;

Примеры циклов

Код 1C v 8.2 УП

 &НаКлиенте

Процедура ВыполнитьКод(Команда)

 

    /// Как организовать цикл в 1с 8.3, 8.2

 

    // Для Цикл

    Для Счетчик = 1 По 5 Цикл

        Сообщить(Счетчик); // 1 2 3 4 5

    КонецЦикла;

 

    // Для Каждого Цикл

 

    Дни = Новый Массив();

    Дни.Добавить("Понедельник");

    Дни.Добавить("Вторник");

    Дни.Добавить("Среда");

 

    Для Каждого Элемент Из Дни Цикл

        Сообщить(Элемент); // Понедельник Вторник Среда

    КонецЦикла;

 

    // Пока Цикл

    Счетчик = 0;

    Пока Счетчик < Дни.Количество() Цикл        

        Сообщить(Дни[Счетчик]); // Понедельник Вторник Среда

        Счетчик = Счетчик + 1;     

    КонецЦикла;     

 

    /// Как организовать обратный цикл в 1с 8.3, 8.2     

 

    Счетчик = Дни.Количество() - 1;     

    Пока Счетчик >= 0 Цикл

        Сообщить(Дни[Счетчик]); // Среда Вторник Понедельник

        Счетчик = Счетчик - 1;

    КонецЦикла;

 

    /// Как прервать цикл в 1с 8.3, 8.2

 

    Для Счетчик = 1 По 5 Цикл

        Если Счетчик > 2 Тогда

            Прервать;

        КонецЕсли;

        Сообщить(Счетчик); // 1 2

    КонецЦикла;

 

    /// Как принудительно продолжить цикл в 1с 8.3, 8.2

 

    Для Счетчик = 1 По 5 Цикл

        Если Счетчик <> 3 Тогда

            Продолжить;

        КонецЕсли;

 

        Сообщить(Счетчик); // 3

    КонецЦикла;   

 

КонецПроцедуры

А какой цикл работает быстрее?

Итак, я нашел пять способов, как можно организовать цикл средствами 1С.

Первый вид цикла, назовем его условно «Для По» выглядит так:

Код 1C v 8.х

 Для н = 0 по КоличествоИтераций Цикл

КакиеТоДействия();

КонецЦикла;

Второй вид «Для Каждого»:

Код 1C v 8.х

 Для Каждого ЭлементКоллекции из Коллекция Цикл

КакиеТоДействия();

КонецЦикла;

Третий «Пока»:

Код 1C v 8.х

 Пока н <> КоличествоИтераций Цикл

КакиеТоДействия();

н = н + 1;

КонецЦикла;

Далее вспомнил ассемблерную молодость & цикл «Если»:

Код 1C v 8.х

 ~НачалоЦикла:

Если н <> КоличествоИтераций Тогда

КакиеТоДействия();

н = н + 1;

Перейти ~НачалоЦикла;

КонецЕсли;

Ну и напоследок «Рекурсия»

Код 1C v 8.х

 Процедура РекурсивныйЦикл(н, КоличествоИтераций)

КакиеТоДействия();

Если н <> КоличествоИтераций Тогда

РекурсивныйЦикл(н+1, КоличествоИтераций);

КонецЕсли;

КонецПроцедуры

Естественно, что относить рекурсию к циклам не совсем корректно, но тем ни менее с её помощью можно добиться похожих результатов. Сразу оговорюсь, что в дальнейшем тестировании рекурсия не участвовала. Во первых все тесты проводились при 1 000 000 итераций, а рекурсия выпадает уже при 2 000. Во вторых скорость рекурсии в десятки раз меньше, чем скорость остальных циклов.

Последнее отступление. Одним из условий было выполнение в цикле каких-либо действий. Во первых пустой цикл используется очень редко. Во вторых цикл «ДляКаждого» используется для какой-либо коллекции, а значит и остальные циклы должны работать с коллекцией, чтобы тестирование проходило в одинаковых условиях.

Ну что ж, поехали. В качестве тела цикла использовалось чтение из заранее заполненного массива.

Код 1C v 8.х

 ПриемникТестовогоЗначения = ТестовыйМассив.Получить(н);

или, при использовании цикла «Для Каждого»

Код 1C v 8.х

 ПриемникТестовогоЗначения = Элем;

Тестирование проводилось на платформе 8.3.5.1231 для трех видов интерфейса (Обычное приложение, Управляемое приложение и Такси).

Результаты для 8.3.5.1231

Интерфейс	ДляПо	ДляКаждого	Пока	Если
Обычное приложение	5734,2	4680,4	7235,4	7263,0
Управляемое приложение	5962,4	4882,6	7497,4	7553,6
Такси	5937,2	4854,6	7500,8	7513,0

Числа это время в миллисекундах полученное с помощью функции ТекущаяУниверсальнаяДатаВМиллисекундах(), которую я вызывал до цикла и после его завершения. Числа дробные, потому что я использовал среднее арифметическое пяти замеров. Почему я не использовал Замер производительности? У меня не было цели замерить скорость каждой строчки кода, только скорость циклов с одинаковым результатом работы.

Казалось бы и все, но & тестировать так тестировать!

Результаты для 8.2.19.106

Интерфейс	ДляПо	ДляКаждого	Пока	Если
Обычное приложение	4411,8	3497,2	5432,0	5454,0
Управляемое приложение	4470,8	3584,8	5522,6	5541,0

В среднем платформа 8.2 на 25% быстрее, чем 8.3. Я немножко не ожидал такой разницы и решил провести тест на другой машине. Скажу только, что там 8.2 была быстрее процентов на 20.

Почему? Не знаю, дезасемблировать ядро в мои планы не входило, но в замер производительности я все же заглянул. Оказалось, что сами циклические операции в 8.3 проходят несколько быстрее, чем в 8.2. Но на строке

Код 1C v 8.х

 ПриемникТестовогоЗначения = ТестовыйМассив.Получить(н);

то есть при считывании элемента коллекции в переменную происходит значительное снижение производительность.

Для себя я сделал несколько выводов:

1. Если есть возможность использовать специализированный цикл & «Для Каждого», то лучше использовать его. Кстати, сам по себе он отрабатывает дольше чем другие циклы, но скорость доступа к элементу коллекции у него на много выше.

2. Если заранее знаешь количество итераций & используй «Для По». «Пока» отработает медленнее.

3. Если использовать цикл «Если» & другие программисты тебя явно не поймут.

В статье использованы материалы с хабра и хелпме

Категория: Встроенные Функции

Функции для работы с ZIP-архивами

В работе часто приходится сжимать выгруженные данные в zip архив, отправлять по почте, и потом автоматически разархивировать полученный zip файл:

Код 1C v 8.х

 // Распаковывает файл архива ZIP в указанный каталог; Извлекает все файлы архива

//

// Параметры:

//  ПолноеИмяФайлаАрхива  - Строка - имя файла архива, который необходимо распаковать

//  ПутьРаспаковкиФайлов  - Строка - путь по которому необходимо распаковать файлы

//  ПарольАрхива          - Строка - пароль для распаковки архива. По умолчанию пустая строка

// 

// Возвращаемое значение:

//  Результат - Булево - Истина, если успешно, Ложь, если нет.

//

Функция РаспаковатьZipФайл(Знач ПолноеИмяФайлаАрхива, Знач ПутьРаспаковкиФайлов, Знач ПарольАрхива = "") Экспорт

	

	// возвращаемое значение функции

	Результат = Истина;

	

	Попытка

		

		Архиватор = Новый ЧтениеZipФайла(ПолноеИмяФайлаАрхива, ПарольАрхива);

		

	Исключение

		Архиватор = Неопределено;

		СообщитьОбОшибке(КраткоеПредставлениеОшибки(ИнформацияОбОшибке()));

		Возврат Ложь;

	КонецПопытки;

	

	Попытка

		

		Архиватор.ИзвлечьВсе(ПутьРаспаковкиФайлов, РежимВосстановленияПутейФайловZIP.НеВосстанавливать);

		

	Исключение

		

		СтрокаСообщения = НСтр("ru = 'Ошибка при распаковке файлов архива: %1 в каталог: %2'");

		СтрокаСообщения = ПодставитьПараметрыВСтроку(СтрокаСообщения, ПолноеИмяФайлаАрхива, ПутьРаспаковкиФайлов);

		Сообщить(СтрокаСообщения);

		

		Результат = Ложь;

	КонецПопытки;

	

	Архиватор.Закрыть();

	Архиватор = Неопределено;

	

	Возврат Результат;

	

КонецФункции





// Запаковывает указанный каталог в файл архива ZIP

//

// Параметры:

//  ПолноеИмяФайлаАрхива  - Строка - имя файла архива, в который необходимо запаковать

//  МаскаУпаковкиФайлов    - Строка - имя файла, помещаемого в архив, или маска.

//			Недопустимо использование в именах файлов и папок букв национальных алфавитов, которые при 

//			преобразовании из символов UNICODE в узкие символы могут быть преобразованы с потерей информации. 

//			Рекомендуется использовать в именах файлов и папок символы латинского алфавита. 

//  ПарольАрхива          - Строка - пароль для архива. По умолчанию пустая строка

// 

// Возвращаемое значение:

//  Результат - Булево - Истина, если успешно, Ложь, если нет.

//

Функция ЗапаковатьВZipФайл(Знач ПолноеИмяФайлаАрхива, Знач МаскаУпаковкиФайлов, Знач ПарольАрхива = "") Экспорт

	

	// возвращаемое значение функции

	Результат = Истина;

	

	Попытка

		

		Архиватор = Новый ЗаписьZipФайла(ПолноеИмяФайлаАрхива, ПарольАрхива);

		

	Исключение

		Архиватор = Неопределено;

		СообщитьОбОшибке(КраткоеПредставлениеОшибки(ИнформацияОбОшибке()));

		Возврат Ложь;

	КонецПопытки;

	

	Попытка

		

		Архиватор.Добавить(МаскаУпаковкиФайлов, РежимСохраненияПутейZIP.НеСохранятьПути);

		Архиватор.Записать();

		

	Исключение

		

		СтрокаСообщения = НСтр("ru = 'Ошибка при запаковке файлов архива: %1 из каталог: %2'");

		СтрокаСообщения = ПодставитьПараметрыВСтроку(СтрокаСообщения, ПолноеИмяФайлаАрхива, МаскаУпаковкиФайлов);

		Сообщить(СтрокаСообщения);

		

		Результат = Ложь;

	КонецПопытки;

	

	Архиватор = Неопределено;

	

	Возврат Результат;

	

КонецФункции

В примере используется строковая функция ПодставитьПараметрыВСтроку():

Код 1C v 8.х

 // Подставляет параметры в строку. Максимально возможное число параметров - 9.

// Параметры в строке задаются как %<номер параметра>. Нумерация параметров начинается с единицы.

//

// Параметры:

//  СтрокаПодстановки  – Строка – шаблон строки с параметрами (вхождениями вида "%ИмяПараметра");

//  Параметр<n>        - Строка - подставляемый параметр.

//

// Возвращаемое значение:

//  Строка   – текстовая строка с подставленными параметрами.

//

// Пример:

//  ПодставитьПараметрыВСтроку(НСтр("ru='%1 пошел в %2'"), "Вася", "Зоопарк") = "Вася пошел в Зоопарк".

//

Функция ПодставитьПараметрыВСтроку(Знач СтрокаПодстановки,

	Знач Параметр1,	Знач Параметр2 = Неопределено, Знач Параметр3 = Неопределено,

	Знач Параметр4 = Неопределено, Знач Параметр5 = Неопределено, Знач Параметр6 = Неопределено,

	Знач Параметр7 = Неопределено, Знач Параметр8 = Неопределено, Знач Параметр9 = Неопределено) Экспорт

	

	Если СтрокаПодстановки = Неопределено ИЛИ СтрДлина(СтрокаПодстановки) = 0 Тогда

		Возврат "";

	КонецЕсли;

	

	Результат = "";

	НачПозиция = 1;

	Позиция = 1;

	Пока Позиция <= СтрДлина(СтрокаПодстановки) Цикл

		СимволСтроки = Сред(СтрокаПодстановки, Позиция, 1);

		Если СимволСтроки <> "%" Тогда

			Позиция = Позиция + 1;

			Продолжить;

		КонецЕсли;

		Результат = Результат + Сред(СтрокаПодстановки, НачПозиция, Позиция - НачПозиция);

		Позиция = Позиция + 1;

		СимволСтроки = Сред(СтрокаПодстановки, Позиция, 1);

		

		Если СимволСтроки = "%" Тогда

			Позиция = Позиция + 1;

			НачПозиция = Позиция;

			Результат = Результат + "%";

			Продолжить;

		КонецЕсли;

		

		Попытка

			НомерПараметра = Число(СимволСтроки);

		Исключение

			ВызватьИсключение НСтр("ru='Входная строка СтрокаПодстановки имеет неверный формат: %'" + СимволСтроки);

		КонецПопытки;

		

		Если СимволСтроки = "1" Тогда

			ЗначениеПараметра = Параметр1;

		ИначеЕсли СимволСтроки = "2" Тогда

			ЗначениеПараметра = Параметр2;

		ИначеЕсли СимволСтроки = "3" Тогда

			ЗначениеПараметра = Параметр3;

		ИначеЕсли СимволСтроки = "4" Тогда

			ЗначениеПараметра = Параметр4;

		ИначеЕсли СимволСтроки = "5" Тогда

			ЗначениеПараметра = Параметр5;

		ИначеЕсли СимволСтроки = "6" Тогда

			ЗначениеПараметра = Параметр6;

		ИначеЕсли СимволСтроки = "7" Тогда

			ЗначениеПараметра = Параметр7;

		ИначеЕсли СимволСтроки = "8" Тогда

			ЗначениеПараметра = Параметр8;

		ИначеЕсли СимволСтроки = "9" Тогда

			ЗначениеПараметра = Параметр9;

		Иначе

			ВызватьИсключение НСтр("ru='Входная строка СтрокаПодстановки имеет неверный формат: %'" + ЗначениеПараметра);

		КонецЕсли;

		Если ЗначениеПараметра = Неопределено Тогда

			ЗначениеПараметра = "";

		Иначе

			ЗначениеПараметра = Строка(ЗначениеПараметра);

		КонецЕсли;

		Результат = Результат + ЗначениеПараметра;

		Позиция = Позиция + 1;

		НачПозиция = Позиция;

	

	КонецЦикла;

	

	Если (НачПозиция <= СтрДлина(СтрокаПодстановки)) Тогда

		Результат = Результат + Сред(СтрокаПодстановки, НачПозиция, СтрДлина(СтрокаПодстановки) - НачПозиция + 1);

	КонецЕсли;

	

	Возврат Результат;

	

КонецФункции

Категория: Работа с Файлами и Каталогами

Как мы писали парсер сайта с ценами для 1С

Недавно, мой постоянный клиент решил проводить маркетинговые исследования по изменению цен на товары у конкурентов... и эти данные захотел использовать в 1С в связке с его прайс-листом + куча отчетов с графиками и процентным отклонением от цен основного конкурента

В результате этого, была написана обработка собирающая данные со страниц разных сайтов. Из целей конфиденциальности - сайты раскрывать не буду...

Вид обработки загрузки данных с сайта в 1С

Ниже код загрузки данных со страницы сайта, смысл такой :

в функция передается адрес страницы сайта
полученный текст страницы обрабатывается, удаляются теги
из полученного текста формируется ТЗ с данными
По названию ищется поставщик из вспомогательного справочника Справочники.Pr_Поставщики.НайтиПоНаименованию(, если нет - создается
на выходе ТЗ с данными

Код 1C v 8.х

 Функция ПолучитьТаблицуДанных(Строка)

	

	тзДанных = Новый ТаблицаЗначений;

	Сервер = "site.ru";

	

	Соединение = Новый HTTPСоединение(Сервер);			

	Заголовки = Новый Соответствие;

	Заголовки.Вставить("host", Сервер);

	ТекАдрес = СтрЗаменить(Строка.Наименование.УРЛСтраницы,"http://","");

	ТекАдрес = СтрЗаменить(ТекАдрес,Сервер,"");

	Запрос = Новый HTTPЗапрос(ТекАдрес, Заголовки);

	Ответ =Соединение.Получить(Запрос);

	Если Ответ.КодСостояния = 200 Тогда // Данные получены, обрабатываем их

		Содержимое= Ответ.ПолучитьТелоКакСтроку();

		//Выведем тест полученной страницы

		НачалоБлока = "<table id=" + """" + "table-price" + """" + " cellspacing=" + """" + "0" + """" + " border=" + """" + "1" + """" + " bordercolor=" + """" + "#dedede" + """" + " class=" + """" + "tablesorter" + """" + " >";

		//НачалоБлока = "<div class=" + """" + "w100fl" + """" + " id=" + """" + "kurs" + """" + ">";

		КонецБлока = "</table>";

		ТекстБлока = Сред(Содержимое, Найти(Содержимое, НачалоБлока) + СтрДлина(НачалоБлока), Найти(Содержимое, КонецБлока) - Найти(Содержимое, НачалоБлока) - СтрДлина(НачалоБлока));

		    				

		//Обработаем тест  				

		обрТекст = СтрЗаменить(ТекстБлока,"<tr>","");

		обрТекст = СтрЗаменить(обрТекст,"</tr>",Символы.ПС);

		обрТекст = СтрЗаменить(обрТекст," >", ">");

		обрТекст = СтрЗаменить(обрТекст,"</th> <th>", " | ");

		обрТекст = СтрЗаменить(обрТекст,"</td> <td>", " | ");

	   	обрТекст = СтрЗаменить(обрТекст,"</th> <th class=" + """" + "sortable_header" + """" + ">", " | ");

		обрТекст = СтрЗаменить(обрТекст,"</th> <th >", " | ");

		обрТекст = СтрЗаменить(обрТекст,"</th><th>", " | ");

		обрТекст = СтрЗаменить(обрТекст,"</td><td>", " | ");

		обрТекст = СтрЗаменить(обрТекст," >", ">");

		RegExp = Новый COMОбъект("VBScript.RegExp");

		RegExp.IgnoreCase = Ложь; 

		RegExp.Global = Истина;    

		RegExp.MultiLine = Истина;    

		

		RegExp.Pattern = "<[^>]*>"; //Ищем теги HTML   

		обрТекст=RegExp.Replace(обрТекст, "");

		//Сообщить(обрТекст);

		

		Если СокрЛП(обрТекст) = "Ни одной позиции не найдено." Тогда

			Сообщить(Строка(Строка.Наименование)+ " = Ни одной позиции не найдено! Строка " + Строка.Наименование);

			Возврат тзДанных;

		КонецЕсли;





		Если Найти(обрТекст, "Страница не найдена") > 0 Тогда

			Сообщить(Строка(ТекАдрес)+" = Страница не найдена, строка " + Строка.Наименование);

			Возврат тзДанных;  

		КонецЕсли;

		

		//Преобразуем полученный текст в таблицу

		Для н=1 По СтрЧислоСтрок(обрТекст)Цикл

			СтрТекста=СтрПолучитьСтроку(обрТекст,н);

			Если Найти(СтрТекста, "Длина Цена") > 0 Тогда

				СтрТекста = СтрЗаменить(СтрТекста, "Длина Цена", "Длина | Цена");

			КонецЕсли;

			Если Найти(СтрТекста, "Марка стали Цена") > 0 Тогда

				СтрТекста = СтрЗаменить(СтрТекста, "Марка стали Цена", "Марка стали | Цена");

			КонецЕсли;

			Если Найти(СтрТекста, ",  Поставщик") > 0 Тогда

				СтрТекста = СтрЗаменить(СтрТекста, ",  Поставщик", " | Поставщик");

			КонецЕсли;

			//Выводим текст страницы построчно

			мсДанных = ПолучитьМассивИзСтрокиСРазделителем(СтрТекста, "|", Истина);

			Если н=1 Тогда

				Для Каждого ткЗнач из мсДанных Цикл

					СтрЗапрещСимволов = " .,<>""\/-";

					ИмяКолонки = ткЗнач;

					Для сч33 = 1 по СтрДлина(СтрЗапрещСимволов) Цикл

						ЗапрещСимв = Сред(СтрЗапрещСимволов, сч33, 1);

						ИмяКолонки = СтрЗаменить(ИмяКолонки, ЗапрещСимв, "_");

					КонецЦикла;

					

					// добавим нужное количество колонок- если перед колонкой Поставщик не хватает

					// бывает, что в шапке определяется меньше колонок, чем реально в таблице

					Если НРег(ИмяКолонки) = "поставщик" Тогда

						Для Сч_дк = (Строка.Наименование.Родитель.Поставшик - 2) по тзДанных.Колонки.Количество() Цикл

							тзДанных.Колонки.Добавить("Колонка_" + (тзДанных.Колонки.Количество() + 1));

						КонецЦикла;

					КонецЕсли;

					

					тзДанных.Колонки.Добавить(ИмяКолонки);

				КонецЦикла;

				тзДанных.Колонки.Добавить("ном", , , 7);

			Иначе 

				НовСтр = тзДанных.Добавить(); нмас=0;

				Для Каждого ткЗнач из мсДанных Цикл

					НовСтр[нмас] = ткЗнач;

					нмас=нмас+1;

				КонецЦикла;

				НовСтр.ном = н;

			КонецЕсли;

			//Сообщить(стр);

		КонецЦикла;

		тзДанных.Колонки.Добавить("ЕстьСоответствие", Новый ОписаниеТипов("Булево"));

		тзДанных.Колонки.Добавить("СпрPr_Поставщики", Новый ОписаниеТипов("СправочникСсылка.Pr_Поставщики"));

		

		Для каждого стр из тзДанных Цикл

			текПоставщик = Справочники.Pr_Поставщики.НайтиПоНаименованию(стр[Строка.Наименование.родитель.Поставшик-1]);

			Если текПоставщик = Справочники.Pr_Поставщики.ПустаяСсылка() Тогда

				НовЭлем = Справочники.Pr_Поставщики.СоздатьЭлемент();

				НовЭлем.Наименование = СокрЛП(стр[Строка.Наименование.родитель.Поставшик-1]);

				НовЭлем.Записать();

				текПоставщик = НовЭлем.Ссылка;

			КонецЕсли;

			стр.СпрPr_Поставщики = текПоставщик;

		КонецЦикла;

	Иначе

		тзДанных.Колонки.Добавить("ЕстьСоответствие", Новый ОписаниеТипов("Булево"));

		тзДанных.Колонки.Добавить("СпрPr_Поставщики", Новый ОписаниеТипов("СправочникСсылка.Pr_Поставщики"));

		

		Сообщить("Ошибка получения данных для строки " + Строка.Наименование);

	КонецЕсли;

	

	Возврат тзДанных;

	

КонецФункции

В коде используется вспомогательная функция ПолучитьМассивИзСтрокиСРазделителем

Код 1C v 8.2 УП

 // Функция разбивает строку разделителем.

// 

// Параметры:

//  пСтрока      - Строка - которую разбиваем;

//  *пРазделитель - Строка, "." - символ-разделитель;

//  *ОбрезатьНепечатныеСимволы - Булево, *Ложь.

//

// Возвращаемое значение:

//  Массив - фрагментов.

//

Функция ПолучитьМассивИзСтрокиСРазделителем(Знач Стр, Разделитель = ".", ОбрезатьНепечатныеСимволы = Ложь) Экспорт

	

	МассивСтрок = Новый Массив;

	

	Если Разделитель = " " Тогда

		Стр = СокрЛП(Стр);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = СокрЛ(Сред(Стр,Поз));

		КонецЦикла;

	Иначе

		ДлинаРазделителя = СтрДлина(Разделитель);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				Фрагмент = Стр;

				Если ОбрезатьНепечатныеСимволы Тогда

					Фрагмент = СокрЛП(Фрагмент);

				КонецЕсли;

				МассивСтрок.Добавить(Фрагмент);

				Возврат МассивСтрок;

			КонецЕсли;

			Фрагмент = Лев(Стр,Поз-1);

			Если ОбрезатьНепечатныеСимволы Тогда

				Фрагмент = СокрЛП(Фрагмент);

			КонецЕсли;

			МассивСтрок.Добавить(Фрагмент);

			Стр = Сред(Стр,Поз+ДлинаРазделителя);

		КонецЦикла;

	КонецЕсли;





	Возврат МассивСтрок;

		

КонецФункции // ПолучитьМассивИзСтрокиСРазделителем()

Конечно, перед тем как мы начали это делать - прошерстили интернет и нашли несколько решений , вот они:

Код 1C v 8.х

 Соединение = ПолучитьCOMОбъект("","Microsoft.XMLHTTP");

ИмяВременногоФайла=ПолучитьИмяВременногоФайла("htm");



Соединение.open("GET", "http://mamba.ru/my", 0);

Соединение.send();



//status: //404 - Not Found //200 - Ok

ТаймАут = 200;

Начало=ТекущаяДата();

Пока Соединение.readyState <> 4 И (ТаймАут=0 ИЛИ ТекущаяДата()-Начало<ТаймАут) Цикл

бфДиалоги.ксОбработкаПрерыванияПользователя();

КонецЦикла;



//Сохраняем во временный файл

обСохранитьДвоичныйБуферВФайл(Соединение.responseBody, ИмяВременногоФайла);



Соединение.open("POST", "http://mamba.ru/my");

Соединение.send("login=xxx&password=&&&");





Функция обСохранитьДвоичныйБуферВФайл(Буфер, ИмяФайла) Экспорт

    Поток = Новый COMОбъект("ADODB.Stream");

    Поток.Type = 1;  //Бинарный

       Поток.Mode = 3; 

    Поток.Open();

    Поток.Write(Буфер);

    Поток.SaveToFile(ИмяФайла);

    Поток.Close();

КонецФункции

Код 1C v 8.х

     НТТР = ПолучитьCOMОбъект("","Microsoft.XMLHTTP");

    ИмяФайлаОтвета = КаталогВременныхФайлов() + "filename.tmp";           

    НТТР.open("GET", "www.google.com",0,,); 

    НТТР.send();

    StreamTypeEnum = Новый Структура("adTypeBinary, adTypeText", 1, 2);

    ConnectModeEnum = Новый Структура(

            "adModeRead, adModeReadWrite, adModeRecursive, adModeShareDenyNone,

            |adModeShareDenyRead, adModeShareDenyWrite, adModeShareExclusive, 

            |adModeUnknown, adModeWrite", 1, 3, 4194304, 16, 4, 8, 12, 0, 2);

    SaveOptionsEnum = Новый Структура("adSaveCreateNotExist, adSaveCreateOverWrite", 1, 2);

    StreamOut = Новый COMОбъект("ADODB.Stream");

    StreamOut.Type = StreamTypeEnum.adTypeBinary;

    StreamOut.Mode = ConnectModeEnum.adModeReadWrite; //Нужны и чтение и запись   

    StreamOut.Open(); //Открыли на чтение и запись

    StreamOut.Write(НТТР.responseBody); 

    StreamOut.SaveToFile(ИмяФайлаОтвета, SaveOptionsEnum.adSaveCreateOverWrite); //"2" - перезапись файла

    StreamOut.Close();

И даже не этом сайте есть статья : Парсер сайта связного на 1С

Нужен парсер сайта в 1С!? - Обращайтесь, контакты в профиле

Категория: Работа с Интернет, Почтой (Mail), FTP

Добавим документы ODF (OpenOffice/LibreOffice) в стандартную обработку Загрузки Табличного документа

Доброго времени суток!

Обработку ЗагрузкаданныхизТабличногоДокументаконечно должен знать каждый 1С-ник. И сколько бы обработок такого плана не появлялось, эта остается классикой. Даже претензии можно предъявлять если вы в ней что-то не понимаете к самой 1С. Хотя какие претензии, исходный код открыть – изучай, не хочу…

Еще чем мне нравится эта обработка – тем что вы читаете данные из внешнего источника, показываете их с помощью объекта табличное поле и только затем выбираете алгоритм загрузки в 1С. При чем загрузка у Вас происходит в среде 1С без привлечения дополнительных компонентов. Без всяких выпадов в неизвестный объект OLE, полей которые не прочитались в обработке загрузки. Если вы видете данные в табличном поле, то они и будут грузиться по вашему алгоритму.

Но что-то в ней не хватает. Конечно стандарта офисных документов ODF (Open Document Format и между прочим ГОСТ Р ИСО/МЭК 26300-2010). Как говаривал мой начальник – есть чем себя занять. Из всех внешних загрузок, которые сейчас есть к сожалению самыми распостраненными являются OLE(Com+) технологии. Возможно что-то еще появиться, но пока примемся за них.

Залезаем в код и видим несколько однотипных функуций

Функция мПрочитатьТабличныйДокументИзExcel(ТабличныйДокумент, ИмяФайла, НомерЛистаExcel = 1) Экспорт

Функция мПрочитатьТабличныйДокументИзТекста(ТабличныйДокумент, ИмяФайла, НомерЛистаExcel = 1) Экспорт

Пора добавить свою:

Код 1C v 8.х

 

// Функция считывает в табличный документ данные из файла в формате ODF Calc(ods)

//

// Параметры:

// ТабличныйДокумент – ТабличныйДокумент, в который необходимо прочитать данные

// ИмяФайла – имя файла в формате ODF, из которого необходимо прочитать данные

// НомерЛистаCalc – номер листа книги Calc, из которого необходимо прочитать данные

//

// Возвращаемое значение:

// Истина, если файл прочитан, Ложь – иначе

//

Функция мПрочитатьТабличныйДокументИзCalc(ТабличныйДокумент, ИмяФайла, НомерЛистаCalc = 1) Экспорт



ВыбФайл = Новый Файл(ИмяФайла);

Если НЕ ВыбФайл.Существует() Тогда

Сообщить(“Файл не существует!”);

Возврат Ложь;

КонецЕсли;



Попытка

ServiceManager = Новый COMОбъект(“com.sun.star.ServiceManager”);

Desktop = ServiceManager.CreateInstance(“com.sun.star.frame.Desktop”);

Desktop.getCurrentFrame().getContainerWindow().setVisible(Ложь); //сделаем невидимым основное окно.



//установим параметры – не показывать таблицу Calc

Параметры = Новый COMSafeArray(“VT_DISPATCH”, 1);

Свойство = ServiceManager.Bridge_GetStruct(“com.sun.star.beans.PropertyValue”);

Свойство.Name = “Hidden”;

Свойство.Value = true;

Параметры.SetValue(0,Свойство);



Document = Desktop.LoadComponentFromURL(“file:///” + ИмяФайла, “_blank”, 0, Параметры);

Состояние(“Обработка файла Office Calc …”);

Листы = Document.getSheets();

Лист = Листы.getByIndex(НомерЛистаCalc-1);

Исключение

Сообщить(“Ошибка загрузки данных. Возможно неверно указан номер листа книги Calc.”);

Возврат ложь;

КонецПопытки;



ТабличныйДокумент.Очистить();



//Определение максимум ячейки с данными…

НульЯчейка = Лист.GetCellbyPosition(0,0);

НульКурсор = Лист.createCursorByRange(НульЯчейка);

НульКурсор.GotoEndOfUsedArea(1);

НульАдрес = НульКурсор.RangeAddress;

ПослСтрока = НульАдрес.EndRow;

ПослКолонка = НульАдрес.EndColumn;



//Для Column = 1 По ПослКолонка + 1 Цикл

// ТабличныйДокумент.Область(“C” + Формат(Column, “ЧГ=”)).ШиринаКолонки = Лист.getColumns.getByIndex(Column-1).Width;

//КонецЦикла;



Для Row = 1 По ПослСтрока + 1 Цикл



Если Лист.getCellByPosition(Column-1,Row-1).getType() = 0 Или Лист.getCellByPosition(Column-1,Row-1).getType() = 1 Тогда ТабличныйДокумент.Область(“R” + Формат(Row, “ЧГ=”) +”C” + Формат(Column, “ЧГ=”)).Текст = Лист.getCellByPosition(Column-1,Row-1).value;

ИначеЕсли Лист.getCellByPosition(Column-1,Row-1).getType() = 2 Тогда ТабличныйДокумент.Область(“R” + Формат(Row, “ЧГ=”) +”C” + Формат(Column, “ЧГ=”)).Текст = Лист.getCellByPosition(Column-1,Row-1).string;

КонецЕсли;

КонецЦикла;



//ServiceManager.quit();

Document.Dispose();

Document = 0;

Параметры = 0;

Desktop = 0;

ServiceManager = 0;



Возврат Истина;



КонецФункции

И добавим в форму выбора файла ods по тексту.

Код 1C v 8.х

 ДиалогВыбораФайла.Фильтр = “Табличный документ (*.mxl)|*.mxl|Лист Calc (*.ods)|*.ods|Лист Excel (*.xls)|*.xls|Текстовый документ (*.txt)|*.txt|dBase III (*.dbf)|*.dbf|”;

И выбор функции для ods

ИначеЕсли нРег(ФайлНаДиске.Расширение) = “.ods” Тогда
мПрочитатьТабличныйДокументИзCalc(ТабличныйДокумент,ДиалогВыбораФайла.ПолноеИмяФайла);

Вот так лучше.

Сайт sikuda.ru

Категория: Работа с Microsoft Office и OpenOffice

Загрузка данных из текстовых файлов, выбирая SQL запросом данные из этих файлов

Код

Колонка1 20 символов – Номер заказа
Колонка2 5 символов – Код контрагента
Колонка3 10 символов – Дата заказа
Колонка4 10 символов – Дата доставки
Колонка5 10 символов – Дата сбора
Колонка6 4 символов – Количество строк в ТЧ

Структура строки в Rows_XXXXX.txt

Код

Колонка1 20 символов – Номер заказа
Колонка2 7 символов – Артикул номенклатуры
Колонка3 9 символов – Количество в базовых ед. изм.

В каждой паре файлов несколько Заказов. Необходимо загрузить эти заказы в БД 1С
Для этого воспользуемся Microsoft.Jet.OLEDB.4.0

Для того чтоб данный драйвер корректно понимал структуру файлов необходимо в каталоге расположения данных файлов, перед выполнением запросов, создать специальный текстовый файл schema.ini cо следующими строками:

Код

[ Head_XXXXX]
ColNameHeader=False
Format=FixedLength
Col1=NumberNote Text Width 20
Col2=StoreNum Text Width 5
Col3=DataNote DateTime Width 10
Col4=DataDev DateTime Width 10
Col5=DataDes DateTime Width 10
Col6=CountLine Long Width 4

[Rows_XXXXX]
ColNameHeader=False
Format=FixedLength
Col1=NumberNote Text Width 20
Col2=Articul Text Width 7
Col3=Counts Double Width 9

Как видим, здесь мы задаем структуру таблицы из файла.
Остается только выполнить запрос к полученной текстовой БД и обработать результат:

Ниже приведен пример кода для платформы 1С 8:

Код 1C v 8.х

 // Загружает данные из текстовых данных

//

// Параметры

// Стр_КаталогДанных - <Строка>

//

// Автор: Gmix 04.05.2006 12:22:09

//     

// Возвращаемое значение:

//   <Булево>

//

Функция ЗагрузитьДанныеИзtxt(Стр_КаталогДанных)

            // проверки заполнения

           

            ОБ_ФайлДанных=Новый Файл(Стр_КаталогДанных);

            Если НЕ ОБ_ФайлДанных.ЭтоКаталог() Тогда

                        Сообщить("Необходимо указать каталог данных!",СтатусСообщения.ОченьВажное);

                        Возврат Ложь;

            КонецЕсли;

          

            Если НЕ ОБ_ФайлДанных.Существует() Тогда

                Сообщить("Каталог """+Стр_КаталогДанных+""" не существует!",СтатусСообщения.ОченьВажное);

                        Возврат Ложь;

            КонецЕсли;

           

            ОБ_АДОКонект = Новый COMОбъект("ADODB.Connection");

            ОБ_АДОРекордсетШапка = Новый COMОбъект("ADODB.Recordset");

            ОБ_АДОРекордсетСтроки = Новый COMОбъект("ADODB.Recordset");

           

            //Определяем пару файлов

            Стр_ОкончаниеФайла="";

            ФайлыШапок = НайтиФайлы(Стр_КаталогДанных, "Head_*.txt");

            Для каждого ФайлШапки Из ФайлыШапок Цикл

                        Стр_ОкончаниеФайла=Сред(ФайлШапки.ИмяБезРасширения,6);

                        Стр_таблицаШапки=ФайлШапки.Имя;

                       

                        Стр_ТаблицаСтрок="Rows_"+Стр_ОкончаниеФайла+".txt";

                        Стр_ИмяФайлСтрок=ДобавлениеСлеша(Стр_КаталогДанных)+Стр_ТаблицаСтрок;

                        ФайлСтрок=Новый Файл(Стр_ИмяФайлСтрок);

                        Если НЕ ФайлСтрок.Существует() Тогда

                            Сообщить("Не найден файл строк для файла шапки """+Стр_таблицаШапки+"""! Пара файлов не обработана",СтатусСообщения.Важное);

                                   Продолжить;

                        КонецЕсли;

                       

                        //Создаем схему данных

                        ФайлСхемыДанных=Новый Файл(ДобавлениеСлеша(Стр_КаталогДанных)+"schema.ini");

                        Если ФайлСхемыДанных.Существует() Тогда

                                  Попытка

                                       УдалитьФайлы(ФайлСхемыДанных.Путь,ФайлСхемыДанных.Имя);

                                   Исключение

                                       Сообщить("Не возможно удалить файл """+ФайлСхемыДанных.ПолноеИмя+""" для создания новой схемы данных! Проверте атрибуты файла",СтатусСообщения.Важное);

                                               Возврат Ложь;

                                   КонецПопытки;

                        КонецЕсли;

                       

                        Стр_СхемаДанныхТхт="["+Стр_таблицаШапки+"]

                                                                                  |ColNameHeader=False

                                                                                  |Format=FixedLength

                                                                                  |Col1=NumberNote Text Width 20

                                                                                  |Col2=StoreNum Text Width 5

                                                                                  |Col3=DataNote DateTime Width 10

                                                                                  |Col4=DataDev DateTime Width 10

                                                                                  |Col5=DataDes DateTime Width 10

                                                                                  |Col6=CountLine Long Width 4

                                                                                 

                                                                                  |["+Стр_ТаблицаСтрок+"]

                                                                                  |ColNameHeader=False

                                                                                  |Format=FixedLength

                                                                                  |Col1=NumberNote Text Width 20

                                                                                  |Col2=Articul Text Width 7

                                                                                  |Col3=Counts Double Width 9";

                       

                        ТекстСхемы=Новый ЗаписьТекста(ФайлСхемыДанных.ПолноеИмя, КодировкаТекста.ANSI);

                        ТекстСхемы.Записать(Стр_СхемаДанныхТхт);

                        ТекстСхемы.Закрыть();

                       

                        // Создаем коннект

                        Попытка

                                   ОБ_АДОКонект.Open("Provider=Microsoft.Jet.OLEDB.4.0;Data Source="+Стр_КаталогДанных+";Extended Properties='text;FMT=Delimited;HDR=NO'");

                       Исключение

                                   Сообщить("Невозможно открыть соединение!"+ОписаниеОшибки(),СтатусСообщения.Важное);

                            Возврат Ложь;

                        КонецПопытки;

 

                       Стр_SQL = "S_elect * FROM "+Стр_таблицаШапки;

                      

                        Попытка

                                    ОБ_АДОРекордсетШапка=ОБ_АДОКонект.Execute(Стр_SQL);                

                        Исключение

                            Сообщить("Ошибка выполнения запроса """+Стр_SQL+"""!"+ОписаниеОшибки(),СтатусСообщения.Важное);

                                   Возврат Ложь;          

                        КонецПопытки;

 

                        Пока НЕ ОБ_АДОРекордсетШапка.EOF Цикл

                                  

                                   // Заказ

                                   Стр_НомерЗаказа     = ОБ_АДОРекордсетШапка.Fields("NumberNote").Value;

                                  Стр_КодКА= ОБ_АДОРекордсетШапка.Fields("StoreNum").Value;

                              

                                   Д_ДатаЗаказа= ОБ_АДОРекордсетШапка.Fields("DataNote").Value;

                                   Д_ДатаДоставки= ОБ_АДОРекордсетШапка.Fields("DataDev").Value;

                                   Д_ДатаСбора= ОБ_АДОРекордсетШапка.Fields("DataDes").Value;

                                   Ч_КоличествоСтрок            = ОБ_АДОРекордсетШапка.Fields("CountLine").Value;

                                 

                                   Сообщить("Заказ № "+Стр_НомерЗаказа+" от " +Д_ДатаЗаказа+ " Код контрагента: "+Стр_КодКА+" Дата доставки: "+Д_ДатаДоставки);

                                  

                                   // Обработка строк заказа

                                   Стр_SQL = "S_elect * FROM "+Стр_ТаблицаСтрок+" WHERE NumberNote='"+Стр_НомерЗаказа+"'";



                                   Попытка

                                               ОБ_АДОРекордсетСтроки=ОБ_АДОКонект.Execute(Стр_SQL);               

                                  Исключение

                                               Сообщить("Ошибка выполнения запроса """+Стр_SQL+"""!"+ОписаниеОшибки(),СтатусСообщения.Важное);

                                               Возврат Ложь;          

                                   КонецПопытки;



                                   Сч=0;

                                   Сообщить(" №           Артикул                     Количество");

                                   Пока НЕ ОБ_АДОРекордсетСтроки.EOF Цикл

                                              //Заполняем таб часть документа

                                               Сч=Сч+1;

                                               Стр_Артикул=СокрЛП(ОБ_АДОРекордсетСтроки.Fields("Articul").Value);

                                               Ч_Количество=ОБ_АДОРекордсетСтроки.Fields("Counts").Value;

                                               Сообщить(""+Сч+"    " +Стр_Артикул+ "               "+Ч_Количество);

                                               ОБ_АДОРекордсетСтроки.MoveNext();

                                   КонецЦикла;



                                   ОБ_АДОРекордсетШапка.MoveNext();

                        КонецЦикла;

           КонецЦикла;

    Возврат Истина;

КонецФункции // ЗагрузитьДанныеИзtxt() Gmix 04.05.2006 12:22:21

Автор: Журавлев Михаил Викторович

Категория: Конвертация данных, Обмен, Перенос

Реквизит ~ Как сохранить, восстановить значения всех элементов формы?

Как сохранить Значения элементов при закрытии формы и восстановить их при открытии формы?

Это можно сделать через СохранитьЗначения(), ВосстановитьЗначение():

Код 1C v 8.х

 СохранитьЗначение("СрокИсполненияЗаказа", СрокИсполнения);

СохранитьЗначение("СкладПоУмолчанию", МестоХранения);



СрокИсполнения = ВосстановитьЗначение("СрокИсполненияЗаказа"));

Но у этого способа, одно НО - Сохраненые значения будут доступны только на там компьютере, на котором их сохранили!

А чтобы эти значения были доступны с любого компьютера, их нужно хранить в базе, например в константах с типом Хранилище значения:
Перебирая все элементы формы, выбрать только поля ввода и записать их значения в структуру.
Потом структуры записываем в константу:

Код 1C v 8.х

 Процедура КнопкаСохранитьНажатие(Кнопка)

	ЭлСтр = Новый Структура;

	Для Каждого Элем Из ЭлементыФормы Цикл

		//Сохранаем только те элементы, у которых можно получить Значение

		//Попытка

		// ЭлСтр.Вставить(Элем.Имя, Элем.Значение);

		//Исключение КонецПопытки; //у элемента нет Значения 

		//Так лучше

		Если ТипЗнч(Элем) = Тип("ПолеВвода") Тогда

			ЭлСтр.Вставить(Элем.Имя, Элем.Значение);

		КонецЕсли;

	КонецЦикла;	

	Константы.MES_ДопСоглашения.Установить(Новый ХранилищеЗначения(ЭлСтр)); 

КонецПроцедуры



Процедура ПриОткрытии()

	//Заполним значения на форме из структуры полученной из хранилища значений

	Попытка

		ЭлСтрХранЗнач=Константы.MES_ДопСоглашения.Получить();

		ЭлСтр=ЭлСтрХранЗнач.Получить();

		Для Каждого Элем из ЭлСтр Цикл

			ЭлементыФормы[Элем.Ключ] = Элем.Значение;

		КонецЦикла;	

	Исключение КонецПопытки;	

КонецПроцедуры

Как сохранять и восстанавливать значения реквизитов на форме?

Категория: Работа с Формой (Диалог) и её элементами

Загрузка данных из текстовых файлов с выборкой через ADO.

Часто бывает потребность загружать данные из текстовых форматов, причем информация для загрузки бьется на 2 и более файлов.

Хорошо бы посредством SQL запроса выбирать данные из этих файлов и производить загрузку! Это вполне возможно и я считаю этот способ наиболее грамотный для решения таких задач!

Имеем 2 файла:
- Head_XXXXX.txt
- Rows_XXXXX.txt

Где XXXXX – порядковой номер пары файлов

Структура строки в Head_XXXXX.txt :

Колонка1 20 символов – Номер заказа
Колонка2 5 символов – Код контрагента
Колонка3 10 символов – Дата заказа
Колонка4 10 символов – Дата доставки
Колонка5 10 символов – Дата сбора
Колонка6 4 символов – Количество строк в ТЧ

Структура строки в Rows_XXXXX.txt :
Колонка1 20 символов – Номер заказа
Колонка2 7 символов – Артикул номенклатуры
Колонка3 9 символов – Количество в базовых ед. изм.

В каждой паре файлов несколько Заказов.
Необходимо загрузить эти заказы в БД 1С

Для этого воспользуемся Microsoft.Jet.OLEDB.4.0
Для того чтоб данный драйвер корректно понимал структуру файлов необходимо в каталоге расположения данных файлов, перед выполнением запросов, создать специальный текстовый файл schema.ini cо следующими строками:

Код

Код 1C v 8.х

 // Загружает данные из текстовых данных

// Параметры

// Стр_КаталогДанных - <Строка>

// Автор: Gmix 04.05.2006 12:22:09

// Возвращаемое значение:

//   <Булево>

Функция ЗагрузитьДанныеИзtxt(Стр_КаталогДанных)

            // проверки заполнения

           

            ОБ_ФайлДанных=Новый Файл(Стр_КаталогДанных);

            Если НЕ ОБ_ФайлДанных.ЭтоКаталог() Тогда

                        Сообщить("Необходимо указать каталог данных!",СтатусСообщения.ОченьВажное);

                        Возврат Ложь;

            КонецЕсли;

           

            Если НЕ ОБ_ФайлДанных.Существует() Тогда

                Сообщить("Каталог """+Стр_КаталогДанных+""" не существует!",СтатусСообщения.ОченьВажное);

                        Возврат Ложь;

            КонецЕсли;

           

            ОБ_АДОКонект = Новый COMОбъект("ADODB.Connection");

            ОБ_АДОРекордсетШапка = Новый COMОбъект("ADODB.Recordset");

            ОБ_АДОРекордсетСтроки = Новый COMОбъект("ADODB.Recordset");

           

            //Определяем пару файлов

            Стр_ОкончаниеФайла="";

            ФайлыШапок = НайтиФайлы(Стр_КаталогДанных, "Head_*.txt");

            Для каждого ФайлШапки Из ФайлыШапок Цикл

                        Стр_ОкончаниеФайла=Сред(ФайлШапки.ИмяБезРасширения,6);

                        Стр_таблицаШапки=ФайлШапки.Имя;

                       

                        Стр_ТаблицаСтрок="Rows_"+Стр_ОкончаниеФайла+".txt";

                        Стр_ИмяФайлСтрок=ДобавлениеСлеша(Стр_КаталогДанных)+Стр_ТаблицаСтрок;

                        ФайлСтрок=Новый Файл(Стр_ИмяФайлСтрок);

                        Если НЕ ФайлСтрок.Существует() Тогда

                            Сообщить("Не найден файл строк для файла шапки """+Стр_таблицаШапки+"""! Пара файлов не обработана",СтатусСообщения.Важное);

                                   Продолжить;

                        КонецЕсли;

                       

                        //Создаем схему данных

                        ФайлСхемыДанных=Новый Файл(ДобавлениеСлеша(Стр_КаталогДанных)+"schema.ini");

                        Если ФайлСхемыДанных.Существует() Тогда

                                   Попытка

                                       УдалитьФайлы(ФайлСхемыДанных.Путь,ФайлСхемыДанных.Имя);

                                   Исключение

                                       Сообщить("Не возможно удалить файл """+ФайлСхемыДанных.ПолноеИмя+""" для создания новой схемы данных! Проверте атрибуты файла",СтатусСообщения.Важное);

                                               Возврат Ложь;

                                   КонецПопытки;

                        КонецЕсли;

                       

                        Стр_СхемаДанныхТхт="["+Стр_таблицаШапки+"]

                                                                                  |ColNameHeader=False

                                                                                  |Format=FixedLength

                                                                                  |Col1=NumberNote Text Width 20

                                                                                  |Col2=StoreNum Text Width 5

                                                                                  |Col3=DataNote DateTime Width 10

                                                                                  |Col4=DataDev DateTime Width 10

                                                                                  |Col5=DataDes DateTime Width 10

                                                                                  |Col6=CountLine Long Width 4

                                                                                  |["+Стр_ТаблицаСтрок+"]

                                                                                  |ColNameHeader=False

                                                                                  |Format=FixedLength

                                                                                  |Col1=NumberNote Text Width 20

                                                                                  |Col2=Articul Text Width 7

                                                                                  |Col3=Counts Double Width 9";

                       

                        ТекстСхемы=Новый ЗаписьТекста(ФайлСхемыДанных.ПолноеИмя, КодировкаТекста.ANSI);

                        ТекстСхемы.Записать(Стр_СхемаДанныхТхт);

                        ТекстСхемы.Закрыть();

                       

                        // Создаем коннект

                        Попытка

                                   ОБ_АДОКонект.Open("Provider=Microsoft.Jet.OLEDB.4.0;Data Source="+Стр_КаталогДанных+";Extended Properties='text;FMT=Delimited;HDR=NO'");

                        Исключение

                                   Сообщить("Невозможно открыть соединение!"+ОписаниеОшибки(),СтатусСообщения.Важное);

                            Возврат Ложь;

                        КонецПопытки;

 

                        Стр_SQL = "S_elect * FROM "+Стр_таблицаШапки;

                       

                        Попытка

                                    ОБ_АДОРекордсетШапка=ОБ_АДОКонект.Execute(Стр_SQL);                

                        Исключение

                            Сообщить("Ошибка выполнения запроса """+Стр_SQL+"""!"+ОписаниеОшибки(),СтатусСообщения.Важное);

                                   Возврат Ложь;          

                        КонецПопытки;

 

                        Пока НЕ ОБ_АДОРекордсетШапка.EOF Цикл

                                  

                                   // Заказ

                                  

                                   Стр_НомерЗаказа     = ОБ_АДОРекордсетШапка.Fields("NumberNote").Value;

                                   Стр_КодКА= ОБ_АДОРекордсетШапка.Fields("StoreNum").Value;

                                  

                                   Д_ДатаЗаказа= ОБ_АДОРекордсетШапка.Fields("DataNote").Value;

                                   Д_ДатаДоставки= ОБ_АДОРекордсетШапка.Fields("DataDev").Value;

                                   Д_ДатаСбора= ОБ_АДОРекордсетШапка.Fields("DataDes").Value;

                                   Ч_КоличествоСтрок            = ОБ_АДОРекордсетШапка.Fields("CountLine").Value;

                               

                                   Сообщить("Заказ № "+Стр_НомерЗаказа+" от " +Д_ДатаЗаказа+ " Код контрагента: "+Стр_КодКА+" Дата доставки: "+Д_ДатаДоставки);



                                   // Обработка строк заказа

                                  Стр_SQL = "S_elect * FROM "+Стр_ТаблицаСтрок+" WHERE NumberNote='"+Стр_НомерЗаказа+"'";

                                   Попытка

                                               ОБ_АДОРекордсетСтроки=ОБ_АДОКонект.Execute(Стр_SQL);               

                                   Исключение

                                               Сообщить("Ошибка выполнения запроса """+Стр_SQL+"""!"+ОписаниеОшибки(),СтатусСообщения.Важное);

                                               Возврат Ложь;          

                                   КонецПопытки;

                                  

                                   Сч=0;

                                   Сообщить(" №           Артикул                     Количество");

                                   Пока НЕ ОБ_АДОРекордсетСтроки.EOF Цикл

                                               //Заполняем таб часть документа

                                               Сч=Сч+1;

                                              Стр_Артикул=СокрЛП(ОБ_АДОРекордсетСтроки.Fields("Articul").Value);

                                               Ч_Количество=ОБ_АДОРекордсетСтроки.Fields("Counts").Value;

                                               Сообщить(""+Сч+"    " +Стр_Артикул+ "               "+Ч_Количество);

                                               ОБ_АДОРекордсетСтроки.MoveNext();

                                   КонецЦикла;

                                   ОБ_АДОРекордсетШапка.MoveNext();

                        КонецЦикла;

            КонецЦикла;

    Возврат Истина;

КонецФункции

Автор Журавлев Михаил Викторович

Категория: JSON, XML, TXT, CSV, DBF

Выгрузка / Загрузка данных посредством текстовых (TXT) файлов

Для работы с текстовыми документами существуют три типа данных – ТекстовыйДокумент, ЗаписьТекста и ЧтениеТекста. Разница двух подходов состоит в способе загрузки документа:
ТекстовыйДокумент загружает файл целиком и далее построчно обрабатывает его;
ЗаписьТекста и ЧтениеТекста загружают файл построчно.

ПРИМЕР 1:
Запись данных справочника в текстовый файл:

Код 1C v 8.х

 Текст = Новый ТекстовыйДокумент;

// перебор элементов справочника

Выборка = Справочники.Клиенты.Выбрать();

Пока Выборка.Следующий() Цикл

  // выводим в файл код и наименование, разделенные 

  // каким-либо разделителем, например, ‘;’

  Текст.ДобавитьСтроку(""+Выборка.Код+";"+Выборка.Наименование);

КонецЦикла;

// запись в текстовый файл

Текст.Записать("C://1.txt");

С помощью типа ЗаписьТекста этот код будет таким:

Код 1C v 8.х

 // файл в формате Unicode

Текст = Новый ЗаписьТекста("C://1.txt", КодировкаТекста.UTF8);

// перебор элементов справочника

Выборка = Справочники.Клиенты.Выбрать();

Пока Выборка.Следующий() Цикл

  // выводим в файл код и наименование, разделенные 

  // каким-либо разделителем, например, ‘;’

  Текст.ЗаписатьСтроку(""+Выборка.Код+";"+Выборка.Наименование);

КонецЦикла;

// запись в текстовый файл

Текст.Закрыть();

Чтение данных из текстового файла в справочник:

Код 1C v 8.х

 Текст = Новый ТекстовыйДокумент;

// открытие файла

Текст.Прочитать("C://1.txt");

// перебор строк текстового документа

Для НомерСтроки=1 по Текст.КоличествоСтрок() Цикл

 // получить строку файла с указанным номером

 Стр = Текст.ПолучитьСтроку(НомерСтроки);

 // «распарсивание» строки

 // ищем позицию символа-разделителя

 Позиция = Найти (Стр, ‘;’);

 // создаем новый элемент справочника

 Спр=Справочники.Клиенты.СоздатьЭлемент();

 // в код записывается подстрока от первого символа до позиции

 // символа-разделителя

 Спр.Код = Сред(Стр,1,Позиция-1); 

 // за символом-резделителем – наименование клиента

 Спр.Наименование = Сред (Стр, Позиция+1);

 Спр.Записать();

КонецЦикла;

С помощью типа ЗаписьТекста этот код будет таким:

Код 1C v 8.х

 // файл в формате Unicode

Текст = Новый ЧтениеТекста("C://1.txt", КодировкаТекста.UTF8);

// перебор элементов справочника

Стр="";

// пока строки в файле остались

Пока Стр<>Неопределено Цикл

 // получить очередную строку файла 

 Стр = Текст.ПрочитатьСтроку();

 // «распарсивание» строки

 // ищем позицию символа-разделителя

 Позиция = Найти (Стр, ‘;’);

 // создаем новый элемент справочника

 Спр=Справочники.Клиенты.СоздатьЭлемент();

 // в код записывается подстрока от первого символа до позиции

 // символа-разделителя

 Спр.Код = Число(Сред(Стр,1,Позиция-1)); 

 // за символом-резделителем – наименование клиента

 Спр.Наименование = Сред (Стр, Позиция+1);

 Спр.Записать();

КонецЦикла;

ПРИМЕР 2:
В строке текста значения реквизитов справочника разделяются символом кавычка. Его можно получить, например, используя функцию Символ(34).
В случае если символ разделителя (в данном случае – кавычка) может встречаться в выгружаемых данных,
перед помещением в строку меняем этот символ на заранее определенную комбинацию символов.
В нашем случае это %квч%.

Код 1C v 8.х

  // Выгрузка данных в текстовый файл

Текст = Новый ТекстовыйДокумент;

Выборка = Справочники.Номенклатура.Выбрать();

Пока Выборка.Следующий() Цикл

	Стр = СтрЗаменить(Выборка.Наименование, Символ(34), "%квч%");

	Код = Строка(Выборка.Код) + Символ(34);

	Текст.ДобавитьСтроку(Код + Стр);

КонецЦикла;

Текст.Записать("c:\temp\text.txt");



//Загрузка данных из текстового файла. При загрузке ориентируемся на используемый разделитель значений (это кавычка).

//После получения значения делаем обратное преобразование для разделителя (при выгрузке 

//данных кавычку, встречающуюся в выгружаемых строках, заменяли комбинацией символов %квч%)

Текст = Новый ТекстовыйДокумент;

Текст.Прочитать("c:\temp\text.txt");

Для НомерСтроки = 1 По Текст.КоличествоСтрок() Цикл

	Стр = Текст.ПолучитьСтроку(НомерСтроки);

	Позиция = Найти(Стр, Символ(34));

	Код = Сред(Стр, 1, Позиция-1);

	прНаименование = Сред(Стр, Позиция + 1);

	Наименование = СтрЗаменить(прНаименование, "%квч%", Символ(34));

	Сообщить(Код + "–" + Наименование);	

КонецЦикла;	





"В предыдущем примере файл ЗАГРУЖАЛСЯ ПОЛНОСТЬЮ, а в следующем примере ЗАГРУЖАЕТСЯ ПОСТРОЧНО."

"Это позволяет при работе с файлами больших размеров значительно уменьшить время выполнения задачи."

//Запись данных в файл построчно

Путь = "c:\temp\text.txt";

Текст = Новый ЗаписьТекста(Путь, КодировкаТекста.UTF8);

Выборка = Справочники.Номенклатура.Выбрать();

Пока Выборка.Следующий() Цикл

	Текст.ЗаписатьСтроку(Выборка.Наименование);

КонецЦикла;	

Текст.Закрыть();



//Чтение данных из файла построчно

Путь = "c:\temp\text.txt";

Текст = Новый ЧтениеТекста(Путь, КодировкаТекста.UTF8);

Стр = Текст.ПрочитатьСтроку();

Пока Стр <> Неопределено Цикл

	Стр = Текст.ПрочитатьСтроку();

	Сообщить(Стр);

КонецЦикла;

Код 1C v 7.x

  //Выгрузка данных в TXT файл

Данные = СоздатьОбъект("Текст");

Данные.КодоваяСтраница(0); // принудительная установка   

НачВремя = _GetPerformanceCounter(); // Запоминаем время запуска алгоритма

ТЗ.ВыбратьСтроки();

Пока ТЗ.ПолучитьСтроку()=1 Цикл 

 Стр = ""+ТЗ.ЭтоГруппа+";"+ТЗ.Уровень+";"+ ТЗ.КодРодителя+";"+ТЗ.Код+";"+ТЗ.Наименование; // Символ - разделитель полей - ";"

 Данные.ДобавитьСтроку(Стр);

КонецЦикла; 

Данные.Записать("c:\export.txt");

КонВремя = _GetPerformanceCounter(); // Запоминаем время окончания алгоритма

// Рассчитываем продолжительность выполнения алгоритма в секундах

Длительность = Окр((КонВремя-НачВремя)/1000,3);

Сообщить("Время выгрузки в TXT файл: "+Длительность+" с");



//Загрузка, чтение данных из TXT файла:

НачВремя = _GetPerformanceCounter(); // Запоминаем время запуска алгоритма

Данные = СоздатьОбъект("Текст");

Данные.КодоваяСтраница(0); // принудительная установка  

Данные.Открыть("c:\export.txt");

КолСтр  = Данные.КоличествоСтрок();

 Для н=1 по КолСтр Цикл 

 ТекСтр = Данные.ПолучитьСтроку(н);   

 Состояние("В файле прочитано строк "+н+" из "+КолСтр);

КонецЦикла; 

КонВремя = _GetPerformanceCounter(); // Запоминаем время окончания алгоритма

// Рассчитываем продолжительность выполнения алгоритма в секундах

Длительность = Окр((КонВремя-НачВремя)/1000,3);

Сообщить("Время чтения TXT файла: "+Длительность+" с");

Категория: JSON, XML, TXT, CSV, DBF

Выгрузка / Загрузка данных посредством DBF файлов?

DBF-файл – это файл, в котором данные хранятся в виде таблицы (Database format). Работа с этими файлами происходит по принципу курсора, т.е. по одной строке. Для работы с DBF-файлами существует тип данных XBase. Несмотря на то, что формат DBF считается уже устаревшим, может возникнуть необходимость работы с файлами данного формата, особенно, если вы перегружаете данные из какой-нибудь старой программы!

Код 1C v 8.х

  // ПРИМЕР 1

// Запись данных справочника в DBF-файл:

БД = Новый XBase;

// проектируется структура таблицы, т.е. имена и типы полей

БД.Поля.Добавить("Code","N",6,0);	// числовое поле Код

БД.Поля.Добавить("Name","S",30);	// строковое поле Наименование

// создание файла с указанной структурой

БД.СоздатьФайл("C://1.dbf");

Выборка = Справочники.Клиенты.Выбрать();

Пока Выборка.Следующий() Цикл

	// создается новая пустая строка таблицы

	БД.Добавить();

	// заполняем поля новой строки

	БД.Code = Выборка.Код;

	БД.Name = Выборка.Наименование;

КонецЦикла;

// зафиксировать изменения в файле

БД.ЗакрытьФайл();



// Чтение данных из DBF-файла в справочник:

БД = Новый XBase;

БД.ОткрытьФайл("C://1.dbf");

// считываем файл построчно

Пока БД.Следующая() Цикл

	// создаем новый элемент справочника

 Спр=Справочники.Клиенты.СоздатьЭлемент();

 	// переносим в реквизиты данные из текущей строки таблицы

 	Спр.Код = БД.Сode; 

 	Спр.Наименование = БД.Name;

Спр.Записать();

КонецЦикла;

БД.ЗакрытьФайл();

Код 1C v 8.х

  // ПРИМЕР 2

// Выгрузка данных в DBF

БД = Новый XBase;

БД.Поля.Добавить("CODE", "S", 5);

БД.Поля.Добавить("NAME", "S", 40);

БД.СоздатьФайл(Путь + "start.dbf", Путь + "index.cdx");

БД.Индексы.Добавить("IDXCODE", "CODE");

ФлИБД = БД.СоздатьИндексныйФайл(Путь + "index.cdx");

БД.АвтоСохранение = Истина;

Выборка = Справочники.Номенклатура.ВыбратьИерархически();

Пока Выборка.Следующий() Цикл

	БД.Добавить();

	БД.CODE = Выборка.Код;

	БД.NAME = Выборка.Наименование;

КонецЦикла;

БД.ЗакрытьФайл();



// Загрузка данных из DBF

БД = Новый XBase;

БД.ОткрытьФайл(Путь + "start.dbf", Путь + "index.cdx"); 

БД.ТекущийИндекс = БД.Индексы.IDXCODE;

Пока БД.Следующая() Цикл

	Сообщить(БД.CODE);

	Сообщить(БД.NAME);

КонецЦикла;	

БД.ЗакрытьФайл();

Код 1C v 7.x

  // Выгрузка ТЗ, Таблицы значений в DBF файл  

 НачВремя = _GetPerformanceCounter(); // Запоминаем время запуска алгоритма

 ДБФ = СоздатьОбъект("XBASE"); 

 ДБФ.ДобавитьПоле("IsGroup","N",1,0);  

 ДБФ.ДобавитьПоле("Level","N",1,0);

 ДБФ.ДобавитьПоле("ParentCode","S",8,0);

 ДБФ.ДобавитьПоле("Code","S",8,0);

 ДБФ.ДобавитьПоле("Descr","S",60,0); 

 ДБФ.КодоваяСтраница(0); // Windows

 ДБФ.СоздатьФайл("c:\export.dbf"); 



 ТЗ.ВыбратьСтроки();

 Пока ТЗ.ПолучитьСтроку()=1 Цикл

  ДБФ.Добавить();  

  ДБФ.IsGroup= ТЗ.ЭтоГруппа;

  ДБФ.Level= ТЗ.Уровень; 

  ДБФ.ParentCode = ТЗ.КодРодителя;

  ДБФ.Code= ТЗ.Код; 

  ДБФ.Descr= СокрЛП(ТЗ.Наименование); 

  ДБФ.Записать(); 

 КонецЦикла;  

 ДБФ.ЗакрытьФайл(); 



 КонВремя = _GetPerformanceCounter(); // Запоминаем время окончания алгоритма

 // Рассчитываем продолжительность выполнения алгоритма в секундах

 Длительность = Окр((КонВремя-НачВремя)/1000,3);

 Сообщить("Время выгрузки в DBF файл: "+Длительность+" с");



 // Загрузка ТЗ, Таблицы значений из DBF файла

  НачВремя = _GetPerformanceCounter(); // Запоминаем время запуска алгоритма 

  ДБФ = СоздатьОбъект("XBASE"); 

  ДБФ.КодоваяСтраница(0); // Windows

  ДБФ.ОткрытьФайл("c:\export.dbf");  

  Если ДБФ.Открыта()=0 Тогда

   Сообщить("Файл DBF не открыт !","!");

   Возврат;

  КонецЕсли;

  КолСтр  = ДБФ.КоличествоЗаписей();

  н= 0; 

  ДБФ.Первая(); 

  ПризнакГруппы  = ДБФ.IsGroup;

  ТекУровень  = ДБФ.Level; 

  ТекКодРодителя = ДБФ.ParentCode;

  ТекКод  = ДБФ.Code; 

  ТекНаименоване = ДБФ.Descr;  

  н = н+1;

  Состояние("В файле прочитано записей "+н+" из "+КолСтр); 

  Пока ДБФ.Следующая()=1 Цикл

   ПризнакГруппы  = ДБФ.IsGroup;

   ТекУровень  = ДБФ.Level; 

   ТекКодРодителя = ДБФ.ParentCode;

   ТекКод  = ДБФ.Code; 

   ТекНаименоване = ДБФ.Descr;

   н = н+1;

   Состояние("В файле прочитано записей "+н+" из "+КолСтр); 

  КонецЦикла;  

  ДБФ.ЗакрытьФайл(); 

  

  КонВремя = _GetPerformanceCounter(); // Запоминаем время окончания алгоритма

  // Рассчитываем продолжительность выполнения алгоритма в секундах

  Длительность = Окр((КонВремя-НачВремя)/1000,3);

  Сообщить("Время чтения DBF файла: "+Длительность+" с");

Категория: JSON, XML, TXT, CSV, DBF

Удалить строки из табличной части справочника

Код 1C v 8.2 УП

  &НаКлиенте

Процедура ОбработатьВыполнить()

    Объект.Обработан=Истина;

    БылоСтрок= Объект.Данные.Количество();

    Для Счетчик =1  по   Объект.Данные.Количество() Цикл 

        НомерСтроки= БылоСтрок-Счетчик;

        лСтр = Объект.Данные[НомерСтроки];

        Если лСтр.Группа = Объект.ВозрастнаяГруппа  Тогда

            // оставляем

        Иначе

            Объект.Данные.Удалить(НомерСтроки);

        КонецЕсли;

    КонецЦикла;

КонецПроцедуры

Код 1C v 8.х

 ЭлементСправочника = Справочники.Контрагенты.НайтиПоКоду("Ю0006"); 

ОбъектСправочника = ЭлементСправочника.ПолучитьОбъект(); 

ОбъектСправочника.ВидыДеятельности.Очистить(); 

ОбъектСправочника.Записать(); 



ОбъектСправочника = ВыбранныйЭлемент.ПолучитьОбъект(); 



// Создать структуру для отбора удаляемых строк. 

СтруктураОтбора = Новый Структура("ВидДеятельности", ВыбранныйВидДеятельности); 



// Получить массив удаляемых строк. 

ПодходящиеСтроки = ОбъектСправочника.ВидыДеятельности.НайтиСтроки(СтруктураОтбора); 



// Удалить строки. 

Для Каждого ОчереднаяСтрока Из ПодходящиеСтроки Цикл 

	ОбъектСправочника.ВидыДеятельности.Удалить(ОчереднаяСтрока); 

КонецЦикла; 

ОбъектСправочника.Записать();

Категория: Справочники

Процедура вычисляет количество лет, месяцев и дней между двумя датами

Код 1C v 8.х

 

// Процедура вычисляет количество лет, месяцев и дней между двумя датами

//

// Параметры

//  Дата1	– дата, первая дата (более поздняя, часто текущая, стаж определяется по состоянию на эту дату)

//  Дата2	– дата, вторая дата (ранняя дата, с нее начинается ""течение"" стажа)

//  Лет		– Число, в этот параметр будет записано кол-во лет между двумя датами (Дата1-Дата2)

//  Месяцев	– Число, в этот параметр будет записано кол-во месяцев между двумя датами (Дата1-Дата2)

//  Дней	– Число, в этот параметр будет записано кол-во дней между двумя датами (Дата1-Дата2)

//

Процедура РазобратьРазностьДат(Дата1, Дата2, Лет = 0, Месяцев = 0, Дней = 0) Экспорт

	

	Лет		= 0;

	Месяцев	= 0;

	Дней	= 0;

	Если Дата1 > Дата2 Тогда

		

		ВременнаяДата = Дата1;

		Если День(ВременнаяДата) < День(Дата2) Тогда

			Дней = (ВременнаяДата - ДобавитьМесяц(ВременнаяДата,-1))/86400;

			ВременнаяДата = ДобавитьМесяц(ВременнаяДата,-1);

		КонецЕсли;

		Если Месяц(ВременнаяДата) < Месяц(Дата2) Тогда

			ВременнаяДата = ДобавитьМесяц(ВременнаяДата,-12);

			Месяцев = 12;

		КонецЕсли;

		Лет		= Макс(			 Год(ВременнаяДата)		- Год(Дата2),	0);

		Месяцев	= Макс(Месяцев	+ Месяц(ВременнаяДата)	- Месяц(Дата2),	0);

		Дней	= Макс(Дней		+ День(ВременнаяДата)	- День(Дата2),	0);

		

		// скорректируем отображаемое значение, если ""вмешалось"" разное количество дней в месяцах

		Если Дата2 <> (ДобавитьМесяц(Дата1,-Лет * 12-Месяцев)-Дней * 86400) Тогда

			Дней = Дней + (День(КонецМесяца(Дата2)) - День(НачалоМесяца(Дата2))) - (День(КонецМесяца(ДобавитьМесяц(Дата1,-1))) - День(НачалоМесяца(ДобавитьМесяц(Дата1,-1))));

		КонецЕсли;

		

	КонецЕсли;



КонецПроцедуры

Вычисление периодов в формате ГГММДД. Вычисление дат по формуле Дата + ГГММДД.
Примечание: Даты передаем в виде 'ДД.ММ.ГГГГ', периоды - "ГГ-ММ-ДД".
Пользуйтесь. arithmometr

Код 1C v 7.x

 

//********************************************************

//Назначение: преобразует строку в число путем преобразования каждого символа

//по правилам преобразования типов

// <стр> - строка;

//

//Примечание:

//

Функция зпГлСтрокуВЧисло(стр) Экспорт

    стр1 = СокрЛП(стр);

    Чис1 = "";

    Для х = 1 По СтрДлина(стр1) Цикл

        Чис1 = Чис1 + Число(Сред(стр1,х,1));

    КонецЦикла;

    Чис = Число(Чис1);

    Возврат Чис;

КонецФункции // зпГлСтрокуВЧисло(стр)

//********************************************************

// Функция зпГлВычислитьСрок(Аргум1,Аргум2="",Парам=777)

// <Аргум1> - Дата1 или Срок1

// <Аргум2> - Дата2 или Срок2

// <Срок> - Период в формате ГГ-ММ-ДД

// Параметры: '0' - ЗнВозврата = Дата2-Дата1 - вичислить период между датами в формате ГГ-ММ-ДД

//         '-1' - ЗнВозврата = Дата1-Срок - вычесть период

//         '1' - ЗнВозврата = Дата1+Срок - добавить период

//         Иначе ЗнВозврата = Правильный срок

//         'П' - ЗнВозврата = Правильный срок прописью

//         'К' - ЗнВозврата = Правильный срок прописью краткий формат

//         '+' - ЗнВозврата = Срок1+Срок2 - сложить периоды

////////         '-' - ЗнВозврата = Срок1-Срок2 - вычесть периоды

//

// Примечание: Ст.241-1 КЗоТ Украины

//

Функция зпГлВычислитьСрок(Аргум1,Аргум2="",Парам="") Экспорт

    Перем ЗнВозврата;



    Если (Парам=0) Тогда

        Дата1 = Мин(Дата(Аргум1),Дата(Аргум2));

        Дата2 = Макс(Дата(Аргум1),Дата(Аргум2));



        Мес = (ДатаГод(Дата2) - ДатаГод(Дата1))* 12 + (ДатаМесяц(Дата2) - ДатаМесяц(Дата1));

        Дни = ДатаЧисло(Дата2) - ДатаЧисло(Дата1);



        Если (Дни < 0) Тогда

            Мес = Мес - 1;

            Дни = Дни + ДатаЧисло(КонМесяца(Дата1));

        КонецЕсли;

        Если (Дни >= ДатаЧисло(КонМесяца(Дата2))) и (Дата2 = КонМесяца(Дата2)) Тогда

            Мес = Мес + 1;

            Дни = 0;

        КонецЕсли;



        Лет = Цел(Мес/12);

        Мес = Мес - Лет* 12;



        ЗнВозврата = Формат(Лет,"Ч(0)2.0")+"-"+Формат(Мес,"Ч(0)2.0")+"-"+Формат(Дни,"Ч(0)2.0");

    ИначеЕсли (Число(Парам)*Число(Парам)=1) Тогда

        Дата1 = Дата(Аргум1);

        Аргум2 = зпГлВычислитьСрок(Аргум2);

        Срок = Аргум2;



        Мес = Число(Лев(Срок,2))* 12 + Число(Сред(Срок,4,2));

        Дни = Число(Прав(Срок,2));



        Дата2 = ДобавитьМесяц(Дата1,Парам*Мес);



        Если (Дата1 = КонМесяца(Дата1)) Тогда

            Дни = Мин(ДатаЧисло(КонМесяца(Дата2)) - 1, Дни);

        ИначеЕсли (Дни >= ДатаЧисло(КонМесяца(Дата2))*((1-Парам)/2) - Парам*ДатаЧисло(Дата2)) Тогда

            Дни = Мин(ДатаЧисло(КонМесяца(ДобавитьМесяц(Дата2,1))) - 1, Дни);

        КонецЕсли;



        ЗнВозврата = Дата2 + Парам*Дни;

    Иначе

        Если (Найти(Парам, "+") > 0) Тогда

            Срок1 = зпГлСтрокуВЧисло(СтрЗаменить(Аргум1+".","-",""))/10;

            Срок2 = зпГлСтрокуВЧисло(СтрЗаменить(Аргум2+".","-",""))/10;



            Дни = Срок1%100 + Срок2%100;

            Мес = Цел((Срок1%10000 + Срок2%10000 - Дни)/1000);

            Лет = Цел(Срок1/10000) + Цел(Срок2/10000);



            Мес = Мес + Цел(Дни/30);

            Дни = Дни%30;

            Лет = Лет + Цел(Мес/12);

            Мес = Мес%12;

        Иначе

            Срок = зпГлСтрокуВЧисло(СтрЗаменить(Аргум1+".","-",""))/10;

            Мес = Цел(Срок/100) - Цел(Срок/10000)*(100-12);

            Дни = Мин(Срок - Цел(Срок/100)* 100, 30);

            Лет = Цел(Мес/12);

            Мес = Мес - Лет* 12;

        КонецЕсли;



        Если (Найти(Парам, "П") > 0) Тогда

            ЗнВозврата = "років "+Лет+", місяців "+Мес+", днів "+Дни;

        ИначеЕсли (Найти(Парам, "К") > 0) Тогда

            ЗнВозврата = ""+Лет+"р."+Мес+"м."+Дни+"д.";

        Иначе

            ЗнВозврата = Формат(Лет,"Ч(0)2.0")+"-"+Формат(Мес,"Ч(0)2.0")+"-"+Формат(Дни,"Ч(0)2.0");

        КонецЕсли;

    КонецЕсли;



    Возврат ЗнВозврата;

КонецФункции

Категория: Работа с Датами (Временем)