модифицированность » Поиск

Результаты по ключевому слову: модифицированность

Как проверить записан ли документ?

Перед обработкой документа необходимо проверить - записан ли документ? если Да - обработать, нет -вывести предупреждение!

Ниже код позволяющий проверить записан ли только что созданные документ:

В Такси и вообще управляемом приложении проверяется ссылка: Объект.Ссылка.Пустая()

Код 1C v 8.3

 // в Управляемом приложении

&НаКлиенте

Процедура ОбработатьДок(Отказ)

         Если не ЗначениеЗаполнено(Объект.Ссылка) тогда

            Отказ=Истина; //Докум еще не записан, т.к. ссылки нет          

    КонецЕсли;

КонецПроцедуры

Код 1C v 8.х

 // В Обычных формах

Если ЭтоНовый() Тогда

Предупреждение("Документ должен быть записан!");

Иначе

// обрабатываем

КонецЕсли;

код, позволяющий проверить признак модифицированности ранее созданного документа:

Код 1C v 8.2 УП

 Если ЭтотОбъект.Модифицированность() Тогда

      

        Предупреждение("Документ был изменен. Для обработки его нужно записать.");

        Возврат Неопределено;     

      

    КонецЕсли;

Категория: Документы

Загрузка картинок в базу 1С (сохранение в хранилище значений)

В теме форма: v8: Получение данных из ХралищаЗначений

Bell в управляемом интерфейсе пробует сохранить выбранные картинки в базу 1С, но возникли сложности с сохранением в хранилище значений. как пример Bell приложил CF файл с мини конфигурацией, за что ему большое спасибо, т.к. большая часть материалов этой статьи написана им, я лишь поправил небольшие участки кода связанные с передачей файлов и сохранение в хранилище значений.

Так как везде уже Такси, то CF я перевел в этот режим и в нем демонстрирую.

Имеется справочник Хранилище данных:

Основная Форма Элемента:

Ее код:

Код 1C v 8.3

 // ПРОЦЕДУРЫ ФОРМЫ

//======================================================================================================

&НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

	

	Если Объект.Ссылка.Пустая() Тогда

			Объект.Наименование = ".";

	КонецЕсли;

		

	Если НЕ Параметры.Ключ.Пустая() Тогда

	   ДанныеАдрес = ПолучитьНавигационнуюСсылку(Объект.Ссылка, "ДанныеХЗ");

	КонецЕсли;

	

КонецПроцедуры

&НаКлиенте

Процедура ПриОткрытии(Отказ)

	

	Если Объект.Ссылка.Пустая() Тогда

	КонецЕсли;





КонецПроцедуры

&НаСервере

Процедура ПередЗаписьюНаСервере(Отказ, ТекущийОбъект, ПараметрыЗаписи)

	

	Если ЭтоАдресВременногоХранилища(ДанныеАдрес) Тогда

		

		РежимСжатия              = Новый СжатиеДанных(9);

		ДанныеСохранения         = ПолучитьИзВременногоХранилища(ДанныеАдрес);

		ТекущийОбъект.ДанныеХЗ   = Новый ХранилищеЗначения(ДанныеСохранения, РежимСжатия);

		

	КонецЕсли;

	

КонецПроцедуры

&НаСервере

Процедура ПриЗаписиНаСервере(Отказ, ТекущийОбъект, ПараметрыЗаписи)

	

	Если ЭтоАдресВременногоХранилища(ДанныеАдрес) Тогда

		УдалитьИзВременногоХранилища(ДанныеАдрес);

		ДанныеАдрес =  ПолучитьНавигационнуюСсылку(ТекущийОбъект.Ссылка, "ДанныеХЗ");

	КонецЕсли;





КонецПроцедуры





// ПРОЦЕДУРЫ ЭЛЕМЕНТОВ ФОРМЫ

//======================================================================================================





&НаКлиенте

Процедура ВыбратьДанные(Команда)

	

	ДанныеВыбрать();





КонецПроцедуры





&НаКлиенте

Процедура СохранитьДанные(Команда)

  	

	Если НЕ ЗначениеЗаполнено(Объект.Ссылка) Тогда

		Предупреждение(НСтр("ru = 'Элемент не записан !!!'"));

		Возврат;

	КонецЕсли;

	

	ДанныеСохранения = ПолучитьНавигационнуюСсылку(Объект.Ссылка, "ДанныеХЗ");

	ИмяСохранения    = Объект.Наименование; 

	//ИмяСохранения    = Объект.Наименование + Объект.ДанныеРасширение; 

    ПолучитьФайл(ДанныеСохранения, ИмяСохранения, Истина);

	

КонецПроцедуры





// ПРОЦЕДУРЫ ПРОЧИЕ

//======================================================================================================





&НаКлиенте

Процедура ДанныеВыбрать()

	

	ПолученныеДанныеАдрес = "";

	Если ПоместитьФайл(ПолученныеДанныеАдрес, , Объект.ДанныеПуть, Истина, УникальныйИдентификатор)Тогда

		

		ДанныеАдрес = ПолученныеДанныеАдрес;

		

		ВыбранныйФайл = Новый Файл(Объект.ДанныеПуть);

		Объект.Наименование          =  ВыбранныйФайл.Имя;

		Объект.ДанныеТекущаяДата     =  ТекущаяДата();

		

		Модифицированность = Истина; 		

	КонецЕсли;

 	

КонецПроцедуры

так же имеется общая форма ФормаЗагрузкиФайлов

При помощи ее выбираются файлы изображений и загружаются в справочник - одновременно можно загружать несколько файлов

код формы:

Код 1C v 8.3

 // ПРОЦЕДУРЫ ЭЛЕМЕНТОВ ФОРМЫ

//======================================================================================================

&НаКлиенте

Процедура СписокФайловПередНачаломДобавления(Элемент, Отказ, Копирование, Родитель, Группа)

	

	Отказ = Истина;

	

	ДобавитьФайлы();





КонецПроцедуры



// ПРОЦЕДУРЫ ПРОЧИЕ

//======================================================================================================

&НаКлиенте

Процедура ДобавитьФайлы()

	

	ВыборФайла = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);

	ВыборФайла.МножественныйВыбор = Истина;

	ВыборФайла.Заголовок = НСтр("ru = 'Выбор файла'", "ru");

	ВыборФайла.Фильтр = НСтр("ru = 'Все файлы'", "ru") + " (*.*)|*.*";

	ВыборФайла.ПредварительныйПросмотр = Истина;

	Если ВыборФайла.Выбрать() Тогда

		

		Для каждого СтрокаФайл Из ВыборФайла.ВыбранныеФайлы Цикл

			

			ОписаниеФайла = Новый Файл(СтрокаФайл);

			

			НВС = СписокФайлов.Добавить();

			НВС.ПолноеИмяФайла   = СтрокаФайл; 

			НВС.РазмерФайла      = ОписаниеФайла.Размер();

			

		КонецЦикла;

		

	КонецЕсли;

		

КонецПроцедуры

&НаКлиенте

Процедура Загрузить()

	

	Если НЕ ПроверитьЗаполнение() Тогда

		Возврат;

	КонецЕсли;

	

	ОчиститьСообщения();

	Если СписокФайлов.Количество() = 0 Тогда

		Сообщить("Файлы не выбраны !!!'");

		Возврат;

	КонецЕсли;

	

	ПомещаемыеФайлы = Новый Массив;

	Для каждого СтрокаФайл Из СписокФайлов Цикл

		Описание = Новый ОписаниеПередаваемогоФайла(СтрокаФайл.ПолноеИмяФайла, "");

		ПомещаемыеФайлы.Добавить(Описание);

	КонецЦикла;

	

	// -------------------------------------------------------------------------------

	ПомещенныеФайлы         = Новый Массив;

	СписокЗагруженныхФайлов = Новый СписокЗначений;

	

	Если ПоместитьФайлы(ПомещаемыеФайлы, ПомещенныеФайлы, , Ложь, УникальныйИдентификатор) Тогда

		

		Закрыть(Истина);

		

	Иначе

		

		Сообщение = Новый СообщениеПользователю();

		Сообщение.Текст = НСтр("ru = 'Файлы не загружены'", "ru");

		Сообщение.Сообщить();

		

	КонецЕсли;





	ОповеститьОВыборе(ПомещенныеФайлы);





КонецПроцедуры

&НаСервере

Функция ПоместитьВыбранныеФайлыВХранилище(ПомещаемыеФайлы)

	

	АдресХЗ = ПоместитьВоВременноеХранилище(ПомещаемыеФайлы, УникальныйИдентификатор);

	Возврат АдресХЗ;

КонецФункции

в коде вызывается ОповеститьОВыборе(ПомещенныеФайлы) и срабатывает обработчик в ФормаСпискаДополнительно

Код 1C v 8.3

 &НаКлиенте

Процедура ОбработкаВыбора(ВыбранноеЗначение, ИсточникВыбора)

	

	Если ИсточникВыбора.ИмяФормы = "ОбщаяФорма.ФормаЗагрузкиФайлов" Тогда

		ОбработкаВыбораПодборНаСервере(ВыбранноеЗначение);

	КонецЕсли;

	

КонецПроцедуры

и следующим кодом идет создание элементов справочника и загрузка изображений из временного хранилища

Код 1C v 8.3

 &НаСервере

Процедура ОбработкаВыбораПодборНаСервере(ВыбранноеЗначение)

	

	Для Каждого СтрокаФайл Из ВыбранноеЗначение Цикл 		

		Файл = Новый Файл(СтрокаФайл.Имя);

		ХранимыйФайл = Справочники.ХранилищеДанныхСправочники.СоздатьЭлемент();

		ХранимыйФайл.Наименование                      = Файл.Имя;

		ХранимыйФайл.ДанныеПуть                        = Файл.Путь;

		ХранимыйФайл.ДанныеТекущаяДата                 = ТекущаяДата();

		ХранимыйФайл.ДанныеХЗ = Новый ХранилищеЗначения(ПолучитьИзВременногоХранилища(СтрокаФайл.Хранение), Новый СжатиеДанных());

 		ХранимыйФайл.Записать();

	КонецЦикла;

	

	Элементы.Список.Обновить();

	

КонецПроцедуры

Скачать DT - Платформа 8.3.4

Категория: Работа с Хранилищем Значений

Как добавить подписи в отчет СКД?

Во многих организациях сформированные отчеты заверяют подписями.
В данном примере я покажу как можно вывести подписи для типового отчета ЗУП Свод начислений.
Для начала создадим макет в котором и разместим подписи, макет я создам общий, т.к. он будет использоваться и в других отчетах.
Макет такой:
title

Открываем Отчет СводНачисленнойЗарплатыОрганизаций, открываем Форму и ищем процедуру ОбновитьОтчет()
После

Код 1C v 8.х

 СформироватьОтчет(ЭлементыФормы.Результат, ДанныеРасшифровки);

добавляем вывод подписей

Код 1C v 8.х

 Макет = ПолучитьОбщийМакет("МакетПодписи");

ОбластьВывести = Макет.ПолучитьОбласть("Подпись");

ЭлементыФормы.Результат.Вывести(ОбластьВывести);

Полный код процедуры ОбновитьОтчет()

Код 1C v 8.х

 Процедура ОбновитьОтчет() Экспорт

СостояниеМодифицированности = Модифицированность;

Если ПанельНастроекНарисована <> Истина Тогда

ОбновлениеОтображения();

КонецЕсли;

ТиповыеОтчеты.ЗагрузитьВРеквизитЗначенияНастроекПанелиПользователя(ЭтотОбъект, ЭтаФорма);

ПараметрыПанели = ТиповыеОтчеты.ПолучитьПараметрыПанелиПользователяОбъекта(ОтчетОбъект);

ЗначенияНастроек = ТиповыеОтчеты.ПолучитьЗначенияНастроекПанелиПользователяОбъекта(ОтчетОбъект);

Отказ = ложь;

ТиповыеОтчеты.ПроверитьЗначенияПараметров(ЗначенияНастроек, ПараметрыПанели, Отказ);

Если Отказ тогда

Возврат;

КонецЕсли;

РежимформированияОтчета = НЕ ЭтоОтработкаРасшифровки;

СформироватьОтчет(ЭлементыФормы.Результат, ДанныеРасшифровки);

//Мигачев - Вывод подписей

Макет = ПолучитьОбщийМакет("МакетПодписи");

ОбластьВывести = Макет.ПолучитьОбласть("Подпись");

// Если надо вывести параметр

//ОбластьВывести.Параметры.Подписант = Бухгалтер;

ЭлементыФормы.Результат.Вывести(ОбластьВывести);

//*//

УправлениеОтчетами.УстановитьКолонтитулыПоУмолчанию(ЭлементыФормы.Результат, Заголовок, Строка(ПараметрыСеанса.ТекущийПользователь));

Модифицированность = СостояниеМодифицированности;

КонецПроцедуры

Категория: Схема Компоновки Данных

Как снять признак модифицированности?

Код 1C v 8.х

 Процедура НапечатанПриИзменении(Элемент)

	Если Напечатан Тогда

		КогдаНапечатан = ТекущаяДата();

	Иначе

		КогдаНапечатан = Дата(1,1,1);

	КонецЕсли;

	Если Модифицированность() Тогда

		УстановитьПривилегированныйРежим(Истина);

		ЭтотОбъект.Записать();

		ЭтаФорма.Модифицированность=Ложь; //сбросили модифицированность 

		УстановитьПривилегированныйРежим(Ложь);

	КонецЕсли;	

КонецПроцедуры

Категория: Работа с Формой (Диалог) и её элементами

Форма при закрытии просит сохранить изменения. Как закрыть без сохранения?

Код 1C v 8.х

  //Можно создать свою кнопку и действие к ней

Процедура ЗакрытьНеСохраняя(Кнопка)

	ЭтаФорма.Модифицированность = Ложь;

 	ЭтаФорма.Закрыть();

КонецПроцедуры



// или в ПередЗаписью

Процедура ПередЗаписью(Отказ, ПараметрыЗаписи) 

 

ЭтаФорма.Модифицированность=Ложь; //сбросили модифицированность 

ЭтаФорма.Закрыть(); // закрыли 



КонецПроцедуры

Модифицированность (Modified)
Использование: Чтение и запись.
Описание: Тип: Булево. Признак изменения (модифицированности) данных в форме.
Модифицированность отображается символом (*) в заголовке окна формы.
Истина - изменена.

Категория: Работа с Формой (Диалог) и её элементами

Восстановление партионного учета в УТ

Проблема следующая:
при выполнении стандартной обработки "проведение по партиям", непонятно почему, но граница актуальности партионного учета не сдвигается, хотя при перепроведении документов никаких ошибок не возникает.

Оказывается:
дата границы последовательности партионного учета, и документа, который установил эту границу не всега совпадают ). Ну понятно, что при перепроведении документа ГП никуда не двинеться.
Перед проведением по партиям добавил следующий код, для исправления таких ошибок, можь пригодиться кому...

Код 1C v 8.х

 Процедура ОчиститьОшибкиГраницыПоследовательности()

Запрос=Новый ЗАпрос;

Запрос.Текст=

"ВЫБРАТЬ

| ВложенныйЗапрос.Регистратор,

| ВложенныйЗапрос.Период,

| ВложенныйЗапрос.РегистраторДата,

| ВложенныйЗапрос.ЕстьДвижения

|ИЗ

| (ВЫБРАТЬ

| Последовательность.Регистратор КАК Регистратор,

| ПРЕДСТАВЛЕНИЕ(Последовательность.Регистратор) КАК РегистраторПредставление,

| Последовательность.Период КАК Период,

| ВЫБОР

| КОГДА СписанныеТоварыСрезПоследних.Регистратор ЕСТЬ NULL

| И РегистрНакопленияПартииТоваровНаСкладах.Регистратор ЕСТЬ NULL

| И РегистрНакопленияПартииТоваровПереданные.Регистратор ЕСТЬ NULL

| ТОГДА ЛОЖЬ

| ИНАЧЕ ИСТИНА

| КОНЕЦ КАК ЕстьДвижения,

| Последовательность.Регистратор.Дата КАК РегистраторДата

| ИЗ

| Последовательность.ПартионныйУчет КАК Последовательность

| ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.СписанныеТовары КАК СписанныеТоварыСрезПоследних

| ПО Последовательность.Регистратор = СписанныеТоварыСрезПоследних.Регистратор

| И (СписанныеТоварыСрезПоследних.НомерСтроки = 1)

| ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ПартииТоваровНаСкладах.Обороты(, , Регистратор, ) КАК РегистрНакопленияПартииТоваровНаСкладах

| ПО Последовательность.Регистратор = РегистрНакопленияПартииТоваровНаСкладах.Регистратор

| ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ПартииТоваровПереданные.Обороты(, , Регистратор, ) КАК РегистрНакопленияПартииТоваровПереданные

| ПО Последовательность.Регистратор = РегистрНакопленияПартииТоваровПереданные.Регистратор) КАК ВложенныйЗапрос

|ГДЕ

| (ВложенныйЗапрос.Период <> ВложенныйЗапрос.РегистраторДата

| ИЛИ (НЕ ВложенныйЗапрос.ЕстьДвижения))";

Выборка=Запрос.Выполнить().Выбрать();

Всего=Выборка.Количество();

Тек=0;

Пока Выборка.Следующий() Цикл

Тек=Тек+1;

Состояние(""+Тек+" из "+Всего);

ОбработкаПрерыванияПользователя();

  Если НЕ Выборка.Регистратор.Проведен Тогда

   НаборЗаписей = Последовательности.ПартионныйУчет.СоздатьНаборЗаписей();

   НаборЗаписей.Отбор.Регистратор.Установить(Выборка.Регистратор);

   НаборЗаписей.Записать();

  КонецЕсли;

  НаборЗаписей = Последовательности.ПартионныйУчет.СоздатьНаборЗаписей();

  НаборЗаписей.Отбор.Регистратор.Установить(Выборка.Регистратор);

  НаборЗаписей.Прочитать();

  Для Каждого СтрокаНабора Из НаборЗаписей Цикл

   СтрокаНабора.Период = Выборка.Регистратор.Дата;

  КонецЦикла;

  Если НаборЗаписей.Модифицированность() Тогда

   НаборЗаписей.Записать();

  КонецЕсли;



  Если (НЕ Выборка.ЕстьДвижения)Тогда

   НаборЗаписей = Последовательности.ПартионныйУчет.СоздатьНаборЗаписей();

   НаборЗаписей.Отбор.Регистратор.Установить(Выборка.Регистратор);

   НаборЗаписей.Записать();

  КонецЕсли;

КонецЦикла;

КонецПроцедуры

Категория: 1С Управление торговлей 10.3

Табличное поле ~ Дополнительная вычисляемая или текстовая колонка в табличной части, списке, журнале

Как добавить дополнительную колонку в табличном поле?
Добавляете колонку, а все вычисления реализуются с помощью события ПриВыводеСтроки табличного поля:

Код 1C v 8.х

 // 1-й вариант:

Процедура НоменклатураПриВыводеСтроки(Элемент, ОформлениеСтроки, ДанныеСтроки)

   СамаЯчейка = ОформлениеСтроки.Ячейки.ИмяЯчейки;

   СамаЯчейка.ОтображатьТекст = Истина;

   СамаЯчейка.Текст = "Лалала";

КонецПроцедуры



// 2-й вариант:

Процедура НоменклатураПриВыводеСтроки(Элемент, ОформлениеСтроки, ДанныеСтроки)

   ОформлениеСтроки.Ячейки.ИмяЯчейки.УстановитьТекст("Лалала");

КонецПроцедуры



// 3-й вариант:

Процедура НоменклатураПриПолученииДанных(Элемент, ОформленияСтрок)

   Для каждого ОформлениеСтроки Из ОформленияСтрок Цикл

    СамаЯчейка = ОформлениеСтроки.Ячейки.ИмяЯчейки;

    СамаЯчейка.ОтображатьТекст = Истина;

    СамаЯчейка.Текст = "Лалала";

   КонецЦикла;

КонецПроцедуры

С помощью этого события можно выводить не только текст, но также флажки и картинки, например:
Картинка:

Код 1C v 8.х

 Ячейка = ОформлениеСтроки.Ячейки.ТипСобытия;

Ячейка.ОтображатьТекст    = Ложь;

Ячейка.ОтображатьФлажок   = Ложь;

Ячейка.ОтображатьКартинку = Истина;

Ячейка.ИндексКартинки = 1; 



// или другой пример:

ТЗ=Новый ТаблицаЗначений;

ТЗ.Колонки.Добавить("ПометкаУдаления",,"ПометкаУдаления");

ТЗ.Колонки.Добавить("Проведен",,"Проведен");

    

КолонкаКартинки=ЭлементыФормы.ТЗ.Колонки.Вставить(0,"<");

КолонкаКартинки.Имя="Картинка";

КолонкаКартинки.Ширина=5;

КолонкаКартинки.ДанныеКартинки="ИндексКартинки";

КолонкаКартинки.КартинкиСтрок= БиблиотекаКартинок.СостоянияДокумента;



Процедура ТЗПриВыводеСтроки(Элемент, ОформлениеСтроки, ДанныеСтроки)

Если ДанныеСтроки.Проведен Тогда

  ОформлениеСтроки.Ячейки.Картинка.ИндексКартинки=0;

ИначеЕсли НЕ ДанныеСтроки.Проведен Тогда

  ОформлениеСтроки.Ячейки.Картинка.ИндексКартинки=2;

ИначеЕсли ДанныеСтроки.ПометкаУдаления Тогда

  ОформлениеСтроки.Ячейки.Картинка.ИндексКартинки=1;

КонецЕсли;

Флажки:

Код 1C v 8.х

 ОформлениеСтроки.Ячейки.Колонка2.ОтображатьФлажок= Истина;

ОформлениеСтроки.Ячейки.Колонка2.УстановитьТекст("");

ОформлениеСтроки.Ячейки.Колонка2.Флажок = Истина;

Еще можно менять цвет фона и текста, шрифт и другие характеристики оформления:

Код 1C v 8.х

 ОформлениеСтроки.Ячейки.<ИмяКолонки>.ЦветФона = Новый Цвет (255,100,100);

ОформлениеСтроки.Ячейки.<ИмяКолонки>.Шрифт = Новый Шрифт(,,Истина);

Можно также управлять доступностью отдельных строк и ячеек табличного поля:

Код 1C v 8.х

 ОформлениеСтроки.Ячейки.Назв.ТолькоПросмотр = Истина;

Обычно колонка должна быть рассчитываемой, или зависимой от данных, поэтому нужно задействовать второй параметр ДанныеСтроки. Этот механизм можно использовать для отображения остатков товаров в форме подбора, текущих цен, долга контрагента, другой информации по строкам.

Но здесь нужно быть осторожным! Событие ПриВыводеСтроки вызывается довольно часто при перерисовке табличного поля. Поэтому процедура должна отрабатывать довольно быстро, чтобы не тормозить вывод списка. Если в ней происходит обращение к базе данных, то вывод может резко замедлиться.

Если начались тормоза, то рекомендуется сделать следующее:
1. Кеширование результата запроса в переменной модуля формы (таблица значений или массив, еще можно использовать соответствие, которое индексируется для примитивных типов данных, например, код товара или артикул)
2. При отключенной колонке (видимость) запрос к базе НЕ должен выполняться.
По умолчанию колонку держать выключенной, включение только по кнопке в форме или при личных настройках определенного пользователя.
3. Лучше выполнять один большой запрос на несколько товаров, чем несколько маленьких запросов на один товар.
4. Список товаров нужно передавать как ПАРАМЕТР виртуальной таблицы Остатки, а не как параметр условия ГДЕ.
5. При повышенных требованиях к скорости отображения списка и большом количестве пользователей можно завести регистр сведений, хранящий актуальные остатки. Для поддержки его актуальности можно создать последовательность.
6. Еще вариант через обработчик - при ПолученииДанных (вроде так называется)... Там сразу передается массив ОформленияСтрок - в нем все строки сразу и вызывается он реже, чем при выводе строки...
7. Завести в табличной части реквизит, куда при открытии формы и по мере надобности помещать остатки, это значительно ускорит вывод остатков, правда будет не лучшим образом влиять на флаг Модифицированность.

Источник.

Категория: Работа с Формой (Диалог) и её элементами

Функция разбора (разложения) строки в массив

Данные функции позволяют разложить строку в массив, используя заданный разделитель
Например есть строка: абв$dfd$232$-0oj$5
Выполнив код: НашМассив = РазложитьСтрокуВМассив(абв$dfd$232$-0oj$5, "$") ;
Получим: НашМассив = абв
dfd
232
-0oj
5

Код 1C v 8.х

 

// Функция "расщепляет" строку на подстроки, используя заданный 

//		разделитель. Разделитель может иметь любую длину. 

//		Если в качестве разделителя задан пробел, рядом стоящие пробелы 

//		считаются одним разделителем, а ведущие и хвостовые пробелы параметра Стр

//		игнорируются.

//		Например, 

//		РазложитьСтрокуВМассивПодстрок(",ку,,,му", ",") возвратит массив значений из пяти элементов, 

//		три из которых - пустые строки, а 

//		РазложитьСтрокуВМассивПодстрок(" ку   му", " ") возвратит массив значений из двух элементов

//

//	Параметры: 

//		Стр - строка, которую необходимо разложить на подстроки. 

//		Разделитель - 	строка-разделитель, по умолчанию - запятая.

//

//	Возвращаемое значение:

//		массив значений, элементы которого - подстроки

//

Функция РазложитьСтрокуВМассив(Знач Стр, Разделитель = ",") Экспорт

	

	МассивСтрок = Новый Массив();

	Если Разделитель = " " Тогда

		Стр = СокрЛП(Стр);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = СокрЛ(Сред(Стр,Поз));

		КонецЦикла;

	Иначе

		ДлинаРазделителя = СтрДлина(Разделитель);

		Пока 1=1 Цикл

			Поз = Найти(Стр,Разделитель);

			Если Поз=0 Тогда

				МассивСтрок.Добавить(Стр);

				Возврат МассивСтрок;

			КонецЕсли;

			МассивСтрок.Добавить(Лев(Стр,Поз-1));

			Стр = Сред(Стр,Поз+ДлинаРазделителя);

		КонецЦикла;

	КонецЕсли;

	

КонецФункции

Пример с использованием предустановленной библиотеки RegExp, т.е. она есть в любом windows.
Плюсы RegExp:
1. Хорошая скорость анализа, т.к. 1С анализ строк (разбор) обычно реализуется циклами и функциями: Лев, Прав, Сред, Найти, а встроенный язык медленный
2. Высокая читаемость и модифицированность (более предсказуем в случае несоответствия строки - разбору)
3. Дополнительный функционал (можно осуществлять анализ, замену и проверку строковых выражений)

Минусы RegExp:
1. Не все задачи можно решить (например рекурсивные разборы тип 1 + (2+3*(2-7)) в случае если нужно разобрать на выражения в скобках) приходится смешивать с кодом.
2. Возможность зависания при использовании сложных шаблонов(редкость, но бывает).
3. RegExp - это дополнительная библиотека и инициализация занимает значительное время.

Код 1C v 8.х

  // Пример с использованием предустановленной библиотеки RegExp, т.е. она есть в любом windows.

Функция РазложитьСтрокуВМассив(Строка, Разделитель = ",") Экспорт

	RegExp = Новый COMОбъект("VBScript.RegExp");    // создаем объект для работы с регулярными выражениями

	

	//Параметры:

	RegExp.MultiLine = Ложь;  // истина — текст многострочный, ложь — одна строка

	RegExp.Global = Истина;   // истина — поиск по всей строке, ложь — до первого совпадения

	RegExp.IgnoreCase = Ложь; // истина — игнорировать регистр строки при поиске

	

	//Разбор строки вида 1,СЛОВО,(1+2); Маска для разделителя ',' [^\,]*"

	RegExp.Pattern = "[^\" + Разделитель + "]+";

	Matches = RegExp.Execute (Строка);

	

	Массив = Новый Массив;

	

	Для Сч = 0 По Matches.Count - 1 Цикл

		Массив.Добавить(Matches.Item(Сч).Value);

	КонецЦикла;

	

	RegExp = Неопределено;

	

	Возврат Массив;

КонецФункции

Посмотрите Функцию разложить строку на подстроки (в список значений), используя заданный разделитель.

Категория: Работа с Текстом (Строкой)

Был ли изменен элемент справочника?

Код 1C v 8.х

  // Модифицированность()  - Определяет, был ли изменен объект после считывания из базы данных. 

// НО Метод не позволяет определить, был ли изменен объект другими пользователями. 

Если Модифицированность() тогда

 Сообщить("Этот элемент справочника был изменен!");

КонецЕсли;

Категория: Справочники

Был ли изменен документ?

Код 1C v 8.х

 

// Модифицированность()  - Определяет, был ли изменен объект после считывания из базы данных. 

// НО Метод не позволяет определить, был ли изменен объект другими пользователями. 

 Если Модифицированность() тогда

	 Сообщить("Документ был изменен!");

КонецЕсли;

Категория: Документы