Перем Л_Лев_Фиг_Скобка, Л_Прав_Фиг_Скобка, Л_Лев_Кв_Скобка, Л_Прав_Кв_Скобка, Л_Кавычка, Л_Экран, Л_Двоеточие, Л_Запятая, Л_Число, Л_Строка, Л_Константа, Л_Финиш;

Перем Цифры1_9, Цифры0_9, ПервыеСимволыКонстант, ОдносимвольныеЛексемы;

Перем НомЛексемы, ТекЛексема;

Перем JSON_Error;

Перем В_Массив, В_Объект, В_Значение;

//*****

Перем НомерСимвола;

Перем ФлагОшибки;

Перем СписокСтроковыхКонстант;

Перем СтекЛексем;

Перем АнализируемаяСтрока;

//*****

Перем ТекКаталог, ТекФайл;

//*****

Функция ПолучитьОбъект_ТЗ() Далее

Функция ПолучитьМассив_ТЗ() Далее

//*****

Функция ТекущиеСимволы(Сколько)

	Возврат Сред(АнализируемаяСтрока, НомерСимвола, Сколько);

КонецФункции

//*****

Функция ПрошлыйСимвол(Сдвиг)

	Возврат Сред(АнализируемаяСтрока, НомерСимвола - Сдвиг, 1);

КонецФункции

//*****

Процедура ДобавитьЛексему(Лексема, Значение, Сдвиг)

	СтекЛексем.НоваяСтрока();

	СтекЛексем.Лексема	= Лексема;

	СтекЛексем.Значение	= Значение;	

	НомерСимвола		= НомерСимвола + Сдвиг;

КонецПроцедуры

//*****

Процедура ОбвестиОбласть(Обл)

	Обл.РамкаСнизу(1);

	Обл.РамкаСверху(1);

	Обл.РамкаСлева(1);

	Обл.РамкаСправа(1);

КонецПроцедуры

//*****

Процедура НапечататьТЗ(Таб, ТЗ, НомС, НомК)

Перем Тип, Обл1, НС, КС, Ключ, Зн, Обл2;

	Тип = ТЗ.ПолучитьЗначение(1, 1);

	НомС = НомС + 1;

	Обл1 = Таб.Область(НомС, НомК);

	ОбвестиОбласть(Обл1);

	Если Тип = В_Значение Тогда

		ТипЗн = ТЗ.ПолучитьЗначение(2, 1);

		Обл1.Текст = ТЗ.ПолучитьЗначение(2, 2);

		Обл1.ГоризонтальноеПоложение(1);

		Если ТипЗн = Л_Число Тогда

			Обл1.ГоризонтальноеПоложение(2);

		ИначеЕсли ТипЗн = Л_Константа Тогда

			Обл1.Полужирный(1);

		ИначеЕсли ТипЗн = Л_Строка Тогда

			Обл1.Контроль(4);

		КонецЕсли;

		Возврат;

	ИначеЕсли (Тип = В_Объект) Или (Тип = В_Массив) Тогда

		Обл1.Текст = Тип;

		Обл1.Полужирный(1);

		Обл1.ЦветФона(12648447);

		Обл1.РамкаСнизу(5);

		КС = ТЗ.КоличествоСтрок();

		Для НС = 2 По КС Цикл

			НомС = НомС + 1;

			Обл2 = Таб.Область(НомС, НомК);

			Обл2.Текст = ТЗ.ПолучитьЗначение(НС, 1);

			Если Тип = В_Массив Тогда

				Обл2.ГоризонтальноеПоложение(2);

			КонецЕсли;

			ОбвестиОбласть(Обл2);

			НомС = НомС - 1;

			НапечататьТЗ(Таб, ТЗ.ПолучитьЗначение(НС, 2), НомС, НомК + 1);

		КонецЦикла;

	Иначе

		Сообщить("Фигня " + Тип, "!");

	КонецЕсли;

КонецПроцедуры

//*****

Процедура ВыравнятьТЗ(Таб, ОграничениеШирины)

Перем НомерКол, НомерСтр, МаксШирина, Обл, ТекШирина, ТекДлина;

	Для НомерКол = 1 По Таб.ШиринаТаблицы() Цикл

		МаксШирина = 0;

		Для НомерСтр = 1 По Таб.ВысотаТаблицы() Цикл

			Обл = Таб.Область(НомерСтр, НомерКол);

			ТекШирина = Обл.ШиринаСтолбца();

			ТекДлина = СтрДлина(СокрЛП(Обл.Текст));

			МаксШирина = Макс(МаксШирина, ТекШирина, ТекДлина);

		КонецЦикла;

		Таб.Область(, НомерКол).ШиринаСтолбца(Мин(МаксШирина, ОграничениеШирины));

	КонецЦикла;

КонецПроцедуры

//*****

Процедура Напечатать_ТЗ(ТЗ)

Перем Таб, НС, НК, МаксШирина, ТекДлина, Обл;	

	Таб = СоздатьОбъект("Таблица");

	МаксНК = 1;

	НС = 0;

	НК = 1;

	НапечататьТЗ(Таб, ТЗ, НС, НК);

	ВыравнятьТЗ(Таб, 30);

	Таб.Область(1, 1, Таб.ВысотаТаблицы(), Таб.ШиринаТаблицы()).ВертикальноеПоложение(2);

	Таб.Опции(0, 0);

	Таб.Показать("JSON");

КонецПроцедуры

//*****

Функция Ошибка()

	ФлагОшибки = 1;

	Возврат 0;

КонецФункции

//*****

Функция ЧитатьКонстанту(ПервСимвол)

Перем КонстантаСтр, ДлинаКонстанты;	

	КонстантаСтр = СписокСтроковыхКонстант.Получить(ПервСимвол);

	ДлинаКонстанты = СтрДлина(КонстантаСтр);

	Если ТекущиеСимволы(ДлинаКонстанты) = КонстантаСтр Тогда

		ДобавитьЛексему(Л_Константа, КонстантаСтр, ДлинаКонстанты);

		Возврат 1;

	Иначе

		Возврат Ошибка();

	КонецЕсли;

КонецФункции

//*****

Процедура ДописатьСимвол(Стр)

	Стр = Стр + ТекущиеСимволы(1);

	НомерСимвола = НомерСимвола + 1;

КонецПроцедуры

//*****

Функция ЧитатьЧисло() 

Перем ЧислоСтр;

	ЧислоСтр = "";

	Если ТекущиеСимволы(1) = "-" Тогда

		ДописатьСимвол(ЧислоСтр);

	КонецЕсли;

	Если Найти(Цифры1_9, ТекущиеСимволы(1)) > 0 Тогда // не с нуля

		ДописатьСимвол(ЧислоСтр);

		Пока Найти(Цифры0_9, ТекущиеСимволы(1)) > 0 Цикл  // любые цыфры 

			ДописатьСимвол(ЧислоСтр);

		КонецЦикла;		

	ИначеЕсли ТекущиеСимволы(1) = "0" Тогда //с нуля - ничего дальше 

		ДописатьСимвол(ЧислоСтр);

	Иначе

		Возврат Ошибка();

	КонецЕсли;

	Если ТекущиеСимволы(1) = "." Тогда // десятичная точка

		ДописатьСимвол(ЧислоСтр);

		Пока Найти(Цифры0_9, ТекущиеСимволы(1)) > 0 Цикл  // любые цыфры

			ДописатьСимвол(ЧислоСтр);

		КонецЦикла;		

	КонецЕсли;

	Если ВРег(ТекущиеСимволы(1)) = "E" Тогда // значок e больное или маленькое

		ДописатьСимвол(ЧислоСтр);

		Если Найти("+-", ТекущиеСимволы(1)) > 0 Тогда  // унарный знак для порядка

			ДописатьСимвол(ЧислоСтр);

		КонецЕсли;

		Пока Найти(Цифры0_9, ТекущиеСимволы(1)) > 0 Цикл  // любые цыфры

			ДописатьСимвол(ЧислоСтр);

		КонецЦикла;		

	КонецЕсли;

	ДобавитьЛексему(Л_Число, ЧислоСтр, 0);

	Возврат 1;

КонецФункции

//*****

Функция ЧитатьСтроку()

Перем СтрокаСтр;

	СтрокаСтр = "";

	НомерСимвола = НомерСимвола + 1;

	Пока (ТекущиеСимволы(1) <> Л_Кавычка) Или ((ТекущиеСимволы(1) = Л_Кавычка) И (ПрошлыйСимвол(1) = Л_Экран) И (ПрошлыйСимвол(2) <> Л_Экран)) Цикл

		ДописатьСимвол(СтрокаСтр);

	КонецЦикла;

	ДобавитьЛексему(Л_Строка, СтрокаСтр, 1); 

	Возврат 1;

КонецФункции 

//*****

Функция ПрочитатьФайл(ИмяФайла)

Перем Т, НомерСтрокиФайла, СтрокаРез;

	Т = СоздатьОбъект("Текст");

	Т.Открыть(ИмяФайла);

	СтрокаРез = "";

	Для НомерСтрокиФайла = 1 По Т.КоличествоСтрок() Цикл

		СтрокаРез = СтрокаРез + Т.ПолучитьСтроку(НомерСтрокиФайла);

	КонецЦикла;

	Возврат СтрокаРез;

КонецФункции

//*****

Функция СледующаяЛексема()

	НомЛексемы = НомЛексемы + 1;

	СтекЛексем.ПолучитьСтрокуПоНомеру(НомЛексемы);

	ТекЛексема = СтекЛексем.Лексема;

	Возврат 1;

КонецФункции

//*****

Функция ОшибкаЛексемы()

Перем РезСтр, НомСтр, ТЛ, ТС;

	Сообщить("Ошибочная лексема № " + НомЛексемы + " : <" + ТекЛексема + ">", "!");

	РезСтр = "";

	Для НомСтр = НомЛексемы + 1 По СтекЛексем.КоличествоСтрок() Цикл

		СтекЛексем.ПолучитьСтрокуПоНомеру(НомСтр);

		ТЛ = СтекЛексем.Лексема;

		Если ТЛ = Л_Строка Тогда 

			ТС = "<" + ТЛ + "(" + СтекЛексем.Значение + ")>";

		ИначеЕсли ТЛ = Л_Константа Тогда

			ТС = "<" + ТЛ + "(" + СтекЛексем.Значение + ")>";

		Иначе

			ТС = "<" + ТЛ + ">";

		КонецЕсли;

		РезСтр = РезСтр + ТС + ",";

	КонецЦикла;

	Сообщить(Лев(РезСтр, 400), "!");

	Возврат 0;

КонецФункции

//*****

Процедура ДобавитьПару(ТЗ, Ключ, Значение)

	ТЗ.НоваяСтрока();

	ТЗ.Ключ		= Ключ;

	ТЗ.Значение	= Значение;

КонецПроцедуры

//*****

Функция НоваяТЗ(Тип)

Перем _ТЗ;

	_ТЗ = СоздатьОбъект("ТаблицаЗначений");

	_ТЗ.НоваяКолонка("Ключ");

	_ТЗ.НоваяКолонка("Значение");

	ДобавитьПару(_ТЗ, Тип, "");

	Возврат _ТЗ;

КонецФункции

//*****

Функция ПолучитьПроизвольноеЗначение_ТЗ()

Перем ТЗ;	

	Если (ТекЛексема = Л_Строка) Или (ТекЛексема = Л_Число) Или (ТекЛексема = Л_Константа) Тогда

		ТЗ = НоваяТЗ(В_Значение);

		ДобавитьПару(ТЗ, ТекЛексема, СтекЛексем.Значение);

		СледующаяЛексема();

		Возврат ТЗ;

	ИначеЕсли ТекЛексема = Л_Лев_Фиг_Скобка Тогда

		Возврат ПолучитьОбъект_ТЗ();

	ИначеЕсли ТекЛексема = Л_Лев_Кв_Скобка 	Тогда

		Возврат ПолучитьМассив_ТЗ();					

	КонецЕсли;

	Возврат ОшибкаЛексемы();

КонецФункции

//*****

Функция ДобавитьКлючЗначение(ТЗ)

Перем НовКлюч, НовЗначение;

	Если ТекЛексема <> Л_Строка Тогда

		Возврат 0;

	КонецЕсли;

	НовКлюч = СтекЛексем.Значение;

	СледующаяЛексема();

	Если ТекЛексема <> Л_Двоеточие Тогда

		Возврат ОшибкаЛексемы();

	КонецЕсли;

	СледующаяЛексема();

	НовЗначение = ПолучитьПроизвольноеЗначение_ТЗ();

	Если НовЗначение = 0 Тогда

		Возврат 0;

	КонецЕсли;

	ДобавитьПару(ТЗ, НовКлюч, НовЗначение);

	Возврат 1;

КонецФункции

//*****

Функция ПолучитьОбъект_ТЗ()

Перем ТЗ;

	ТЗ = НоваяТЗ(В_Объект);

	СледующаяЛексема();

	Если ТекЛексема = Л_Прав_Фиг_Скобка Тогда // пустой объект

		СледующаяЛексема();

		Возврат ТЗ;

	КонецЕсли;

	Если ДобавитьКлючЗначение(ТЗ) = 0 Тогда   // первая пара ключ-значение

		Возврат 0;

	КонецЕсли;	

	Пока ТекЛексема = Л_Запятая Цикл			// пока запятые

		СледующаяЛексема();

		Если ДобавитьКлючЗначение(ТЗ) = 0 Тогда	// пара ключ-значение

			Возврат 0;

		КонецЕсли;

	КонецЦикла;

	Если ТекЛексема = Л_Прав_Фиг_Скобка Тогда

		СледующаяЛексема();

		Возврат ТЗ;

	КонецЕсли;

	Возврат 0;

КонецФункции

//*****

Функция ПолучитьМассив_ТЗ()

Перем ТЗ, _Ключ, _Значение;

	ТЗ = НоваяТЗ(В_Массив);

	СледующаяЛексема();

	Если ТекЛексема = Л_Прав_Кв_Скобка Тогда

		СледующаяЛексема();

		Возврат ТЗ;

	КонецЕсли;

	_Значение = ПолучитьПроизвольноеЗначение_ТЗ();

	Если _Значение = 0 Тогда

		Возврат 0;

	КонецЕсли;

	_Ключ = 0; // JS - индексы массиворв с нуля

	ДобавитьПару(ТЗ, _Ключ, _Значение);	

	Пока ТекЛексема = Л_Запятая Цикл

		СледующаяЛексема();

		_Значение = ПолучитьПроизвольноеЗначение_ТЗ();

		Если _Значение = 0 Тогда

			Возврат 0;

		КонецЕсли;

		_Ключ = _Ключ + 1;

		ДобавитьПару(ТЗ, _Ключ, _Значение);

	КонецЦикла;

	Если ТекЛексема = Л_Прав_Кв_Скобка Тогда

		СледующаяЛексема();

		Возврат ТЗ;

	КонецЕсли;

	Возврат 0;

КонецФункции

//*****

Функция ПрочитатьОбъект_ТЗ()

Перем Рез;	

	НомЛексемы = 0;

	СледующаяЛексема();

	Если ТекЛексема = Л_Лев_Фиг_Скобка Тогда

		Рез = ПолучитьОбъект_ТЗ();

	ИначеЕсли ТекЛексема = Л_Лев_Кв_Скобка Тогда

		Рез = ПолучитьМассив_ТЗ();

	Иначе

		Рез = ПолучитьПроизвольноеЗначение_ТЗ();

	КонецЕсли;

	Если (Рез = 0) Или (ТекЛексема <> Л_Финиш) Тогда

		ОшибкаЛексемы();

		Возврат 0;

	КонецЕсли;

	Возврат Рез;	

КонецФункции

//*****

Функция СгенерироватьТЗ(НачАнализируемаяСтрока)

Перем НачальныйСимвол, Рез;

	АнализируемаяСтрока = НачАнализируемаяСтрока;

	СтекЛексем = СоздатьОбъект("ТаблицаЗначений");

	СтекЛексем.НоваяКолонка("Лексема" , "Строка");

	СтекЛексем.НоваяКолонка("Значение", "Строка");

	ФлагОшибки = 0;

	НомерСимвола = 1;

	Пока НомерСимвола <= СтрДлина(АнализируемаяСтрока) Цикл

		НачальныйСимвол = ТекущиеСимволы(1);

		Если Найти(" " + Симв(9), НачальныйСимвол) > 0 Тогда  // пробелы и разделители строк пропускаем

			НомерСимвола = НомерСимвола + 1;

		ИначеЕсли НачальныйСимвол = Л_Кавычка	Тогда // кавычка - читаем строку

			ЧитатьСтроку();

		ИначеЕсли Найти(ОдносимвольныеЛексемы, НачальныйСимвол) > 0 Тогда

			ДобавитьЛексему(НачальныйСимвол, "", 1);

		ИначеЕсли Найти(ПервыеСимволыКонстант, НачальныйСимвол) > 0 Тогда // первая буква из начала константы - константа null, true, false

			Если ЧитатьКонстанту(НачальныйСимвол) = 0 Тогда

				Прервать;

			КонецЕсли;

		ИначеЕсли Найти("-" + Цифры0_9, НачальныйСимвол) > 0 Тогда // число

			Если ЧитатьЧисло() = 0 Тогда

				Прервать;

			КонецЕсли;

		Иначе		// иных вариантов нет

			Сообщить("========= " + НомерСимвола, "!");

			Сообщить(НачальныйСимвол, "!");

			Сообщить("<" + НачальныйСимвол + "> " + КодСимв(НачальныйСимвол), "!");

			Сообщить(ТекущиеСимволы(100), "!");

			Возврат 0;

		КонецЕсли;

	КонецЦикла;

	Если ФлагОшибки <> 0 Тогда

		Сообщить("Ошибка парсинга JSON - выражения", "!");

		Возврат 0;

	ИначеЕсли СтекЛексем.КоличествоСтрок() = 0 Тогда

		Сообщить("Пустой стек", "!");

		Возврат 0;

	КонецЕсли;

	ДобавитьЛексему(Л_Финиш, "", 0);

	Возврат ПрочитатьОбъект_ТЗ();

КонецФункции

//*****

Функция JSON_Error(Стр = "")

	Если Стр <> "" Тогда

		Сообщить("JSON-ОШИБКА: " + Стр, "!");

	КонецЕсли;

	Возврат JSON_Error;

КонецФункции

//*****

Функция JSON_Type(Парам)

	Если ТипЗначенияСтр(Парам) <> "ТаблицаЗначений" Тогда

		Возврат JSON_Error();

	ИначеЕсли Парам.КоличествоКолонок() <> 2 Тогда

		Возврат JSON_Error();

	ИначеЕсли Парам.КоличествоСтрок() < 2 Тогда

		Возврат JSON_Error();

	КонецЕсли;

	Возврат Парам.ПолучитьЗначение(1, 1);

КонецФункции

//*****

Функция JSON_GetValue(Парам, Keys)

Перем Тип, До, После, ПозЗакр, Л1, П2, Инд, ИндСтр, НС, КвоСтрок;

	Тип = JSON_Type(Парам);

	ПозЗакр = Найти(Keys, "]");

	Если ПозЗакр = 0 Тогда

		ПозЗакр = СтрДлина(Keys) + 1;

	КонецЕсли;	

	До = Лев(Keys, ПозЗакр);

	После = Сред(Keys, ПозЗакр + 1);

	Л1 = Лев(До, 1);

	П2 = Найти(До, "]");

	Если Тип = JSON_Error Тогда

		Возврат JSON_Error("Параметра");

	КонецЕсли;

	КвоСтрок = Парам.КоличествоСтрок();

	Если До = "" Тогда // сам объект

		Если (Тип = В_Массив) Или (Тип = В_Объект) Тогда

			Возврат JSON_Error();

		ИначеЕсли Тип = В_Значение Тогда

			Возврат Парам.ПолучитьЗначение(2, 2);

		Иначе

			Возврат JSON_Error("№ 1");

		КонецЕсли;		

	ИначеЕсли До = ".length" Тогда // размер массива или объекта. Для значения - ошибка

		Если (Тип = В_Массив) Или (Тип = В_Объект) Тогда

			Возврат Парам.КоличествоСтрок() - 1;

		Иначе

			Возврат JSON_Error("Длина скаляра");

		КонецЕсли;

	ИначеЕсли Л1 = "[" Тогда // размер массива или объекта. Для значения - ошибка

		Если П2 = 0 Тогда

			Возврат JSON_Error("Индексация: <" + До + ">");

		КонецЕсли;

		Инд = Сред(До, 2, П2 - 2);

		Если (Найти("'""", Лев(Инд, 1)) > 0) И (Найти("'""", Прав(Инд, 1)) > 0) Тогда // строковый только объект

			ИндСтр = Сред(Инд, 2, СтрДлина(Инд) - 2);

			Если Тип <> В_Объект Тогда

				Возврат JSON_Error("Строковый индекс <" + ИндСтр + "> только для Объекта");

			КонецЕсли;

			НС = 0;

			Если Парам.НайтиЗначение(ИндСтр, НС, 1) = 1 Тогда

				Возврат JSON_GetValue(Парам.ПолучитьЗначение(НС, 2), После);

			КонецЕсли;

			Возврат JSON_Error("Нет индекса <" + ИндСтр + ">");

		КонецЕсли;

		ИндЧис = 0 + Инд;

		Если "" + ИндЧис <> Инд Тогда // защита от <5D>

			Возврат JSON_Error("Ошибка 1 числового индекса <" + Инд + ">");

		ИначеЕсли Цел(ИндЧис) <> ИндЧис Тогда // защита от неЦелого индекса

			Возврат JSON_Error("Ошибка 2 числового индекса <" + Инд + "> (нецелый)");

		ИначеЕсли ИндЧис < 0 Тогда

			Возврат JSON_Error("Ошибка 3 числового индекса <" + Инд + "> (отрицательный)");

		ИначеЕсли ИндЧис > (КвоСтрок - 2) Тогда

			Возврат JSON_Error("Ошибка 4 числового индекса <" + Инд + "> (" + ИндЧис + ">" + (КвоСтрок - 2) + ")");

		КонецЕсли;

		Возврат JSON_GetValue(Парам.ПолучитьЗначение(ИндЧис + 1, 2), После);

	Иначе

		Возврат JSON_Error("Ошибка 5 <" + До + ">");

	КонецЕсли;

КонецФункции

//*****

Процедура ПриОткрытии()

Перем Рез1, ТипУзла1, Зн1, Значение;	

	ОчиститьОкноСообщений();

	СтатусВозврата(0);

	Рез1 = СгенерироватьТЗ(ПрочитатьФайл(ТекКаталог + "j1.json"));

	Напечатать_ТЗ(Рез1);

	ТипУзла1 = JSON_Type(Рез1);

	Сообщить("Тип узла: " + ТипУзла1);

	Зн1 = JSON_GetValue(Рез1, ".length");									Сообщить("1) Размер: " 		+ Зн1);

	Зн3 = JSON_GetValue(Рез1, "['1']");										Сообщить("3) ['1']: <" 		+ Зн3 + ">");

	Зн4 = JSON_GetValue(Рез1, "[1]");										Сообщить("4) [1]: <" 		+ Зн4 + ">");

	Зн5 = JSON_GetValue(Рез1, "['Массив'][6]");								Сообщить("5) [*]: <" + Зн5 + ">");

	Зн6 = JSON_GetValue(Рез1, "['Соответствие']['ДопустимоеИмяСвойства']");	Сообщить("6) [*]: <" + Зн6 + ">");

КонецПроцедуры

//*****

Процедура ДобавитьСтроковуюКонстанту(КонстантаСтр)

Перем ПервыйСимвол;	

	ПервыйСимвол = Лев(КонстантаСтр, 1);

	ПервыеСимволыКонстант = ПервыеСимволыКонстант + ПервыйСимвол;

	СписокСтроковыхКонстант.Установить(ПервыйСимвол, КонстантаСтр);

КонецПроцедуры

//*****

РасположениеФайла(ТекКаталог, ТекФайл);

//*****

Л_Лев_Фиг_Скобка	= "{";

Л_Прав_Фиг_Скобка	= "}";

Л_Лев_Кв_Скобка		= "["; 

Л_Прав_Кв_Скобка	= "]";

Л_Двоеточие			= ":";

Л_Запятая			= ",";

Л_Экран				= "\";

Л_Кавычка			= """";

Л_Финиш				= "";

Л_Число				= "number";

Л_Строка			= "string";

Л_Константа			= "const";

ОдносимвольныеЛексемы = Л_Лев_Фиг_Скобка + Л_Прав_Фиг_Скобка + Л_Лев_Кв_Скобка + Л_Прав_Кв_Скобка + Л_Двоеточие + Л_Запятая;

//*****

Цифры1_9 = "123456789";

Цифры0_9 = "0" + Цифры1_9;

//*****

В_Массив   = "###array";

В_Объект   = "###object";

В_Значение = "###value";

//*****

СписокСтроковыхКонстант	= СоздатьОбъект("СписокЗначений");

ПервыеСимволыКонстант	= "";

ДобавитьСтроковуюКонстанту("null");

ДобавитьСтроковуюКонстанту("false");

ДобавитьСтроковуюКонстанту("true");

JSON_Error = "ERROR";

 // Распаковывает файл архива ZIP в указанный каталог; Извлекает все файлы архива

//

// Параметры:

//  ПолноеИмяФайлаАрхива  - Строка - имя файла архива, который необходимо распаковать

//  ПутьРаспаковкиФайлов  - Строка - путь по которому необходимо распаковать файлы

//  ПарольАрхива          - Строка - пароль для распаковки архива. По умолчанию пустая строка

// 

// Возвращаемое значение:

//  Результат - Булево - Истина, если успешно, Ложь, если нет.

//

Функция РаспаковатьZipФайл(Знач ПолноеИмяФайлаАрхива, Знач ПутьРаспаковкиФайлов, Знач ПарольАрхива = "") Экспорт

	

	// возвращаемое значение функции

	Результат = Истина;

	

	Попытка

		

		Архиватор = Новый ЧтениеZipФайла(ПолноеИмяФайлаАрхива, ПарольАрхива);

		

	Исключение

		Архиватор = Неопределено;

		СообщитьОбОшибке(КраткоеПредставлениеОшибки(ИнформацияОбОшибке()));

		Возврат Ложь;

	КонецПопытки;

	

	Попытка

		

		Архиватор.ИзвлечьВсе(ПутьРаспаковкиФайлов, РежимВосстановленияПутейФайловZIP.НеВосстанавливать);

		

	Исключение

		

		СтрокаСообщения = НСтр("ru = 'Ошибка при распаковке файлов архива: %1 в каталог: %2'");

		СтрокаСообщения = ПодставитьПараметрыВСтроку(СтрокаСообщения, ПолноеИмяФайлаАрхива, ПутьРаспаковкиФайлов);

		Сообщить(СтрокаСообщения);

		

		Результат = Ложь;

	КонецПопытки;

	

	Архиватор.Закрыть();

	Архиватор = Неопределено;

	

	Возврат Результат;

	

КонецФункции





// Запаковывает указанный каталог в файл архива ZIP

//

// Параметры:

//  ПолноеИмяФайлаАрхива  - Строка - имя файла архива, в который необходимо запаковать

//  МаскаУпаковкиФайлов    - Строка - имя файла, помещаемого в архив, или маска.

//			Недопустимо использование в именах файлов и папок букв национальных алфавитов, которые при 

//			преобразовании из символов UNICODE в узкие символы могут быть преобразованы с потерей информации. 

//			Рекомендуется использовать в именах файлов и папок символы латинского алфавита. 

//  ПарольАрхива          - Строка - пароль для архива. По умолчанию пустая строка

// 

// Возвращаемое значение:

//  Результат - Булево - Истина, если успешно, Ложь, если нет.

//

Функция ЗапаковатьВZipФайл(Знач ПолноеИмяФайлаАрхива, Знач МаскаУпаковкиФайлов, Знач ПарольАрхива = "") Экспорт

	

	// возвращаемое значение функции

	Результат = Истина;

	

	Попытка

		

		Архиватор = Новый ЗаписьZipФайла(ПолноеИмяФайлаАрхива, ПарольАрхива);

		

	Исключение

		Архиватор = Неопределено;

		СообщитьОбОшибке(КраткоеПредставлениеОшибки(ИнформацияОбОшибке()));

		Возврат Ложь;

	КонецПопытки;

	

	Попытка

		

		Архиватор.Добавить(МаскаУпаковкиФайлов, РежимСохраненияПутейZIP.НеСохранятьПути);

		Архиватор.Записать();

		

	Исключение

		

		СтрокаСообщения = НСтр("ru = 'Ошибка при запаковке файлов архива: %1 из каталог: %2'");

		СтрокаСообщения = ПодставитьПараметрыВСтроку(СтрокаСообщения, ПолноеИмяФайлаАрхива, МаскаУпаковкиФайлов);

		Сообщить(СтрокаСообщения);

		

		Результат = Ложь;

	КонецПопытки;

	

	Архиватор = Неопределено;

	

	Возврат Результат;

	

КонецФункции   

 // Подставляет параметры в строку. Максимально возможное число параметров - 9.

// Параметры в строке задаются как %<номер параметра>. Нумерация параметров начинается с единицы.

//

// Параметры:

//  СтрокаПодстановки  – Строка – шаблон строки с параметрами (вхождениями вида "%ИмяПараметра");

//  Параметр<n>        - Строка - подставляемый параметр.

//

// Возвращаемое значение:

//  Строка   – текстовая строка с подставленными параметрами.

//

// Пример:

//  ПодставитьПараметрыВСтроку(НСтр("ru='%1 пошел в %2'"), "Вася", "Зоопарк") = "Вася пошел в Зоопарк".

//

Функция ПодставитьПараметрыВСтроку(Знач СтрокаПодстановки,

	Знач Параметр1,	Знач Параметр2 = Неопределено, Знач Параметр3 = Неопределено,

	Знач Параметр4 = Неопределено, Знач Параметр5 = Неопределено, Знач Параметр6 = Неопределено,

	Знач Параметр7 = Неопределено, Знач Параметр8 = Неопределено, Знач Параметр9 = Неопределено) Экспорт

	

	Если СтрокаПодстановки = Неопределено ИЛИ СтрДлина(СтрокаПодстановки) = 0 Тогда

		Возврат "";

	КонецЕсли;

	

	Результат = "";

	НачПозиция = 1;

	Позиция = 1;

	Пока Позиция <= СтрДлина(СтрокаПодстановки) Цикл

		СимволСтроки = Сред(СтрокаПодстановки, Позиция, 1);

		Если СимволСтроки <> "%" Тогда

			Позиция = Позиция + 1;

			Продолжить;

		КонецЕсли;

		Результат = Результат + Сред(СтрокаПодстановки, НачПозиция, Позиция - НачПозиция);

		Позиция = Позиция + 1;

		СимволСтроки = Сред(СтрокаПодстановки, Позиция, 1);

		

		Если СимволСтроки = "%" Тогда

			Позиция = Позиция + 1;

			НачПозиция = Позиция;

			Результат = Результат + "%";

			Продолжить;

		КонецЕсли;

		

		Попытка

			НомерПараметра = Число(СимволСтроки);

		Исключение

			ВызватьИсключение НСтр("ru='Входная строка СтрокаПодстановки имеет неверный формат: %'" + СимволСтроки);

		КонецПопытки;

		

		Если СимволСтроки = "1" Тогда

			ЗначениеПараметра = Параметр1;

		ИначеЕсли СимволСтроки = "2" Тогда

			ЗначениеПараметра = Параметр2;

		ИначеЕсли СимволСтроки = "3" Тогда

			ЗначениеПараметра = Параметр3;

		ИначеЕсли СимволСтроки = "4" Тогда

			ЗначениеПараметра = Параметр4;

		ИначеЕсли СимволСтроки = "5" Тогда

			ЗначениеПараметра = Параметр5;

		ИначеЕсли СимволСтроки = "6" Тогда

			ЗначениеПараметра = Параметр6;

		ИначеЕсли СимволСтроки = "7" Тогда

			ЗначениеПараметра = Параметр7;

		ИначеЕсли СимволСтроки = "8" Тогда

			ЗначениеПараметра = Параметр8;

		ИначеЕсли СимволСтроки = "9" Тогда

			ЗначениеПараметра = Параметр9;

		Иначе

			ВызватьИсключение НСтр("ru='Входная строка СтрокаПодстановки имеет неверный формат: %'" + ЗначениеПараметра);

		КонецЕсли;

		Если ЗначениеПараметра = Неопределено Тогда

			ЗначениеПараметра = "";

		Иначе

			ЗначениеПараметра = Строка(ЗначениеПараметра);

		КонецЕсли;

		Результат = Результат + ЗначениеПараметра;

		Позиция = Позиция + 1;

		НачПозиция = Позиция;

	

	КонецЦикла;

	

	Если (НачПозиция <= СтрДлина(СтрокаПодстановки)) Тогда

		Результат = Результат + Сред(СтрокаПодстановки, НачПозиция, СтрДлина(СтрокаПодстановки) - НачПозиция + 1);

	КонецЕсли;

	

	Возврат Результат;

	

КонецФункции   

 // Пребразует строку наименования в строку идентификатора колонки ТЗ 

// Аргументы: 

// Наименование товара, которое будет преобразовано в наименование колонки ТЗ в соответствии с правилами именования переменных. 

// Символ - символ, на который будут заменятся символы, не соответствующие правилам именования переменных. 

Функция глНаименованиеКолонки(Элемент, Символ="_") Экспорт 

Перем Результат; 

Результат = "_"+СтрЗаменить(Элемент," ",Символ); 

Результат = СтрЗаменить(Результат,"/",Символ); 

Результат = СтрЗаменить(Результат,"\",Символ); 

Результат = СтрЗаменить(Результат,".",Символ); 

Результат = СтрЗаменить(Результат,",",Символ); 

Результат = СтрЗаменить(Результат,"+",Символ); 

Результат = СтрЗаменить(Результат,"-",Символ); 

Результат = СтрЗаменить(Результат,"!",Символ); 

Результат = СтрЗаменить(Результат,"@",Символ); 

Результат = СтрЗаменить(Результат,"#",Символ); 

Результат = СтрЗаменить(Результат,"$",Символ); 

Результат = СтрЗаменить(Результат,"%",Символ); 

Результат = СтрЗаменить(Результат,"^",Символ); 

Результат = СтрЗаменить(Результат,"&",Символ); 

Результат = СтрЗаменить(Результат,"*",Символ); 

Результат = СтрЗаменить(Результат,"(",Символ); 

Результат = СтрЗаменить(Результат,")",Символ); 

Результат = СтрЗаменить(Результат,"№",Символ); 

Результат = СтрЗаменить(Результат,";",Символ); 

Результат = СтрЗаменить(Результат,":",Символ); 

Результат = СтрЗаменить(Результат,"?",Символ); 

Возврат Результат; 

КонецФункции   

 

Функция УдалитьНедопустимыеСимволыXML(Стр)



    Позиция = НайтиНедопустимыеСимволыXML(Стр, , );



	Пока Позиция <> 0 Цикл

		Стр = Лев(Стр, Позиция-1) + Сред(Стр, Позиция+1);

		Позиция = НайтиНедопустимыеСимволыXML(Стр, , );

	КонецЦикла; 



	Возврат Стр;



КонецФункции //УдалитьНедопустимыеСимволыXML()

   

 Процедура ОчиститьЗаПериод()

	Пока Истина Цикл

		НачатьТранзакцию(РежимУправленияБлокировкойДанных.Управляемый);

		Попытка

			текЗапрос = новый Запрос;

			текЗапрос.Текст = 



			"ВЫБРАТЬ

			|	усИсторияОстатковПоПоказателям.Склад,

			|	усИсторияОстатковПоПоказателям.Поклажедатель,

			|	усИсторияОстатковПоПоказателям.Показатель,

			|	усИсторияОстатковПоПоказателям.Период

			|ИЗ

			|	РегистрСведений.усИсторияОстатковПоПоказателям КАК усИсторияОстатковПоПоказателям

			|ГДЕ

			|	усИсторияОстатковПоПоказателям.Период МЕЖДУ &ПериодС И &ПериодПо";



			текЗапрос.УстановитьПараметр("ПериодС", ГраницаОчисткиС);

			текЗапрос.УстановитьПараметр("ПериодПо", ГраницаОчисткиПо);

			тбзЗаписиЖурнала = текЗапрос.Выполнить().Выгрузить();



			// Блокировка данных

			текБлокировка = Новый БлокировкаДанных;

			тбдЖурнал = текБлокировка.Добавить("РегистрСведений.усИсторияОстатковПоПоказателям");

			тбдЖурнал.Режим = РежимБлокировкиДанных.Исключительный;

			Если тбзЗаписиЖурнала.Количество() тогда

				тбдЖурнал.ИсточникДанных = тбзЗаписиЖурнала;

				тбдЖурнал.ИспользоватьИзИсточникаДанных("Склад", "Склад");

				тбдЖурнал.ИспользоватьИзИсточникаДанных("Поклажедатель", "Поклажедатель");

				тбдЖурнал.ИспользоватьИзИсточникаДанных("Показатель", "Показатель");



				// Заблокировать

				текБлокировка.Заблокировать();



				Для каждого текЗаписьЖурнала из тбзЗаписиЖурнала цикл

					текЗапись = РегистрыСведений.усИсторияОстатковПоПоказателям.СоздатьМенеджерЗаписи();

					ЗаполнитьЗначенияСвойств(текЗапись, текЗаписьЖурнала);

					текЗапись.Удалить();

				КонецЦикла;



			КонецЕсли;



			ЗафиксироватьТранзакцию();

			Прервать;



		Исключение // сообщим об ошибке

			стрОписаниеОшибки = ОписаниеОшибки();

			ОтменитьТранзакцию();

			Сообщить("Ошибка блокировки" + ОписаниеОшибки());

			Прервать;

		КонецПопытки;

	КонецЦикла;

КонецПроцедуры // ОчиститьЗаПериод()   

 // Параметры:

//  СтрокаПараметр - строка, проверяемая строка.

//

// Возвращаемое значение:

//		Истина - строка состоит из допустимых символов

//		Ложь - в строке встречаются недопустимые символы

// 

// Описание:

//		Строка проверяется на наличие только русских и латинских букв;

//		кроме того,	допускаются дефис, "Ё", "ё".

//

Функция СтрокаНаписанаРусскимиИлиЛатинскими(Знач СтрокаПараметр)

	

	СтрокаПараметр = СокрЛП(СтрокаПараметр);	



	КоличествоСимволов = СтрДлина(СтрокаПараметр);

	

	Если  КоличествоСимволов > 0 Тогда

		

		ПервыйСимвол = КодСимвола(Лев(СтрокаПараметр,1)); 

		Русские = (ПервыйСимвол >= 192) или (ПервыйСимвол = 184) или (ПервыйСимвол = 168);

		

		СписокДопустимыхЗначений = Новый Соответствие;

		СписокДопустимыхЗначений.Вставить(184,Истина);   // ё

		СписокДопустимыхЗначений.Вставить(168,Истина);   // Ё

		СписокДопустимыхЗначений.Вставить(45,Истина);   //  "-"



		Для Сч = 1 По КоличествоСимволов Цикл

			

			Код = КодСимвола(Сред(СтрокаПараметр,Сч));   

			

			// Большие латинские буквы: 65 - 90

			// Маленькие латинские буквы: 97 - 122

			// Русские буквы: 192 и больше

			

			//русские:

			Если Русские Тогда

				

				Если (СписокДопустимыхЗначений[Код] = Неопределено) и (Код < 192)  Тогда

					Возврат Ложь;

				КонецЕсли;



			// латинские:	

			ИначеЕсли (Код <> 45) и ((Код < 65) или	(Код > 90) и (Код < 97) или (Код > 122))  Тогда    

				Возврат Ложь;

			КонецЕсли;

				

		КонецЦикла;

		

		Возврат Истина;



	Иначе 	

		Возврат Истина;

	КонецЕсли;

КонецФункции