минута » Поиск

Результаты по ключевому слову: минута

Универсальный парсер RSS для 1С

На одном проекте - клиент попросил отображать в программе данные, которые выдаю специализированные сайта в формате RSS - Что делать !?

Писать парсер rss для 1С

Первым делом, взглянув на ссылки, подумал что - обычный XML, сейчас его разложу и быстренько загружу в базу, но:

Выяснилось что сайты имеют разные форматы ввода RSS и главное они не валидные(

таким образом, написав небольшой код, который получает ссылку, далее XMLФайл.Прочитать() на одном сайте проходил на ура (этот пример я описывал в статье: Чтение данных с сайта в формате XML и загрузка в 1С), а вот второй сайт, и третий тоже, при попытке прочитать() выдавали:

{ОбщийМодуль.РегЗадания.Модуль(79)}: Ошибка при вызове метода контекста (Прочитать)

Пока XMLФайл.Прочитать() Цикл

по причине:

Ошибка разбора XML: - [1,1]

Фатальная ошибка:

Extra content at the end of the document

SystemId url rss

решил попробовать на rss других известных сайтов - 80% из проверяемых выдавали ошибку

Пришлось написать прямой построчный парсер RSS:

Структура конфигурации

ИсточникиRSS - URL на RSS, ДанныеRSS - сюда записываются загруженные данные новостей

Код получился таким(в принципе код универсальный, но возможно что-то придется подпилить):

Код 1C v 8.3

 

// RSS

Процедура ПрочитатьRSS(ИсточникRSS)

	url = ИсточникRSS.UrlRSS;

	

	// Получим Сервер

	Если Найти(url,".ru")>0 Тогда urlСервер = Лев(url,Найти(url,".ru")+2);	

	ИначеЕсли Найти(url,".com")>0 Тогда urlСервер = Лев(url,Найти(url,".com")+3);

	ИначеЕсли Найти(url,".org")>0 Тогда urlСервер = Лев(url,Найти(url,".org")+3);

	ИначеЕсли Найти(url,".info")>0 Тогда urlСервер = Лев(url,Найти(url,".info")+4);

	ИначеЕсли Найти(url,".pro")>0 Тогда urlСервер = Лев(url,Найти(url,".pro")+3);

	КонецЕсли;	 		

		

	//Определим тип соединения

	Если Лев(url,5)="https" Тогда

		//ssl = Новый ЗащищенноеСоединениеOpenSSL(Новый СертификатКлиентаWindows(), Новый СертификатыУдостоверяющихЦентровWindows());   

		ssl = Новый ЗащищенноеСоединениеOpenSSL( неопределено, неопределено );

		ТекАдрес = СтрЗаменить(url,urlСервер,""); Сервер = СтрЗаменить(urlСервер,"https://",""); 

		Соединение = Новый HTTPСоединение(Сервер,,,,,

		5, // таймаут в секундах

		ssl // защищенное HTTPS соединение

		);

	Иначе //Обычный HTTP 		

		ТекАдрес = СтрЗаменить(url,urlСервер,""); Сервер = СтрЗаменить(urlСервер,"http://","");

		Соединение = Новый HTTPСоединение(Сервер);

	КонецЕсли;





	Заголовки = Новый Соответствие;

	Заголовки.Вставить("host", Сервер);  

	Запрос = Новый HTTPЗапрос(ТекАдрес, Заголовки);

	Ответ =Соединение.Получить(Запрос);

	Если Ответ.КодСостояния = 200 Тогда // Данные получены, обрабатываем их

		Содержимое= Ответ.ПолучитьТелоКакСтроку();

		//Преобразуем содержимое

		Содержимое = СтрЗаменить(Содержимое,"<br/>","|"); 

		Содержимое = СтрЗаменить(Содержимое,"<![CDATA[",""); Содержимое = СтрЗаменить(Содержимое,"]]>","");  

		Содержимое = СтрЗаменить(Содержимое,Символы.ПС,""); Содержимое = СтрЗаменить(Содержимое,Символы.ВК,""); 

		Содержимое = СтрЗаменить(Содержимое,Символы.ВТаб,""); Содержимое = СтрЗаменить(Содержимое,Символы.Таб,""); 

		Содержимое = СтрЗаменить(Содержимое,"><",">"+Символы.ПС+"<"); 

		

		RegExp = Новый COMОбъект("VBScript.RegExp"); //Регулярка

		RegExp.IgnoreCase = Ложь; 

		RegExp.Global = Истина;    

		RegExp.MultiLine = Истина;   		

		RegExp.Pattern = "<[^>]*>"; //Ищем теги HTML   

		

		//Разберем полученный текст в таблицу

		ЭтоЗапись=Ложь;

		Для н=1 По СтрЧислоСтрок(Содержимое)Цикл

			обрТекст=СтрПолучитьСтроку(Содержимое,н);

			

			Если обрТекст = "<item>" Тогда //Началась запись 

				ЗаписьСтр = Новый Структура(); ЭтоЗапись=Истина; Продолжить;  

			ИначеЕсли обрТекст = "</item>" Тогда //Закончилась запись 

				

				/////////////// ЗАПИСЬ Закончилась //////////////

				/// теперь запишем ее в базу - Справочник ДанныеRSS

				// сначала ПОИСК ДУБЛЕЙ - вдруг уже загружен 				

				Запрос = Новый Запрос;

				Запрос.Текст = 

				"ВЫБРАТЬ

				|	ДанныеRSS.Ссылка

				|ИЗ

				|	Справочник.ДанныеRSS КАК ДанныеRSS

				|ГДЕ

				|	ДанныеRSS.ИсточникRSS =ИсточникRSS

				|	И ДанныеRSS.link ПОДОБНОlink";

				

				Запрос.УстановитьПараметр("link", "%"+ЗаписьСтр.link+"%");

				Запрос.УстановитьПараметр("ИсточникRSS", ИсточникRSS);				

				РезультатЗапроса = Запрос.Выполнить().Выбрать();

				Если РезультатЗапроса.Следующий() Тогда

					// Такая запись уже есть, пока ничего не делаем

				Иначе

					//СОЗДАЕМ Новый

					НовЭлем  = Справочники.ДанныеRSS.СоздатьЭлемент();

					ЗаполнитьЗначенияСвойств(НовЭлем,ЗаписьСтр);

					НовЭлем.ИсточникRSS = ИсточникRSS;

					НовЭлем.Записать(); 					

				КонецЕсли; 				

				/////////////////////// *** /////////////////////

				

				ЭтоЗапись=Ложь; Продолжить; 

			КонецЕсли; //Данные записи

			

			Если ЭтоЗапись Тогда	

				Если Найти(обрТекст,"title>")>0 и Найти(обрТекст,"/title>")>0 Тогда				

					обрТекст = СтрЗаменить(обрТекст,"title",""); обрТекст = СтрЗаменить(обрТекст,"<>",""); обрТекст = СтрЗаменить(обрТекст,"</>","");

					ЗаписьСтр.Вставить("Наименование",СокрЛП(обрТекст));

				КонецЕсли;

				

				Если Найти(обрТекст,"link>")>0 и Найти(обрТекст,"/link>")>0 Тогда				

					обрТекст = СтрЗаменить(обрТекст,"link",""); обрТекст = СтрЗаменить(обрТекст,"<>",""); обрТекст = СтрЗаменить(обрТекст,"</>","");

					ЗаписьСтр.Вставить("link",СокрЛП(обрТекст));

				КонецЕсли;

				

				Если Найти(обрТекст,"description>")>0 и Найти(обрТекст,"/description>")>0 Тогда			

					обрТекст = СтрЗаменить(обрТекст,"description",""); обрТекст = СтрЗаменить(обрТекст,"<>",""); обрТекст = СтрЗаменить(обрТекст,"</>","");

					обрТекст=RegExp.Replace(обрТекст, ""); //Удалим все теги

					ЗаписьСтр.Вставить("desc",СокрЛП(обрТекст));

				КонецЕсли;

				

				Если Найти(обрТекст,"pubDate>")>0 и Найти(обрТекст,"/pubDate>")>0 Тогда			

					обрТекст = СтрЗаменить(обрТекст,"pubDate",""); обрТекст = СтрЗаменить(обрТекст,"<>",""); обрТекст = СтрЗаменить(обрТекст,"</>","");

					ЗаписьСтр.Вставить("pubDate",ПреобразоватьRFC822КДате0(СокрЛП(обрТекст)));

				КонецЕсли;

				

				Если Найти(обрТекст,"enclosure")>0 Тогда					 

					обрТекст = СтрЗаменить(обрТекст,"""",""); обрТекст = СтрЗаменить(обрТекст,"<enclosure url=","");

					обрТекст = СтрЗаменить(обрТекст,"<enclosure url=",""); обрТекст = СтрЗаменить(обрТекст,"type=image/png length=/>","");

					ЗаписьСтр.Вставить("img",СокрЛП(обрТекст));

				КонецЕсли;

			КонецЕсли;	

							

		КонецЦикла;

		

	КонецЕсли;

	

КонецПроцедуры	









Процедура ПроверкаRSS() Экспорт

	Запрос = Новый Запрос;

	Запрос.Текст = 

	"ВЫБРАТЬ

	|	ИсточникиRSS.Ссылка КАК Ссылка

	|ИЗ

	|	Справочник.ИсточникиRSS КАК ИсточникиRSS

	|ГДЕ

	|	ИсточникиRSS.Использовать

	|	И ДОБАВИТЬКДАТЕ(ИсточникиRSS.ДатаПоследнегоОбновления, СЕКУНДА, ИсточникиRSS.ПериодОбновленияВСекундах) <ТекДата"; 	

	Запрос.УстановитьПараметр("ТекДата", ТекущаяДата());

	РезультатЗапроса = Запрос.Выполнить();

	ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

	Пока ВыборкаДетальныеЗаписи.Следующий() Цикл

		ПрочитатьRSS(ВыборкаДетальныеЗаписи.Ссылка);

		// Запишем дату последнего обновления

		ТекОб = ВыборкаДетальныеЗаписи.Ссылка.ПолучитьОбъект();

		ТекОб.ДатаПоследнегоОбновления = ТекущаяДата();

		ТекОб.Записать();

	КонецЦикла;

КонецПроцедуры



Функция ПреобразоватьRFC822КДате0(ДатаВФорматеRFC822) Экспорт

    КопияСтроки = ДатаВФорматеRFC822;

    СтруктураДаты = Новый Структура("Год,Месяц,День,Час,Минута,Секунда",  "","","","","","");

    Месяцы = Новый Структура("Jan,Feb,Mar,Apr,May,Jun,Jul,Aug,Sep,Oct,Nov,Dec",  "01","02","03","04","05","06","07","08","09","10","11","12");

    Для каждого КлючИЗначение Из Месяцы Цикл

        Позиция = Найти(КопияСтроки,КлючИЗначение.Ключ);

        Если Позиция > 0  Тогда

             СтруктураДаты.Месяц = КлючИЗначение.Значение;

            Прервать;

        КонецЕсли;

    КонецЦикла; 

	Состояние = 0;

	КопияСтроки = СтрЗаменить(КопияСтроки,", 1 ",", 01 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 2 ",", 02 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 3 ",", 03 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 4 ",", 04 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 5 ",", 05 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 6 ",", 06 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 7 ",", 07 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 8 ",", 08 ");

	КопияСтроки = СтрЗаменить(КопияСтроки,", 9 ",", 09 ");

	Для ш=0 По СтрДлина(КопияСтроки) Цикл

        ТекущийСимвол = Сред(КопияСтроки,ш,1); //ПолучитьСимвол(КопияСтроки, ш);

        ТекСимволЦифра= ЭтоЦифра(ТекущийСимвол);

        Если ТекСимволЦифра И Состояние = 0  Тогда

            СтруктураДаты.День = СтруктураДаты.День + ТекущийСимвол;

            Состояние = 1; //начало день

        ИначеЕсли ТекСимволЦифра И Состояние = 1  Тогда

            СтруктураДаты.День = СтруктураДаты.День + ТекущийСимвол;

            Состояние = 2; //ждем год

        ИначеЕсли ТекСимволЦифра И Состояние = 2  Тогда

            СтруктураДаты.Год = СтруктураДаты.Год + ТекущийСимвол;

            Состояние = 3; //продолжаем год

        ИначеЕсли ТекСимволЦифра И Состояние = 3  Тогда

            СтруктураДаты.Год = СтруктураДаты.Год + ТекущийСимвол;

        ИначеЕсли ТекущийСимвол = " " И Состояние = 3 Тогда

               Состояние = 4; //дальше час    

        ИначеЕсли ТекСимволЦифра И Состояние = 4  Тогда

            СтруктураДаты.Час = СтруктураДаты.Час + ТекущийСимвол;

        ИначеЕсли ТекущийСимвол = ":" И Состояние = 4  Тогда

            Состояние = 5; //дальше минута

        ИначеЕсли ТекСимволЦифра И Состояние = 5  Тогда

            СтруктураДаты.Минута = СтруктураДаты.Минута +  ТекущийСимвол;

        ИначеЕсли ТекущийСимвол = ":" И Состояние = 5  Тогда

            Состояние = 6; //дальше секунда

        ИначеЕсли ТекСимволЦифра И Состояние = 6  Тогда

            СтруктураДаты.Секунда = СтруктураДаты.Секунда +  ТекущийСимвол;

        ИначеЕсли ТекущийСимвол = " " И Состояние = 6 Тогда

            Прервать;

        КонецЕсли;

    КонецЦикла;

    Попытка

        Результат = Дата(СтруктураДаты.Год+СтруктураДаты.Месяц+СтруктураДаты.День

                        +СтруктураДаты.Час+СтруктураДаты.Минута+СтруктураДаты.Секунда);

    Исключение

        Результат = Неопределено;    

    КонецПопытки;

    Возврат Результат;

КонецФункции



Функция ЭтоЦифра(Символ) Экспорт

     Если (КодСимвола(Символ)>=48) И (КодСимвола(Символ)<=57) Тогда Возврат Истина; Иначе Возврат ложь; КонецЕсли;

КонецФункции



Функция ПолучитьСимвол(КопияСтроки, ш)

	Возврат Сред(КопияСтроки,ш,1);

КонецФункции

Результат загрузки новостей RSS HelpF.pro

Кстати, как позже выяснилось, здесь уже есть статья с примером через IE и DOM: Получения новостей с RSS-канала сайта buh.ru

Категория: Работа с Интернет, Почтой (Mail), FTP

Как преобразовать дату в формат RFC 822 и обратно?

Создавая обмены данными между 1С и сайтами, часто приходится форматировать вывод даты в стандарт RCF-822 или преобразовывать его в понятную для 1С ДатуВремя.

Дата в формате RFC-822 выглядит так: Tue, 12 Aug 2013 14:15:00 +0400

Небольшая справка по стандартам:

Как дату перевести в формат RFC-822?

Код 1C v 8.2 УП

 ДатаВФорматеRFC822 = Формат(ТекущаяДата(),"Л=en_US; ДФ='ddd, dd MMM yyyy hh:mm:ss +0400    '");

Как из формата RFC-822 получить дату и время для 1С?

Код 1C v 8.2 УП

 // Функция преобразовывает дату в формате RFC822 к формату 1С - дата и время
// Параметры
//  ДатаВФорматеRFC822  – Строка вида "Thu, 10 Aug 2006 14:48:27 +0400"
// Возвращаемое значение:
//   <Дата>   –    Результат преобразования или Неопределено, если преобразование не удалось
Функция ПреобразоватьRFC822КДате0(ДатаВФорматеRFC822) Экспорт
    КопияСтроки = ДатаВФорматеRFC822;
    СтруктураДаты = Новый Структура("Год,Месяц,День,Час,Минута,Секунда",  "","","","","","");
    Месяцы = Новый Структура("Jan,Feb,Mar,Apr,May,Jun,Jul,Aug,Sep,Oct,Nov,Dec",  "01","02","03","04","05","06","07","08","09","10","11","12");
    Для каждого КлючИЗначение Из Месяцы Цикл
        Позиция = Найти(КопияСтроки,КлючИЗначение.Ключ);
        Если Позиция > 0  Тогда
             СтруктураДаты.Месяц = КлючИЗначение.Значение;
            Прервать;
        КонецЕсли;
    КонецЦикла; 
    Состояние = 0;
    Для ш=0 По СтрДлина(КопияСтроки) Цикл
        ТекущийСимвол = ПолучитьСимвол(КопияСтроки, ш);
        ТекСимволЦифра= ЭтоЦифра(ТекущийСимвол);
        Если ТекСимволЦифра И Состояние = 0  Тогда
            СтруктураДаты.День = СтруктураДаты.День + ТекущийСимвол;
            Состояние = 1; //начало день
        ИначеЕсли ТекСимволЦифра И Состояние = 1  Тогда
            СтруктураДаты.День = СтруктураДаты.День + ТекущийСимвол;
            Состояние = 2; //ждем год
        ИначеЕсли ТекСимволЦифра И Состояние = 2  Тогда
            СтруктураДаты.Год = СтруктураДаты.Год + ТекущийСимвол;
            Состояние = 3; //продолжаем год
        ИначеЕсли ТекСимволЦифра И Состояние = 3  Тогда
            СтруктураДаты.Год = СтруктураДаты.Год + ТекущийСимвол;
        ИначеЕсли ТекущийСимвол = " " И Состояние = 3 Тогда
               Состояние = 4; //дальше час    
        ИначеЕсли ТекСимволЦифра И Состояние = 4  Тогда
            СтруктураДаты.Час = СтруктураДаты.Час + ТекущийСимвол;
        ИначеЕсли ТекущийСимвол = ":" И Состояние = 4  Тогда
            Состояние = 5; //дальше минута
        ИначеЕсли ТекСимволЦифра И Состояние = 5  Тогда
            СтруктураДаты.Минута = СтруктураДаты.Минута +  ТекущийСимвол;
        ИначеЕсли ТекущийСимвол = ":" И Состояние = 5  Тогда
            Состояние = 6; //дальше секунда
        ИначеЕсли ТекСимволЦифра И Состояние = 6  Тогда
            СтруктураДаты.Секунда = СтруктураДаты.Секунда +  ТекущийСимвол;
        ИначеЕсли ТекущийСимвол = " " И Состояние = 6 Тогда
            Прервать;
        КонецЕсли;
    КонецЦикла;
    Попытка
        Результат = Дата(СтруктураДаты.Год+СтруктураДаты.Месяц+СтруктураДаты.День
                        +СтруктураДаты.Час+СтруктураДаты.Минута+СтруктураДаты.Секунда);
    Исключение
        Результат = Неопределено;    
    КонецПопытки;
    Возврат Результат;
КонецФункции // ПреобразоватьRFC822КДате()

В процессе изучения вопроса, встретил еще несколько вариантов:

Код 1C v 8.х

  // Автор: Mavka 

// По типу: Wed, 30 Mar 2011 17:50:11 +0200 

// Я написала код, но без учета часовых поясов( 

Функция ВДатуRFC822(Дата1С, ПоправкаGMT) Экспорт

    Перем ТемпДата;

    Перем ТемпГод;

    Перем ТемпМесяц;

    Перем ТемпДень;

    Перем ДатаRFC822;

    Перем ТемпЧас;

    Перем ТемпМинута;

    Перем ТемпСекунда;

    Перем НомерДняНедели;

    Перем ТемпДеньНедели;

    Перем МесяцИмя;

    ТемпДата = Дата1С - 60 * 60 * ПоправкаGMT;

    ТемпГод = СтрЗаменить(Формат(Год(ТемпДата),"ND=4; NLZ="),Символы.НПП,"");

    ТемпМесяц = Месяц(ТемпДата);

    Если ТемпМесяц = 1 Тогда

         МесяцИмя = "Jan";

     ИначеЕсли ТемпМесяц = 2 Тогда

         МесяцИмя = "Feb";

     ИначеЕсли ТемпМесяц = 3 ТОгда

         МесяцИмя = "Mar";

     ИначеЕсли ТемпМесяц = 4 Тогда

         МесяцИмя = "Apr";

     ИначеЕсли ТемпМесяц = 5 Тогда 

         МесяцИмя = "May";

     ИначеЕсли ТемпМесяц = 6 Тогда

         МесяцИмя = "Jun";

     ИначеЕсли ТемпМесяц = 7 Тогда

         МесяцИмя = "Jul";

     ИначеЕсли ТемпМесяц = 8 ТОгда

         МесяцИмя = "Aug";

     ИначеЕсли ТемпМесяц = 9 Тогда

         МесяцИмя = "Sep";

     ИначеЕсли ТемпМесяц = 10 Тогда 

         МесяцИмя = "Oct";

     ИначеЕсли ТемпМесяц = 11 Тогда

         МесяцИмя = "Nov";

     Иначе        

         МесяцИмя = "Dec";

    КонецЕсли;

    ТемпДень = Формат(День(ТемпДата),"ND=2; NLZ=");

    НомерДняНедели = ДеньНедели(ТемпДата);

    Если НомерДняНедели = 1 Тогда

         ТемпДеньНедели = "Mon";

     ИначеЕсли НомерДняНедели = 2 Тогда

         ТемпДеньНедели = "Tue";

     ИначеЕсли НомерДняНедели = 3 ТОгда

         ТемпДеньНедели = "Wed";

     ИначеЕсли НомерДняНедели = 4 Тогда

         ТемпДеньНедели = "Thu";

     ИначеЕсли НомерДняНедели = 5 Тогда 

         ТемпДеньНедели = "Fri";

     ИначеЕсли НомерДняНедели = 6 Тогда

         ТемпДеньНедели = "Sat";

     Иначе        

         ТемпДеньНедели = "Sun";

    КонецЕсли;

    

        ТемпЧас = ?(Час(ТемпДата) = 0, "00", Формат(Час(ТемпДата),"ND=2; NLZ="));

        ТемпМинута = ?(Минута(ТемпДата) = 0, "00", Формат(Минута(ТемпДата),"ND=2; NLZ="));

        ТемпСекунда = ?(Секунда(ТемпДата) = 0, "00", Формат(Секунда(ТемпДата),"ND=2; NLZ="));

        ДатаRFC822 = ТемпДеньНедели+ ", " + ТемпДень + " " + МесяцИмя + " " + ТемпГод + " " + ТемпЧас + ":" + ТемпМинута + ":" + ТемпСекунда + " +0200";

    

    Возврат ДатаRFC822;

КонецФункции

Категория: Работа с Датами (Временем)

Сложение дат в запросе (Прибавить к дате секунды, дни) - ДобавитьКДате

При разработке отчетов бывает необходимо в запросе прибавить к дате несколько секунд, дней, месяцев.

Для этого имеется встроенная функция ДобавитьКДате

Синтаксис функции:

ДОБАВИТЬКДАТЕ(<Исходная Дата>, <Единица Измерения>, <Количество>)

Исходная дата – дата, к которой необходимо прибавить или вычесть требуемое количество временных единиц.
Единица измерения – параметр, который определяет единицу прибавляемого времени. Возможные значения: Год, Квартал, Месяц, День, Час, Минута, Секунда.
Количество – количество временных единиц, которых необходимо прибавить к исходному значению.

Код 1C v 8.2 УП

 // Разные примеры использования

// Минута

ДОБАВИТЬКДАТЕ(ДАТАВРЕМЯ(2999, 1, 1, 0, 0, 0), Минута, 30) КАК Часы,

// Час

ДОБАВИТЬКДАТЕ(ДАТАВРЕМЯ(2999, 1, 1, 0, 0, 0), ЧАС, ЧАС(СтатусыУслуг.ЗапланированноеВремя)) КАК Часы

// Месяц

ДобавитьКДате(ДатаВремя(2002, 10, 12, 10, 15, 34), "Месяц", 1)

Рабочий код:

Код 1C v 8.2 УП

 Запрос = Новый Запрос;

	Запрос.Текст = 

	"ВЫБРАТЬ

	|	ИсточникиRSS.Ссылка КАК Ссылка

	|ИЗ

	|	Справочник.ИсточникиRSS КАК ИсточникиRSS

	|ГДЕ

	|	ИсточникиRSS.Использовать

	|	И ДОБАВИТЬКДАТЕ(ИсточникиRSS.ДатаПоследнегоОбновления, СЕКУНДА, ИсточникиRSS.ПериодОбновленияВСекундах) <ТекДата"; 	

	Запрос.УстановитьПараметр("ТекДата", ТекущаяДата());

	РезультатЗапроса = Запрос.Выполнить();

	ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

	Пока ВыборкаДетальныеЗаписи.Следующий() Цикл

	

	КонецЦикла;

Категория: Запросы

Как в запросе указать пустую дату? - ДАТАВРЕМЯ()

Для указания Даты и Времени в запросе предназначена функция ДАТАВРЕМЯ(

ДАТАВРЕМЯ ( <Целое число>, <Целое число>, <Целое число>[, <Целое число>, <Целое число>, <Целое число>] )
Значения типа дата задаются с помощью ключевого слова ДАТАВРЕМЯ, после которого в скобках последовательно указываются год, месяц, день, час, минута, секунда. Последние три указывать необязательно.

Максимальная дата которую возможно задать при помощи литерала ДАТАВРЕМЯ – 31.12.3999 23:59:59.

Код 1C v 8.х

 ВЫБРАТЬ НачалоПериода(ДатаВремя(2002, 10, 12, 10, 15, 34), Месяц)

Код 1C v 8.х

 Запрос = Новый Запрос;

Запрос.Текст = 

	"ВЫБРАТЬ

	|	НаборЗаписей.Период,

	|	НаборЗаписей.ФизЛицо,

	|	ВЫБОР

	|		КОГДА НаборЗаписей.Организация.ГоловнаяОрганизация = ЗНАЧЕНИЕ(Справочник.Организации.ПустаяСсылка)

	|			ТОГДА НаборЗаписей.Организация

	|		ИНАЧЕ НаборЗаписей.Организация.ГоловнаяОрганизация

	|	КОНЕЦ КАК Организация,

	|	НаборЗаписей.ПринятПоДолгосрочномуДоговору,

	|	ВЫБОР

	|		КОГДА НаборЗаписей.ПериодЗавершения = ДАТАВРЕМЯ(1, 1, 1)

	|			ТОГДА НаборЗаписей.ПериодЗавершения

	|		ИНАЧЕ КОНЕЦПЕРИОДА(НаборЗаписей.ПериодЗавершения, МЕСЯЦ)

	|	КОНЕЦ КАК ПериодЗавершения,

	|	НаборЗаписей.Документ

	|ИЗ

	|	ВТНаборЗаписей КАК НаборЗаписей";

	ЭтотОбъект.Загрузить(Запрос.Выполнить().Выгрузить());

Категория: Запросы

Как вычислить разницу между двумя датами в часах и минутах

Код 1C v 8.х

 Функция РазностьВремени(Время1, Время2);

	

	Разность = Время1 - Время2;

	

	Если Разность > 0 Тогда

		Часов = Цел(Разность / 3600);

		Минут = Цел((Разность - Часов * 3600) / 60);

		

		Возврат Дата(1, 1, 1, Часов, Минут, 0);

		

	Иначе

		Возврат Дата(1,1,1,0,0,0);

	КонецЕсли;

	

КонецФункции





//Пример использования	

Опоздание= РазностьВремени(ВремяПриезда, ВремяПодачи);

Категория: Работа с Датами (Временем)

Как оповестить пользователей из серверного модуля или регламентного задания.

Код 1C v 8.2 УП

 

// Оповестим пользователей о неактуальности данных.

// Если мы не хотим подключать обработчик ожидания,

//воспользуемся командой Windows

МинутаХ = Формат(НачалоМинуты(КонецМинуты(ТекущаяДата()+300)+1),"ДФ=HH:mm:ss");

Текст = " Внимание!"+Символ(13)+ "Данные в системе 1с ЗУП Тест будут неактуальны 5 минут!"+Символ(13)+"Не формируйте отчеты и документы до "+МинутаХ;

Соединения = ПолучитьСоединенияИнформационнойБазы();

КОМПЫ = Новый Соответствие ;

Для каждого ЭлементСоединения Из Соединения Цикл

    КОМПЫ.Вставить(ЭлементСоединения.ИмяКомпьютера);

КонецЦикла;  		 

Для  каждого Компьютер из  КОМПЫ Цикл

    СтрокаМесаги = "MSG /time:30 /server:"+ СокрЛП(Компьютер.Ключ)+" * "+Текст;

    //СтрокаМесаги = "NET SEND "+ СокрЛП(Компьютер.Ключ)+Текст;

    ЗапуститьПриложение(СтрокаМесаги);

КонецЦикла;

Категория: Пользователь, роль доступа, интерфейс

Функция переводит Дату в формате 1С в формат вида 'YYYYMMDD hh:mm:ss' и обратно

Код 1C v 8.х

 // Функция переводит дату в формате 1С в международный текстовый формат вида 'YYYYMMDD hh:mm:ss'

// Параметры:  Дата1С - Дата   - Дата в формате 1С

// Возвращаемое значение: Строка - Дата в международном текстовом формате

//

Функция ДатаВСтроку(Дата1С)

                Результат = Формат(Год(Дата1С),"ЧГ=0") + ?(СтрДлина(Строка(Месяц(Дата1С))) < 2,"0" + Строка(Месяц(Дата1С)) , Строка(Месяц(Дата1С)))

                + ?(СтрДлина(Строка(День(Дата1С))) < 2, "0" + Строка(День(Дата1С)), Строка(День(Дата1С))) + " "

                + ?(СтрДлина(Строка(Час(Дата1С))) < 2, "0" + Строка(Час(Дата1С)), Строка(Час(Дата1С))) + ":" 

                + ?(СтрДлина(Строка(Минута(Дата1С))) < 2, "0" + Строка(Минута(Дата1С)), Строка(Минута(Дата1С))) + ":"

                + ?(СтрДлина(Строка(Секунда(Дата1С))) <2, "0" + Строка(Секунда(Дата1С)), Строка(Секунда(Дата1С)));

                Возврат Результат;

КонецФункции



// Функция переводит строку в дату с указанным форматом

// Параметры:

//            Строка                 - Строка              - Дата в виде строки

//            ФорматДаты    - Строка              - Формат даты, в который переводится строка

// Возвращаемое значение: Дата      - Дата в указанном формате

//

Функция ПривестиСтрокуКДате(Строка, ФорматДаты="дмг")

                Список = Новый Массив;

                

                Подстрока = "";

                Позиция = 1;

                ДлинаСтроки = СтрДлина(Строка) + 1;

                

                Пока Позиция <= ДлинаСтроки цикл

                               Символ = Сред(Строка, Позиция, 1);

                               Если (Символ >= "0") И (Символ <= "9") тогда

                                               Подстрока = Подстрока + Символ;

                               ИначеЕсли Подстрока <> "" тогда

                                               Список.Добавить(Число(Подстрока));

                                               Подстрока = "";

                               КонецЕсли;

                               Позиция = Позиция + 1;

                КонецЦикла;

                

                Если Список.Количество() < 3 тогда

                               Возврат Неопределено;

                КонецЕсли;

                

                Если ФорматДаты="дмг" тогда

                               День = Список[0]; Месяц = Список[1]; Год = Список[2];

                ИначеЕсли ФорматДаты="мдг" тогда

                               День = Список[1]; Месяц = Список[0]; Год = Список[2];

                ИначеЕсли ФорматДаты="гмд" тогда

                               День = Список[2]; Месяц = Список[1]; Год = Список[0];

                Иначе

                               День = 1; Месяц = 1; Год = 1;

                КонецЕсли;

                               

                Час = 0; Минута = 0; Секунда = 0;

                Если Список.Количество() >= 5 тогда

                               Час                        = Список[3];

                               Минута               = Список[4];

                               Секунда = ?(Список.Количество() >= 6, Список[5], 0);

                КонецЕсли;

                

                Попытка

                               Результат = Дата(Год, Месяц, День, Час, Минута, Секунда);

                Исключение

                               Возврат Неопределено;

                КонецПопытки;

                

                Возврат Результат;

                

КонецФункции

Категория: Работа с Датами (Временем)

Дополнение результата запроса Датами в Установленном ПЕРИОДЕ

Иногда возникает необходимость вывести в отчет информацию таким образом, чтобы некоторые итоговые значения были рассчитаны на каждую дату в заданном интервале с указанной периодичностью. Например, требуется получить обороты по неделям вне зависимости от того, были ли обороты в конкретную неделю или нет. Для решения подобной задачи в языке запросов предусмотрена конструкция ПЕРИОДАМИ. Данная конструкция указывается в предложении ИТОГИ после поля "Период". После ключевого слова ПЕРИОДАМИ в скобках указывается вид периода (одно из Секунда, Минута, Час, День, Неделя, Месяц, Квартал, Год, Декада, Полугодие), начальная и конечные даты интересуемого периода. В случае если начальные и конечные даты не указаны, будут использованы первая и последняя даты, участвующие в результате.

Пример:

Код 1C v 8.х

 ВЫБРАТЬ 

    УчетНоменклатурыОбороты.Период КАК Период,

    УчетНоменклатурыОбороты.КоличествоОборот КАК КоличествоОборот

ИЗ

    РегистрНакопления.УчетНоменклатуры.Обороты(, , Неделя, ) КАК УчетНоменклатурыОбороты 



УПОРЯДОЧИТЬ ПО 

    Период 



ИТОГИ СУММА(КоличествоОборот) ПО

    Период ПЕРИОДАМИ(НЕДЕЛЯ,,)

Результат данного запроса будет дополнен записями на даты начала каждой недели.

Заметим, что так как для дополненных периодов в результате запроса отсутствуют детальные записи, то дополненные записи будут получаться из выборки только в том случае, если при обходе выборки будут получаться все периоды, участвующие в запросе, что достигается установкой третьего параметра функции "Выбрать" результата запроса.

Пример:

Код 1C v 8.х

 ВыборкаПериод = Результат.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам, "Период", "ВСЕ"); 

Пока ВыборкаПериод.Следующий() Цикл 

    ОбластьПериод.Параметры.Заполнить(ВыборкаПериод); 

    ТабДок.Вывести(ОбластьПериод, ВыборкаПериод.Уровень()); 

КонецЦикла;

Категория: Запросы

Функция РАЗНОСТЬДАТ

РАЗНОСТЬДАТ(<Выражение>, <Выражение>, Секунда | Минута | Час | День | Месяц | Квартал | Год)
В качестве первого параметра передается выражение, значение которого необходимо вычесть из значения второго параметра.
В качестве второго параметра функции передается выражение, из которого необходимо вычесть значение первого параметра.
Третий параметр содержит единицу измерения, в которой необходимо получить результат функции. В качестве третьего параметра можно использовать следующие значения: Секунда, Минута, Час, День, Месяц, Квартал, Год. При расчете результата функция игнорирует единицы измерения, которые меньше, чем указанная в данном параметре единица.

Например, если в качестве третьего параметра указать Час, то при расчете результата будут игнорироваться минуты и секунды, присутствующие в первых двух параметрах. Если же в третьем параметре указать Месяц, то игнорироваться будут дни, часы, минуты и секунды.

Рассмотрим, какие значения будет возвращать функция при различных значениях третьего параметра:

Код 1C v 8.х

 

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 12, 31, 10, 20, 34), ДАТАВРЕМЯ(2003, 01, 01, 9, 18, 06), СЕКУНДА) // 82 652

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 12, 31, 10, 20, 34), ДАТАВРЕМЯ(2003, 01, 01, 9, 18, 06), МИНУТА) // 1 378

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 12, 31, 10, 20, 34), ДАТАВРЕМЯ(2003, 01, 01, 9, 18, 06), ЧАС) // 23

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 12, 31, 10, 20, 34), ДАТАВРЕМЯ(2003, 01, 01, 9, 18, 06), ДЕНЬ) // 1

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 12, 31, 10, 20, 34), ДАТАВРЕМЯ(2003, 01, 01, 9, 18, 06), МЕСЯЦ) // 1

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 12, 31, 10, 20, 34), ДАТАВРЕМЯ(2003, 01, 01, 9, 18, 06), КВАРТАЛ) // 1

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 12, 31, 10, 20, 34), ДАТАВРЕМЯ(2003, 01, 01, 9, 18, 06), ГОД) // 1

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 01, 01, 0, 0, 0), ДАТАВРЕМЯ(2002, 12, 31, 23, 59, 59), СЕКУНДА) // 31 535 999

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 01, 01, 0, 0, 0), ДАТАВРЕМЯ(2002, 12, 31, 23, 59, 59), МИНУТА) // 525 599

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 01, 01, 0, 0, 0), ДАТАВРЕМЯ(2002, 12, 31, 23, 59, 59), ЧАС) // 8 759

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 01, 01, 0, 0, 0), ДАТАВРЕМЯ(2002, 12, 31, 23, 59, 59), ДЕНЬ) // 364

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 01, 01, 0, 0, 0), ДАТАВРЕМЯ(2002, 12, 31, 23, 59, 59), МЕСЯЦ) // 11

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 01, 01, 0, 0, 0), ДАТАВРЕМЯ(2002, 12, 31, 23, 59, 59), КВАРТАЛ) // 3

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(2002, 01, 01, 0, 0, 0), ДАТАВРЕМЯ(2002, 12, 31, 23, 59, 59), ГОД) // 0

Категория: Запросы

Функции для работы с датами через запрос (Разность, Добавление, Граница)

Код 1C v 8.х

 // Получает разность календарных дат указанного вида. В случае ошибки возвращает -1

Функция ПолучитьРазностьДат(рНачДата,рКонДата,рВидРазности="ДЕНЬ") Экспорт

Если не ЗначениеЗаполнено(рНачДата) или не ЗначениеЗаполнено(рКонДата) Тогда Возврат -1 КонецЕсли;

Если рНачДата=рКонДата Тогда Возврат 0 КонецЕсли;

строСтандПер="СЕКУНДА МИНУТА ЧАС ДЕНЬ НЕДЕЛЯ ДЕКАДА МЕСЯЦ КВАРТАЛ ГОД";

Если Найти(строСтандПер,рВидРазности)=0 Тогда рВидРазности="ДЕНЬ" КонецЕсли;

тз="ВЫБРАТЬ РАЗНОСТЬДАТ(&НачДата,&КонДата,"+СокрЛП(рВидРазности)+")+1 КАК ПериодовВремени";

з=Новый Запрос(тз);

Если рВидРазности="СЕКУНДА" или рВидРазности="МИНУТА" или рВидРазности="ЧАС" Тогда

      // ставим, как есть, с учётом времени

      Если рНачДата>рКонДата Тогда // всё наоборот

            рПервая=рКонДата; рВторая=рНачДата; коэф=-1;

      Иначе

            рПервая=рНачДата; рВторая=рКонДата; коэф=1;

      КонецЕсли;       

Иначе

      // ставим от начала дня

      Если рНачДата>рКонДата Тогда // всё наоборот

            рПервая=НачалоДня(рКонДата); рВторая=НачалоДня(рНачДата); коэф=-1;

      Иначе

            рПервая=НачалоДня(рНачДата); рВторая=НачалоДня(рКонДата); коэф=1;

      КонецЕсли;       

КонецЕсли;



Попытка

      з.УстановитьПараметр("НачДата",рПервая);

      з.УстановитьПараметр("КонДата",рВторая);

      рРезультат=з.Выполнить().Выгрузить(ОбходРезультатаЗапроса.Прямой).Получить(0).ПериодовВремени;

      Если ТипЗнч(рРезультат)<>Тип("Число") Тогда Возврат -1 Иначе Возврат коэф*рРезультат КонецЕсли;

Исключение

      Возврат -1

КонецПопытки;

КонецФункции





Функция ДобавитьКДате(рДата,рРазность,рВидРазности="ДЕНЬ") Экспорт

Если рРазность=0 Тогда Возврат рДата КонецЕсли;

строСтандПер="СЕКУНДА МИНУТА ЧАС ДЕНЬ НЕДЕЛЯ ДЕКАДА МЕСЯЦ КВАРТАЛ ГОД";

Если Найти(строСтандПер,рВидРазности)=0 Тогда рВидРазности="ДЕНЬ" КонецЕсли;



тз="ВЫБРАТЬ ДОБАВИТЬКДАТЕ(&УслДата,"+СокрЛП(рВидРазности)+",&УслРазность) КАК РезДата";

з=Новый Запрос(тз);

з.УстановитьПараметр("УслДата",рДата);

з.УстановитьПараметр("УслРазность",рРазность);

рРезультат=з.Выполнить().Выгрузить(ОбходРезультатаЗапроса.Прямой).Получить(0).РезДата;

Если ТипЗнч(рРезультат)<>Тип("Дата") Тогда Возврат Дата(1,1,1) Иначе Возврат рРезультат КонецЕсли;

КонецФункции





Функция ГраницаПериода(рДата,рВидПериода="ДЕНЬ",рВидГраницы) Экспорт

строСтандПер="СЕКУНДА МИНУТА ЧАС ДЕНЬ НЕДЕЛЯ ДЕКАДА МЕСЯЦ КВАРТАЛ ГОД";

Если Найти(строСтандПер,рВидПериода)=0 Тогда рВидПериода="ДЕНЬ" КонецЕсли;

Если Найти(ВРег(рВидГраницы),"НАЧ")<>0 Тогда

      рГраница="НАЧАЛОПЕРИОДА";

ИначеЕсли Найти(ВРег(рВидГраницы),"КОН")<>0 Тогда

      рГраница="КОНЕЦПЕРИОДА";

Иначе

      Возврат рДата;

КонецЕсли;

тз="ВЫБРАТЬ "+рГраница+"(&УслДата,"+СокрЛП(рВидПериода)+") КАК РезДата";



з=Новый Запрос(тз);

з.УстановитьПараметр("УслДата",рДата);

рРезультат=з.Выполнить().Выгрузить(ОбходРезультатаЗапроса.Прямой).Получить(0).РезДата;



Если ТипЗнч(рРезультат)<>Тип("Дата") Тогда Возврат Дата(1,1,1) Иначе Возврат рРезультат КонецЕсли;

КонецФункции

Категория: Работа с Датами (Временем)

Как указать нужную,конкретную дату?

Значения данного типа содержит дату григорианского календаря (с 01 января 0001 года) и время с точностью до секунды.
Литералы:
Строка цифр, заключенная в одинарные кавычки вида: 'ГГГГММДДччммсс', где:
ГГГГ - четыре цифры года (включая тысячелетие и век);
ММ - две цифры месяца:
ДД - две цифры даты;
чч - две цифры часа (в 24-х часовом формате);
мм - две цифры минут;
сс - две цифры секунд;

Код 1C v 8.х

 '20050308' 

Дата(2005, 1, 1) 

Дата(1, 1, 1) 

Дата(2005, 1, 1, 10, 29, 50) 

ДАТАВРЕМЯ(2005, 01, 01)

В литерале типа Дата обязательно должно задаваться значение года, месяца и дня. Для задания даты соответствующей началу отсчета достаточно указать '00010101'.
Допускается при указании литералов типа Дата опускать последние символы (секунды, минуты, часы и т.д.). Это означает, что данные параметры будут равны нулю (для времени) или единице (для даты).
В литерале даты допускается использование различных разделителей:

Код 1C v 8.х

 Сообщить('20040814093941');

Сообщить('2004-08-14 09:39:41');

Код 1C v 8.х

 // Перевод Даты в Строку и Обратно

//ТекущаяДата() - 28.02.2010 23:58:59



//Переведем текущую дату в строку

СтрокаДата = Формат(ТекущаяДата(), "ггггММддЧЧммсс");  // Получаем:  20100228235859



//Переведем строку в дату

ТекДата = Дата(СтрокаДата); // Получаем:  28.02.2010 23:58:59

В языке ЗАПРОСов значения типа Дата задаются с помощью ключевого слова ДАТАВРЕМЯ, после которого в скобках последовательно указываются год, месяц, день, час, минута и секунда. Последние три указывать не обязательно:

Код 1C v 8.х

 ДАТАВРЕМЯ(2003, 10, 12, 10, 15, 34)

ДАТАВРЕМЯ(2003, 10, 12)

Код 1C v 7.x

 ДатаНачала = '01.01.2009';

//В условиях

Если РабочаяДата() > '31.12.2009' Тогда

   //...

КонецЕсли;

Категория: Работа с Датами (Временем)