// оперделим два массива для формирования S-Блока

перем масТемп[254], масSБлок[254];

// переменая для управления объектом Script Control

перем олеШелл;



//*******************************************

// стрКодировать(стрИсточник, стрКлюч)

//

// Параметры:

//  стрИсточник - Строка. Набор симвлов для преобразования.

//  стрКлюч - Строка. Набор симвлов для формирования S-Блока.

//

// Возвращаемое значение:

//  Строка. Набор симвлов после преоброзования.

//

// Описание:

//  Функция шифрует или дешифрует набор символов с помощью

//  S-Блока сформированного на основе ключа.

//

функция стрКодировать(стрИсточник, стрКлюч)

    // Инициализация данных для формирования S-Блока

    чисДлинаКлюча = стрдлина(стрКлюч);

    у = 0;

    для х = 1 по 254 цикл

        у = у + 1;

        у = ?(у > чисДлинаКлюча, 1, у);

        масТемп[х] = кодсимв(сред(стрКлюч, у, 1));

        масSБлок[х] = х - 1;

    конеццикла;

    // Формирование S-Блока

    у = 0;

    для х = 1 по 254 цикл

        у = (у + масТемп[х] + масSБлок[х]) % 254 + 1;

        чисТемп = масSБлок[х];

        масSБлок[х] = масSБлок[у];

        масSБлок[у] = чисТемп;

    конеццикла;

    // Ну и сообственно преобразование

    чисДлинаТекста = стрдлина(стрИсточник);

    у = 0;

    ч = 0;

    для х = 1 по чисДлинаТекста цикл

        чисБайт = кодсимв(сред(стрИсточник, х, 1));

        у = (у + 1) % 254 + 1;

        ч = (ч + масSБлок[у]) % 254 + 1;

        чисТемп = масSБлок[у];

        масSБлок[у] = масSБлок[ч];

        масSБлок[ч] = чисТемп;

        чисТемп = масSБлок[(масSБлок[у] + масSБлок[ч]) % 254 + 1];

        чисБайт = число(олеШелл.Run("intXOR", чисБайт, чисТемп));

        Ответ = Ответ + симв(чисБайт);

    конеццикла;

    // Возвращаем полученную строку

    возврат Ответ;

конецфункции



//*******************************************

// Этот блок обязателен.

// Необходимо что бы он отработал до первого вызова

// функции стрКодировать

//*******************************************

// Создаем объект для управления скриптами

олеШелл = создатьобъект("MSScriptControl.ScriptControl");

// Устанавливаем рабочий язык для выполнения скриптов

олеШелл.Language = "VBScript";

// Сам срипт для проведения логически-исключающего сложение двух операндов

стрКод =

"function intXOR(x, y)

|  intXOR = x xor y

|end function";

// Добавим наш скрипт в котрол скриптов

олеШелл.AddCode(стрКод);



Ответ = стрКодировать("Это пример реализации алгоритма шифрования RC4 на языке 1С", "Казахстанский Клуб профессионалов 1С");

сообщить(Ответ);

Ответ = стрКодировать(Ответ, "Казахстанский Клуб профессионалов 1С");

сообщить(Ответ);

 // Глобальная переменная в которой будем хранить

// известные нам типы статусов сетевой карты

перем сзТипСтатуса;

// Глобальная переменая

перем обШелл;



//*******************************************

// стрСтатусАдаптера(стрИмя = "")

//

// Параметры:

//  стрИмя - Строка. Имя сетевой статус которой надо определить.

//           В том виде как показа в сетвых подключениях.

//

// Возвращаемое значение:

//  Строка. Статус заданой сетевой.

//

// Описание:

//  Функция определяет статус сетевой.

//

функция стрСтатусАдаптера(стрИмя = "")

    Ответ = "";

    // Попытаемся получить статус через контрол скриптов

    попытка

        сзСтевые = создатьобъект("списокзначений");

        // Выполняем скрипт. Из полученного значения пытаемся

        // сформировать список значений

        сзСтевые = значениеизстроки(обШелл.Run("strGetAdapterInfo"));

    исключение

        // По каким-то причинам выполнить скрипт не удалось

        Ответ = "Статус установить не удалось";

    конецпопытки;

    // Если в возращаемом значение пустая строка, то скрипт

    // выполнился. Можно смотреть дальше.

    если Ответ = "" тогда

        // Получаем индекс статуса сетевой.

        стрСтатус = строка(сзСтевые.Получить(стрИмя));

        // Проверяем на пустое значение индекса.

        если пустоезначение(стрСтатус) = 1 тогда

            // Если индекс пуст, то сетевая суказанным именем отсуствует

            Ответ = "Сетевая с таким именем отсуствует";

        иначе

            // Ищем индекс статуса в известных нам типов статуса.

            чисПозиция = сзТипСтатуса.НайтиЗначение(стрСтатус);

            если чисПозиция = 0 тогда

                // Не нашли. Смотрим MSDN

                Ответ = "Не известный тип статуса сетевой";

            иначе

                // Получаем строковое представление статуса.

                сзТипСтатуса.ПолучитьЗначение(чисПозиция, Ответ);

            конецесли;

        конецесли;

    конецесли;

    // Возвращаем полученный статус

    возврат Ответ;

конецфункции;



//*******************************************

// Этот блок обязателен.

// Необходимо что бы он отработал до первого вызова

// функции стрСтатусАдаптера

//*******************************************

// Создаем объект для управления скриптами

обШелл = создатьобъект("MSScriptControl.ScriptControl");

// Устанавливаем рабочий язык для выполнения скриптов

обШелл.Language = "VBScript";

// Сам срипт который соберет статусы всех сетевых устройств

тхтКод = "

|function strGetAdapterInfo()

|  dim objNetworkAdapter

|  Answer = ""{""""СписокЗначений"""",{""

|  set objWMI = getobject(""WinMgmts:\\.\Root\CIMV2"")

|  set objNetworkAdapters = objWMI.ExecQuery(""S_elect * FROM Win32_NetworkAdapter"", , 48)

|  for each objNetworkAdapter in objNetworkAdapters

|    Answer = Answer & ""{{""""Строка"""","""""" & objNetworkAdapter.NetConnectionStatus &_

|             """"""}, """""" & objNetworkAdapter.NetConnectionID & """""",""""0""""}""

|            

|  next

|  Answer = Answer & ""}}""

|  strGetAdapterInfo = Answer

|  end function";

// Добавим наш скрипт в котрол скриптов

обШелл.AddCode(тхтКод);

// Создадим список значений в который поместим все известные нам

// виды статуса сетевых устройств.

сзТипСтатуса = создатьобъект("списокзначений");

// Поместим в список значений виды статусов их строковое представление

сзТипСтатуса.ДобавитьЗначение("0", "Отключенно");

сзТипСтатуса.ДобавитьЗначение("1", "Подключение");

сзТипСтатуса.ДобавитьЗначение("2", "Подключено");

сзТипСтатуса.ДобавитьЗначение("3", "Отключение");

сзТипСтатуса.ДобавитьЗначение("4", "Устройство не представленно");

сзТипСтатуса.ДобавитьЗначение("5", "Устройство отключено");

сзТипСтатуса.ДобавитьЗначение("6", "Устройство не исправно");

сзТипСтатуса.ДобавитьЗначение("7", "Соединение разорвано");

сзТипСтатуса.ДобавитьЗначение("8", "Аутентификация");

сзТипСтатуса.ДобавитьЗначение("9", "Аутентификация прошла успешно");

сзТипСтатуса.ДобавитьЗначение("10", "Аутентификация не прошла");

сзТипСтатуса.ДобавитьЗначение("11", "Неправильный адресс");

сзТипСтатуса.ДобавитьЗначение("12", "Требуется полномочия");

 

// Функция выполняет пропорциональное распределение суммы в соответствии с заданными коэффициентами распределения

//

// Параметры:

//		ИсхСумма - распределяемая сумма

//		МассивКоэф - массив коэффициентов распределения

//		Точность - точность округления при распределении. Необязателен.

//

//	Возврат:

//		МассивСумм - массив размерностью равный массиву коэффициентов, содержит

//			суммы в соответствии с весом коэффициента (из массива коэффициентов)

//          В случае если распределить не удалось (сумма = 0, кол-во коэф. = 0,

//          или суммарный вес коэф. = 0), тогда возвращается значение Неопределено

//

Функция РаспределитьПропорционально(Знач ИсхСумма, МассивКоэф, Знач Точность = 2) Экспорт

	

	Если МассивКоэф.Количество() = 0 Или ИсхСумма = 0 Или ИсхСумма = Null Тогда

		Возврат Неопределено;

	КонецЕсли;

	

	ИндексМакс = 0;

	МаксЗнач   = 0;

	РаспрСумма = 0;

	СуммаКоэф  = 0;

	

	Для К = 0 По МассивКоэф.Количество() - 1 Цикл

		

		МодульЧисла = ?(МассивКоэф[К] > 0, МассивКоэф[К], - МассивКоэф[К]);

		

		Если МаксЗнач < МодульЧисла Тогда

			МаксЗнач = МодульЧисла;

			ИндексМакс = К;

		КонецЕсли;

		

		СуммаКоэф = СуммаКоэф + МассивКоэф[К];

		

	КонецЦикла;

	

	Если СуммаКоэф = 0 Тогда

		Возврат Неопределено;

	КонецЕсли;

	

	МассивСумм = Новый Массив(МассивКоэф.Количество());

	

	Для К = 0 По МассивКоэф.Количество() - 1 Цикл

		МассивСумм[К] = Окр(ИсхСумма * МассивКоэф[К] / СуммаКоэф, Точность, 1);

		РаспрСумма = РаспрСумма + МассивСумм[К];

	КонецЦикла;

	

	// Погрешности округления отнесем на коэффиецент с максимальным весом

	Если Не РаспрСумма = ИсхСумма Тогда

		МассивСумм[ИндексМакс] = МассивСумм[ИндексМакс] + ИсхСумма - РаспрСумма;

	КонецЕсли;

	

	Возврат МассивСумм;

	

КонецФункции

   

 

//Функция формирует удобное для чтения представление значений.



// Примеры форматирования чисел

ЗначФормат = Формат(123456.789, "ЧЦ=10; ЧДЦ=2");      // ЗначФормат = "123 456,79"

ЗначФормат = Формат(123456.789, "ЧГ=0; ЧДЦ=2");      // ЗначФормат = "123456,79"

ЗначФормат = Формат(123456.789, "ЧРД='-'");           // ЗначФормат = "123 456-789"

ЗначФормат = Формат(-123456.789, "ЧО=0");             // ЗначФормат = "(123 456,789)";

ЗначФормат = Формат(13, "ЧЦ=5; ЧВН=; ЧГ=0");      // ЗначФормат = "00013";



//В 8 версии для вывовода чисел прописью используется ЧислоПрописью

ЧислоПрописью(Сумма, "L=ru_RU", Валюта.ПараметрыПрописиНаРусском)  

ЧислоПрописью(1457.25,"L=en_US","dollar, dollars, cent, cents, 2"); // One thousand four hundreds fifty seven dollars 25 cents. 

ЧислоПрописью(Сумма,"Рубль,рубля,рублей,м,копейка,копейки,копеек,ж,2");



//Пример представления Числа в виде Даты

ЗначФормат = Формат(25021949, "ЧЦ=8; ЧРГ=.; ЧВН=; ЧГ=4,2,0");      // ЗначФормат = "25.02.1949"



// Примеры форматирования дат

ЗначФормат = Формат('20020820153309', "ДФ=""дд ММММ гггг 'г.' ЧЧ:мм:сс""");     // ЗначФормат = "20 августа 2002 г. 15:33:09"

ЗначФормат = Формат('20020820153309', "ДФ=""дд/ММ-гггг""");                     // ЗначФормат = "20/08-2002"

ЗначФормат = Формат('20020820153309', "ДФ='q ""кв."" yyyy'"); 		            // ЗначФормат = "3 кв. 2002";

ЗначФормат = Формат('20020820153309', "ДФ='""Итого"" q ""квартал""'") ;	   // ЗначФормат = "Итого 3 квартал";

ЗначФормат = Формат('20020820153309', "ДФ='ММММ гггг'");  		            // ЗначФормат = "Август 2002 г.";

ЗначФормат = Формат('20020820153309', "ДЛФ=ДД");                                // ЗначФормат = "20 августа 2002 г.";

ЗначФормат = Формат('20020820153309', "ДЛФ=Д");                                 // ЗначФормат = "20.08.2002";

ЗначФормат = Формат('20020820153309', "ДЛФ=В");                                 // ЗначФормат = "15:33:09";



ЗначФормат = Формат('20020820153309', "ДФ=HHmmssyyyyMMdd");                                 // ЗначФормат = "15330920020820";

ЗначФормат = Формат('20020820153309', "ДФ=HH:mm:ss yyyy MM dd");                                 // Время 24 часа  - ЗначФормат = "15:33:09 2002 08 20";

ЗначФормат = Формат('20020820153309', "ДФ=hh:mm:ss yyyy MM dd");                                 // Время 12 часов - ЗначФормат = "03:33:09 2002 08 20";



Формат(Дата(2009, 1, 1), "ДЛФ=DD") + ", " + ОпределитьДеньНедели(ДеньНедели(Дата(2009, 1, 1)));   // 1 января 2009 г., Четверг (Смотрите в "Работаем с Датами" Функция Определить день недели)

Формат(Дата(2009, 1, 1), "ДФ=ММММ") + ", " + Формат(Дата(2009, 1, 1), "ДФ=yyyy") + " г.";         // Январь, 2009 г.

Формат(НачалоНедели(Дата(2009, 1, 1)), "ДФ='dd MMMM yyyy'") + " г. - " + Формат(КонецНедели(Дата(2009, 1, 1)), "ДФ='dd MMMM yyyy'") + " г."; // 29 декабря 2008 г. - 04 января 2009 г.



// ДЕКАДУ нельзя вывести через формат, но можно так:

Строка(Цел(День(Дата('20020820153309')) / 10) + 1)+" декада"  = 2 декада



// Примеры форматирования логических выражений

ЗначФормат = Формат(Истина, "БЛ=Отсутствует; БИ=Доступен");                     // ЗначФормат = "Доступен";

ЗначФормат = Формат(Ложь, "БЛ=Нет; БИ=Да");                     				// ЗначФормат = "Нет";

   

 

// Символы, определяющие тип форматируемых данных: 

// Ч — число (Англоязычный синоним: N)  

ЗначФормат = Формат(123.15, "Ч(0)10.2") // 0000123.15

Долг = Строка(Формат(Долг(), "Ч12.2")) + " " + Валюта.Сокр_назв;



// Возможен вывод денежных величин и просто целых чисел прописью. В этом случае форматная строка должна иметь вид "ЧПДС".

// Наличие буквы "П" (в английском варианте для аналогичной цели используется буква "S") определяет сам факт вывода числа прописью. 

// Символ "Д" (в английском варианте — "M") обозначает вывод денежной величины и является необязательным. 

// Символ "С" (в английском варианте — "H") также необязателен и означает вывод с копейками.

ИтогоСуммаПрописью  = Формат(Итог("Сумма"), "ЧПДС");

КоличествоНаименованийПрописью = Формат(КоличествоСтрок(), "ЧП");



// С — строка (Англоязычный синоним: S) 

// "Сn", где n — положительное целое число определяющее ширину поля, в котором будет размещаться строка. 

// В случае, если ширина поля превосходит длину строки сформатированная строка будет дополнена справа пробелами, если же ширина поля меньше длины строки — строка будет усечена справа.





// Д — дата (Англоязычный синоним: D)

ДатаДокумента = Формат(Док.ДатаДок,"Д ДД.ММ.ГГ");  //12.03.08

ДатаДокумента = Формат("01.01.1999", "Д(0)ДДММММГГГГ"); // 01 Января 1999 г.



//Для форматирования даты используется форматная строка вида "Д<ПодстрокаФормата>", где <Подстрока Формата> представляет собой строку, определяющую вид сформатированного представления даты:

//DDMMYY (ДДММГГ)  дата в виде ДД.ММ.ГГ 

//DDMMYYYY (ДДММГГГГ)  дата в виде ДД.ММ.ГГГГ 

//DDMMMMYYYY (ДДММММГГГГ)  дата в виде ДД месяц прописью ГГГГ 

//(0)DDMMMMYYYY ((0)ДДММММГГГГ) этот формат представляет собой вариант предыдущего формата с тем отличием, что число месяца всегда выводится двумя цифрами, т. е. для чисел меньших 10 спереди будет добавлен 0. Например: Формат('01.01.1999', ' 'Д(0)ДДММММГГГГ' ') = 01 Января 1999 г. 

//MMMMYYYY (ММММГГГГ) дата в виде месяц прописью ГГГГ 

//MMMMYY (ММММГГ) дата в виде месяц прописью ГГ 

//ММММ (ММММ) дата в виде месяц прописью 

//QQQQYYYY (ККККГГГГ) дата в виде N квартала ГГГГ 

//QQQQYY (ККККГГ) дата в виде N квартала ГГ 

//QQQQ дата в виде N квартала 

//YYYYMMDD (ГГГГММДД) дата в виде ГГГГММДД, то есть дата '10.11.1998' будет представлена как строка "19981110" 

//WWWW (HHHH) выводит наименование дня недели, соответствующее указанной дате. Наименования дней недели берутся из файла прописи.