номерколонки » Поиск

Результаты по ключевому слову: номерколонки

Пример работы с MS EXCEL (листы, поиск на листе)

Код 1C v 8.х

 ДокументExcel = ПолучитьCOMОбъект(ИмяФайла); //Листы :                     СписокЛистов = Новый СписокЗначений;                                     Для каждого Лист Из ДокументExcel.Sheets Цикл                         СписокЛистов.Добавить(Лист.Index,Лист.Name);                 КонецЦикла;      ЛистExcel= ДокументExcel.Sheets(НомерЛистаКниги); ПоследняяСтрока = ЛистExcel.UsedRange.Rows.Count; ЛеваяКолонка = ЛистExcel.UsedRange.Column; ПоследняяКолонка =  ЛистExcel.UsedRange.Columns.Count; НомерКолонкиСТекстом=ЛистExcel.UsedRange.Find("text").Column; //Или НомерКолонкиСТекстом=ЛистExcel.Cells.Find("text").Column; //Подчищаем за собой память ДокументExcel.Application.Quit();

Категория: Работа с Microsoft Office и OpenOffice

Функции сохранения таблицы значений в файл и чтения из файла

В данном примере хочу привести несколько универсальных функций по выгрузке таблицы значений в файл и дальнейшего чтения из файла:

Порядок программных действий при выгрузке в файл выглядит так:

Подготавливаем таблицу значений (выгружаем из табличной части, выбираем колонки);
Конвертируем таблицу значений в табличный документ;
Сохраняем табличный документ в MXL.

При загрузке таблицы порядок действий такой:

Читаем из файла табличный документ;
Конвертируем табличный документ в таблицу значений;
Используем эту таблицу значений в своих целях (загружаем в табличную часть).

Соответственно файл для хранения данных таблицы имеет расширение *.mxl.

Основные функции для реализации поставленной задачи следующие:

ПреобразоватьТДвТЗ – Функция преобразования табличного документа в таблицу значений.

ПреобразоватьТЗвТД – Функция обратного преобразования таблицы значений в табличный документ.

ПрочитатьТЗИзMXL – Читает из файла данные, определяет колонки таблицы и преобразует эти данные в таблицу значений.

ЗаписатьТЗВMXL – Преобразует таблицу значений в табличный документ и записывает его в файл.

Код 1C v 8.3

 // Преобразовать табличный документ в таблицу значений.

//

// Параметры:

//	ТабДок - <ТабличныйДокумент> - Исходный табличный документ;

//	СтруктураКолонок - <Структура>, <ТаблицаЗначений> - Структура колонок;

//	НачалоСтрока - <Число> - Строка начала области;

//	НачалоСтолбец - <Число> - Столбец начала области;

//	КонецСтрока - <Число> - Строка конца области;

//	КонецСтолбец - <Число> - Столбец конца области.

//	

// Возвращаемое значение:

//	<ТаблицаЗначений> - Полученная таблица значений.

//

Функция ПреобразоватьТДвТЗ(ТабДок, СтруктураКолонок, Знач НачалоСтрока = Неопределено, Знач НачалоСтолбец = Неопределено, Знач КонецСтрока = Неопределено, Знач КонецСтолбец = Неопределено) Экспорт

 

	// Определение габаритов таблицы

	Если НачалоСтрока = Неопределено И НачалоСтолбец = Неопределено Тогда

		НачалоСтрока = 1;

		НачалоСтолбец = 1;

	КонецЕсли;

 

	Если НачалоСтрока = Неопределено Тогда

		НачалоСтрока = 1;

		Пока НЕ ТабДок.Область(НачалоСтрока, НачалоСтолбец).СодержитЗначение 

		 И НачалоСтрока < ТабДок.ВысотаТаблицы 

		Цикл

			НачалоСтрока = НачалоСтрока + 1;

		КонецЦикла;

	ИначеЕсли НачалоСтолбец = Неопределено Тогда

		НачалоСтолбец = 1;

		Пока НЕ ТабДок.Область(НачалоСтрока, НачалоСтолбец).СодержитЗначение 

		 И НачалоСтолбец < ТабДок.ШиринаТаблицы

		Цикл

			НачалоСтолбец = НачалоСтолбец + 1;

		КонецЦикла;

	КонецЕсли;

 

	КонецСтрока = ?(КонецСтрока = Неопределено, ТабДок.ВысотаТаблицы, КонецСтрока);

	КонецСтолбец = ?(КонецСтолбец = Неопределено, ТабДок.ШиринаТаблицы, КонецСтолбец);

 

	// Преобразование

	ЭтоТаблица = (ТипЗнч(СтруктураКолонок) = Тип("ТаблицаЗначений"));

	ТабЗначений = ПолучитьТаблицуВывода(СтруктураКолонок);

 

	Для ИндексСтроки = НачалоСтрока По КонецСтрока Цикл

		СтрокаТЗ = ТабЗначений.Добавить();

 

		ИндексКолонки = НачалоСтолбец;

		Для Каждого Колонка Из СтруктураКолонок Цикл

			НаименованиеКолонки = ?(ЭтоТаблица, Колонка.Наименование, Колонка.Ключ);

			пИндексКолонки = ?(ЭтоТаблица, Колонка.СтолбецОтчёт, ИндексКолонки);

 

			Если ТабДок.Область(ИндексСтроки, пИндексКолонки).СодержитЗначение Тогда

				СтрокаТЗ[НаименованиеКолонки] = ТабДок.Область(ИндексСтроки, пИндексКолонки).Значение;

			Иначе

				СтрокаТЗ[НаименованиеКолонки] = ТабДок.Область(ИндексСтроки, пИндексКолонки).Текст;

			КонецЕсли;

 

			ИндексКолонки = ИндексКолонки + 1;

		КонецЦикла;

	КонецЦикла;

 

	Возврат ТабЗначений;

КонецФункции;



// Преобразовать таблицу значений в табличный документ.

//

// Параметры:

//	ТабЗначений - <ТаблицаЗначений> - Исходная таблица значений;

//	ТабДок - <ТабличныйДокумент> - Полученный табличный документ. Если параметр не задан, 

//	 то документ создаётся заново и возвращается функцией;

//	НачалоСтрока - <Число> - Строка начала области;

//	НачалоСтолбец - <Число> - Столбец начала области;

//	ВыводитьЗаголовки - <Булево> - Определяет выводить ли имена колонок или нет.

//	

// Возвращаемое значение:

//	<ТабличныйДокумент> - Полученный табличный документ (возвращает параметр "ТабДок").

//

Функция ПреобразоватьТЗвТД(ТабЗначений, ТабДок = Неопределено, Знач НачалоСтрока = Неопределено, Знач НачалоСтолбец = Неопределено, ВыводитьЗаголовки = Ложь) Экспорт

 

	Если ТабДок = Неопределено Тогда

		ТабДок = Новый ТабличныйДокумент;

	КонецЕсли;

 

	// Определение габаритов таблицы

	НачалоСтрока = ?(НачалоСтрока = Неопределено, 1, НачалоСтрока);

	НачалоСтолбец = ?(НачалоСтолбец = Неопределено, 1, НачалоСтолбец);

 

	// Преобразование

	ИндексСтроки = НачалоСтрока;

	Если ВыводитьЗаголовки Тогда

		ИндексКолонки = НачалоСтолбец;

		Для Каждого Колонка Из ТабЗначений.Колонки Цикл

			ТабДок.Область(ИндексСтроки, ИндексКолонки).Текст = ?(ПустаяСтрока(Колонка.Заголовок), Колонка.Имя, Колонка.Заголовок);

			ИндексКолонки = ИндексКолонки + 1;

		КонецЦикла;

		ИндексСтроки = ИндексСтроки + 1;

	КонецЕсли;

 

	Для Каждого Элемент Из ТабЗначений Цикл

		ИндексКолонки = НачалоСтолбец;

		Для Каждого Колонка Из ТабЗначений.Колонки Цикл

			ТабДок.Область(ИндексСтроки, ИндексКолонки).СодержитЗначение = Истина;

			ТабДок.Область(ИндексСтроки, ИндексКолонки).ТипЗначения = Новый ОписаниеТипов(Колонка.ТипЗначения);

			ТабДок.Область(ИндексСтроки, ИндексКолонки).Значение = Элемент[Колонка.Имя];

			ИндексКолонки = ИндексКолонки + 1;

		КонецЦикла;

		ИндексСтроки = ИндексСтроки + 1;

	КонецЦикла;

 

	Возврат ТабДок;

КонецФункции;



// Читает табличный документ из файла MXL и преобразует его в таблицу значений.

//

// Параметры:

//	ИмяФайла - <Строка> - Путь к файлу MXL;

//	СтруктураКолонок - <Структура>, <ТаблицаЗначений> - Структура колонок. Если этот параметр

//		не задан, то структура колонок формируется из самого табличного документа;

//	ЕстьЗаголовок - <Булево> - Есть ли первая строка с заголовками или нет.

//	

// Возвращаемое значение:

//	<ТаблицаЗначений> - Полученная таблица значений.

//

Функция ПрочитатьТЗИзMXL(ИмяФайла, СтруктураКолонок = Неопределено, ЕстьЗаголовок = Истина) Экспорт

 

	ТабДок = Новый ТабличныйДокумент;

	ТабДок.Прочитать(ИмяФайла);

 

	Если СтруктураКолонок = Неопределено И ЕстьЗаголовок Тогда

		СтруктураКолонок = Новый Структура;

		Для ИндексКолонки = 1 По ТабДок.ШиринаТаблицы Цикл

			Обл1 = ТабДок.Область(1, ИндексКолонки);

			Обл2 = ТабДок.Область(2, ИндексКолонки);

			ИмяКолонки = СокрЛП(Обл1.Текст);

			ИмяКолонки = ?(Найти(ИмяКолонки, " ") > 0, СтрЗаменить(ТРег(ИмяКолонки), " ", ""), ИмяКолонки);

			СтруктураКолонок.Вставить(ИмяКолонки, ?(Обл2.СодержитЗначение, Обл2.ТипЗначения, Новый ОписаниеТипов));

		КонецЦикла;

	ИначеЕсли СтруктураКолонок = Неопределено И НЕ ЕстьЗаголовок Тогда

		СтруктураКолонок = Новый Структура;

		Для ИндексКолонки = 1 По ТабДок.ШиринаТаблицы Цикл

			Обл2 = ТабДок.Область(1, ИндексКолонки);

			ИмяКолонки = "К" + Формат(ИндексКолонки, "ЧДЦ=0; ЧН=0; ЧГ=0");

			СтруктураКолонок.Вставить(ИмяКолонки, ?(Обл2.СодержитЗначение, Обл2.ТипЗначения, Новый ОписаниеТипов));

		КонецЦикла;

	КонецЕсли;

 

    Таблица = ПреобразоватьТДвТЗ(ТабДок, СтруктураКолонок, ?(ЕстьЗаголовок, 2, 1), 1);

 

	Возврат Таблица;

КонецФункции;



// Сохраняет таблицу значений в файле в виде табличного документа.

//

// Параметры:

//	ИмяФайла - <Строка> - Путь к файлу MXL;

//	ТабЗначений - <ТаблицаЗначений> - Сохраняемая таблица значений;

//	ЕстьЗаголовок - <Булево> - Есть ли первая строка с заголовками или нет.

//

Процедура ЗаписатьТЗВMXL(ИмяФайла, ТабЗначений, ЕстьЗаголовок = Истина) Экспорт

 

	ТабДок = ПреобразоватьТЗвТД(ТабЗначений, Неопределено, 1, 1, ЕстьЗаголовок);

	ТабДок.Записать(ИмяФайла, ТипФайлаТабличногоДокумента.MXL);

 

КонецПроцедуры;

Еще небольшой набор функций для вывода таблицы значений в табличный документ. После формирования табличного документа, - сохраняем его в файл mxl.

Табличный документ можно сохранить a файлы следующих типов:

ANSITXT - Текстовый документ
DOCX - документ MS Word
HTML
HTML3
HTML4
HTML5
MXL
MXL7
ODS - Файл Open Office
PDF - файл Acrobat Readr
TXT - Текстовый документ
XLS - файл Excel
XLS95 - файл Excel95
XLS97 - файл Excel97
XLSX - файл Excel2010

Код 1C v 8.3

 // Получаем таблицу значения из файла. 

Функция ЗагрузитьТЗизФайла(ИмяФайла)    

    Путь = КаталогВременныхФайлов() + ИмяФайла; 

    Текст = Новый ЧтениеТекста(Путь, КодировкаТекста.UTF8); 

    стрТЗ = Текст.Прочитать(); 

    Текст.Закрыть(); 

    // получим таблицу значений из строки

    ТЗ = ЗначениеИзСтрокиВнутр(стрТЗ);    

    Возврат ТЗ;    

КонецФункции    



// Заполнить ячейки в строке  значениями 

//

Функция ЗаписьТЗ2ТабДок(записьТЗ,НомерСтроки,ТабличныйДокумент)

    НомерКолонки = 1;

    Символ160 = Символ(160);    

    // цикл по колонкам таблицы

    // РезультатЗапроса.Колонки.Количество()    // - количество колонок

    Для каждого полеТЗ из ЗаписьТЗ цикл 

        // значения ячейки в Excel

        типПоляТЗ = ТипЗнч(полеТЗ);

        если типПоляТЗ = Тип("Число") тогда             

            полеТЗ=Строка(полеТЗ); 

            полеТЗ=СтрЗаменить(полеТЗ,Символ160,"");

            полеТЗ=СтрЗаменить(полеТЗ,",",".");

        иначеесли типПоляТЗ = Тип("Строка") тогда      

        иначе        

            полеТЗ = строка(полеТЗ);

        КонецЕсли;    

        имяОбласти = "R" + номерСтроки + "C" + НомерКолонки;

        имяОбласти = СтрЗаменить(имяОбласти,Символ(160),"");         

        Ячейка = ТабличныйДокумент.Область(имяОбласти);

        Ячейка.Текст = полеТЗ;

        НомерКолонки = НомерКолонки + 1;

    КонецЦикла;            

КонецФункции



// Заполнить наименованиями колонок таблицу

Функция НаимКолонок2Mxl(ТаблицаЗначений,ТабличныйДокумент)

    // массКолонки = новый массив();

    номерСтроки=1;

    номКолонки=1; 

    ТабличныйДокумент = новый ТабличныйДокумент;

    // цикл по коллекции колонок

    Для НомКол=0 по ТаблицаЗначений.Колонки.Количество() - 1 Цикл

        //Сообщить(Колонка.Имя + "(" + Колонка.ТипЗначения + ")" );            

        имяКолонки=ТаблицаЗначений.Колонки[НомКол].Имя;

        //ТабличныйДокумент.Область(

        имяОбласти = "R" + номерСтроки + "C" + номКолонки;

        имяОбласти = СтрЗаменить(имяОбласти,Символ(160),"");         

        Ячейка = ТабличныйДокумент.Область(имяОбласти);

        //значениеЯчейки = СтрЗаменить(имяОбласти,Символ(160),"");         

        Ячейка.Текст = имяКолонки;

        // на основе текущего шрифта сделаем Жирный

        ЖирныйШрифт = ?(ЖирныйШрифт = Неопределено,Новый Шрифт(Ячейка.Шрифт,,,Истина),ЖирныйШрифт);         

        Ячейка.Шрифт = ЖирныйШрифт;

        номКолонки = номКолонки + 1;        

    КонецЦикла;

КонецФункции





// Заполнить построчно табличный документ

Функция Таблица2Mxl(ТаблицаЗначений,ТабличныйДокумент)

    //Выборка = РезультатЗапроса.Выбрать();

    НомСтр=1; // заполняем данными начиная со 2-й строки    

    // цикл по строкам таблицы

    Для каждого записьТЗ из ТаблицаЗначений Цикл

        НомСтр = НомСтр + 1;

        // цикл по колонкам таблицы        

        ЗаписьТЗ2ТабДок(записьТЗ,НомСтр,ТабличныйДокумент);         

    КонецЦикла;    

КонецФункции



// Таблица значений в табличный документ

Функция ТаблицаЗначений2Mxl(ТаблицаЗначений,ФайлMxl)

    ТабличныйДокумент = новый ТабличныйДокумент;

    // вывести колонки

    НаимКолонок2Mxl(ТаблицаЗначений,ТабличныйДокумент);

    // вывести содержимое таблицы    

    Таблица2Mxl(ТаблицаЗначений,ТабличныйДокумент);

    ТабличныйДокумент.Записать(ФайлMxl,ТипФайлаТабличногоДокумента.MXL);

    ТабличныйДокумент.Показать(ФайлMxl,ФайлMxl);

    Возврат 0;

КонецФункции





Функция    Тест_ВыгрузитьТЗвMxl();

    файл_мТЗИсходныеДанные = "мТЗИсходныеДанные.dat";        

    ТЗ = ЗагрузитьТЗизФайла(файл_мТЗИсходныеДанные);    

    ФайлMxl = КаталогВременныхФайлов() + СтрЗаменить(файл_мТЗИсходныеДанные,".dat",".mxl");  

    ТаблицаЗначений2Mxl(ТЗ,ФайлMxl);

КонецФункции



Тест_ВыгрузитьТЗвMxl();

Пример выгруженной таблицы значений в файл:

Категория: Работа с Таблицей Значений

Загрузка данных в документ из табличного документа (в ТД скопировано из Excel)

Частенько пользователи просят упростить ввод данных в программу используя копирование таблиц из Excel. Ниже я приведу пример как загрузить данные скопированные из Excel:

Создаем форму для загрузки данных:

внутри пишем код:

Код 1C v 8.х

 // Функция ПолучитьТЗИзМакета(ТабДок, КолонкаИндекса = 1)     

    ТаблицаДанных = Новый ТаблицаЗначений;

    НомерКолонки = 0;

    Пока Истина Цикл

        НомерКолонки = НомерКолонки + 1;

        ИмяКолонки = ТабДок.Область(1, НомерКолонки).Текст;

        Если ПустаяСтрока(ИмяКолонки) Тогда

            Прервать;

        КонецЕсли;        

        ТаблицаДанных.Колонки.Добавить("К"+Строка(НомерКолонки));

    КонецЦикла;

    

    СчетчикКолонок = НомерКолонки - 1;

    

    НомерСтроки = 1; ФлагПрерывания = Ложь;

    Пока Истина Цикл

        НомерСтроки = НомерСтроки + 1;

        Стр = ТаблицаДанных.Добавить();

        

        Для А = 1 ПО СчетчикКолонок Цикл

            ТекстКолонки = ТабДок.Область(НомерСтроки, А).Текст;

            Если ПустаяСтрока(ТекстКолонки) Тогда

                Если А = КолонкаИндекса Тогда

                    Флагпрерывания = Истина;

                    ТаблицаДанных.Удалить(Стр);

                КонецЕсли;

            Иначе

                Стр[А - 1] = ТекстКолонки

            КонецЕсли;

            

            Если Флагпрерывания Тогда

                Прервать

            КонецЕсли;

        КонецЦикла;

        

        Если Флагпрерывания Тогда

            Прервать

        КонецЕсли;

    КонецЦикла;

    

    Возврат ТаблицаДанных

КонецФункции



Процедура ОсновныеДействияФормыЗагрузить(Кнопка)

	тзДанных=ПолучитьТЗИзМакета(ЭлементыФормы.ПолеТД);

	Закрыть(тзДанных);

КонецПроцедуры

В документ добавлена кнопка - Загрузка из Excel ее код:

Код 1C v 8.х

  //Функция преобразует строку вида 31.01.2015 в дату

Функция РазобратьДату(ИзмДата);

	Возврат Дата(Сред(ИзмДата,7,4)+Сред(ИзмДата,4,2)+Сред(ИзмДата,0,2));	       	

КонецФункции



Процедура ЗагрузитьИзЕкселНажатие(Элемент)

тзДанных = ПолучитьФорму("ФормаЗагрузкиИзExcel").ОткрытьМодально();	

//ТЗ получили, загружаем:

ГрафикПлатежейКлиент.Очистить();

Для Каждого стр из тзДанных Цикл 

	 нСтр = ГрафикПлатежейКлиент.Добавить();

	 нСтр.Дата = РазобратьДату(стр.К1);

	 нСтр.Сумма = стр.К2;

	 нСтр.СуммаАкта = стр.К3;

КонецЦикла;



КонецПроцедуры

Смысл в том что из Excel копируют таблицу:

Жмут на кнопку загрузить и в документе Табличная часть заполняется автоматически:

Категория: Табличный документ

Загрузка данных из CSV файла

Код 1C v 8.х

  // выберем CSV файл

ДиалогВыбора = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);

ДиалогВыбора.Заголовок = “Выберите файл”;



Если ДиалогВыбора.Выбрать() Тогда

ИмяФайла = ДиалогВыбора.ПолноеИмяФайла;

КонецЕсли;



//Обработка данных из CSV

// очищаем информацию в таблице и находим файл на диске, а потом считываем его:



//очищаем таблицу и удаляем колонки

Таблица.Очистить();

Таблица.Колонки.Очистить();

ЭлементыФормы.Таблица.Колонки.Очистить();



// чтение файла

ЗагружаемыйФайл = Новый ТекстовыйДокумент;

ЗагружаемыйФайл.Прочитать(ИмяФайла);



//После того как мы получили все данные из файла, мы считываем 1 строку файла

// и формируем колонки на форме с наименованиями из файла



//шапка по умолчанию 1 строка, из первой строки делаем колонки таблицы

Шапка = ЗагружаемыйФайл.ПолучитьСтроку(1);



//раскладываем строку в массив

МассивКолонок = РазложитьСтрокуВМассивПодстрок(Шапка,Разделитель); // процедура из типовой конфигурации, разбивает строку в массив по разделителям



//генерируем колонки

Для Каждого ИмяКолонки Из МассивКолонок Цикл



ИмяБезПробелов = СтрЗаменить(ИмяКолонки,” “,”"); // убираем из имени колонок пробелы

Таблица.Колонки.Добавить(ИмяБезПробелов,,ИмяКолонки);

НоваяКолонка = ЭлементыФормы.Таблица.Колонки.Добавить(ИмяБезПробелов, ИмяКолонки);

НоваяКолонка.Данные = ИмяБезПробелов;



КонецЦикла;



// После того, как шапка сформирована можно приступать к обработке самих данных

Для НомерСтроки=2 по ЗагружаемыйФайл.КоличествоСтрок() Цикл



Состояние(“Обрабатывается “+Строка(Формат(?(ЗагружаемыйФайл.КоличествоСтрок()=0,0,((100*НомерСтроки)/                                                                                                ЗагружаемыйФайл.КоличествоСтрок())),”ЧЦ=3; ЧДЦ=0&#8243;))+” %”);

ОбработкаПрерыванияПользователя(); //указав данный оператор, цикл можно прервать в любой момент нажатие ctrl+break



// получить строку файла с указанным номером и преобразуем её в массив

Строка = ЗагружаемыйФайл.ПолучитьСтроку(НомерСтроки);

МассивКолонок = РазложитьСтрокуВМассивПодстрок(Строка,Разделитель);// процедура из типовой конфигурации, разбивает строку в массив по разделителям

НоваяСтрока = Таблица.Добавить();



Если МассивКолонок.Количество() <> Таблица.Колонки.Количество() Тогда

Сообщить(“Ошибка со строкой ” + Строка);

Продолжить; // скорее всего в тексте содержит разделитель

КонецЕсли;



Для НомерКолонки = 1 по МассивКолонок.Количество() Цикл

//заполняем строку значениями

ТекущееЗначение = МассивКолонок[НомерКолонки-1];

ИмяКолонки = Таблица.Колонки[НомерКолонки-1].Имя;

НоваяСтрока[ИмяКолонки] = ТекущееЗначение;

КонецЦикла;



КонецЦикла;

Категория: XML, DBF, TXT, CSV

Как результат СКД в виде Табличного Документа разобрать и вывести в Таблицу Значений

В отчете должна быть настроена и указана основная схема компоновки данных
Когда идет конвертирование в ТЗ, то ищется в первом столбце пустая строка, как только она найдена - конвертация считается завершенной.
Поэтому для сложных отчетов - выводите первым столбцом Системное поле № п/п.

Код 1C v 8.х

 

// В МОДУЛЕ ФОРМЫ

&НаКлиенте

Процедура СформироватьБезСКД(Команда)

	СформироватьСервер();		

КонецПроцедуры



&НаСервере

Функция СформироватьСервер()

	мОтчет    = РеквизитФормыВЗначение("Отчет");

	Результат =  мОтчет.СформироватьПечатнуюФорму();

КонецФункции





// В МОДУЛЕ ОБЪЕКТА

Функция СформироватьПечатнуюФорму() Экспорт

   рзДанные = ПолучитьДанныеДляОтчета();

   Возврат рзДанные;	

КонецФункции





Функция ТДВТаблицуЗначений(ТабДок, КолонкаИндекса = 1)

  

    ТаблицаДанных = Новый ТаблицаЗначений;

    НомерКолонки = 0;

    Пока Истина Цикл

        НомерКолонки = НомерКолонки + 1;

        ИмяКолонки = ТабДок.Область(1, НомерКолонки).Текст;

        Если ПустаяСтрока(ИмяКолонки) Тогда

            Прервать;

        КонецЕсли;        

        ТаблицаДанных.Колонки.Добавить(СтрЗаменить(ИмяКолонки, " ","_"));

    КонецЦикла;

    

    СчетчикКолонок = НомерКолонки - 1;

    

    НомерСтроки = 1; ФлагПрерывания = Ложь;

    Пока Истина Цикл

        НомерСтроки = НомерСтроки + 1;

        Стр = ТаблицаДанных.Добавить();

        

        Для А = 1 ПО СчетчикКолонок Цикл

            ТекстКолонки = ТабДок.Область(НомерСтроки, А).Текст;

            Если ПустаяСтрока(ТекстКолонки) Тогда

                Если А = КолонкаИндекса Тогда

                    Флагпрерывания = Истина;

                    ТаблицаДанных.Удалить(Стр);

                КонецЕсли;

            Иначе

                Стр[А - 1] = ТекстКолонки

            КонецЕсли;

            

            Если Флагпрерывания Тогда

                Прервать

            КонецЕсли;

        КонецЦикла;

        

        Если Флагпрерывания Тогда

            Прервать

        КонецЕсли;

    КонецЦикла;

    

    Возврат ТаблицаДанных

КонецФункции





Функция ПолучитьДанныеДляОтчета()

	КомпоновщикНастроек.Настройки.ПараметрыДанных.УстановитьЗначениеПараметра("НачалоПериода", НачалоПериода);

	КомпоновщикНастроек.Настройки.ПараметрыДанных.УстановитьЗначениеПараметра("КонецПериода", КонецДня(КонецПериода));

	КомпоновщикНастроек.Настройки.ПараметрыДанных.УстановитьЗначениеПараметра("Организация", Организация);

			

	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;

    ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;



    МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпоновщикНастроек.Настройки, ДанныеРасшифровки,, Тип("ГенераторМакетаКомпоновкиДанных"));



    ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;

    ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки,, ДанныеРасшифровки);



    ТабличныйДокумент = Новый ТабличныйДокумент;



    ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;

    ПроцессорВывода.УстановитьДокумент(ТабличныйДокумент);



    ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных, Истина);



	///Переведем ТабДокумент в ТЗ

	 тзДанные = ТДВТаблицуЗначений(ТабличныйДокумент);	

 	Возврат  тзДанные;

КонецФункции

Категория: Схема Компоновки Данных

Выбор оптимального алгоритма для разбора строки в массив

Столкнулся с проблемой: ПолучитьСтрокуПоНомеру() медленно отрабатывает на входных данных >100 000 строк. Как сделать бытсрее?

Код 1C v 8.х

  // Пример Defender aka LINN

ВремяНачала = ТекущаяДата(); 

Сообщить("Обработка начата: " + ВремяНачала); 



ТЗ = Новый ТаблицаЗначений; 

Текст = ПолучитьМакет("Макет").ПолучитьТекст(); 



RE = New COMObject("VBScript.RegExp"); 

RE.Global        = Истина; 

RE.IgnoreCase    = Истина; 

RE.Multiline    = Истина; 



RE.Pattern = "^.*$"; 



Строки = RE.Execute(Текст); 



RE.Pattern = "([^\|]+?|\|)(?=\|)"; 



ДобавитьКолонки = Истина; 



Для Каждого СтрокаТекста из Строки Цикл 

   СтрокаДляРазбора = СтрокаТекста.Value; 

    

   Результат = RE.Execute(СтрокаДляРазбора); 

    

   Если ДобавитьКолонки Тогда 

       НомерКолонки = 0; 

       Для Каждого Совпадение Из Результат Цикл 

           НомерКолонки = НомерКолонки + 1; 

           ТЗ.Колонки.Добавить("Колонка" + НомерКолонки); 

       КонецЦикла; 

       ДобавитьКолонки = Ложь; 

   КонецЕсли; 

    

   НоваяСтрока = ТЗ.Добавить(); 

    

   НомерКолонки = 0; 

   Для Каждого Совпадение Из Результат Цикл 

        

       Значение = Совпадение.Value; 

        

       НоваяСтрока[НомерКолонки] = ?(Значение = "|", "", Значение); 

       НомерКолонки = НомерКолонки + 1; 

   КонецЦикла; 

КонецЦикла; 



ВремяОкончания = ТекущаяДата(); 



Сообщить("Обработка завершена: " + ВремяОкончания + ", время обработки: " + Формат('00010101' + (ВремяОкончания-ВремяНачала), "ДФ=мм:сс")); 

Сообщить("Количество строк: " + ТЗ.Количество());

Код 1C v 8.х

 // Пример  aleks-id

Функция InitRegExp(Разделитель = "|")

    RegExp = Новый COMОбъект("VBScript.RegExp");

    

    //Параметры: 

    RegExp.MultiLine = Истина;  // истина — текст многострочный, ложь — одна строка 

    RegExp.Global = Истина;   // истина — поиск по всей строке, ложь — до первого совпадения 

    RegExp.IgnoreCase = Ложь; // истина — игнорировать регистр строки при поиске 

    

    RegExp.Pattern = "[^\" + Разделитель + "]+";

    Возврат RegExp;

КонецФункции



Функция РазложитьСтрокуВМассив(RegExp, Строка)

    

    Matches = RegExp.Execute (Строка);

    

    Массив = Новый Массив;

    

    Для Сч = 0 По Matches.Count - 1 Цикл

        Массив.Добавить(Matches.Item(Сч).Value);

    КонецЦикла;

    

    

    Возврат Массив;

КонецФункции



Процедура КнопкаВыполнитьНажатие(Кнопка)

    Текст = Новый ЧтениеТекста("C:\aktivy.txt", КодировкаТекста.ANSI);

    RegExp = InitRegExp();

    Стр = Текст.ПрочитатьСтроку();

    Пока Стр <> Неопределено Цикл

        масс = РазложитьСтрокуВМассив(RegExp, Стр);

        Стр = Текст.ПрочитатьСтроку();

    КонецЦикла;

    RegExp = Неопределено;

КонецПроцедуры

Категория: Регулярные выражения

Чтение и Вывод данных в Excel

Замечание: В Excel разделителем дробной части считается символ ",". Поэтому перед сохранением таблицы 1С в формате Excel замените в ней другой разделитель (например ".") на ",". Иначе в Excel с этими числами не удастся произвести вычисления, или они вообще не будут отображаться как числа. Например, в таблице 1С "15.2" отобразится в Excel как "15.фев".

Для 8.х заменить СоздатьОбъект( на Новый COMОбъект(

Чтение (Получение) данных из Excel
Доступ из 1С к Excel производится посредством OLE. Например, код

Код 1C v 7.x

 Попытка

 Эксель = СоздатьОбъект("Excel.Application");

Исключение

 Сообщить(ОписаниеОшибки() + " Программа Exсel не установлена на данном компьютере!");

 Возврат;

КонецПопытки;

позволит получить доступ через переменную "Эксель" к запущенному приложению Excel. А далее уже можно получить доступ к книге (файлу), листу и ячейке с данными.Чтобы открыть книгу (файл)

Код 1C v 7.x

 Книга = Эксель.WorkBooks.Open(ПутьКФайлу);

//ПутьКФайлу - полный путь к файлу книги Excel.



//Выбор листа книги для работы с ним:

Лист = Книга.WorkSheets(НомерЛиста);

//или

Лист = Книга.WorkSheets(ИмяЛиста);

// где НомерЛиста - номер листа в книге, ИмяЛиста - имя листа в книге.



// Получение значения ячейки листа:

Значение = Лист.Cells(НомерСтроки, НомерКолонки).Value;

// где НомерСтроки, НомерКолонки - номер строки и номер колонки, на пересечении которых находится ячейка.

Важно: не забывайте поле выполнения нужных действий добавлять код

Код 1C v 7.x

 Эксель.Quit();

, иначе запущенный процесс останется незавершенным и будет занимать память и процессор компьютера.

Вывод данных в Excel
Для вывода (выгрузки) данных в Excel необходимо либо открыть существующую книгу, либо создать новую, и выбрать рабочий лист для вывода данных. Открытие существующей книги описано выше, а для создания новой книги нужно использовать следующий код:

Код 1C v 7.x

 Попытка

 Эксель = СоздатьОбъект("Excel.Application");

Исключение

 Сообщить(ОписаниеОшибки() + " Программа Exсel не установлена на данном компьютере!");

 Возврат;

КонецПопытки;



Книга = Эксель.WorkBooks.Add();

Так как при создании книги в Excel автоматически создаются листы (Сервис->Параметры->Общие->Листов в новой книге), то нужно лишь произвести выбор листа, с которым будет вестись работа:

Код 1C v 7.x

 Лист = Книга.WorkSheets(НомерЛиста);



// либо добавить в книгу новый лист, если необходимо:

Лист = Книга.Sheets.Add();

Следующим шагом будет установка значения ячейки:

Код 1C v 7.x

 Лист.Cells(НомерСтроки, НомерКолонки).Value = Значение;

// где НомерСтроки, НомерКолонки - номер строки и номер колонки, на пересечении которых находится ячейка.

И в конце нужно произвести запись созданной книги:

Код 1C v 7.x

 Попытка

 Книга.SaveAs(ПутьКФайлу);

Исключение

 Сообщить(ОписаниеОшибки()+" Файл не сохранен!");

 Возврат;

КонецПопытки;

// где ПутьКФайлу - полный путь к файлу книги Excel (включая имя).

Важно: не забывайте, что в имени файлов не должно содержаться символов \ / : * ? " > <

Категория: Работа с Microsoft Office и OpenOffice

Получение всех родителей элемента справочника

В языке запросов не предусмотрено специальных средств для получения всех родителей элемента. Для выполнения задачи можно воспользоваться иерархическими итогами, однако получение иерархических итогов оптимизировано для построения итогов большого количества записей, и не вполне эффективно для получения родителей одного элемента. Для более эффективного получения всех родительских записей элемента, рекомендуется перебирать в цикле его родителей небольшими порциями. Пример:

Код 1C v 8.х

 ТекущийЭлементНоменклатуры = ЭлементНоменклатура;



Запрос = Новый Запрос("ВЫБРАТЬ 

                      | Номенклатура.Родитель, 

                      | Номенклатура.Родитель.Родитель, 

                      | Номенклатура.Родитель.Родитель.Родитель, 

                      | Номенклатура.Родитель.Родитель.Родитель.Родитель, 

                      | Номенклатура.Родитель.Родитель.Родитель.Родитель.Родитель 

                      |ИЗ 

                      | Справочник.Номенклатура КАК Номенклатура 

                      |

                      |ГДЕ 

                      | Номенклатура.Ссылка = &ТекущийЭлементНоменклатуры"; 



Пока Истина Цикл 

    Запрос.УстановитьПараметр("ТекущийЭлементНоменклатуры", ТекущийЭлементНоменклатуры); 

    Результат = Запрос.Выполнить(); 

    Если Результат.Пустой() Тогда 

        Прервать; 

    КонецЕсли; 

    Выборка = Результат.Выбрать(); 

    Выборка.Следующий(); 

    Для НомерКолонки = 0 По Результат.Колонки.Количество() - 1 Цикл 

        ТекущийЭлементНоменклатуры = Выборка[НомерКолонки]; 

        Если ТекущийЭлементНоменклатуры = Справочники.Номенклатура.ПустаяСсылка() Тогда 

            Прервать; 

        Иначе 

            Сообщить(ТекущийЭлементНоменклатуры); 

        КонецЕсли; 

    КонецЦикла; 



    Если ТекущийЭлементНоменклатуры = Справочники.Номенклатура.ПустаяСсылка() Тогда 

        Прервать; 

    КонецЕсли; 

КонецЦикла;

В данном примере в окно служебных сообщений выводятся все родители для ссылки, записанной в переменную ЭлементНоменклатура. В цикле выбирается по 5 родителей ссылки.

Если число уровней в справочнике ограничено и невелико, то возможно получение всех родителей одним запросом без цикла.

Категория: Справочники

Функция выгружает справочник в таблицу значений

Пример выгрузки(помещения) справочника в Таблицу Значений (ТЗ):

Код 1C v 7.x

  // Параметры:

//		ВидСправочника				-	Строка, указывающая вид справочника, как он задан в конфигураторе

//		ДобавлятьЭлементыСправочника		-	1-	добавить колонку с наименованием "Элемент", содержащую элементы справочников, 0 - не добавлять колонку

//		ИмяРеквизита 				-	Имя реквизита, как он задан в конфигураторе. Используется при заполнении таблицы из выборки по значению реквизита.

//		ЗначениеРеквизита			-	Значение реквизита, по которому надо построить выборку. Используется при заполнении таблицы из выборки по значению реквизита.

//		ЭлементВладелец 				-	Владелец, указывается для подчиненных справочников

//		ЭлементРодитель 				-	Родитель, используется в случае, если надо ограничить выборку условием принадлежности элементов одной группе

//		ВключатьПодчиненные 			-	Установить флаг выборки всех подчиненных элементов.

//		Иерархия				-   Флаг указывающий на то как выбирать элементы (1 - выбирать элементы с учетом иерархии, 0 - выбирать элементы без учета иерархии)

//		ВОбратномПорядке			-	Число: 1 - выбирать элементы справочника в обратном порядке; 0 - выбирать элементы справочника в прямом порядке

//		ВключатьГруппы				-	1 - выбирать среди групп справочника, 0 - выбирать только среди элементов

//

// Возвращает: Таблица значений, колонками которой, являются реквизиты справочника



Функция СправочникВТЗ(ВидСправочника, ДобавлятьЭлементыСправочника = 0,ИмяРеквизита = 0, ЗначениеРеквизита = 0, ЭлементВладелец = 0, ЭлементРодитель = 0, ВключатьПодчиненные = 1, Иерархия = 1, ВОбратномПорядке = 0, ВключатьГруппы = 0) Экспорт

	

	ТаблицаСпр			=	СоздатьОбъект("ТаблицаЗначений");

	мдСпр				=	Метаданные.Справочник(ВидСправочника);

	ВсегоРеквизитовСпр	=	мдСпр.Реквизит();

	Для индРекв			= 	1 по ВсегоРеквизитовСпр Цикл

		Вид = мдСпр.Реквизит(индРекв).Вид;

		ТаблицаСпр.НоваяКолонка(мдСпр.Реквизит(индРекв).Идентификатор, мдСпр.Реквизит(индРекв).Тип + ?(ПустоеЗначение(Вид) = 0, "." + Вид, ""), мдСпр.Реквизит(индРекв).Длина, мдСпр.Реквизит(индРекв).Точность);

	КонецЦикла;

	ТаблицаСпр.НоваяКолонка("Код", ?(мдСпр.ТипКода = "Текстовый", "Строка", "Число"), мдСпр.ДлинаКода);

	ТаблицаСпр.НоваяКолонка("Наименование", "Строка", мдСпр.ДлинаНаименования);

	Если ДобавлятьЭлементыСправочника = 1 тогда

		ТаблицаСпр.НоваяКолонка("Элемент", "Справочник." + ВидСправочника);

	КонецЕсли;

	Спр = СоздатьОбъект("Справочник." + ВидСправочника);

	Если ЭлементВладелец <> 0 тогда

		Спр.ИспользоватьВладельца(ЭлементВладелец);

	КонецЕсли;

	Если ЭлементРодитель <> 0 тогда

		Спр.ИспользоватьРодителя(ЭлементРодитель);

	КонецЕсли;

	Спр.ОбратныйПорядок(ВОбратномПорядке);

	Спр.ВключатьПодчиненные(ВключатьПодчиненные);

	Если ИмяРеквизита = 0 тогда

		Спр.ВыбратьЭлементы(Иерархия);

	Иначе

		Спр.ВыбратьЭлементыПоРеквизиту(ИмяРеквизита, ЗначениеРеквизита, Иерархия, ВключатьГруппы);

	КонецЕсли;

	

	Пока Спр.ПолучитьЭлемент() = 1 Цикл

		      

		ТаблицаСпр.НоваяСтрока();

		ТекущаяСтрока	=	ТаблицаСпр.НомерСтроки;

		Для НомерКолонки= 	1 по ВсегоРеквизитовСпр Цикл

			ТаблицаСпр.УстановитьЗначение(ТекущаяСтрока, НомерКолонки, Спр.ПолучитьАтрибут(мдСпр.Реквизит(НомерКолонки)));

		КонецЦикла;

		ТаблицаСпр.Код			=	Спр.Код;

		ТаблицаСпр.Наименование	=	Спр.Наименование;

		Если ДобавлятьЭлементыСправочника = 1 тогда

			ТаблицаСпр.УстановитьЗначение(ТекущаяСтрока, "Элемент", Спр.ТекущийЭлемент());

		КонецЕсли;

		

	КонецЦикла;

	

	Возврат ТаблицаСпр;	

КонецФункции

Новинки игровых автоматов с возможностью играть на бездепозитный бонус за регистрацию в онлайн казино на деньги.

Категория: Справочники

Функция загружает весь табличный документ в таблицу значений

Код 1C v 8.х

  // Вариант 1

// По переданному табличному документу возвращает таблицу значений, 

// при условии что в первой строке таблицы - идентификаторы колонок 

// Автор : dimoff

Функция ПолучитьТЗИзМакета(ТабДок, КолонкаИндекса = 1) Экспорт

    

    ТаблицаДанных = Новый ТаблицаЗначений;

    НомерКолонки = 0;

    Пока Истина Цикл

        НомерКолонки = НомерКолонки + 1;

        ИмяКолонки = ТабДок.Область(1, НомерКолонки).Текст;

        Если ПустаяСтрока(ИмяКолонки) Тогда

            Прервать;

        КонецЕсли;        

        ТаблицаДанных.Колонки.Добавить(ИмяКолонки);

    КонецЦикла;

    

    СчетчикКолонок = НомерКолонки - 1;

    

    НомерСтроки = 1; ФлагПрерывания = Ложь;

    Пока Истина Цикл

        НомерСтроки = НомерСтроки + 1;

        Стр = ТаблицаДанных.Добавить();

        

        Для А = 1 ПО СчетчикКолонок Цикл

            ТекстКолонки = ТабДок.Область(НомерСтроки, А).Текст;

            Если ПустаяСтрока(ТекстКолонки) Тогда

                Если А = КолонкаИндекса Тогда

                    Флагпрерывания = Истина;

                    ТаблицаДанных.Удалить(Стр);

                КонецЕсли;

            Иначе

                Стр[А - 1] = ТекстКолонки

            КонецЕсли;

            

            Если Флагпрерывания Тогда

                Прервать

            КонецЕсли;

        КонецЦикла;

        

        Если Флагпрерывания Тогда

            Прервать

        КонецЕсли;

    КонецЦикла;

    

    Возврат ТаблицаДанных

КонецФункции



// Варинат 2

//Функция загружает весь макет, табличный документ в таблицу значений

//Первая строка содержит подписи колонок (должны быть правильные идентификаторы)

//Пустые строки (состоящией из пробелов, переводов строки и т.п.) заменяет на Неопределено

//Если в ячейке есть значение, в ячейку таблицы значений попадает именно это значение

//Автор : Гений1С

Функция обМакетВТаблицуЗначений(Макет) Экспорт

    Перем ТЗ;

ТЗ=Новый ТаблицаЗначений();

#Если Клиент Тогда

    //Считываем колонки

	Для Стр=1 По Макет.ВысотаТаблицы Цикл

		Если Стр>1 Тогда

        	ТекСтр=ТЗ.Добавить();

		КонецЕсли;

		ПустаяСтрока=истина;

		Для Кол=1 По Макет.ШиринаТаблицы Цикл

			Яч=Макет.Область(Стр, Кол);

			Если Яч.СодержитЗначение Тогда

				Зн=Яч.Значение;

			Иначе

				Зн=Яч.Текст;

			КонецЕсли;

			Если ТипЗнч(Зн)=Тип("Строка") И ПустаяСтрока(Зн) Тогда

				Зн=Неопределено;

			КонецЕсли;

			

			//Добавляем колонку

			Если Стр=1 Тогда

		        ТЗ.Колонки.Добавить(Зн);

			Иначе

				ТекСтр[Кол-1]=Зн;

			КонецЕсли;

		КонецЦикла;

	КонецЦикла;

#КонецЕсли

   Возврат ТЗ;

КонецФункции

Категория: Табличный документ

Автоматическая установка ширины колонки табличного документа.

Процедура, которая "примерно" делает автоширину колонок (навроде, как если бы выделить все колонки и дважды щелкнуть мышкой по границе заголовка колонки). Привожу текст, работает неахти, но лучше чем ничего:

Код 1C v 8.х

 Процедура РасчетШириныКолонок(ТабличныйДокумент)

    

    Перем МаксимальноеКоличествоСтрок, МаксимальнаяШиринаКолонки;

    Перем КонечнаяСтрока, НачальнаяСтрока, ТекущаяКолонка, ТекущаяСтрока, НачалоДанных;

    Перем ОбластьШапки, ОбластьПодвала;

    Перем ШиринаКолонки, ТекстЯчейки, НомерСтрокиТекста;

    Перем КоличествоУровнейГруппировокСтрок, Отступ;

    Перем ШириныКолонок;

    

    // Максимальное количество строк отчета, которые будут использованы для расчета ширин колонок

 

    МаксимальноеКоличествоСтрок = 50;

    // Ограничение максимальной ширины колонки

 

    МаксимальнаяШиринаКолонки = 50;

    // Массив, в который будут помещаться ширины колонок

 

    ШириныКолонок = Новый Массив;

    // Получим количество уровней группировок в отчете для учета автоматического отступа

 

    КоличествоУровнейГруппировокСтрок = ТабличныйДокумент.КоличествоУровнейГруппировокСтрок();

    

    // Инициализируем начальные строки

 

    НачальнаяСтрока = 0;

    НачалоДанных = 0;

    

    // Найдем в результирующем документе область шапки таблицы

 

    ОбластьШапки = ТабличныйДокумент.Области.Найти("ШапкаТаблицы");

    Если ТипЗнч(ОбластьШапки) = Тип("ОбластьЯчеекТабличногоДокумента") Тогда

        

        // Из шапки таблицы получим начальную строку с которой будем рассчитывать ширины

         НачальнаяСтрока = ОбластьШапки.Верх;

        НачалоДанных = ОбластьШапки.Низ + 1;

    Иначе

        

        // Если область шапки таблицы не найдена, найдем область шапки строк

         ОбластьШапки = ТабличныйДокумент.Области.Найти("ШапкаСтрок");

        Если ТипЗнч(ОбластьШапки) = Тип("ОбластьЯчеекТабличногоДокумента") Тогда

            

            // Из шапки таблицы получим начальную строку с которой будем рассчитывать ширины

             НачальнаяСтрока = ОбластьШапки.Верх;

            НачалоДанных = ОбластьШапки.Низ + 1;

            

        КонецЕсли;

    КонецЕсли;

    

    // Получим область подвала отчета и вычислим конечную строку расчета

 

    ОбластьПодвала = ТабличныйДокумент.Области.Найти("Подвал");

    Если ТипЗнч(ОбластьПодвала) = Тип("ОбластьЯчеекТабличногоДокумента") Тогда

        // Область подвала найдена

        КонечнаяСтрока = ОбластьПодвала.Верх - 1;

        Если КонечнаяСтрока - НачальнаяСтрока > МаксимальноеКоличествоСтрок Тогда

            КонечнаяСтрока = НачальнаяСтрока + МаксимальноеКоличествоСтрок;

        КонецЕсли;

    Иначе 

            // Область подвала не найдена

        КонечнаяСтрока = НачальнаяСтрока + МаксимальноеКоличествоСтрок;

    КонецЕсли;

    

    // Ограничим конечную строку

    КонечнаяСтрока = Мин(КонечнаяСтрока, ТабличныйДокумент.ВысотаТаблицы);

    // Переберем все колонки отчета

    Для ТекущаяКолонка = 1 По ТабличныйДокумент.ШиринаТаблицы Цикл

        АвтоОтступ = 0;

        // Переберем строки, которые будут использованы для расчета ширин колонок

        Для ТекущаяСтрока = НачальнаяСтрока По КонечнаяСтрока Цикл

            ШиринаКолонки = 0;

            // Получим область текущей ячейки

            ОбластьЯчейки = ТабличныйДокумент.Область(ТекущаяСтрока, ТекущаяКолонка);

            Если ОбластьЯчейки.Лево <> ТекущаяКолонка Или ОбластьЯчейки.Верх <> ТекущаяСтрока Тогда

                // Данная ячейка принадлежит объединенным ячейкам и не является начальной ячейкой

                Продолжить;

            КонецЕсли;

            Если КоличествоУровнейГруппировокСтрок > 0 И ТекущаяСтрока = НачалоДанных Тогда

                // Для первой строки с данными получим значение автоотступа

                АвтоОтступ = ОбластьЯчейки.АвтоОтступ;

            КонецЕсли;

            // Получим текст ячейки

            ТекстЯчейки = ОбластьЯчейки.Текст;

            // Для каждой строки из текста ячейки рассчитаем количество символов в строке

            Для НомерСтрокиТекста = 1 По СтрЧислоСтрок(ТекстЯчейки) Цикл

                ШиринаТекстаЯчейки = СтрДлина(СтрПолучитьСтроку(ТекстЯчейки, НомерСтрокиТекста));

                // Если используется автоотступ, то прибавим к ширине ячейки его величину

                Если АвтоОтступ <> Неопределено И АвтоОтступ > 0 Тогда

                    ШиринаТекстаЯчейки = ШиринаТекстаЯчейки + КоличествоУровнейГруппировокСтрок * АвтоОтступ;

                КонецЕсли;

                ШиринаКолонки = Макс(ШиринаКолонки, ШиринаТекстаЯчейки);

            КонецЦикла;



            Если ШиринаКолонки > МаксимальнаяШиринаКолонки Тогда

                // Ограничим ширину колонки

                ШиринаКолонки = МаксимальнаяШиринаКолонки;

            КонецЕсли;

            Если ШиринаКолонки <> 0 Тогда

                // Ширина колонки рассчитана

                // Определим, сколько ячеек по ширине используется в области для текущей ячейки

                КоличествоКолонок = ОбластьЯчейки.Право - ОбластьЯчейки.Лево;

                // Переберем все ячейки, расположенные в области

                 Для НомерКолонки = 0 По КоличествоКолонок Цикл

                    Если ШириныКолонок.ВГраница() > ТекущаяКолонка - 1 + НомерКолонки Тогда

                        // В массиве ширин колонок уже был элемент для текущей колонки

                        Если ШириныКолонок[ТекущаяКолонка - 1 + НомерКолонки] = Неопределено Тогда

                            // Значение ширины колонки еще не было установлено

                            ШириныКолонок[ТекущаяКолонка - 1 + НомерКолонки] = ШиринаКолонки / (КоличествоКолонок + 1);

                        Иначе

                            // Значение ширины колонки уже было установлено

                             // Вычислим максимум ширины колонки

                             ШириныКолонок[ТекущаяКолонка - 1 + НомерКолонки] = 

                                Макс(ШириныКолонок[ТекущаяКолонка - 1 + НомерКолонки], ШиринаКолонки / (КоличествоКолонок + 1));

                        КонецЕсли;

                    Иначе

                        // В массиве ширин колонок еще не было элемента для данной колонки

                        // Добавим элемент в массив ширин колонок

                        ШириныКолонок.Вставить(ТекущаяКолонка - 1 + НомерКолонки, ШиринаКолонки / (КоличествоКолонок + 1));

                    КонецЕсли;

                КонецЦикла;

            КонецЕсли;

        КонецЦикла;    // Конец цикла перебора строк

    КонецЦикла;    // Конец цикла перебора колонок

    

    // Переберем все элементы в массиве вычисленных ширин колонок

     Для ТекущаяКолонка = 0 По ШириныКолонок.ВГраница() Цикл

        Если ШириныКолонок[ТекущаяКолонка] <> Неопределено Тогда

            // Ширина колонок установлена

            // Установим ширину области ячеек

            ТабличныйДокумент.Область(, ТекущаяКолонка + 1, НачалоДанных, ТекущаяКолонка + 1).ШиринаКолонки = ШириныКолонок[ТекущаяКолонка] + 1;

        КонецЕсли;

    КонецЦикла;

КонецПроцедуры

Очень полезная штука при условии, что у Вас заранее невозможно определить размер итоговых колонок в печатной форме. А так, надо просто "натравить" процедуру с соответствующими параметрами на нужные ячейки таблицы, и они сами "выровняются" и приобретут необходимый размер (ширину).

Код 1C v 7.x

 //<!-- Патырило С.С. 22-04-2004 : Автоматическая установка ширины колонки

//  Для изменения ширины колонки уже сформированной таблицы, требуется передать

// в качестве параметров переменную с объектом "Таблица", координаты ячейки (группы ячеек)

// для которых нужно установить ширину столбца и ширину столбца в символах.

// При этом не обязательно передавать координаты требуемой ячейки (итоговой),

// (т.е. когда нет возможности или сложно определить позицию итоговой строки)

// достаточно указать ячейку из данного столбца (например первую).

//  Процедура установит ширину столбца выбрав максимальное из значений - 

// текущего размера (установленного в конфигураторе, или программно перед вызовом 

// функции) и переданного в качестве параметра. 

Процедура глУстШиринуЯчейки(Таб, Строка1, Столбец1, Строка2, Столбец2, ДлТекста = 0) Экспорт

	Если ДлТекста = 0 Тогда

	    врДлина	= СтрДлина(СокрЛП(Таб.Область(Строка1, Столбец1, Строка2, Столбец2).Текст));

	Иначе

		врДлина	= ДлТекста;

	КонецЕсли;

	Таб.Область(Строка1, Столбец1, Строка2, Столбец2).ШиринаСтолбца(Макс(Таб.Область(Строка1, Столбец1, Строка2, Столбец2).ШиринаСтолбца(), врДлина));

КонецПроцедуры

// --> Патырило С.С. 22-04-2004

Категория: Табличный документ

Подключение к EXCEL и чтение данных из листа Excel

Код 1C v 8.х

 Ex = Новый COMObject("Excel.Application");

   Ex.Workbooks.Open(Путь);

   Ex.Visible = 1;    

   ТекЛист=Ex.WorkSheets(1);        

   Для Ячейка = 1 по 400 цикл

       Если НЕ  ТекЛист.Cells(Ячейка,1).Value  = Неопределено тогда

           Сообщить(Строка(ТекЛист.Cells(Ячейка,1).Value));    

           Карта = Справочники.Номенклатура.НайтиПоКоду(ИзЧислаВСтроку(ТекЛист.Cells(Ячейка,1).Value));    

           Если Карта.Пустая() тогда        

               Сообщить(" Пустой элемент "  + ТекЛист.Cells(Ячейка,1));

           иначе

               Объект = Карта.ПолучитьОбъект();

               Объект.ОсновнойПоставщик = ОсновнойКлиент;

               Объект.Записать();

               конецесли;    

       конецесли;

   конеццикла;

Примеры процедур для чтения данных из EXCEL

Код 1C v 8.х

 

// Функция получает данные из файла Excel

//

// Параметры:

//   пФайл - Имя файла

//   пЛист - Имя листа с данными

//   СтруктураКолонок - Структура вида "ИмяКолонки" - "НомерКолонки"

//                      если не задано, созадуться колонки вида "К1", "К2"

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция Excel_ПолучитьДанные_ADO(пФайл, пЛист, СтруктураКолонок = Неопределено, Знач НачСтрока = 0, Знач КонСтрока = 0) Экспорт



    #Если Клиент Тогда

    Состояние("Установка соединения с Excel");

    #КонецЕсли



    //ЗаголовкиВСтроке1 = "HDR=YES;"

    ЗаголовкиВСтроке1 = "HDR=NO;";



    СтрокаСоединения ="Provider=Microsoft.Jet.OLEDB.4.0;Data Source= " + СокрЛП(пФайл) +" ;Extended Properties=""Excel 8.0;" + ЗаголовкиВСтроке1 + "IMEX=1;""";



    Connection = Новый COMОбъект("ADODB.Connection");

    Connection.ConnectionString =  СтрокаСоединения;



    Попытка

        Connection.Open();

    Исключение

        Сообщить ("Проблемы с подключением к Excel" );

        Возврат Неопределено;

    КонецПопытки;



    RS = Новый COMОбъект("ADODB.Recordset");



    ТекстЗапроса =

    "S_elect

    |    Лист.*

    |FROM

    |    [" + пЛист + "$] as Лист";



    Попытка

        RS.Open(ТекстЗапроса, Connection);

    Исключение

        Сообщить ("Проблемы с выполнением запроса");

        Возврат Неопределено;

    КонецПопытки;



    Таблица = Новый ТаблицаЗначений;



    Если СтруктураКолонок = Неопределено Тогда



        Для Счетчик = 1 По RS.Fields.Count Цикл

            Поле = RS.Fields.Item(Счетчик - 1);

            Колонка = Таблица.Колонки.Добавить("К" + Счетчик, , Поле.Name);

        КонецЦикла;



    Иначе



        Для каждого КлючИЗначение Из СтруктураКолонок Цикл

            Колонка = Таблица.Колонки.Добавить(КлючИЗначение.Ключ);

        КонецЦикла;



    КонецЕсли;



    НомерСтроки = 0;

    КолвоСтрок  = RS.RecordCount;



    Пока RS.EOF() = 0 Цикл



        НомерСтроки = НомерСтроки + 1;



        #Если Клиент Тогда

        Состояние("Чтение файла: " + Формат(НомерСтроки) + " из " + Формат(КолвоСтрок));

        ОбработкаПрерыванияПользователя();

        #КонецЕсли



        Если НомерСтроки < НачСтрока Тогда

            RS.MoveNext();

            Продолжить;

        КонецЕсли;



        Если КонСтрока > 0 И НомерСтроки > КонСтрока Тогда

            Прервать;

        КонецЕсли;



        НоваяСтрока = Таблица.Добавить();



        Если СтруктураКолонок = Неопределено Тогда



            Для Счетчик = 1 По RS.Fields.Count Цикл



                Поле = RS.Fields.Item(Счетчик - 1);

                НоваяСтрока["К" + Счетчик] = Поле.Value;



            КонецЦикла;



        Иначе



            Для каждого КлючИЗначение Из СтруктураКолонок Цикл



                Поле = RS.Fields.Item(КлючИЗначение.Значение - 1);

                НоваяСтрока[КлючИЗначение.Ключ] = Поле.Value;



            КонецЦикла;



        КонецЕсли;



        // Обработка других полей

        RS.MoveNext();



    КонецЦикла;



    // Завершение работы



    RS.Close();

    Connection.Close();



    Возврат Таблица;



КонецФункции



// Функция получает данные из файла Excel

//

// Параметры:

//   пФайл     - Имя файла

//   пЛист     - Имя листа с данными

//   СтруктураКолонок - Структура вида "ИмяКолонки" - "НомерКолонки"

//                      если не задано, созадуться колонки вида "К1", "К2"

//   XLSОбъект - COM объект типа "Excel.Application"

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция Excel_ПолучитьДанные_COM(пФайл, пЛист, СтруктураКолонок = Неопределено, Знач НачСтрока = 0, Знач КонСтрока = 0, XLSОбъект = Неопределено) Экспорт



    #Если Клиент Тогда

    Состояние("Открытие Excel");

    #КонецЕсли



    Если XLSОбъект = Неопределено Тогда

        XLSОбъект = Новый COMОбъект("Excel.Application");

        XLSОбъект.Visible       = Ложь;

        XLSОбъект.DisplayAlerts = Ложь;

    КонецЕсли;



    Попытка

        Book = XLSОбъект.Workbooks.Open(пФайл, , Истина);

    Исключение

        Сообщить ("Проблемы с подключением к Excel" );

        Возврат Неопределено;

    КонецПопытки;



    Лист = Book.Sheets(1);

    КолвоКолонок = Лист.Cells(1,1).SpecialCells(11).Column;

    КолвоСтрок   = Лист.Cells(1,1).SpecialCells(11).Row;



    Таблица = Новый ТаблицаЗначений;



    Если СтруктураКолонок = Неопределено Тогда



        Для Счетчик = 1 По КолвоКолонок Цикл

            Колонка = Таблица.Колонки.Добавить("К" + Счетчик);

        КонецЦикла;



    Иначе



        Для каждого КлючИЗначение Из СтруктураКолонок Цикл

            Колонка = Таблица.Колонки.Добавить(КлючИЗначение.Ключ);

        КонецЦикла;



    КонецЕсли;



    НачСтрока = ?(НачСтрока = 0, 1, НачСтрока);

    КонСтрока = ?(КонСтрока = 0, КолвоСтрок, КонСтрока);

    КонСтрока = Мин(КонСтрока, КолвоСтрок);



    Для НомерСтроки = НачСтрока По КонСтрока Цикл



        #Если Клиент Тогда

        Состояние("Чтение файла: " + Формат(НомерСтроки) + " из " + Формат(КонСтрока));

        ОбработкаПрерыванияПользователя();

        #КонецЕсли



        НоваяСтрока = Таблица.Добавить();



        Если СтруктураКолонок = Неопределено Тогда



            Для НомерКолонки = 1 По КолвоКолонок Цикл



                Поле = Лист.Cells(НомерСтроки, НомерКолонки);

                НоваяСтрока["К" + Формат(НомерКолонки, "ЧГ=0")] = Поле.Value;



            КонецЦикла;



        Иначе



            Для каждого КлючИЗначение Из СтруктураКолонок Цикл



                Поле = Лист.Cells(НомерСтроки, КлючИЗначение.Значение);

                НоваяСтрока[КлючИЗначение.Ключ] = Поле.Value;



            КонецЦикла;



        КонецЕсли;



    КонецЦикла;



    XLSОбъект.Application.Quit();

    Возврат Таблица;



КонецФункции



// Функция получает данные из файла Excel

//

// Параметры:

//   пФайл     - Имя файла

//   пЛист     - Имя листа с данными

//   СтруктураКолонок - Структура вида "ИмяКолонки" - "НомерКолонки"

//                      если не задано, созадуться колонки вида "К1", "К2"

//   XLSОбъект - COM объект типа "Excel.Application"

//

// Возвращаемое значение:

//   ТаблицаЗначений

//

Функция Excel_ПолучитьДанные_COMArray(пФайл, пЛист, СтруктураКолонок = Неопределено, Знач НачСтрока = 0, Знач КонСтрока = 0, XLSОбъект = Неопределено) Экспорт



    #Если Клиент Тогда

    Состояние("Открытие Excel");

    #КонецЕсли



    Если XLSОбъект = Неопределено Тогда

        XLSОбъект = Новый COMОбъект("Excel.Application");

        XLSОбъект.Visible       = Ложь;

        XLSОбъект.DisplayAlerts = Ложь;

    КонецЕсли;



    Попытка

        Book = XLSОбъект.Workbooks.Open(пФайл, , Истина);

    Исключение

        Сообщить ("Проблемы с подключением к Excel" );

        Возврат Неопределено;

    КонецПопытки;



    Лист = Book.Sheets(1);

    КолвоКолонок = Лист.Cells(1,1).SpecialCells(11).Column;

    КолвоСтрок   = Лист.Cells(1,1).SpecialCells(11).Row;



    Таблица = Новый ТаблицаЗначений;



    Если СтруктураКолонок = Неопределено Тогда



        Для Счетчик = 1 По КолвоКолонок Цикл

            Колонка = Таблица.Колонки.Добавить("К" + Счетчик);

        КонецЦикла;



    Иначе



        МаксимальныйНомерКолонки = 0;

        Для каждого КлючИЗначение Из СтруктураКолонок Цикл

            Колонка = Таблица.Колонки.Добавить(КлючИЗначение.Ключ);

            МаксимальныйНомерКолонки = Макс(МаксимальныйНомерКолонки, КлючИЗначение.Значение);

        КонецЦикла;



        КолвоКолонок = Мин(КолвоКолонок, МаксимальныйНомерКолонки);



    КонецЕсли;



    НачСтрока = ?(НачСтрока = 0, 1, НачСтрока);

    КонСтрока = ?(КонСтрока = 0, КолвоСтрок, КонСтрока);

    КонСтрока = Мин(КонСтрока, КолвоСтрок);



    // Массив типа COMSafeArray

    Массив = Лист.Range(Лист.Cells(НачСтрока, 1), Лист.Cells(КонСтрока, КолвоКолонок)).Value;

    КолвоСтрок   = Массив.GetUpperBound(1);



    Для НомерСтроки = 1 По КолвоСтрок Цикл



        #Если Клиент Тогда

        Состояние("Чтение файла: " + Формат(НомерСтроки) + " из " + Формат(КолвоСтрок));

        ОбработкаПрерыванияПользователя();

        #КонецЕсли



        НоваяСтрока = Таблица.Добавить();



        Если СтруктураКолонок = Неопределено Тогда



            Для НомерКолонки = 1 По КолвоКолонок Цикл



                НоваяСтрока["К" + Формат(НомерКолонки, "ЧГ=0")] = Массив.GetValue(НомерКолонки, НомерСтроки);



            КонецЦикла;



        Иначе



            Для каждого КлючИЗначение Из СтруктураКолонок Цикл



                НоваяСтрока[КлючИЗначение.Ключ] = Массив.GetValue(КлючИЗначение.Значение, НомерСтроки);



            КонецЦикла;



        КонецЕсли;



    КонецЦикла;



    XLSОбъект.Application.Quit();

    Возврат Таблица;



КонецФункции



// Функция получает список листов Excel

//

// Параметры:

//   пФайл - Имя файла

//   XLSОбъект - COM объект типа "Excel.Application"

//

// Возвращаемое значение:

//   СписокЗначений

//

Функция Excel_ПолучитьСписокЛистов(пФайл, XLSОбъект = Неопределено) Экспорт



    Если XLSОбъект = Неопределено Тогда

        XLSОбъект = Новый COMОбъект("Excel.Application");

        XLSОбъект.Visible       = Ложь;

        XLSОбъект.DisplayAlerts = Ложь;

    КонецЕсли;



    Попытка

        Book = XLSОбъект.Workbooks.Open(пФайл, , Истина);

    Исключение

        Возврат Новый СписокЗначений;

    КонецПопытки;



    СписокЛистов = Новый СписокЗначений;

    Для каждого Лист Из XLSОбъект.Sheets Цикл

        СписокЛистов.Добавить(Лист.Name);

    КонецЦикла;



    XLSОбъект.Application.Quit();

    Возврат СписокЛистов;



КонецФункции

Код 1C v 7.x

 Попытка

  Excel = СоздатьОбъект("Excel.Application");

 Исключение

  Сообщить(ОписаниеОшибки()+"; программа Excel не установлена на данном компьютере!");

     Возврат;

 КонецПопытки;

РабочиеКниги=Excel.WorkBooks;  // создаем рабочую книгу



 Попытка // открываем файл

  Отчет=РабочиеКниги.Open(Каталог+ИмяФайла); 

 Исключение 

  Сообщить(ОписаниеОшибки()+"; фаил с макросом не найден!");

  Возврат;

 КонецПопытки;



// заносим в таблицу какие-либо данные



 Лист = Отчет.Worksheets(1);



 Для Ном=1 По 20 Цикл

      Ячейка = Лист .Cells(ном,1); Ячейка.Value;

      Сообщить(Ячейка );

 КонецЦикла; 



Excel.Visible=1;



Попытка

      Отчет.Save();

Исключение

     Сообщить(ОписаниеОшибки()+"; не могу сохранить отчет!");

  Возврат;

 КонецПопытки;

Категория: Работа с Microsoft Office и OpenOffice